src/HOL/Real.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 60429 d3d1e185cd63
child 60758 d8d85a8172b5
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title:      HOL/Real.thy
     2     Author:     Jacques D. Fleuriot, University of Edinburgh, 1998
     3     Author:     Larry Paulson, University of Cambridge
     4     Author:     Jeremy Avigad, Carnegie Mellon University
     5     Author:     Florian Zuleger, Johannes Hoelzl, and Simon Funke, TU Muenchen
     6     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     7     Construction of Cauchy Reals by Brian Huffman, 2010
     8 *)
     9 
    10 section {* Development of the Reals using Cauchy Sequences *}
    11 
    12 theory Real
    13 imports Rat Conditionally_Complete_Lattices
    14 begin
    15 
    16 text {*
    17   This theory contains a formalization of the real numbers as
    18   equivalence classes of Cauchy sequences of rationals.  See
    19   @{file "~~/src/HOL/ex/Dedekind_Real.thy"} for an alternative
    20   construction using Dedekind cuts.
    21 *}
    22 
    23 subsection {* Preliminary lemmas *}
    24 
    25 lemma add_diff_add:
    26   fixes a b c d :: "'a::ab_group_add"
    27   shows "(a + c) - (b + d) = (a - b) + (c - d)"
    28   by simp
    29 
    30 lemma minus_diff_minus:
    31   fixes a b :: "'a::ab_group_add"
    32   shows "- a - - b = - (a - b)"
    33   by simp
    34 
    35 lemma mult_diff_mult:
    36   fixes x y a b :: "'a::ring"
    37   shows "(x * y - a * b) = x * (y - b) + (x - a) * b"
    38   by (simp add: algebra_simps)
    39 
    40 lemma inverse_diff_inverse:
    41   fixes a b :: "'a::division_ring"
    42   assumes "a \<noteq> 0" and "b \<noteq> 0"
    43   shows "inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
    44   using assms by (simp add: algebra_simps)
    45 
    46 lemma obtain_pos_sum:
    47   fixes r :: rat assumes r: "0 < r"
    48   obtains s t where "0 < s" and "0 < t" and "r = s + t"
    49 proof
    50     from r show "0 < r/2" by simp
    51     from r show "0 < r/2" by simp
    52     show "r = r/2 + r/2" by simp
    53 qed
    54 
    55 subsection {* Sequences that converge to zero *}
    56 
    57 definition
    58   vanishes :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
    59 where
    60   "vanishes X = (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r)"
    61 
    62 lemma vanishesI: "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r) \<Longrightarrow> vanishes X"
    63   unfolding vanishes_def by simp
    64 
    65 lemma vanishesD: "\<lbrakk>vanishes X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r"
    66   unfolding vanishes_def by simp
    67 
    68 lemma vanishes_const [simp]: "vanishes (\<lambda>n. c) \<longleftrightarrow> c = 0"
    69   unfolding vanishes_def
    70   apply (cases "c = 0", auto)
    71   apply (rule exI [where x="\<bar>c\<bar>"], auto)
    72   done
    73 
    74 lemma vanishes_minus: "vanishes X \<Longrightarrow> vanishes (\<lambda>n. - X n)"
    75   unfolding vanishes_def by simp
    76 
    77 lemma vanishes_add:
    78   assumes X: "vanishes X" and Y: "vanishes Y"
    79   shows "vanishes (\<lambda>n. X n + Y n)"
    80 proof (rule vanishesI)
    81   fix r :: rat assume "0 < r"
    82   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
    83     by (rule obtain_pos_sum)
    84   obtain i where i: "\<forall>n\<ge>i. \<bar>X n\<bar> < s"
    85     using vanishesD [OF X s] ..
    86   obtain j where j: "\<forall>n\<ge>j. \<bar>Y n\<bar> < t"
    87     using vanishesD [OF Y t] ..
    88   have "\<forall>n\<ge>max i j. \<bar>X n + Y n\<bar> < r"
    89   proof (clarsimp)
    90     fix n assume n: "i \<le> n" "j \<le> n"
    91     have "\<bar>X n + Y n\<bar> \<le> \<bar>X n\<bar> + \<bar>Y n\<bar>" by (rule abs_triangle_ineq)
    92     also have "\<dots> < s + t" by (simp add: add_strict_mono i j n)
    93     finally show "\<bar>X n + Y n\<bar> < r" unfolding r .
    94   qed
    95   thus "\<exists>k. \<forall>n\<ge>k. \<bar>X n + Y n\<bar> < r" ..
    96 qed
    97 
    98 lemma vanishes_diff:
    99   assumes X: "vanishes X" and Y: "vanishes Y"
   100   shows "vanishes (\<lambda>n. X n - Y n)"
   101   unfolding diff_conv_add_uminus by (intro vanishes_add vanishes_minus X Y)
   102 
   103 lemma vanishes_mult_bounded:
   104   assumes X: "\<exists>a>0. \<forall>n. \<bar>X n\<bar> < a"
   105   assumes Y: "vanishes (\<lambda>n. Y n)"
   106   shows "vanishes (\<lambda>n. X n * Y n)"
   107 proof (rule vanishesI)
   108   fix r :: rat assume r: "0 < r"
   109   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
   110     using X by fast
   111   obtain b where b: "0 < b" "r = a * b"
   112   proof
   113     show "0 < r / a" using r a by simp
   114     show "r = a * (r / a)" using a by simp
   115   qed
   116   obtain k where k: "\<forall>n\<ge>k. \<bar>Y n\<bar> < b"
   117     using vanishesD [OF Y b(1)] ..
   118   have "\<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r"
   119     by (simp add: b(2) abs_mult mult_strict_mono' a k)
   120   thus "\<exists>k. \<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r" ..
   121 qed
   122 
   123 subsection {* Cauchy sequences *}
   124 
   125 definition
   126   cauchy :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
   127 where
   128   "cauchy X \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r)"
   129 
   130 lemma cauchyI:
   131   "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r) \<Longrightarrow> cauchy X"
   132   unfolding cauchy_def by simp
   133 
   134 lemma cauchyD:
   135   "\<lbrakk>cauchy X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r"
   136   unfolding cauchy_def by simp
   137 
   138 lemma cauchy_const [simp]: "cauchy (\<lambda>n. x)"
   139   unfolding cauchy_def by simp
   140 
   141 lemma cauchy_add [simp]:
   142   assumes X: "cauchy X" and Y: "cauchy Y"
   143   shows "cauchy (\<lambda>n. X n + Y n)"
   144 proof (rule cauchyI)
   145   fix r :: rat assume "0 < r"
   146   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   147     by (rule obtain_pos_sum)
   148   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   149     using cauchyD [OF X s] ..
   150   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
   151     using cauchyD [OF Y t] ..
   152   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r"
   153   proof (clarsimp)
   154     fix m n assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   155     have "\<bar>(X m + Y m) - (X n + Y n)\<bar> \<le> \<bar>X m - X n\<bar> + \<bar>Y m - Y n\<bar>"
   156       unfolding add_diff_add by (rule abs_triangle_ineq)
   157     also have "\<dots> < s + t"
   158       by (rule add_strict_mono, simp_all add: i j *)
   159     finally show "\<bar>(X m + Y m) - (X n + Y n)\<bar> < r" unfolding r .
   160   qed
   161   thus "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r" ..
   162 qed
   163 
   164 lemma cauchy_minus [simp]:
   165   assumes X: "cauchy X"
   166   shows "cauchy (\<lambda>n. - X n)"
   167 using assms unfolding cauchy_def
   168 unfolding minus_diff_minus abs_minus_cancel .
   169 
   170 lemma cauchy_diff [simp]:
   171   assumes X: "cauchy X" and Y: "cauchy Y"
   172   shows "cauchy (\<lambda>n. X n - Y n)"
   173   using assms unfolding diff_conv_add_uminus by (simp del: add_uminus_conv_diff)
   174 
   175 lemma cauchy_imp_bounded:
   176   assumes "cauchy X" shows "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
   177 proof -
   178   obtain k where k: "\<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < 1"
   179     using cauchyD [OF assms zero_less_one] ..
   180   show "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
   181   proof (intro exI conjI allI)
   182     have "0 \<le> \<bar>X 0\<bar>" by simp
   183     also have "\<bar>X 0\<bar> \<le> Max (abs ` X ` {..k})" by simp
   184     finally have "0 \<le> Max (abs ` X ` {..k})" .
   185     thus "0 < Max (abs ` X ` {..k}) + 1" by simp
   186   next
   187     fix n :: nat
   188     show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1"
   189     proof (rule linorder_le_cases)
   190       assume "n \<le> k"
   191       hence "\<bar>X n\<bar> \<le> Max (abs ` X ` {..k})" by simp
   192       thus "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" by simp
   193     next
   194       assume "k \<le> n"
   195       have "\<bar>X n\<bar> = \<bar>X k + (X n - X k)\<bar>" by simp
   196       also have "\<bar>X k + (X n - X k)\<bar> \<le> \<bar>X k\<bar> + \<bar>X n - X k\<bar>"
   197         by (rule abs_triangle_ineq)
   198       also have "\<dots> < Max (abs ` X ` {..k}) + 1"
   199         by (rule add_le_less_mono, simp, simp add: k `k \<le> n`)
   200       finally show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" .
   201     qed
   202   qed
   203 qed
   204 
   205 lemma cauchy_mult [simp]:
   206   assumes X: "cauchy X" and Y: "cauchy Y"
   207   shows "cauchy (\<lambda>n. X n * Y n)"
   208 proof (rule cauchyI)
   209   fix r :: rat assume "0 < r"
   210   then obtain u v where u: "0 < u" and v: "0 < v" and "r = u + v"
   211     by (rule obtain_pos_sum)
   212   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
   213     using cauchy_imp_bounded [OF X] by fast
   214   obtain b where b: "0 < b" "\<forall>n. \<bar>Y n\<bar> < b"
   215     using cauchy_imp_bounded [OF Y] by fast
   216   obtain s t where s: "0 < s" and t: "0 < t" and r: "r = a * t + s * b"
   217   proof
   218     show "0 < v/b" using v b(1) by simp
   219     show "0 < u/a" using u a(1) by simp
   220     show "r = a * (u/a) + (v/b) * b"
   221       using a(1) b(1) `r = u + v` by simp
   222   qed
   223   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   224     using cauchyD [OF X s] ..
   225   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
   226     using cauchyD [OF Y t] ..
   227   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>X m * Y m - X n * Y n\<bar> < r"
   228   proof (clarsimp)
   229     fix m n assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   230     have "\<bar>X m * Y m - X n * Y n\<bar> = \<bar>X m * (Y m - Y n) + (X m - X n) * Y n\<bar>"
   231       unfolding mult_diff_mult ..
   232     also have "\<dots> \<le> \<bar>X m * (Y m - Y n)\<bar> + \<bar>(X m - X n) * Y n\<bar>"
   233       by (rule abs_triangle_ineq)
   234     also have "\<dots> = \<bar>X m\<bar> * \<bar>Y m - Y n\<bar> + \<bar>X m - X n\<bar> * \<bar>Y n\<bar>"
   235       unfolding abs_mult ..
   236     also have "\<dots> < a * t + s * b"
   237       by (simp_all add: add_strict_mono mult_strict_mono' a b i j *)
   238     finally show "\<bar>X m * Y m - X n * Y n\<bar> < r" unfolding r .
   239   qed
   240   thus "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m * Y m - X n * Y n\<bar> < r" ..
   241 qed
   242 
   243 lemma cauchy_not_vanishes_cases:
   244   assumes X: "cauchy X"
   245   assumes nz: "\<not> vanishes X"
   246   shows "\<exists>b>0. \<exists>k. (\<forall>n\<ge>k. b < - X n) \<or> (\<forall>n\<ge>k. b < X n)"
   247 proof -
   248   obtain r where "0 < r" and r: "\<forall>k. \<exists>n\<ge>k. r \<le> \<bar>X n\<bar>"
   249     using nz unfolding vanishes_def by (auto simp add: not_less)
   250   obtain s t where s: "0 < s" and t: "0 < t" and "r = s + t"
   251     using `0 < r` by (rule obtain_pos_sum)
   252   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   253     using cauchyD [OF X s] ..
   254   obtain k where "i \<le> k" and "r \<le> \<bar>X k\<bar>"
   255     using r by fast
   256   have k: "\<forall>n\<ge>k. \<bar>X n - X k\<bar> < s"
   257     using i `i \<le> k` by auto
   258   have "X k \<le> - r \<or> r \<le> X k"
   259     using `r \<le> \<bar>X k\<bar>` by auto
   260   hence "(\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
   261     unfolding `r = s + t` using k by auto
   262   hence "\<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)" ..
   263   thus "\<exists>t>0. \<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
   264     using t by auto
   265 qed
   266 
   267 lemma cauchy_not_vanishes:
   268   assumes X: "cauchy X"
   269   assumes nz: "\<not> vanishes X"
   270   shows "\<exists>b>0. \<exists>k. \<forall>n\<ge>k. b < \<bar>X n\<bar>"
   271 using cauchy_not_vanishes_cases [OF assms]
   272 by clarify (rule exI, erule conjI, rule_tac x=k in exI, auto)
   273 
   274 lemma cauchy_inverse [simp]:
   275   assumes X: "cauchy X"
   276   assumes nz: "\<not> vanishes X"
   277   shows "cauchy (\<lambda>n. inverse (X n))"
   278 proof (rule cauchyI)
   279   fix r :: rat assume "0 < r"
   280   obtain b i where b: "0 < b" and i: "\<forall>n\<ge>i. b < \<bar>X n\<bar>"
   281     using cauchy_not_vanishes [OF X nz] by fast
   282   from b i have nz: "\<forall>n\<ge>i. X n \<noteq> 0" by auto
   283   obtain s where s: "0 < s" and r: "r = inverse b * s * inverse b"
   284   proof
   285     show "0 < b * r * b" by (simp add: `0 < r` b)
   286     show "r = inverse b * (b * r * b) * inverse b"
   287       using b by simp
   288   qed
   289   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>X m - X n\<bar> < s"
   290     using cauchyD [OF X s] ..
   291   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>inverse (X m) - inverse (X n)\<bar> < r"
   292   proof (clarsimp)
   293     fix m n assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   294     have "\<bar>inverse (X m) - inverse (X n)\<bar> =
   295           inverse \<bar>X m\<bar> * \<bar>X m - X n\<bar> * inverse \<bar>X n\<bar>"
   296       by (simp add: inverse_diff_inverse nz * abs_mult)
   297     also have "\<dots> < inverse b * s * inverse b"
   298       by (simp add: mult_strict_mono less_imp_inverse_less
   299                     i j b * s)
   300     finally show "\<bar>inverse (X m) - inverse (X n)\<bar> < r" unfolding r .
   301   qed
   302   thus "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>inverse (X m) - inverse (X n)\<bar> < r" ..
   303 qed
   304 
   305 lemma vanishes_diff_inverse:
   306   assumes X: "cauchy X" "\<not> vanishes X"
   307   assumes Y: "cauchy Y" "\<not> vanishes Y"
   308   assumes XY: "vanishes (\<lambda>n. X n - Y n)"
   309   shows "vanishes (\<lambda>n. inverse (X n) - inverse (Y n))"
   310 proof (rule vanishesI)
   311   fix r :: rat assume r: "0 < r"
   312   obtain a i where a: "0 < a" and i: "\<forall>n\<ge>i. a < \<bar>X n\<bar>"
   313     using cauchy_not_vanishes [OF X] by fast
   314   obtain b j where b: "0 < b" and j: "\<forall>n\<ge>j. b < \<bar>Y n\<bar>"
   315     using cauchy_not_vanishes [OF Y] by fast
   316   obtain s where s: "0 < s" and "inverse a * s * inverse b = r"
   317   proof
   318     show "0 < a * r * b"
   319       using a r b by simp
   320     show "inverse a * (a * r * b) * inverse b = r"
   321       using a r b by simp
   322   qed
   323   obtain k where k: "\<forall>n\<ge>k. \<bar>X n - Y n\<bar> < s"
   324     using vanishesD [OF XY s] ..
   325   have "\<forall>n\<ge>max (max i j) k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r"
   326   proof (clarsimp)
   327     fix n assume n: "i \<le> n" "j \<le> n" "k \<le> n"
   328     have "X n \<noteq> 0" and "Y n \<noteq> 0"
   329       using i j a b n by auto
   330     hence "\<bar>inverse (X n) - inverse (Y n)\<bar> =
   331         inverse \<bar>X n\<bar> * \<bar>X n - Y n\<bar> * inverse \<bar>Y n\<bar>"
   332       by (simp add: inverse_diff_inverse abs_mult)
   333     also have "\<dots> < inverse a * s * inverse b"
   334       apply (intro mult_strict_mono' less_imp_inverse_less)
   335       apply (simp_all add: a b i j k n)
   336       done
   337     also note `inverse a * s * inverse b = r`
   338     finally show "\<bar>inverse (X n) - inverse (Y n)\<bar> < r" .
   339   qed
   340   thus "\<exists>k. \<forall>n\<ge>k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r" ..
   341 qed
   342 
   343 subsection {* Equivalence relation on Cauchy sequences *}
   344 
   345 definition realrel :: "(nat \<Rightarrow> rat) \<Rightarrow> (nat \<Rightarrow> rat) \<Rightarrow> bool"
   346   where "realrel = (\<lambda>X Y. cauchy X \<and> cauchy Y \<and> vanishes (\<lambda>n. X n - Y n))"
   347 
   348 lemma realrelI [intro?]:
   349   assumes "cauchy X" and "cauchy Y" and "vanishes (\<lambda>n. X n - Y n)"
   350   shows "realrel X Y"
   351   using assms unfolding realrel_def by simp
   352 
   353 lemma realrel_refl: "cauchy X \<Longrightarrow> realrel X X"
   354   unfolding realrel_def by simp
   355 
   356 lemma symp_realrel: "symp realrel"
   357   unfolding realrel_def
   358   by (rule sympI, clarify, drule vanishes_minus, simp)
   359 
   360 lemma transp_realrel: "transp realrel"
   361   unfolding realrel_def
   362   apply (rule transpI, clarify)
   363   apply (drule (1) vanishes_add)
   364   apply (simp add: algebra_simps)
   365   done
   366 
   367 lemma part_equivp_realrel: "part_equivp realrel"
   368   by (fast intro: part_equivpI symp_realrel transp_realrel
   369     realrel_refl cauchy_const)
   370 
   371 subsection {* The field of real numbers *}
   372 
   373 quotient_type real = "nat \<Rightarrow> rat" / partial: realrel
   374   morphisms rep_real Real
   375   by (rule part_equivp_realrel)
   376 
   377 lemma cr_real_eq: "pcr_real = (\<lambda>x y. cauchy x \<and> Real x = y)"
   378   unfolding real.pcr_cr_eq cr_real_def realrel_def by auto
   379 
   380 lemma Real_induct [induct type: real]: (* TODO: generate automatically *)
   381   assumes "\<And>X. cauchy X \<Longrightarrow> P (Real X)" shows "P x"
   382 proof (induct x)
   383   case (1 X)
   384   hence "cauchy X" by (simp add: realrel_def)
   385   thus "P (Real X)" by (rule assms)
   386 qed
   387 
   388 lemma eq_Real:
   389   "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X = Real Y \<longleftrightarrow> vanishes (\<lambda>n. X n - Y n)"
   390   using real.rel_eq_transfer
   391   unfolding real.pcr_cr_eq cr_real_def rel_fun_def realrel_def by simp
   392 
   393 lemma Domainp_pcr_real [transfer_domain_rule]: "Domainp pcr_real = cauchy"
   394 by (simp add: real.domain_eq realrel_def)
   395 
   396 instantiation real :: field
   397 begin
   398 
   399 lift_definition zero_real :: "real" is "\<lambda>n. 0"
   400   by (simp add: realrel_refl)
   401 
   402 lift_definition one_real :: "real" is "\<lambda>n. 1"
   403   by (simp add: realrel_refl)
   404 
   405 lift_definition plus_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n + Y n"
   406   unfolding realrel_def add_diff_add
   407   by (simp only: cauchy_add vanishes_add simp_thms)
   408 
   409 lift_definition uminus_real :: "real \<Rightarrow> real" is "\<lambda>X n. - X n"
   410   unfolding realrel_def minus_diff_minus
   411   by (simp only: cauchy_minus vanishes_minus simp_thms)
   412 
   413 lift_definition times_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n * Y n"
   414   unfolding realrel_def mult_diff_mult
   415   by (subst (4) mult.commute, simp only: cauchy_mult vanishes_add
   416     vanishes_mult_bounded cauchy_imp_bounded simp_thms)
   417 
   418 lift_definition inverse_real :: "real \<Rightarrow> real"
   419   is "\<lambda>X. if vanishes X then (\<lambda>n. 0) else (\<lambda>n. inverse (X n))"
   420 proof -
   421   fix X Y assume "realrel X Y"
   422   hence X: "cauchy X" and Y: "cauchy Y" and XY: "vanishes (\<lambda>n. X n - Y n)"
   423     unfolding realrel_def by simp_all
   424   have "vanishes X \<longleftrightarrow> vanishes Y"
   425   proof
   426     assume "vanishes X"
   427     from vanishes_diff [OF this XY] show "vanishes Y" by simp
   428   next
   429     assume "vanishes Y"
   430     from vanishes_add [OF this XY] show "vanishes X" by simp
   431   qed
   432   thus "?thesis X Y"
   433     unfolding realrel_def
   434     by (simp add: vanishes_diff_inverse X Y XY)
   435 qed
   436 
   437 definition
   438   "x - y = (x::real) + - y"
   439 
   440 definition
   441   "x div y = (x::real) * inverse y"
   442 
   443 lemma add_Real:
   444   assumes X: "cauchy X" and Y: "cauchy Y"
   445   shows "Real X + Real Y = Real (\<lambda>n. X n + Y n)"
   446   using assms plus_real.transfer
   447   unfolding cr_real_eq rel_fun_def by simp
   448 
   449 lemma minus_Real:
   450   assumes X: "cauchy X"
   451   shows "- Real X = Real (\<lambda>n. - X n)"
   452   using assms uminus_real.transfer
   453   unfolding cr_real_eq rel_fun_def by simp
   454 
   455 lemma diff_Real:
   456   assumes X: "cauchy X" and Y: "cauchy Y"
   457   shows "Real X - Real Y = Real (\<lambda>n. X n - Y n)"
   458   unfolding minus_real_def
   459   by (simp add: minus_Real add_Real X Y)
   460 
   461 lemma mult_Real:
   462   assumes X: "cauchy X" and Y: "cauchy Y"
   463   shows "Real X * Real Y = Real (\<lambda>n. X n * Y n)"
   464   using assms times_real.transfer
   465   unfolding cr_real_eq rel_fun_def by simp
   466 
   467 lemma inverse_Real:
   468   assumes X: "cauchy X"
   469   shows "inverse (Real X) =
   470     (if vanishes X then 0 else Real (\<lambda>n. inverse (X n)))"
   471   using assms inverse_real.transfer zero_real.transfer
   472   unfolding cr_real_eq rel_fun_def by (simp split: split_if_asm, metis)
   473 
   474 instance proof
   475   fix a b c :: real
   476   show "a + b = b + a"
   477     by transfer (simp add: ac_simps realrel_def)
   478   show "(a + b) + c = a + (b + c)"
   479     by transfer (simp add: ac_simps realrel_def)
   480   show "0 + a = a"
   481     by transfer (simp add: realrel_def)
   482   show "- a + a = 0"
   483     by transfer (simp add: realrel_def)
   484   show "a - b = a + - b"
   485     by (rule minus_real_def)
   486   show "(a * b) * c = a * (b * c)"
   487     by transfer (simp add: ac_simps realrel_def)
   488   show "a * b = b * a"
   489     by transfer (simp add: ac_simps realrel_def)
   490   show "1 * a = a"
   491     by transfer (simp add: ac_simps realrel_def)
   492   show "(a + b) * c = a * c + b * c"
   493     by transfer (simp add: distrib_right realrel_def)
   494   show "(0\<Colon>real) \<noteq> (1\<Colon>real)"
   495     by transfer (simp add: realrel_def)
   496   show "a \<noteq> 0 \<Longrightarrow> inverse a * a = 1"
   497     apply transfer
   498     apply (simp add: realrel_def)
   499     apply (rule vanishesI)
   500     apply (frule (1) cauchy_not_vanishes, clarify)
   501     apply (rule_tac x=k in exI, clarify)
   502     apply (drule_tac x=n in spec, simp)
   503     done
   504   show "a div b = a * inverse b"
   505     by (rule divide_real_def)
   506   show "inverse (0::real) = 0"
   507     by transfer (simp add: realrel_def)
   508 qed
   509 
   510 end
   511 
   512 subsection {* Positive reals *}
   513 
   514 lift_definition positive :: "real \<Rightarrow> bool"
   515   is "\<lambda>X. \<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n"
   516 proof -
   517   { fix X Y
   518     assume "realrel X Y"
   519     hence XY: "vanishes (\<lambda>n. X n - Y n)"
   520       unfolding realrel_def by simp_all
   521     assume "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n"
   522     then obtain r i where "0 < r" and i: "\<forall>n\<ge>i. r < X n"
   523       by fast
   524     obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   525       using `0 < r` by (rule obtain_pos_sum)
   526     obtain j where j: "\<forall>n\<ge>j. \<bar>X n - Y n\<bar> < s"
   527       using vanishesD [OF XY s] ..
   528     have "\<forall>n\<ge>max i j. t < Y n"
   529     proof (clarsimp)
   530       fix n assume n: "i \<le> n" "j \<le> n"
   531       have "\<bar>X n - Y n\<bar> < s" and "r < X n"
   532         using i j n by simp_all
   533       thus "t < Y n" unfolding r by simp
   534     qed
   535     hence "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < Y n" using t by fast
   536   } note 1 = this
   537   fix X Y assume "realrel X Y"
   538   hence "realrel X Y" and "realrel Y X"
   539     using symp_realrel unfolding symp_def by auto
   540   thus "?thesis X Y"
   541     by (safe elim!: 1)
   542 qed
   543 
   544 lemma positive_Real:
   545   assumes X: "cauchy X"
   546   shows "positive (Real X) \<longleftrightarrow> (\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n)"
   547   using assms positive.transfer
   548   unfolding cr_real_eq rel_fun_def by simp
   549 
   550 lemma positive_zero: "\<not> positive 0"
   551   by transfer auto
   552 
   553 lemma positive_add:
   554   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   555 apply transfer
   556 apply (clarify, rename_tac a b i j)
   557 apply (rule_tac x="a + b" in exI, simp)
   558 apply (rule_tac x="max i j" in exI, clarsimp)
   559 apply (simp add: add_strict_mono)
   560 done
   561 
   562 lemma positive_mult:
   563   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   564 apply transfer
   565 apply (clarify, rename_tac a b i j)
   566 apply (rule_tac x="a * b" in exI, simp)
   567 apply (rule_tac x="max i j" in exI, clarsimp)
   568 apply (rule mult_strict_mono, auto)
   569 done
   570 
   571 lemma positive_minus:
   572   "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   573 apply transfer
   574 apply (simp add: realrel_def)
   575 apply (drule (1) cauchy_not_vanishes_cases, safe, fast, fast)
   576 done
   577 
   578 instantiation real :: linordered_field
   579 begin
   580 
   581 definition
   582   "x < y \<longleftrightarrow> positive (y - x)"
   583 
   584 definition
   585   "x \<le> (y::real) \<longleftrightarrow> x < y \<or> x = y"
   586 
   587 definition
   588   "abs (a::real) = (if a < 0 then - a else a)"
   589 
   590 definition
   591   "sgn (a::real) = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   592 
   593 instance proof
   594   fix a b c :: real
   595   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   596     by (rule abs_real_def)
   597   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   598     unfolding less_eq_real_def less_real_def
   599     by (auto, drule (1) positive_add, simp_all add: positive_zero)
   600   show "a \<le> a"
   601     unfolding less_eq_real_def by simp
   602   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   603     unfolding less_eq_real_def less_real_def
   604     by (auto, drule (1) positive_add, simp add: algebra_simps)
   605   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   606     unfolding less_eq_real_def less_real_def
   607     by (auto, drule (1) positive_add, simp add: positive_zero)
   608   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   609     unfolding less_eq_real_def less_real_def by auto
   610     (* FIXME: Procedure int_combine_numerals: c + b - (c + a) \<equiv> b + - a *)
   611     (* Should produce c + b - (c + a) \<equiv> b - a *)
   612   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   613     by (rule sgn_real_def)
   614   show "a \<le> b \<or> b \<le> a"
   615     unfolding less_eq_real_def less_real_def
   616     by (auto dest!: positive_minus)
   617   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   618     unfolding less_real_def
   619     by (drule (1) positive_mult, simp add: algebra_simps)
   620 qed
   621 
   622 end
   623 
   624 instantiation real :: distrib_lattice
   625 begin
   626 
   627 definition
   628   "(inf :: real \<Rightarrow> real \<Rightarrow> real) = min"
   629 
   630 definition
   631   "(sup :: real \<Rightarrow> real \<Rightarrow> real) = max"
   632 
   633 instance proof
   634 qed (auto simp add: inf_real_def sup_real_def max_min_distrib2)
   635 
   636 end
   637 
   638 lemma of_nat_Real: "of_nat x = Real (\<lambda>n. of_nat x)"
   639 apply (induct x)
   640 apply (simp add: zero_real_def)
   641 apply (simp add: one_real_def add_Real)
   642 done
   643 
   644 lemma of_int_Real: "of_int x = Real (\<lambda>n. of_int x)"
   645 apply (cases x rule: int_diff_cases)
   646 apply (simp add: of_nat_Real diff_Real)
   647 done
   648 
   649 lemma of_rat_Real: "of_rat x = Real (\<lambda>n. x)"
   650 apply (induct x)
   651 apply (simp add: Fract_of_int_quotient of_rat_divide)
   652 apply (simp add: of_int_Real divide_inverse)
   653 apply (simp add: inverse_Real mult_Real)
   654 done
   655 
   656 instance real :: archimedean_field
   657 proof
   658   fix x :: real
   659   show "\<exists>z. x \<le> of_int z"
   660     apply (induct x)
   661     apply (frule cauchy_imp_bounded, clarify)
   662     apply (rule_tac x="ceiling b + 1" in exI)
   663     apply (rule less_imp_le)
   664     apply (simp add: of_int_Real less_real_def diff_Real positive_Real)
   665     apply (rule_tac x=1 in exI, simp add: algebra_simps)
   666     apply (rule_tac x=0 in exI, clarsimp)
   667     apply (rule le_less_trans [OF abs_ge_self])
   668     apply (rule less_le_trans [OF _ le_of_int_ceiling])
   669     apply simp
   670     done
   671 qed
   672 
   673 instantiation real :: floor_ceiling
   674 begin
   675 
   676 definition [code del]:
   677   "floor (x::real) = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   678 
   679 instance proof
   680   fix x :: real
   681   show "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   682     unfolding floor_real_def using floor_exists1 by (rule theI')
   683 qed
   684 
   685 end
   686 
   687 subsection {* Completeness *}
   688 
   689 lemma not_positive_Real:
   690   assumes X: "cauchy X"
   691   shows "\<not> positive (Real X) \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> r)"
   692 unfolding positive_Real [OF X]
   693 apply (auto, unfold not_less)
   694 apply (erule obtain_pos_sum)
   695 apply (drule_tac x=s in spec, simp)
   696 apply (drule_tac r=t in cauchyD [OF X], clarify)
   697 apply (drule_tac x=k in spec, clarsimp)
   698 apply (rule_tac x=n in exI, clarify, rename_tac m)
   699 apply (drule_tac x=m in spec, simp)
   700 apply (drule_tac x=n in spec, simp)
   701 apply (drule spec, drule (1) mp, clarify, rename_tac i)
   702 apply (rule_tac x="max i k" in exI, simp)
   703 done
   704 
   705 lemma le_Real:
   706   assumes X: "cauchy X" and Y: "cauchy Y"
   707   shows "Real X \<le> Real Y = (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r)"
   708 unfolding not_less [symmetric, where 'a=real] less_real_def
   709 apply (simp add: diff_Real not_positive_Real X Y)
   710 apply (simp add: diff_le_eq ac_simps)
   711 done
   712 
   713 lemma le_RealI:
   714   assumes Y: "cauchy Y"
   715   shows "\<forall>n. x \<le> of_rat (Y n) \<Longrightarrow> x \<le> Real Y"
   716 proof (induct x)
   717   fix X assume X: "cauchy X" and "\<forall>n. Real X \<le> of_rat (Y n)"
   718   hence le: "\<And>m r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. X n \<le> Y m + r"
   719     by (simp add: of_rat_Real le_Real)
   720   {
   721     fix r :: rat assume "0 < r"
   722     then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   723       by (rule obtain_pos_sum)
   724     obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>Y m - Y n\<bar> < s"
   725       using cauchyD [OF Y s] ..
   726     obtain j where j: "\<forall>n\<ge>j. X n \<le> Y i + t"
   727       using le [OF t] ..
   728     have "\<forall>n\<ge>max i j. X n \<le> Y n + r"
   729     proof (clarsimp)
   730       fix n assume n: "i \<le> n" "j \<le> n"
   731       have "X n \<le> Y i + t" using n j by simp
   732       moreover have "\<bar>Y i - Y n\<bar> < s" using n i by simp
   733       ultimately show "X n \<le> Y n + r" unfolding r by simp
   734     qed
   735     hence "\<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r" ..
   736   }
   737   thus "Real X \<le> Real Y"
   738     by (simp add: of_rat_Real le_Real X Y)
   739 qed
   740 
   741 lemma Real_leI:
   742   assumes X: "cauchy X"
   743   assumes le: "\<forall>n. of_rat (X n) \<le> y"
   744   shows "Real X \<le> y"
   745 proof -
   746   have "- y \<le> - Real X"
   747     by (simp add: minus_Real X le_RealI of_rat_minus le)
   748   thus ?thesis by simp
   749 qed
   750 
   751 lemma less_RealD:
   752   assumes Y: "cauchy Y"
   753   shows "x < Real Y \<Longrightarrow> \<exists>n. x < of_rat (Y n)"
   754 by (erule contrapos_pp, simp add: not_less, erule Real_leI [OF Y])
   755 
   756 lemma of_nat_less_two_power:
   757   "of_nat n < (2::'a::linordered_idom) ^ n"
   758 apply (induct n)
   759 apply simp
   760 by (metis add_le_less_mono mult_2 of_nat_Suc one_le_numeral one_le_power power_Suc)
   761 
   762 lemma complete_real:
   763   fixes S :: "real set"
   764   assumes "\<exists>x. x \<in> S" and "\<exists>z. \<forall>x\<in>S. x \<le> z"
   765   shows "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
   766 proof -
   767   obtain x where x: "x \<in> S" using assms(1) ..
   768   obtain z where z: "\<forall>x\<in>S. x \<le> z" using assms(2) ..
   769 
   770   def P \<equiv> "\<lambda>x. \<forall>y\<in>S. y \<le> of_rat x"
   771   obtain a where a: "\<not> P a"
   772   proof
   773     have "of_int (floor (x - 1)) \<le> x - 1" by (rule of_int_floor_le)
   774     also have "x - 1 < x" by simp
   775     finally have "of_int (floor (x - 1)) < x" .
   776     hence "\<not> x \<le> of_int (floor (x - 1))" by (simp only: not_le)
   777     then show "\<not> P (of_int (floor (x - 1)))"
   778       unfolding P_def of_rat_of_int_eq using x by fast
   779   qed
   780   obtain b where b: "P b"
   781   proof
   782     show "P (of_int (ceiling z))"
   783     unfolding P_def of_rat_of_int_eq
   784     proof
   785       fix y assume "y \<in> S"
   786       hence "y \<le> z" using z by simp
   787       also have "z \<le> of_int (ceiling z)" by (rule le_of_int_ceiling)
   788       finally show "y \<le> of_int (ceiling z)" .
   789     qed
   790   qed
   791 
   792   def avg \<equiv> "\<lambda>x y :: rat. x/2 + y/2"
   793   def bisect \<equiv> "\<lambda>(x, y). if P (avg x y) then (x, avg x y) else (avg x y, y)"
   794   def A \<equiv> "\<lambda>n. fst ((bisect ^^ n) (a, b))"
   795   def B \<equiv> "\<lambda>n. snd ((bisect ^^ n) (a, b))"
   796   def C \<equiv> "\<lambda>n. avg (A n) (B n)"
   797   have A_0 [simp]: "A 0 = a" unfolding A_def by simp
   798   have B_0 [simp]: "B 0 = b" unfolding B_def by simp
   799   have A_Suc [simp]: "\<And>n. A (Suc n) = (if P (C n) then A n else C n)"
   800     unfolding A_def B_def C_def bisect_def split_def by simp
   801   have B_Suc [simp]: "\<And>n. B (Suc n) = (if P (C n) then C n else B n)"
   802     unfolding A_def B_def C_def bisect_def split_def by simp
   803 
   804   have width: "\<And>n. B n - A n = (b - a) / 2^n"
   805     apply (simp add: eq_divide_eq)
   806     apply (induct_tac n, simp)
   807     apply (simp add: C_def avg_def power_Suc algebra_simps)
   808     done
   809 
   810   have twos: "\<And>y r :: rat. 0 < r \<Longrightarrow> \<exists>n. y / 2 ^ n < r"
   811     apply (simp add: divide_less_eq)
   812     apply (subst mult.commute)
   813     apply (frule_tac y=y in ex_less_of_nat_mult)
   814     apply clarify
   815     apply (rule_tac x=n in exI)
   816     apply (erule less_trans)
   817     apply (rule mult_strict_right_mono)
   818     apply (rule le_less_trans [OF _ of_nat_less_two_power])
   819     apply simp
   820     apply assumption
   821     done
   822 
   823   have PA: "\<And>n. \<not> P (A n)"
   824     by (induct_tac n, simp_all add: a)
   825   have PB: "\<And>n. P (B n)"
   826     by (induct_tac n, simp_all add: b)
   827   have ab: "a < b"
   828     using a b unfolding P_def
   829     apply (clarsimp simp add: not_le)
   830     apply (drule (1) bspec)
   831     apply (drule (1) less_le_trans)
   832     apply (simp add: of_rat_less)
   833     done
   834   have AB: "\<And>n. A n < B n"
   835     by (induct_tac n, simp add: ab, simp add: C_def avg_def)
   836   have A_mono: "\<And>i j. i \<le> j \<Longrightarrow> A i \<le> A j"
   837     apply (auto simp add: le_less [where 'a=nat])
   838     apply (erule less_Suc_induct)
   839     apply (clarsimp simp add: C_def avg_def)
   840     apply (simp add: add_divide_distrib [symmetric])
   841     apply (rule AB [THEN less_imp_le])
   842     apply simp
   843     done
   844   have B_mono: "\<And>i j. i \<le> j \<Longrightarrow> B j \<le> B i"
   845     apply (auto simp add: le_less [where 'a=nat])
   846     apply (erule less_Suc_induct)
   847     apply (clarsimp simp add: C_def avg_def)
   848     apply (simp add: add_divide_distrib [symmetric])
   849     apply (rule AB [THEN less_imp_le])
   850     apply simp
   851     done
   852   have cauchy_lemma:
   853     "\<And>X. \<forall>n. \<forall>i\<ge>n. A n \<le> X i \<and> X i \<le> B n \<Longrightarrow> cauchy X"
   854     apply (rule cauchyI)
   855     apply (drule twos [where y="b - a"])
   856     apply (erule exE)
   857     apply (rule_tac x=n in exI, clarify, rename_tac i j)
   858     apply (rule_tac y="B n - A n" in le_less_trans) defer
   859     apply (simp add: width)
   860     apply (drule_tac x=n in spec)
   861     apply (frule_tac x=i in spec, drule (1) mp)
   862     apply (frule_tac x=j in spec, drule (1) mp)
   863     apply (frule A_mono, drule B_mono)
   864     apply (frule A_mono, drule B_mono)
   865     apply arith
   866     done
   867   have "cauchy A"
   868     apply (rule cauchy_lemma [rule_format])
   869     apply (simp add: A_mono)
   870     apply (erule order_trans [OF less_imp_le [OF AB] B_mono])
   871     done
   872   have "cauchy B"
   873     apply (rule cauchy_lemma [rule_format])
   874     apply (simp add: B_mono)
   875     apply (erule order_trans [OF A_mono less_imp_le [OF AB]])
   876     done
   877   have 1: "\<forall>x\<in>S. x \<le> Real B"
   878   proof
   879     fix x assume "x \<in> S"
   880     then show "x \<le> Real B"
   881       using PB [unfolded P_def] `cauchy B`
   882       by (simp add: le_RealI)
   883   qed
   884   have 2: "\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> Real A \<le> z"
   885     apply clarify
   886     apply (erule contrapos_pp)
   887     apply (simp add: not_le)
   888     apply (drule less_RealD [OF `cauchy A`], clarify)
   889     apply (subgoal_tac "\<not> P (A n)")
   890     apply (simp add: P_def not_le, clarify)
   891     apply (erule rev_bexI)
   892     apply (erule (1) less_trans)
   893     apply (simp add: PA)
   894     done
   895   have "vanishes (\<lambda>n. (b - a) / 2 ^ n)"
   896   proof (rule vanishesI)
   897     fix r :: rat assume "0 < r"
   898     then obtain k where k: "\<bar>b - a\<bar> / 2 ^ k < r"
   899       using twos by fast
   900     have "\<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r"
   901     proof (clarify)
   902       fix n assume n: "k \<le> n"
   903       have "\<bar>(b - a) / 2 ^ n\<bar> = \<bar>b - a\<bar> / 2 ^ n"
   904         by simp
   905       also have "\<dots> \<le> \<bar>b - a\<bar> / 2 ^ k"
   906         using n by (simp add: divide_left_mono)
   907       also note k
   908       finally show "\<bar>(b - a) / 2 ^ n\<bar> < r" .
   909     qed
   910     thus "\<exists>k. \<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r" ..
   911   qed
   912   hence 3: "Real B = Real A"
   913     by (simp add: eq_Real `cauchy A` `cauchy B` width)
   914   show "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
   915     using 1 2 3 by (rule_tac x="Real B" in exI, simp)
   916 qed
   917 
   918 instantiation real :: linear_continuum
   919 begin
   920 
   921 subsection{*Supremum of a set of reals*}
   922 
   923 definition "Sup X = (LEAST z::real. \<forall>x\<in>X. x \<le> z)"
   924 definition "Inf (X::real set) = - Sup (uminus ` X)"
   925 
   926 instance
   927 proof
   928   { fix x :: real and X :: "real set"
   929     assume x: "x \<in> X" "bdd_above X"
   930     then obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
   931       using complete_real[of X] unfolding bdd_above_def by blast
   932     then show "x \<le> Sup X"
   933       unfolding Sup_real_def by (rule LeastI2_order) (auto simp: x) }
   934   note Sup_upper = this
   935 
   936   { fix z :: real and X :: "real set"
   937     assume x: "X \<noteq> {}" and z: "\<And>x. x \<in> X \<Longrightarrow> x \<le> z"
   938     then obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
   939       using complete_real[of X] by blast
   940     then have "Sup X = s"
   941       unfolding Sup_real_def by (best intro: Least_equality)  
   942     also from s z have "... \<le> z"
   943       by blast
   944     finally show "Sup X \<le> z" . }
   945   note Sup_least = this
   946 
   947   { fix x :: real and X :: "real set" assume x: "x \<in> X" "bdd_below X" then show "Inf X \<le> x"
   948       using Sup_upper[of "-x" "uminus ` X"] by (auto simp: Inf_real_def) }
   949   { fix z :: real and X :: "real set" assume "X \<noteq> {}" "\<And>x. x \<in> X \<Longrightarrow> z \<le> x" then show "z \<le> Inf X"
   950       using Sup_least[of "uminus ` X" "- z"] by (force simp: Inf_real_def) }
   951   show "\<exists>a b::real. a \<noteq> b"
   952     using zero_neq_one by blast
   953 qed
   954 end
   955 
   956 
   957 subsection {* Hiding implementation details *}
   958 
   959 hide_const (open) vanishes cauchy positive Real
   960 
   961 declare Real_induct [induct del]
   962 declare Abs_real_induct [induct del]
   963 declare Abs_real_cases [cases del]
   964 
   965 lifting_update real.lifting
   966 lifting_forget real.lifting
   967   
   968 subsection{*More Lemmas*}
   969 
   970 text {* BH: These lemmas should not be necessary; they should be
   971 covered by existing simp rules and simplification procedures. *}
   972 
   973 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   974 by simp (* solved by linordered_ring_less_cancel_factor simproc *)
   975 
   976 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   977 by simp (* solved by linordered_ring_le_cancel_factor simproc *)
   978 
   979 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   980 by simp (* solved by linordered_ring_le_cancel_factor simproc *)
   981 
   982 
   983 subsection {* Embedding numbers into the Reals *}
   984 
   985 abbreviation
   986   real_of_nat :: "nat \<Rightarrow> real"
   987 where
   988   "real_of_nat \<equiv> of_nat"
   989 
   990 abbreviation
   991   real_of_int :: "int \<Rightarrow> real"
   992 where
   993   "real_of_int \<equiv> of_int"
   994 
   995 abbreviation
   996   real_of_rat :: "rat \<Rightarrow> real"
   997 where
   998   "real_of_rat \<equiv> of_rat"
   999 
  1000 class real_of =
  1001   fixes real :: "'a \<Rightarrow> real"
  1002 
  1003 instantiation nat :: real_of
  1004 begin
  1005 
  1006 definition real_nat :: "nat \<Rightarrow> real" where real_of_nat_def [code_unfold]: "real \<equiv> of_nat" 
  1007 
  1008 instance ..
  1009 end
  1010 
  1011 instantiation int :: real_of
  1012 begin
  1013 
  1014 definition real_int :: "int \<Rightarrow> real" where real_of_int_def [code_unfold]: "real \<equiv> of_int" 
  1015 
  1016 instance ..
  1017 end
  1018 
  1019 declare [[coercion_enabled]]
  1020 
  1021 declare [[coercion "of_nat :: nat \<Rightarrow> int"]]
  1022 declare [[coercion "real   :: nat \<Rightarrow> real"]]
  1023 declare [[coercion "real   :: int \<Rightarrow> real"]]
  1024 
  1025 (* We do not add rat to the coerced types, this has often unpleasant side effects when writing
  1026 inverse (Suc n) which sometimes gets two coercions: of_rat (inverse (of_nat (Suc n))) *)
  1027 
  1028 declare [[coercion_map map]]
  1029 declare [[coercion_map "\<lambda>f g h x. g (h (f x))"]]
  1030 declare [[coercion_map "\<lambda>f g (x,y). (f x, g y)"]]
  1031 
  1032 lemma real_eq_of_nat: "real = of_nat"
  1033   unfolding real_of_nat_def ..
  1034 
  1035 lemma real_eq_of_int: "real = of_int"
  1036   unfolding real_of_int_def ..
  1037 
  1038 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
  1039 by (simp add: real_of_int_def) 
  1040 
  1041 lemma real_of_one [simp]: "real (1::int) = (1::real)"
  1042 by (simp add: real_of_int_def) 
  1043 
  1044 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
  1045 by (simp add: real_of_int_def) 
  1046 
  1047 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
  1048 by (simp add: real_of_int_def) 
  1049 
  1050 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
  1051 by (simp add: real_of_int_def) 
  1052 
  1053 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
  1054 by (simp add: real_of_int_def) 
  1055 
  1056 lemma real_of_int_power [simp]: "real (x ^ n) = real (x::int) ^ n"
  1057 by (simp add: real_of_int_def of_int_power)
  1058 
  1059 lemmas power_real_of_int = real_of_int_power [symmetric]
  1060 
  1061 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
  1062   apply (subst real_eq_of_int)+
  1063   apply (rule of_int_setsum)
  1064 done
  1065 
  1066 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
  1067     (PROD x:A. real(f x))"
  1068   apply (subst real_eq_of_int)+
  1069   apply (rule of_int_setprod)
  1070 done
  1071 
  1072 lemma real_of_int_zero_cancel [simp, algebra, presburger]: "(real x = 0) = (x = (0::int))"
  1073 by (simp add: real_of_int_def) 
  1074 
  1075 lemma real_of_int_inject [iff, algebra, presburger]: "(real (x::int) = real y) = (x = y)"
  1076 by (simp add: real_of_int_def) 
  1077 
  1078 lemma real_of_int_less_iff [iff, presburger]: "(real (x::int) < real y) = (x < y)"
  1079 by (simp add: real_of_int_def) 
  1080 
  1081 lemma real_of_int_le_iff [simp, presburger]: "(real (x::int) \<le> real y) = (x \<le> y)"
  1082 by (simp add: real_of_int_def) 
  1083 
  1084 lemma real_of_int_gt_zero_cancel_iff [simp, presburger]: "(0 < real (n::int)) = (0 < n)"
  1085 by (simp add: real_of_int_def) 
  1086 
  1087 lemma real_of_int_ge_zero_cancel_iff [simp, presburger]: "(0 <= real (n::int)) = (0 <= n)"
  1088 by (simp add: real_of_int_def) 
  1089 
  1090 lemma real_of_int_lt_zero_cancel_iff [simp, presburger]: "(real (n::int) < 0) = (n < 0)" 
  1091 by (simp add: real_of_int_def)
  1092 
  1093 lemma real_of_int_le_zero_cancel_iff [simp, presburger]: "(real (n::int) <= 0) = (n <= 0)"
  1094 by (simp add: real_of_int_def)
  1095 
  1096 lemma one_less_real_of_int_cancel_iff: "1 < real (i :: int) \<longleftrightarrow> 1 < i"
  1097   unfolding real_of_one[symmetric] real_of_int_less_iff ..
  1098 
  1099 lemma one_le_real_of_int_cancel_iff: "1 \<le> real (i :: int) \<longleftrightarrow> 1 \<le> i"
  1100   unfolding real_of_one[symmetric] real_of_int_le_iff ..
  1101 
  1102 lemma real_of_int_less_one_cancel_iff: "real (i :: int) < 1 \<longleftrightarrow> i < 1"
  1103   unfolding real_of_one[symmetric] real_of_int_less_iff ..
  1104 
  1105 lemma real_of_int_le_one_cancel_iff: "real (i :: int) \<le> 1 \<longleftrightarrow> i \<le> 1"
  1106   unfolding real_of_one[symmetric] real_of_int_le_iff ..
  1107 
  1108 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
  1109 by (auto simp add: abs_if)
  1110 
  1111 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
  1112   apply (subgoal_tac "real n + 1 = real (n + 1)")
  1113   apply (simp del: real_of_int_add)
  1114   apply auto
  1115 done
  1116 
  1117 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
  1118   apply (subgoal_tac "real m + 1 = real (m + 1)")
  1119   apply (simp del: real_of_int_add)
  1120   apply simp
  1121 done
  1122 
  1123 lemma real_of_int_div_aux: "(real (x::int)) / (real d) = 
  1124     real (x div d) + (real (x mod d)) / (real d)"
  1125 proof -
  1126   have "x = (x div d) * d + x mod d"
  1127     by auto
  1128   then have "real x = real (x div d) * real d + real(x mod d)"
  1129     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
  1130   then have "real x / real d = ... / real d"
  1131     by simp
  1132   then show ?thesis
  1133     by (auto simp add: add_divide_distrib algebra_simps)
  1134 qed
  1135 
  1136 lemma real_of_int_div:
  1137   fixes d n :: int
  1138   shows "d dvd n \<Longrightarrow> real (n div d) = real n / real d"
  1139   by (simp add: real_of_int_div_aux)
  1140 
  1141 lemma real_of_int_div2:
  1142   "0 <= real (n::int) / real (x) - real (n div x)"
  1143   apply (case_tac "x = 0")
  1144   apply simp
  1145   apply (case_tac "0 < x")
  1146   apply (simp add: algebra_simps)
  1147   apply (subst real_of_int_div_aux)
  1148   apply simp
  1149   apply (simp add: algebra_simps)
  1150   apply (subst real_of_int_div_aux)
  1151   apply simp
  1152   apply (subst zero_le_divide_iff)
  1153   apply auto
  1154 done
  1155 
  1156 lemma real_of_int_div3:
  1157   "real (n::int) / real (x) - real (n div x) <= 1"
  1158   apply (simp add: algebra_simps)
  1159   apply (subst real_of_int_div_aux)
  1160   apply (auto simp add: divide_le_eq intro: order_less_imp_le)
  1161 done
  1162 
  1163 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
  1164 by (insert real_of_int_div2 [of n x], simp)
  1165 
  1166 lemma Ints_real_of_int [simp]: "real (x::int) \<in> Ints"
  1167 unfolding real_of_int_def by (rule Ints_of_int)
  1168 
  1169 
  1170 subsection{*Embedding the Naturals into the Reals*}
  1171 
  1172 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
  1173 by (simp add: real_of_nat_def)
  1174 
  1175 lemma real_of_nat_1 [simp]: "real (1::nat) = 1"
  1176 by (simp add: real_of_nat_def)
  1177 
  1178 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
  1179 by (simp add: real_of_nat_def)
  1180 
  1181 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
  1182 by (simp add: real_of_nat_def)
  1183 
  1184 (*Not for addsimps: often the LHS is used to represent a positive natural*)
  1185 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
  1186 by (simp add: real_of_nat_def)
  1187 
  1188 lemma real_of_nat_less_iff [iff]: 
  1189      "(real (n::nat) < real m) = (n < m)"
  1190 by (simp add: real_of_nat_def)
  1191 
  1192 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
  1193 by (simp add: real_of_nat_def)
  1194 
  1195 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
  1196 by (simp add: real_of_nat_def)
  1197 
  1198 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
  1199 by (simp add: real_of_nat_def del: of_nat_Suc)
  1200 
  1201 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
  1202 by (simp add: real_of_nat_def of_nat_mult)
  1203 
  1204 lemma real_of_nat_power [simp]: "real (m ^ n) = real (m::nat) ^ n"
  1205 by (simp add: real_of_nat_def of_nat_power)
  1206 
  1207 lemmas power_real_of_nat = real_of_nat_power [symmetric]
  1208 
  1209 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
  1210     (SUM x:A. real(f x))"
  1211   apply (subst real_eq_of_nat)+
  1212   apply (rule of_nat_setsum)
  1213 done
  1214 
  1215 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
  1216     (PROD x:A. real(f x))"
  1217   apply (subst real_eq_of_nat)+
  1218   apply (rule of_nat_setprod)
  1219 done
  1220 
  1221 lemma real_of_card: "real (card A) = setsum (%x.1) A"
  1222   apply (subst card_eq_setsum)
  1223   apply (subst real_of_nat_setsum)
  1224   apply simp
  1225 done
  1226 
  1227 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
  1228 by (simp add: real_of_nat_def)
  1229 
  1230 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
  1231 by (simp add: real_of_nat_def)
  1232 
  1233 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
  1234 by (simp add: add: real_of_nat_def of_nat_diff)
  1235 
  1236 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
  1237 by (auto simp: real_of_nat_def)
  1238 
  1239 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
  1240 by (simp add: add: real_of_nat_def)
  1241 
  1242 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
  1243 by (simp add: add: real_of_nat_def)
  1244 
  1245 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
  1246   apply (subgoal_tac "real n + 1 = real (Suc n)")
  1247   apply simp
  1248   apply (auto simp add: real_of_nat_Suc)
  1249 done
  1250 
  1251 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
  1252   apply (subgoal_tac "real m + 1 = real (Suc m)")
  1253   apply (simp add: less_Suc_eq_le)
  1254   apply (simp add: real_of_nat_Suc)
  1255 done
  1256 
  1257 lemma real_of_nat_div_aux: "(real (x::nat)) / (real d) = 
  1258     real (x div d) + (real (x mod d)) / (real d)"
  1259 proof -
  1260   have "x = (x div d) * d + x mod d"
  1261     by auto
  1262   then have "real x = real (x div d) * real d + real(x mod d)"
  1263     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
  1264   then have "real x / real d = \<dots> / real d"
  1265     by simp
  1266   then show ?thesis
  1267     by (auto simp add: add_divide_distrib algebra_simps)
  1268 qed
  1269 
  1270 lemma real_of_nat_div: "(d :: nat) dvd n ==>
  1271     real(n div d) = real n / real d"
  1272   by (subst real_of_nat_div_aux)
  1273     (auto simp add: dvd_eq_mod_eq_0 [symmetric])
  1274 
  1275 lemma real_of_nat_div2:
  1276   "0 <= real (n::nat) / real (x) - real (n div x)"
  1277 apply (simp add: algebra_simps)
  1278 apply (subst real_of_nat_div_aux)
  1279 apply simp
  1280 done
  1281 
  1282 lemma real_of_nat_div3:
  1283   "real (n::nat) / real (x) - real (n div x) <= 1"
  1284 apply(case_tac "x = 0")
  1285 apply (simp)
  1286 apply (simp add: algebra_simps)
  1287 apply (subst real_of_nat_div_aux)
  1288 apply simp
  1289 done
  1290 
  1291 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
  1292 by (insert real_of_nat_div2 [of n x], simp)
  1293 
  1294 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
  1295 by (simp add: real_of_int_def real_of_nat_def)
  1296 
  1297 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
  1298   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
  1299   apply force
  1300   apply (simp only: real_of_int_of_nat_eq)
  1301 done
  1302 
  1303 lemma Nats_real_of_nat [simp]: "real (n::nat) \<in> Nats"
  1304 unfolding real_of_nat_def by (rule of_nat_in_Nats)
  1305 
  1306 lemma Ints_real_of_nat [simp]: "real (n::nat) \<in> Ints"
  1307 unfolding real_of_nat_def by (rule Ints_of_nat)
  1308 
  1309 subsection {* The Archimedean Property of the Reals *}
  1310 
  1311 theorem reals_Archimedean:
  1312   assumes x_pos: "0 < x"
  1313   shows "\<exists>n. inverse (real (Suc n)) < x"
  1314   unfolding real_of_nat_def using x_pos
  1315   by (rule ex_inverse_of_nat_Suc_less)
  1316 
  1317 lemma reals_Archimedean2: "\<exists>n. (x::real) < real (n::nat)"
  1318   unfolding real_of_nat_def by (rule ex_less_of_nat)
  1319 
  1320 lemma reals_Archimedean3:
  1321   assumes x_greater_zero: "0 < x"
  1322   shows "\<forall>(y::real). \<exists>(n::nat). y < real n * x"
  1323   unfolding real_of_nat_def using `0 < x`
  1324   by (auto intro: ex_less_of_nat_mult)
  1325 
  1326 
  1327 subsection{* Rationals *}
  1328 
  1329 lemma Rats_real_nat[simp]: "real(n::nat) \<in> \<rat>"
  1330 by (simp add: real_eq_of_nat)
  1331 
  1332 lemma Rats_eq_int_div_int:
  1333   "\<rat> = { real(i::int)/real(j::int) |i j. j \<noteq> 0}" (is "_ = ?S")
  1334 proof
  1335   show "\<rat> \<subseteq> ?S"
  1336   proof
  1337     fix x::real assume "x : \<rat>"
  1338     then obtain r where "x = of_rat r" unfolding Rats_def ..
  1339     have "of_rat r : ?S"
  1340       by (cases r)(auto simp add:of_rat_rat real_eq_of_int)
  1341     thus "x : ?S" using `x = of_rat r` by simp
  1342   qed
  1343 next
  1344   show "?S \<subseteq> \<rat>"
  1345   proof(auto simp:Rats_def)
  1346     fix i j :: int assume "j \<noteq> 0"
  1347     hence "real i / real j = of_rat(Fract i j)"
  1348       by (simp add:of_rat_rat real_eq_of_int)
  1349     thus "real i / real j \<in> range of_rat" by blast
  1350   qed
  1351 qed
  1352 
  1353 lemma Rats_eq_int_div_nat:
  1354   "\<rat> = { real(i::int)/real(n::nat) |i n. n \<noteq> 0}"
  1355 proof(auto simp:Rats_eq_int_div_int)
  1356   fix i j::int assume "j \<noteq> 0"
  1357   show "EX (i'::int) (n::nat). real i/real j = real i'/real n \<and> 0<n"
  1358   proof cases
  1359     assume "j>0"
  1360     hence "real i/real j = real i/real(nat j) \<and> 0<nat j"
  1361       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
  1362     thus ?thesis by blast
  1363   next
  1364     assume "~ j>0"
  1365     hence "real i/real j = real(-i)/real(nat(-j)) \<and> 0<nat(-j)" using `j\<noteq>0`
  1366       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
  1367     thus ?thesis by blast
  1368   qed
  1369 next
  1370   fix i::int and n::nat assume "0 < n"
  1371   hence "real i/real n = real i/real(int n) \<and> int n \<noteq> 0" by simp
  1372   thus "\<exists>(i'::int) j::int. real i/real n = real i'/real j \<and> j \<noteq> 0" by blast
  1373 qed
  1374 
  1375 lemma Rats_abs_nat_div_natE:
  1376   assumes "x \<in> \<rat>"
  1377   obtains m n :: nat
  1378   where "n \<noteq> 0" and "\<bar>x\<bar> = real m / real n" and "gcd m n = 1"
  1379 proof -
  1380   from `x \<in> \<rat>` obtain i::int and n::nat where "n \<noteq> 0" and "x = real i / real n"
  1381     by(auto simp add: Rats_eq_int_div_nat)
  1382   hence "\<bar>x\<bar> = real(nat(abs i)) / real n" by simp
  1383   then obtain m :: nat where x_rat: "\<bar>x\<bar> = real m / real n" by blast
  1384   let ?gcd = "gcd m n"
  1385   from `n\<noteq>0` have gcd: "?gcd \<noteq> 0" by simp
  1386   let ?k = "m div ?gcd"
  1387   let ?l = "n div ?gcd"
  1388   let ?gcd' = "gcd ?k ?l"
  1389   have "?gcd dvd m" .. then have gcd_k: "?gcd * ?k = m"
  1390     by (rule dvd_mult_div_cancel)
  1391   have "?gcd dvd n" .. then have gcd_l: "?gcd * ?l = n"
  1392     by (rule dvd_mult_div_cancel)
  1393   from `n \<noteq> 0` and gcd_l
  1394   have "?gcd * ?l \<noteq> 0" by simp
  1395   then have "?l \<noteq> 0" by (blast dest!: mult_not_zero) 
  1396   moreover
  1397   have "\<bar>x\<bar> = real ?k / real ?l"
  1398   proof -
  1399     from gcd have "real ?k / real ?l =
  1400       real (?gcd * ?k) / real (?gcd * ?l)"
  1401       by (simp only: real_of_nat_mult) simp
  1402     also from gcd_k and gcd_l have "\<dots> = real m / real n" by simp
  1403     also from x_rat have "\<dots> = \<bar>x\<bar>" ..
  1404     finally show ?thesis ..
  1405   qed
  1406   moreover
  1407   have "?gcd' = 1"
  1408   proof -
  1409     have "?gcd * ?gcd' = gcd (?gcd * ?k) (?gcd * ?l)"
  1410       by (rule gcd_mult_distrib_nat)
  1411     with gcd_k gcd_l have "?gcd * ?gcd' = ?gcd" by simp
  1412     with gcd show ?thesis by auto
  1413   qed
  1414   ultimately show ?thesis ..
  1415 qed
  1416 
  1417 subsection{*Density of the Rational Reals in the Reals*}
  1418 
  1419 text{* This density proof is due to Stefan Richter and was ported by TN.  The
  1420 original source is \emph{Real Analysis} by H.L. Royden.
  1421 It employs the Archimedean property of the reals. *}
  1422 
  1423 lemma Rats_dense_in_real:
  1424   fixes x :: real
  1425   assumes "x < y" shows "\<exists>r\<in>\<rat>. x < r \<and> r < y"
  1426 proof -
  1427   from `x<y` have "0 < y-x" by simp
  1428   with reals_Archimedean obtain q::nat 
  1429     where q: "inverse (real q) < y-x" and "0 < q" by auto
  1430   def p \<equiv> "ceiling (y * real q) - 1"
  1431   def r \<equiv> "of_int p / real q"
  1432   from q have "x < y - inverse (real q)" by simp
  1433   also have "y - inverse (real q) \<le> r"
  1434     unfolding r_def p_def
  1435     by (simp add: le_divide_eq left_diff_distrib le_of_int_ceiling `0 < q`)
  1436   finally have "x < r" .
  1437   moreover have "r < y"
  1438     unfolding r_def p_def
  1439     by (simp add: divide_less_eq diff_less_eq `0 < q`
  1440       less_ceiling_iff [symmetric])
  1441   moreover from r_def have "r \<in> \<rat>" by simp
  1442   ultimately show ?thesis by fast
  1443 qed
  1444 
  1445 lemma of_rat_dense:
  1446   fixes x y :: real
  1447   assumes "x < y"
  1448   shows "\<exists>q :: rat. x < of_rat q \<and> of_rat q < y"
  1449 using Rats_dense_in_real [OF `x < y`]
  1450 by (auto elim: Rats_cases)
  1451 
  1452 
  1453 subsection{*Numerals and Arithmetic*}
  1454 
  1455 lemma [code_abbrev]:
  1456   "real_of_int (numeral k) = numeral k"
  1457   "real_of_int (- numeral k) = - numeral k"
  1458   by simp_all
  1459 
  1460 text{*Collapse applications of @{const real} to @{const numeral}*}
  1461 lemma real_numeral [simp]:
  1462   "real (numeral v :: int) = numeral v"
  1463   "real (- numeral v :: int) = - numeral v"
  1464 by (simp_all add: real_of_int_def)
  1465 
  1466 lemma  real_of_nat_numeral [simp]:
  1467   "real (numeral v :: nat) = numeral v"
  1468 by (simp add: real_of_nat_def)
  1469 
  1470 declaration {*
  1471   K (Lin_Arith.add_inj_thms [@{thm real_of_nat_le_iff} RS iffD2, @{thm real_of_nat_inject} RS iffD2]
  1472     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: real_of_nat_less_iff RS iffD2 *)
  1473   #> Lin_Arith.add_inj_thms [@{thm real_of_int_le_iff} RS iffD2, @{thm real_of_int_inject} RS iffD2]
  1474     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: real_of_int_less_iff RS iffD2 *)
  1475   #> Lin_Arith.add_simps [@{thm real_of_nat_zero}, @{thm real_of_nat_Suc}, @{thm real_of_nat_add},
  1476       @{thm real_of_nat_mult}, @{thm real_of_int_zero}, @{thm real_of_one},
  1477       @{thm real_of_int_add}, @{thm real_of_int_minus}, @{thm real_of_int_diff},
  1478       @{thm real_of_int_mult}, @{thm real_of_int_of_nat_eq},
  1479       @{thm real_of_nat_numeral}, @{thm real_numeral(1)}, @{thm real_numeral(2)},
  1480       @{thm real_of_int_def[symmetric]}, @{thm real_of_nat_def[symmetric]}]
  1481   #> Lin_Arith.add_inj_const (@{const_name real}, @{typ "nat \<Rightarrow> real"})
  1482   #> Lin_Arith.add_inj_const (@{const_name real}, @{typ "int \<Rightarrow> real"})
  1483   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat \<Rightarrow> real"})
  1484   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int \<Rightarrow> real"}))
  1485 *}
  1486 
  1487 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
  1488 
  1489 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
  1490 by arith
  1491 
  1492 text {* FIXME: redundant with @{text add_eq_0_iff} below *}
  1493 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
  1494 by auto
  1495 
  1496 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
  1497 by auto
  1498 
  1499 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
  1500 by auto
  1501 
  1502 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
  1503 by auto
  1504 
  1505 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
  1506 by auto
  1507 
  1508 subsection {* Lemmas about powers *}
  1509 
  1510 text {* FIXME: declare this in Rings.thy or not at all *}
  1511 declare abs_mult_self [simp]
  1512 
  1513 (* used by Import/HOL/real.imp *)
  1514 lemma two_realpow_ge_one: "(1::real) \<le> 2 ^ n"
  1515 by simp
  1516 
  1517 lemma two_realpow_gt [simp]: "real (n::nat) < 2 ^ n"
  1518   by (simp add: of_nat_less_two_power real_of_nat_def)
  1519 
  1520 text {* TODO: no longer real-specific; rename and move elsewhere *}
  1521 lemma realpow_Suc_le_self:
  1522   fixes r :: "'a::linordered_semidom"
  1523   shows "[| 0 \<le> r; r \<le> 1 |] ==> r ^ Suc n \<le> r"
  1524 by (insert power_decreasing [of 1 "Suc n" r], simp)
  1525 
  1526 text {* TODO: no longer real-specific; rename and move elsewhere *}
  1527 lemma realpow_minus_mult:
  1528   fixes x :: "'a::monoid_mult"
  1529   shows "0 < n \<Longrightarrow> x ^ (n - 1) * x = x ^ n"
  1530 by (simp add: power_Suc power_commutes split add: nat_diff_split)
  1531 
  1532 text {* FIXME: declare this [simp] for all types, or not at all *}
  1533 lemma real_two_squares_add_zero_iff [simp]:
  1534   "(x * x + y * y = 0) = ((x::real) = 0 \<and> y = 0)"
  1535 by (rule sum_squares_eq_zero_iff)
  1536 
  1537 text {* FIXME: declare this [simp] for all types, or not at all *}
  1538 lemma realpow_two_sum_zero_iff [simp]:
  1539      "(x\<^sup>2 + y\<^sup>2 = (0::real)) = (x = 0 & y = 0)"
  1540 by (rule sum_power2_eq_zero_iff)
  1541 
  1542 lemma real_minus_mult_self_le [simp]: "-(u * u) \<le> (x * (x::real))"
  1543 by (rule_tac y = 0 in order_trans, auto)
  1544 
  1545 lemma realpow_square_minus_le [simp]: "- u\<^sup>2 \<le> (x::real)\<^sup>2"
  1546 by (auto simp add: power2_eq_square)
  1547 
  1548 
  1549 lemma numeral_power_eq_real_of_int_cancel_iff[simp]:
  1550   "numeral x ^ n = real (y::int) \<longleftrightarrow> numeral x ^ n = y"
  1551   by (metis real_numeral(1) real_of_int_inject real_of_int_power)
  1552 
  1553 lemma real_of_int_eq_numeral_power_cancel_iff[simp]:
  1554   "real (y::int) = numeral x ^ n \<longleftrightarrow> y = numeral x ^ n"
  1555   using numeral_power_eq_real_of_int_cancel_iff[of x n y]
  1556   by metis
  1557 
  1558 lemma numeral_power_eq_real_of_nat_cancel_iff[simp]:
  1559   "numeral x ^ n = real (y::nat) \<longleftrightarrow> numeral x ^ n = y"
  1560   by (metis of_nat_eq_iff of_nat_numeral real_of_int_eq_numeral_power_cancel_iff
  1561     real_of_int_of_nat_eq zpower_int)
  1562 
  1563 lemma real_of_nat_eq_numeral_power_cancel_iff[simp]:
  1564   "real (y::nat) = numeral x ^ n \<longleftrightarrow> y = numeral x ^ n"
  1565   using numeral_power_eq_real_of_nat_cancel_iff[of x n y]
  1566   by metis
  1567 
  1568 lemma numeral_power_le_real_of_nat_cancel_iff[simp]:
  1569   "(numeral x::real) ^ n \<le> real a \<longleftrightarrow> (numeral x::nat) ^ n \<le> a"
  1570   unfolding real_of_nat_le_iff[symmetric] by simp
  1571 
  1572 lemma real_of_nat_le_numeral_power_cancel_iff[simp]:
  1573   "real a \<le> (numeral x::real) ^ n \<longleftrightarrow> a \<le> (numeral x::nat) ^ n"
  1574   unfolding real_of_nat_le_iff[symmetric] by simp
  1575 
  1576 lemma numeral_power_le_real_of_int_cancel_iff[simp]:
  1577   "(numeral x::real) ^ n \<le> real a \<longleftrightarrow> (numeral x::int) ^ n \<le> a"
  1578   unfolding real_of_int_le_iff[symmetric] by simp
  1579 
  1580 lemma real_of_int_le_numeral_power_cancel_iff[simp]:
  1581   "real a \<le> (numeral x::real) ^ n \<longleftrightarrow> a \<le> (numeral x::int) ^ n"
  1582   unfolding real_of_int_le_iff[symmetric] by simp
  1583 
  1584 lemma numeral_power_less_real_of_nat_cancel_iff[simp]:
  1585   "(numeral x::real) ^ n < real a \<longleftrightarrow> (numeral x::nat) ^ n < a"
  1586   unfolding real_of_nat_less_iff[symmetric] by simp
  1587 
  1588 lemma real_of_nat_less_numeral_power_cancel_iff[simp]:
  1589   "real a < (numeral x::real) ^ n \<longleftrightarrow> a < (numeral x::nat) ^ n"
  1590   unfolding real_of_nat_less_iff[symmetric] by simp
  1591 
  1592 lemma numeral_power_less_real_of_int_cancel_iff[simp]:
  1593   "(numeral x::real) ^ n < real a \<longleftrightarrow> (numeral x::int) ^ n < a"
  1594   unfolding real_of_int_less_iff[symmetric] by simp
  1595 
  1596 lemma real_of_int_less_numeral_power_cancel_iff[simp]:
  1597   "real a < (numeral x::real) ^ n \<longleftrightarrow> a < (numeral x::int) ^ n"
  1598   unfolding real_of_int_less_iff[symmetric] by simp
  1599 
  1600 lemma neg_numeral_power_le_real_of_int_cancel_iff[simp]:
  1601   "(- numeral x::real) ^ n \<le> real a \<longleftrightarrow> (- numeral x::int) ^ n \<le> a"
  1602   unfolding real_of_int_le_iff[symmetric] by simp
  1603 
  1604 lemma real_of_int_le_neg_numeral_power_cancel_iff[simp]:
  1605   "real a \<le> (- numeral x::real) ^ n \<longleftrightarrow> a \<le> (- numeral x::int) ^ n"
  1606   unfolding real_of_int_le_iff[symmetric] by simp
  1607 
  1608 
  1609 subsection{*Density of the Reals*}
  1610 
  1611 lemma real_lbound_gt_zero:
  1612      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
  1613 apply (rule_tac x = " (min d1 d2) /2" in exI)
  1614 apply (simp add: min_def)
  1615 done
  1616 
  1617 
  1618 text{*Similar results are proved in @{text Fields}*}
  1619 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
  1620   by auto
  1621 
  1622 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
  1623   by auto
  1624 
  1625 lemma real_sum_of_halves: "x/2 + x/2 = (x::real)"
  1626   by simp
  1627 
  1628 subsection{*Absolute Value Function for the Reals*}
  1629 
  1630 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
  1631 by (simp add: abs_if)
  1632 
  1633 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
  1634 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
  1635 by (force simp add: abs_le_iff)
  1636 
  1637 lemma abs_add_one_gt_zero: "(0::real) < 1 + abs(x)"
  1638 by (simp add: abs_if)
  1639 
  1640 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
  1641 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
  1642 
  1643 lemma abs_add_one_not_less_self: "~ abs(x) + (1::real) < x"
  1644 by simp
  1645  
  1646 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
  1647 by simp
  1648 
  1649 
  1650 subsection{*Floor and Ceiling Functions from the Reals to the Integers*}
  1651 
  1652 (* FIXME: theorems for negative numerals *)
  1653 lemma numeral_less_real_of_int_iff [simp]:
  1654      "((numeral n) < real (m::int)) = (numeral n < m)"
  1655 apply auto
  1656 apply (rule real_of_int_less_iff [THEN iffD1])
  1657 apply (drule_tac [2] real_of_int_less_iff [THEN iffD2], auto)
  1658 done
  1659 
  1660 lemma numeral_less_real_of_int_iff2 [simp]:
  1661      "(real (m::int) < (numeral n)) = (m < numeral n)"
  1662 apply auto
  1663 apply (rule real_of_int_less_iff [THEN iffD1])
  1664 apply (drule_tac [2] real_of_int_less_iff [THEN iffD2], auto)
  1665 done
  1666 
  1667 lemma real_of_nat_less_numeral_iff [simp]:
  1668   "real (n::nat) < numeral w \<longleftrightarrow> n < numeral w"
  1669   using real_of_nat_less_iff[of n "numeral w"] by simp
  1670 
  1671 lemma numeral_less_real_of_nat_iff [simp]:
  1672   "numeral w < real (n::nat) \<longleftrightarrow> numeral w < n"
  1673   using real_of_nat_less_iff[of "numeral w" n] by simp
  1674 
  1675 lemma numeral_le_real_of_nat_iff[simp]:
  1676   "(numeral n \<le> real(m::nat)) = (numeral n \<le> m)"
  1677 by (metis not_le real_of_nat_less_numeral_iff)
  1678 
  1679 lemma numeral_le_real_of_int_iff [simp]:
  1680      "((numeral n) \<le> real (m::int)) = (numeral n \<le> m)"
  1681 by (simp add: linorder_not_less [symmetric])
  1682 
  1683 lemma numeral_le_real_of_int_iff2 [simp]:
  1684      "(real (m::int) \<le> (numeral n)) = (m \<le> numeral n)"
  1685 by (simp add: linorder_not_less [symmetric])
  1686 
  1687 lemma floor_real_of_nat [simp]: "floor (real (n::nat)) = int n"
  1688 unfolding real_of_nat_def by simp
  1689 
  1690 lemma floor_minus_real_of_nat [simp]: "floor (- real (n::nat)) = - int n"
  1691 unfolding real_of_nat_def by (simp add: floor_minus)
  1692 
  1693 lemma floor_real_of_int [simp]: "floor (real (n::int)) = n"
  1694 unfolding real_of_int_def by simp
  1695 
  1696 lemma floor_minus_real_of_int [simp]: "floor (- real (n::int)) = - n"
  1697 unfolding real_of_int_def by (simp add: floor_minus)
  1698 
  1699 lemma real_lb_ub_int: " \<exists>n::int. real n \<le> r & r < real (n+1)"
  1700 unfolding real_of_int_def by (rule floor_exists)
  1701 
  1702 lemma lemma_floor: "real m \<le> r \<Longrightarrow> r < real n + 1 \<Longrightarrow> m \<le> (n::int)"
  1703   by simp
  1704 
  1705 lemma real_of_int_floor_le [simp]: "real (floor r) \<le> r"
  1706 unfolding real_of_int_def by (rule of_int_floor_le)
  1707 
  1708 lemma lemma_floor2: "real n < real (x::int) + 1 ==> n \<le> x"
  1709   by simp
  1710 
  1711 lemma real_of_int_floor_cancel [simp]:
  1712     "(real (floor x) = x) = (\<exists>n::int. x = real n)"
  1713   using floor_real_of_int by metis
  1714 
  1715 lemma floor_eq: "[| real n < x; x < real n + 1 |] ==> floor x = n"
  1716   by linarith
  1717 
  1718 lemma floor_eq2: "[| real n \<le> x; x < real n + 1 |] ==> floor x = n"
  1719   by linarith
  1720 
  1721 lemma floor_eq3: "[| real n < x; x < real (Suc n) |] ==> nat(floor x) = n"
  1722   by linarith
  1723 
  1724 lemma floor_eq4: "[| real n \<le> x; x < real (Suc n) |] ==> nat(floor x) = n"
  1725   by linarith
  1726 
  1727 lemma real_of_int_floor_ge_diff_one [simp]: "r - 1 \<le> real(floor r)"
  1728   by linarith
  1729 
  1730 lemma real_of_int_floor_gt_diff_one [simp]: "r - 1 < real(floor r)"
  1731   by linarith
  1732 
  1733 lemma real_of_int_floor_add_one_ge [simp]: "r \<le> real(floor r) + 1"
  1734   by linarith
  1735 
  1736 lemma real_of_int_floor_add_one_gt [simp]: "r < real(floor r) + 1"
  1737   by linarith
  1738 
  1739 lemma le_floor: "real a <= x ==> a <= floor x"
  1740   by linarith
  1741 
  1742 lemma real_le_floor: "a <= floor x ==> real a <= x"
  1743   by linarith
  1744 
  1745 lemma le_floor_eq: "(a <= floor x) = (real a <= x)"
  1746   by linarith
  1747 
  1748 lemma floor_less_eq: "(floor x < a) = (x < real a)"
  1749   by linarith
  1750 
  1751 lemma less_floor_eq: "(a < floor x) = (real a + 1 <= x)"
  1752   by linarith
  1753 
  1754 lemma floor_le_eq: "(floor x <= a) = (x < real a + 1)"
  1755   by linarith
  1756 
  1757 lemma floor_eq_iff: "floor x = b \<longleftrightarrow> real b \<le> x \<and> x < real (b + 1)"
  1758   by linarith
  1759 
  1760 lemma floor_add [simp]: "floor (x + real a) = floor x + a"
  1761   by linarith
  1762 
  1763 lemma floor_add2[simp]: "floor (real a + x) = a + floor x"
  1764   by linarith
  1765 
  1766 lemma floor_subtract [simp]: "floor (x - real a) = floor x - a"
  1767   by linarith
  1768 
  1769 lemma floor_divide_real_eq_div: "0 \<le> b \<Longrightarrow> floor (a / real b) = floor a div b"
  1770 proof cases
  1771   assume "0 < b"
  1772   { fix i j :: int assume "real i \<le> a" "a < 1 + real i"
  1773       "real j * real b \<le> a" "a < real b + real j * real b"
  1774     then have "i < b + j * b" "j * b < 1 + i"
  1775       unfolding real_of_int_less_iff[symmetric] by auto
  1776     then have "(j - i div b) * b \<le> i mod b" "i mod b < ((j - i div b) + 1) * b"
  1777       by (auto simp: field_simps)
  1778     then have "(j - i div b) * b < 1 * b" "0 * b < ((j - i div b) + 1) * b"
  1779       using pos_mod_bound[OF `0<b`, of i] pos_mod_sign[OF `0<b`, of i] by linarith+
  1780     then have "j = i div b"
  1781       using `0 < b` unfolding mult_less_cancel_right by auto }
  1782   with `0 < b` show ?thesis
  1783     by (auto split: floor_split simp: field_simps)
  1784 qed auto
  1785 
  1786 lemma floor_divide_eq_div:
  1787   "floor (real a / real b) = a div b"
  1788   using floor_divide_of_int_eq [of a b] real_eq_of_int by simp
  1789 
  1790 lemma floor_divide_eq_div_numeral[simp]: "\<lfloor>numeral a / numeral b::real\<rfloor> = numeral a div numeral b"
  1791   using floor_divide_eq_div[of "numeral a" "numeral b"] by simp
  1792 
  1793 lemma floor_minus_divide_eq_div_numeral[simp]: "\<lfloor>- (numeral a / numeral b)::real\<rfloor> = - numeral a div numeral b"
  1794   using floor_divide_eq_div[of "- numeral a" "numeral b"] by simp
  1795 
  1796 lemma ceiling_real_of_nat [simp]: "ceiling (real (n::nat)) = int n"
  1797   by linarith
  1798 
  1799 lemma real_of_int_ceiling_ge [simp]: "r \<le> real (ceiling r)"
  1800   by linarith
  1801 
  1802 lemma ceiling_real_of_int [simp]: "ceiling (real (n::int)) = n"
  1803   by linarith
  1804 
  1805 lemma real_of_int_ceiling_cancel [simp]:
  1806      "(real (ceiling x) = x) = (\<exists>n::int. x = real n)"
  1807   using ceiling_real_of_int by metis
  1808 
  1809 lemma ceiling_eq: "[| real n < x; x < real n + 1 |] ==> ceiling x = n + 1"
  1810   by linarith
  1811 
  1812 lemma ceiling_eq2: "[| real n < x; x \<le> real n + 1 |] ==> ceiling x = n + 1"
  1813   by linarith
  1814 
  1815 lemma ceiling_eq3: "[| real n - 1 < x; x \<le> real n  |] ==> ceiling x = n"
  1816   by linarith
  1817 
  1818 lemma real_of_int_ceiling_diff_one_le [simp]: "real (ceiling r) - 1 \<le> r"
  1819   by linarith
  1820 
  1821 lemma real_of_int_ceiling_le_add_one [simp]: "real (ceiling r) \<le> r + 1"
  1822   by linarith
  1823 
  1824 lemma ceiling_le: "x <= real a ==> ceiling x <= a"
  1825   by linarith
  1826 
  1827 lemma ceiling_le_real: "ceiling x <= a ==> x <= real a"
  1828   by linarith
  1829 
  1830 lemma ceiling_le_eq: "(ceiling x <= a) = (x <= real a)"
  1831   by linarith
  1832 
  1833 lemma less_ceiling_eq: "(a < ceiling x) = (real a < x)"
  1834   by linarith
  1835 
  1836 lemma ceiling_less_eq: "(ceiling x < a) = (x <= real a - 1)"
  1837   by linarith
  1838 
  1839 lemma le_ceiling_eq: "(a <= ceiling x) = (real a - 1 < x)"
  1840   by linarith
  1841 
  1842 lemma ceiling_add [simp]: "ceiling (x + real a) = ceiling x + a"
  1843   by linarith
  1844 
  1845 lemma ceiling_subtract [simp]: "ceiling (x - real a) = ceiling x - a"
  1846   by linarith
  1847 
  1848 lemma ceiling_divide_eq_div: "\<lceil>real a / real b\<rceil> = - (- a div b)"
  1849   unfolding ceiling_def minus_divide_left real_of_int_minus[symmetric] floor_divide_eq_div by simp_all
  1850 
  1851 lemma ceiling_divide_eq_div_numeral [simp]:
  1852   "\<lceil>numeral a / numeral b :: real\<rceil> = - (- numeral a div numeral b)"
  1853   using ceiling_divide_eq_div[of "numeral a" "numeral b"] by simp
  1854 
  1855 lemma ceiling_minus_divide_eq_div_numeral [simp]:
  1856   "\<lceil>- (numeral a / numeral b :: real)\<rceil> = - (numeral a div numeral b)"
  1857   using ceiling_divide_eq_div[of "- numeral a" "numeral b"] by simp
  1858 
  1859 text{* The following lemmas are remnants of the erstwhile functions natfloor
  1860 and natceiling. *}
  1861 
  1862 lemma nat_floor_neg: "(x::real) <= 0 ==> nat(floor x) = 0"
  1863   by linarith
  1864 
  1865 lemma le_nat_floor: "real x <= a ==> x <= nat(floor a)"
  1866   by linarith
  1867 
  1868 lemma le_mult_nat_floor:
  1869   shows "nat(floor a) * nat(floor b) \<le> nat(floor (a * b))"
  1870   by (cases "0 <= a & 0 <= b")
  1871      (auto simp add: nat_mult_distrib[symmetric] nat_mono le_mult_floor)
  1872 
  1873 lemma nat_ceiling_le_eq: "(nat(ceiling x) <= a) = (x <= real a)"
  1874   by linarith
  1875 
  1876 lemma real_nat_ceiling_ge: "x <= real(nat(ceiling x))"
  1877   by linarith
  1878 
  1879 
  1880 lemma Rats_no_top_le: "\<exists> q \<in> \<rat>. (x :: real) \<le> q"
  1881   by (auto intro!: bexI[of _ "of_nat (nat(ceiling x))"]) linarith
  1882 
  1883 lemma Rats_no_bot_less: "\<exists> q \<in> \<rat>. q < (x :: real)"
  1884   apply (auto intro!: bexI[of _ "of_int (floor x - 1)"])
  1885   apply (rule less_le_trans[OF _ of_int_floor_le])
  1886   apply simp
  1887   done
  1888 
  1889 subsection {* Exponentiation with floor *}
  1890 
  1891 lemma floor_power:
  1892   assumes "x = real (floor x)"
  1893   shows "floor (x ^ n) = floor x ^ n"
  1894 proof -
  1895   have *: "x ^ n = real (floor x ^ n)"
  1896     using assms by (induct n arbitrary: x) simp_all
  1897   show ?thesis unfolding real_of_int_inject[symmetric]
  1898     unfolding * floor_real_of_int ..
  1899 qed
  1900 (*
  1901 lemma natfloor_power:
  1902   assumes "x = real (natfloor x)"
  1903   shows "natfloor (x ^ n) = natfloor x ^ n"
  1904 proof -
  1905   from assms have "0 \<le> floor x" by auto
  1906   note assms[unfolded natfloor_def real_nat_eq_real[OF `0 \<le> floor x`]]
  1907   from floor_power[OF this]
  1908   show ?thesis unfolding natfloor_def nat_power_eq[OF `0 \<le> floor x`, symmetric]
  1909     by simp
  1910 qed
  1911 *)
  1912 lemma floor_numeral_power[simp]:
  1913   "\<lfloor>numeral x ^ n\<rfloor> = numeral x ^ n"
  1914   by (metis floor_of_int of_int_numeral of_int_power)
  1915 
  1916 lemma ceiling_numeral_power[simp]:
  1917   "\<lceil>numeral x ^ n\<rceil> = numeral x ^ n"
  1918   by (metis ceiling_of_int of_int_numeral of_int_power)
  1919 
  1920 
  1921 subsection {* Implementation of rational real numbers *}
  1922 
  1923 text {* Formal constructor *}
  1924 
  1925 definition Ratreal :: "rat \<Rightarrow> real" where
  1926   [code_abbrev, simp]: "Ratreal = of_rat"
  1927 
  1928 code_datatype Ratreal
  1929 
  1930 
  1931 text {* Numerals *}
  1932 
  1933 lemma [code_abbrev]:
  1934   "(of_rat (of_int a) :: real) = of_int a"
  1935   by simp
  1936 
  1937 lemma [code_abbrev]:
  1938   "(of_rat 0 :: real) = 0"
  1939   by simp
  1940 
  1941 lemma [code_abbrev]:
  1942   "(of_rat 1 :: real) = 1"
  1943   by simp
  1944 
  1945 lemma [code_abbrev]:
  1946   "(of_rat (- 1) :: real) = - 1"
  1947   by simp
  1948 
  1949 lemma [code_abbrev]:
  1950   "(of_rat (numeral k) :: real) = numeral k"
  1951   by simp
  1952 
  1953 lemma [code_abbrev]:
  1954   "(of_rat (- numeral k) :: real) = - numeral k"
  1955   by simp
  1956 
  1957 lemma [code_post]:
  1958   "(of_rat (1 / numeral k) :: real) = 1 / numeral k"
  1959   "(of_rat (numeral k / numeral l) :: real) = numeral k / numeral l"
  1960   "(of_rat (- (1 / numeral k)) :: real) = - (1 / numeral k)"
  1961   "(of_rat (- (numeral k / numeral l)) :: real) = - (numeral k / numeral l)"
  1962   by (simp_all add: of_rat_divide of_rat_minus)
  1963 
  1964 
  1965 text {* Operations *}
  1966 
  1967 lemma zero_real_code [code]:
  1968   "0 = Ratreal 0"
  1969 by simp
  1970 
  1971 lemma one_real_code [code]:
  1972   "1 = Ratreal 1"
  1973 by simp
  1974 
  1975 instantiation real :: equal
  1976 begin
  1977 
  1978 definition "HOL.equal (x\<Colon>real) y \<longleftrightarrow> x - y = 0"
  1979 
  1980 instance proof
  1981 qed (simp add: equal_real_def)
  1982 
  1983 lemma real_equal_code [code]:
  1984   "HOL.equal (Ratreal x) (Ratreal y) \<longleftrightarrow> HOL.equal x y"
  1985   by (simp add: equal_real_def equal)
  1986 
  1987 lemma [code nbe]:
  1988   "HOL.equal (x::real) x \<longleftrightarrow> True"
  1989   by (rule equal_refl)
  1990 
  1991 end
  1992 
  1993 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> x \<le> y"
  1994   by (simp add: of_rat_less_eq)
  1995 
  1996 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> x < y"
  1997   by (simp add: of_rat_less)
  1998 
  1999 lemma real_plus_code [code]: "Ratreal x + Ratreal y = Ratreal (x + y)"
  2000   by (simp add: of_rat_add)
  2001 
  2002 lemma real_times_code [code]: "Ratreal x * Ratreal y = Ratreal (x * y)"
  2003   by (simp add: of_rat_mult)
  2004 
  2005 lemma real_uminus_code [code]: "- Ratreal x = Ratreal (- x)"
  2006   by (simp add: of_rat_minus)
  2007 
  2008 lemma real_minus_code [code]: "Ratreal x - Ratreal y = Ratreal (x - y)"
  2009   by (simp add: of_rat_diff)
  2010 
  2011 lemma real_inverse_code [code]: "inverse (Ratreal x) = Ratreal (inverse x)"
  2012   by (simp add: of_rat_inverse)
  2013  
  2014 lemma real_divide_code [code]: "Ratreal x / Ratreal y = Ratreal (x / y)"
  2015   by (simp add: of_rat_divide)
  2016 
  2017 lemma real_floor_code [code]: "floor (Ratreal x) = floor x"
  2018   by (metis Ratreal_def floor_le_iff floor_unique le_floor_iff of_int_floor_le of_rat_of_int_eq real_less_eq_code)
  2019 
  2020 
  2021 text {* Quickcheck *}
  2022 
  2023 definition (in term_syntax)
  2024   valterm_ratreal :: "rat \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> real \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2025   [code_unfold]: "valterm_ratreal k = Code_Evaluation.valtermify Ratreal {\<cdot>} k"
  2026 
  2027 notation fcomp (infixl "\<circ>>" 60)
  2028 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2029 
  2030 instantiation real :: random
  2031 begin
  2032 
  2033 definition
  2034   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>r. Pair (valterm_ratreal r))"
  2035 
  2036 instance ..
  2037 
  2038 end
  2039 
  2040 no_notation fcomp (infixl "\<circ>>" 60)
  2041 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2042 
  2043 instantiation real :: exhaustive
  2044 begin
  2045 
  2046 definition
  2047   "exhaustive_real f d = Quickcheck_Exhaustive.exhaustive (%r. f (Ratreal r)) d"
  2048 
  2049 instance ..
  2050 
  2051 end
  2052 
  2053 instantiation real :: full_exhaustive
  2054 begin
  2055 
  2056 definition
  2057   "full_exhaustive_real f d = Quickcheck_Exhaustive.full_exhaustive (%r. f (valterm_ratreal r)) d"
  2058 
  2059 instance ..
  2060 
  2061 end
  2062 
  2063 instantiation real :: narrowing
  2064 begin
  2065 
  2066 definition
  2067   "narrowing = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.cons Ratreal) narrowing"
  2068 
  2069 instance ..
  2070 
  2071 end
  2072 
  2073 
  2074 subsection {* Setup for Nitpick *}
  2075 
  2076 declaration {*
  2077   Nitpick_HOL.register_frac_type @{type_name real}
  2078    [(@{const_name zero_real_inst.zero_real}, @{const_name Nitpick.zero_frac}),
  2079     (@{const_name one_real_inst.one_real}, @{const_name Nitpick.one_frac}),
  2080     (@{const_name plus_real_inst.plus_real}, @{const_name Nitpick.plus_frac}),
  2081     (@{const_name times_real_inst.times_real}, @{const_name Nitpick.times_frac}),
  2082     (@{const_name uminus_real_inst.uminus_real}, @{const_name Nitpick.uminus_frac}),
  2083     (@{const_name inverse_real_inst.inverse_real}, @{const_name Nitpick.inverse_frac}),
  2084     (@{const_name ord_real_inst.less_real}, @{const_name Nitpick.less_frac}),
  2085     (@{const_name ord_real_inst.less_eq_real}, @{const_name Nitpick.less_eq_frac})]
  2086 *}
  2087 
  2088 lemmas [nitpick_unfold] = inverse_real_inst.inverse_real one_real_inst.one_real
  2089     ord_real_inst.less_real ord_real_inst.less_eq_real plus_real_inst.plus_real
  2090     times_real_inst.times_real uminus_real_inst.uminus_real
  2091     zero_real_inst.zero_real
  2092 
  2093 
  2094 subsection {* Setup for SMT *}
  2095 
  2096 ML_file "Tools/SMT/smt_real.ML"
  2097 ML_file "Tools/SMT/z3_real.ML"
  2098 
  2099 lemma [z3_rule]:
  2100   "0 + (x::real) = x"
  2101   "x + 0 = x"
  2102   "0 * x = 0"
  2103   "1 * x = x"
  2104   "x + y = y + x"
  2105   by auto
  2106 
  2107 end