src/Pure/library.ML
author wenzelm
Wed Oct 01 17:32:38 1997 +0200 (1997-10-01)
changeset 3762 f20b071a429a
parent 3699 7c30ab9e25d1
child 3832 17a20a2af8f5
permissions -rw-r--r--
added split_last;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic tables, balanced trees,
     8 orders, input / output, timing, filenames, misc functions.
     9 *)
    10 
    11 infix |> ~~ \ \\ orelf ins ins_string ins_int orf andf prefix upto downto
    12       mem mem_int mem_string union union_int union_string  
    13       inter inter_int inter_string subset subset_int subset_string subdir_of;
    14 
    15 
    16 structure Library =
    17 struct
    18 
    19 (** functions **)
    20 
    21 (*handy combinators*)
    22 fun curry f x y = f (x, y);
    23 fun uncurry f (x, y) = f x y;
    24 fun I x = x;
    25 fun K x y = x;
    26 
    27 (*reverse apply*)
    28 fun (x |> f) = f x;
    29 
    30 (*combine two functions forming the union of their domains*)
    31 fun (f orelf g) = fn x => f x handle Match => g x;
    32 
    33 (*application of (infix) operator to its left or right argument*)
    34 fun apl (x, f) y = f (x, y);
    35 fun apr (f, y) x = f (x, y);
    36 
    37 (*functional for pairs*)
    38 fun pairself f (x, y) = (f x, f y);
    39 
    40 (*function exponentiation: f(...(f x)...) with n applications of f*)
    41 fun funpow n f x =
    42   let fun rep (0, x) = x
    43         | rep (n, x) = rep (n - 1, f x)
    44   in rep (n, x) end;
    45 
    46 
    47 
    48 (** stamps **)
    49 
    50 type stamp = unit ref;
    51 val stamp: unit -> stamp = ref;
    52 
    53 
    54 
    55 (** options **)
    56 
    57 datatype 'a option = None | Some of 'a;
    58 
    59 exception OPTION of string;
    60 
    61 fun the (Some x) = x
    62   | the None = raise OPTION "the";
    63 
    64 fun if_none None y = y
    65   | if_none (Some x) _ = x;
    66 
    67 fun is_some (Some _) = true
    68   | is_some None = false;
    69 
    70 fun is_none (Some _) = false
    71   | is_none None = true;
    72 
    73 fun apsome f (Some x) = Some (f x)
    74   | apsome _ None = None;
    75 
    76 
    77 
    78 (** pairs **)
    79 
    80 fun pair x y = (x, y);
    81 fun rpair x y = (y, x);
    82 
    83 fun fst (x, y) = x;
    84 fun snd (x, y) = y;
    85 
    86 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
    87 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
    88 
    89 fun swap (x, y) = (y, x);
    90 
    91 (*apply the function to a component of a pair*)
    92 fun apfst f (x, y) = (f x, y);
    93 fun apsnd f (x, y) = (x, f y);
    94 
    95 
    96 
    97 (** booleans **)
    98 
    99 (* equality *)
   100 
   101 fun equal x y = x = y;
   102 fun not_equal x y = x <> y;
   103 
   104 
   105 (* operators for combining predicates *)
   106 
   107 fun (p orf q) = fn x => p x orelse q x;
   108 
   109 fun (p andf q) = fn x => p x andalso q x;
   110 
   111 fun notf p x = not (p x);
   112 
   113 
   114 (* predicates on lists *)
   115 
   116 fun orl [] = false
   117   | orl (x :: xs) = x orelse orl xs;
   118 
   119 fun andl [] = true
   120   | andl (x :: xs) = x andalso andl xs;
   121 
   122 (*Several object-logics declare theories named List or Option, hiding the
   123   eponymous basis library structures.*)
   124 structure List_ = List
   125 and       Option_ = Option;
   126 
   127 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   128 fun exists (pred: 'a -> bool) : 'a list -> bool =
   129   let fun boolf [] = false
   130         | boolf (x :: xs) = pred x orelse boolf xs
   131   in boolf end;
   132 
   133 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   134 fun forall (pred: 'a -> bool) : 'a list -> bool =
   135   let fun boolf [] = true
   136         | boolf (x :: xs) = pred x andalso boolf xs
   137   in boolf end;
   138 
   139 
   140 (* flags *)
   141 
   142 fun set flag = (flag := true; true);
   143 fun reset flag = (flag := false; false);
   144 fun toggle flag = (flag := not (! flag); ! flag);
   145 
   146 fun setmp flag value f x =
   147   let
   148     val orig_value = ! flag;
   149     fun return y = (flag := orig_value; y);
   150   in
   151     flag := value;
   152     return (f x handle exn => (return (); raise exn))
   153   end;
   154 
   155 
   156 
   157 (** lists **)
   158 
   159 exception LIST of string;
   160 
   161 fun null [] = true
   162   | null (_ :: _) = false;
   163 
   164 fun hd [] = raise LIST "hd"
   165   | hd (x :: _) = x;
   166 
   167 fun tl [] = raise LIST "tl"
   168   | tl (_ :: xs) = xs;
   169 
   170 fun cons x xs = x :: xs;
   171 
   172 
   173 (* fold *)
   174 
   175 (*the following versions of fold are designed to fit nicely with infixes*)
   176 
   177 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   178     for operators that associate to the left (TAIL RECURSIVE)*)
   179 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   180   let fun itl (e, [])  = e
   181         | itl (e, a::l) = itl (f(e, a), l)
   182   in  itl end;
   183 
   184 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   185     for operators that associate to the right (not tail recursive)*)
   186 fun foldr f (l, e) =
   187   let fun itr [] = e
   188         | itr (a::l) = f(a, itr l)
   189   in  itr l  end;
   190 
   191 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   192     for n > 0, operators that associate to the right (not tail recursive)*)
   193 fun foldr1 f l =
   194   let fun itr [x] = x                       (* FIXME [] case: elim warn (?) *)
   195         | itr (x::l) = f(x, itr l)
   196   in  itr l  end;
   197 
   198 
   199 (* basic list functions *)
   200 
   201 (*length of a list, should unquestionably be a standard function*)
   202 local fun length1 (n, [])  = n   (*TAIL RECURSIVE*)
   203         | length1 (n, x :: xs) = length1 (n + 1, xs)
   204 in  fun length l = length1 (0, l) end;
   205 
   206 (*take the first n elements from a list*)
   207 fun take (n, []) = []
   208   | take (n, x :: xs) =
   209       if n > 0 then x :: take (n - 1, xs) else [];
   210 
   211 (*drop the first n elements from a list*)
   212 fun drop (n, []) = []
   213   | drop (n, x :: xs) =
   214       if n > 0 then drop (n - 1, xs) else x :: xs;
   215 
   216 (*return nth element of a list, where 0 designates the first element;
   217   raise EXCEPTION if list too short*)
   218 fun nth_elem NL =
   219   (case drop NL of
   220     [] => raise LIST "nth_elem"
   221   | x :: _ => x);
   222 
   223 (*last element of a list*)
   224 fun last_elem [] = raise LIST "last_elem"
   225   | last_elem [x] = x
   226   | last_elem (_ :: xs) = last_elem xs;
   227 
   228 (*rear decomposition*)
   229 fun split_last [] = raise LIST "split_last"
   230   | split_last [x] = ([], x)
   231   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   232 
   233 
   234 (*find the position of an element in a list*)
   235 fun find (x, ys) =
   236   let fun f (y :: ys, i) = if x = y then i else f (ys, i + 1)
   237         | f (_, _) = raise LIST "find"
   238   in f (ys, 0) end;
   239 
   240 (*flatten a list of lists to a list*)
   241 fun flat (ls: 'c list list) : 'c list = foldr (op @) (ls, []);
   242 
   243 
   244 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   245   (proc x1; ...; proc xn) for side effects*)
   246 fun seq (proc: 'a -> unit) : 'a list -> unit =
   247   let fun seqf [] = ()
   248         | seqf (x :: xs) = (proc x; seqf xs)
   249   in seqf end;
   250 
   251 
   252 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   253 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   254   | separate _ xs = xs;
   255 
   256 (*make the list [x, x, ..., x] of length n*)
   257 fun replicate n (x: 'a) : 'a list =
   258   let fun rep (0, xs) = xs
   259         | rep (n, xs) = rep (n - 1, x :: xs)
   260   in
   261     if n < 0 then raise LIST "replicate"
   262     else rep (n, [])
   263   end;
   264 
   265 
   266 (* filter *)
   267 
   268 (*copy the list preserving elements that satisfy the predicate*)
   269 fun filter (pred: 'a->bool) : 'a list -> 'a list =
   270   let fun filt [] = []
   271         | filt (x :: xs) = if pred x then x :: filt xs else filt xs
   272   in filt end;
   273 
   274 fun filter_out f = filter (not o f);
   275 
   276 
   277 fun mapfilter (f: 'a -> 'b option) ([]: 'a list) = [] : 'b list
   278   | mapfilter f (x :: xs) =
   279       (case f x of
   280         None => mapfilter f xs
   281       | Some y => y :: mapfilter f xs);
   282 
   283 
   284 fun find_first _ [] = None
   285   | find_first pred (x :: xs) =
   286       if pred x then Some x else find_first pred xs;
   287 
   288 
   289 (* lists of pairs *)
   290 
   291 fun map2 _ ([], []) = []
   292   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   293   | map2 _ _ = raise LIST "map2";
   294 
   295 fun exists2 _ ([], []) = false
   296   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   297   | exists2 _ _ = raise LIST "exists2";
   298 
   299 fun forall2 _ ([], []) = true
   300   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   301   | forall2 _ _ = raise LIST "forall2";
   302 
   303 (*combine two lists forming a list of pairs:
   304   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   305 fun [] ~~ [] = []
   306   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   307   | _ ~~ _ = raise LIST "~~";
   308 
   309 
   310 (*inverse of ~~; the old 'split':
   311   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   312 fun split_list (l: ('a * 'b) list) = (map #1 l, map #2 l);
   313 
   314 
   315 (* prefixes, suffixes *)
   316 
   317 fun [] prefix _ = true
   318   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   319   | _ prefix _ = false;
   320 
   321 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   322    where xi is the first element that does not satisfy the predicate*)
   323 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   324   let fun take (rxs, []) = (rev rxs, [])
   325         | take (rxs, x :: xs) =
   326             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   327   in  take([], xs)  end;
   328 
   329 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   330    where xi is the last element that does not satisfy the predicate*)
   331 fun take_suffix _ [] = ([], [])
   332   | take_suffix pred (x :: xs) =
   333       (case take_suffix pred xs of
   334         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   335       | (prfx, sffx) => (x :: prfx, sffx));
   336 
   337 
   338 
   339 (** integers **)
   340 
   341 fun inc i = (i := ! i + 1; ! i);
   342 fun dec i = (i := ! i - 1; ! i);
   343 
   344 
   345 (* lists of integers *)
   346 
   347 (*make the list [from, from + 1, ..., to]*)
   348 fun (from upto to) =
   349   if from > to then [] else from :: ((from + 1) upto to);
   350 
   351 (*make the list [from, from - 1, ..., to]*)
   352 fun (from downto to) =
   353   if from < to then [] else from :: ((from - 1) downto to);
   354 
   355 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   356 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   357   | downto0 ([], n) = n = ~1;
   358 
   359 
   360 (* convert integers to strings *)
   361 
   362 (*expand the number in the given base;
   363   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   364 fun radixpand (base, num) : int list =
   365   let
   366     fun radix (n, tail) =
   367       if n < base then n :: tail
   368       else radix (n div base, (n mod base) :: tail)
   369   in radix (num, []) end;
   370 
   371 (*expands a number into a string of characters starting from "zerochar";
   372   example: radixstring (2, "0", 8) gives "1000"*)
   373 fun radixstring (base, zerochar, num) =
   374   let val offset = ord zerochar;
   375       fun chrof n = chr (offset + n)
   376   in implode (map chrof (radixpand (base, num))) end;
   377 
   378 
   379 val string_of_int = Int.toString;
   380 
   381 fun string_of_indexname (a,0) = a
   382   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   383 
   384 
   385 (** strings **)
   386 
   387 fun is_letter ch =
   388   ord "A" <= ord ch andalso ord ch <= ord "Z" orelse
   389   ord "a" <= ord ch andalso ord ch <= ord "z";
   390 
   391 fun is_digit ch =
   392   ord "0" <= ord ch andalso ord ch <= ord "9";
   393 
   394 (*letter or _ or prime (')*)
   395 fun is_quasi_letter "_" = true
   396   | is_quasi_letter "'" = true
   397   | is_quasi_letter ch = is_letter ch;
   398 
   399 (*white space: blanks, tabs, newlines, formfeeds*)
   400 val is_blank : string -> bool =
   401   fn " " => true | "\t" => true | "\n" => true | "\^L" => true | "\160" => true
   402     | _ => false;
   403 
   404 val is_letdig = is_quasi_letter orf is_digit;
   405 
   406 (*printable chars*)
   407 fun is_printable c = ord c > ord " " andalso ord c <= ord "~";
   408 
   409 
   410 (*lower all chars of string*)
   411 val to_lower =
   412   let
   413     fun lower ch =
   414       if ch >= "A" andalso ch <= "Z" then
   415         chr (ord ch - ord "A" + ord "a")
   416       else ch;
   417   in implode o (map lower) o explode end;
   418 
   419 
   420 (*enclose in brackets*)
   421 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   422 
   423 (*simple quoting (does not escape special chars)*)
   424 val quote = enclose "\"" "\"";
   425 
   426 (*space_implode "..." (explode "hello"); gives "h...e...l...l...o"*)
   427 fun space_implode a bs = implode (separate a bs);
   428 
   429 val commas = space_implode ", ";
   430 val commas_quote = commas o map quote;
   431 
   432 (*concatenate messages, one per line, into a string*)
   433 val cat_lines = space_implode "\n";
   434 
   435 (*space_explode "." "h.e..l.lo"; gives ["h", "e", "l", "lo"]*)
   436 fun space_explode sep s =
   437   let fun divide [] "" = []
   438         | divide [] part = [part]
   439         | divide (c::s) part =
   440             if c = sep then
   441               (if part = "" then divide s "" else part :: divide s "")
   442             else divide s (part ^ c)
   443   in divide (explode s) "" end;
   444 
   445 
   446 (** lists as sets **)
   447 
   448 (*membership in a list*)
   449 fun x mem [] = false
   450   | x mem (y :: ys) = x = y orelse x mem ys;
   451 
   452 (*membership in a list, optimized version for ints*)
   453 fun (x:int) mem_int [] = false
   454   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   455 
   456 (*membership in a list, optimized version for strings*)
   457 fun (x:string) mem_string [] = false
   458   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   459 
   460 (*generalized membership test*)
   461 fun gen_mem eq (x, []) = false
   462   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   463 
   464 
   465 (*insertion into list if not already there*)
   466 fun (x ins xs) = if x mem xs then xs else x :: xs;
   467 
   468 (*insertion into list, optimized version for ints*)
   469 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   470 
   471 (*insertion into list, optimized version for strings*)
   472 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   473 
   474 (*generalized insertion*)
   475 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   476 
   477 
   478 (*union of sets represented as lists: no repetitions*)
   479 fun xs union [] = xs
   480   | [] union ys = ys
   481   | (x :: xs) union ys = xs union (x ins ys);
   482 
   483 (*union of sets, optimized version for ints*)
   484 fun (xs:int list) union_int [] = xs
   485   | [] union_int ys = ys
   486   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   487 
   488 (*union of sets, optimized version for strings*)
   489 fun (xs:string list) union_string [] = xs
   490   | [] union_string ys = ys
   491   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   492 
   493 (*generalized union*)
   494 fun gen_union eq (xs, []) = xs
   495   | gen_union eq ([], ys) = ys
   496   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   497 
   498 
   499 (*intersection*)
   500 fun [] inter ys = []
   501   | (x :: xs) inter ys =
   502       if x mem ys then x :: (xs inter ys) else xs inter ys;
   503 
   504 (*intersection, optimized version for ints*)
   505 fun ([]:int list) inter_int ys = []
   506   | (x :: xs) inter_int ys =
   507       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   508 
   509 (*intersection, optimized version for strings *)
   510 fun ([]:string list) inter_string ys = []
   511   | (x :: xs) inter_string ys =
   512       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   513 
   514 
   515 (*subset*)
   516 fun [] subset ys = true
   517   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   518 
   519 (*subset, optimized version for ints*)
   520 fun ([]:int list) subset_int ys = true
   521   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   522 
   523 (*subset, optimized version for strings*)
   524 fun ([]:string list) subset_string ys = true
   525   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   526 
   527 (*set equality for strings*)
   528 fun eq_set_string ((xs:string list), ys) =
   529   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   530 
   531 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   532 
   533 
   534 (*removing an element from a list WITHOUT duplicates*)
   535 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   536   | [] \ x = [];
   537 
   538 fun ys \\ xs = foldl (op \) (ys,xs);
   539 
   540 (*removing an element from a list -- possibly WITH duplicates*)
   541 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   542 
   543 fun gen_rems eq = foldl (gen_rem eq);
   544 
   545 
   546 (*makes a list of the distinct members of the input; preserves order, takes
   547   first of equal elements*)
   548 fun gen_distinct eq lst =
   549   let
   550     val memb = gen_mem eq;
   551 
   552     fun dist (rev_seen, []) = rev rev_seen
   553       | dist (rev_seen, x :: xs) =
   554           if memb (x, rev_seen) then dist (rev_seen, xs)
   555           else dist (x :: rev_seen, xs);
   556   in
   557     dist ([], lst)
   558   end;
   559 
   560 fun distinct l = gen_distinct (op =) l;
   561 
   562 
   563 (*returns the tail beginning with the first repeated element, or []*)
   564 fun findrep [] = []
   565   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   566 
   567 
   568 (*returns a list containing all repeated elements exactly once; preserves
   569   order, takes first of equal elements*)
   570 fun gen_duplicates eq lst =
   571   let
   572     val memb = gen_mem eq;
   573 
   574     fun dups (rev_dups, []) = rev rev_dups
   575       | dups (rev_dups, x :: xs) =
   576           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   577             dups (rev_dups, xs)
   578           else dups (x :: rev_dups, xs);
   579   in
   580     dups ([], lst)
   581   end;
   582 
   583 fun duplicates l = gen_duplicates (op =) l;
   584 
   585 
   586 
   587 (** association lists **)
   588 
   589 (*association list lookup*)
   590 fun assoc ([], key) = None
   591   | assoc ((keyi, xi) :: pairs, key) =
   592       if key = keyi then Some xi else assoc (pairs, key);
   593 
   594 (*association list lookup, optimized version for ints*)
   595 fun assoc_int ([], (key:int)) = None
   596   | assoc_int ((keyi, xi) :: pairs, key) =
   597       if key = keyi then Some xi else assoc_int (pairs, key);
   598 
   599 (*association list lookup, optimized version for strings*)
   600 fun assoc_string ([], (key:string)) = None
   601   | assoc_string ((keyi, xi) :: pairs, key) =
   602       if key = keyi then Some xi else assoc_string (pairs, key);
   603 
   604 (*association list lookup, optimized version for string*ints*)
   605 fun assoc_string_int ([], (key:string*int)) = None
   606   | assoc_string_int ((keyi, xi) :: pairs, key) =
   607       if key = keyi then Some xi else assoc_string_int (pairs, key);
   608 
   609 fun assocs ps x =
   610   (case assoc (ps, x) of
   611     None => []
   612   | Some ys => ys);
   613 
   614 (*two-fold association list lookup*)
   615 fun assoc2 (aal, (key1, key2)) =
   616   (case assoc (aal, key1) of
   617     Some al => assoc (al, key2)
   618   | None => None);
   619 
   620 (*generalized association list lookup*)
   621 fun gen_assoc eq ([], key) = None
   622   | gen_assoc eq ((keyi, xi) :: pairs, key) =
   623       if eq (key, keyi) then Some xi else gen_assoc eq (pairs, key);
   624 
   625 (*association list update*)
   626 fun overwrite (al, p as (key, _)) =
   627   let fun over ((q as (keyi, _)) :: pairs) =
   628             if keyi = key then p :: pairs else q :: (over pairs)
   629         | over [] = [p]
   630   in over al end;
   631 
   632 fun gen_overwrite eq (al, p as (key, _)) =
   633   let fun over ((q as (keyi, _)) :: pairs) =
   634             if eq (keyi, key) then p :: pairs else q :: (over pairs)
   635         | over [] = [p]
   636   in over al end;
   637 
   638 
   639 
   640 (** generic tables **)
   641 
   642 (*Tables are supposed to be 'efficient' encodings of lists of elements distinct
   643   wrt. an equality "eq". The extend and merge operations below are optimized
   644   for long-term space efficiency.*)
   645 
   646 (*append (new) elements to a table*)
   647 fun generic_extend _ _ _ tab [] = tab
   648   | generic_extend eq dest_tab mk_tab tab1 lst2 =
   649       let
   650         val lst1 = dest_tab tab1;
   651         val new_lst2 = gen_rems eq (lst2, lst1);
   652       in
   653         if null new_lst2 then tab1
   654         else mk_tab (lst1 @ new_lst2)
   655       end;
   656 
   657 (*append (new) elements of 2nd table to 1st table*)
   658 fun generic_merge eq dest_tab mk_tab tab1 tab2 =
   659   let
   660     val lst1 = dest_tab tab1;
   661     val lst2 = dest_tab tab2;
   662     val new_lst2 = gen_rems eq (lst2, lst1);
   663   in
   664     if null new_lst2 then tab1
   665     else if gen_subset eq (lst1, lst2) then tab2
   666     else mk_tab (lst1 @ new_lst2)
   667   end;
   668 
   669 
   670 (*lists as tables*)
   671 fun extend_list tab = generic_extend (op =) I I tab;
   672 fun merge_lists tab = generic_merge (op =) I I tab;
   673 
   674 fun merge_rev_lists xs [] = xs
   675   | merge_rev_lists [] ys = ys
   676   | merge_rev_lists xs (y :: ys) =
   677       (if y mem xs then I else cons y) (merge_rev_lists xs ys);
   678 
   679 
   680 
   681 (** balanced trees **)
   682 
   683 exception Balance;      (*indicates non-positive argument to balancing fun*)
   684 
   685 (*balanced folding; avoids deep nesting*)
   686 fun fold_bal f [x] = x
   687   | fold_bal f [] = raise Balance
   688   | fold_bal f xs =
   689       let val k = length xs div 2
   690       in  f (fold_bal f (take(k, xs)),
   691              fold_bal f (drop(k, xs)))
   692       end;
   693 
   694 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   695 fun access_bal (f, g, x) n i =
   696   let fun acc n i =     (*1<=i<=n*)
   697           if n=1 then x else
   698           let val n2 = n div 2
   699           in  if i<=n2 then f (acc n2 i)
   700                        else g (acc (n-n2) (i-n2))
   701           end
   702   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   703 
   704 (*construct ALL such accesses; could try harder to share recursive calls!*)
   705 fun accesses_bal (f, g, x) n =
   706   let fun acc n =
   707           if n=1 then [x] else
   708           let val n2 = n div 2
   709               val acc2 = acc n2
   710           in  if n-n2=n2 then map f acc2 @ map g acc2
   711                          else map f acc2 @ map g (acc (n-n2)) end
   712   in  if 1<=n then acc n else raise Balance  end;
   713 
   714 
   715 
   716 (** orders **)
   717 
   718 datatype order = LESS | EQUAL | GREATER;
   719 
   720 fun intord (i, j: int) =
   721   if i < j then LESS
   722   else if i = j then EQUAL
   723   else GREATER;
   724 
   725 fun stringord (a, b: string) =
   726   if a < b then LESS
   727   else if a = b then EQUAL
   728   else GREATER;
   729 
   730 
   731 
   732 (** input / output and diagnostics **)
   733 
   734 val cd = OS.FileSys.chDir;
   735 val pwd = OS.FileSys.getDir;
   736 
   737 
   738 local
   739   fun out s =
   740     (TextIO.output (TextIO.stdOut, s); TextIO.flushOut TextIO.stdOut);
   741 
   742   fun lines cs =
   743     (case take_prefix (not_equal "\n") cs of
   744       (cs', []) => [implode cs']
   745     | (cs', _ :: cs'') => implode cs' :: lines cs'');
   746 
   747   fun prefix_lines prfx txt =
   748     txt |> explode |> lines |> map (fn s => prfx ^ s ^ "\n") |> implode;
   749 in
   750 
   751 (*hooks for output channels: normal, warning, error*)
   752 val prs_fn = ref (fn s => out s);
   753 val warning_fn = ref (fn s => out (prefix_lines "### " s));
   754 val error_fn = ref (fn s => out (prefix_lines "*** " s));
   755 
   756 end;
   757 
   758 fun prs s = !prs_fn s;
   759 fun writeln s = prs (s ^ "\n");
   760 
   761 fun warning s = !warning_fn s;
   762 
   763 (*print error message and abort to top level*)
   764 exception ERROR;
   765 fun error_msg s = !error_fn s;
   766 fun error s = (error_msg s; raise ERROR);
   767 fun sys_error msg = (error_msg " !! SYSTEM ERROR !!\n"; error msg);
   768 
   769 fun assert p msg = if p then () else error msg;
   770 fun deny p msg = if p then error msg else ();
   771 
   772 (*Assert pred for every member of l, generating a message if pred fails*)
   773 fun assert_all pred l msg_fn = 
   774   let fun asl [] = ()
   775         | asl (x::xs) = if pred x then asl xs
   776                         else error (msg_fn x)
   777   in  asl l  end;
   778 
   779 
   780 (* handle errors (capturing messages) *)
   781 
   782 datatype 'a error =
   783   Error of string |
   784   OK of 'a;
   785 
   786 fun handle_error f x =
   787   let
   788     val buffer = ref "";
   789     fun capture s = buffer := ! buffer ^ s ^ "\n";
   790     val result = Some (setmp error_fn capture f x) handle ERROR => None;
   791   in
   792     case result of
   793       None => Error (! buffer)
   794     | Some y => OK y
   795   end;
   796 
   797 
   798 (* read / write files *)
   799 
   800 fun read_file name =
   801   let
   802     val instream  = TextIO.openIn name;
   803     val intext = TextIO.inputAll instream;
   804   in
   805     TextIO.closeIn instream;
   806     intext
   807   end;
   808 
   809 fun write_file name txt =
   810   let val outstream = TextIO.openOut name in
   811     TextIO.output (outstream, txt);
   812     TextIO.closeOut outstream
   813   end;
   814 
   815 fun append_file name txt =
   816   let val outstream = TextIO.openAppend name in
   817     TextIO.output (outstream, txt);
   818     TextIO.closeOut outstream
   819   end;
   820 
   821 
   822 (*for the "test" target in IsaMakefiles -- signifies successful termination*)
   823 fun maketest msg =
   824   (writeln msg; write_file "test" "Test examples ran successfully\n");
   825 
   826 
   827 (*print a list surrounded by the brackets lpar and rpar, with comma separator
   828   print nothing for empty list*)
   829 fun print_list (lpar, rpar, pre: 'a -> unit) (l : 'a list) =
   830   let fun prec x = (prs ","; pre x)
   831   in
   832     (case l of
   833       [] => ()
   834     | x::l => (prs lpar; pre x; seq prec l; prs rpar))
   835   end;
   836 
   837 (*print a list of items separated by newlines*)
   838 fun print_list_ln (pre: 'a -> unit) : 'a list -> unit =
   839   seq (fn x => (pre x; writeln ""));
   840 
   841 
   842 val print_int = prs o string_of_int;
   843 
   844 
   845 (* output to LaTeX / xdvi *)
   846 fun latex s =
   847   execute ("( cd /tmp ; echo \"" ^ s ^
   848     "\" | isa2latex -s > $$.tex ; latex $$.tex ; xdvi $$.dvi ; rm $$.* ) > /dev/null &");
   849 
   850 
   851 (** timing **)
   852 
   853 (*unconditional timing function*)
   854 fun timeit x = cond_timeit true x;
   855 
   856 (*timed application function*)
   857 fun timeap f x = timeit (fn () => f x);
   858 
   859 (*timed "use" function, printing filenames*)
   860 fun time_use fname = timeit (fn () =>
   861   (writeln ("\n**** Starting " ^ fname ^ " ****"); use fname;
   862    writeln ("\n**** Finished " ^ fname ^ " ****")));
   863 
   864 (*use the file, but exit with error code if errors found.*)
   865 fun exit_use fname = use fname handle _ => exit 1;
   866 
   867 
   868 (** filenames and paths **)
   869 
   870 (*Convert UNIX filename of the form "path/file" to "path/" and "file";
   871   if filename contains no slash, then it returns "" and "file"*)
   872 val split_filename =
   873   (pairself implode) o take_suffix (not_equal "/") o explode;
   874 
   875 val base_name = #2 o split_filename;
   876 
   877 (*Merge splitted filename (path and file);
   878   if path does not end with one a slash is appended*)
   879 fun tack_on "" name = name
   880   | tack_on path name =
   881       if last_elem (explode path) = "/" then path ^ name
   882       else path ^ "/" ^ name;
   883 
   884 (*Remove the extension of a filename, i.e. the part after the last '.'*)
   885 val remove_ext = implode o #1 o take_suffix (not_equal ".") o explode;
   886 
   887 (*Make relative path to reach an absolute location from a different one*)
   888 fun relative_path cur_path dest_path =
   889   let (*Remove common beginning of both paths and make relative path*)
   890       fun mk_relative [] [] = []
   891         | mk_relative [] ds = ds
   892         | mk_relative cs [] = map (fn _ => "..") cs
   893         | mk_relative (c::cs) (d::ds) =
   894             if c = d then mk_relative cs ds
   895             else ".." :: map (fn _ => "..") cs @ (d::ds);
   896   in if cur_path = "" orelse hd (explode cur_path) <> "/" orelse
   897         dest_path = "" orelse hd (explode dest_path) <> "/" then
   898        error "Relative or empty path passed to relative_path"
   899      else ();
   900      space_implode "/" (mk_relative (space_explode "/" cur_path)
   901                                     (space_explode "/" dest_path))
   902   end;
   903 
   904 (*Determine if absolute path1 is a subdirectory of absolute path2*)
   905 fun path1 subdir_of path2 =
   906   if hd (explode path1) <> "/" orelse hd (explode path2) <> "/" then
   907     error "Relative or empty path passed to subdir_of"
   908   else (space_explode "/" path2) prefix (space_explode "/" path1);
   909 
   910 fun absolute_path cwd file =
   911   let fun rm_points [] result = rev result
   912         | rm_points (".."::ds) result = rm_points ds (tl result)
   913         | rm_points ("."::ds) result = rm_points ds result
   914         | rm_points (d::ds) result = rm_points ds (d::result);
   915   in if file = "" then ""
   916      else if hd (explode file) = "/" then file
   917      else "/" ^ space_implode "/"
   918                   (rm_points (space_explode "/" (tack_on cwd file)) [])
   919   end;
   920 
   921 fun file_exists file = (file_info file <> "");
   922 
   923 
   924 (** misc functions **)
   925 
   926 (*use the keyfun to make a list of (x, key) pairs*)
   927 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
   928   let fun keypair x = (x, keyfun x)
   929   in map keypair end;
   930 
   931 (*given a list of (x, key) pairs and a searchkey
   932   return the list of xs from each pair whose key equals searchkey*)
   933 fun keyfilter [] searchkey = []
   934   | keyfilter ((x, key) :: pairs) searchkey =
   935       if key = searchkey then x :: keyfilter pairs searchkey
   936       else keyfilter pairs searchkey;
   937 
   938 
   939 (*Partition list into elements that satisfy predicate and those that don't.
   940   Preserves order of elements in both lists.*)
   941 fun partition (pred: 'a->bool) (ys: 'a list) : ('a list * 'a list) =
   942     let fun part ([], answer) = answer
   943           | part (x::xs, (ys, ns)) = if pred(x)
   944             then  part (xs, (x::ys, ns))
   945             else  part (xs, (ys, x::ns))
   946     in  part (rev ys, ([], []))  end;
   947 
   948 
   949 fun partition_eq (eq:'a * 'a -> bool) =
   950     let fun part [] = []
   951           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
   952                            in (x::xs)::(part xs') end
   953     in part end;
   954 
   955 
   956 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   957    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   958 fun partition_list p i j =
   959   let fun part k xs =
   960             if k>j then
   961               (case xs of [] => []
   962                          | _ => raise LIST "partition_list")
   963             else
   964             let val (ns, rest) = partition (p k) xs;
   965             in  ns :: part(k+1)rest  end
   966   in  part i end;
   967 
   968 
   969 (* sorting *)
   970 
   971 (*insertion sort; stable (does not reorder equal elements)
   972   'less' is less-than test on type 'a*)
   973 fun sort (less: 'a*'a -> bool) =
   974   let fun insert (x, []) = [x]
   975         | insert (x, y::ys) =
   976               if less(y, x) then y :: insert (x, ys) else x::y::ys;
   977       fun sort1 [] = []
   978         | sort1 (x::xs) = insert (x, sort1 xs)
   979   in  sort1  end;
   980 
   981 (*sort strings*)
   982 val sort_strings = sort (op <= : string * string -> bool);
   983 
   984 
   985 (* transitive closure (not Warshall's algorithm) *)
   986 
   987 fun transitive_closure [] = []
   988   | transitive_closure ((x, ys)::ps) =
   989       let val qs = transitive_closure ps
   990           val zs = foldl (fn (zs, y) => assocs qs y union_string zs) (ys, ys)
   991           fun step(u, us) = (u, if x mem_string us then zs union_string us 
   992                                 else us)
   993       in (x, zs) :: map step qs end;
   994 
   995 
   996 (* generating identifiers *)
   997 
   998 local
   999   val a = ord "a" and z = ord "z" and A = ord "A" and Z = ord "Z"
  1000   and k0 = ord "0" and k9 = ord "9"
  1001 
  1002   val seedr = ref 0;
  1003 in
  1004 
  1005 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1006 fun newid n = 
  1007   let fun char i =
  1008                if i<26 then chr (A+i)
  1009           else if i<52 then chr (a+i-26)
  1010           else if i<62 then chr (k0+i-52)
  1011           else if i=62 then "_"
  1012           else  (*i=63*)    "'"
  1013   in  implode (map char (radixpand (64,n)))  end;
  1014 
  1015 (*Freshly generated identifiers with given prefix; MUST start with a letter*)
  1016 fun gensym pre = pre ^ 
  1017                  (#1(newid (!seedr), 
  1018                      seedr := 1+ !seedr))
  1019 
  1020 (*Increment a list of letters like a reversed base 26 number.
  1021   If head is "z", bumps chars in tail.
  1022   Digits are incremented as if they were integers.
  1023   "_" and "'" are not changed.
  1024   For making variants of identifiers.*)
  1025 
  1026 fun bump_int_list(c::cs) = if c="9" then "0" :: bump_int_list cs else
  1027         if k0 <= ord(c) andalso ord(c) < k9 then chr(ord(c)+1) :: cs
  1028         else "1" :: c :: cs
  1029   | bump_int_list([]) = error("bump_int_list: not an identifier");
  1030 
  1031 fun bump_list([], d) = [d]
  1032   | bump_list(["'"], d) = [d, "'"]
  1033   | bump_list("z"::cs, _) = "a" :: bump_list(cs, "a")
  1034   | bump_list("Z"::cs, _) = "A" :: bump_list(cs, "A")
  1035   | bump_list("9"::cs, _) = "0" :: bump_int_list cs
  1036   | bump_list(c::cs, _) = let val k = ord(c)
  1037         in if (a <= k andalso k < z) orelse (A <= k andalso k < Z) orelse
  1038               (k0 <= k andalso k < k9) then chr(k+1) :: cs else
  1039            if c="'" orelse c="_" then c :: bump_list(cs, "") else
  1040                 error("bump_list: not legal in identifier: " ^
  1041                         implode(rev(c::cs)))
  1042         end;
  1043 
  1044 end;
  1045 
  1046 fun bump_string s : string = implode (rev (bump_list(rev(explode s), "")));
  1047 
  1048 
  1049 (* lexical scanning *)
  1050 
  1051 (*scan a list of characters into "words" composed of "letters" (recognized by
  1052   is_let) and separated by any number of non-"letters"*)
  1053 fun scanwords is_let cs =
  1054   let fun scan1 [] = []
  1055         | scan1 cs =
  1056             let val (lets, rest) = take_prefix is_let cs
  1057             in implode lets :: scanwords is_let rest end;
  1058   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1059 
  1060 end;
  1061 
  1062 (*Variable-branching trees: for proof terms*)
  1063 datatype 'a mtree = Join of 'a * 'a mtree list;
  1064 
  1065 open Library;