src/HOL/Rings.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 60516 0826b7025d07
child 60529 24c2ef12318b
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)" 
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116   
   117 end  
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast 
   134 
   135 end
   136 
   137 context comm_monoid_mult
   138 begin
   139 
   140 subclass dvd .
   141 
   142 lemma dvd_refl [simp]:
   143   "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma one_dvd [simp]:
   159   "1 dvd a"
   160   by (auto intro!: dvdI)
   161 
   162 lemma dvd_mult [simp]:
   163   "a dvd c \<Longrightarrow> a dvd (b * c)"
   164   by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   165 
   166 lemma dvd_mult2 [simp]:
   167   "a dvd b \<Longrightarrow> a dvd (b * c)"
   168   using dvd_mult [of a b c] by (simp add: ac_simps) 
   169 
   170 lemma dvd_triv_right [simp]:
   171   "a dvd b * a"
   172   by (rule dvd_mult) (rule dvd_refl)
   173 
   174 lemma dvd_triv_left [simp]:
   175   "a dvd a * b"
   176   by (rule dvd_mult2) (rule dvd_refl)
   177 
   178 lemma mult_dvd_mono:
   179   assumes "a dvd b"
   180     and "c dvd d"
   181   shows "a * c dvd b * d"
   182 proof -
   183   from `a dvd b` obtain b' where "b = a * b'" ..
   184   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   185   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   186   then show ?thesis ..
   187 qed
   188 
   189 lemma dvd_mult_left:
   190   "a * b dvd c \<Longrightarrow> a dvd c"
   191   by (simp add: dvd_def mult.assoc) blast
   192 
   193 lemma dvd_mult_right:
   194   "a * b dvd c \<Longrightarrow> b dvd c"
   195   using dvd_mult_left [of b a c] by (simp add: ac_simps)
   196   
   197 end
   198 
   199 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult
   200 begin
   201 
   202 subclass semiring_1 ..
   203 
   204 lemma dvd_0_left_iff [simp]:
   205   "0 dvd a \<longleftrightarrow> a = 0"
   206   by (auto intro: dvd_refl elim!: dvdE)
   207 
   208 lemma dvd_0_right [iff]:
   209   "a dvd 0"
   210 proof
   211   show "0 = a * 0" by simp
   212 qed
   213 
   214 lemma dvd_0_left:
   215   "0 dvd a \<Longrightarrow> a = 0"
   216   by simp
   217 
   218 lemma dvd_add [simp]:
   219   assumes "a dvd b" and "a dvd c"
   220   shows "a dvd (b + c)"
   221 proof -
   222   from `a dvd b` obtain b' where "b = a * b'" ..
   223   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   224   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   225   then show ?thesis ..
   226 qed
   227 
   228 end
   229 
   230 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   231   + zero_neq_one + monoid_mult
   232 begin
   233 
   234 subclass semiring_0_cancel ..
   235 
   236 subclass semiring_1 ..
   237 
   238 end
   239 
   240 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add
   241   + zero_neq_one + comm_monoid_mult
   242 begin
   243 
   244 subclass semiring_1_cancel ..
   245 subclass comm_semiring_0_cancel ..
   246 subclass comm_semiring_1 ..
   247 
   248 end
   249 
   250 class comm_semiring_1_diff_distrib = comm_semiring_1_cancel +
   251   assumes right_diff_distrib' [algebra_simps]: "a * (b - c) = a * b - a * c"
   252 begin
   253 
   254 lemma left_diff_distrib' [algebra_simps]:
   255   "(b - c) * a = b * a - c * a"
   256   by (simp add: algebra_simps)
   257 
   258 lemma dvd_add_times_triv_left_iff [simp]:
   259   "a dvd c * a + b \<longleftrightarrow> a dvd b"
   260 proof -
   261   have "a dvd a * c + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   262   proof
   263     assume ?Q then show ?P by simp
   264   next
   265     assume ?P
   266     then obtain d where "a * c + b = a * d" ..
   267     then have "a * c + b - a * c = a * d - a * c" by simp
   268     then have "b = a * d - a * c" by simp
   269     then have "b = a * (d - c)" by (simp add: algebra_simps) 
   270     then show ?Q ..
   271   qed
   272   then show "a dvd c * a + b \<longleftrightarrow> a dvd b" by (simp add: ac_simps)
   273 qed
   274 
   275 lemma dvd_add_times_triv_right_iff [simp]:
   276   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   277   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   278 
   279 lemma dvd_add_triv_left_iff [simp]:
   280   "a dvd a + b \<longleftrightarrow> a dvd b"
   281   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   282 
   283 lemma dvd_add_triv_right_iff [simp]:
   284   "a dvd b + a \<longleftrightarrow> a dvd b"
   285   using dvd_add_times_triv_right_iff [of a b 1] by simp
   286 
   287 lemma dvd_add_right_iff:
   288   assumes "a dvd b"
   289   shows "a dvd b + c \<longleftrightarrow> a dvd c" (is "?P \<longleftrightarrow> ?Q")
   290 proof
   291   assume ?P then obtain d where "b + c = a * d" ..
   292   moreover from `a dvd b` obtain e where "b = a * e" ..
   293   ultimately have "a * e + c = a * d" by simp
   294   then have "a * e + c - a * e = a * d - a * e" by simp
   295   then have "c = a * d - a * e" by simp
   296   then have "c = a * (d - e)" by (simp add: algebra_simps)
   297   then show ?Q ..
   298 next
   299   assume ?Q with assms show ?P by simp
   300 qed
   301 
   302 lemma dvd_add_left_iff:
   303   assumes "a dvd c"
   304   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   305   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   306 
   307 end
   308 
   309 class ring = semiring + ab_group_add
   310 begin
   311 
   312 subclass semiring_0_cancel ..
   313 
   314 text {* Distribution rules *}
   315 
   316 lemma minus_mult_left: "- (a * b) = - a * b"
   317 by (rule minus_unique) (simp add: distrib_right [symmetric]) 
   318 
   319 lemma minus_mult_right: "- (a * b) = a * - b"
   320 by (rule minus_unique) (simp add: distrib_left [symmetric]) 
   321 
   322 text{*Extract signs from products*}
   323 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   324 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   325 
   326 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   327 by simp
   328 
   329 lemma minus_mult_commute: "- a * b = a * - b"
   330 by simp
   331 
   332 lemma right_diff_distrib [algebra_simps]:
   333   "a * (b - c) = a * b - a * c"
   334   using distrib_left [of a b "-c "] by simp
   335 
   336 lemma left_diff_distrib [algebra_simps]:
   337   "(a - b) * c = a * c - b * c"
   338   using distrib_right [of a "- b" c] by simp
   339 
   340 lemmas ring_distribs =
   341   distrib_left distrib_right left_diff_distrib right_diff_distrib
   342 
   343 lemma eq_add_iff1:
   344   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   345 by (simp add: algebra_simps)
   346 
   347 lemma eq_add_iff2:
   348   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   349 by (simp add: algebra_simps)
   350 
   351 end
   352 
   353 lemmas ring_distribs =
   354   distrib_left distrib_right left_diff_distrib right_diff_distrib
   355 
   356 class comm_ring = comm_semiring + ab_group_add
   357 begin
   358 
   359 subclass ring ..
   360 subclass comm_semiring_0_cancel ..
   361 
   362 lemma square_diff_square_factored:
   363   "x * x - y * y = (x + y) * (x - y)"
   364   by (simp add: algebra_simps)
   365 
   366 end
   367 
   368 class ring_1 = ring + zero_neq_one + monoid_mult
   369 begin
   370 
   371 subclass semiring_1_cancel ..
   372 
   373 lemma square_diff_one_factored:
   374   "x * x - 1 = (x + 1) * (x - 1)"
   375   by (simp add: algebra_simps)
   376 
   377 end
   378 
   379 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   380 begin
   381 
   382 subclass ring_1 ..
   383 subclass comm_semiring_1_cancel ..
   384 
   385 subclass comm_semiring_1_diff_distrib
   386   by unfold_locales (simp add: algebra_simps)
   387 
   388 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   389 proof
   390   assume "x dvd - y"
   391   then have "x dvd - 1 * - y" by (rule dvd_mult)
   392   then show "x dvd y" by simp
   393 next
   394   assume "x dvd y"
   395   then have "x dvd - 1 * y" by (rule dvd_mult)
   396   then show "x dvd - y" by simp
   397 qed
   398 
   399 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   400 proof
   401   assume "- x dvd y"
   402   then obtain k where "y = - x * k" ..
   403   then have "y = x * - k" by simp
   404   then show "x dvd y" ..
   405 next
   406   assume "x dvd y"
   407   then obtain k where "y = x * k" ..
   408   then have "y = - x * - k" by simp
   409   then show "- x dvd y" ..
   410 qed
   411 
   412 lemma dvd_diff [simp]:
   413   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   414   using dvd_add [of x y "- z"] by simp
   415 
   416 end
   417 
   418 class semiring_no_zero_divisors = semiring_0 +
   419   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   420 begin
   421 
   422 lemma divisors_zero:
   423   assumes "a * b = 0"
   424   shows "a = 0 \<or> b = 0"
   425 proof (rule classical)
   426   assume "\<not> (a = 0 \<or> b = 0)"
   427   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   428   with no_zero_divisors have "a * b \<noteq> 0" by blast
   429   with assms show ?thesis by simp
   430 qed
   431 
   432 lemma mult_eq_0_iff [simp]:
   433   shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   434 proof (cases "a = 0 \<or> b = 0")
   435   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   436     then show ?thesis using no_zero_divisors by simp
   437 next
   438   case True then show ?thesis by auto
   439 qed
   440 
   441 end
   442 
   443 class semiring_no_zero_divisors_cancel = semiring_no_zero_divisors +
   444   assumes mult_cancel_right [simp]: "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   445     and mult_cancel_left [simp]: "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   446 begin
   447 
   448 lemma mult_left_cancel:
   449   "c \<noteq> 0 \<Longrightarrow> c * a = c * b \<longleftrightarrow> a = b"
   450   by simp 
   451 
   452 lemma mult_right_cancel:
   453   "c \<noteq> 0 \<Longrightarrow> a * c = b * c \<longleftrightarrow> a = b"
   454   by simp 
   455 
   456 end
   457 
   458 class ring_no_zero_divisors = ring + semiring_no_zero_divisors
   459 begin
   460 
   461 subclass semiring_no_zero_divisors_cancel
   462 proof
   463   fix a b c
   464   have "a * c = b * c \<longleftrightarrow> (a - b) * c = 0"
   465     by (simp add: algebra_simps)
   466   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   467     by auto
   468   finally show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b" .
   469   have "c * a = c * b \<longleftrightarrow> c * (a - b) = 0"
   470     by (simp add: algebra_simps)
   471   also have "\<dots> \<longleftrightarrow> c = 0 \<or> a = b"
   472     by auto
   473   finally show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b" .
   474 qed
   475 
   476 end
   477 
   478 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   479 begin
   480 
   481 lemma square_eq_1_iff:
   482   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   483 proof -
   484   have "(x - 1) * (x + 1) = x * x - 1"
   485     by (simp add: algebra_simps)
   486   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   487     by simp
   488   thus ?thesis
   489     by (simp add: eq_neg_iff_add_eq_0)
   490 qed
   491 
   492 lemma mult_cancel_right1 [simp]:
   493   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   494 by (insert mult_cancel_right [of 1 c b], force)
   495 
   496 lemma mult_cancel_right2 [simp]:
   497   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   498 by (insert mult_cancel_right [of a c 1], simp)
   499  
   500 lemma mult_cancel_left1 [simp]:
   501   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   502 by (insert mult_cancel_left [of c 1 b], force)
   503 
   504 lemma mult_cancel_left2 [simp]:
   505   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   506 by (insert mult_cancel_left [of c a 1], simp)
   507 
   508 end
   509 
   510 class semidom = comm_semiring_1_diff_distrib + semiring_no_zero_divisors
   511 
   512 class idom = comm_ring_1 + semiring_no_zero_divisors
   513 begin
   514 
   515 subclass semidom ..
   516 
   517 subclass ring_1_no_zero_divisors ..
   518 
   519 lemma dvd_mult_cancel_right [simp]:
   520   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   521 proof -
   522   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   523     unfolding dvd_def by (simp add: ac_simps)
   524   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   525     unfolding dvd_def by simp
   526   finally show ?thesis .
   527 qed
   528 
   529 lemma dvd_mult_cancel_left [simp]:
   530   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   531 proof -
   532   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   533     unfolding dvd_def by (simp add: ac_simps)
   534   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   535     unfolding dvd_def by simp
   536   finally show ?thesis .
   537 qed
   538 
   539 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> a = b \<or> a = - b"
   540 proof
   541   assume "a * a = b * b"
   542   then have "(a - b) * (a + b) = 0"
   543     by (simp add: algebra_simps)
   544   then show "a = b \<or> a = - b"
   545     by (simp add: eq_neg_iff_add_eq_0)
   546 next
   547   assume "a = b \<or> a = - b"
   548   then show "a * a = b * b" by auto
   549 qed
   550 
   551 end
   552 
   553 text {*
   554   The theory of partially ordered rings is taken from the books:
   555   \begin{itemize}
   556   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
   557   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   558   \end{itemize}
   559   Most of the used notions can also be looked up in 
   560   \begin{itemize}
   561   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   562   \item \emph{Algebra I} by van der Waerden, Springer.
   563   \end{itemize}
   564 *}
   565 
   566 class divide =
   567   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "div" 70)
   568 
   569 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   570 
   571 context semiring
   572 begin
   573 
   574 lemma [field_simps]:
   575   shows distrib_left_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b + c) = a * b + a * c"
   576     and distrib_right_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a + b) * c = a * c + b * c"
   577   by (rule distrib_left distrib_right)+
   578 
   579 end
   580 
   581 context ring
   582 begin
   583 
   584 lemma [field_simps]:
   585   shows left_diff_distrib_NO_MATCH: "NO_MATCH (x div y) c \<Longrightarrow> (a - b) * c = a * c - b * c"
   586     and right_diff_distrib_NO_MATCH: "NO_MATCH (x div y) a \<Longrightarrow> a * (b - c) = a * b - a * c"
   587   by (rule left_diff_distrib right_diff_distrib)+
   588 
   589 end
   590 
   591 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a::divide \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   592 
   593 class semidom_divide = semidom + divide +
   594   assumes nonzero_mult_divide_cancel_right [simp]: "b \<noteq> 0 \<Longrightarrow> (a * b) div b = a"
   595   assumes divide_zero [simp]: "a div 0 = 0"
   596 begin
   597 
   598 lemma nonzero_mult_divide_cancel_left [simp]:
   599   "a \<noteq> 0 \<Longrightarrow> (a * b) div a = b"
   600   using nonzero_mult_divide_cancel_right [of a b] by (simp add: ac_simps)
   601 
   602 subclass semiring_no_zero_divisors_cancel
   603 proof
   604   fix a b c
   605   { fix a b c
   606     show "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   607     proof (cases "c = 0")
   608       case True then show ?thesis by simp
   609     next
   610       case False
   611       { assume "a * c = b * c"
   612         then have "a * c div c = b * c div c"
   613           by simp
   614         with False have "a = b"
   615           by simp
   616       } then show ?thesis by auto
   617     qed
   618   }
   619   from this [of a c b]
   620   show "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   621     by (simp add: ac_simps)
   622 qed
   623 
   624 lemma div_self [simp]:
   625   assumes "a \<noteq> 0"
   626   shows "a div a = 1"
   627   using assms nonzero_mult_divide_cancel_left [of a 1] by simp
   628 
   629 end
   630 
   631 class idom_divide = idom + semidom_divide
   632 
   633 class algebraic_semidom = semidom_divide
   634 begin
   635 
   636 lemma dvd_div_mult_self [simp]:
   637   "a dvd b \<Longrightarrow> b div a * a = b"
   638   by (cases "a = 0") (auto elim: dvdE simp add: ac_simps)
   639 
   640 lemma dvd_mult_div_cancel [simp]:
   641   "a dvd b \<Longrightarrow> a * (b div a) = b"
   642   using dvd_div_mult_self [of a b] by (simp add: ac_simps)
   643   
   644 lemma div_mult_swap:
   645   assumes "c dvd b"
   646   shows "a * (b div c) = (a * b) div c"
   647 proof (cases "c = 0")
   648   case True then show ?thesis by simp
   649 next
   650   case False from assms obtain d where "b = c * d" ..
   651   moreover from False have "a * divide (d * c) c = ((a * d) * c) div c"
   652     by simp
   653   ultimately show ?thesis by (simp add: ac_simps)
   654 qed
   655 
   656 lemma dvd_div_mult:
   657   assumes "c dvd b"
   658   shows "b div c * a = (b * a) div c"
   659   using assms div_mult_swap [of c b a] by (simp add: ac_simps)
   660 
   661   
   662 text \<open>Units: invertible elements in a ring\<close>
   663 
   664 abbreviation is_unit :: "'a \<Rightarrow> bool"
   665 where
   666   "is_unit a \<equiv> a dvd 1"
   667 
   668 lemma not_is_unit_0 [simp]:
   669   "\<not> is_unit 0"
   670   by simp
   671 
   672 lemma unit_imp_dvd [dest]: 
   673   "is_unit b \<Longrightarrow> b dvd a"
   674   by (rule dvd_trans [of _ 1]) simp_all
   675 
   676 lemma unit_dvdE:
   677   assumes "is_unit a"
   678   obtains c where "a \<noteq> 0" and "b = a * c"
   679 proof -
   680   from assms have "a dvd b" by auto
   681   then obtain c where "b = a * c" ..
   682   moreover from assms have "a \<noteq> 0" by auto
   683   ultimately show thesis using that by blast
   684 qed
   685 
   686 lemma dvd_unit_imp_unit:
   687   "a dvd b \<Longrightarrow> is_unit b \<Longrightarrow> is_unit a"
   688   by (rule dvd_trans)
   689 
   690 lemma unit_div_1_unit [simp, intro]:
   691   assumes "is_unit a"
   692   shows "is_unit (1 div a)"
   693 proof -
   694   from assms have "1 = 1 div a * a" by simp
   695   then show "is_unit (1 div a)" by (rule dvdI)
   696 qed
   697 
   698 lemma is_unitE [elim?]:
   699   assumes "is_unit a"
   700   obtains b where "a \<noteq> 0" and "b \<noteq> 0"
   701     and "is_unit b" and "1 div a = b" and "1 div b = a"
   702     and "a * b = 1" and "c div a = c * b"
   703 proof (rule that)
   704   def b \<equiv> "1 div a"
   705   then show "1 div a = b" by simp
   706   from b_def `is_unit a` show "is_unit b" by simp
   707   from `is_unit a` and `is_unit b` show "a \<noteq> 0" and "b \<noteq> 0" by auto
   708   from b_def `is_unit a` show "a * b = 1" by simp
   709   then have "1 = a * b" ..
   710   with b_def `b \<noteq> 0` show "1 div b = a" by simp
   711   from `is_unit a` have "a dvd c" ..
   712   then obtain d where "c = a * d" ..
   713   with `a \<noteq> 0` `a * b = 1` show "c div a = c * b"
   714     by (simp add: mult.assoc mult.left_commute [of a])
   715 qed
   716 
   717 lemma unit_prod [intro]:
   718   "is_unit a \<Longrightarrow> is_unit b \<Longrightarrow> is_unit (a * b)"
   719   by (subst mult_1_left [of 1, symmetric]) (rule mult_dvd_mono) 
   720   
   721 lemma unit_div [intro]:
   722   "is_unit a \<Longrightarrow> is_unit b \<Longrightarrow> is_unit (a div b)"
   723   by (erule is_unitE [of b a]) (simp add: ac_simps unit_prod)
   724 
   725 lemma mult_unit_dvd_iff:
   726   assumes "is_unit b"
   727   shows "a * b dvd c \<longleftrightarrow> a dvd c"
   728 proof
   729   assume "a * b dvd c"
   730   with assms show "a dvd c"
   731     by (simp add: dvd_mult_left)
   732 next
   733   assume "a dvd c"
   734   then obtain k where "c = a * k" ..
   735   with assms have "c = (a * b) * (1 div b * k)"
   736     by (simp add: mult_ac)
   737   then show "a * b dvd c" by (rule dvdI)
   738 qed
   739 
   740 lemma dvd_mult_unit_iff:
   741   assumes "is_unit b"
   742   shows "a dvd c * b \<longleftrightarrow> a dvd c"
   743 proof
   744   assume "a dvd c * b"
   745   with assms have "c * b dvd c * (b * (1 div b))"
   746     by (subst mult_assoc [symmetric]) simp
   747   also from `is_unit b` have "b * (1 div b) = 1" by (rule is_unitE) simp
   748   finally have "c * b dvd c" by simp
   749   with `a dvd c * b` show "a dvd c" by (rule dvd_trans)
   750 next
   751   assume "a dvd c"
   752   then show "a dvd c * b" by simp
   753 qed
   754 
   755 lemma div_unit_dvd_iff:
   756   "is_unit b \<Longrightarrow> a div b dvd c \<longleftrightarrow> a dvd c"
   757   by (erule is_unitE [of _ a]) (auto simp add: mult_unit_dvd_iff)
   758 
   759 lemma dvd_div_unit_iff:
   760   "is_unit b \<Longrightarrow> a dvd c div b \<longleftrightarrow> a dvd c"
   761   by (erule is_unitE [of _ c]) (simp add: dvd_mult_unit_iff)
   762 
   763 lemmas unit_dvd_iff = mult_unit_dvd_iff div_unit_dvd_iff
   764   dvd_mult_unit_iff dvd_div_unit_iff -- \<open>FIXME consider fact collection\<close>
   765 
   766 lemma unit_mult_div_div [simp]:
   767   "is_unit a \<Longrightarrow> b * (1 div a) = b div a"
   768   by (erule is_unitE [of _ b]) simp
   769 
   770 lemma unit_div_mult_self [simp]:
   771   "is_unit a \<Longrightarrow> b div a * a = b"
   772   by (rule dvd_div_mult_self) auto
   773 
   774 lemma unit_div_1_div_1 [simp]:
   775   "is_unit a \<Longrightarrow> 1 div (1 div a) = a"
   776   by (erule is_unitE) simp
   777 
   778 lemma unit_div_mult_swap:
   779   "is_unit c \<Longrightarrow> a * (b div c) = (a * b) div c"
   780   by (erule unit_dvdE [of _ b]) (simp add: mult.left_commute [of _ c])
   781 
   782 lemma unit_div_commute:
   783   "is_unit b \<Longrightarrow> (a div b) * c = (a * c) div b"
   784   using unit_div_mult_swap [of b c a] by (simp add: ac_simps)
   785 
   786 lemma unit_eq_div1:
   787   "is_unit b \<Longrightarrow> a div b = c \<longleftrightarrow> a = c * b"
   788   by (auto elim: is_unitE)
   789 
   790 lemma unit_eq_div2:
   791   "is_unit b \<Longrightarrow> a = c div b \<longleftrightarrow> a * b = c"
   792   using unit_eq_div1 [of b c a] by auto
   793 
   794 lemma unit_mult_left_cancel:
   795   assumes "is_unit a"
   796   shows "a * b = a * c \<longleftrightarrow> b = c" (is "?P \<longleftrightarrow> ?Q")
   797   using assms mult_cancel_left [of a b c] by auto 
   798 
   799 lemma unit_mult_right_cancel:
   800   "is_unit a \<Longrightarrow> b * a = c * a \<longleftrightarrow> b = c"
   801   using unit_mult_left_cancel [of a b c] by (auto simp add: ac_simps)
   802 
   803 lemma unit_div_cancel:
   804   assumes "is_unit a"
   805   shows "b div a = c div a \<longleftrightarrow> b = c"
   806 proof -
   807   from assms have "is_unit (1 div a)" by simp
   808   then have "b * (1 div a) = c * (1 div a) \<longleftrightarrow> b = c"
   809     by (rule unit_mult_right_cancel)
   810   with assms show ?thesis by simp
   811 qed
   812   
   813 
   814 text \<open>Associated elements in a ring – an equivalence relation induced by the quasi-order divisibility \<close>
   815 
   816 definition associated :: "'a \<Rightarrow> 'a \<Rightarrow> bool" 
   817 where
   818   "associated a b \<longleftrightarrow> a dvd b \<and> b dvd a"
   819 
   820 lemma associatedI:
   821   "a dvd b \<Longrightarrow> b dvd a \<Longrightarrow> associated a b"
   822   by (simp add: associated_def)
   823 
   824 lemma associatedD1:
   825   "associated a b \<Longrightarrow> a dvd b"
   826   by (simp add: associated_def)
   827 
   828 lemma associatedD2:
   829   "associated a b \<Longrightarrow> b dvd a"
   830   by (simp add: associated_def)
   831 
   832 lemma associated_refl [simp]:
   833   "associated a a"
   834   by (auto intro: associatedI)
   835 
   836 lemma associated_sym:
   837   "associated b a \<longleftrightarrow> associated a b"
   838   by (auto intro: associatedI dest: associatedD1 associatedD2)
   839 
   840 lemma associated_trans:
   841   "associated a b \<Longrightarrow> associated b c \<Longrightarrow> associated a c"
   842   by (auto intro: associatedI dvd_trans dest: associatedD1 associatedD2)
   843 
   844 lemma associated_0 [simp]:
   845   "associated 0 b \<longleftrightarrow> b = 0"
   846   "associated a 0 \<longleftrightarrow> a = 0"
   847   by (auto dest: associatedD1 associatedD2)
   848 
   849 lemma associated_unit:
   850   "associated a b \<Longrightarrow> is_unit a \<Longrightarrow> is_unit b"
   851   using dvd_unit_imp_unit by (auto dest!: associatedD1 associatedD2)
   852 
   853 lemma is_unit_associatedI:
   854   assumes "is_unit c" and "a = c * b"
   855   shows "associated a b"
   856 proof (rule associatedI)
   857   from `a = c * b` show "b dvd a" by auto
   858   from `is_unit c` obtain d where "c * d = 1" by (rule is_unitE)
   859   moreover from `a = c * b` have "d * a = d * (c * b)" by simp
   860   ultimately have "b = a * d" by (simp add: ac_simps)
   861   then show "a dvd b" ..
   862 qed
   863 
   864 lemma associated_is_unitE:
   865   assumes "associated a b"
   866   obtains c where "is_unit c" and "a = c * b"
   867 proof (cases "b = 0")
   868   case True with assms have "is_unit 1" and "a = 1 * b" by simp_all
   869   with that show thesis .
   870 next
   871   case False
   872   from assms have "a dvd b" and "b dvd a" by (auto dest: associatedD1 associatedD2)
   873   then obtain c d where "b = a * d" and "a = b * c" by (blast elim: dvdE)
   874   then have "a = c * b" and "(c * d) * b = 1 * b" by (simp_all add: ac_simps)
   875   with False have "c * d = 1" using mult_cancel_right [of "c * d" b 1] by simp
   876   then have "is_unit c" by auto
   877   with `a = c * b` that show thesis by blast
   878 qed
   879   
   880 lemmas unit_simps = mult_unit_dvd_iff div_unit_dvd_iff dvd_mult_unit_iff 
   881   dvd_div_unit_iff unit_div_mult_swap unit_div_commute
   882   unit_mult_left_cancel unit_mult_right_cancel unit_div_cancel 
   883   unit_eq_div1 unit_eq_div2
   884 
   885 end
   886 
   887 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   888   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   889   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   890 begin
   891 
   892 lemma mult_mono:
   893   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   894 apply (erule mult_right_mono [THEN order_trans], assumption)
   895 apply (erule mult_left_mono, assumption)
   896 done
   897 
   898 lemma mult_mono':
   899   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   900 apply (rule mult_mono)
   901 apply (fast intro: order_trans)+
   902 done
   903 
   904 end
   905 
   906 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   907 begin
   908 
   909 subclass semiring_0_cancel ..
   910 
   911 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   912 using mult_left_mono [of 0 b a] by simp
   913 
   914 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   915 using mult_left_mono [of b 0 a] by simp
   916 
   917 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   918 using mult_right_mono [of a 0 b] by simp
   919 
   920 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   921 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0" 
   922 by (drule mult_right_mono [of b 0], auto)
   923 
   924 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0" 
   925 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   926 
   927 end
   928 
   929 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   930 begin
   931 
   932 subclass ordered_cancel_semiring ..
   933 
   934 subclass ordered_comm_monoid_add ..
   935 
   936 lemma mult_left_less_imp_less:
   937   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   938 by (force simp add: mult_left_mono not_le [symmetric])
   939  
   940 lemma mult_right_less_imp_less:
   941   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   942 by (force simp add: mult_right_mono not_le [symmetric])
   943 
   944 end
   945 
   946 class linordered_semiring_1 = linordered_semiring + semiring_1
   947 begin
   948 
   949 lemma convex_bound_le:
   950   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   951   shows "u * x + v * y \<le> a"
   952 proof-
   953   from assms have "u * x + v * y \<le> u * a + v * a"
   954     by (simp add: add_mono mult_left_mono)
   955   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   956 qed
   957 
   958 end
   959 
   960 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   961   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   962   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   963 begin
   964 
   965 subclass semiring_0_cancel ..
   966 
   967 subclass linordered_semiring
   968 proof
   969   fix a b c :: 'a
   970   assume A: "a \<le> b" "0 \<le> c"
   971   from A show "c * a \<le> c * b"
   972     unfolding le_less
   973     using mult_strict_left_mono by (cases "c = 0") auto
   974   from A show "a * c \<le> b * c"
   975     unfolding le_less
   976     using mult_strict_right_mono by (cases "c = 0") auto
   977 qed
   978 
   979 lemma mult_left_le_imp_le:
   980   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   981 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   982  
   983 lemma mult_right_le_imp_le:
   984   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   985 by (force simp add: mult_strict_right_mono not_less [symmetric])
   986 
   987 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   988 using mult_strict_left_mono [of 0 b a] by simp
   989 
   990 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   991 using mult_strict_left_mono [of b 0 a] by simp
   992 
   993 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   994 using mult_strict_right_mono [of a 0 b] by simp
   995 
   996 text {* Legacy - use @{text mult_neg_pos} *}
   997 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0" 
   998 by (drule mult_strict_right_mono [of b 0], auto)
   999 
  1000 lemma zero_less_mult_pos:
  1001   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
  1002 apply (cases "b\<le>0")
  1003  apply (auto simp add: le_less not_less)
  1004 apply (drule_tac mult_pos_neg [of a b])
  1005  apply (auto dest: less_not_sym)
  1006 done
  1007 
  1008 lemma zero_less_mult_pos2:
  1009   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
  1010 apply (cases "b\<le>0")
  1011  apply (auto simp add: le_less not_less)
  1012 apply (drule_tac mult_pos_neg2 [of a b])
  1013  apply (auto dest: less_not_sym)
  1014 done
  1015 
  1016 text{*Strict monotonicity in both arguments*}
  1017 lemma mult_strict_mono:
  1018   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
  1019   shows "a * c < b * d"
  1020   using assms apply (cases "c=0")
  1021   apply (simp)
  1022   apply (erule mult_strict_right_mono [THEN less_trans])
  1023   apply (force simp add: le_less)
  1024   apply (erule mult_strict_left_mono, assumption)
  1025   done
  1026 
  1027 text{*This weaker variant has more natural premises*}
  1028 lemma mult_strict_mono':
  1029   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
  1030   shows "a * c < b * d"
  1031 by (rule mult_strict_mono) (insert assms, auto)
  1032 
  1033 lemma mult_less_le_imp_less:
  1034   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
  1035   shows "a * c < b * d"
  1036   using assms apply (subgoal_tac "a * c < b * c")
  1037   apply (erule less_le_trans)
  1038   apply (erule mult_left_mono)
  1039   apply simp
  1040   apply (erule mult_strict_right_mono)
  1041   apply assumption
  1042   done
  1043 
  1044 lemma mult_le_less_imp_less:
  1045   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
  1046   shows "a * c < b * d"
  1047   using assms apply (subgoal_tac "a * c \<le> b * c")
  1048   apply (erule le_less_trans)
  1049   apply (erule mult_strict_left_mono)
  1050   apply simp
  1051   apply (erule mult_right_mono)
  1052   apply simp
  1053   done
  1054 
  1055 end
  1056 
  1057 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
  1058 begin
  1059 
  1060 subclass linordered_semiring_1 ..
  1061 
  1062 lemma convex_bound_lt:
  1063   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
  1064   shows "u * x + v * y < a"
  1065 proof -
  1066   from assms have "u * x + v * y < u * a + v * a"
  1067     by (cases "u = 0")
  1068        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
  1069   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
  1070 qed
  1071 
  1072 end
  1073 
  1074 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add + 
  1075   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
  1076 begin
  1077 
  1078 subclass ordered_semiring
  1079 proof
  1080   fix a b c :: 'a
  1081   assume "a \<le> b" "0 \<le> c"
  1082   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
  1083   thus "a * c \<le> b * c" by (simp only: mult.commute)
  1084 qed
  1085 
  1086 end
  1087 
  1088 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
  1089 begin
  1090 
  1091 subclass comm_semiring_0_cancel ..
  1092 subclass ordered_comm_semiring ..
  1093 subclass ordered_cancel_semiring ..
  1094 
  1095 end
  1096 
  1097 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
  1098   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
  1099 begin
  1100 
  1101 subclass linordered_semiring_strict
  1102 proof
  1103   fix a b c :: 'a
  1104   assume "a < b" "0 < c"
  1105   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
  1106   thus "a * c < b * c" by (simp only: mult.commute)
  1107 qed
  1108 
  1109 subclass ordered_cancel_comm_semiring
  1110 proof
  1111   fix a b c :: 'a
  1112   assume "a \<le> b" "0 \<le> c"
  1113   thus "c * a \<le> c * b"
  1114     unfolding le_less
  1115     using mult_strict_left_mono by (cases "c = 0") auto
  1116 qed
  1117 
  1118 end
  1119 
  1120 class ordered_ring = ring + ordered_cancel_semiring 
  1121 begin
  1122 
  1123 subclass ordered_ab_group_add ..
  1124 
  1125 lemma less_add_iff1:
  1126   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
  1127 by (simp add: algebra_simps)
  1128 
  1129 lemma less_add_iff2:
  1130   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
  1131 by (simp add: algebra_simps)
  1132 
  1133 lemma le_add_iff1:
  1134   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
  1135 by (simp add: algebra_simps)
  1136 
  1137 lemma le_add_iff2:
  1138   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
  1139 by (simp add: algebra_simps)
  1140 
  1141 lemma mult_left_mono_neg:
  1142   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
  1143   apply (drule mult_left_mono [of _ _ "- c"])
  1144   apply simp_all
  1145   done
  1146 
  1147 lemma mult_right_mono_neg:
  1148   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
  1149   apply (drule mult_right_mono [of _ _ "- c"])
  1150   apply simp_all
  1151   done
  1152 
  1153 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
  1154 using mult_right_mono_neg [of a 0 b] by simp
  1155 
  1156 lemma split_mult_pos_le:
  1157   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
  1158 by (auto simp add: mult_nonpos_nonpos)
  1159 
  1160 end
  1161 
  1162 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
  1163 begin
  1164 
  1165 subclass ordered_ring ..
  1166 
  1167 subclass ordered_ab_group_add_abs
  1168 proof
  1169   fix a b
  1170   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
  1171     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
  1172 qed (auto simp add: abs_if)
  1173 
  1174 lemma zero_le_square [simp]: "0 \<le> a * a"
  1175   using linear [of 0 a]
  1176   by (auto simp add: mult_nonpos_nonpos)
  1177 
  1178 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
  1179   by (simp add: not_less)
  1180 
  1181 end
  1182 
  1183 class linordered_ring_strict = ring + linordered_semiring_strict
  1184   + ordered_ab_group_add + abs_if
  1185 begin
  1186 
  1187 subclass linordered_ring ..
  1188 
  1189 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
  1190 using mult_strict_left_mono [of b a "- c"] by simp
  1191 
  1192 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
  1193 using mult_strict_right_mono [of b a "- c"] by simp
  1194 
  1195 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
  1196 using mult_strict_right_mono_neg [of a 0 b] by simp
  1197 
  1198 subclass ring_no_zero_divisors
  1199 proof
  1200   fix a b
  1201   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
  1202   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
  1203   have "a * b < 0 \<or> 0 < a * b"
  1204   proof (cases "a < 0")
  1205     case True note A' = this
  1206     show ?thesis proof (cases "b < 0")
  1207       case True with A'
  1208       show ?thesis by (auto dest: mult_neg_neg)
  1209     next
  1210       case False with B have "0 < b" by auto
  1211       with A' show ?thesis by (auto dest: mult_strict_right_mono)
  1212     qed
  1213   next
  1214     case False with A have A': "0 < a" by auto
  1215     show ?thesis proof (cases "b < 0")
  1216       case True with A'
  1217       show ?thesis by (auto dest: mult_strict_right_mono_neg)
  1218     next
  1219       case False with B have "0 < b" by auto
  1220       with A' show ?thesis by auto
  1221     qed
  1222   qed
  1223   then show "a * b \<noteq> 0" by (simp add: neq_iff)
  1224 qed
  1225 
  1226 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
  1227   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
  1228      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
  1229 
  1230 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
  1231   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
  1232 
  1233 lemma mult_less_0_iff:
  1234   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
  1235   apply (insert zero_less_mult_iff [of "-a" b])
  1236   apply force
  1237   done
  1238 
  1239 lemma mult_le_0_iff:
  1240   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
  1241   apply (insert zero_le_mult_iff [of "-a" b]) 
  1242   apply force
  1243   done
  1244 
  1245 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
  1246    also with the relations @{text "\<le>"} and equality.*}
  1247 
  1248 text{*These ``disjunction'' versions produce two cases when the comparison is
  1249  an assumption, but effectively four when the comparison is a goal.*}
  1250 
  1251 lemma mult_less_cancel_right_disj:
  1252   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
  1253   apply (cases "c = 0")
  1254   apply (auto simp add: neq_iff mult_strict_right_mono 
  1255                       mult_strict_right_mono_neg)
  1256   apply (auto simp add: not_less 
  1257                       not_le [symmetric, of "a*c"]
  1258                       not_le [symmetric, of a])
  1259   apply (erule_tac [!] notE)
  1260   apply (auto simp add: less_imp_le mult_right_mono 
  1261                       mult_right_mono_neg)
  1262   done
  1263 
  1264 lemma mult_less_cancel_left_disj:
  1265   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
  1266   apply (cases "c = 0")
  1267   apply (auto simp add: neq_iff mult_strict_left_mono 
  1268                       mult_strict_left_mono_neg)
  1269   apply (auto simp add: not_less 
  1270                       not_le [symmetric, of "c*a"]
  1271                       not_le [symmetric, of a])
  1272   apply (erule_tac [!] notE)
  1273   apply (auto simp add: less_imp_le mult_left_mono 
  1274                       mult_left_mono_neg)
  1275   done
  1276 
  1277 text{*The ``conjunction of implication'' lemmas produce two cases when the
  1278 comparison is a goal, but give four when the comparison is an assumption.*}
  1279 
  1280 lemma mult_less_cancel_right:
  1281   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1282   using mult_less_cancel_right_disj [of a c b] by auto
  1283 
  1284 lemma mult_less_cancel_left:
  1285   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
  1286   using mult_less_cancel_left_disj [of c a b] by auto
  1287 
  1288 lemma mult_le_cancel_right:
  1289    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1290 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
  1291 
  1292 lemma mult_le_cancel_left:
  1293   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
  1294 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
  1295 
  1296 lemma mult_le_cancel_left_pos:
  1297   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
  1298 by (auto simp: mult_le_cancel_left)
  1299 
  1300 lemma mult_le_cancel_left_neg:
  1301   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
  1302 by (auto simp: mult_le_cancel_left)
  1303 
  1304 lemma mult_less_cancel_left_pos:
  1305   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
  1306 by (auto simp: mult_less_cancel_left)
  1307 
  1308 lemma mult_less_cancel_left_neg:
  1309   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
  1310 by (auto simp: mult_less_cancel_left)
  1311 
  1312 end
  1313 
  1314 lemmas mult_sign_intros =
  1315   mult_nonneg_nonneg mult_nonneg_nonpos
  1316   mult_nonpos_nonneg mult_nonpos_nonpos
  1317   mult_pos_pos mult_pos_neg
  1318   mult_neg_pos mult_neg_neg
  1319 
  1320 class ordered_comm_ring = comm_ring + ordered_comm_semiring
  1321 begin
  1322 
  1323 subclass ordered_ring ..
  1324 subclass ordered_cancel_comm_semiring ..
  1325 
  1326 end
  1327 
  1328 class linordered_semidom = semidom + linordered_comm_semiring_strict +
  1329   assumes zero_less_one [simp]: "0 < 1"
  1330 begin
  1331 
  1332 lemma pos_add_strict:
  1333   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1334   using add_strict_mono [of 0 a b c] by simp
  1335 
  1336 lemma zero_le_one [simp]: "0 \<le> 1"
  1337 by (rule zero_less_one [THEN less_imp_le]) 
  1338 
  1339 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1340 by (simp add: not_le) 
  1341 
  1342 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1343 by (simp add: not_less) 
  1344 
  1345 lemma less_1_mult:
  1346   assumes "1 < m" and "1 < n"
  1347   shows "1 < m * n"
  1348   using assms mult_strict_mono [of 1 m 1 n]
  1349     by (simp add:  less_trans [OF zero_less_one]) 
  1350 
  1351 lemma mult_left_le: "c \<le> 1 \<Longrightarrow> 0 \<le> a \<Longrightarrow> a * c \<le> a"
  1352   using mult_left_mono[of c 1 a] by simp
  1353 
  1354 lemma mult_le_one: "a \<le> 1 \<Longrightarrow> 0 \<le> b \<Longrightarrow> b \<le> 1 \<Longrightarrow> a * b \<le> 1"
  1355   using mult_mono[of a 1 b 1] by simp
  1356 
  1357 end
  1358 
  1359 class linordered_idom = comm_ring_1 +
  1360   linordered_comm_semiring_strict + ordered_ab_group_add +
  1361   abs_if + sgn_if
  1362 begin
  1363 
  1364 subclass linordered_semiring_1_strict ..
  1365 subclass linordered_ring_strict ..
  1366 subclass ordered_comm_ring ..
  1367 subclass idom ..
  1368 
  1369 subclass linordered_semidom
  1370 proof
  1371   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1372   thus "0 < 1" by (simp add: le_less)
  1373 qed 
  1374 
  1375 lemma linorder_neqE_linordered_idom:
  1376   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1377   using assms by (rule neqE)
  1378 
  1379 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1380 
  1381 lemma mult_le_cancel_right1:
  1382   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1383 by (insert mult_le_cancel_right [of 1 c b], simp)
  1384 
  1385 lemma mult_le_cancel_right2:
  1386   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1387 by (insert mult_le_cancel_right [of a c 1], simp)
  1388 
  1389 lemma mult_le_cancel_left1:
  1390   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1391 by (insert mult_le_cancel_left [of c 1 b], simp)
  1392 
  1393 lemma mult_le_cancel_left2:
  1394   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1395 by (insert mult_le_cancel_left [of c a 1], simp)
  1396 
  1397 lemma mult_less_cancel_right1:
  1398   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1399 by (insert mult_less_cancel_right [of 1 c b], simp)
  1400 
  1401 lemma mult_less_cancel_right2:
  1402   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1403 by (insert mult_less_cancel_right [of a c 1], simp)
  1404 
  1405 lemma mult_less_cancel_left1:
  1406   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1407 by (insert mult_less_cancel_left [of c 1 b], simp)
  1408 
  1409 lemma mult_less_cancel_left2:
  1410   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1411 by (insert mult_less_cancel_left [of c a 1], simp)
  1412 
  1413 lemma sgn_sgn [simp]:
  1414   "sgn (sgn a) = sgn a"
  1415 unfolding sgn_if by simp
  1416 
  1417 lemma sgn_0_0:
  1418   "sgn a = 0 \<longleftrightarrow> a = 0"
  1419 unfolding sgn_if by simp
  1420 
  1421 lemma sgn_1_pos:
  1422   "sgn a = 1 \<longleftrightarrow> a > 0"
  1423 unfolding sgn_if by simp
  1424 
  1425 lemma sgn_1_neg:
  1426   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1427 unfolding sgn_if by auto
  1428 
  1429 lemma sgn_pos [simp]:
  1430   "0 < a \<Longrightarrow> sgn a = 1"
  1431 unfolding sgn_1_pos .
  1432 
  1433 lemma sgn_neg [simp]:
  1434   "a < 0 \<Longrightarrow> sgn a = - 1"
  1435 unfolding sgn_1_neg .
  1436 
  1437 lemma sgn_times:
  1438   "sgn (a * b) = sgn a * sgn b"
  1439 by (auto simp add: sgn_if zero_less_mult_iff)
  1440 
  1441 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1442 unfolding sgn_if abs_if by auto
  1443 
  1444 lemma sgn_greater [simp]:
  1445   "0 < sgn a \<longleftrightarrow> 0 < a"
  1446   unfolding sgn_if by auto
  1447 
  1448 lemma sgn_less [simp]:
  1449   "sgn a < 0 \<longleftrightarrow> a < 0"
  1450   unfolding sgn_if by auto
  1451 
  1452 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1453   by (simp add: abs_if)
  1454 
  1455 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1456   by (simp add: abs_if)
  1457 
  1458 lemma dvd_if_abs_eq:
  1459   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1460 by(subst abs_dvd_iff[symmetric]) simp
  1461 
  1462 text {* The following lemmas can be proven in more general structures, but
  1463 are dangerous as simp rules in absence of @{thm neg_equal_zero}, 
  1464 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1465 
  1466 lemma equation_minus_iff_1 [simp, no_atp]:
  1467   "1 = - a \<longleftrightarrow> a = - 1"
  1468   by (fact equation_minus_iff)
  1469 
  1470 lemma minus_equation_iff_1 [simp, no_atp]:
  1471   "- a = 1 \<longleftrightarrow> a = - 1"
  1472   by (subst minus_equation_iff, auto)
  1473 
  1474 lemma le_minus_iff_1 [simp, no_atp]:
  1475   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1476   by (fact le_minus_iff)
  1477 
  1478 lemma minus_le_iff_1 [simp, no_atp]:
  1479   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1480   by (fact minus_le_iff)
  1481 
  1482 lemma less_minus_iff_1 [simp, no_atp]:
  1483   "1 < - b \<longleftrightarrow> b < - 1"
  1484   by (fact less_minus_iff)
  1485 
  1486 lemma minus_less_iff_1 [simp, no_atp]:
  1487   "- a < 1 \<longleftrightarrow> - 1 < a"
  1488   by (fact minus_less_iff)
  1489 
  1490 end
  1491 
  1492 text {* Simprules for comparisons where common factors can be cancelled. *}
  1493 
  1494 lemmas mult_compare_simps =
  1495     mult_le_cancel_right mult_le_cancel_left
  1496     mult_le_cancel_right1 mult_le_cancel_right2
  1497     mult_le_cancel_left1 mult_le_cancel_left2
  1498     mult_less_cancel_right mult_less_cancel_left
  1499     mult_less_cancel_right1 mult_less_cancel_right2
  1500     mult_less_cancel_left1 mult_less_cancel_left2
  1501     mult_cancel_right mult_cancel_left
  1502     mult_cancel_right1 mult_cancel_right2
  1503     mult_cancel_left1 mult_cancel_left2
  1504 
  1505 text {* Reasoning about inequalities with division *}
  1506 
  1507 context linordered_semidom
  1508 begin
  1509 
  1510 lemma less_add_one: "a < a + 1"
  1511 proof -
  1512   have "a + 0 < a + 1"
  1513     by (blast intro: zero_less_one add_strict_left_mono)
  1514   thus ?thesis by simp
  1515 qed
  1516 
  1517 lemma zero_less_two: "0 < 1 + 1"
  1518 by (blast intro: less_trans zero_less_one less_add_one)
  1519 
  1520 end
  1521 
  1522 context linordered_idom
  1523 begin
  1524 
  1525 lemma mult_right_le_one_le:
  1526   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1527   by (rule mult_left_le)
  1528 
  1529 lemma mult_left_le_one_le:
  1530   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1531   by (auto simp add: mult_le_cancel_right2)
  1532 
  1533 end
  1534 
  1535 text {* Absolute Value *}
  1536 
  1537 context linordered_idom
  1538 begin
  1539 
  1540 lemma mult_sgn_abs:
  1541   "sgn x * \<bar>x\<bar> = x"
  1542   unfolding abs_if sgn_if by auto
  1543 
  1544 lemma abs_one [simp]:
  1545   "\<bar>1\<bar> = 1"
  1546   by (simp add: abs_if)
  1547 
  1548 end
  1549 
  1550 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1551   assumes abs_eq_mult:
  1552     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1553 
  1554 context linordered_idom
  1555 begin
  1556 
  1557 subclass ordered_ring_abs proof
  1558 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1559 
  1560 lemma abs_mult:
  1561   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>" 
  1562   by (rule abs_eq_mult) auto
  1563 
  1564 lemma abs_mult_self:
  1565   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1566   by (simp add: abs_if) 
  1567 
  1568 lemma abs_mult_less:
  1569   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1570 proof -
  1571   assume ac: "\<bar>a\<bar> < c"
  1572   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1573   assume "\<bar>b\<bar> < d"
  1574   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1575 qed
  1576 
  1577 lemma abs_less_iff:
  1578   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b" 
  1579   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1580 
  1581 lemma abs_mult_pos:
  1582   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1583   by (simp add: abs_mult)
  1584 
  1585 lemma abs_diff_less_iff:
  1586   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1587   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1588 
  1589 lemma abs_diff_le_iff:
  1590    "\<bar>x - a\<bar> \<le> r \<longleftrightarrow> a - r \<le> x \<and> x \<le> a + r"
  1591   by (auto simp add: diff_le_eq ac_simps abs_le_iff)
  1592 
  1593 end
  1594 
  1595 hide_fact (open) comm_mult_left_mono comm_mult_strict_left_mono distrib
  1596 
  1597 code_identifier
  1598   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1599 
  1600 end