src/Pure/Isar/attrib.ML
author wenzelm
Fri Jun 10 11:47:52 2011 +0200 (2011-06-10)
changeset 43347 f18cf88453d6
parent 42813 6c841fa92fa2
child 44046 a43ca8ed6564
permissions -rw-r--r--
tuned name (cf. blast_stats);
     1 (*  Title:      Pure/Isar/attrib.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Symbolic representation of attributes -- with name and syntax.
     5 *)
     6 
     7 signature ATTRIB =
     8 sig
     9   type src = Args.src
    10   type binding = binding * src list
    11   val empty_binding: binding
    12   val print_attributes: theory -> unit
    13   val intern: theory -> xstring -> string
    14   val intern_src: theory -> src -> src
    15   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    16   val defined: theory -> string -> bool
    17   val attribute: theory -> src -> attribute
    18   val attribute_i: theory -> src -> attribute
    19   val map_specs: ('a -> 'att) ->
    20     (('c * 'a list) * 'b) list -> (('c * 'att list) * 'b) list
    21   val map_facts: ('a -> 'att) ->
    22     (('c * 'a list) * ('d * 'a list) list) list ->
    23     (('c * 'att list) * ('d * 'att list) list) list
    24   val map_facts_refs: ('a -> 'att) -> ('b -> 'fact) ->
    25     (('c * 'a list) * ('b * 'a list) list) list ->
    26     (('c * 'att list) * ('fact * 'att list) list) list
    27   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    28   val crude_closure: Proof.context -> src -> src
    29   val setup: Binding.binding -> attribute context_parser -> string -> theory -> theory
    30   val attribute_setup: bstring * Position.T -> Symbol_Pos.text * Position.T -> string ->
    31     theory -> theory
    32   val add_del: attribute -> attribute -> attribute context_parser
    33   val thm_sel: Facts.interval list parser
    34   val thm: thm context_parser
    35   val thms: thm list context_parser
    36   val multi_thm: thm list context_parser
    37   val print_configs: Proof.context -> unit
    38   val internal: (morphism -> attribute) -> src
    39   val config_bool: Binding.binding ->
    40     (Context.generic -> bool) -> bool Config.T * (theory -> theory)
    41   val config_int: Binding.binding ->
    42     (Context.generic -> int) -> int Config.T * (theory -> theory)
    43   val config_real: Binding.binding ->
    44     (Context.generic -> real) -> real Config.T * (theory -> theory)
    45   val config_string: Binding.binding ->
    46     (Context.generic -> string) -> string Config.T * (theory -> theory)
    47   val setup_config_bool: Binding.binding -> (Context.generic -> bool) -> bool Config.T
    48   val setup_config_int: Binding.binding -> (Context.generic -> int) -> int Config.T
    49   val setup_config_string: Binding.binding -> (Context.generic -> string) -> string Config.T
    50   val setup_config_real: Binding.binding -> (Context.generic -> real) -> real Config.T
    51 end;
    52 
    53 structure Attrib: ATTRIB =
    54 struct
    55 
    56 (* source and bindings *)
    57 
    58 type src = Args.src;
    59 
    60 type binding = binding * src list;
    61 val empty_binding: binding = (Binding.empty, []);
    62 
    63 
    64 
    65 (** named attributes **)
    66 
    67 (* theory data *)
    68 
    69 structure Attributes = Theory_Data
    70 (
    71   type T = ((src -> attribute) * string) Name_Space.table;
    72   val empty : T = Name_Space.empty_table "attribute";
    73   val extend = I;
    74   fun merge data : T = Name_Space.merge_tables data;
    75 );
    76 
    77 fun print_attributes thy =
    78   let
    79     val ctxt = Proof_Context.init_global thy;
    80     val attribs = Attributes.get thy;
    81     fun prt_attr (name, (_, "")) = Pretty.str name
    82       | prt_attr (name, (_, comment)) =
    83           Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    84   in
    85     [Pretty.big_list "attributes:" (map prt_attr (Name_Space.extern_table ctxt attribs))]
    86     |> Pretty.chunks |> Pretty.writeln
    87   end;
    88 
    89 fun add_attribute name att comment thy = thy
    90   |> Attributes.map
    91     (Name_Space.define (Proof_Context.init_global thy) true (Sign.naming_of thy)
    92       (name, (att, comment)) #> snd);
    93 
    94 
    95 (* name space *)
    96 
    97 val intern = Name_Space.intern o #1 o Attributes.get;
    98 val intern_src = Args.map_name o intern;
    99 
   100 fun extern ctxt = Name_Space.extern ctxt (#1 (Attributes.get (Proof_Context.theory_of ctxt)));
   101 
   102 
   103 (* pretty printing *)
   104 
   105 fun pretty_attribs _ [] = []
   106   | pretty_attribs ctxt srcs =
   107       [Pretty.enum "," "[" "]" (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs)];
   108 
   109 
   110 (* get attributes *)
   111 
   112 val defined = Symtab.defined o #2 o Attributes.get;
   113 
   114 fun attribute_i thy =
   115   let
   116     val (space, tab) = Attributes.get thy;
   117     fun attr src =
   118       let val ((name, _), pos) = Args.dest_src src in
   119         (case Symtab.lookup tab name of
   120           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   121         | SOME (att, _) => (Position.report pos (Name_Space.markup space name); att src))
   122       end;
   123   in attr end;
   124 
   125 fun attribute thy = attribute_i thy o intern_src thy;
   126 
   127 
   128 (* attributed declarations *)
   129 
   130 fun map_specs f = map (apfst (apsnd (map f)));
   131 
   132 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   133 fun map_facts_refs f g = map_facts f #> map (apsnd (map (apfst g)));
   134 
   135 
   136 (* fact expressions *)
   137 
   138 fun eval_thms ctxt srcs = ctxt
   139   |> Proof_Context.note_thmss ""
   140     (map_facts_refs (attribute (Proof_Context.theory_of ctxt)) (Proof_Context.get_fact ctxt)
   141       [((Binding.empty, []), srcs)])
   142   |> fst |> maps snd;
   143 
   144 
   145 (* crude_closure *)
   146 
   147 (*Produce closure without knowing facts in advance! The following
   148   works reasonably well for attribute parsers that do not peek at the
   149   thm structure.*)
   150 
   151 fun crude_closure ctxt src =
   152  (try (fn () => attribute_i (Proof_Context.theory_of ctxt) src
   153     (Context.Proof ctxt, Drule.asm_rl)) ();
   154   Args.closure src);
   155 
   156 
   157 (* attribute setup *)
   158 
   159 fun syntax scan = Args.syntax "attribute" scan;
   160 
   161 fun setup name scan =
   162   add_attribute name
   163     (fn src => fn (ctxt, th) => let val (a, ctxt') = syntax scan src ctxt in a (ctxt', th) end);
   164 
   165 fun attribute_setup name (txt, pos) cmt =
   166   Context.theory_map (ML_Context.expression pos
   167     "val (name, scan, comment): binding * attribute context_parser * string"
   168     "Context.map_theory (Attrib.setup name scan comment)"
   169     (ML_Lex.read Position.none ("(" ^ ML_Syntax.make_binding name ^ ", ") @
   170       ML_Lex.read pos txt @
   171       ML_Lex.read Position.none (", " ^ ML_Syntax.print_string cmt ^ ")")));
   172 
   173 
   174 (* add/del syntax *)
   175 
   176 fun add_del add del = Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add);
   177 
   178 
   179 
   180 (** parsing attributed theorems **)
   181 
   182 val thm_sel = Parse.$$$ "(" |-- Parse.list1
   183  (Parse.nat --| Parse.minus -- Parse.nat >> Facts.FromTo ||
   184   Parse.nat --| Parse.minus >> Facts.From ||
   185   Parse.nat >> Facts.Single) --| Parse.$$$ ")";
   186 
   187 local
   188 
   189 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   190 
   191 fun gen_thm pick = Scan.depend (fn context =>
   192   let
   193     val thy = Context.theory_of context;
   194     val get = Context.cases (Global_Theory.get_fact context) Proof_Context.get_fact context;
   195     val get_fact = get o Facts.Fact;
   196     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   197   in
   198     Parse.$$$ "[" |-- Args.attribs (intern thy) --| Parse.$$$ "]" >> (fn srcs =>
   199       let
   200         val atts = map (attribute_i thy) srcs;
   201         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   202       in (context', pick "" [th']) end)
   203     ||
   204     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   205       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   206      Scan.ahead (Parse.position fact_name) :|-- (fn (name, pos) =>
   207       Args.named_fact (get_named pos) -- Scan.option thm_sel
   208         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   209     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   210       let
   211         val ths = Facts.select thmref fact;
   212         val atts = map (attribute_i thy) srcs;
   213         val (context', ths') = Library.foldl_map (Library.apply atts) (context, ths);
   214       in (context', pick name ths') end)
   215   end);
   216 
   217 in
   218 
   219 val thm = gen_thm Facts.the_single;
   220 val multi_thm = gen_thm (K I);
   221 val thms = Scan.repeat multi_thm >> flat;
   222 
   223 end;
   224 
   225 
   226 
   227 (** basic attributes **)
   228 
   229 (* internal *)
   230 
   231 fun internal att = Args.src (("Pure.attribute", [Token.mk_attribute att]), Position.none);
   232 
   233 
   234 (* rule composition *)
   235 
   236 val COMP_att =
   237   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   238     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B)));
   239 
   240 val THEN_att =
   241   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   242     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B)));
   243 
   244 val OF_att =
   245   thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A));
   246 
   247 
   248 (* rename_abs *)
   249 
   250 fun rename_abs x = (Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars')) x;
   251 
   252 
   253 (* unfold / fold definitions *)
   254 
   255 fun unfolded_syntax rule =
   256   thms >> (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths));
   257 
   258 val unfolded = unfolded_syntax Local_Defs.unfold;
   259 val folded = unfolded_syntax Local_Defs.fold;
   260 
   261 
   262 (* rule format *)
   263 
   264 val rule_format = Args.mode "no_asm"
   265   >> (fn true => Object_Logic.rule_format_no_asm | false => Object_Logic.rule_format);
   266 
   267 val elim_format = Thm.rule_attribute (K Tactic.make_elim);
   268 
   269 
   270 (* misc rules *)
   271 
   272 val no_vars = Thm.rule_attribute (fn context => fn th =>
   273   let
   274     val ctxt = Variable.set_body false (Context.proof_of context);
   275     val ((_, [th']), _) = Variable.import true [th] ctxt;
   276   in th' end);
   277 
   278 val eta_long =
   279   Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion));
   280 
   281 val rotated = Scan.optional Parse.int 1 >> (fn n => Thm.rule_attribute (K (rotate_prems n)));
   282 
   283 
   284 (* theory setup *)
   285 
   286 val _ = Context.>> (Context.map_theory
   287  (setup (Binding.name "attribute") (Scan.lift Args.internal_attribute >> Morphism.form)
   288     "internal attribute" #>
   289   setup (Binding.name "tagged") (Scan.lift (Args.name -- Args.name) >> Thm.tag) "tagged theorem" #>
   290   setup (Binding.name "untagged") (Scan.lift Args.name >> Thm.untag) "untagged theorem" #>
   291   setup (Binding.name "kind") (Scan.lift Args.name >> Thm.kind) "theorem kind" #>
   292   setup (Binding.name "COMP") COMP_att "direct composition with rules (no lifting)" #>
   293   setup (Binding.name "THEN") THEN_att "resolution with rule" #>
   294   setup (Binding.name "OF") OF_att "rule applied to facts" #>
   295   setup (Binding.name "rename_abs") (Scan.lift rename_abs)
   296     "rename bound variables in abstractions" #>
   297   setup (Binding.name "unfolded") unfolded "unfolded definitions" #>
   298   setup (Binding.name "folded") folded "folded definitions" #>
   299   setup (Binding.name "consumes") (Scan.lift (Scan.optional Parse.nat 1) >> Rule_Cases.consumes)
   300     "number of consumed facts" #>
   301   setup (Binding.name "constraints") (Scan.lift Parse.nat >> Rule_Cases.constraints)
   302     "number of equality constraints" #>
   303   setup (Binding.name "case_names") (Scan.lift (Scan.repeat1 Args.name) >> Rule_Cases.case_names)
   304     "named rule cases" #>
   305   setup (Binding.name "case_conclusion")
   306     (Scan.lift (Args.name -- Scan.repeat Args.name) >> Rule_Cases.case_conclusion)
   307     "named conclusion of rule cases" #>
   308   setup (Binding.name "params")
   309     (Scan.lift (Parse.and_list1 (Scan.repeat Args.name)) >> Rule_Cases.params)
   310     "named rule parameters" #>
   311   setup (Binding.name "standard") (Scan.succeed (Thm.rule_attribute (K Drule.export_without_context)))
   312     "result put into standard form (legacy)" #>
   313   setup (Binding.name "rule_format") rule_format "result put into canonical rule format" #>
   314   setup (Binding.name "elim_format") (Scan.succeed elim_format)
   315     "destruct rule turned into elimination rule format" #>
   316   setup (Binding.name "no_vars") (Scan.succeed no_vars) "frozen schematic vars" #>
   317   setup (Binding.name "eta_long") (Scan.succeed eta_long)
   318     "put theorem into eta long beta normal form" #>
   319   setup (Binding.name "atomize") (Scan.succeed Object_Logic.declare_atomize)
   320     "declaration of atomize rule" #>
   321   setup (Binding.name "rulify") (Scan.succeed Object_Logic.declare_rulify)
   322     "declaration of rulify rule" #>
   323   setup (Binding.name "rotated") (Scan.lift rotated) "rotated theorem premises" #>
   324   setup (Binding.name "defn") (add_del Local_Defs.defn_add Local_Defs.defn_del)
   325     "declaration of definitional transformations" #>
   326   setup (Binding.name "abs_def") (Scan.succeed (Thm.rule_attribute (K Drule.abs_def)))
   327     "abstract over free variables of a definition"));
   328 
   329 
   330 
   331 (** configuration options **)
   332 
   333 (* naming *)
   334 
   335 structure Configs = Theory_Data
   336 (
   337   type T = Config.raw Symtab.table;
   338   val empty = Symtab.empty;
   339   val extend = I;
   340   fun merge data = Symtab.merge (K true) data;
   341 );
   342 
   343 fun print_configs ctxt =
   344   let
   345     val thy = Proof_Context.theory_of ctxt;
   346     fun prt (name, config) =
   347       let val value = Config.get ctxt config in
   348         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   349           Pretty.str (Config.print_value value)]
   350       end;
   351     val configs = Name_Space.extern_table ctxt (#1 (Attributes.get thy), Configs.get thy);
   352   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   353 
   354 
   355 (* concrete syntax *)
   356 
   357 local
   358 
   359 val equals = Parse.$$$ "=";
   360 
   361 fun scan_value (Config.Bool _) =
   362       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   363       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   364       Scan.succeed (Config.Bool true)
   365   | scan_value (Config.Int _) = equals |-- Parse.int >> Config.Int
   366   | scan_value (Config.Real _) = equals |-- Parse.real >> Config.Real
   367   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   368 
   369 fun scan_config thy config =
   370   let val config_type = Config.get_global thy config
   371   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   372 
   373 fun register binding config thy =
   374   let val name = Sign.full_name thy binding in
   375     thy
   376     |> setup binding (Scan.lift (scan_config thy config) >> Morphism.form) "configuration option"
   377     |> Configs.map (Symtab.update (name, config))
   378   end;
   379 
   380 fun declare make coerce binding default =
   381   let
   382     val name = Binding.name_of binding;
   383     val config_value = Config.declare_generic {global = false} name (make o default);
   384     val config = coerce config_value;
   385   in (config, register binding config_value) end;
   386 
   387 in
   388 
   389 val config_bool = declare Config.Bool Config.bool;
   390 val config_int = declare Config.Int Config.int;
   391 val config_real = declare Config.Real Config.real;
   392 val config_string = declare Config.String Config.string;
   393 
   394 fun register_config config = register (Binding.name (Config.name_of config)) config;
   395 
   396 end;
   397 
   398 
   399 (* implicit setup *)
   400 
   401 local
   402 
   403 fun setup_config declare_config binding default =
   404   let
   405     val (config, setup) = declare_config binding default;
   406     val _ = Context.>> (Context.map_theory setup);
   407   in config end;
   408 
   409 in
   410 
   411 val setup_config_bool = setup_config config_bool;
   412 val setup_config_int = setup_config config_int;
   413 val setup_config_string = setup_config config_string;
   414 val setup_config_real = setup_config config_real;
   415 
   416 end;
   417 
   418 
   419 (* theory setup *)
   420 
   421 val _ = Context.>> (Context.map_theory
   422  (register_config Ast.trace_raw #>
   423   register_config Ast.stats_raw #>
   424   register_config Syntax.positions_raw #>
   425   register_config Printer.show_brackets_raw #>
   426   register_config Printer.show_sorts_raw #>
   427   register_config Printer.show_types_raw #>
   428   register_config Printer.show_structs_raw #>
   429   register_config Printer.show_question_marks_raw #>
   430   register_config Syntax.ambiguity_level_raw #>
   431   register_config Syntax_Trans.eta_contract_raw #>
   432   register_config Name_Space.names_long_raw #>
   433   register_config Name_Space.names_short_raw #>
   434   register_config Name_Space.names_unique_raw #>
   435   register_config ML_Context.trace_raw #>
   436   register_config Proof_Context.show_abbrevs_raw #>
   437   register_config Goal_Display.goals_limit_raw #>
   438   register_config Goal_Display.show_main_goal_raw #>
   439   register_config Goal_Display.show_consts_raw #>
   440   register_config Display.show_hyps_raw #>
   441   register_config Display.show_tags_raw #>
   442   register_config Unify.trace_bound_raw #>
   443   register_config Unify.search_bound_raw #>
   444   register_config Unify.trace_simp_raw #>
   445   register_config Unify.trace_types_raw #>
   446   register_config Raw_Simplifier.simp_depth_limit_raw #>
   447   register_config Raw_Simplifier.simp_trace_depth_limit_raw #>
   448   register_config Raw_Simplifier.simp_debug_raw #>
   449   register_config Raw_Simplifier.simp_trace_raw));
   450 
   451 end;