src/Tools/nbe.ML
author wenzelm
Sun Sep 12 19:04:02 2010 +0200 (2010-09-12)
changeset 39288 f1ae2493d93f
parent 39134 917b4b6ba3d2
child 39290 44e4d8dfd6bf
permissions -rw-r--r--
eliminated aliases of Type.constraint;
     1 (*  Title:      Tools/nbe.ML
     2     Authors:    Klaus Aehlig, LMU Muenchen; Tobias Nipkow, Florian Haftmann, TU Muenchen
     3 
     4 Normalization by evaluation, based on generic code generator.
     5 *)
     6 
     7 signature NBE =
     8 sig
     9   val dynamic_eval_conv: conv
    10   val dynamic_eval_value: theory -> term -> term
    11 
    12   datatype Univ =
    13       Const of int * Univ list               (*named (uninterpreted) constants*)
    14     | DFree of string * int                  (*free (uninterpreted) dictionary parameters*)
    15     | BVar of int * Univ list
    16     | Abs of (int * (Univ list -> Univ)) * Univ list
    17   val apps: Univ -> Univ list -> Univ        (*explicit applications*)
    18   val abss: int -> (Univ list -> Univ) -> Univ
    19                                              (*abstractions as closures*)
    20   val same: Univ -> Univ -> bool
    21 
    22   val univs_ref: (unit -> Univ list -> Univ list) option Unsynchronized.ref
    23   val trace: bool Unsynchronized.ref
    24 
    25   val setup: theory -> theory
    26   val add_const_alias: thm -> theory -> theory
    27 end;
    28 
    29 structure Nbe: NBE =
    30 struct
    31 
    32 (* generic non-sense *)
    33 
    34 val trace = Unsynchronized.ref false;
    35 fun traced f x = if !trace then (tracing (f x); x) else x;
    36 
    37 
    38 (** certificates and oracle for "trivial type classes" **)
    39 
    40 structure Triv_Class_Data = Theory_Data
    41 (
    42   type T = (class * thm) list;
    43   val empty = [];
    44   val extend = I;
    45   fun merge data : T = AList.merge (op =) (K true) data;
    46 );
    47 
    48 fun add_const_alias thm thy =
    49   let
    50     val (ofclass, eqn) = case try Logic.dest_equals (Thm.prop_of thm)
    51      of SOME ofclass_eq => ofclass_eq
    52       | _ => error ("Bad certificate: " ^ Display.string_of_thm_global thy thm);
    53     val (T, class) = case try Logic.dest_of_class ofclass
    54      of SOME T_class => T_class
    55       | _ => error ("Bad certificate: " ^ Display.string_of_thm_global thy thm);
    56     val tvar = case try Term.dest_TVar T
    57      of SOME (tvar as (_, sort)) => if null (filter (can (AxClass.get_info thy)) sort)
    58           then tvar
    59           else error ("Bad sort: " ^ Display.string_of_thm_global thy thm)
    60       | _ => error ("Bad type: " ^ Display.string_of_thm_global thy thm);
    61     val _ = if Term.add_tvars eqn [] = [tvar] then ()
    62       else error ("Inconsistent type: " ^ Display.string_of_thm_global thy thm);
    63     val lhs_rhs = case try Logic.dest_equals eqn
    64      of SOME lhs_rhs => lhs_rhs
    65       | _ => error ("Not an equation: " ^ Syntax.string_of_term_global thy eqn);
    66     val c_c' = case try (pairself (Code.check_const thy)) lhs_rhs
    67      of SOME c_c' => c_c'
    68       | _ => error ("Not an equation with two constants: "
    69           ^ Syntax.string_of_term_global thy eqn);
    70     val _ = if the_list (AxClass.class_of_param thy (snd c_c')) = [class] then ()
    71       else error ("Inconsistent class: " ^ Display.string_of_thm_global thy thm);
    72   in Triv_Class_Data.map (AList.update (op =) (class, thm)) thy end;
    73 
    74 local
    75 
    76 val get_triv_classes = map fst o Triv_Class_Data.get;
    77 
    78 val (_, triv_of_class) = Context.>>> (Context.map_theory_result
    79   (Thm.add_oracle (Binding.name "triv_of_class", fn (thy, T, class) =>
    80     Thm.cterm_of thy (Logic.mk_of_class (T, class)))));
    81 
    82 in
    83 
    84 fun lift_triv_classes_conv thy conv ct =
    85   let
    86     val algebra = Sign.classes_of thy;
    87     val certT = Thm.ctyp_of thy;
    88     val triv_classes = get_triv_classes thy;
    89     fun additional_classes sort = filter_out (fn class => Sorts.sort_le algebra (sort, [class])) triv_classes;
    90     fun mk_entry (v, sort) =
    91       let
    92         val T = TFree (v, sort);
    93         val cT = certT T;
    94         val triv_sort = additional_classes sort;
    95       in
    96         (v, (Sorts.inter_sort algebra (sort, triv_sort),
    97           (cT, AList.make (fn class => Thm.of_class (cT, class)) sort
    98             @ AList.make (fn class => triv_of_class (thy, T, class)) triv_sort)))
    99       end;
   100     val vs_tab = map mk_entry (Term.add_tfrees (Thm.term_of ct) []);
   101     fun instantiate thm =
   102       let
   103         val cert_tvars = map (certT o TVar) (Term.add_tvars
   104           ((fst o Logic.dest_equals o Logic.strip_imp_concl o Thm.prop_of) thm) []);
   105         val instantiation =
   106           map2 (fn cert_tvar => fn (_, (_, (cT, _))) => (cert_tvar, cT)) cert_tvars vs_tab;
   107       in Thm.instantiate (instantiation, []) thm end;
   108     fun of_class (TFree (v, _), class) =
   109           the (AList.lookup (op =) ((snd o snd o the o AList.lookup (op =) vs_tab) v) class)
   110       | of_class (T, _) = error ("Bad type " ^ Syntax.string_of_typ_global thy T);
   111     fun strip_of_class thm =
   112       let
   113         val prems_of_class = Thm.prop_of thm
   114           |> Logic.strip_imp_prems
   115           |> map (Logic.dest_of_class #> of_class);
   116       in fold Thm.elim_implies prems_of_class thm end;
   117   in
   118     ct
   119     |> (Drule.cterm_fun o map_types o map_type_tfree)
   120         (fn (v, sort) => TFree (v, (fst o the o AList.lookup (op =) vs_tab) v))
   121     |> conv
   122     |> Thm.strip_shyps
   123     |> Thm.varifyT_global
   124     |> Thm.unconstrainT
   125     |> instantiate
   126     |> strip_of_class
   127   end;
   128 
   129 fun lift_triv_classes_rew thy rew t =
   130   let
   131     val algebra = Sign.classes_of thy;
   132     val triv_classes = get_triv_classes thy;
   133     val vs = Term.add_tfrees t [];
   134   in t
   135     |> (map_types o map_type_tfree)
   136         (fn (v, sort) => TFree (v, Sorts.inter_sort algebra (sort, triv_classes)))
   137     |> rew
   138     |> (map_types o map_type_tfree)
   139         (fn (v, _) => TFree (v, the (AList.lookup (op =) vs v)))
   140   end;
   141 
   142 end;
   143 
   144 
   145 (** the semantic universe **)
   146 
   147 (*
   148    Functions are given by their semantical function value. To avoid
   149    trouble with the ML-type system, these functions have the most
   150    generic type, that is "Univ list -> Univ". The calling convention is
   151    that the arguments come as a list, the last argument first. In
   152    other words, a function call that usually would look like
   153 
   154    f x_1 x_2 ... x_n   or   f(x_1,x_2, ..., x_n)
   155 
   156    would be in our convention called as
   157 
   158               f [x_n,..,x_2,x_1]
   159 
   160    Moreover, to handle functions that are still waiting for some
   161    arguments we have additionally a list of arguments collected to far
   162    and the number of arguments we're still waiting for.
   163 *)
   164 
   165 datatype Univ =
   166     Const of int * Univ list           (*named (uninterpreted) constants*)
   167   | DFree of string * int              (*free (uninterpreted) dictionary parameters*)
   168   | BVar of int * Univ list            (*bound variables, named*)
   169   | Abs of (int * (Univ list -> Univ)) * Univ list
   170                                        (*abstractions as closures*);
   171 
   172 fun same (Const (k, xs)) (Const (l, ys)) = k = l andalso sames xs ys
   173   | same (DFree (s, k)) (DFree (t, l)) = s = t andalso k = l
   174   | same (BVar (k, xs)) (BVar (l, ys)) = k = l andalso sames xs ys
   175   | same _ _ = false
   176 and sames xs ys = length xs = length ys andalso forall (uncurry same) (xs ~~ ys);
   177 
   178 
   179 (* constructor functions *)
   180 
   181 fun abss n f = Abs ((n, f), []);
   182 fun apps (Abs ((n, f), xs)) ys = let val k = n - length ys in
   183       case int_ord (k, 0)
   184        of EQUAL => f (ys @ xs)
   185         | LESS => let val (zs, ws) = chop (~ k) ys in apps (f (ws @ xs)) zs end
   186         | GREATER => Abs ((k, f), ys @ xs) (*note: reverse convention also for apps!*)
   187       end
   188   | apps (Const (name, xs)) ys = Const (name, ys @ xs)
   189   | apps (BVar (n, xs)) ys = BVar (n, ys @ xs);
   190 
   191 
   192 (** assembling and compiling ML code from terms **)
   193 
   194 (* abstract ML syntax *)
   195 
   196 infix 9 `$` `$$`;
   197 fun e1 `$` e2 = "(" ^ e1 ^ " " ^ e2 ^ ")";
   198 fun e `$$` [] = e
   199   | e `$$` es = "(" ^ e ^ " " ^ space_implode " " es ^ ")";
   200 fun ml_abs v e = "(fn " ^ v ^ " => " ^ e ^ ")";
   201 
   202 fun ml_cases t cs =
   203   "(case " ^ t ^ " of " ^ space_implode " | " (map (fn (p, t) => p ^ " => " ^ t) cs) ^ ")";
   204 fun ml_Let d e = "let\n" ^ d ^ " in " ^ e ^ " end";
   205 fun ml_as v t = "(" ^ v ^ " as " ^ t ^ ")";
   206 
   207 fun ml_and [] = "true"
   208   | ml_and [x] = x
   209   | ml_and xs = "(" ^ space_implode " andalso " xs ^ ")";
   210 fun ml_if b x y = "(if " ^ b ^ " then " ^ x ^ " else " ^ y ^ ")";
   211 
   212 fun ml_list es = "[" ^ commas es ^ "]";
   213 
   214 fun ml_fundefs ([(name, [([], e)])]) =
   215       "val " ^ name ^ " = " ^ e ^ "\n"
   216   | ml_fundefs (eqs :: eqss) =
   217       let
   218         fun fundef (name, eqs) =
   219           let
   220             fun eqn (es, e) = name ^ " " ^ space_implode " " es ^ " = " ^ e
   221           in space_implode "\n  | " (map eqn eqs) end;
   222       in
   223         (prefix "fun " o fundef) eqs :: map (prefix "and " o fundef) eqss
   224         |> cat_lines
   225         |> suffix "\n"
   226       end;
   227 
   228 
   229 (* nbe specific syntax and sandbox communication *)
   230 
   231 val univs_ref = Unsynchronized.ref (NONE : (unit -> Univ list -> Univ list) option);
   232 
   233 local
   234   val prefix =      "Nbe.";
   235   val name_ref =    prefix ^ "univs_ref";
   236   val name_const =  prefix ^ "Const";
   237   val name_abss =   prefix ^ "abss";
   238   val name_apps =   prefix ^ "apps";
   239   val name_same =   prefix ^ "same";
   240 in
   241 
   242 val univs_cookie = (name_ref, univs_ref);
   243 
   244 fun nbe_fun 0 "" = "nbe_value"
   245   | nbe_fun i c = "c_" ^ translate_string (fn "." => "_" | c => c) c ^ "_" ^ string_of_int i;
   246 fun nbe_dict v n = "d_" ^ v ^ "_" ^ string_of_int n;
   247 fun nbe_bound v = "v_" ^ v;
   248 fun nbe_bound_optional NONE = "_"
   249   | nbe_bound_optional (SOME v) = nbe_bound v;
   250 fun nbe_default v = "w_" ^ v;
   251 
   252 (*note: these three are the "turning spots" where proper argument order is established!*)
   253 fun nbe_apps t [] = t
   254   | nbe_apps t ts = name_apps `$$` [t, ml_list (rev ts)];
   255 fun nbe_apps_local i c ts = nbe_fun i c `$` ml_list (rev ts);
   256 fun nbe_apps_constr idx_of c ts =
   257   let
   258     val c' = if !trace then string_of_int (idx_of c) ^ " (*" ^ c ^ "*)"
   259       else string_of_int (idx_of c);
   260   in name_const `$` ("(" ^ c' ^ ", " ^ ml_list (rev ts) ^ ")") end;
   261 
   262 fun nbe_abss 0 f = f `$` ml_list []
   263   | nbe_abss n f = name_abss `$$` [string_of_int n, f];
   264 
   265 fun nbe_same v1 v2 = "(" ^ name_same ^ " " ^ nbe_bound v1 ^ " " ^ nbe_bound v2 ^ ")";
   266 
   267 end;
   268 
   269 open Basic_Code_Thingol;
   270 
   271 
   272 (* code generation *)
   273 
   274 fun assemble_eqnss idx_of deps eqnss =
   275   let
   276     fun prep_eqns (c, (vs, eqns)) =
   277       let
   278         val dicts = maps (fn (v, sort) => map_index (nbe_dict v o fst) sort) vs;
   279         val num_args = length dicts + ((length o fst o hd) eqns);
   280       in (c, (num_args, (dicts, eqns))) end;
   281     val eqnss' = map prep_eqns eqnss;
   282 
   283     fun assemble_constapp c dss ts = 
   284       let
   285         val ts' = (maps o map) assemble_idict dss @ ts;
   286       in case AList.lookup (op =) eqnss' c
   287        of SOME (num_args, _) => if num_args <= length ts'
   288             then let val (ts1, ts2) = chop num_args ts'
   289             in nbe_apps (nbe_apps_local 0 c ts1) ts2
   290             end else nbe_apps (nbe_abss num_args (nbe_fun 0 c)) ts'
   291         | NONE => if member (op =) deps c
   292             then nbe_apps (nbe_fun 0 c) ts'
   293             else nbe_apps_constr idx_of c ts'
   294       end
   295     and assemble_idict (DictConst (inst, dss)) =
   296           assemble_constapp inst dss []
   297       | assemble_idict (DictVar (supers, (v, (n, _)))) =
   298           fold_rev (fn super => assemble_constapp super [] o single) supers (nbe_dict v n);
   299 
   300     fun assemble_iterm constapp =
   301       let
   302         fun of_iterm match_cont t =
   303           let
   304             val (t', ts) = Code_Thingol.unfold_app t
   305           in of_iapp match_cont t' (fold_rev (cons o of_iterm NONE) ts []) end
   306         and of_iapp match_cont (IConst (c, ((_, dss), _))) ts = constapp c dss ts
   307           | of_iapp match_cont (IVar v) ts = nbe_apps (nbe_bound_optional v) ts
   308           | of_iapp match_cont ((v, _) `|=> t) ts =
   309               nbe_apps (nbe_abss 1 (ml_abs (ml_list [nbe_bound_optional v]) (of_iterm NONE t))) ts
   310           | of_iapp match_cont (ICase (((t, _), cs), t0)) ts =
   311               nbe_apps (ml_cases (of_iterm NONE t)
   312                 (map (fn (p, t) => (of_iterm NONE p, of_iterm match_cont t)) cs
   313                   @ [("_", case match_cont of SOME s => s | NONE => of_iterm NONE t0)])) ts
   314       in of_iterm end;
   315 
   316     fun subst_nonlin_vars args =
   317       let
   318         val vs = (fold o Code_Thingol.fold_varnames)
   319           (fn v => AList.map_default (op =) (v, 0) (Integer.add 1)) args [];
   320         val names = Name.make_context (map fst vs);
   321         fun declare v k ctxt = let val vs = Name.invents ctxt v k
   322           in (vs, fold Name.declare vs ctxt) end;
   323         val (vs_renames, _) = fold_map (fn (v, k) => if k > 1
   324           then declare v (k - 1) #>> (fn vs => (v, vs))
   325           else pair (v, [])) vs names;
   326         val samepairs = maps (fn (v, vs) => map (pair v) vs) vs_renames;
   327         fun subst_vars (t as IConst _) samepairs = (t, samepairs)
   328           | subst_vars (t as IVar NONE) samepairs = (t, samepairs)
   329           | subst_vars (t as IVar (SOME v)) samepairs = (case AList.lookup (op =) samepairs v
   330              of SOME v' => (IVar (SOME v'), AList.delete (op =) v samepairs)
   331               | NONE => (t, samepairs))
   332           | subst_vars (t1 `$ t2) samepairs = samepairs
   333               |> subst_vars t1
   334               ||>> subst_vars t2
   335               |>> (op `$)
   336           | subst_vars (ICase (_, t)) samepairs = subst_vars t samepairs;
   337         val (args', _) = fold_map subst_vars args samepairs;
   338       in (samepairs, args') end;
   339 
   340     fun assemble_eqn c dicts default_args (i, (args, rhs)) =
   341       let
   342         val is_eval = (c = "");
   343         val default_rhs = nbe_apps_local (i+1) c (dicts @ default_args);
   344         val match_cont = if is_eval then NONE else SOME default_rhs;
   345         val assemble_arg = assemble_iterm
   346           (fn c => fn _ => fn ts => nbe_apps_constr idx_of c ts) NONE;
   347         val assemble_rhs = assemble_iterm assemble_constapp match_cont;
   348         val (samepairs, args') = subst_nonlin_vars args;
   349         val s_args = map assemble_arg args';
   350         val s_rhs = if null samepairs then assemble_rhs rhs
   351           else ml_if (ml_and (map (uncurry nbe_same) samepairs))
   352             (assemble_rhs rhs) default_rhs;
   353         val eqns = if is_eval then
   354             [([ml_list (rev (dicts @ s_args))], s_rhs)]
   355           else
   356             [([ml_list (rev (dicts @ map2 ml_as default_args s_args))], s_rhs),
   357               ([ml_list (rev (dicts @ default_args))], default_rhs)]
   358       in (nbe_fun i c, eqns) end;
   359 
   360     fun assemble_eqns (c, (num_args, (dicts, eqns))) =
   361       let
   362         val default_args = map nbe_default
   363           (Name.invent_list [] "a" (num_args - length dicts));
   364         val eqns' = map_index (assemble_eqn c dicts default_args) eqns
   365           @ (if c = "" then [] else [(nbe_fun (length eqns) c,
   366             [([ml_list (rev (dicts @ default_args))],
   367               nbe_apps_constr idx_of c (dicts @ default_args))])]);
   368       in (eqns', nbe_abss num_args (nbe_fun 0 c)) end;
   369 
   370     val (fun_vars, fun_vals) = map_split assemble_eqns eqnss';
   371     val deps_vars = ml_list (map (nbe_fun 0) deps);
   372   in ml_abs deps_vars (ml_Let (ml_fundefs (flat fun_vars)) (ml_list fun_vals)) end;
   373 
   374 
   375 (* code compilation *)
   376 
   377 fun compile_eqnss ctxt gr raw_deps [] = []
   378   | compile_eqnss ctxt gr raw_deps eqnss =
   379       let
   380         val (deps, deps_vals) = split_list (map_filter
   381           (fn dep => Option.map (fn univ => (dep, univ)) (fst ((Graph.get_node gr dep)))) raw_deps);
   382         val idx_of = raw_deps
   383           |> map (fn dep => (dep, snd (Graph.get_node gr dep)))
   384           |> AList.lookup (op =)
   385           |> (fn f => the o f);
   386         val s = assemble_eqnss idx_of deps eqnss;
   387         val cs = map fst eqnss;
   388       in
   389         s
   390         |> traced (fn s => "\n--- code to be evaluated:\n" ^ s)
   391         |> pair ""
   392         |> ML_Context.evaluate ctxt (!trace) univs_cookie
   393         |> (fn f => f deps_vals)
   394         |> (fn univs => cs ~~ univs)
   395       end;
   396 
   397 
   398 (* preparing function equations *)
   399 
   400 fun eqns_of_stmt (_, Code_Thingol.Fun (_, ((_, []), _))) =
   401       []
   402   | eqns_of_stmt (const, Code_Thingol.Fun (_, (((vs, _), eqns), _))) =
   403       [(const, (vs, map fst eqns))]
   404   | eqns_of_stmt (_, Code_Thingol.Datatypecons _) =
   405       []
   406   | eqns_of_stmt (_, Code_Thingol.Datatype _) =
   407       []
   408   | eqns_of_stmt (class, Code_Thingol.Class (_, (v, (super_classes, classparams)))) =
   409       let
   410         val names = map snd super_classes @ map fst classparams;
   411         val params = Name.invent_list [] "d" (length names);
   412         fun mk (k, name) =
   413           (name, ([(v, [])],
   414             [([IConst (class, (([], []), [])) `$$ map (IVar o SOME) params],
   415               IVar (SOME (nth params k)))]));
   416       in map_index mk names end
   417   | eqns_of_stmt (_, Code_Thingol.Classrel _) =
   418       []
   419   | eqns_of_stmt (_, Code_Thingol.Classparam _) =
   420       []
   421   | eqns_of_stmt (inst, Code_Thingol.Classinst ((class, (_, arity_args)), (super_instances, (classparam_instances, _)))) =
   422       [(inst, (arity_args, [([], IConst (class, (([], []), [])) `$$
   423         map (fn (_, (_, (inst, dss))) => IConst (inst, (([], dss), []))) super_instances
   424         @ map (IConst o snd o fst) classparam_instances)]))];
   425 
   426 fun compile_stmts ctxt stmts_deps =
   427   let
   428     val names = map (fst o fst) stmts_deps;
   429     val names_deps = map (fn ((name, _), deps) => (name, deps)) stmts_deps;
   430     val eqnss = maps (eqns_of_stmt o fst) stmts_deps;
   431     val refl_deps = names_deps
   432       |> maps snd
   433       |> distinct (op =)
   434       |> fold (insert (op =)) names;
   435     fun new_node name (gr, (maxidx, idx_tab)) = if can (Graph.get_node gr) name
   436       then (gr, (maxidx, idx_tab))
   437       else (Graph.new_node (name, (NONE, maxidx)) gr,
   438         (maxidx + 1, Inttab.update_new (maxidx, name) idx_tab));
   439     fun compile gr = eqnss
   440       |> compile_eqnss ctxt gr refl_deps
   441       |> rpair gr;
   442   in
   443     fold new_node refl_deps
   444     #> apfst (fold (fn (name, deps) => fold (curry Graph.add_edge name) deps) names_deps
   445       #> compile
   446       #-> fold (fn (name, univ) => (Graph.map_node name o apfst) (K (SOME univ))))
   447   end;
   448 
   449 fun ensure_stmts ctxt program =
   450   let
   451     fun add_stmts names (gr, (maxidx, idx_tab)) = if exists ((can o Graph.get_node) gr) names
   452       then (gr, (maxidx, idx_tab))
   453       else (gr, (maxidx, idx_tab))
   454         |> compile_stmts ctxt (map (fn name => ((name, Graph.get_node program name),
   455           Graph.imm_succs program name)) names);
   456   in
   457     fold_rev add_stmts (Graph.strong_conn program)
   458   end;
   459 
   460 
   461 (** evaluation **)
   462 
   463 (* term evaluation *)
   464 
   465 fun eval_term ctxt gr deps (vs : (string * sort) list, t) =
   466   let 
   467     val dict_frees = maps (fn (v, sort) => map_index (curry DFree v o fst) sort) vs;
   468   in
   469     ("", (vs, [([], t)]))
   470     |> singleton (compile_eqnss ctxt gr deps)
   471     |> snd
   472     |> (fn t => apps t (rev dict_frees))
   473   end;
   474 
   475 
   476 (* reification *)
   477 
   478 fun typ_of_itype program vs (ityco `%% itys) =
   479       let
   480         val Code_Thingol.Datatype (tyco, _) = Graph.get_node program ityco;
   481       in Type (tyco, map (typ_of_itype program vs) itys) end
   482   | typ_of_itype program vs (ITyVar v) =
   483       let
   484         val sort = (the o AList.lookup (op =) vs) v;
   485       in TFree ("'" ^ v, sort) end;
   486 
   487 fun term_of_univ thy program idx_tab t =
   488   let
   489     fun take_until f [] = []
   490       | take_until f (x::xs) = if f x then [] else x :: take_until f xs;
   491     fun is_dict (Const (idx, _)) = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   492          of Code_Thingol.Class _ => true
   493           | Code_Thingol.Classrel _ => true
   494           | Code_Thingol.Classinst _ => true
   495           | _ => false)
   496       | is_dict (DFree _) = true
   497       | is_dict _ = false;
   498     fun const_of_idx idx = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   499      of Code_Thingol.Fun (c, _) => c
   500       | Code_Thingol.Datatypecons (c, _) => c
   501       | Code_Thingol.Classparam (c, _) => c);
   502     fun of_apps bounds (t, ts) =
   503       fold_map (of_univ bounds) ts
   504       #>> (fn ts' => list_comb (t, rev ts'))
   505     and of_univ bounds (Const (idx, ts)) typidx =
   506           let
   507             val ts' = take_until is_dict ts;
   508             val c = const_of_idx idx;
   509             val T = map_type_tvar (fn ((v, i), _) =>
   510               Type_Infer.param typidx (v ^ string_of_int i, []))
   511                 (Sign.the_const_type thy c);
   512             val typidx' = typidx + 1;
   513           in of_apps bounds (Term.Const (c, T), ts') typidx' end
   514       | of_univ bounds (BVar (n, ts)) typidx =
   515           of_apps bounds (Bound (bounds - n - 1), ts) typidx
   516       | of_univ bounds (t as Abs _) typidx =
   517           typidx
   518           |> of_univ (bounds + 1) (apps t [BVar (bounds, [])])
   519           |-> (fn t' => pair (Term.Abs ("u", dummyT, t')))
   520   in of_univ 0 t 0 |> fst end;
   521 
   522 
   523 (* function store *)
   524 
   525 structure Nbe_Functions = Code_Data
   526 (
   527   type T = (Univ option * int) Graph.T * (int * string Inttab.table);
   528   val empty = (Graph.empty, (0, Inttab.empty));
   529 );
   530 
   531 
   532 (* compilation, evaluation and reification *)
   533 
   534 fun compile_eval thy program =
   535   let
   536     val ctxt = ProofContext.init_global thy;
   537     val (gr, (_, idx_tab)) =
   538       Nbe_Functions.change thy (ensure_stmts ctxt program);
   539   in fn vs_t => fn deps =>
   540     vs_t
   541     |> eval_term ctxt gr deps
   542     |> term_of_univ thy program idx_tab
   543   end;
   544 
   545 
   546 (* evaluation with type reconstruction *)
   547 
   548 fun normalize thy program ((vs0, (vs, ty)), t) deps =
   549   let
   550     val ty' = typ_of_itype program vs0 ty;
   551     fun type_infer t =
   552       singleton (Type_Infer.infer_types (Syntax.pp_global thy) (Sign.tsig_of thy) I
   553         (try (Type.strip_sorts o Sign.the_const_type thy)) (K NONE) Name.context 0)
   554       (Type.constraint ty' t);
   555     val string_of_term =
   556       Syntax.string_of_term (Config.put show_types true (Syntax.init_pretty_global thy));
   557     fun check_tvars t =
   558       if null (Term.add_tvars t []) then t
   559       else error ("Illegal schematic type variables in normalized term: " ^ string_of_term t);
   560   in
   561     compile_eval thy program (vs, t) deps
   562     |> traced (fn t => "Normalized:\n" ^ string_of_term t)
   563     |> type_infer
   564     |> traced (fn t => "Types inferred:\n" ^ string_of_term t)
   565     |> check_tvars
   566     |> traced (fn _ => "---\n")
   567   end;
   568 
   569 
   570 (* evaluation oracle *)
   571 
   572 fun mk_equals thy lhs raw_rhs =
   573   let
   574     val ty = Thm.typ_of (Thm.ctyp_of_term lhs);
   575     val eq = Thm.cterm_of thy (Term.Const ("==", ty --> ty --> propT));
   576     val rhs = Thm.cterm_of thy raw_rhs;
   577   in Thm.mk_binop eq lhs rhs end;
   578 
   579 val (_, raw_oracle) = Context.>>> (Context.map_theory_result
   580   (Thm.add_oracle (Binding.name "norm", fn (thy, program, vsp_ty_t, deps, ct) =>
   581     mk_equals thy ct (normalize thy program vsp_ty_t deps))));
   582 
   583 fun oracle thy program vsp_ty_t deps ct = raw_oracle (thy, program, vsp_ty_t, deps, ct);
   584 
   585 fun no_frees_rew rew t =
   586   let
   587     val frees = map Free (Term.add_frees t []);
   588   in
   589     t
   590     |> fold_rev lambda frees
   591     |> rew
   592     |> curry (Term.betapplys o swap) frees
   593   end;
   594 
   595 val dynamic_eval_conv = Code_Simp.no_frees_conv (Conv.tap_thy
   596   (fn thy => lift_triv_classes_conv thy (Code_Thingol.dynamic_eval_conv thy (K (oracle thy)))));
   597 
   598 fun dynamic_eval_value thy = lift_triv_classes_rew thy
   599   (no_frees_rew (Code_Thingol.dynamic_eval_value thy I (K (normalize thy))));
   600 
   601 
   602 (* evaluation command *)
   603 
   604 fun norm_print_term ctxt modes t =
   605   let
   606     val thy = ProofContext.theory_of ctxt;
   607     val t' = dynamic_eval_value thy t;
   608     val ty' = Term.type_of t';
   609     val ctxt' = Variable.auto_fixes t ctxt;
   610     val p = Print_Mode.with_modes modes (fn () =>
   611       Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t'), Pretty.fbrk,
   612         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' ty')]) ();
   613   in Pretty.writeln p end;
   614 
   615 
   616 (** Isar setup **)
   617 
   618 fun norm_print_term_cmd (modes, s) state =
   619   let val ctxt = Toplevel.context_of state
   620   in norm_print_term ctxt modes (Syntax.read_term ctxt s) end;
   621 
   622 val setup = Value.add_evaluator ("nbe", dynamic_eval_value o ProofContext.theory_of);
   623 
   624 val opt_modes =
   625   Scan.optional (Parse.$$$ "(" |-- Parse.!!! (Scan.repeat1 Parse.xname --| Parse.$$$ ")")) [];
   626 
   627 val _ =
   628   Outer_Syntax.improper_command "normal_form" "normalize term by evaluation" Keyword.diag
   629     (opt_modes -- Parse.term >> (Toplevel.keep o norm_print_term_cmd));
   630 
   631 end;
   632