src/HOLCF/Fixrec.thy
author huffman
Tue Nov 25 23:29:01 2008 +0100 (2008-11-25)
changeset 28891 f199def7a6a5
parent 26046 1624b3304bb9
child 29063 7619f0561cd7
permissions -rw-r--r--
separate run and cases combinators
     1 (*  Title:      HOLCF/Fixrec.thy
     2     ID:         $Id$
     3     Author:     Amber Telfer and Brian Huffman
     4 *)
     5 
     6 header "Package for defining recursive functions in HOLCF"
     7 
     8 theory Fixrec
     9 imports Sprod Ssum Up One Tr Fix
    10 uses ("Tools/fixrec_package.ML")
    11 begin
    12 
    13 subsection {* Maybe monad type *}
    14 
    15 defaultsort cpo
    16 
    17 pcpodef (open) 'a maybe = "UNIV::(one ++ 'a u) set"
    18 by simp
    19 
    20 constdefs
    21   fail :: "'a maybe"
    22   "fail \<equiv> Abs_maybe (sinl\<cdot>ONE)"
    23 
    24 constdefs
    25   return :: "'a \<rightarrow> 'a maybe" where
    26   "return \<equiv> \<Lambda> x. Abs_maybe (sinr\<cdot>(up\<cdot>x))"
    27 
    28 definition
    29   maybe_when :: "'b \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'a maybe \<rightarrow> 'b::pcpo" where
    30   "maybe_when = (\<Lambda> f r m. sscase\<cdot>(\<Lambda> x. f)\<cdot>(fup\<cdot>r)\<cdot>(Rep_maybe m))"
    31 
    32 lemma maybeE:
    33   "\<lbrakk>p = \<bottom> \<Longrightarrow> Q; p = fail \<Longrightarrow> Q; \<And>x. p = return\<cdot>x \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    34 apply (unfold fail_def return_def)
    35 apply (cases p, rename_tac r)
    36 apply (rule_tac p=r in ssumE, simp add: Abs_maybe_strict)
    37 apply (rule_tac p=x in oneE, simp, simp)
    38 apply (rule_tac p=y in upE, simp, simp add: cont_Abs_maybe)
    39 done
    40 
    41 lemma return_defined [simp]: "return\<cdot>x \<noteq> \<bottom>"
    42 by (simp add: return_def cont_Abs_maybe Abs_maybe_defined)
    43 
    44 lemma fail_defined [simp]: "fail \<noteq> \<bottom>"
    45 by (simp add: fail_def Abs_maybe_defined)
    46 
    47 lemma return_eq [simp]: "(return\<cdot>x = return\<cdot>y) = (x = y)"
    48 by (simp add: return_def cont_Abs_maybe Abs_maybe_inject)
    49 
    50 lemma return_neq_fail [simp]:
    51   "return\<cdot>x \<noteq> fail" "fail \<noteq> return\<cdot>x"
    52 by (simp_all add: return_def fail_def cont_Abs_maybe Abs_maybe_inject)
    53 
    54 lemma maybe_when_rews [simp]:
    55   "maybe_when\<cdot>f\<cdot>r\<cdot>\<bottom> = \<bottom>"
    56   "maybe_when\<cdot>f\<cdot>r\<cdot>fail = f"
    57   "maybe_when\<cdot>f\<cdot>r\<cdot>(return\<cdot>x) = r\<cdot>x"
    58 by (simp_all add: return_def fail_def maybe_when_def cont_Rep_maybe
    59                   cont_Abs_maybe Abs_maybe_inverse Rep_maybe_strict)
    60 
    61 translations
    62   "case m of fail \<Rightarrow> t1 | return\<cdot>x \<Rightarrow> t2" == "CONST maybe_when\<cdot>t1\<cdot>(\<Lambda> x. t2)\<cdot>m"
    63 
    64 
    65 subsubsection {* Monadic bind operator *}
    66 
    67 definition
    68   bind :: "'a maybe \<rightarrow> ('a \<rightarrow> 'b maybe) \<rightarrow> 'b maybe" where
    69   "bind = (\<Lambda> m f. case m of fail \<Rightarrow> fail | return\<cdot>x \<Rightarrow> f\<cdot>x)"
    70 
    71 text {* monad laws *}
    72 
    73 lemma bind_strict [simp]: "bind\<cdot>\<bottom>\<cdot>f = \<bottom>"
    74 by (simp add: bind_def)
    75 
    76 lemma bind_fail [simp]: "bind\<cdot>fail\<cdot>f = fail"
    77 by (simp add: bind_def)
    78 
    79 lemma left_unit [simp]: "bind\<cdot>(return\<cdot>a)\<cdot>k = k\<cdot>a"
    80 by (simp add: bind_def)
    81 
    82 lemma right_unit [simp]: "bind\<cdot>m\<cdot>return = m"
    83 by (rule_tac p=m in maybeE, simp_all)
    84 
    85 lemma bind_assoc:
    86  "bind\<cdot>(bind\<cdot>m\<cdot>k)\<cdot>h = bind\<cdot>m\<cdot>(\<Lambda> a. bind\<cdot>(k\<cdot>a)\<cdot>h)"
    87 by (rule_tac p=m in maybeE, simp_all)
    88 
    89 subsubsection {* Run operator *}
    90 
    91 definition
    92   run :: "'a maybe \<rightarrow> 'a::pcpo" where
    93   "run = maybe_when\<cdot>\<bottom>\<cdot>ID"
    94 
    95 text {* rewrite rules for run *}
    96 
    97 lemma run_strict [simp]: "run\<cdot>\<bottom> = \<bottom>"
    98 by (simp add: run_def)
    99 
   100 lemma run_fail [simp]: "run\<cdot>fail = \<bottom>"
   101 by (simp add: run_def)
   102 
   103 lemma run_return [simp]: "run\<cdot>(return\<cdot>x) = x"
   104 by (simp add: run_def)
   105 
   106 subsubsection {* Monad plus operator *}
   107 
   108 definition
   109   mplus :: "'a maybe \<rightarrow> 'a maybe \<rightarrow> 'a maybe" where
   110   "mplus = (\<Lambda> m1 m2. case m1 of fail \<Rightarrow> m2 | return\<cdot>x \<Rightarrow> m1)"
   111 
   112 abbreviation
   113   mplus_syn :: "['a maybe, 'a maybe] \<Rightarrow> 'a maybe"  (infixr "+++" 65)  where
   114   "m1 +++ m2 == mplus\<cdot>m1\<cdot>m2"
   115 
   116 text {* rewrite rules for mplus *}
   117 
   118 lemma mplus_strict [simp]: "\<bottom> +++ m = \<bottom>"
   119 by (simp add: mplus_def)
   120 
   121 lemma mplus_fail [simp]: "fail +++ m = m"
   122 by (simp add: mplus_def)
   123 
   124 lemma mplus_return [simp]: "return\<cdot>x +++ m = return\<cdot>x"
   125 by (simp add: mplus_def)
   126 
   127 lemma mplus_fail2 [simp]: "m +++ fail = m"
   128 by (rule_tac p=m in maybeE, simp_all)
   129 
   130 lemma mplus_assoc: "(x +++ y) +++ z = x +++ (y +++ z)"
   131 by (rule_tac p=x in maybeE, simp_all)
   132 
   133 subsubsection {* Fatbar combinator *}
   134 
   135 definition
   136   fatbar :: "('a \<rightarrow> 'b maybe) \<rightarrow> ('a \<rightarrow> 'b maybe) \<rightarrow> ('a \<rightarrow> 'b maybe)" where
   137   "fatbar = (\<Lambda> a b x. a\<cdot>x +++ b\<cdot>x)"
   138 
   139 abbreviation
   140   fatbar_syn :: "['a \<rightarrow> 'b maybe, 'a \<rightarrow> 'b maybe] \<Rightarrow> 'a \<rightarrow> 'b maybe" (infixr "\<parallel>" 60)  where
   141   "m1 \<parallel> m2 == fatbar\<cdot>m1\<cdot>m2"
   142 
   143 lemma fatbar1: "m\<cdot>x = \<bottom> \<Longrightarrow> (m \<parallel> ms)\<cdot>x = \<bottom>"
   144 by (simp add: fatbar_def)
   145 
   146 lemma fatbar2: "m\<cdot>x = fail \<Longrightarrow> (m \<parallel> ms)\<cdot>x = ms\<cdot>x"
   147 by (simp add: fatbar_def)
   148 
   149 lemma fatbar3: "m\<cdot>x = return\<cdot>y \<Longrightarrow> (m \<parallel> ms)\<cdot>x = return\<cdot>y"
   150 by (simp add: fatbar_def)
   151 
   152 lemmas fatbar_simps = fatbar1 fatbar2 fatbar3
   153 
   154 lemma run_fatbar1: "m\<cdot>x = \<bottom> \<Longrightarrow> run\<cdot>((m \<parallel> ms)\<cdot>x) = \<bottom>"
   155 by (simp add: fatbar_def)
   156 
   157 lemma run_fatbar2: "m\<cdot>x = fail \<Longrightarrow> run\<cdot>((m \<parallel> ms)\<cdot>x) = run\<cdot>(ms\<cdot>x)"
   158 by (simp add: fatbar_def)
   159 
   160 lemma run_fatbar3: "m\<cdot>x = return\<cdot>y \<Longrightarrow> run\<cdot>((m \<parallel> ms)\<cdot>x) = y"
   161 by (simp add: fatbar_def)
   162 
   163 lemmas run_fatbar_simps [simp] = run_fatbar1 run_fatbar2 run_fatbar3
   164 
   165 subsection {* Case branch combinator *}
   166 
   167 constdefs
   168   branch :: "('a \<rightarrow> 'b maybe) \<Rightarrow> ('b \<rightarrow> 'c) \<rightarrow> ('a \<rightarrow> 'c maybe)"
   169   "branch p \<equiv> \<Lambda> r x. bind\<cdot>(p\<cdot>x)\<cdot>(\<Lambda> y. return\<cdot>(r\<cdot>y))"
   170 
   171 lemma branch_rews:
   172   "p\<cdot>x = \<bottom> \<Longrightarrow> branch p\<cdot>r\<cdot>x = \<bottom>"
   173   "p\<cdot>x = fail \<Longrightarrow> branch p\<cdot>r\<cdot>x = fail"
   174   "p\<cdot>x = return\<cdot>y \<Longrightarrow> branch p\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>y)"
   175 by (simp_all add: branch_def)
   176 
   177 lemma branch_return [simp]: "branch return\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>x)"
   178 by (simp add: branch_def)
   179 
   180 subsubsection {* Cases operator *}
   181 
   182 definition
   183   cases :: "'a maybe \<rightarrow> 'a::pcpo" where
   184   "cases = maybe_when\<cdot>\<bottom>\<cdot>ID"
   185 
   186 text {* rewrite rules for cases *}
   187 
   188 lemma cases_strict [simp]: "cases\<cdot>\<bottom> = \<bottom>"
   189 by (simp add: cases_def)
   190 
   191 lemma cases_fail [simp]: "cases\<cdot>fail = \<bottom>"
   192 by (simp add: cases_def)
   193 
   194 lemma cases_return [simp]: "cases\<cdot>(return\<cdot>x) = x"
   195 by (simp add: cases_def)
   196 
   197 subsection {* Case syntax *}
   198 
   199 nonterminals
   200   Case_syn  Cases_syn
   201 
   202 syntax
   203   "_Case_syntax":: "['a, Cases_syn] => 'b"               ("(Case _ of/ _)" 10)
   204   "_Case1"      :: "['a, 'b] => Case_syn"                ("(2_ =>/ _)" 10)
   205   ""            :: "Case_syn => Cases_syn"               ("_")
   206   "_Case2"      :: "[Case_syn, Cases_syn] => Cases_syn"  ("_/ | _")
   207 
   208 syntax (xsymbols)
   209   "_Case1"      :: "['a, 'b] => Case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   210 
   211 translations
   212   "_Case_syntax x ms" == "CONST Fixrec.cases\<cdot>(ms\<cdot>x)"
   213   "_Case2 m ms" == "m \<parallel> ms"
   214 
   215 text {* Parsing Case expressions *}
   216 
   217 syntax
   218   "_pat" :: "'a"
   219   "_var" :: "'a"
   220   "_noargs" :: "'a"
   221 
   222 translations
   223   "_Case1 p r" => "CONST branch (_pat p)\<cdot>(_var p r)"
   224   "_var (_args x y) r" => "CONST csplit\<cdot>(_var x (_var y r))"
   225   "_var _noargs r" => "CONST unit_when\<cdot>r"
   226 
   227 parse_translation {*
   228 (* rewrites (_pat x) => (return) *)
   229 (* rewrites (_var x t) => (Abs_CFun (%x. t)) *)
   230   [("_pat", K (Syntax.const "Fixrec.return")),
   231    mk_binder_tr ("_var", "Abs_CFun")];
   232 *}
   233 
   234 text {* Printing Case expressions *}
   235 
   236 syntax
   237   "_match" :: "'a"
   238 
   239 print_translation {*
   240   let
   241     fun dest_LAM (Const (@{const_syntax Rep_CFun},_) $ Const (@{const_syntax unit_when},_) $ t) =
   242           (Syntax.const "_noargs", t)
   243     |   dest_LAM (Const (@{const_syntax Rep_CFun},_) $ Const (@{const_syntax csplit},_) $ t) =
   244           let
   245             val (v1, t1) = dest_LAM t;
   246             val (v2, t2) = dest_LAM t1;
   247           in (Syntax.const "_args" $ v1 $ v2, t2) end 
   248     |   dest_LAM (Const (@{const_syntax Abs_CFun},_) $ t) =
   249           let
   250             val abs = case t of Abs abs => abs
   251                 | _ => ("x", dummyT, incr_boundvars 1 t $ Bound 0);
   252             val (x, t') = atomic_abs_tr' abs;
   253           in (Syntax.const "_var" $ x, t') end
   254     |   dest_LAM _ = raise Match; (* too few vars: abort translation *)
   255 
   256     fun Case1_tr' [Const(@{const_syntax branch},_) $ p, r] =
   257           let val (v, t) = dest_LAM r;
   258           in Syntax.const "_Case1" $ (Syntax.const "_match" $ p $ v) $ t end;
   259 
   260   in [(@{const_syntax Rep_CFun}, Case1_tr')] end;
   261 *}
   262 
   263 translations
   264   "x" <= "_match Fixrec.return (_var x)"
   265 
   266 
   267 subsection {* Pattern combinators for data constructors *}
   268 
   269 types ('a, 'b) pat = "'a \<rightarrow> 'b maybe"
   270 
   271 definition
   272   cpair_pat :: "('a, 'c) pat \<Rightarrow> ('b, 'd) pat \<Rightarrow> ('a \<times> 'b, 'c \<times> 'd) pat" where
   273   "cpair_pat p1 p2 = (\<Lambda>\<langle>x, y\<rangle>.
   274     bind\<cdot>(p1\<cdot>x)\<cdot>(\<Lambda> a. bind\<cdot>(p2\<cdot>y)\<cdot>(\<Lambda> b. return\<cdot>\<langle>a, b\<rangle>)))"
   275 
   276 definition
   277   spair_pat ::
   278   "('a, 'c) pat \<Rightarrow> ('b, 'd) pat \<Rightarrow> ('a::pcpo \<otimes> 'b::pcpo, 'c \<times> 'd) pat" where
   279   "spair_pat p1 p2 = (\<Lambda>(:x, y:). cpair_pat p1 p2\<cdot>\<langle>x, y\<rangle>)"
   280 
   281 definition
   282   sinl_pat :: "('a, 'c) pat \<Rightarrow> ('a::pcpo \<oplus> 'b::pcpo, 'c) pat" where
   283   "sinl_pat p = sscase\<cdot>p\<cdot>(\<Lambda> x. fail)"
   284 
   285 definition
   286   sinr_pat :: "('b, 'c) pat \<Rightarrow> ('a::pcpo \<oplus> 'b::pcpo, 'c) pat" where
   287   "sinr_pat p = sscase\<cdot>(\<Lambda> x. fail)\<cdot>p"
   288 
   289 definition
   290   up_pat :: "('a, 'b) pat \<Rightarrow> ('a u, 'b) pat" where
   291   "up_pat p = fup\<cdot>p"
   292 
   293 definition
   294   TT_pat :: "(tr, unit) pat" where
   295   "TT_pat = (\<Lambda> b. If b then return\<cdot>() else fail fi)"
   296 
   297 definition
   298   FF_pat :: "(tr, unit) pat" where
   299   "FF_pat = (\<Lambda> b. If b then fail else return\<cdot>() fi)"
   300 
   301 definition
   302   ONE_pat :: "(one, unit) pat" where
   303   "ONE_pat = (\<Lambda> ONE. return\<cdot>())"
   304 
   305 text {* Parse translations (patterns) *}
   306 translations
   307   "_pat (XCONST cpair\<cdot>x\<cdot>y)" => "CONST cpair_pat (_pat x) (_pat y)"
   308   "_pat (XCONST spair\<cdot>x\<cdot>y)" => "CONST spair_pat (_pat x) (_pat y)"
   309   "_pat (XCONST sinl\<cdot>x)" => "CONST sinl_pat (_pat x)"
   310   "_pat (XCONST sinr\<cdot>x)" => "CONST sinr_pat (_pat x)"
   311   "_pat (XCONST up\<cdot>x)" => "CONST up_pat (_pat x)"
   312   "_pat (XCONST TT)" => "CONST TT_pat"
   313   "_pat (XCONST FF)" => "CONST FF_pat"
   314   "_pat (XCONST ONE)" => "CONST ONE_pat"
   315 
   316 text {* CONST version is also needed for constructors with special syntax *}
   317 translations
   318   "_pat (CONST cpair\<cdot>x\<cdot>y)" => "CONST cpair_pat (_pat x) (_pat y)"
   319   "_pat (CONST spair\<cdot>x\<cdot>y)" => "CONST spair_pat (_pat x) (_pat y)"
   320 
   321 text {* Parse translations (variables) *}
   322 translations
   323   "_var (XCONST cpair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   324   "_var (XCONST spair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   325   "_var (XCONST sinl\<cdot>x) r" => "_var x r"
   326   "_var (XCONST sinr\<cdot>x) r" => "_var x r"
   327   "_var (XCONST up\<cdot>x) r" => "_var x r"
   328   "_var (XCONST TT) r" => "_var _noargs r"
   329   "_var (XCONST FF) r" => "_var _noargs r"
   330   "_var (XCONST ONE) r" => "_var _noargs r"
   331 
   332 translations
   333   "_var (CONST cpair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   334   "_var (CONST spair\<cdot>x\<cdot>y) r" => "_var (_args x y) r"
   335 
   336 text {* Print translations *}
   337 translations
   338   "CONST cpair\<cdot>(_match p1 v1)\<cdot>(_match p2 v2)"
   339       <= "_match (CONST cpair_pat p1 p2) (_args v1 v2)"
   340   "CONST spair\<cdot>(_match p1 v1)\<cdot>(_match p2 v2)"
   341       <= "_match (CONST spair_pat p1 p2) (_args v1 v2)"
   342   "CONST sinl\<cdot>(_match p1 v1)" <= "_match (CONST sinl_pat p1) v1"
   343   "CONST sinr\<cdot>(_match p1 v1)" <= "_match (CONST sinr_pat p1) v1"
   344   "CONST up\<cdot>(_match p1 v1)" <= "_match (CONST up_pat p1) v1"
   345   "CONST TT" <= "_match (CONST TT_pat) _noargs"
   346   "CONST FF" <= "_match (CONST FF_pat) _noargs"
   347   "CONST ONE" <= "_match (CONST ONE_pat) _noargs"
   348 
   349 lemma cpair_pat1:
   350   "branch p\<cdot>r\<cdot>x = \<bottom> \<Longrightarrow> branch (cpair_pat p q)\<cdot>(csplit\<cdot>r)\<cdot>\<langle>x, y\<rangle> = \<bottom>"
   351 apply (simp add: branch_def cpair_pat_def)
   352 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   353 done
   354 
   355 lemma cpair_pat2:
   356   "branch p\<cdot>r\<cdot>x = fail \<Longrightarrow> branch (cpair_pat p q)\<cdot>(csplit\<cdot>r)\<cdot>\<langle>x, y\<rangle> = fail"
   357 apply (simp add: branch_def cpair_pat_def)
   358 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   359 done
   360 
   361 lemma cpair_pat3:
   362   "branch p\<cdot>r\<cdot>x = return\<cdot>s \<Longrightarrow>
   363    branch (cpair_pat p q)\<cdot>(csplit\<cdot>r)\<cdot>\<langle>x, y\<rangle> = branch q\<cdot>s\<cdot>y"
   364 apply (simp add: branch_def cpair_pat_def)
   365 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   366 apply (rule_tac p="q\<cdot>y" in maybeE, simp_all)
   367 done
   368 
   369 lemmas cpair_pat [simp] =
   370   cpair_pat1 cpair_pat2 cpair_pat3
   371 
   372 lemma spair_pat [simp]:
   373   "branch (spair_pat p1 p2)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   374   "\<lbrakk>x \<noteq> \<bottom>; y \<noteq> \<bottom>\<rbrakk>
   375      \<Longrightarrow> branch (spair_pat p1 p2)\<cdot>r\<cdot>(:x, y:) =
   376          branch (cpair_pat p1 p2)\<cdot>r\<cdot>\<langle>x, y\<rangle>"
   377 by (simp_all add: branch_def spair_pat_def)
   378 
   379 lemma sinl_pat [simp]:
   380   "branch (sinl_pat p)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   381   "x \<noteq> \<bottom> \<Longrightarrow> branch (sinl_pat p)\<cdot>r\<cdot>(sinl\<cdot>x) = branch p\<cdot>r\<cdot>x"
   382   "y \<noteq> \<bottom> \<Longrightarrow> branch (sinl_pat p)\<cdot>r\<cdot>(sinr\<cdot>y) = fail"
   383 by (simp_all add: branch_def sinl_pat_def)
   384 
   385 lemma sinr_pat [simp]:
   386   "branch (sinr_pat p)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   387   "x \<noteq> \<bottom> \<Longrightarrow> branch (sinr_pat p)\<cdot>r\<cdot>(sinl\<cdot>x) = fail"
   388   "y \<noteq> \<bottom> \<Longrightarrow> branch (sinr_pat p)\<cdot>r\<cdot>(sinr\<cdot>y) = branch p\<cdot>r\<cdot>y"
   389 by (simp_all add: branch_def sinr_pat_def)
   390 
   391 lemma up_pat [simp]:
   392   "branch (up_pat p)\<cdot>r\<cdot>\<bottom> = \<bottom>"
   393   "branch (up_pat p)\<cdot>r\<cdot>(up\<cdot>x) = branch p\<cdot>r\<cdot>x"
   394 by (simp_all add: branch_def up_pat_def)
   395 
   396 lemma TT_pat [simp]:
   397   "branch TT_pat\<cdot>(unit_when\<cdot>r)\<cdot>\<bottom> = \<bottom>"
   398   "branch TT_pat\<cdot>(unit_when\<cdot>r)\<cdot>TT = return\<cdot>r"
   399   "branch TT_pat\<cdot>(unit_when\<cdot>r)\<cdot>FF = fail"
   400 by (simp_all add: branch_def TT_pat_def)
   401 
   402 lemma FF_pat [simp]:
   403   "branch FF_pat\<cdot>(unit_when\<cdot>r)\<cdot>\<bottom> = \<bottom>"
   404   "branch FF_pat\<cdot>(unit_when\<cdot>r)\<cdot>TT = fail"
   405   "branch FF_pat\<cdot>(unit_when\<cdot>r)\<cdot>FF = return\<cdot>r"
   406 by (simp_all add: branch_def FF_pat_def)
   407 
   408 lemma ONE_pat [simp]:
   409   "branch ONE_pat\<cdot>(unit_when\<cdot>r)\<cdot>\<bottom> = \<bottom>"
   410   "branch ONE_pat\<cdot>(unit_when\<cdot>r)\<cdot>ONE = return\<cdot>r"
   411 by (simp_all add: branch_def ONE_pat_def)
   412 
   413 
   414 subsection {* Wildcards, as-patterns, and lazy patterns *}
   415 
   416 syntax
   417   "_as_pat" :: "[idt, 'a] \<Rightarrow> 'a" (infixr "\<as>" 10)
   418   "_lazy_pat" :: "'a \<Rightarrow> 'a" ("\<lazy> _" [1000] 1000)
   419 
   420 definition
   421   wild_pat :: "'a \<rightarrow> unit maybe" where
   422   "wild_pat = (\<Lambda> x. return\<cdot>())"
   423 
   424 definition
   425   as_pat :: "('a \<rightarrow> 'b maybe) \<Rightarrow> 'a \<rightarrow> ('a \<times> 'b) maybe" where
   426   "as_pat p = (\<Lambda> x. bind\<cdot>(p\<cdot>x)\<cdot>(\<Lambda> a. return\<cdot>\<langle>x, a\<rangle>))"
   427 
   428 definition
   429   lazy_pat :: "('a \<rightarrow> 'b::pcpo maybe) \<Rightarrow> ('a \<rightarrow> 'b maybe)" where
   430   "lazy_pat p = (\<Lambda> x. return\<cdot>(cases\<cdot>(p\<cdot>x)))"
   431 
   432 text {* Parse translations (patterns) *}
   433 translations
   434   "_pat _" => "CONST wild_pat"
   435   "_pat (_as_pat x y)" => "CONST as_pat (_pat y)"
   436   "_pat (_lazy_pat x)" => "CONST lazy_pat (_pat x)"
   437 
   438 text {* Parse translations (variables) *}
   439 translations
   440   "_var _ r" => "_var _noargs r"
   441   "_var (_as_pat x y) r" => "_var (_args x y) r"
   442   "_var (_lazy_pat x) r" => "_var x r"
   443 
   444 text {* Print translations *}
   445 translations
   446   "_" <= "_match (CONST wild_pat) _noargs"
   447   "_as_pat x (_match p v)" <= "_match (CONST as_pat p) (_args (_var x) v)"
   448   "_lazy_pat (_match p v)" <= "_match (CONST lazy_pat p) v"
   449 
   450 text {* Lazy patterns in lambda abstractions *}
   451 translations
   452   "_cabs (_lazy_pat p) r" == "CONST Fixrec.cases oo (_Case1 (_lazy_pat p) r)"
   453 
   454 lemma wild_pat [simp]: "branch wild_pat\<cdot>(unit_when\<cdot>r)\<cdot>x = return\<cdot>r"
   455 by (simp add: branch_def wild_pat_def)
   456 
   457 lemma as_pat [simp]:
   458   "branch (as_pat p)\<cdot>(csplit\<cdot>r)\<cdot>x = branch p\<cdot>(r\<cdot>x)\<cdot>x"
   459 apply (simp add: branch_def as_pat_def)
   460 apply (rule_tac p="p\<cdot>x" in maybeE, simp_all)
   461 done
   462 
   463 lemma lazy_pat [simp]:
   464   "branch p\<cdot>r\<cdot>x = \<bottom> \<Longrightarrow> branch (lazy_pat p)\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>\<bottom>)"
   465   "branch p\<cdot>r\<cdot>x = fail \<Longrightarrow> branch (lazy_pat p)\<cdot>r\<cdot>x = return\<cdot>(r\<cdot>\<bottom>)"
   466   "branch p\<cdot>r\<cdot>x = return\<cdot>s \<Longrightarrow> branch (lazy_pat p)\<cdot>r\<cdot>x = return\<cdot>s"
   467 apply (simp_all add: branch_def lazy_pat_def)
   468 apply (rule_tac [!] p="p\<cdot>x" in maybeE, simp_all)
   469 done
   470 
   471 
   472 subsection {* Match functions for built-in types *}
   473 
   474 defaultsort pcpo
   475 
   476 definition
   477   match_UU :: "'a \<rightarrow> unit maybe" where
   478   "match_UU = (\<Lambda> x. fail)"
   479 
   480 definition
   481   match_cpair :: "'a::cpo \<times> 'b::cpo \<rightarrow> ('a \<times> 'b) maybe" where
   482   "match_cpair = csplit\<cdot>(\<Lambda> x y. return\<cdot><x,y>)"
   483 
   484 definition
   485   match_spair :: "'a \<otimes> 'b \<rightarrow> ('a \<times> 'b) maybe" where
   486   "match_spair = ssplit\<cdot>(\<Lambda> x y. return\<cdot><x,y>)"
   487 
   488 definition
   489   match_sinl :: "'a \<oplus> 'b \<rightarrow> 'a maybe" where
   490   "match_sinl = sscase\<cdot>return\<cdot>(\<Lambda> y. fail)"
   491 
   492 definition
   493   match_sinr :: "'a \<oplus> 'b \<rightarrow> 'b maybe" where
   494   "match_sinr = sscase\<cdot>(\<Lambda> x. fail)\<cdot>return"
   495 
   496 definition
   497   match_up :: "'a::cpo u \<rightarrow> 'a maybe" where
   498   "match_up = fup\<cdot>return"
   499 
   500 definition
   501   match_ONE :: "one \<rightarrow> unit maybe" where
   502   "match_ONE = (\<Lambda> ONE. return\<cdot>())"
   503  
   504 definition
   505   match_TT :: "tr \<rightarrow> unit maybe" where
   506   "match_TT = (\<Lambda> b. If b then return\<cdot>() else fail fi)"
   507  
   508 definition
   509   match_FF :: "tr \<rightarrow> unit maybe" where
   510   "match_FF = (\<Lambda> b. If b then fail else return\<cdot>() fi)"
   511 
   512 lemma match_UU_simps [simp]:
   513   "match_UU\<cdot>x = fail"
   514 by (simp add: match_UU_def)
   515 
   516 lemma match_cpair_simps [simp]:
   517   "match_cpair\<cdot><x,y> = return\<cdot><x,y>"
   518 by (simp add: match_cpair_def)
   519 
   520 lemma match_spair_simps [simp]:
   521   "\<lbrakk>x \<noteq> \<bottom>; y \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> match_spair\<cdot>(:x,y:) = return\<cdot><x,y>"
   522   "match_spair\<cdot>\<bottom> = \<bottom>"
   523 by (simp_all add: match_spair_def)
   524 
   525 lemma match_sinl_simps [simp]:
   526   "x \<noteq> \<bottom> \<Longrightarrow> match_sinl\<cdot>(sinl\<cdot>x) = return\<cdot>x"
   527   "x \<noteq> \<bottom> \<Longrightarrow> match_sinl\<cdot>(sinr\<cdot>x) = fail"
   528   "match_sinl\<cdot>\<bottom> = \<bottom>"
   529 by (simp_all add: match_sinl_def)
   530 
   531 lemma match_sinr_simps [simp]:
   532   "x \<noteq> \<bottom> \<Longrightarrow> match_sinr\<cdot>(sinr\<cdot>x) = return\<cdot>x"
   533   "x \<noteq> \<bottom> \<Longrightarrow> match_sinr\<cdot>(sinl\<cdot>x) = fail"
   534   "match_sinr\<cdot>\<bottom> = \<bottom>"
   535 by (simp_all add: match_sinr_def)
   536 
   537 lemma match_up_simps [simp]:
   538   "match_up\<cdot>(up\<cdot>x) = return\<cdot>x"
   539   "match_up\<cdot>\<bottom> = \<bottom>"
   540 by (simp_all add: match_up_def)
   541 
   542 lemma match_ONE_simps [simp]:
   543   "match_ONE\<cdot>ONE = return\<cdot>()"
   544   "match_ONE\<cdot>\<bottom> = \<bottom>"
   545 by (simp_all add: match_ONE_def)
   546 
   547 lemma match_TT_simps [simp]:
   548   "match_TT\<cdot>TT = return\<cdot>()"
   549   "match_TT\<cdot>FF = fail"
   550   "match_TT\<cdot>\<bottom> = \<bottom>"
   551 by (simp_all add: match_TT_def)
   552 
   553 lemma match_FF_simps [simp]:
   554   "match_FF\<cdot>FF = return\<cdot>()"
   555   "match_FF\<cdot>TT = fail"
   556   "match_FF\<cdot>\<bottom> = \<bottom>"
   557 by (simp_all add: match_FF_def)
   558 
   559 subsection {* Mutual recursion *}
   560 
   561 text {*
   562   The following rules are used to prove unfolding theorems from
   563   fixed-point definitions of mutually recursive functions.
   564 *}
   565 
   566 lemma cpair_equalI: "\<lbrakk>x \<equiv> cfst\<cdot>p; y \<equiv> csnd\<cdot>p\<rbrakk> \<Longrightarrow> <x,y> \<equiv> p"
   567 by (simp add: surjective_pairing_Cprod2)
   568 
   569 lemma cpair_eqD1: "<x,y> = <x',y'> \<Longrightarrow> x = x'"
   570 by simp
   571 
   572 lemma cpair_eqD2: "<x,y> = <x',y'> \<Longrightarrow> y = y'"
   573 by simp
   574 
   575 text {* lemma for proving rewrite rules *}
   576 
   577 lemma ssubst_lhs: "\<lbrakk>t = s; P s = Q\<rbrakk> \<Longrightarrow> P t = Q"
   578 by simp
   579 
   580 
   581 subsection {* Initializing the fixrec package *}
   582 
   583 use "Tools/fixrec_package.ML"
   584 
   585 hide (open) const return bind fail run cases
   586 
   587 end