src/HOL/Complete_Lattice.thy
author haftmann
Sat Jul 16 22:28:35 2011 +0200 (2011-07-16)
changeset 43854 f1d23df1adde
parent 43853 020ddc6a9508
child 43865 db18f4d0cc7d
permissions -rw-r--r--
generalized some lemmas
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty [simp]:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty [simp]:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_UNIV [simp]:
    56   "\<Sqinter>UNIV = \<bottom>"
    57   by (simp add: Sup_Inf Sup_empty [symmetric])
    58 
    59 lemma Sup_UNIV [simp]:
    60   "\<Squnion>UNIV = \<top>"
    61   by (simp add: Inf_Sup Inf_empty [symmetric])
    62 
    63 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    64   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    65 
    66 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    67   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    68 
    69 lemma Inf_singleton [simp]:
    70   "\<Sqinter>{a} = a"
    71   by (auto intro: antisym Inf_lower Inf_greatest)
    72 
    73 lemma Sup_singleton [simp]:
    74   "\<Squnion>{a} = a"
    75   by (auto intro: antisym Sup_upper Sup_least)
    76 
    77 lemma Inf_binary:
    78   "\<Sqinter>{a, b} = a \<sqinter> b"
    79   by (simp add: Inf_insert)
    80 
    81 lemma Sup_binary:
    82   "\<Squnion>{a, b} = a \<squnion> b"
    83   by (simp add: Sup_insert)
    84 
    85 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    86   by (auto intro: Inf_greatest dest: Inf_lower)
    87 
    88 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    89   by (auto intro: Sup_least dest: Sup_upper)
    90 
    91 lemma Inf_mono:
    92   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
    93   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
    94 proof (rule Inf_greatest)
    95   fix b assume "b \<in> B"
    96   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
    97   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
    98   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
    99 qed
   100 
   101 lemma Sup_mono:
   102   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   103   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   104 proof (rule Sup_least)
   105   fix a assume "a \<in> A"
   106   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   107   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   108   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   109 qed
   110 
   111 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   112   using Sup_upper[of u A] by auto
   113 
   114 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   115   using Inf_lower[of u A] by auto
   116 
   117 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   118   "INFI A f = \<Sqinter> (f ` A)"
   119 
   120 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   121   "SUPR A f = \<Squnion> (f ` A)"
   122 
   123 end
   124 
   125 syntax
   126   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
   127   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   128   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
   129   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   130 
   131 syntax (xsymbols)
   132   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   133   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   134   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   135   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   136 
   137 translations
   138   "INF x y. B"   == "INF x. INF y. B"
   139   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   140   "INF x. B"     == "INF x:CONST UNIV. B"
   141   "INF x:A. B"   == "CONST INFI A (%x. B)"
   142   "SUP x y. B"   == "SUP x. SUP y. B"
   143   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   144   "SUP x. B"     == "SUP x:CONST UNIV. B"
   145   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   146 
   147 print_translation {*
   148   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   149     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   150 *} -- {* to avoid eta-contraction of body *}
   151 
   152 context complete_lattice
   153 begin
   154 
   155 lemma SUP_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> SUPR A f = SUPR A g"
   156   by (simp add: SUPR_def cong: image_cong)
   157 
   158 lemma INF_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> INFI A f = INFI A g"
   159   by (simp add: INFI_def cong: image_cong)
   160 
   161 lemma le_SUPI: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   162   by (auto simp add: SUPR_def intro: Sup_upper)
   163 
   164 lemma le_SUPI2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> M i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   165   using le_SUPI[of i A M] by auto
   166 
   167 lemma SUP_leI: "(\<And>i. i \<in> A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. M i) \<sqsubseteq> u"
   168   by (auto simp add: SUPR_def intro: Sup_least)
   169 
   170 lemma INF_leI: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> M i"
   171   by (auto simp add: INFI_def intro: Inf_lower)
   172 
   173 lemma INF_leI2: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> u"
   174   using INF_leI[of i A M] by auto
   175 
   176 lemma le_INFI: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. M i)"
   177   by (auto simp add: INFI_def intro: Inf_greatest)
   178 
   179 lemma SUP_le_iff: "(\<Squnion>i\<in>A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   180   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   181 
   182 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   183   unfolding INFI_def by (auto simp add: le_Inf_iff)
   184 
   185 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. M) = M"
   186   by (auto intro: antisym INF_leI le_INFI)
   187 
   188 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. M) = M"
   189   by (auto intro: antisym SUP_leI le_SUPI)
   190 
   191 lemma INF_mono:
   192   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   193   by (force intro!: Inf_mono simp: INFI_def)
   194 
   195 lemma SUP_mono:
   196   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   197   by (force intro!: Sup_mono simp: SUPR_def)
   198 
   199 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<sqsubseteq> INFI A f"
   200   by (intro INF_mono) auto
   201 
   202 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<sqsubseteq> SUPR B f"
   203   by (intro SUP_mono) auto
   204 
   205 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   206   by (iprover intro: INF_leI le_INFI order_trans antisym)
   207 
   208 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   209   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   210 
   211 lemma INFI_insert: "(\<Sqinter>x\<in>insert a A. B x) = B a \<sqinter> INFI A B"
   212   by (simp add: INFI_def Inf_insert)
   213 
   214 lemma SUPR_insert: "(\<Squnion>x\<in>insert a A. B x) = B a \<squnion> SUPR A B"
   215   by (simp add: SUPR_def Sup_insert)
   216 
   217 end
   218 
   219 lemma Inf_less_iff:
   220   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   221   shows "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   222   unfolding not_le [symmetric] le_Inf_iff by auto
   223 
   224 lemma less_Sup_iff:
   225   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   226   shows "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   227   unfolding not_le [symmetric] Sup_le_iff by auto
   228 
   229 lemma INF_less_iff:
   230   fixes a :: "'a::{complete_lattice,linorder}"
   231   shows "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   232   unfolding INFI_def Inf_less_iff by auto
   233 
   234 lemma less_SUP_iff:
   235   fixes a :: "'a::{complete_lattice,linorder}"
   236   shows "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   237   unfolding SUPR_def less_Sup_iff by auto
   238 
   239 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   240 
   241 instantiation bool :: complete_lattice
   242 begin
   243 
   244 definition
   245   "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   246 
   247 definition
   248   "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   249 
   250 instance proof
   251 qed (auto simp add: Inf_bool_def Sup_bool_def)
   252 
   253 end
   254 
   255 lemma INFI_bool_eq [simp]:
   256   "INFI = Ball"
   257 proof (rule ext)+
   258   fix A :: "'a set"
   259   fix P :: "'a \<Rightarrow> bool"
   260   show "(\<Sqinter>x\<in>A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
   261     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   262 qed
   263 
   264 lemma SUPR_bool_eq [simp]:
   265   "SUPR = Bex"
   266 proof (rule ext)+
   267   fix A :: "'a set"
   268   fix P :: "'a \<Rightarrow> bool"
   269   show "(\<Squnion>x\<in>A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P x)"
   270     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   271 qed
   272 
   273 instantiation "fun" :: (type, complete_lattice) complete_lattice
   274 begin
   275 
   276 definition
   277   "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   278 
   279 lemma Inf_apply:
   280   "(\<Sqinter>A) x = \<Sqinter>{y. \<exists>f\<in>A. y = f x}"
   281   by (simp add: Inf_fun_def)
   282 
   283 definition
   284   "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   285 
   286 lemma Sup_apply:
   287   "(\<Squnion>A) x = \<Squnion>{y. \<exists>f\<in>A. y = f x}"
   288   by (simp add: Sup_fun_def)
   289 
   290 instance proof
   291 qed (auto simp add: le_fun_def Inf_apply Sup_apply
   292   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   293 
   294 end
   295 
   296 lemma INFI_apply:
   297   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   298   by (auto intro: arg_cong [of _ _ Inf] simp add: INFI_def Inf_apply)
   299 
   300 lemma SUPR_apply:
   301   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   302   by (auto intro: arg_cong [of _ _ Sup] simp add: SUPR_def Sup_apply)
   303 
   304 
   305 subsection {* Inter *}
   306 
   307 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   308   "Inter S \<equiv> \<Sqinter>S"
   309   
   310 notation (xsymbols)
   311   Inter  ("\<Inter>_" [90] 90)
   312 
   313 lemma Inter_eq:
   314   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   315 proof (rule set_eqI)
   316   fix x
   317   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   318     by auto
   319   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   320     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   321 qed
   322 
   323 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   324   by (unfold Inter_eq) blast
   325 
   326 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   327   by (simp add: Inter_eq)
   328 
   329 text {*
   330   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   331   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   332   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   333 *}
   334 
   335 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   336   by auto
   337 
   338 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   339   -- {* ``Classical'' elimination rule -- does not require proving
   340     @{prop "X \<in> C"}. *}
   341   by (unfold Inter_eq) blast
   342 
   343 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   344   by (fact Inf_lower)
   345 
   346 lemma (in complete_lattice) Inf_less_eq:
   347   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   348     and "A \<noteq> {}"
   349   shows "\<Sqinter>A \<sqsubseteq> u"
   350 proof -
   351   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   352   moreover with assms have "v \<sqsubseteq> u" by blast
   353   ultimately show ?thesis by (rule Inf_lower2)
   354 qed
   355 
   356 lemma Inter_subset:
   357   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   358   by (fact Inf_less_eq)
   359 
   360 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   361   by (fact Inf_greatest)
   362 
   363 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   364   by (fact Inf_binary [symmetric])
   365 
   366 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   367   by (fact Inf_empty)
   368 
   369 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   370   by (fact Inf_UNIV)
   371 
   372 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   373   by (fact Inf_insert)
   374 
   375 lemma (in complete_lattice) Inf_inter_less: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   376   by (auto intro: Inf_greatest Inf_lower)
   377 
   378 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   379   by (fact Inf_inter_less)
   380 
   381 lemma (in complete_lattice) Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   382   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   383 
   384 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   385   by (fact Inf_union_distrib)
   386 
   387 lemma (in complete_lattice) Inf_top_conv [no_atp]:
   388   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   389   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   390 proof -
   391   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   392   proof
   393     assume "\<forall>x\<in>A. x = \<top>"
   394     then have "A = {} \<or> A = {\<top>}" by auto
   395     then show "\<Sqinter>A = \<top>" by auto
   396   next
   397     assume "\<Sqinter>A = \<top>"
   398     show "\<forall>x\<in>A. x = \<top>"
   399     proof (rule ccontr)
   400       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   401       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   402       then obtain B where "A = insert x B" by blast
   403       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by (simp add: Inf_insert)
   404     qed
   405   qed
   406   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   407 qed
   408 
   409 lemma Inter_UNIV_conv [simp,no_atp]:
   410   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   411   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   412   by (fact Inf_top_conv)+
   413 
   414 lemma (in complete_lattice) Inf_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   415   by (auto intro: Inf_greatest Inf_lower)
   416 
   417 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   418   by (fact Inf_anti_mono)
   419 
   420 
   421 subsection {* Intersections of families *}
   422 
   423 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   424   "INTER \<equiv> INFI"
   425 
   426 syntax
   427   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   428   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   429 
   430 syntax (xsymbols)
   431   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   432   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   433 
   434 syntax (latex output)
   435   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   436   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   437 
   438 translations
   439   "INT x y. B"  == "INT x. INT y. B"
   440   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   441   "INT x. B"    == "INT x:CONST UNIV. B"
   442   "INT x:A. B"  == "CONST INTER A (%x. B)"
   443 
   444 print_translation {*
   445   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   446 *} -- {* to avoid eta-contraction of body *}
   447 
   448 lemma INTER_eq_Inter_image:
   449   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   450   by (fact INFI_def)
   451   
   452 lemma Inter_def:
   453   "\<Inter>S = (\<Inter>x\<in>S. x)"
   454   by (simp add: INTER_eq_Inter_image image_def)
   455 
   456 lemma INTER_def:
   457   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   458   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   459 
   460 lemma Inter_image_eq [simp]:
   461   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   462   by (rule sym) (fact INFI_def)
   463 
   464 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   465   by (unfold INTER_def) blast
   466 
   467 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   468   by (unfold INTER_def) blast
   469 
   470 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   471   by auto
   472 
   473 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   474   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   475   by (unfold INTER_def) blast
   476 
   477 lemma (in complete_lattice) INFI_cong:
   478   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Sqinter>x\<in>A. C x) = (\<Sqinter>x\<in>B. D x)"
   479   by (simp add: INFI_def image_def)
   480 
   481 lemma INT_cong [cong]:
   482   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   483   by (fact INFI_cong)
   484 
   485 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   486   by blast
   487 
   488 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   489   by blast
   490 
   491 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   492   by (fact INF_leI)
   493 
   494 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   495   by (fact le_INFI)
   496 
   497 lemma (in complete_lattice) INFI_empty:
   498   "(\<Sqinter>x\<in>{}. B x) = \<top>"
   499   by (simp add: INFI_def)
   500 
   501 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   502   by (fact INFI_empty)
   503 
   504 lemma (in complete_lattice) INFI_absorb:
   505   assumes "k \<in> I"
   506   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   507 proof -
   508   from assms obtain J where "I = insert k J" by blast
   509   then show ?thesis by (simp add: INFI_insert)
   510 qed
   511 
   512 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   513   by (fact INFI_absorb)
   514 
   515 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   516   by (fact le_INF_iff)
   517 
   518 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   519   by (fact INFI_insert)
   520 
   521 -- {* continue generalization from here *}
   522 
   523 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   524   by blast
   525 
   526 lemma INT_insert_distrib:
   527     "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   528   by blast
   529 
   530 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   531   by auto
   532 
   533 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   534   -- {* Look: it has an \emph{existential} quantifier *}
   535   by blast
   536 
   537 lemma INTER_UNIV_conv [simp]:
   538  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   539  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   540   by blast+
   541 
   542 lemma INT_bool_eq: "(\<Inter>b. A b) = (A True \<inter> A False)"
   543   by (auto intro: bool_induct)
   544 
   545 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   546   by blast
   547 
   548 lemma INT_anti_mono:
   549   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
   550     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   551   -- {* The last inclusion is POSITIVE! *}
   552   by (blast dest: subsetD)
   553 
   554 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   555   by blast
   556 
   557 
   558 subsection {* Union *}
   559 
   560 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   561   "Union S \<equiv> \<Squnion>S"
   562 
   563 notation (xsymbols)
   564   Union  ("\<Union>_" [90] 90)
   565 
   566 lemma Union_eq:
   567   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   568 proof (rule set_eqI)
   569   fix x
   570   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   571     by auto
   572   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   573     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   574 qed
   575 
   576 lemma Union_iff [simp, no_atp]:
   577   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   578   by (unfold Union_eq) blast
   579 
   580 lemma UnionI [intro]:
   581   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   582   -- {* The order of the premises presupposes that @{term C} is rigid;
   583     @{term A} may be flexible. *}
   584   by auto
   585 
   586 lemma UnionE [elim!]:
   587   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   588   by auto
   589 
   590 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   591   by (iprover intro: subsetI UnionI)
   592 
   593 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   594   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   595 
   596 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   597   by blast
   598 
   599 lemma Union_empty [simp]: "\<Union>{} = {}"
   600   by blast
   601 
   602 lemma Union_UNIV [simp]: "\<Union>UNIV = UNIV"
   603   by blast
   604 
   605 lemma Union_insert [simp]: "\<Union>insert a B = a \<union> \<Union>B"
   606   by blast
   607 
   608 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
   609   by blast
   610 
   611 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   612   by blast
   613 
   614 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   615   by blast
   616 
   617 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   618   by blast
   619 
   620 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
   621   by blast
   622 
   623 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   624   by blast
   625 
   626 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   627   by blast
   628 
   629 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
   630   by blast
   631 
   632 
   633 subsection {* Unions of families *}
   634 
   635 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   636   "UNION \<equiv> SUPR"
   637 
   638 syntax
   639   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   640   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   641 
   642 syntax (xsymbols)
   643   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   644   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   645 
   646 syntax (latex output)
   647   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   648   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   649 
   650 translations
   651   "UN x y. B"   == "UN x. UN y. B"
   652   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   653   "UN x. B"     == "UN x:CONST UNIV. B"
   654   "UN x:A. B"   == "CONST UNION A (%x. B)"
   655 
   656 text {*
   657   Note the difference between ordinary xsymbol syntax of indexed
   658   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   659   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   660   former does not make the index expression a subscript of the
   661   union/intersection symbol because this leads to problems with nested
   662   subscripts in Proof General.
   663 *}
   664 
   665 print_translation {*
   666   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   667 *} -- {* to avoid eta-contraction of body *}
   668 
   669 lemma UNION_eq_Union_image:
   670   "(\<Union>x\<in>A. B x) = \<Union>(B ` A)"
   671   by (fact SUPR_def)
   672 
   673 lemma Union_def:
   674   "\<Union>S = (\<Union>x\<in>S. x)"
   675   by (simp add: UNION_eq_Union_image image_def)
   676 
   677 lemma UNION_def [no_atp]:
   678   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   679   by (auto simp add: UNION_eq_Union_image Union_eq)
   680   
   681 lemma Union_image_eq [simp]:
   682   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
   683   by (rule sym) (fact UNION_eq_Union_image)
   684   
   685 lemma UN_iff [simp]: "(b \<in> (\<Union>x\<in>A. B x)) = (\<exists>x\<in>A. b \<in> B x)"
   686   by (unfold UNION_def) blast
   687 
   688 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
   689   -- {* The order of the premises presupposes that @{term A} is rigid;
   690     @{term b} may be flexible. *}
   691   by auto
   692 
   693 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
   694   by (unfold UNION_def) blast
   695 
   696 lemma UN_cong [cong]:
   697     "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   698   by (simp add: UNION_def)
   699 
   700 lemma strong_UN_cong:
   701     "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   702   by (simp add: UNION_def simp_implies_def)
   703 
   704 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
   705   by blast
   706 
   707 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
   708   by (fact le_SUPI)
   709 
   710 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
   711   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   712 
   713 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   714   by blast
   715 
   716 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   717   by blast
   718 
   719 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   720   by blast
   721 
   722 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   723   by blast
   724 
   725 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   726   by blast
   727 
   728 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   729   by auto
   730 
   731 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   732   by blast
   733 
   734 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   735   by blast
   736 
   737 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   738   by blast
   739 
   740 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   741   by (fact SUP_le_iff)
   742 
   743 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   744   by blast
   745 
   746 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   747   by auto
   748 
   749 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   750   by blast
   751 
   752 lemma UNION_empty_conv[simp]:
   753   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   754   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   755 by blast+
   756 
   757 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   758   by blast
   759 
   760 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   761   by blast
   762 
   763 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   764   by blast
   765 
   766 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   767   by (auto simp add: split_if_mem2)
   768 
   769 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
   770   by (auto intro: bool_contrapos)
   771 
   772 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   773   by blast
   774 
   775 lemma UN_mono:
   776   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
   777     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   778   by (blast dest: subsetD)
   779 
   780 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
   781   by blast
   782 
   783 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
   784   by blast
   785 
   786 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
   787   -- {* NOT suitable for rewriting *}
   788   by blast
   789 
   790 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
   791   by blast
   792 
   793 
   794 subsection {* Distributive laws *}
   795 
   796 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   797   by blast
   798 
   799 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   800   by blast
   801 
   802 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
   803   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   804   -- {* Union of a family of unions *}
   805   by blast
   806 
   807 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   808   -- {* Equivalent version *}
   809   by blast
   810 
   811 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   812   by blast
   813 
   814 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
   815   by blast
   816 
   817 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   818   -- {* Equivalent version *}
   819   by blast
   820 
   821 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   822   -- {* Halmos, Naive Set Theory, page 35. *}
   823   by blast
   824 
   825 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   826   by blast
   827 
   828 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   829   by blast
   830 
   831 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   832   by blast
   833 
   834 
   835 subsection {* Complement *}
   836 
   837 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   838   by blast
   839 
   840 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   841   by blast
   842 
   843 
   844 subsection {* Miniscoping and maxiscoping *}
   845 
   846 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   847            and Intersections. *}
   848 
   849 lemma UN_simps [simp]:
   850   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
   851   "\<And>A B C. (\<Union>x\<in>C. A x \<union>  B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
   852   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
   853   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter>B)"
   854   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
   855   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
   856   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
   857   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
   858   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
   859   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
   860   by auto
   861 
   862 lemma INT_simps [simp]:
   863   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter>B)"
   864   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
   865   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
   866   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
   867   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
   868   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
   869   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
   870   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
   871   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
   872   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
   873   by auto
   874 
   875 lemma ball_simps [simp,no_atp]:
   876   "\<And>A P Q. (\<forall>x\<in>A. P x \<or> Q) \<longleftrightarrow> ((\<forall>x\<in>A. P x) \<or> Q)"
   877   "\<And>A P Q. (\<forall>x\<in>A. P \<or> Q x) \<longleftrightarrow> (P \<or> (\<forall>x\<in>A. Q x))"
   878   "\<And>A P Q. (\<forall>x\<in>A. P \<longrightarrow> Q x) \<longleftrightarrow> (P \<longrightarrow> (\<forall>x\<in>A. Q x))"
   879   "\<And>A P Q. (\<forall>x\<in>A. P x \<longrightarrow> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<longrightarrow> Q)"
   880   "\<And>P. (\<forall>x\<in>{}. P x) \<longleftrightarrow> True"
   881   "\<And>P. (\<forall>x\<in>UNIV. P x) \<longleftrightarrow> (\<forall>x. P x)"
   882   "\<And>a B P. (\<forall>x\<in>insert a B. P x) \<longleftrightarrow> (P a \<and> (\<forall>x\<in>B. P x))"
   883   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
   884   "\<And>A B P. (\<forall>x\<in> UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
   885   "\<And>P Q. (\<forall>x\<in>Collect Q. P x) \<longleftrightarrow> (\<forall>x. Q x \<longrightarrow> P x)"
   886   "\<And>A P f. (\<forall>x\<in>f`A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P (f x))"
   887   "\<And>A P. (\<not> (\<forall>x\<in>A. P x)) \<longleftrightarrow> (\<exists>x\<in>A. \<not> P x)"
   888   by auto
   889 
   890 lemma bex_simps [simp,no_atp]:
   891   "\<And>A P Q. (\<exists>x\<in>A. P x \<and> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<and> Q)"
   892   "\<And>A P Q. (\<exists>x\<in>A. P \<and> Q x) \<longleftrightarrow> (P \<and> (\<exists>x\<in>A. Q x))"
   893   "\<And>P. (\<exists>x\<in>{}. P x) \<longleftrightarrow> False"
   894   "\<And>P. (\<exists>x\<in>UNIV. P x) \<longleftrightarrow> (\<exists>x. P x)"
   895   "\<And>a B P. (\<exists>x\<in>insert a B. P x) \<longleftrightarrow> (P a | (\<exists>x\<in>B. P x))"
   896   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
   897   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
   898   "\<And>P Q. (\<exists>x\<in>Collect Q. P x) \<longleftrightarrow> (\<exists>x. Q x \<and> P x)"
   899   "\<And>A P f. (\<exists>x\<in>f`A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P (f x))"
   900   "\<And>A P. (\<not>(\<exists>x\<in>A. P x)) \<longleftrightarrow> (\<forall>x\<in>A. \<not> P x)"
   901   by auto
   902 
   903 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   904 
   905 lemma UN_extend_simps:
   906   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
   907   "\<And>A B C. (\<Union>x\<in>C. A x) \<union>  B  = (if C={} then B else (\<Union>x\<in>C. A x \<union>  B))"
   908   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
   909   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
   910   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
   911   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
   912   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
   913   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
   914   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
   915   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
   916   by auto
   917 
   918 lemma INT_extend_simps:
   919   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
   920   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
   921   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
   922   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
   923   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
   924   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
   925   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
   926   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
   927   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
   928   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
   929   by auto
   930 
   931 
   932 no_notation
   933   less_eq  (infix "\<sqsubseteq>" 50) and
   934   less (infix "\<sqsubset>" 50) and
   935   bot ("\<bottom>") and
   936   top ("\<top>") and
   937   inf  (infixl "\<sqinter>" 70) and
   938   sup  (infixl "\<squnion>" 65) and
   939   Inf  ("\<Sqinter>_" [900] 900) and
   940   Sup  ("\<Squnion>_" [900] 900)
   941 
   942 no_syntax (xsymbols)
   943   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   944   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   945   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   946   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   947 
   948 lemmas mem_simps =
   949   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   950   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   951   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   952 
   953 end