src/HOL/Real_Vector_Spaces.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 60307 75e1aa7a450e
child 60758 d8d85a8172b5
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    37 apply (cases "finite A")
    38 apply (induct set: finite)
    39 apply (simp add: zero)
    40 apply (simp add: add)
    41 apply (simp add: zero)
    42 done
    43 
    44 end
    45 
    46 subsection {* Vector spaces *}
    47 
    48 locale vector_space =
    49   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    50   assumes scale_right_distrib [algebra_simps]:
    51     "scale a (x + y) = scale a x + scale a y"
    52   and scale_left_distrib [algebra_simps]:
    53     "scale (a + b) x = scale a x + scale b x"
    54   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    55   and scale_one [simp]: "scale 1 x = x"
    56 begin
    57 
    58 lemma scale_left_commute:
    59   "scale a (scale b x) = scale b (scale a x)"
    60 by (simp add: mult.commute)
    61 
    62 lemma scale_zero_left [simp]: "scale 0 x = 0"
    63   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    64   and scale_left_diff_distrib [algebra_simps]:
    65         "scale (a - b) x = scale a x - scale b x"
    66   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    67 proof -
    68   interpret s: additive "\<lambda>a. scale a x"
    69     proof qed (rule scale_left_distrib)
    70   show "scale 0 x = 0" by (rule s.zero)
    71   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    72   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    73   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    74 qed
    75 
    76 lemma scale_zero_right [simp]: "scale a 0 = 0"
    77   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    78   and scale_right_diff_distrib [algebra_simps]:
    79         "scale a (x - y) = scale a x - scale a y"
    80   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    81 proof -
    82   interpret s: additive "\<lambda>x. scale a x"
    83     proof qed (rule scale_right_distrib)
    84   show "scale a 0 = 0" by (rule s.zero)
    85   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    86   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    87   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    88 qed
    89 
    90 lemma scale_eq_0_iff [simp]:
    91   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    92 proof cases
    93   assume "a = 0" thus ?thesis by simp
    94 next
    95   assume anz [simp]: "a \<noteq> 0"
    96   { assume "scale a x = 0"
    97     hence "scale (inverse a) (scale a x) = 0" by simp
    98     hence "x = 0" by simp }
    99   thus ?thesis by force
   100 qed
   101 
   102 lemma scale_left_imp_eq:
   103   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   104 proof -
   105   assume nonzero: "a \<noteq> 0"
   106   assume "scale a x = scale a y"
   107   hence "scale a (x - y) = 0"
   108      by (simp add: scale_right_diff_distrib)
   109   hence "x - y = 0" by (simp add: nonzero)
   110   thus "x = y" by (simp only: right_minus_eq)
   111 qed
   112 
   113 lemma scale_right_imp_eq:
   114   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   115 proof -
   116   assume nonzero: "x \<noteq> 0"
   117   assume "scale a x = scale b x"
   118   hence "scale (a - b) x = 0"
   119      by (simp add: scale_left_diff_distrib)
   120   hence "a - b = 0" by (simp add: nonzero)
   121   thus "a = b" by (simp only: right_minus_eq)
   122 qed
   123 
   124 lemma scale_cancel_left [simp]:
   125   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   126 by (auto intro: scale_left_imp_eq)
   127 
   128 lemma scale_cancel_right [simp]:
   129   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   130 by (auto intro: scale_right_imp_eq)
   131 
   132 end
   133 
   134 subsection {* Real vector spaces *}
   135 
   136 class scaleR =
   137   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   138 begin
   139 
   140 abbreviation
   141   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   142 where
   143   "x /\<^sub>R r == scaleR (inverse r) x"
   144 
   145 end
   146 
   147 class real_vector = scaleR + ab_group_add +
   148   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   149   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   150   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   151   and scaleR_one: "scaleR 1 x = x"
   152 
   153 interpretation real_vector:
   154   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   155 apply unfold_locales
   156 apply (rule scaleR_add_right)
   157 apply (rule scaleR_add_left)
   158 apply (rule scaleR_scaleR)
   159 apply (rule scaleR_one)
   160 done
   161 
   162 text {* Recover original theorem names *}
   163 
   164 lemmas scaleR_left_commute = real_vector.scale_left_commute
   165 lemmas scaleR_zero_left = real_vector.scale_zero_left
   166 lemmas scaleR_minus_left = real_vector.scale_minus_left
   167 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   168 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   169 lemmas scaleR_zero_right = real_vector.scale_zero_right
   170 lemmas scaleR_minus_right = real_vector.scale_minus_right
   171 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   172 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   173 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   174 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   175 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   176 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   177 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   178 
   179 text {* Legacy names *}
   180 
   181 lemmas scaleR_left_distrib = scaleR_add_left
   182 lemmas scaleR_right_distrib = scaleR_add_right
   183 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   184 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   185 
   186 lemma scaleR_minus1_left [simp]:
   187   fixes x :: "'a::real_vector"
   188   shows "scaleR (-1) x = - x"
   189   using scaleR_minus_left [of 1 x] by simp
   190 
   191 class real_algebra = real_vector + ring +
   192   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   193   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   194 
   195 class real_algebra_1 = real_algebra + ring_1
   196 
   197 class real_div_algebra = real_algebra_1 + division_ring
   198 
   199 class real_field = real_div_algebra + field
   200 
   201 instantiation real :: real_field
   202 begin
   203 
   204 definition
   205   real_scaleR_def [simp]: "scaleR a x = a * x"
   206 
   207 instance proof
   208 qed (simp_all add: algebra_simps)
   209 
   210 end
   211 
   212 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   213 proof qed (rule scaleR_left_distrib)
   214 
   215 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   216 proof qed (rule scaleR_right_distrib)
   217 
   218 lemma nonzero_inverse_scaleR_distrib:
   219   fixes x :: "'a::real_div_algebra" shows
   220   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   221 by (rule inverse_unique, simp)
   222 
   223 lemma inverse_scaleR_distrib:
   224   fixes x :: "'a::{real_div_algebra, division_ring}"
   225   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226 apply (case_tac "a = 0", simp)
   227 apply (case_tac "x = 0", simp)
   228 apply (erule (1) nonzero_inverse_scaleR_distrib)
   229 done
   230 
   231 
   232 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   233 @{term of_real} *}
   234 
   235 definition
   236   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   237   "of_real r = scaleR r 1"
   238 
   239 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   240 by (simp add: of_real_def)
   241 
   242 lemma of_real_0 [simp]: "of_real 0 = 0"
   243 by (simp add: of_real_def)
   244 
   245 lemma of_real_1 [simp]: "of_real 1 = 1"
   246 by (simp add: of_real_def)
   247 
   248 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   249 by (simp add: of_real_def scaleR_left_distrib)
   250 
   251 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   252 by (simp add: of_real_def)
   253 
   254 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   255 by (simp add: of_real_def scaleR_left_diff_distrib)
   256 
   257 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   258 by (simp add: of_real_def mult.commute)
   259 
   260 lemma of_real_setsum[simp]: "of_real (setsum f s) = (\<Sum>x\<in>s. of_real (f x))"
   261   by (induct s rule: infinite_finite_induct) auto
   262 
   263 lemma of_real_setprod[simp]: "of_real (setprod f s) = (\<Prod>x\<in>s. of_real (f x))"
   264   by (induct s rule: infinite_finite_induct) auto
   265 
   266 lemma nonzero_of_real_inverse:
   267   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   268    inverse (of_real x :: 'a::real_div_algebra)"
   269 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   270 
   271 lemma of_real_inverse [simp]:
   272   "of_real (inverse x) =
   273    inverse (of_real x :: 'a::{real_div_algebra, division_ring})"
   274 by (simp add: of_real_def inverse_scaleR_distrib)
   275 
   276 lemma nonzero_of_real_divide:
   277   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   278    (of_real x / of_real y :: 'a::real_field)"
   279 by (simp add: divide_inverse nonzero_of_real_inverse)
   280 
   281 lemma of_real_divide [simp]:
   282   "of_real (x / y) =
   283    (of_real x / of_real y :: 'a::{real_field, field})"
   284 by (simp add: divide_inverse)
   285 
   286 lemma of_real_power [simp]:
   287   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   288 by (induct n) simp_all
   289 
   290 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   291 by (simp add: of_real_def)
   292 
   293 lemma inj_of_real:
   294   "inj of_real"
   295   by (auto intro: injI)
   296 
   297 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   298 
   299 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   300 proof
   301   fix r
   302   show "of_real r = id r"
   303     by (simp add: of_real_def)
   304 qed
   305 
   306 text{*Collapse nested embeddings*}
   307 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   308 by (induct n) auto
   309 
   310 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   311 by (cases z rule: int_diff_cases, simp)
   312 
   313 lemma of_real_real_of_nat_eq [simp]: "of_real (real n) = of_nat n"
   314   by (simp add: real_of_nat_def)
   315 
   316 lemma of_real_real_of_int_eq [simp]: "of_real (real z) = of_int z"
   317   by (simp add: real_of_int_def)
   318 
   319 lemma of_real_numeral [simp]: "of_real (numeral w) = numeral w"
   320 using of_real_of_int_eq [of "numeral w"] by simp
   321 
   322 lemma of_real_neg_numeral [simp]: "of_real (- numeral w) = - numeral w"
   323 using of_real_of_int_eq [of "- numeral w"] by simp
   324 
   325 text{*Every real algebra has characteristic zero*}
   326 
   327 instance real_algebra_1 < ring_char_0
   328 proof
   329   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   330   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   331 qed
   332 
   333 instance real_field < field_char_0 ..
   334 
   335 
   336 subsection {* The Set of Real Numbers *}
   337 
   338 definition Reals :: "'a::real_algebra_1 set" where
   339   "Reals = range of_real"
   340 
   341 notation (xsymbols)
   342   Reals  ("\<real>")
   343 
   344 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   345 by (simp add: Reals_def)
   346 
   347 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   348 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   349 
   350 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   351 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   352 
   353 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   354 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   355 
   356 lemma Reals_0 [simp]: "0 \<in> Reals"
   357 apply (unfold Reals_def)
   358 apply (rule range_eqI)
   359 apply (rule of_real_0 [symmetric])
   360 done
   361 
   362 lemma Reals_1 [simp]: "1 \<in> Reals"
   363 apply (unfold Reals_def)
   364 apply (rule range_eqI)
   365 apply (rule of_real_1 [symmetric])
   366 done
   367 
   368 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   369 apply (auto simp add: Reals_def)
   370 apply (rule range_eqI)
   371 apply (rule of_real_add [symmetric])
   372 done
   373 
   374 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   375 apply (auto simp add: Reals_def)
   376 apply (rule range_eqI)
   377 apply (rule of_real_minus [symmetric])
   378 done
   379 
   380 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   381 apply (auto simp add: Reals_def)
   382 apply (rule range_eqI)
   383 apply (rule of_real_diff [symmetric])
   384 done
   385 
   386 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   387 apply (auto simp add: Reals_def)
   388 apply (rule range_eqI)
   389 apply (rule of_real_mult [symmetric])
   390 done
   391 
   392 lemma nonzero_Reals_inverse:
   393   fixes a :: "'a::real_div_algebra"
   394   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   395 apply (auto simp add: Reals_def)
   396 apply (rule range_eqI)
   397 apply (erule nonzero_of_real_inverse [symmetric])
   398 done
   399 
   400 lemma Reals_inverse:
   401   fixes a :: "'a::{real_div_algebra, division_ring}"
   402   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   403 apply (auto simp add: Reals_def)
   404 apply (rule range_eqI)
   405 apply (rule of_real_inverse [symmetric])
   406 done
   407 
   408 lemma Reals_inverse_iff [simp]:
   409   fixes x:: "'a :: {real_div_algebra, division_ring}"
   410   shows "inverse x \<in> \<real> \<longleftrightarrow> x \<in> \<real>"
   411 by (metis Reals_inverse inverse_inverse_eq)
   412 
   413 lemma nonzero_Reals_divide:
   414   fixes a b :: "'a::real_field"
   415   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   416 apply (auto simp add: Reals_def)
   417 apply (rule range_eqI)
   418 apply (erule nonzero_of_real_divide [symmetric])
   419 done
   420 
   421 lemma Reals_divide [simp]:
   422   fixes a b :: "'a::{real_field, field}"
   423   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   424 apply (auto simp add: Reals_def)
   425 apply (rule range_eqI)
   426 apply (rule of_real_divide [symmetric])
   427 done
   428 
   429 lemma Reals_power [simp]:
   430   fixes a :: "'a::{real_algebra_1}"
   431   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   432 apply (auto simp add: Reals_def)
   433 apply (rule range_eqI)
   434 apply (rule of_real_power [symmetric])
   435 done
   436 
   437 lemma Reals_cases [cases set: Reals]:
   438   assumes "q \<in> \<real>"
   439   obtains (of_real) r where "q = of_real r"
   440   unfolding Reals_def
   441 proof -
   442   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   443   then obtain r where "q = of_real r" ..
   444   then show thesis ..
   445 qed
   446 
   447 lemma setsum_in_Reals [intro,simp]:
   448   assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setsum f s \<in> \<real>"
   449 proof (cases "finite s")
   450   case True then show ?thesis using assms
   451     by (induct s rule: finite_induct) auto
   452 next
   453   case False then show ?thesis using assms
   454     by (metis Reals_0 setsum.infinite)
   455 qed
   456 
   457 lemma setprod_in_Reals [intro,simp]:
   458   assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setprod f s \<in> \<real>"
   459 proof (cases "finite s")
   460   case True then show ?thesis using assms
   461     by (induct s rule: finite_induct) auto
   462 next
   463   case False then show ?thesis using assms
   464     by (metis Reals_1 setprod.infinite)
   465 qed
   466 
   467 lemma Reals_induct [case_names of_real, induct set: Reals]:
   468   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   469   by (rule Reals_cases) auto
   470 
   471 subsection {* Ordered real vector spaces *}
   472 
   473 class ordered_real_vector = real_vector + ordered_ab_group_add +
   474   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   475   assumes scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   476 begin
   477 
   478 lemma scaleR_mono:
   479   "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   480 apply (erule scaleR_right_mono [THEN order_trans], assumption)
   481 apply (erule scaleR_left_mono, assumption)
   482 done
   483 
   484 lemma scaleR_mono':
   485   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   486   by (rule scaleR_mono) (auto intro: order.trans)
   487 
   488 lemma pos_le_divideRI:
   489   assumes "0 < c"
   490   assumes "c *\<^sub>R a \<le> b"
   491   shows "a \<le> b /\<^sub>R c"
   492 proof -
   493   from scaleR_left_mono[OF assms(2)] assms(1)
   494   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   495     by simp
   496   with assms show ?thesis
   497     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   498 qed
   499 
   500 lemma pos_le_divideR_eq:
   501   assumes "0 < c"
   502   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   503 proof rule
   504   assume "a \<le> b /\<^sub>R c"
   505   from scaleR_left_mono[OF this] assms
   506   have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   507     by simp
   508   with assms show "c *\<^sub>R a \<le> b"
   509     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   510 qed (rule pos_le_divideRI[OF assms])
   511 
   512 lemma scaleR_image_atLeastAtMost:
   513   "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   514   apply (auto intro!: scaleR_left_mono)
   515   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   516   apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   517   done
   518 
   519 end
   520 
   521 lemma neg_le_divideR_eq:
   522   fixes a :: "'a :: ordered_real_vector"
   523   assumes "c < 0"
   524   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> b \<le> c *\<^sub>R a"
   525   using pos_le_divideR_eq [of "-c" a "-b"] assms
   526   by simp
   527 
   528 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   529   using scaleR_left_mono [of 0 x a]
   530   by simp
   531 
   532 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> (x::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   533   using scaleR_left_mono [of x 0 a] by simp
   534 
   535 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   536   using scaleR_right_mono [of a 0 x] by simp
   537 
   538 lemma split_scaleR_neg_le: "(0 \<le> a & x \<le> 0) | (a \<le> 0 & 0 \<le> x) \<Longrightarrow>
   539   a *\<^sub>R (x::'a::ordered_real_vector) \<le> 0"
   540   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   541 
   542 lemma le_add_iff1:
   543   fixes c d e::"'a::ordered_real_vector"
   544   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   545   by (simp add: algebra_simps)
   546 
   547 lemma le_add_iff2:
   548   fixes c d e::"'a::ordered_real_vector"
   549   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   550   by (simp add: algebra_simps)
   551 
   552 lemma scaleR_left_mono_neg:
   553   fixes a b::"'a::ordered_real_vector"
   554   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   555   apply (drule scaleR_left_mono [of _ _ "- c"])
   556   apply simp_all
   557   done
   558 
   559 lemma scaleR_right_mono_neg:
   560   fixes c::"'a::ordered_real_vector"
   561   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   562   apply (drule scaleR_right_mono [of _ _ "- c"])
   563   apply simp_all
   564   done
   565 
   566 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> (b::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   567 using scaleR_right_mono_neg [of a 0 b] by simp
   568 
   569 lemma split_scaleR_pos_le:
   570   fixes b::"'a::ordered_real_vector"
   571   shows "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   572   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   573 
   574 lemma zero_le_scaleR_iff:
   575   fixes b::"'a::ordered_real_vector"
   576   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0" (is "?lhs = ?rhs")
   577 proof cases
   578   assume "a \<noteq> 0"
   579   show ?thesis
   580   proof
   581     assume lhs: ?lhs
   582     {
   583       assume "0 < a"
   584       with lhs have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   585         by (intro scaleR_mono) auto
   586       hence ?rhs using `0 < a`
   587         by simp
   588     } moreover {
   589       assume "0 > a"
   590       with lhs have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   591         by (intro scaleR_mono) auto
   592       hence ?rhs using `0 > a`
   593         by simp
   594     } ultimately show ?rhs using `a \<noteq> 0` by arith
   595   qed (auto simp: not_le `a \<noteq> 0` intro!: split_scaleR_pos_le)
   596 qed simp
   597 
   598 lemma scaleR_le_0_iff:
   599   fixes b::"'a::ordered_real_vector"
   600   shows "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   601   by (insert zero_le_scaleR_iff [of "-a" b]) force
   602 
   603 lemma scaleR_le_cancel_left:
   604   fixes b::"'a::ordered_real_vector"
   605   shows "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   606   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   607     dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   608 
   609 lemma scaleR_le_cancel_left_pos:
   610   fixes b::"'a::ordered_real_vector"
   611   shows "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   612   by (auto simp: scaleR_le_cancel_left)
   613 
   614 lemma scaleR_le_cancel_left_neg:
   615   fixes b::"'a::ordered_real_vector"
   616   shows "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   617   by (auto simp: scaleR_le_cancel_left)
   618 
   619 lemma scaleR_left_le_one_le:
   620   fixes x::"'a::ordered_real_vector" and a::real
   621   shows "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   622   using scaleR_right_mono[of a 1 x] by simp
   623 
   624 
   625 subsection {* Real normed vector spaces *}
   626 
   627 class dist =
   628   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   629 
   630 class norm =
   631   fixes norm :: "'a \<Rightarrow> real"
   632 
   633 class sgn_div_norm = scaleR + norm + sgn +
   634   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   635 
   636 class dist_norm = dist + norm + minus +
   637   assumes dist_norm: "dist x y = norm (x - y)"
   638 
   639 class open_dist = "open" + dist +
   640   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   641 
   642 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   643   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   644   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   645   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   646 begin
   647 
   648 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   649 proof -
   650   have "0 = norm (x + -1 *\<^sub>R x)"
   651     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   652   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   653   finally show ?thesis by simp
   654 qed
   655 
   656 end
   657 
   658 class real_normed_algebra = real_algebra + real_normed_vector +
   659   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   660 
   661 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   662   assumes norm_one [simp]: "norm 1 = 1"
   663 
   664 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   665   assumes norm_mult: "norm (x * y) = norm x * norm y"
   666 
   667 class real_normed_field = real_field + real_normed_div_algebra
   668 
   669 instance real_normed_div_algebra < real_normed_algebra_1
   670 proof
   671   fix x y :: 'a
   672   show "norm (x * y) \<le> norm x * norm y"
   673     by (simp add: norm_mult)
   674 next
   675   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   676     by (rule norm_mult)
   677   thus "norm (1::'a) = 1" by simp
   678 qed
   679 
   680 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   681 by simp
   682 
   683 lemma zero_less_norm_iff [simp]:
   684   fixes x :: "'a::real_normed_vector"
   685   shows "(0 < norm x) = (x \<noteq> 0)"
   686 by (simp add: order_less_le)
   687 
   688 lemma norm_not_less_zero [simp]:
   689   fixes x :: "'a::real_normed_vector"
   690   shows "\<not> norm x < 0"
   691 by (simp add: linorder_not_less)
   692 
   693 lemma norm_le_zero_iff [simp]:
   694   fixes x :: "'a::real_normed_vector"
   695   shows "(norm x \<le> 0) = (x = 0)"
   696 by (simp add: order_le_less)
   697 
   698 lemma norm_minus_cancel [simp]:
   699   fixes x :: "'a::real_normed_vector"
   700   shows "norm (- x) = norm x"
   701 proof -
   702   have "norm (- x) = norm (scaleR (- 1) x)"
   703     by (simp only: scaleR_minus_left scaleR_one)
   704   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   705     by (rule norm_scaleR)
   706   finally show ?thesis by simp
   707 qed
   708 
   709 lemma norm_minus_commute:
   710   fixes a b :: "'a::real_normed_vector"
   711   shows "norm (a - b) = norm (b - a)"
   712 proof -
   713   have "norm (- (b - a)) = norm (b - a)"
   714     by (rule norm_minus_cancel)
   715   thus ?thesis by simp
   716 qed
   717 
   718 lemma norm_triangle_ineq2:
   719   fixes a b :: "'a::real_normed_vector"
   720   shows "norm a - norm b \<le> norm (a - b)"
   721 proof -
   722   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   723     by (rule norm_triangle_ineq)
   724   thus ?thesis by simp
   725 qed
   726 
   727 lemma norm_triangle_ineq3:
   728   fixes a b :: "'a::real_normed_vector"
   729   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   730 apply (subst abs_le_iff)
   731 apply auto
   732 apply (rule norm_triangle_ineq2)
   733 apply (subst norm_minus_commute)
   734 apply (rule norm_triangle_ineq2)
   735 done
   736 
   737 lemma norm_triangle_ineq4:
   738   fixes a b :: "'a::real_normed_vector"
   739   shows "norm (a - b) \<le> norm a + norm b"
   740 proof -
   741   have "norm (a + - b) \<le> norm a + norm (- b)"
   742     by (rule norm_triangle_ineq)
   743   then show ?thesis by simp
   744 qed
   745 
   746 lemma norm_diff_ineq:
   747   fixes a b :: "'a::real_normed_vector"
   748   shows "norm a - norm b \<le> norm (a + b)"
   749 proof -
   750   have "norm a - norm (- b) \<le> norm (a - - b)"
   751     by (rule norm_triangle_ineq2)
   752   thus ?thesis by simp
   753 qed
   754 
   755 lemma norm_diff_triangle_ineq:
   756   fixes a b c d :: "'a::real_normed_vector"
   757   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   758 proof -
   759   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   760     by (simp add: algebra_simps)
   761   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   762     by (rule norm_triangle_ineq)
   763   finally show ?thesis .
   764 qed
   765 
   766 lemma norm_triangle_mono:
   767   fixes a b :: "'a::real_normed_vector"
   768   shows "\<lbrakk>norm a \<le> r; norm b \<le> s\<rbrakk> \<Longrightarrow> norm (a + b) \<le> r + s"
   769 by (metis add_mono_thms_linordered_semiring(1) norm_triangle_ineq order.trans)
   770 
   771 lemma norm_setsum:
   772   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   773   shows "norm (setsum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   774   by (induct A rule: infinite_finite_induct) (auto intro: norm_triangle_mono)
   775 
   776 lemma setsum_norm_le:
   777   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   778   assumes fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
   779   shows "norm (setsum f S) \<le> setsum g S"
   780   by (rule order_trans [OF norm_setsum setsum_mono]) (simp add: fg)
   781 
   782 lemma abs_norm_cancel [simp]:
   783   fixes a :: "'a::real_normed_vector"
   784   shows "\<bar>norm a\<bar> = norm a"
   785 by (rule abs_of_nonneg [OF norm_ge_zero])
   786 
   787 lemma norm_add_less:
   788   fixes x y :: "'a::real_normed_vector"
   789   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   790 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   791 
   792 lemma norm_mult_less:
   793   fixes x y :: "'a::real_normed_algebra"
   794   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   795 apply (rule order_le_less_trans [OF norm_mult_ineq])
   796 apply (simp add: mult_strict_mono')
   797 done
   798 
   799 lemma norm_of_real [simp]:
   800   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   801 unfolding of_real_def by simp
   802 
   803 lemma norm_numeral [simp]:
   804   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   805 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   806 
   807 lemma norm_neg_numeral [simp]:
   808   "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   809 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   810 
   811 lemma norm_of_int [simp]:
   812   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   813 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   814 
   815 lemma norm_of_nat [simp]:
   816   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   817 apply (subst of_real_of_nat_eq [symmetric])
   818 apply (subst norm_of_real, simp)
   819 done
   820 
   821 lemma nonzero_norm_inverse:
   822   fixes a :: "'a::real_normed_div_algebra"
   823   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   824 apply (rule inverse_unique [symmetric])
   825 apply (simp add: norm_mult [symmetric])
   826 done
   827 
   828 lemma norm_inverse:
   829   fixes a :: "'a::{real_normed_div_algebra, division_ring}"
   830   shows "norm (inverse a) = inverse (norm a)"
   831 apply (case_tac "a = 0", simp)
   832 apply (erule nonzero_norm_inverse)
   833 done
   834 
   835 lemma nonzero_norm_divide:
   836   fixes a b :: "'a::real_normed_field"
   837   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   838 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   839 
   840 lemma norm_divide:
   841   fixes a b :: "'a::{real_normed_field, field}"
   842   shows "norm (a / b) = norm a / norm b"
   843 by (simp add: divide_inverse norm_mult norm_inverse)
   844 
   845 lemma norm_power_ineq:
   846   fixes x :: "'a::{real_normed_algebra_1}"
   847   shows "norm (x ^ n) \<le> norm x ^ n"
   848 proof (induct n)
   849   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   850 next
   851   case (Suc n)
   852   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   853     by (rule norm_mult_ineq)
   854   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   855     using norm_ge_zero by (rule mult_left_mono)
   856   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   857     by simp
   858 qed
   859 
   860 lemma norm_power:
   861   fixes x :: "'a::{real_normed_div_algebra}"
   862   shows "norm (x ^ n) = norm x ^ n"
   863 by (induct n) (simp_all add: norm_mult)
   864 
   865 text{*Despite a superficial resemblance, @{text norm_eq_1} is not relevant.*}
   866 lemma square_norm_one:
   867   fixes x :: "'a::real_normed_div_algebra"
   868   assumes "x^2 = 1" shows "norm x = 1"
   869   by (metis assms norm_minus_cancel norm_one power2_eq_1_iff)
   870 
   871 lemma norm_less_p1:
   872   fixes x :: "'a::real_normed_algebra_1"
   873   shows "norm x < norm (of_real (norm x) + 1 :: 'a)"
   874 proof -
   875   have "norm x < norm (of_real (norm x + 1) :: 'a)"
   876     by (simp add: of_real_def)
   877   then show ?thesis
   878     by simp
   879 qed
   880 
   881 lemma setprod_norm:
   882   fixes f :: "'a \<Rightarrow> 'b::{comm_semiring_1,real_normed_div_algebra}"
   883   shows "setprod (\<lambda>x. norm(f x)) A = norm (setprod f A)"
   884   by (induct A rule: infinite_finite_induct) (auto simp: norm_mult)
   885 
   886 lemma norm_setprod_le:
   887   "norm (setprod f A) \<le> (\<Prod>a\<in>A. norm (f a :: 'a :: {real_normed_algebra_1, comm_monoid_mult}))"
   888 proof (induction A rule: infinite_finite_induct)
   889   case (insert a A)
   890   then have "norm (setprod f (insert a A)) \<le> norm (f a) * norm (setprod f A)"
   891     by (simp add: norm_mult_ineq)
   892   also have "norm (setprod f A) \<le> (\<Prod>a\<in>A. norm (f a))"
   893     by (rule insert)
   894   finally show ?case
   895     by (simp add: insert mult_left_mono)
   896 qed simp_all
   897 
   898 lemma norm_setprod_diff:
   899   fixes z w :: "'i \<Rightarrow> 'a::{real_normed_algebra_1, comm_monoid_mult}"
   900   shows "(\<And>i. i \<in> I \<Longrightarrow> norm (z i) \<le> 1) \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> norm (w i) \<le> 1) \<Longrightarrow>
   901     norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))"
   902 proof (induction I rule: infinite_finite_induct)
   903   case (insert i I)
   904   note insert.hyps[simp]
   905 
   906   have "norm ((\<Prod>i\<in>insert i I. z i) - (\<Prod>i\<in>insert i I. w i)) =
   907     norm ((\<Prod>i\<in>I. z i) * (z i - w i) + ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * w i)"
   908     (is "_ = norm (?t1 + ?t2)")
   909     by (auto simp add: field_simps)
   910   also have "... \<le> norm ?t1 + norm ?t2"
   911     by (rule norm_triangle_ineq)
   912   also have "norm ?t1 \<le> norm (\<Prod>i\<in>I. z i) * norm (z i - w i)"
   913     by (rule norm_mult_ineq)
   914   also have "\<dots> \<le> (\<Prod>i\<in>I. norm (z i)) * norm(z i - w i)"
   915     by (rule mult_right_mono) (auto intro: norm_setprod_le)
   916   also have "(\<Prod>i\<in>I. norm (z i)) \<le> (\<Prod>i\<in>I. 1)"
   917     by (intro setprod_mono) (auto intro!: insert)
   918   also have "norm ?t2 \<le> norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * norm (w i)"
   919     by (rule norm_mult_ineq)
   920   also have "norm (w i) \<le> 1"
   921     by (auto intro: insert)
   922   also have "norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))"
   923     using insert by auto
   924   finally show ?case
   925     by (auto simp add: ac_simps mult_right_mono mult_left_mono)
   926 qed simp_all
   927 
   928 lemma norm_power_diff:
   929   fixes z w :: "'a::{real_normed_algebra_1, comm_monoid_mult}"
   930   assumes "norm z \<le> 1" "norm w \<le> 1"
   931   shows "norm (z^m - w^m) \<le> m * norm (z - w)"
   932 proof -
   933   have "norm (z^m - w^m) = norm ((\<Prod> i < m. z) - (\<Prod> i < m. w))"
   934     by (simp add: setprod_constant)
   935   also have "\<dots> \<le> (\<Sum>i<m. norm (z - w))"
   936     by (intro norm_setprod_diff) (auto simp add: assms)
   937   also have "\<dots> = m * norm (z - w)"
   938     by (simp add: real_of_nat_def)
   939   finally show ?thesis .
   940 qed
   941 
   942 subsection {* Metric spaces *}
   943 
   944 class metric_space = open_dist +
   945   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   946   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   947 begin
   948 
   949 lemma dist_self [simp]: "dist x x = 0"
   950 by simp
   951 
   952 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   953 using dist_triangle2 [of x x y] by simp
   954 
   955 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   956 by (simp add: less_le)
   957 
   958 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   959 by (simp add: not_less)
   960 
   961 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   962 by (simp add: le_less)
   963 
   964 lemma dist_commute: "dist x y = dist y x"
   965 proof (rule order_antisym)
   966   show "dist x y \<le> dist y x"
   967     using dist_triangle2 [of x y x] by simp
   968   show "dist y x \<le> dist x y"
   969     using dist_triangle2 [of y x y] by simp
   970 qed
   971 
   972 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   973 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   974 
   975 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   976 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   977 
   978 lemma dist_triangle_alt:
   979   shows "dist y z <= dist x y + dist x z"
   980 by (rule dist_triangle3)
   981 
   982 lemma dist_pos_lt:
   983   shows "x \<noteq> y ==> 0 < dist x y"
   984 by (simp add: zero_less_dist_iff)
   985 
   986 lemma dist_nz:
   987   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   988 by (simp add: zero_less_dist_iff)
   989 
   990 lemma dist_triangle_le:
   991   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   992 by (rule order_trans [OF dist_triangle2])
   993 
   994 lemma dist_triangle_lt:
   995   shows "dist x z + dist y z < e ==> dist x y < e"
   996 by (rule le_less_trans [OF dist_triangle2])
   997 
   998 lemma dist_triangle_half_l:
   999   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
  1000 by (rule dist_triangle_lt [where z=y], simp)
  1001 
  1002 lemma dist_triangle_half_r:
  1003   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
  1004 by (rule dist_triangle_half_l, simp_all add: dist_commute)
  1005 
  1006 subclass topological_space
  1007 proof
  1008   have "\<exists>e::real. 0 < e"
  1009     by (fast intro: zero_less_one)
  1010   then show "open UNIV"
  1011     unfolding open_dist by simp
  1012 next
  1013   fix S T assume "open S" "open T"
  1014   then show "open (S \<inter> T)"
  1015     unfolding open_dist
  1016     apply clarify
  1017     apply (drule (1) bspec)+
  1018     apply (clarify, rename_tac r s)
  1019     apply (rule_tac x="min r s" in exI, simp)
  1020     done
  1021 next
  1022   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
  1023     unfolding open_dist by fast
  1024 qed
  1025 
  1026 lemma open_ball: "open {y. dist x y < d}"
  1027 proof (unfold open_dist, intro ballI)
  1028   fix y assume *: "y \<in> {y. dist x y < d}"
  1029   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
  1030     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
  1031 qed
  1032 
  1033 subclass first_countable_topology
  1034 proof
  1035   fix x
  1036   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1037   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
  1038     fix S assume "open S" "x \<in> S"
  1039     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
  1040       by (auto simp: open_dist subset_eq dist_commute)
  1041     moreover
  1042     from e obtain i where "inverse (Suc i) < e"
  1043       by (auto dest!: reals_Archimedean)
  1044     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
  1045       by auto
  1046     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
  1047       by blast
  1048   qed (auto intro: open_ball)
  1049 qed
  1050 
  1051 end
  1052 
  1053 instance metric_space \<subseteq> t2_space
  1054 proof
  1055   fix x y :: "'a::metric_space"
  1056   assume xy: "x \<noteq> y"
  1057   let ?U = "{y'. dist x y' < dist x y / 2}"
  1058   let ?V = "{x'. dist y x' < dist x y / 2}"
  1059   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
  1060                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
  1061   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
  1062     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
  1063     using open_ball[of _ "dist x y / 2"] by auto
  1064   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1065     by blast
  1066 qed
  1067 
  1068 text {* Every normed vector space is a metric space. *}
  1069 
  1070 instance real_normed_vector < metric_space
  1071 proof
  1072   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
  1073     unfolding dist_norm by simp
  1074 next
  1075   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
  1076     unfolding dist_norm
  1077     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
  1078 qed
  1079 
  1080 subsection {* Class instances for real numbers *}
  1081 
  1082 instantiation real :: real_normed_field
  1083 begin
  1084 
  1085 definition dist_real_def:
  1086   "dist x y = \<bar>x - y\<bar>"
  1087 
  1088 definition open_real_def [code del]:
  1089   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
  1090 
  1091 definition real_norm_def [simp]:
  1092   "norm r = \<bar>r\<bar>"
  1093 
  1094 instance
  1095 apply (intro_classes, unfold real_norm_def real_scaleR_def)
  1096 apply (rule dist_real_def)
  1097 apply (rule open_real_def)
  1098 apply (simp add: sgn_real_def)
  1099 apply (rule abs_eq_0)
  1100 apply (rule abs_triangle_ineq)
  1101 apply (rule abs_mult)
  1102 apply (rule abs_mult)
  1103 done
  1104 
  1105 end
  1106 
  1107 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
  1108 
  1109 instance real :: linorder_topology
  1110 proof
  1111   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1112   proof (rule ext, safe)
  1113     fix S :: "real set" assume "open S"
  1114     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
  1115       unfolding open_real_def bchoice_iff ..
  1116     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
  1117       by (fastforce simp: dist_real_def)
  1118     show "generate_topology (range lessThan \<union> range greaterThan) S"
  1119       apply (subst *)
  1120       apply (intro generate_topology_Union generate_topology.Int)
  1121       apply (auto intro: generate_topology.Basis)
  1122       done
  1123   next
  1124     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
  1125     moreover have "\<And>a::real. open {..<a}"
  1126       unfolding open_real_def dist_real_def
  1127     proof clarify
  1128       fix x a :: real assume "x < a"
  1129       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
  1130       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
  1131     qed
  1132     moreover have "\<And>a::real. open {a <..}"
  1133       unfolding open_real_def dist_real_def
  1134     proof clarify
  1135       fix x a :: real assume "a < x"
  1136       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1137       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1138     qed
  1139     ultimately show "open S"
  1140       by induct auto
  1141   qed
  1142 qed
  1143 
  1144 instance real :: linear_continuum_topology ..
  1145 
  1146 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1147 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1148 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1149 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1150 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1151 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1152 
  1153 subsection {* Extra type constraints *}
  1154 
  1155 text {* Only allow @{term "open"} in class @{text topological_space}. *}
  1156 
  1157 setup {* Sign.add_const_constraint
  1158   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
  1159 
  1160 text {* Only allow @{term dist} in class @{text metric_space}. *}
  1161 
  1162 setup {* Sign.add_const_constraint
  1163   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
  1164 
  1165 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
  1166 
  1167 setup {* Sign.add_const_constraint
  1168   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
  1169 
  1170 subsection {* Sign function *}
  1171 
  1172 lemma norm_sgn:
  1173   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
  1174 by (simp add: sgn_div_norm)
  1175 
  1176 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
  1177 by (simp add: sgn_div_norm)
  1178 
  1179 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
  1180 by (simp add: sgn_div_norm)
  1181 
  1182 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
  1183 by (simp add: sgn_div_norm)
  1184 
  1185 lemma sgn_scaleR:
  1186   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
  1187 by (simp add: sgn_div_norm ac_simps)
  1188 
  1189 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1190 by (simp add: sgn_div_norm)
  1191 
  1192 lemma sgn_of_real:
  1193   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
  1194 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1195 
  1196 lemma sgn_mult:
  1197   fixes x y :: "'a::real_normed_div_algebra"
  1198   shows "sgn (x * y) = sgn x * sgn y"
  1199 by (simp add: sgn_div_norm norm_mult mult.commute)
  1200 
  1201 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
  1202 by (simp add: sgn_div_norm divide_inverse)
  1203 
  1204 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
  1205 unfolding real_sgn_eq by simp
  1206 
  1207 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
  1208 unfolding real_sgn_eq by simp
  1209 
  1210 lemma zero_le_sgn_iff [simp]: "0 \<le> sgn x \<longleftrightarrow> 0 \<le> (x::real)"
  1211   by (cases "0::real" x rule: linorder_cases) simp_all
  1212 
  1213 lemma zero_less_sgn_iff [simp]: "0 < sgn x \<longleftrightarrow> 0 < (x::real)"
  1214   by (cases "0::real" x rule: linorder_cases) simp_all
  1215 
  1216 lemma sgn_le_0_iff [simp]: "sgn x \<le> 0 \<longleftrightarrow> (x::real) \<le> 0"
  1217   by (cases "0::real" x rule: linorder_cases) simp_all
  1218 
  1219 lemma sgn_less_0_iff [simp]: "sgn x < 0 \<longleftrightarrow> (x::real) < 0"
  1220   by (cases "0::real" x rule: linorder_cases) simp_all
  1221 
  1222 lemma norm_conv_dist: "norm x = dist x 0"
  1223   unfolding dist_norm by simp
  1224 
  1225 lemma dist_diff [simp]: "dist a (a - b) = norm b"  "dist (a - b) a = norm b"
  1226   by (simp_all add: dist_norm)
  1227   
  1228 subsection {* Bounded Linear and Bilinear Operators *}
  1229 
  1230 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1231   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1232 
  1233 lemma linearI:
  1234   assumes "\<And>x y. f (x + y) = f x + f y"
  1235   assumes "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1236   shows "linear f"
  1237   by default (rule assms)+
  1238 
  1239 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1240   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1241 begin
  1242 
  1243 lemma pos_bounded:
  1244   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1245 proof -
  1246   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1247     using bounded by fast
  1248   show ?thesis
  1249   proof (intro exI impI conjI allI)
  1250     show "0 < max 1 K"
  1251       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1252   next
  1253     fix x
  1254     have "norm (f x) \<le> norm x * K" using K .
  1255     also have "\<dots> \<le> norm x * max 1 K"
  1256       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1257     finally show "norm (f x) \<le> norm x * max 1 K" .
  1258   qed
  1259 qed
  1260 
  1261 lemma nonneg_bounded:
  1262   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1263 proof -
  1264   from pos_bounded
  1265   show ?thesis by (auto intro: order_less_imp_le)
  1266 qed
  1267 
  1268 lemma linear: "linear f" ..
  1269 
  1270 end
  1271 
  1272 lemma bounded_linear_intro:
  1273   assumes "\<And>x y. f (x + y) = f x + f y"
  1274   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1275   assumes "\<And>x. norm (f x) \<le> norm x * K"
  1276   shows "bounded_linear f"
  1277   by default (fast intro: assms)+
  1278 
  1279 locale bounded_bilinear =
  1280   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
  1281                  \<Rightarrow> 'c::real_normed_vector"
  1282     (infixl "**" 70)
  1283   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1284   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1285   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1286   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1287   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1288 begin
  1289 
  1290 lemma pos_bounded:
  1291   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1292 apply (cut_tac bounded, erule exE)
  1293 apply (rule_tac x="max 1 K" in exI, safe)
  1294 apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1295 apply (drule spec, drule spec, erule order_trans)
  1296 apply (rule mult_left_mono [OF max.cobounded2])
  1297 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1298 done
  1299 
  1300 lemma nonneg_bounded:
  1301   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1302 proof -
  1303   from pos_bounded
  1304   show ?thesis by (auto intro: order_less_imp_le)
  1305 qed
  1306 
  1307 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1308 by (rule additive.intro, rule add_right)
  1309 
  1310 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1311 by (rule additive.intro, rule add_left)
  1312 
  1313 lemma zero_left: "prod 0 b = 0"
  1314 by (rule additive.zero [OF additive_left])
  1315 
  1316 lemma zero_right: "prod a 0 = 0"
  1317 by (rule additive.zero [OF additive_right])
  1318 
  1319 lemma minus_left: "prod (- a) b = - prod a b"
  1320 by (rule additive.minus [OF additive_left])
  1321 
  1322 lemma minus_right: "prod a (- b) = - prod a b"
  1323 by (rule additive.minus [OF additive_right])
  1324 
  1325 lemma diff_left:
  1326   "prod (a - a') b = prod a b - prod a' b"
  1327 by (rule additive.diff [OF additive_left])
  1328 
  1329 lemma diff_right:
  1330   "prod a (b - b') = prod a b - prod a b'"
  1331 by (rule additive.diff [OF additive_right])
  1332 
  1333 lemma bounded_linear_left:
  1334   "bounded_linear (\<lambda>a. a ** b)"
  1335 apply (cut_tac bounded, safe)
  1336 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1337 apply (rule add_left)
  1338 apply (rule scaleR_left)
  1339 apply (simp add: ac_simps)
  1340 done
  1341 
  1342 lemma bounded_linear_right:
  1343   "bounded_linear (\<lambda>b. a ** b)"
  1344 apply (cut_tac bounded, safe)
  1345 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1346 apply (rule add_right)
  1347 apply (rule scaleR_right)
  1348 apply (simp add: ac_simps)
  1349 done
  1350 
  1351 lemma prod_diff_prod:
  1352   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1353 by (simp add: diff_left diff_right)
  1354 
  1355 end
  1356 
  1357 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1358   by default (auto intro!: exI[of _ 1])
  1359 
  1360 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1361   by default (auto intro!: exI[of _ 1])
  1362 
  1363 lemma bounded_linear_add:
  1364   assumes "bounded_linear f"
  1365   assumes "bounded_linear g"
  1366   shows "bounded_linear (\<lambda>x. f x + g x)"
  1367 proof -
  1368   interpret f: bounded_linear f by fact
  1369   interpret g: bounded_linear g by fact
  1370   show ?thesis
  1371   proof
  1372     from f.bounded obtain Kf where Kf: "\<And>x. norm (f x) \<le> norm x * Kf" by blast
  1373     from g.bounded obtain Kg where Kg: "\<And>x. norm (g x) \<le> norm x * Kg" by blast
  1374     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1375       using add_mono[OF Kf Kg]
  1376       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1377   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1378 qed
  1379 
  1380 lemma bounded_linear_minus:
  1381   assumes "bounded_linear f"
  1382   shows "bounded_linear (\<lambda>x. - f x)"
  1383 proof -
  1384   interpret f: bounded_linear f by fact
  1385   show ?thesis apply (unfold_locales)
  1386     apply (simp add: f.add)
  1387     apply (simp add: f.scaleR)
  1388     apply (simp add: f.bounded)
  1389     done
  1390 qed
  1391 
  1392 lemma bounded_linear_compose:
  1393   assumes "bounded_linear f"
  1394   assumes "bounded_linear g"
  1395   shows "bounded_linear (\<lambda>x. f (g x))"
  1396 proof -
  1397   interpret f: bounded_linear f by fact
  1398   interpret g: bounded_linear g by fact
  1399   show ?thesis proof (unfold_locales)
  1400     fix x y show "f (g (x + y)) = f (g x) + f (g y)"
  1401       by (simp only: f.add g.add)
  1402   next
  1403     fix r x show "f (g (scaleR r x)) = scaleR r (f (g x))"
  1404       by (simp only: f.scaleR g.scaleR)
  1405   next
  1406     from f.pos_bounded
  1407     obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf" by fast
  1408     from g.pos_bounded
  1409     obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg" by fast
  1410     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1411     proof (intro exI allI)
  1412       fix x
  1413       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1414         using f .
  1415       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1416         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1417       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1418         by (rule mult.assoc)
  1419       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1420     qed
  1421   qed
  1422 qed
  1423 
  1424 lemma bounded_bilinear_mult:
  1425   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1426 apply (rule bounded_bilinear.intro)
  1427 apply (rule distrib_right)
  1428 apply (rule distrib_left)
  1429 apply (rule mult_scaleR_left)
  1430 apply (rule mult_scaleR_right)
  1431 apply (rule_tac x="1" in exI)
  1432 apply (simp add: norm_mult_ineq)
  1433 done
  1434 
  1435 lemma bounded_linear_mult_left:
  1436   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1437   using bounded_bilinear_mult
  1438   by (rule bounded_bilinear.bounded_linear_left)
  1439 
  1440 lemma bounded_linear_mult_right:
  1441   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1442   using bounded_bilinear_mult
  1443   by (rule bounded_bilinear.bounded_linear_right)
  1444 
  1445 lemmas bounded_linear_mult_const =
  1446   bounded_linear_mult_left [THEN bounded_linear_compose]
  1447 
  1448 lemmas bounded_linear_const_mult =
  1449   bounded_linear_mult_right [THEN bounded_linear_compose]
  1450 
  1451 lemma bounded_linear_divide:
  1452   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1453   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1454 
  1455 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1456 apply (rule bounded_bilinear.intro)
  1457 apply (rule scaleR_left_distrib)
  1458 apply (rule scaleR_right_distrib)
  1459 apply simp
  1460 apply (rule scaleR_left_commute)
  1461 apply (rule_tac x="1" in exI, simp)
  1462 done
  1463 
  1464 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1465   using bounded_bilinear_scaleR
  1466   by (rule bounded_bilinear.bounded_linear_left)
  1467 
  1468 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1469   using bounded_bilinear_scaleR
  1470   by (rule bounded_bilinear.bounded_linear_right)
  1471 
  1472 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1473   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1474 
  1475 lemma real_bounded_linear:
  1476   fixes f :: "real \<Rightarrow> real"
  1477   shows "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1478 proof -
  1479   { fix x assume "bounded_linear f"
  1480     then interpret bounded_linear f .
  1481     from scaleR[of x 1] have "f x = x * f 1"
  1482       by simp }
  1483   then show ?thesis
  1484     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1485 qed
  1486 
  1487 instance real_normed_algebra_1 \<subseteq> perfect_space
  1488 proof
  1489   fix x::'a
  1490   show "\<not> open {x}"
  1491     unfolding open_dist dist_norm
  1492     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1493 qed
  1494 
  1495 subsection {* Filters and Limits on Metric Space *}
  1496 
  1497 lemma (in metric_space) nhds_metric: "nhds x = (INF e:{0 <..}. principal {y. dist y x < e})"
  1498   unfolding nhds_def
  1499 proof (safe intro!: INF_eq)
  1500   fix S assume "open S" "x \<in> S"
  1501   then obtain e where "{y. dist y x < e} \<subseteq> S" "0 < e"
  1502     by (auto simp: open_dist subset_eq)
  1503   then show "\<exists>e\<in>{0<..}. principal {y. dist y x < e} \<le> principal S"
  1504     by auto
  1505 qed (auto intro!: exI[of _ "{y. dist x y < e}" for e] open_ball simp: dist_commute)
  1506 
  1507 lemma (in metric_space) tendsto_iff:
  1508   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1509   unfolding nhds_metric filterlim_INF filterlim_principal by auto
  1510 
  1511 lemma (in metric_space) tendstoI: "(\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F) \<Longrightarrow> (f ---> l) F"
  1512   by (auto simp: tendsto_iff)
  1513 
  1514 lemma (in metric_space) tendstoD: "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1515   by (auto simp: tendsto_iff)
  1516 
  1517 lemma (in metric_space) eventually_nhds_metric:
  1518   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1519   unfolding nhds_metric
  1520   by (subst eventually_INF_base)
  1521      (auto simp: eventually_principal Bex_def subset_eq intro: exI[of _ "min a b" for a b])
  1522 
  1523 lemma eventually_at:
  1524   fixes a :: "'a :: metric_space"
  1525   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1526   unfolding eventually_at_filter eventually_nhds_metric by (auto simp: dist_nz)
  1527 
  1528 lemma eventually_at_le:
  1529   fixes a :: "'a::metric_space"
  1530   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1531   unfolding eventually_at_filter eventually_nhds_metric
  1532   apply auto
  1533   apply (rule_tac x="d / 2" in exI)
  1534   apply auto
  1535   done
  1536 
  1537 lemma metric_tendsto_imp_tendsto:
  1538   fixes a :: "'a :: metric_space" and b :: "'b :: metric_space"
  1539   assumes f: "(f ---> a) F"
  1540   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1541   shows "(g ---> b) F"
  1542 proof (rule tendstoI)
  1543   fix e :: real assume "0 < e"
  1544   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1545   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1546     using le_less_trans by (rule eventually_elim2)
  1547 qed
  1548 
  1549 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1550   unfolding filterlim_at_top
  1551   apply (intro allI)
  1552   apply (rule_tac c="nat(ceiling (Z + 1))" in eventually_sequentiallyI)
  1553   by linarith
  1554 
  1555 subsubsection {* Limits of Sequences *}
  1556 
  1557 lemma lim_sequentially: "X ----> (L::'a::metric_space) \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1558   unfolding tendsto_iff eventually_sequentially ..
  1559 
  1560 lemmas LIMSEQ_def = lim_sequentially  (*legacy binding*)
  1561 
  1562 lemma LIMSEQ_iff_nz: "X ----> (L::'a::metric_space) = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1563   unfolding lim_sequentially by (metis Suc_leD zero_less_Suc)
  1564 
  1565 lemma metric_LIMSEQ_I:
  1566   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> (L::'a::metric_space)"
  1567 by (simp add: lim_sequentially)
  1568 
  1569 lemma metric_LIMSEQ_D:
  1570   "\<lbrakk>X ----> (L::'a::metric_space); 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1571 by (simp add: lim_sequentially)
  1572 
  1573 
  1574 subsubsection {* Limits of Functions *}
  1575 
  1576 lemma LIM_def: "f -- (a::'a::metric_space) --> (L::'b::metric_space) =
  1577      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
  1578         --> dist (f x) L < r)"
  1579   unfolding tendsto_iff eventually_at by simp
  1580 
  1581 lemma metric_LIM_I:
  1582   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
  1583     \<Longrightarrow> f -- (a::'a::metric_space) --> (L::'b::metric_space)"
  1584 by (simp add: LIM_def)
  1585 
  1586 lemma metric_LIM_D:
  1587   "\<lbrakk>f -- (a::'a::metric_space) --> (L::'b::metric_space); 0 < r\<rbrakk>
  1588     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1589 by (simp add: LIM_def)
  1590 
  1591 lemma metric_LIM_imp_LIM:
  1592   assumes f: "f -- a --> (l::'a::metric_space)"
  1593   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1594   shows "g -- a --> (m::'b::metric_space)"
  1595   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1596 
  1597 lemma metric_LIM_equal2:
  1598   assumes 1: "0 < R"
  1599   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
  1600   shows "g -- a --> l \<Longrightarrow> f -- (a::'a::metric_space) --> l"
  1601 apply (rule topological_tendstoI)
  1602 apply (drule (2) topological_tendstoD)
  1603 apply (simp add: eventually_at, safe)
  1604 apply (rule_tac x="min d R" in exI, safe)
  1605 apply (simp add: 1)
  1606 apply (simp add: 2)
  1607 done
  1608 
  1609 lemma metric_LIM_compose2:
  1610   assumes f: "f -- (a::'a::metric_space) --> b"
  1611   assumes g: "g -- b --> c"
  1612   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1613   shows "(\<lambda>x. g (f x)) -- a --> c"
  1614   using inj
  1615   by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1616 
  1617 lemma metric_isCont_LIM_compose2:
  1618   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1619   assumes f [unfolded isCont_def]: "isCont f a"
  1620   assumes g: "g -- f a --> l"
  1621   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1622   shows "(\<lambda>x. g (f x)) -- a --> l"
  1623 by (rule metric_LIM_compose2 [OF f g inj])
  1624 
  1625 subsection {* Complete metric spaces *}
  1626 
  1627 subsection {* Cauchy sequences *}
  1628 
  1629 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1630   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
  1631 
  1632 subsection {* Cauchy Sequences *}
  1633 
  1634 lemma metric_CauchyI:
  1635   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1636   by (simp add: Cauchy_def)
  1637 
  1638 lemma metric_CauchyD:
  1639   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1640   by (simp add: Cauchy_def)
  1641 
  1642 lemma metric_Cauchy_iff2:
  1643   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1644 apply (simp add: Cauchy_def, auto)
  1645 apply (drule reals_Archimedean, safe)
  1646 apply (drule_tac x = n in spec, auto)
  1647 apply (rule_tac x = M in exI, auto)
  1648 apply (drule_tac x = m in spec, simp)
  1649 apply (drule_tac x = na in spec, auto)
  1650 done
  1651 
  1652 lemma Cauchy_iff2:
  1653   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1654   unfolding metric_Cauchy_iff2 dist_real_def ..
  1655 
  1656 lemma Cauchy_subseq_Cauchy:
  1657   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1658 apply (auto simp add: Cauchy_def)
  1659 apply (drule_tac x=e in spec, clarify)
  1660 apply (rule_tac x=M in exI, clarify)
  1661 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1662 done
  1663 
  1664 theorem LIMSEQ_imp_Cauchy:
  1665   assumes X: "X ----> a" shows "Cauchy X"
  1666 proof (rule metric_CauchyI)
  1667   fix e::real assume "0 < e"
  1668   hence "0 < e/2" by simp
  1669   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1670   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1671   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1672   proof (intro exI allI impI)
  1673     fix m assume "N \<le> m"
  1674     hence m: "dist (X m) a < e/2" using N by fast
  1675     fix n assume "N \<le> n"
  1676     hence n: "dist (X n) a < e/2" using N by fast
  1677     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1678       by (rule dist_triangle2)
  1679     also from m n have "\<dots> < e" by simp
  1680     finally show "dist (X m) (X n) < e" .
  1681   qed
  1682 qed
  1683 
  1684 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1685 unfolding convergent_def
  1686 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1687 
  1688 subsubsection {* Cauchy Sequences are Convergent *}
  1689 
  1690 class complete_space = metric_space +
  1691   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1692 
  1693 lemma Cauchy_convergent_iff:
  1694   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1695   shows "Cauchy X = convergent X"
  1696 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1697 
  1698 subsection {* The set of real numbers is a complete metric space *}
  1699 
  1700 text {*
  1701 Proof that Cauchy sequences converge based on the one from
  1702 @{url "http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html"}
  1703 *}
  1704 
  1705 text {*
  1706   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1707   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1708 *}
  1709 
  1710 lemma increasing_LIMSEQ:
  1711   fixes f :: "nat \<Rightarrow> real"
  1712   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  1713       and bdd: "\<And>n. f n \<le> l"
  1714       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  1715   shows "f ----> l"
  1716 proof (rule increasing_tendsto)
  1717   fix x assume "x < l"
  1718   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  1719     by auto
  1720   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
  1721     by (auto simp: field_simps)
  1722   with `e < l - x` `0 < e` have "x < f n" by simp
  1723   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  1724     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  1725 qed (insert bdd, auto)
  1726 
  1727 lemma real_Cauchy_convergent:
  1728   fixes X :: "nat \<Rightarrow> real"
  1729   assumes X: "Cauchy X"
  1730   shows "convergent X"
  1731 proof -
  1732   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1733   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
  1734 
  1735   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
  1736   fix y::real assume "y \<in> S"
  1737   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1738     by (simp add: S_def)
  1739   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1740   hence "y < X (max M N)" by simp
  1741   also have "\<dots> < x" using N by simp
  1742   finally have "y \<le> x"
  1743     by (rule order_less_imp_le) }
  1744   note bound_isUb = this
  1745 
  1746   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  1747     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  1748   hence N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  1749   have [simp]: "S \<noteq> {}"
  1750   proof (intro exI ex_in_conv[THEN iffD1])
  1751     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1752       by (simp add: abs_diff_less_iff dist_real_def)
  1753     thus "X N - 1 \<in> S" by (rule mem_S)
  1754   qed
  1755   have [simp]: "bdd_above S"
  1756   proof
  1757     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1758       by (simp add: abs_diff_less_iff dist_real_def)
  1759     thus "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  1760       by (rule bound_isUb)
  1761   qed
  1762   have "X ----> Sup S"
  1763   proof (rule metric_LIMSEQ_I)
  1764   fix r::real assume "0 < r"
  1765   hence r: "0 < r/2" by simp
  1766   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  1767     using metric_CauchyD [OF X r] by auto
  1768   hence "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  1769   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1770     by (simp only: dist_real_def abs_diff_less_iff)
  1771 
  1772   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1773   hence "X N - r/2 \<in> S" by (rule mem_S)
  1774   hence 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  1775 
  1776   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1777   from bound_isUb[OF this]
  1778   have 2: "Sup S \<le> X N + r/2"
  1779     by (intro cSup_least) simp_all
  1780 
  1781   show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  1782   proof (intro exI allI impI)
  1783     fix n assume n: "N \<le> n"
  1784     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1785     thus "dist (X n) (Sup S) < r" using 1 2
  1786       by (simp add: abs_diff_less_iff dist_real_def)
  1787   qed
  1788   qed
  1789   then show ?thesis unfolding convergent_def by auto
  1790 qed
  1791 
  1792 instance real :: complete_space
  1793   by intro_classes (rule real_Cauchy_convergent)
  1794 
  1795 class banach = real_normed_vector + complete_space
  1796 
  1797 instance real :: banach by default
  1798 
  1799 lemma tendsto_at_topI_sequentially:
  1800   fixes f :: "real \<Rightarrow> 'b::first_countable_topology"
  1801   assumes *: "\<And>X. filterlim X at_top sequentially \<Longrightarrow> (\<lambda>n. f (X n)) ----> y"
  1802   shows "(f ---> y) at_top"
  1803 proof -
  1804   from nhds_countable[of y] guess A . note A = this
  1805 
  1806   have "\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m"
  1807   proof (rule ccontr)
  1808     assume "\<not> (\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m)"
  1809     then obtain m where "\<And>k. \<exists>x\<ge>k. f x \<notin> A m"
  1810       by auto
  1811     then have "\<exists>X. \<forall>n. (f (X n) \<notin> A m) \<and> max n (X n) + 1 \<le> X (Suc n)"
  1812       by (intro dependent_nat_choice) (auto simp del: max.bounded_iff)
  1813     then obtain X where X: "\<And>n. f (X n) \<notin> A m" "\<And>n. max n (X n) + 1 \<le> X (Suc n)"
  1814       by auto
  1815     { fix n have "1 \<le> n \<longrightarrow> real n \<le> X n"
  1816         using X[of "n - 1"] by auto }
  1817     then have "filterlim X at_top sequentially"
  1818       by (force intro!: filterlim_at_top_mono[OF filterlim_real_sequentially]
  1819                 simp: eventually_sequentially)
  1820     from topological_tendstoD[OF *[OF this] A(2, 3), of m] X(1) show False
  1821       by auto
  1822   qed
  1823   then obtain k where "\<And>m x. k m \<le> x \<Longrightarrow> f x \<in> A m"
  1824     by metis
  1825   then show ?thesis
  1826     unfolding at_top_def A
  1827     by (intro filterlim_base[where i=k]) auto
  1828 qed
  1829 
  1830 lemma tendsto_at_topI_sequentially_real:
  1831   fixes f :: "real \<Rightarrow> real"
  1832   assumes mono: "mono f"
  1833   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
  1834   shows "(f ---> y) at_top"
  1835 proof (rule tendstoI)
  1836   fix e :: real assume "0 < e"
  1837   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
  1838     by (auto simp: lim_sequentially dist_real_def)
  1839   { fix x :: real
  1840     obtain n where "x \<le> real_of_nat n"
  1841       using ex_le_of_nat[of x] ..
  1842     note monoD[OF mono this]
  1843     also have "f (real_of_nat n) \<le> y"
  1844       by (rule LIMSEQ_le_const[OF limseq])
  1845          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
  1846     finally have "f x \<le> y" . }
  1847   note le = this
  1848   have "eventually (\<lambda>x. real N \<le> x) at_top"
  1849     by (rule eventually_ge_at_top)
  1850   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  1851   proof eventually_elim
  1852     fix x assume N': "real N \<le> x"
  1853     with N[of N] le have "y - f (real N) < e" by auto
  1854     moreover note monoD[OF mono N']
  1855     ultimately show "dist (f x) y < e"
  1856       using le[of x] by (auto simp: dist_real_def field_simps)
  1857   qed
  1858 qed
  1859 
  1860 end
  1861