src/HOL/Set_Interval.thy
author haftmann
Fri Jun 19 07:53:35 2015 +0200 (2015-06-19)
changeset 60517 f16e4fb20652
parent 60162 645058aa9d6f
child 60586 1d31e3a50373
permissions -rw-r--r--
separate class for notions specific for integral (semi)domains, in contrast to fields where these are trivial
     1 (*  Title:      HOL/Set_Interval.thy
     2     Author:     Tobias Nipkow
     3     Author:     Clemens Ballarin
     4     Author:     Jeremy Avigad
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 
     8 Modern convention: Ixy stands for an interval where x and y
     9 describe the lower and upper bound and x,y : {c,o,i}
    10 where c = closed, o = open, i = infinite.
    11 Examples: Ico = {_ ..< _} and Ici = {_ ..}
    12 *)
    13 
    14 section {* Set intervals *}
    15 
    16 theory Set_Interval
    17 imports Lattices_Big Nat_Transfer
    18 begin
    19 
    20 context ord
    21 begin
    22 
    23 definition
    24   lessThan    :: "'a => 'a set" ("(1{..<_})") where
    25   "{..<u} == {x. x < u}"
    26 
    27 definition
    28   atMost      :: "'a => 'a set" ("(1{.._})") where
    29   "{..u} == {x. x \<le> u}"
    30 
    31 definition
    32   greaterThan :: "'a => 'a set" ("(1{_<..})") where
    33   "{l<..} == {x. l<x}"
    34 
    35 definition
    36   atLeast     :: "'a => 'a set" ("(1{_..})") where
    37   "{l..} == {x. l\<le>x}"
    38 
    39 definition
    40   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    41   "{l<..<u} == {l<..} Int {..<u}"
    42 
    43 definition
    44   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    45   "{l..<u} == {l..} Int {..<u}"
    46 
    47 definition
    48   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    49   "{l<..u} == {l<..} Int {..u}"
    50 
    51 definition
    52   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    53   "{l..u} == {l..} Int {..u}"
    54 
    55 end
    56 
    57 
    58 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    59 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    60 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    61 
    62 syntax
    63   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" [0, 0, 10] 10)
    64   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" [0, 0, 10] 10)
    65   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" [0, 0, 10] 10)
    66   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (xsymbols)
    69   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" [0, 0, 10] 10)
    70   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" [0, 0, 10] 10)
    71   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" [0, 0, 10] 10)
    72   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" [0, 0, 10] 10)
    73 
    74 syntax (latex output)
    75   "_UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    76   "_UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" [0, 0, 10] 10)
    77   "_INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    78   "_INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" [0, 0, 10] 10)
    79 
    80 translations
    81   "UN i<=n. A"  == "UN i:{..n}. A"
    82   "UN i<n. A"   == "UN i:{..<n}. A"
    83   "INT i<=n. A" == "INT i:{..n}. A"
    84   "INT i<n. A"  == "INT i:{..<n}. A"
    85 
    86 
    87 subsection {* Various equivalences *}
    88 
    89 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    90 by (simp add: lessThan_def)
    91 
    92 lemma Compl_lessThan [simp]:
    93     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    94 apply (auto simp add: lessThan_def atLeast_def)
    95 done
    96 
    97 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    98 by auto
    99 
   100 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
   101 by (simp add: greaterThan_def)
   102 
   103 lemma Compl_greaterThan [simp]:
   104     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   105   by (auto simp add: greaterThan_def atMost_def)
   106 
   107 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   108 apply (subst Compl_greaterThan [symmetric])
   109 apply (rule double_complement)
   110 done
   111 
   112 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   113 by (simp add: atLeast_def)
   114 
   115 lemma Compl_atLeast [simp]:
   116     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   117   by (auto simp add: lessThan_def atLeast_def)
   118 
   119 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   120 by (simp add: atMost_def)
   121 
   122 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   123 by (blast intro: order_antisym)
   124 
   125 lemma (in linorder) lessThan_Int_lessThan: "{ a <..} \<inter> { b <..} = { max a b <..}"
   126   by auto
   127 
   128 lemma (in linorder) greaterThan_Int_greaterThan: "{..< a} \<inter> {..< b} = {..< min a b}"
   129   by auto
   130 
   131 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   132 
   133 lemma atLeast_subset_iff [iff]:
   134      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   135 by (blast intro: order_trans)
   136 
   137 lemma atLeast_eq_iff [iff]:
   138      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   139 by (blast intro: order_antisym order_trans)
   140 
   141 lemma greaterThan_subset_iff [iff]:
   142      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   143 apply (auto simp add: greaterThan_def)
   144  apply (subst linorder_not_less [symmetric], blast)
   145 done
   146 
   147 lemma greaterThan_eq_iff [iff]:
   148      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   149 apply (rule iffI)
   150  apply (erule equalityE)
   151  apply simp_all
   152 done
   153 
   154 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   155 by (blast intro: order_trans)
   156 
   157 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   158 by (blast intro: order_antisym order_trans)
   159 
   160 lemma lessThan_subset_iff [iff]:
   161      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   162 apply (auto simp add: lessThan_def)
   163  apply (subst linorder_not_less [symmetric], blast)
   164 done
   165 
   166 lemma lessThan_eq_iff [iff]:
   167      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   168 apply (rule iffI)
   169  apply (erule equalityE)
   170  apply simp_all
   171 done
   172 
   173 lemma lessThan_strict_subset_iff:
   174   fixes m n :: "'a::linorder"
   175   shows "{..<m} < {..<n} \<longleftrightarrow> m < n"
   176   by (metis leD lessThan_subset_iff linorder_linear not_less_iff_gr_or_eq psubset_eq)
   177 
   178 lemma (in linorder) Ici_subset_Ioi_iff: "{a ..} \<subseteq> {b <..} \<longleftrightarrow> b < a"
   179   by auto
   180 
   181 lemma (in linorder) Iic_subset_Iio_iff: "{.. a} \<subseteq> {..< b} \<longleftrightarrow> a < b"
   182   by auto
   183 
   184 subsection {*Two-sided intervals*}
   185 
   186 context ord
   187 begin
   188 
   189 lemma greaterThanLessThan_iff [simp]:
   190   "(i : {l<..<u}) = (l < i & i < u)"
   191 by (simp add: greaterThanLessThan_def)
   192 
   193 lemma atLeastLessThan_iff [simp]:
   194   "(i : {l..<u}) = (l <= i & i < u)"
   195 by (simp add: atLeastLessThan_def)
   196 
   197 lemma greaterThanAtMost_iff [simp]:
   198   "(i : {l<..u}) = (l < i & i <= u)"
   199 by (simp add: greaterThanAtMost_def)
   200 
   201 lemma atLeastAtMost_iff [simp]:
   202   "(i : {l..u}) = (l <= i & i <= u)"
   203 by (simp add: atLeastAtMost_def)
   204 
   205 text {* The above four lemmas could be declared as iffs. Unfortunately this
   206 breaks many proofs. Since it only helps blast, it is better to leave them
   207 alone. *}
   208 
   209 lemma greaterThanLessThan_eq: "{ a <..< b} = { a <..} \<inter> {..< b }"
   210   by auto
   211 
   212 end
   213 
   214 subsubsection{* Emptyness, singletons, subset *}
   215 
   216 context order
   217 begin
   218 
   219 lemma atLeastatMost_empty[simp]:
   220   "b < a \<Longrightarrow> {a..b} = {}"
   221 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   222 
   223 lemma atLeastatMost_empty_iff[simp]:
   224   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   225 by auto (blast intro: order_trans)
   226 
   227 lemma atLeastatMost_empty_iff2[simp]:
   228   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   229 by auto (blast intro: order_trans)
   230 
   231 lemma atLeastLessThan_empty[simp]:
   232   "b <= a \<Longrightarrow> {a..<b} = {}"
   233 by(auto simp: atLeastLessThan_def)
   234 
   235 lemma atLeastLessThan_empty_iff[simp]:
   236   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   237 by auto (blast intro: le_less_trans)
   238 
   239 lemma atLeastLessThan_empty_iff2[simp]:
   240   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   241 by auto (blast intro: le_less_trans)
   242 
   243 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   244 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   245 
   246 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   247 by auto (blast intro: less_le_trans)
   248 
   249 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   250 by auto (blast intro: less_le_trans)
   251 
   252 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   253 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   254 
   255 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   256 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   257 
   258 lemma atLeastAtMost_singleton': "a = b \<Longrightarrow> {a .. b} = {a}" by simp
   259 
   260 lemma atLeastatMost_subset_iff[simp]:
   261   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   262 unfolding atLeastAtMost_def atLeast_def atMost_def
   263 by (blast intro: order_trans)
   264 
   265 lemma atLeastatMost_psubset_iff:
   266   "{a..b} < {c..d} \<longleftrightarrow>
   267    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   268 by(simp add: psubset_eq set_eq_iff less_le_not_le)(blast intro: order_trans)
   269 
   270 lemma Icc_eq_Icc[simp]:
   271   "{l..h} = {l'..h'} = (l=l' \<and> h=h' \<or> \<not> l\<le>h \<and> \<not> l'\<le>h')"
   272 by(simp add: order_class.eq_iff)(auto intro: order_trans)
   273 
   274 lemma atLeastAtMost_singleton_iff[simp]:
   275   "{a .. b} = {c} \<longleftrightarrow> a = b \<and> b = c"
   276 proof
   277   assume "{a..b} = {c}"
   278   hence *: "\<not> (\<not> a \<le> b)" unfolding atLeastatMost_empty_iff[symmetric] by simp
   279   with `{a..b} = {c}` have "c \<le> a \<and> b \<le> c" by auto
   280   with * show "a = b \<and> b = c" by auto
   281 qed simp
   282 
   283 lemma Icc_subset_Ici_iff[simp]:
   284   "{l..h} \<subseteq> {l'..} = (~ l\<le>h \<or> l\<ge>l')"
   285 by(auto simp: subset_eq intro: order_trans)
   286 
   287 lemma Icc_subset_Iic_iff[simp]:
   288   "{l..h} \<subseteq> {..h'} = (~ l\<le>h \<or> h\<le>h')"
   289 by(auto simp: subset_eq intro: order_trans)
   290 
   291 lemma not_Ici_eq_empty[simp]: "{l..} \<noteq> {}"
   292 by(auto simp: set_eq_iff)
   293 
   294 lemma not_Iic_eq_empty[simp]: "{..h} \<noteq> {}"
   295 by(auto simp: set_eq_iff)
   296 
   297 lemmas not_empty_eq_Ici_eq_empty[simp] = not_Ici_eq_empty[symmetric]
   298 lemmas not_empty_eq_Iic_eq_empty[simp] = not_Iic_eq_empty[symmetric]
   299 
   300 end
   301 
   302 context no_top
   303 begin
   304 
   305 (* also holds for no_bot but no_top should suffice *)
   306 lemma not_UNIV_le_Icc[simp]: "\<not> UNIV \<subseteq> {l..h}"
   307 using gt_ex[of h] by(auto simp: subset_eq less_le_not_le)
   308 
   309 lemma not_UNIV_le_Iic[simp]: "\<not> UNIV \<subseteq> {..h}"
   310 using gt_ex[of h] by(auto simp: subset_eq less_le_not_le)
   311 
   312 lemma not_Ici_le_Icc[simp]: "\<not> {l..} \<subseteq> {l'..h'}"
   313 using gt_ex[of h']
   314 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   315 
   316 lemma not_Ici_le_Iic[simp]: "\<not> {l..} \<subseteq> {..h'}"
   317 using gt_ex[of h']
   318 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   319 
   320 end
   321 
   322 context no_bot
   323 begin
   324 
   325 lemma not_UNIV_le_Ici[simp]: "\<not> UNIV \<subseteq> {l..}"
   326 using lt_ex[of l] by(auto simp: subset_eq less_le_not_le)
   327 
   328 lemma not_Iic_le_Icc[simp]: "\<not> {..h} \<subseteq> {l'..h'}"
   329 using lt_ex[of l']
   330 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   331 
   332 lemma not_Iic_le_Ici[simp]: "\<not> {..h} \<subseteq> {l'..}"
   333 using lt_ex[of l']
   334 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   335 
   336 end
   337 
   338 
   339 context no_top
   340 begin
   341 
   342 (* also holds for no_bot but no_top should suffice *)
   343 lemma not_UNIV_eq_Icc[simp]: "\<not> UNIV = {l'..h'}"
   344 using gt_ex[of h'] by(auto simp: set_eq_iff  less_le_not_le)
   345 
   346 lemmas not_Icc_eq_UNIV[simp] = not_UNIV_eq_Icc[symmetric]
   347 
   348 lemma not_UNIV_eq_Iic[simp]: "\<not> UNIV = {..h'}"
   349 using gt_ex[of h'] by(auto simp: set_eq_iff  less_le_not_le)
   350 
   351 lemmas not_Iic_eq_UNIV[simp] = not_UNIV_eq_Iic[symmetric]
   352 
   353 lemma not_Icc_eq_Ici[simp]: "\<not> {l..h} = {l'..}"
   354 unfolding atLeastAtMost_def using not_Ici_le_Iic[of l'] by blast
   355 
   356 lemmas not_Ici_eq_Icc[simp] = not_Icc_eq_Ici[symmetric]
   357 
   358 (* also holds for no_bot but no_top should suffice *)
   359 lemma not_Iic_eq_Ici[simp]: "\<not> {..h} = {l'..}"
   360 using not_Ici_le_Iic[of l' h] by blast
   361 
   362 lemmas not_Ici_eq_Iic[simp] = not_Iic_eq_Ici[symmetric]
   363 
   364 end
   365 
   366 context no_bot
   367 begin
   368 
   369 lemma not_UNIV_eq_Ici[simp]: "\<not> UNIV = {l'..}"
   370 using lt_ex[of l'] by(auto simp: set_eq_iff  less_le_not_le)
   371 
   372 lemmas not_Ici_eq_UNIV[simp] = not_UNIV_eq_Ici[symmetric]
   373 
   374 lemma not_Icc_eq_Iic[simp]: "\<not> {l..h} = {..h'}"
   375 unfolding atLeastAtMost_def using not_Iic_le_Ici[of h'] by blast
   376 
   377 lemmas not_Iic_eq_Icc[simp] = not_Icc_eq_Iic[symmetric]
   378 
   379 end
   380 
   381 
   382 context dense_linorder
   383 begin
   384 
   385 lemma greaterThanLessThan_empty_iff[simp]:
   386   "{ a <..< b } = {} \<longleftrightarrow> b \<le> a"
   387   using dense[of a b] by (cases "a < b") auto
   388 
   389 lemma greaterThanLessThan_empty_iff2[simp]:
   390   "{} = { a <..< b } \<longleftrightarrow> b \<le> a"
   391   using dense[of a b] by (cases "a < b") auto
   392 
   393 lemma atLeastLessThan_subseteq_atLeastAtMost_iff:
   394   "{a ..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   395   using dense[of "max a d" "b"]
   396   by (force simp: subset_eq Ball_def not_less[symmetric])
   397 
   398 lemma greaterThanAtMost_subseteq_atLeastAtMost_iff:
   399   "{a <.. b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   400   using dense[of "a" "min c b"]
   401   by (force simp: subset_eq Ball_def not_less[symmetric])
   402 
   403 lemma greaterThanLessThan_subseteq_atLeastAtMost_iff:
   404   "{a <..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   405   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   406   by (force simp: subset_eq Ball_def not_less[symmetric])
   407 
   408 lemma atLeastAtMost_subseteq_atLeastLessThan_iff:
   409   "{a .. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a \<le> b \<longrightarrow> c \<le> a \<and> b < d)"
   410   using dense[of "max a d" "b"]
   411   by (force simp: subset_eq Ball_def not_less[symmetric])
   412 
   413 lemma greaterThanAtMost_subseteq_atLeastLessThan_iff:
   414   "{a <.. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b < d)"
   415   using dense[of "a" "min c b"]
   416   by (force simp: subset_eq Ball_def not_less[symmetric])
   417 
   418 lemma greaterThanLessThan_subseteq_atLeastLessThan_iff:
   419   "{a <..< b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   420   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   421   by (force simp: subset_eq Ball_def not_less[symmetric])
   422 
   423 lemma greaterThanLessThan_subseteq_greaterThanAtMost_iff:
   424   "{a <..< b} \<subseteq> { c <.. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   425   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   426   by (force simp: subset_eq Ball_def not_less[symmetric])
   427 
   428 end
   429 
   430 context no_top
   431 begin
   432 
   433 lemma greaterThan_non_empty[simp]: "{x <..} \<noteq> {}"
   434   using gt_ex[of x] by auto
   435 
   436 end
   437 
   438 context no_bot
   439 begin
   440 
   441 lemma lessThan_non_empty[simp]: "{..< x} \<noteq> {}"
   442   using lt_ex[of x] by auto
   443 
   444 end
   445 
   446 lemma (in linorder) atLeastLessThan_subset_iff:
   447   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   448 apply (auto simp:subset_eq Ball_def)
   449 apply(frule_tac x=a in spec)
   450 apply(erule_tac x=d in allE)
   451 apply (simp add: less_imp_le)
   452 done
   453 
   454 lemma atLeastLessThan_inj:
   455   fixes a b c d :: "'a::linorder"
   456   assumes eq: "{a ..< b} = {c ..< d}" and "a < b" "c < d"
   457   shows "a = c" "b = d"
   458 using assms by (metis atLeastLessThan_subset_iff eq less_le_not_le linorder_antisym_conv2 subset_refl)+
   459 
   460 lemma atLeastLessThan_eq_iff:
   461   fixes a b c d :: "'a::linorder"
   462   assumes "a < b" "c < d"
   463   shows "{a ..< b} = {c ..< d} \<longleftrightarrow> a = c \<and> b = d"
   464   using atLeastLessThan_inj assms by auto
   465 
   466 lemma (in linorder) Ioc_inj: "{a <.. b} = {c <.. d} \<longleftrightarrow> (b \<le> a \<and> d \<le> c) \<or> a = c \<and> b = d"
   467   by (metis eq_iff greaterThanAtMost_empty_iff2 greaterThanAtMost_iff le_cases not_le)
   468 
   469 lemma (in order) Iio_Int_singleton: "{..<k} \<inter> {x} = (if x < k then {x} else {})"
   470   by auto
   471 
   472 lemma (in linorder) Ioc_subset_iff: "{a<..b} \<subseteq> {c<..d} \<longleftrightarrow> (b \<le> a \<or> c \<le> a \<and> b \<le> d)"
   473   by (auto simp: subset_eq Ball_def) (metis less_le not_less)
   474 
   475 lemma (in order_bot) atLeast_eq_UNIV_iff: "{x..} = UNIV \<longleftrightarrow> x = bot"
   476 by (auto simp: set_eq_iff intro: le_bot)
   477 
   478 lemma (in order_top) atMost_eq_UNIV_iff: "{..x} = UNIV \<longleftrightarrow> x = top"
   479 by (auto simp: set_eq_iff intro: top_le)
   480 
   481 lemma (in bounded_lattice) atLeastAtMost_eq_UNIV_iff:
   482   "{x..y} = UNIV \<longleftrightarrow> (x = bot \<and> y = top)"
   483 by (auto simp: set_eq_iff intro: top_le le_bot)
   484 
   485 lemma Iio_eq_empty_iff: "{..< n::'a::{linorder, order_bot}} = {} \<longleftrightarrow> n = bot"
   486   by (auto simp: set_eq_iff not_less le_bot)
   487 
   488 lemma Iio_eq_empty_iff_nat: "{..< n::nat} = {} \<longleftrightarrow> n = 0"
   489   by (simp add: Iio_eq_empty_iff bot_nat_def)
   490 
   491 lemma mono_image_least:
   492   assumes f_mono: "mono f" and f_img: "f ` {m ..< n} = {m' ..< n'}" "m < n"
   493   shows "f m = m'"
   494 proof -
   495   from f_img have "{m' ..< n'} \<noteq> {}"
   496     by (metis atLeastLessThan_empty_iff image_is_empty)
   497   with f_img have "m' \<in> f ` {m ..< n}" by auto
   498   then obtain k where "f k = m'" "m \<le> k" by auto
   499   moreover have "m' \<le> f m" using f_img by auto
   500   ultimately show "f m = m'"
   501     using f_mono by (auto elim: monoE[where x=m and y=k])
   502 qed
   503 
   504 
   505 subsection {* Infinite intervals *}
   506 
   507 context dense_linorder
   508 begin
   509 
   510 lemma infinite_Ioo:
   511   assumes "a < b"
   512   shows "\<not> finite {a<..<b}"
   513 proof
   514   assume fin: "finite {a<..<b}"
   515   moreover have ne: "{a<..<b} \<noteq> {}"
   516     using `a < b` by auto
   517   ultimately have "a < Max {a <..< b}" "Max {a <..< b} < b"
   518     using Max_in[of "{a <..< b}"] by auto
   519   then obtain x where "Max {a <..< b} < x" "x < b"
   520     using dense[of "Max {a<..<b}" b] by auto
   521   then have "x \<in> {a <..< b}"
   522     using `a < Max {a <..< b}` by auto
   523   then have "x \<le> Max {a <..< b}"
   524     using fin by auto
   525   with `Max {a <..< b} < x` show False by auto
   526 qed
   527 
   528 lemma infinite_Icc: "a < b \<Longrightarrow> \<not> finite {a .. b}"
   529   using greaterThanLessThan_subseteq_atLeastAtMost_iff[of a b a b] infinite_Ioo[of a b]
   530   by (auto dest: finite_subset)
   531 
   532 lemma infinite_Ico: "a < b \<Longrightarrow> \<not> finite {a ..< b}"
   533   using greaterThanLessThan_subseteq_atLeastLessThan_iff[of a b a b] infinite_Ioo[of a b]
   534   by (auto dest: finite_subset)
   535 
   536 lemma infinite_Ioc: "a < b \<Longrightarrow> \<not> finite {a <.. b}"
   537   using greaterThanLessThan_subseteq_greaterThanAtMost_iff[of a b a b] infinite_Ioo[of a b]
   538   by (auto dest: finite_subset)
   539 
   540 end
   541 
   542 lemma infinite_Iio: "\<not> finite {..< a :: 'a :: {no_bot, linorder}}"
   543 proof
   544   assume "finite {..< a}"
   545   then have *: "\<And>x. x < a \<Longrightarrow> Min {..< a} \<le> x"
   546     by auto
   547   obtain x where "x < a"
   548     using lt_ex by auto
   549 
   550   obtain y where "y < Min {..< a}"
   551     using lt_ex by auto
   552   also have "Min {..< a} \<le> x"
   553     using `x < a` by fact
   554   also note `x < a`
   555   finally have "Min {..< a} \<le> y"
   556     by fact
   557   with `y < Min {..< a}` show False by auto
   558 qed
   559 
   560 lemma infinite_Iic: "\<not> finite {.. a :: 'a :: {no_bot, linorder}}"
   561   using infinite_Iio[of a] finite_subset[of "{..< a}" "{.. a}"]
   562   by (auto simp: subset_eq less_imp_le)
   563 
   564 lemma infinite_Ioi: "\<not> finite {a :: 'a :: {no_top, linorder} <..}"
   565 proof
   566   assume "finite {a <..}"
   567   then have *: "\<And>x. a < x \<Longrightarrow> x \<le> Max {a <..}"
   568     by auto
   569 
   570   obtain y where "Max {a <..} < y"
   571     using gt_ex by auto
   572 
   573   obtain x where "a < x"
   574     using gt_ex by auto
   575   also then have "x \<le> Max {a <..}"
   576     by fact
   577   also note `Max {a <..} < y`
   578   finally have "y \<le> Max { a <..}"
   579     by fact
   580   with `Max {a <..} < y` show False by auto
   581 qed
   582 
   583 lemma infinite_Ici: "\<not> finite {a :: 'a :: {no_top, linorder} ..}"
   584   using infinite_Ioi[of a] finite_subset[of "{a <..}" "{a ..}"]
   585   by (auto simp: subset_eq less_imp_le)
   586 
   587 subsubsection {* Intersection *}
   588 
   589 context linorder
   590 begin
   591 
   592 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   593 by auto
   594 
   595 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   596 by auto
   597 
   598 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   599 by auto
   600 
   601 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   602 by auto
   603 
   604 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   605 by auto
   606 
   607 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   608 by auto
   609 
   610 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   611 by auto
   612 
   613 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   614 by auto
   615 
   616 lemma Int_atMost[simp]: "{..a} \<inter> {..b} = {.. min a b}"
   617   by (auto simp: min_def)
   618 
   619 lemma Ioc_disjoint: "{a<..b} \<inter> {c<..d} = {} \<longleftrightarrow> b \<le> a \<or> d \<le> c \<or> b \<le> c \<or> d \<le> a"
   620   using assms by auto
   621 
   622 end
   623 
   624 context complete_lattice
   625 begin
   626 
   627 lemma
   628   shows Sup_atLeast[simp]: "Sup {x ..} = top"
   629     and Sup_greaterThanAtLeast[simp]: "x < top \<Longrightarrow> Sup {x <..} = top"
   630     and Sup_atMost[simp]: "Sup {.. y} = y"
   631     and Sup_atLeastAtMost[simp]: "x \<le> y \<Longrightarrow> Sup { x .. y} = y"
   632     and Sup_greaterThanAtMost[simp]: "x < y \<Longrightarrow> Sup { x <.. y} = y"
   633   by (auto intro!: Sup_eqI)
   634 
   635 lemma
   636   shows Inf_atMost[simp]: "Inf {.. x} = bot"
   637     and Inf_atMostLessThan[simp]: "top < x \<Longrightarrow> Inf {..< x} = bot"
   638     and Inf_atLeast[simp]: "Inf {x ..} = x"
   639     and Inf_atLeastAtMost[simp]: "x \<le> y \<Longrightarrow> Inf { x .. y} = x"
   640     and Inf_atLeastLessThan[simp]: "x < y \<Longrightarrow> Inf { x ..< y} = x"
   641   by (auto intro!: Inf_eqI)
   642 
   643 end
   644 
   645 lemma
   646   fixes x y :: "'a :: {complete_lattice, dense_linorder}"
   647   shows Sup_lessThan[simp]: "Sup {..< y} = y"
   648     and Sup_atLeastLessThan[simp]: "x < y \<Longrightarrow> Sup { x ..< y} = y"
   649     and Sup_greaterThanLessThan[simp]: "x < y \<Longrightarrow> Sup { x <..< y} = y"
   650     and Inf_greaterThan[simp]: "Inf {x <..} = x"
   651     and Inf_greaterThanAtMost[simp]: "x < y \<Longrightarrow> Inf { x <.. y} = x"
   652     and Inf_greaterThanLessThan[simp]: "x < y \<Longrightarrow> Inf { x <..< y} = x"
   653   by (auto intro!: Inf_eqI Sup_eqI intro: dense_le dense_le_bounded dense_ge dense_ge_bounded)
   654 
   655 subsection {* Intervals of natural numbers *}
   656 
   657 subsubsection {* The Constant @{term lessThan} *}
   658 
   659 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   660 by (simp add: lessThan_def)
   661 
   662 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   663 by (simp add: lessThan_def less_Suc_eq, blast)
   664 
   665 text {* The following proof is convenient in induction proofs where
   666 new elements get indices at the beginning. So it is used to transform
   667 @{term "{..<Suc n}"} to @{term "0::nat"} and @{term "{..< n}"}. *}
   668 
   669 lemma zero_notin_Suc_image: "0 \<notin> Suc ` A"
   670   by auto
   671 
   672 lemma lessThan_Suc_eq_insert_0: "{..<Suc n} = insert 0 (Suc ` {..<n})"
   673   by (auto simp: image_iff less_Suc_eq_0_disj)
   674 
   675 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   676 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   677 
   678 lemma Iic_Suc_eq_insert_0: "{.. Suc n} = insert 0 (Suc ` {.. n})"
   679   unfolding lessThan_Suc_atMost[symmetric] lessThan_Suc_eq_insert_0[of "Suc n"] ..
   680 
   681 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   682 by blast
   683 
   684 subsubsection {* The Constant @{term greaterThan} *}
   685 
   686 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   687 apply (simp add: greaterThan_def)
   688 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   689 done
   690 
   691 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   692 apply (simp add: greaterThan_def)
   693 apply (auto elim: linorder_neqE)
   694 done
   695 
   696 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   697 by blast
   698 
   699 subsubsection {* The Constant @{term atLeast} *}
   700 
   701 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   702 by (unfold atLeast_def UNIV_def, simp)
   703 
   704 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   705 apply (simp add: atLeast_def)
   706 apply (simp add: Suc_le_eq)
   707 apply (simp add: order_le_less, blast)
   708 done
   709 
   710 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   711   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   712 
   713 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   714 by blast
   715 
   716 subsubsection {* The Constant @{term atMost} *}
   717 
   718 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   719 by (simp add: atMost_def)
   720 
   721 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   722 apply (simp add: atMost_def)
   723 apply (simp add: less_Suc_eq order_le_less, blast)
   724 done
   725 
   726 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   727 by blast
   728 
   729 subsubsection {* The Constant @{term atLeastLessThan} *}
   730 
   731 text{*The orientation of the following 2 rules is tricky. The lhs is
   732 defined in terms of the rhs.  Hence the chosen orientation makes sense
   733 in this theory --- the reverse orientation complicates proofs (eg
   734 nontermination). But outside, when the definition of the lhs is rarely
   735 used, the opposite orientation seems preferable because it reduces a
   736 specific concept to a more general one. *}
   737 
   738 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   739 by(simp add:lessThan_def atLeastLessThan_def)
   740 
   741 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   742 by(simp add:atMost_def atLeastAtMost_def)
   743 
   744 declare atLeast0LessThan[symmetric, code_unfold]
   745         atLeast0AtMost[symmetric, code_unfold]
   746 
   747 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   748 by (simp add: atLeastLessThan_def)
   749 
   750 subsubsection {* Intervals of nats with @{term Suc} *}
   751 
   752 text{*Not a simprule because the RHS is too messy.*}
   753 lemma atLeastLessThanSuc:
   754     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   755 by (auto simp add: atLeastLessThan_def)
   756 
   757 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   758 by (auto simp add: atLeastLessThan_def)
   759 (*
   760 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   761 by (induct k, simp_all add: atLeastLessThanSuc)
   762 
   763 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   764 by (auto simp add: atLeastLessThan_def)
   765 *)
   766 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   767   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   768 
   769 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   770   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   771     greaterThanAtMost_def)
   772 
   773 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   774   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   775     greaterThanLessThan_def)
   776 
   777 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   778 by (auto simp add: atLeastAtMost_def)
   779 
   780 lemma atLeastAtMost_insertL: "m \<le> n \<Longrightarrow> insert m {Suc m..n} = {m ..n}"
   781 by auto
   782 
   783 text {* The analogous result is useful on @{typ int}: *}
   784 (* here, because we don't have an own int section *)
   785 lemma atLeastAtMostPlus1_int_conv:
   786   "m <= 1+n \<Longrightarrow> {m..1+n} = insert (1+n) {m..n::int}"
   787   by (auto intro: set_eqI)
   788 
   789 lemma atLeastLessThan_add_Un: "i \<le> j \<Longrightarrow> {i..<j+k} = {i..<j} \<union> {j..<j+k::nat}"
   790   apply (induct k) 
   791   apply (simp_all add: atLeastLessThanSuc)   
   792   done
   793 
   794 subsubsection {* Intervals and numerals *}
   795 
   796 lemma lessThan_nat_numeral:  --{*Evaluation for specific numerals*}
   797   "lessThan (numeral k :: nat) = insert (pred_numeral k) (lessThan (pred_numeral k))"
   798   by (simp add: numeral_eq_Suc lessThan_Suc)
   799 
   800 lemma atMost_nat_numeral:  --{*Evaluation for specific numerals*}
   801   "atMost (numeral k :: nat) = insert (numeral k) (atMost (pred_numeral k))"
   802   by (simp add: numeral_eq_Suc atMost_Suc)
   803 
   804 lemma atLeastLessThan_nat_numeral:  --{*Evaluation for specific numerals*}
   805   "atLeastLessThan m (numeral k :: nat) = 
   806      (if m \<le> (pred_numeral k) then insert (pred_numeral k) (atLeastLessThan m (pred_numeral k))
   807                  else {})"
   808   by (simp add: numeral_eq_Suc atLeastLessThanSuc)
   809 
   810 subsubsection {* Image *}
   811 
   812 lemma image_add_atLeastAtMost:
   813   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   814 proof
   815   show "?A \<subseteq> ?B" by auto
   816 next
   817   show "?B \<subseteq> ?A"
   818   proof
   819     fix n assume a: "n : ?B"
   820     hence "n - k : {i..j}" by auto
   821     moreover have "n = (n - k) + k" using a by auto
   822     ultimately show "n : ?A" by blast
   823   qed
   824 qed
   825 
   826 lemma image_add_atLeastLessThan:
   827   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   828 proof
   829   show "?A \<subseteq> ?B" by auto
   830 next
   831   show "?B \<subseteq> ?A"
   832   proof
   833     fix n assume a: "n : ?B"
   834     hence "n - k : {i..<j}" by auto
   835     moreover have "n = (n - k) + k" using a by auto
   836     ultimately show "n : ?A" by blast
   837   qed
   838 qed
   839 
   840 corollary image_Suc_atLeastAtMost[simp]:
   841   "Suc ` {i..j} = {Suc i..Suc j}"
   842 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   843 
   844 corollary image_Suc_atLeastLessThan[simp]:
   845   "Suc ` {i..<j} = {Suc i..<Suc j}"
   846 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   847 
   848 lemma image_add_int_atLeastLessThan:
   849     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   850   apply (auto simp add: image_def)
   851   apply (rule_tac x = "x - l" in bexI)
   852   apply auto
   853   done
   854 
   855 lemma image_minus_const_atLeastLessThan_nat:
   856   fixes c :: nat
   857   shows "(\<lambda>i. i - c) ` {x ..< y} =
   858       (if c < y then {x - c ..< y - c} else if x < y then {0} else {})"
   859     (is "_ = ?right")
   860 proof safe
   861   fix a assume a: "a \<in> ?right"
   862   show "a \<in> (\<lambda>i. i - c) ` {x ..< y}"
   863   proof cases
   864     assume "c < y" with a show ?thesis
   865       by (auto intro!: image_eqI[of _ _ "a + c"])
   866   next
   867     assume "\<not> c < y" with a show ?thesis
   868       by (auto intro!: image_eqI[of _ _ x] split: split_if_asm)
   869   qed
   870 qed auto
   871 
   872 lemma image_int_atLeastLessThan: "int ` {a..<b} = {int a..<int b}"
   873   by (auto intro!: image_eqI [where x = "nat x" for x])
   874 
   875 context ordered_ab_group_add
   876 begin
   877 
   878 lemma
   879   fixes x :: 'a
   880   shows image_uminus_greaterThan[simp]: "uminus ` {x<..} = {..<-x}"
   881   and image_uminus_atLeast[simp]: "uminus ` {x..} = {..-x}"
   882 proof safe
   883   fix y assume "y < -x"
   884   hence *:  "x < -y" using neg_less_iff_less[of "-y" x] by simp
   885   have "- (-y) \<in> uminus ` {x<..}"
   886     by (rule imageI) (simp add: *)
   887   thus "y \<in> uminus ` {x<..}" by simp
   888 next
   889   fix y assume "y \<le> -x"
   890   have "- (-y) \<in> uminus ` {x..}"
   891     by (rule imageI) (insert `y \<le> -x`[THEN le_imp_neg_le], simp)
   892   thus "y \<in> uminus ` {x..}" by simp
   893 qed simp_all
   894 
   895 lemma
   896   fixes x :: 'a
   897   shows image_uminus_lessThan[simp]: "uminus ` {..<x} = {-x<..}"
   898   and image_uminus_atMost[simp]: "uminus ` {..x} = {-x..}"
   899 proof -
   900   have "uminus ` {..<x} = uminus ` uminus ` {-x<..}"
   901     and "uminus ` {..x} = uminus ` uminus ` {-x..}" by simp_all
   902   thus "uminus ` {..<x} = {-x<..}" and "uminus ` {..x} = {-x..}"
   903     by (simp_all add: image_image
   904         del: image_uminus_greaterThan image_uminus_atLeast)
   905 qed
   906 
   907 lemma
   908   fixes x :: 'a
   909   shows image_uminus_atLeastAtMost[simp]: "uminus ` {x..y} = {-y..-x}"
   910   and image_uminus_greaterThanAtMost[simp]: "uminus ` {x<..y} = {-y..<-x}"
   911   and image_uminus_atLeastLessThan[simp]: "uminus ` {x..<y} = {-y<..-x}"
   912   and image_uminus_greaterThanLessThan[simp]: "uminus ` {x<..<y} = {-y<..<-x}"
   913   by (simp_all add: atLeastAtMost_def greaterThanAtMost_def atLeastLessThan_def
   914       greaterThanLessThan_def image_Int[OF inj_uminus] Int_commute)
   915 end
   916 
   917 subsubsection {* Finiteness *}
   918 
   919 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   920   by (induct k) (simp_all add: lessThan_Suc)
   921 
   922 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   923   by (induct k) (simp_all add: atMost_Suc)
   924 
   925 lemma finite_greaterThanLessThan [iff]:
   926   fixes l :: nat shows "finite {l<..<u}"
   927 by (simp add: greaterThanLessThan_def)
   928 
   929 lemma finite_atLeastLessThan [iff]:
   930   fixes l :: nat shows "finite {l..<u}"
   931 by (simp add: atLeastLessThan_def)
   932 
   933 lemma finite_greaterThanAtMost [iff]:
   934   fixes l :: nat shows "finite {l<..u}"
   935 by (simp add: greaterThanAtMost_def)
   936 
   937 lemma finite_atLeastAtMost [iff]:
   938   fixes l :: nat shows "finite {l..u}"
   939 by (simp add: atLeastAtMost_def)
   940 
   941 text {* A bounded set of natural numbers is finite. *}
   942 lemma bounded_nat_set_is_finite:
   943   "(ALL i:N. i < (n::nat)) ==> finite N"
   944 apply (rule finite_subset)
   945  apply (rule_tac [2] finite_lessThan, auto)
   946 done
   947 
   948 text {* A set of natural numbers is finite iff it is bounded. *}
   949 lemma finite_nat_set_iff_bounded:
   950   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   951 proof
   952   assume f:?F  show ?B
   953     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   954 next
   955   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   956 qed
   957 
   958 lemma finite_nat_set_iff_bounded_le:
   959   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   960 apply(simp add:finite_nat_set_iff_bounded)
   961 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   962 done
   963 
   964 lemma finite_less_ub:
   965      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   966 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   967 
   968 
   969 text{* Any subset of an interval of natural numbers the size of the
   970 subset is exactly that interval. *}
   971 
   972 lemma subset_card_intvl_is_intvl:
   973   assumes "A \<subseteq> {k..<k + card A}"
   974   shows "A = {k..<k + card A}"
   975 proof (cases "finite A")
   976   case True
   977   from this and assms show ?thesis
   978   proof (induct A rule: finite_linorder_max_induct)
   979     case empty thus ?case by auto
   980   next
   981     case (insert b A)
   982     hence *: "b \<notin> A" by auto
   983     with insert have "A <= {k..<k + card A}" and "b = k + card A"
   984       by fastforce+
   985     with insert * show ?case by auto
   986   qed
   987 next
   988   case False
   989   with assms show ?thesis by simp
   990 qed
   991 
   992 
   993 subsubsection {* Proving Inclusions and Equalities between Unions *}
   994 
   995 lemma UN_le_eq_Un0:
   996   "(\<Union>i\<le>n::nat. M i) = (\<Union>i\<in>{1..n}. M i) \<union> M 0" (is "?A = ?B")
   997 proof
   998   show "?A <= ?B"
   999   proof
  1000     fix x assume "x : ?A"
  1001     then obtain i where i: "i\<le>n" "x : M i" by auto
  1002     show "x : ?B"
  1003     proof(cases i)
  1004       case 0 with i show ?thesis by simp
  1005     next
  1006       case (Suc j) with i show ?thesis by auto
  1007     qed
  1008   qed
  1009 next
  1010   show "?B <= ?A" by auto
  1011 qed
  1012 
  1013 lemma UN_le_add_shift:
  1014   "(\<Union>i\<le>n::nat. M(i+k)) = (\<Union>i\<in>{k..n+k}. M i)" (is "?A = ?B")
  1015 proof
  1016   show "?A <= ?B" by fastforce
  1017 next
  1018   show "?B <= ?A"
  1019   proof
  1020     fix x assume "x : ?B"
  1021     then obtain i where i: "i : {k..n+k}" "x : M(i)" by auto
  1022     hence "i-k\<le>n & x : M((i-k)+k)" by auto
  1023     thus "x : ?A" by blast
  1024   qed
  1025 qed
  1026 
  1027 lemma UN_UN_finite_eq: "(\<Union>n::nat. \<Union>i\<in>{0..<n}. A i) = (\<Union>n. A n)"
  1028   by (auto simp add: atLeast0LessThan) 
  1029 
  1030 lemma UN_finite_subset: "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> C) \<Longrightarrow> (\<Union>n. A n) \<subseteq> C"
  1031   by (subst UN_UN_finite_eq [symmetric]) blast
  1032 
  1033 lemma UN_finite2_subset: 
  1034      "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) \<subseteq> (\<Union>n. B n)"
  1035   apply (rule UN_finite_subset)
  1036   apply (subst UN_UN_finite_eq [symmetric, of B]) 
  1037   apply blast
  1038   done
  1039 
  1040 lemma UN_finite2_eq:
  1041   "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) = (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) = (\<Union>n. B n)"
  1042   apply (rule subset_antisym)
  1043    apply (rule UN_finite2_subset, blast)
  1044  apply (rule UN_finite2_subset [where k=k])
  1045  apply (force simp add: atLeastLessThan_add_Un [of 0])
  1046  done
  1047 
  1048 
  1049 subsubsection {* Cardinality *}
  1050 
  1051 lemma card_lessThan [simp]: "card {..<u} = u"
  1052   by (induct u, simp_all add: lessThan_Suc)
  1053 
  1054 lemma card_atMost [simp]: "card {..u} = Suc u"
  1055   by (simp add: lessThan_Suc_atMost [THEN sym])
  1056 
  1057 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
  1058 proof -
  1059   have "{l..<u} = (%x. x + l) ` {..<u-l}"
  1060     apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
  1061     apply (rule_tac x = "x - l" in exI)
  1062     apply arith
  1063     done
  1064   then have "card {l..<u} = card {..<u-l}"
  1065     by (simp add: card_image inj_on_def)
  1066   then show ?thesis
  1067     by simp
  1068 qed
  1069 
  1070 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
  1071   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
  1072 
  1073 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
  1074   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
  1075 
  1076 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
  1077   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
  1078 
  1079 lemma ex_bij_betw_nat_finite:
  1080   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
  1081 apply(drule finite_imp_nat_seg_image_inj_on)
  1082 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
  1083 done
  1084 
  1085 lemma ex_bij_betw_finite_nat:
  1086   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
  1087 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
  1088 
  1089 lemma finite_same_card_bij:
  1090   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
  1091 apply(drule ex_bij_betw_finite_nat)
  1092 apply(drule ex_bij_betw_nat_finite)
  1093 apply(auto intro!:bij_betw_trans)
  1094 done
  1095 
  1096 lemma ex_bij_betw_nat_finite_1:
  1097   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
  1098 by (rule finite_same_card_bij) auto
  1099 
  1100 lemma bij_betw_iff_card:
  1101   assumes FIN: "finite A" and FIN': "finite B"
  1102   shows BIJ: "(\<exists>f. bij_betw f A B) \<longleftrightarrow> (card A = card B)"
  1103 using assms
  1104 proof(auto simp add: bij_betw_same_card)
  1105   assume *: "card A = card B"
  1106   obtain f where "bij_betw f A {0 ..< card A}"
  1107   using FIN ex_bij_betw_finite_nat by blast
  1108   moreover obtain g where "bij_betw g {0 ..< card B} B"
  1109   using FIN' ex_bij_betw_nat_finite by blast
  1110   ultimately have "bij_betw (g o f) A B"
  1111   using * by (auto simp add: bij_betw_trans)
  1112   thus "(\<exists>f. bij_betw f A B)" by blast
  1113 qed
  1114 
  1115 lemma inj_on_iff_card_le:
  1116   assumes FIN: "finite A" and FIN': "finite B"
  1117   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> B) = (card A \<le> card B)"
  1118 proof (safe intro!: card_inj_on_le)
  1119   assume *: "card A \<le> card B"
  1120   obtain f where 1: "inj_on f A" and 2: "f ` A = {0 ..< card A}"
  1121   using FIN ex_bij_betw_finite_nat unfolding bij_betw_def by force
  1122   moreover obtain g where "inj_on g {0 ..< card B}" and 3: "g ` {0 ..< card B} = B"
  1123   using FIN' ex_bij_betw_nat_finite unfolding bij_betw_def by force
  1124   ultimately have "inj_on g (f ` A)" using subset_inj_on[of g _ "f ` A"] * by force
  1125   hence "inj_on (g o f) A" using 1 comp_inj_on by blast
  1126   moreover
  1127   {have "{0 ..< card A} \<le> {0 ..< card B}" using * by force
  1128    with 2 have "f ` A  \<le> {0 ..< card B}" by blast
  1129    hence "(g o f) ` A \<le> B" unfolding comp_def using 3 by force
  1130   }
  1131   ultimately show "(\<exists>f. inj_on f A \<and> f ` A \<le> B)" by blast
  1132 qed (insert assms, auto)
  1133 
  1134 subsection {* Intervals of integers *}
  1135 
  1136 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
  1137   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
  1138 
  1139 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
  1140   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
  1141 
  1142 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
  1143     "{l+1..<u} = {l<..<u::int}"
  1144   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
  1145 
  1146 subsubsection {* Finiteness *}
  1147 
  1148 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
  1149     {(0::int)..<u} = int ` {..<nat u}"
  1150   apply (unfold image_def lessThan_def)
  1151   apply auto
  1152   apply (rule_tac x = "nat x" in exI)
  1153   apply (auto simp add: zless_nat_eq_int_zless [THEN sym])
  1154   done
  1155 
  1156 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
  1157   apply (cases "0 \<le> u")
  1158   apply (subst image_atLeastZeroLessThan_int, assumption)
  1159   apply (rule finite_imageI)
  1160   apply auto
  1161   done
  1162 
  1163 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
  1164   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
  1165   apply (erule subst)
  1166   apply (rule finite_imageI)
  1167   apply (rule finite_atLeastZeroLessThan_int)
  1168   apply (rule image_add_int_atLeastLessThan)
  1169   done
  1170 
  1171 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
  1172   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
  1173 
  1174 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
  1175   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
  1176 
  1177 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
  1178   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
  1179 
  1180 
  1181 subsubsection {* Cardinality *}
  1182 
  1183 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
  1184   apply (cases "0 \<le> u")
  1185   apply (subst image_atLeastZeroLessThan_int, assumption)
  1186   apply (subst card_image)
  1187   apply (auto simp add: inj_on_def)
  1188   done
  1189 
  1190 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
  1191   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
  1192   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
  1193   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
  1194   apply (erule subst)
  1195   apply (rule card_image)
  1196   apply (simp add: inj_on_def)
  1197   apply (rule image_add_int_atLeastLessThan)
  1198   done
  1199 
  1200 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
  1201 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
  1202 apply (auto simp add: algebra_simps)
  1203 done
  1204 
  1205 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
  1206 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
  1207 
  1208 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
  1209 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
  1210 
  1211 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
  1212 proof -
  1213   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
  1214   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
  1215 qed
  1216 
  1217 lemma card_less:
  1218 assumes zero_in_M: "0 \<in> M"
  1219 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
  1220 proof -
  1221   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
  1222   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
  1223 qed
  1224 
  1225 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
  1226 apply (rule card_bij_eq [of Suc _ _ "\<lambda>x. x - Suc 0"])
  1227 apply auto
  1228 apply (rule inj_on_diff_nat)
  1229 apply auto
  1230 apply (case_tac x)
  1231 apply auto
  1232 apply (case_tac xa)
  1233 apply auto
  1234 apply (case_tac xa)
  1235 apply auto
  1236 done
  1237 
  1238 lemma card_less_Suc:
  1239   assumes zero_in_M: "0 \<in> M"
  1240     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
  1241 proof -
  1242   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
  1243   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
  1244     by (auto simp only: insert_Diff)
  1245   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
  1246   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] 
  1247   have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
  1248     apply (subst card_insert)
  1249     apply simp_all
  1250     apply (subst b)
  1251     apply (subst card_less_Suc2[symmetric])
  1252     apply simp_all
  1253     done
  1254   with c show ?thesis by simp
  1255 qed
  1256 
  1257 
  1258 subsection {*Lemmas useful with the summation operator setsum*}
  1259 
  1260 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
  1261 
  1262 subsubsection {* Disjoint Unions *}
  1263 
  1264 text {* Singletons and open intervals *}
  1265 
  1266 lemma ivl_disj_un_singleton:
  1267   "{l::'a::linorder} Un {l<..} = {l..}"
  1268   "{..<u} Un {u::'a::linorder} = {..u}"
  1269   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
  1270   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
  1271   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
  1272   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
  1273 by auto
  1274 
  1275 text {* One- and two-sided intervals *}
  1276 
  1277 lemma ivl_disj_un_one:
  1278   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
  1279   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
  1280   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
  1281   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
  1282   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
  1283   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
  1284   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
  1285   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
  1286 by auto
  1287 
  1288 text {* Two- and two-sided intervals *}
  1289 
  1290 lemma ivl_disj_un_two:
  1291   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
  1292   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
  1293   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
  1294   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
  1295   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
  1296   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
  1297   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
  1298   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
  1299 by auto
  1300 
  1301 lemma ivl_disj_un_two_touch:
  1302   "[| (l::'a::linorder) < m; m < u |] ==> {l<..m} Un {m..<u} = {l<..<u}"
  1303   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m..<u} = {l..<u}"
  1304   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..m} Un {m..u} = {l<..u}"
  1305   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m..u} = {l..u}"
  1306 by auto
  1307 
  1308 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two ivl_disj_un_two_touch
  1309 
  1310 subsubsection {* Disjoint Intersections *}
  1311 
  1312 text {* One- and two-sided intervals *}
  1313 
  1314 lemma ivl_disj_int_one:
  1315   "{..l::'a::order} Int {l<..<u} = {}"
  1316   "{..<l} Int {l..<u} = {}"
  1317   "{..l} Int {l<..u} = {}"
  1318   "{..<l} Int {l..u} = {}"
  1319   "{l<..u} Int {u<..} = {}"
  1320   "{l<..<u} Int {u..} = {}"
  1321   "{l..u} Int {u<..} = {}"
  1322   "{l..<u} Int {u..} = {}"
  1323   by auto
  1324 
  1325 text {* Two- and two-sided intervals *}
  1326 
  1327 lemma ivl_disj_int_two:
  1328   "{l::'a::order<..<m} Int {m..<u} = {}"
  1329   "{l<..m} Int {m<..<u} = {}"
  1330   "{l..<m} Int {m..<u} = {}"
  1331   "{l..m} Int {m<..<u} = {}"
  1332   "{l<..<m} Int {m..u} = {}"
  1333   "{l<..m} Int {m<..u} = {}"
  1334   "{l..<m} Int {m..u} = {}"
  1335   "{l..m} Int {m<..u} = {}"
  1336   by auto
  1337 
  1338 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
  1339 
  1340 subsubsection {* Some Differences *}
  1341 
  1342 lemma ivl_diff[simp]:
  1343  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
  1344 by(auto)
  1345 
  1346 lemma (in linorder) lessThan_minus_lessThan [simp]:
  1347   "{..< n} - {..< m} = {m ..< n}"
  1348   by auto
  1349 
  1350 
  1351 subsubsection {* Some Subset Conditions *}
  1352 
  1353 lemma ivl_subset [simp]:
  1354  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
  1355 apply(auto simp:linorder_not_le)
  1356 apply(rule ccontr)
  1357 apply(insert linorder_le_less_linear[of i n])
  1358 apply(clarsimp simp:linorder_not_le)
  1359 apply(fastforce)
  1360 done
  1361 
  1362 
  1363 subsection {* Summation indexed over intervals *}
  1364 
  1365 syntax
  1366   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
  1367   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
  1368   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
  1369   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
  1370 syntax (xsymbols)
  1371   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1372   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1373   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1374   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1375 syntax (HTML output)
  1376   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1377   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1378   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1379   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1380 syntax (latex_sum output)
  1381   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1382  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1383   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1384  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1385   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1386  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1387   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1388  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1389 
  1390 translations
  1391   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
  1392   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
  1393   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
  1394   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
  1395 
  1396 text{* The above introduces some pretty alternative syntaxes for
  1397 summation over intervals:
  1398 \begin{center}
  1399 \begin{tabular}{lll}
  1400 Old & New & \LaTeX\\
  1401 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
  1402 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
  1403 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
  1404 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
  1405 \end{tabular}
  1406 \end{center}
  1407 The left column shows the term before introduction of the new syntax,
  1408 the middle column shows the new (default) syntax, and the right column
  1409 shows a special syntax. The latter is only meaningful for latex output
  1410 and has to be activated explicitly by setting the print mode to
  1411 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
  1412 antiquotations). It is not the default \LaTeX\ output because it only
  1413 works well with italic-style formulae, not tt-style.
  1414 
  1415 Note that for uniformity on @{typ nat} it is better to use
  1416 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
  1417 not provide all lemmas available for @{term"{m..<n}"} also in the
  1418 special form for @{term"{..<n}"}. *}
  1419 
  1420 text{* This congruence rule should be used for sums over intervals as
  1421 the standard theorem @{text[source]setsum.cong} does not work well
  1422 with the simplifier who adds the unsimplified premise @{term"x:B"} to
  1423 the context. *}
  1424 
  1425 lemma setsum_ivl_cong:
  1426  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
  1427  setsum f {a..<b} = setsum g {c..<d}"
  1428 by(rule setsum.cong, simp_all)
  1429 
  1430 (* FIXME why are the following simp rules but the corresponding eqns
  1431 on intervals are not? *)
  1432 
  1433 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
  1434 by (simp add:atMost_Suc ac_simps)
  1435 
  1436 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
  1437 by (simp add:lessThan_Suc ac_simps)
  1438 
  1439 lemma setsum_cl_ivl_Suc[simp]:
  1440   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
  1441 by (auto simp:ac_simps atLeastAtMostSuc_conv)
  1442 
  1443 lemma setsum_op_ivl_Suc[simp]:
  1444   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
  1445 by (auto simp:ac_simps atLeastLessThanSuc)
  1446 (*
  1447 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
  1448     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
  1449 by (auto simp:ac_simps atLeastAtMostSuc_conv)
  1450 *)
  1451 
  1452 lemma setsum_head:
  1453   fixes n :: nat
  1454   assumes mn: "m <= n" 
  1455   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
  1456 proof -
  1457   from mn
  1458   have "{m..n} = {m} \<union> {m<..n}"
  1459     by (auto intro: ivl_disj_un_singleton)
  1460   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
  1461     by (simp add: atLeast0LessThan)
  1462   also have "\<dots> = ?rhs" by simp
  1463   finally show ?thesis .
  1464 qed
  1465 
  1466 lemma setsum_head_Suc:
  1467   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
  1468 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
  1469 
  1470 lemma setsum_head_upt_Suc:
  1471   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
  1472 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
  1473 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
  1474 done
  1475 
  1476 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
  1477   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
  1478 proof-
  1479   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
  1480   thus ?thesis by (auto simp: ivl_disj_int setsum.union_disjoint
  1481     atLeastSucAtMost_greaterThanAtMost)
  1482 qed
  1483 
  1484 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1485   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
  1486 by (simp add:setsum.union_disjoint[symmetric] ivl_disj_int ivl_disj_un)
  1487 
  1488 lemma setsum_diff_nat_ivl:
  1489 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1490 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1491   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
  1492 using setsum_add_nat_ivl [of m n p f,symmetric]
  1493 apply (simp add: ac_simps)
  1494 done
  1495 
  1496 lemma setsum_natinterval_difff:
  1497   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
  1498   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
  1499           (if m <= n then f m - f(n + 1) else 0)"
  1500 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
  1501 
  1502 lemma setsum_nat_group: "(\<Sum>m<n::nat. setsum f {m * k ..< m*k + k}) = setsum f {..< n * k}"
  1503   apply (subgoal_tac "k = 0 | 0 < k", auto)
  1504   apply (induct "n")
  1505   apply (simp_all add: setsum_add_nat_ivl add.commute atLeast0LessThan[symmetric])
  1506   done
  1507 
  1508 lemma setsum_triangle_reindex:
  1509   fixes n :: nat
  1510   shows "(\<Sum>(i,j)\<in>{(i,j). i+j < n}. f i j) = (\<Sum>k<n. \<Sum>i\<le>k. f i (k - i))"
  1511   apply (simp add: setsum.Sigma)
  1512   apply (rule setsum.reindex_bij_witness[where j="\<lambda>(i, j). (i+j, i)" and i="\<lambda>(k, i). (i, k - i)"])
  1513   apply auto
  1514   done
  1515 
  1516 lemma setsum_triangle_reindex_eq:
  1517   fixes n :: nat
  1518   shows "(\<Sum>(i,j)\<in>{(i,j). i+j \<le> n}. f i j) = (\<Sum>k\<le>n. \<Sum>i\<le>k. f i (k - i))"
  1519 using setsum_triangle_reindex [of f "Suc n"]
  1520 by (simp only: Nat.less_Suc_eq_le lessThan_Suc_atMost)
  1521 
  1522 lemma nat_diff_setsum_reindex: "(\<Sum>i<n. f (n - Suc i)) = (\<Sum>i<n. f i)"
  1523   by (rule setsum.reindex_bij_witness[where i="\<lambda>i. n - Suc i" and j="\<lambda>i. n - Suc i"]) auto
  1524 
  1525 subsection{* Shifting bounds *}
  1526 
  1527 lemma setsum_shift_bounds_nat_ivl:
  1528   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
  1529 by (induct "n", auto simp:atLeastLessThanSuc)
  1530 
  1531 lemma setsum_shift_bounds_cl_nat_ivl:
  1532   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
  1533   by (rule setsum.reindex_bij_witness[where i="\<lambda>i. i + k" and j="\<lambda>i. i - k"]) auto
  1534 
  1535 corollary setsum_shift_bounds_cl_Suc_ivl:
  1536   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
  1537 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
  1538 
  1539 corollary setsum_shift_bounds_Suc_ivl:
  1540   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
  1541 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
  1542 
  1543 lemma setsum_shift_lb_Suc0_0:
  1544   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
  1545 by(simp add:setsum_head_Suc)
  1546 
  1547 lemma setsum_shift_lb_Suc0_0_upt:
  1548   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
  1549 apply(cases k)apply simp
  1550 apply(simp add:setsum_head_upt_Suc)
  1551 done
  1552 
  1553 lemma setsum_atMost_Suc_shift:
  1554   fixes f :: "nat \<Rightarrow> 'a::comm_monoid_add"
  1555   shows "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
  1556 proof (induct n)
  1557   case 0 show ?case by simp
  1558 next
  1559   case (Suc n) note IH = this
  1560   have "(\<Sum>i\<le>Suc (Suc n). f i) = (\<Sum>i\<le>Suc n. f i) + f (Suc (Suc n))"
  1561     by (rule setsum_atMost_Suc)
  1562   also have "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
  1563     by (rule IH)
  1564   also have "f 0 + (\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) =
  1565              f 0 + ((\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)))"
  1566     by (rule add.assoc)
  1567   also have "(\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) = (\<Sum>i\<le>Suc n. f (Suc i))"
  1568     by (rule setsum_atMost_Suc [symmetric])
  1569   finally show ?case .
  1570 qed
  1571 
  1572 lemma setsum_last_plus: fixes n::nat shows "m <= n \<Longrightarrow> (\<Sum>i = m..n. f i) = f n + (\<Sum>i = m..<n. f i)"
  1573   by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost add.commute)
  1574 
  1575 lemma setsum_Suc_diff:
  1576   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1577   assumes "m \<le> Suc n"
  1578   shows "(\<Sum>i = m..n. f(Suc i) - f i) = f (Suc n) - f m"
  1579 using assms by (induct n) (auto simp: le_Suc_eq)
  1580 
  1581 lemma nested_setsum_swap:
  1582      "(\<Sum>i = 0..n. (\<Sum>j = 0..<i. a i j)) = (\<Sum>j = 0..<n. \<Sum>i = Suc j..n. a i j)"
  1583   by (induction n) (auto simp: setsum.distrib)
  1584 
  1585 lemma nested_setsum_swap':
  1586      "(\<Sum>i\<le>n. (\<Sum>j<i. a i j)) = (\<Sum>j<n. \<Sum>i = Suc j..n. a i j)"
  1587   by (induction n) (auto simp: setsum.distrib)
  1588 
  1589 lemma setsum_zero_power' [simp]:
  1590   fixes c :: "nat \<Rightarrow> 'a::field"
  1591   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
  1592   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
  1593   by auto
  1594 
  1595 
  1596 subsection {* The formula for geometric sums *}
  1597 
  1598 lemma geometric_sum:
  1599   assumes "x \<noteq> 1"
  1600   shows "(\<Sum>i<n. x ^ i) = (x ^ n - 1) / (x - 1::'a::field)"
  1601 proof -
  1602   from assms obtain y where "y = x - 1" and "y \<noteq> 0" by simp_all
  1603   moreover have "(\<Sum>i<n. (y + 1) ^ i) = ((y + 1) ^ n - 1) / y"
  1604     by (induct n) (simp_all add: power_Suc field_simps `y \<noteq> 0`)
  1605   ultimately show ?thesis by simp
  1606 qed
  1607 
  1608 lemma diff_power_eq_setsum:
  1609   fixes y :: "'a::{comm_ring,monoid_mult}"
  1610   shows
  1611     "x ^ (Suc n) - y ^ (Suc n) =
  1612       (x - y) * (\<Sum>p<Suc n. (x ^ p) * y ^ (n - p))"
  1613 proof (induct n)
  1614   case (Suc n)
  1615   have "x ^ Suc (Suc n) - y ^ Suc (Suc n) = x * (x * x^n) - y * (y * y ^ n)"
  1616     by (simp add: power_Suc)
  1617   also have "... = y * (x ^ (Suc n) - y ^ (Suc n)) + (x - y) * (x * x^n)"
  1618     by (simp add: power_Suc algebra_simps)
  1619   also have "... = y * ((x - y) * (\<Sum>p<Suc n. (x ^ p) * y ^ (n - p))) + (x - y) * (x * x^n)"
  1620     by (simp only: Suc)
  1621   also have "... = (x - y) * (y * (\<Sum>p<Suc n. (x ^ p) * y ^ (n - p))) + (x - y) * (x * x^n)"
  1622     by (simp only: mult.left_commute)
  1623   also have "... = (x - y) * (\<Sum>p<Suc (Suc n). x ^ p * y ^ (Suc n - p))"
  1624     by (simp add: power_Suc field_simps Suc_diff_le setsum_left_distrib setsum_right_distrib)
  1625   finally show ?case .
  1626 qed simp
  1627 
  1628 corollary power_diff_sumr2: --{* @{text COMPLEX_POLYFUN} in HOL Light *}
  1629   fixes x :: "'a::{comm_ring,monoid_mult}"
  1630   shows   "x^n - y^n = (x - y) * (\<Sum>i<n. y^(n - Suc i) * x^i)"
  1631 using diff_power_eq_setsum[of x "n - 1" y]
  1632 by (cases "n = 0") (simp_all add: field_simps)
  1633 
  1634 lemma power_diff_1_eq:
  1635   fixes x :: "'a::{comm_ring,monoid_mult}"
  1636   shows "n \<noteq> 0 \<Longrightarrow> x^n - 1 = (x - 1) * (\<Sum>i<n. (x^i))"
  1637 using diff_power_eq_setsum [of x _ 1]
  1638   by (cases n) auto
  1639 
  1640 lemma one_diff_power_eq':
  1641   fixes x :: "'a::{comm_ring,monoid_mult}"
  1642   shows "n \<noteq> 0 \<Longrightarrow> 1 - x^n = (1 - x) * (\<Sum>i<n. x^(n - Suc i))"
  1643 using diff_power_eq_setsum [of 1 _ x]
  1644   by (cases n) auto
  1645 
  1646 lemma one_diff_power_eq:
  1647   fixes x :: "'a::{comm_ring,monoid_mult}"
  1648   shows "n \<noteq> 0 \<Longrightarrow> 1 - x^n = (1 - x) * (\<Sum>i<n. x^i)"
  1649 by (metis one_diff_power_eq' [of n x] nat_diff_setsum_reindex)
  1650 
  1651 
  1652 subsection {* The formula for arithmetic sums *}
  1653 
  1654 lemma gauss_sum:
  1655   "(2::'a::comm_semiring_1)*(\<Sum>i\<in>{1..n}. of_nat i) = of_nat n*((of_nat n)+1)"
  1656 proof (induct n)
  1657   case 0
  1658   show ?case by simp
  1659 next
  1660   case (Suc n)
  1661   then show ?case
  1662     by (simp add: algebra_simps add: one_add_one [symmetric] del: one_add_one)
  1663       (* FIXME: make numeral cancellation simprocs work for semirings *)
  1664 qed
  1665 
  1666 theorem arith_series_general:
  1667   "(2::'a::comm_semiring_1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1668   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1669 proof cases
  1670   assume ngt1: "n > 1"
  1671   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1672   have
  1673     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1674      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1675     by (rule setsum.distrib)
  1676   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1677   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1678     unfolding One_nat_def
  1679     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt ac_simps)
  1680   also have "2*\<dots> = 2*?n*a + d*2*(\<Sum>i\<in>{1..<n}. ?I i)"
  1681     by (simp add: algebra_simps)
  1682   also from ngt1 have "{1..<n} = {1..n - 1}"
  1683     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1684   also from ngt1
  1685   have "2*?n*a + d*2*(\<Sum>i\<in>{1..n - 1}. ?I i) = (2*?n*a + d*?I (n - 1)*?I n)"
  1686     by (simp only: mult.assoc gauss_sum [of "n - 1"], unfold One_nat_def)
  1687       (simp add:  mult.commute trans [OF add.commute of_nat_Suc [symmetric]])
  1688   finally show ?thesis
  1689     unfolding mult_2 by (simp add: algebra_simps)
  1690 next
  1691   assume "\<not>(n > 1)"
  1692   hence "n = 1 \<or> n = 0" by auto
  1693   thus ?thesis by (auto simp: mult_2)
  1694 qed
  1695 
  1696 lemma arith_series_nat:
  1697   "(2::nat) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1698 proof -
  1699   have
  1700     "2 * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1701     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1702     by (rule arith_series_general)
  1703   thus ?thesis
  1704     unfolding One_nat_def by auto
  1705 qed
  1706 
  1707 lemma arith_series_int:
  1708   "2 * (\<Sum>i\<in>{..<n}. a + int i * d) = int n * (a + (a + int(n - 1)*d))"
  1709   by (fact arith_series_general) (* FIXME: duplicate *)
  1710 
  1711 lemma sum_diff_distrib: "\<forall>x. Q x \<le> P x  \<Longrightarrow> (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x :: nat)"
  1712   by (subst setsum_subtractf_nat) auto
  1713 
  1714 subsection {* Products indexed over intervals *}
  1715 
  1716 syntax
  1717   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1718   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1719   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1720   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1721 syntax (xsymbols)
  1722   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1723   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1724   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1725   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1726 syntax (HTML output)
  1727   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1728   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1729   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1730   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1731 syntax (latex_prod output)
  1732   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1733  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1734   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1735  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1736   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1737  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1738   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1739  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1740 
  1741 translations
  1742   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1743   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1744   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1745   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1746 
  1747 subsection {* Transfer setup *}
  1748 
  1749 lemma transfer_nat_int_set_functions:
  1750     "{..n} = nat ` {0..int n}"
  1751     "{m..n} = nat ` {int m..int n}"  (* need all variants of these! *)
  1752   apply (auto simp add: image_def)
  1753   apply (rule_tac x = "int x" in bexI)
  1754   apply auto
  1755   apply (rule_tac x = "int x" in bexI)
  1756   apply auto
  1757   done
  1758 
  1759 lemma transfer_nat_int_set_function_closures:
  1760     "x >= 0 \<Longrightarrow> nat_set {x..y}"
  1761   by (simp add: nat_set_def)
  1762 
  1763 declare transfer_morphism_nat_int[transfer add
  1764   return: transfer_nat_int_set_functions
  1765     transfer_nat_int_set_function_closures
  1766 ]
  1767 
  1768 lemma transfer_int_nat_set_functions:
  1769     "is_nat m \<Longrightarrow> is_nat n \<Longrightarrow> {m..n} = int ` {nat m..nat n}"
  1770   by (simp only: is_nat_def transfer_nat_int_set_functions
  1771     transfer_nat_int_set_function_closures
  1772     transfer_nat_int_set_return_embed nat_0_le
  1773     cong: transfer_nat_int_set_cong)
  1774 
  1775 lemma transfer_int_nat_set_function_closures:
  1776     "is_nat x \<Longrightarrow> nat_set {x..y}"
  1777   by (simp only: transfer_nat_int_set_function_closures is_nat_def)
  1778 
  1779 declare transfer_morphism_int_nat[transfer add
  1780   return: transfer_int_nat_set_functions
  1781     transfer_int_nat_set_function_closures
  1782 ]
  1783 
  1784 lemma setprod_int_plus_eq: "setprod int {i..i+j} =  \<Prod>{int i..int (i+j)}"
  1785   by (induct j) (auto simp add: atLeastAtMostSuc_conv atLeastAtMostPlus1_int_conv)
  1786 
  1787 lemma setprod_int_eq: "setprod int {i..j} =  \<Prod>{int i..int j}"
  1788 proof (cases "i \<le> j")
  1789   case True
  1790   then show ?thesis
  1791     by (metis Nat.le_iff_add setprod_int_plus_eq)
  1792 next
  1793   case False
  1794   then show ?thesis
  1795     by auto
  1796 qed
  1797 
  1798 end