src/Pure/tctical.ML
author wenzelm
Wed Jan 21 22:26:49 2009 +0100 (2009-01-21)
changeset 29605 f2924219125e
parent 29272 fb3ccf499df5
child 30145 09817540ccae
permissions -rw-r--r--
eliminated obsolete var morphism;
     1 (*  Title:      Pure/tctical.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Tacticals.
     5 *)
     6 
     7 infix 1 THEN THEN' THEN_ALL_NEW;
     8 infix 0 ORELSE APPEND INTLEAVE ORELSE' APPEND' INTLEAVE';
     9 infix 0 THEN_ELSE;
    10 
    11 signature TACTICAL =
    12 sig
    13   type tactic = thm -> thm Seq.seq
    14   val THEN: tactic * tactic -> tactic
    15   val ORELSE: tactic * tactic -> tactic
    16   val APPEND: tactic * tactic -> tactic
    17   val INTLEAVE: tactic * tactic -> tactic
    18   val THEN_ELSE: tactic * (tactic*tactic) -> tactic
    19   val THEN': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    20   val ORELSE': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    21   val APPEND': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    22   val INTLEAVE': ('a -> tactic) * ('a -> tactic) -> 'a -> tactic
    23   val all_tac: tactic
    24   val no_tac: tactic
    25   val DETERM: tactic -> tactic
    26   val COND: (thm -> bool) -> tactic -> tactic -> tactic
    27   val TRY: tactic -> tactic
    28   val EVERY: tactic list -> tactic
    29   val EVERY': ('a -> tactic) list -> 'a -> tactic
    30   val EVERY1: (int -> tactic) list -> tactic
    31   val FIRST: tactic list -> tactic
    32   val FIRST': ('a -> tactic) list -> 'a -> tactic
    33   val FIRST1: (int -> tactic) list -> tactic
    34   val RANGE: (int -> tactic) list -> int -> tactic
    35   val print_tac: string -> tactic
    36   val pause_tac: tactic
    37   val trace_REPEAT: bool ref
    38   val suppress_tracing: bool ref
    39   val tracify: bool ref -> tactic -> tactic
    40   val traced_tac: (thm -> (thm * thm Seq.seq) option) -> tactic
    41   val DETERM_UNTIL: (thm -> bool) -> tactic -> tactic
    42   val REPEAT_DETERM_N: int -> tactic -> tactic
    43   val REPEAT_DETERM: tactic -> tactic
    44   val REPEAT: tactic -> tactic
    45   val REPEAT_DETERM1: tactic -> tactic
    46   val REPEAT1: tactic -> tactic
    47   val FILTER: (thm -> bool) -> tactic -> tactic
    48   val CHANGED: tactic -> tactic
    49   val CHANGED_PROP: tactic -> tactic
    50   val ALLGOALS: (int -> tactic) -> tactic
    51   val SOMEGOAL: (int -> tactic) -> tactic
    52   val FIRSTGOAL: (int -> tactic) -> tactic
    53   val REPEAT_SOME: (int -> tactic) -> tactic
    54   val REPEAT_DETERM_SOME: (int -> tactic) -> tactic
    55   val REPEAT_FIRST: (int -> tactic) -> tactic
    56   val REPEAT_DETERM_FIRST: (int -> tactic) -> tactic
    57   val TRYALL: (int -> tactic) -> tactic
    58   val CSUBGOAL: ((cterm * int) -> tactic) -> int -> tactic
    59   val SUBGOAL: ((term * int) -> tactic) -> int -> tactic
    60   val CHANGED_GOAL: (int -> tactic) -> int -> tactic
    61   val THEN_ALL_NEW: (int -> tactic) * (int -> tactic) -> int -> tactic
    62   val REPEAT_ALL_NEW: (int -> tactic) -> int -> tactic
    63   val strip_context: term -> (string * typ) list * term list * term
    64   val metahyps_thms: int -> thm -> thm list option
    65   val METAHYPS: (thm list -> tactic) -> int -> tactic
    66   val PRIMSEQ: (thm -> thm Seq.seq) -> tactic
    67   val PRIMITIVE: (thm -> thm) -> tactic
    68   val SINGLE: tactic -> thm -> thm option
    69   val CONVERSION: conv -> int -> tactic
    70 end;
    71 
    72 structure Tactical : TACTICAL =
    73 struct
    74 
    75 (**** Tactics ****)
    76 
    77 (*A tactic maps a proof tree to a sequence of proof trees:
    78     if length of sequence = 0 then the tactic does not apply;
    79     if length > 1 then backtracking on the alternatives can occur.*)
    80 
    81 type tactic = thm -> thm Seq.seq;
    82 
    83 
    84 (*** LCF-style tacticals ***)
    85 
    86 (*the tactical THEN performs one tactic followed by another*)
    87 fun (tac1 THEN tac2) st = Seq.maps tac2 (tac1 st);
    88 
    89 
    90 (*The tactical ORELSE uses the first tactic that returns a nonempty sequence.
    91   Like in LCF, ORELSE commits to either tac1 or tac2 immediately.
    92   Does not backtrack to tac2 if tac1 was initially chosen. *)
    93 fun (tac1 ORELSE tac2) st =
    94     case Seq.pull(tac1 st) of
    95         NONE       => tac2 st
    96       | sequencecell => Seq.make(fn()=> sequencecell);
    97 
    98 
    99 (*The tactical APPEND combines the results of two tactics.
   100   Like ORELSE, but allows backtracking on both tac1 and tac2.
   101   The tactic tac2 is not applied until needed.*)
   102 fun (tac1 APPEND tac2) st =
   103   Seq.append (tac1 st) (Seq.make(fn()=> Seq.pull (tac2 st)));
   104 
   105 (*Like APPEND, but interleaves results of tac1 and tac2.*)
   106 fun (tac1 INTLEAVE tac2) st =
   107     Seq.interleave(tac1 st,
   108                         Seq.make(fn()=> Seq.pull (tac2 st)));
   109 
   110 (*Conditional tactic.
   111         tac1 ORELSE tac2 = tac1 THEN_ELSE (all_tac, tac2)
   112         tac1 THEN tac2   = tac1 THEN_ELSE (tac2, no_tac)
   113 *)
   114 fun (tac THEN_ELSE (tac1, tac2)) st =
   115     case Seq.pull(tac st) of
   116         NONE    => tac2 st                                   (*failed; try tactic 2*)
   117       | seqcell => Seq.maps tac1 (Seq.make(fn()=> seqcell)); (*succeeded; use tactic 1*)
   118 
   119 
   120 (*Versions for combining tactic-valued functions, as in
   121      SOMEGOAL (resolve_tac rls THEN' assume_tac) *)
   122 fun (tac1 THEN' tac2) x = tac1 x THEN tac2 x;
   123 fun (tac1 ORELSE' tac2) x = tac1 x ORELSE tac2 x;
   124 fun (tac1 APPEND' tac2) x = tac1 x APPEND tac2 x;
   125 fun (tac1 INTLEAVE' tac2) x = tac1 x INTLEAVE tac2 x;
   126 
   127 (*passes all proofs through unchanged;  identity of THEN*)
   128 fun all_tac st = Seq.single st;
   129 
   130 (*passes no proofs through;  identity of ORELSE and APPEND*)
   131 fun no_tac st  = Seq.empty;
   132 
   133 
   134 (*Make a tactic deterministic by chopping the tail of the proof sequence*)
   135 fun DETERM tac = Seq.DETERM tac;
   136 
   137 (*Conditional tactical: testfun controls which tactic to use next.
   138   Beware: due to eager evaluation, both thentac and elsetac are evaluated.*)
   139 fun COND testfun thenf elsef = (fn prf =>
   140     if testfun prf then  thenf prf   else  elsef prf);
   141 
   142 (*Do the tactic or else do nothing*)
   143 fun TRY tac = tac ORELSE all_tac;
   144 
   145 (*** List-oriented tactics ***)
   146 
   147 local
   148   (*This version of EVERY avoids backtracking over repeated states*)
   149 
   150   fun EVY (trail, []) st =
   151         Seq.make (fn()=> SOME(st,
   152                         Seq.make (fn()=> Seq.pull (evyBack trail))))
   153     | EVY (trail, tac::tacs) st =
   154           case Seq.pull(tac st) of
   155               NONE    => evyBack trail              (*failed: backtrack*)
   156             | SOME(st',q) => EVY ((st',q,tacs)::trail, tacs) st'
   157   and evyBack [] = Seq.empty (*no alternatives*)
   158     | evyBack ((st',q,tacs)::trail) =
   159           case Seq.pull q of
   160               NONE        => evyBack trail
   161             | SOME(st,q') => if Thm.eq_thm (st',st)
   162                              then evyBack ((st',q',tacs)::trail)
   163                              else EVY ((st,q',tacs)::trail, tacs) st
   164 in
   165 
   166 (* EVERY [tac1,...,tacn]   equals    tac1 THEN ... THEN tacn   *)
   167 fun EVERY tacs = EVY ([], tacs);
   168 end;
   169 
   170 
   171 (* EVERY' [tac1,...,tacn] i  equals    tac1 i THEN ... THEN tacn i   *)
   172 fun EVERY' tacs i = EVERY (map (fn f => f i) tacs);
   173 
   174 (*Apply every tactic to 1*)
   175 fun EVERY1 tacs = EVERY' tacs 1;
   176 
   177 (* FIRST [tac1,...,tacn]   equals    tac1 ORELSE ... ORELSE tacn   *)
   178 fun FIRST tacs = fold_rev (curry op ORELSE) tacs no_tac;
   179 
   180 (* FIRST' [tac1,...,tacn] i  equals    tac1 i ORELSE ... ORELSE tacn i   *)
   181 fun FIRST' tacs = fold_rev (curry op ORELSE') tacs (K no_tac);
   182 
   183 (*Apply first tactic to 1*)
   184 fun FIRST1 tacs = FIRST' tacs 1;
   185 
   186 (*Apply tactics on consecutive subgoals*)
   187 fun RANGE [] _ = all_tac
   188   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   189 
   190 
   191 (*** Tracing tactics ***)
   192 
   193 (*Print the current proof state and pass it on.*)
   194 fun print_tac msg =
   195     (fn st =>
   196      (tracing msg;
   197       tracing ((Pretty.string_of o Pretty.chunks o
   198                  Display.pretty_goals (! Display.goals_limit)) st);
   199       Seq.single st));
   200 
   201 (*Pause until a line is typed -- if non-empty then fail. *)
   202 fun pause_tac st =
   203   (tracing "** Press RETURN to continue:";
   204    if TextIO.inputLine TextIO.stdIn = SOME "\n" then Seq.single st
   205    else (tracing "Goodbye";  Seq.empty));
   206 
   207 exception TRACE_EXIT of thm
   208 and TRACE_QUIT;
   209 
   210 (*Tracing flags*)
   211 val trace_REPEAT= ref false
   212 and suppress_tracing = ref false;
   213 
   214 (*Handle all tracing commands for current state and tactic *)
   215 fun exec_trace_command flag (tac, st) =
   216    case TextIO.inputLine TextIO.stdIn of
   217        SOME "\n" => tac st
   218      | SOME "f\n" => Seq.empty
   219      | SOME "o\n" => (flag:=false;  tac st)
   220      | SOME "s\n" => (suppress_tracing:=true;  tac st)
   221      | SOME "x\n" => (tracing "Exiting now";  raise (TRACE_EXIT st))
   222      | SOME "quit\n" => raise TRACE_QUIT
   223      | _     => (tracing
   224 "Type RETURN to continue or...\n\
   225 \     f    - to fail here\n\
   226 \     o    - to switch tracing off\n\
   227 \     s    - to suppress tracing until next entry to a tactical\n\
   228 \     x    - to exit at this point\n\
   229 \     quit - to abort this tracing run\n\
   230 \** Well? "     ;  exec_trace_command flag (tac, st));
   231 
   232 
   233 (*Extract from a tactic, a thm->thm seq function that handles tracing*)
   234 fun tracify flag tac st =
   235   if !flag andalso not (!suppress_tracing)
   236            then (Display.print_goals (! Display.goals_limit) st;
   237                  tracing "** Press RETURN to continue:";
   238                  exec_trace_command flag (tac,st))
   239   else tac st;
   240 
   241 (*Create a tactic whose outcome is given by seqf, handling TRACE_EXIT*)
   242 fun traced_tac seqf st =
   243     (suppress_tracing := false;
   244      Seq.make (fn()=> seqf st
   245                          handle TRACE_EXIT st' => SOME(st', Seq.empty)));
   246 
   247 
   248 (*Deterministic DO..UNTIL: only retains the first outcome; tail recursive.
   249   Forces repitition until predicate on state is fulfilled.*)
   250 fun DETERM_UNTIL p tac =
   251 let val tac = tracify trace_REPEAT tac
   252     fun drep st = if p st then SOME (st, Seq.empty)
   253                           else (case Seq.pull(tac st) of
   254                                   NONE        => NONE
   255                                 | SOME(st',_) => drep st')
   256 in  traced_tac drep  end;
   257 
   258 (*Deterministic REPEAT: only retains the first outcome;
   259   uses less space than REPEAT; tail recursive.
   260   If non-negative, n bounds the number of repetitions.*)
   261 fun REPEAT_DETERM_N n tac =
   262   let val tac = tracify trace_REPEAT tac
   263       fun drep 0 st = SOME(st, Seq.empty)
   264         | drep n st =
   265            (case Seq.pull(tac st) of
   266                 NONE       => SOME(st, Seq.empty)
   267               | SOME(st',_) => drep (n-1) st')
   268   in  traced_tac (drep n)  end;
   269 
   270 (*Allows any number of repetitions*)
   271 val REPEAT_DETERM = REPEAT_DETERM_N ~1;
   272 
   273 (*General REPEAT: maintains a stack of alternatives; tail recursive*)
   274 fun REPEAT tac =
   275   let val tac = tracify trace_REPEAT tac
   276       fun rep qs st =
   277         case Seq.pull(tac st) of
   278             NONE       => SOME(st, Seq.make(fn()=> repq qs))
   279           | SOME(st',q) => rep (q::qs) st'
   280       and repq [] = NONE
   281         | repq(q::qs) = case Seq.pull q of
   282             NONE       => repq qs
   283           | SOME(st,q) => rep (q::qs) st
   284   in  traced_tac (rep [])  end;
   285 
   286 (*Repeat 1 or more times*)
   287 fun REPEAT_DETERM1 tac = DETERM tac THEN REPEAT_DETERM tac;
   288 fun REPEAT1 tac = tac THEN REPEAT tac;
   289 
   290 
   291 (** Filtering tacticals **)
   292 
   293 fun FILTER pred tac st = Seq.filter pred (tac st);
   294 
   295 (*Accept only next states that change the theorem somehow*)
   296 fun CHANGED tac st =
   297   let fun diff st' = not (Thm.eq_thm (st, st'));
   298   in Seq.filter diff (tac st) end;
   299 
   300 (*Accept only next states that change the theorem's prop field
   301   (changes to signature, hyps, etc. don't count)*)
   302 fun CHANGED_PROP tac st =
   303   let fun diff st' = not (Thm.eq_thm_prop (st, st'));
   304   in Seq.filter diff (tac st) end;
   305 
   306 
   307 (*** Tacticals based on subgoal numbering ***)
   308 
   309 (*For n subgoals, performs tac(n) THEN ... THEN tac(1)
   310   Essential to work backwards since tac(i) may add/delete subgoals at i. *)
   311 fun ALLGOALS tac st =
   312   let fun doall 0 = all_tac
   313         | doall n = tac(n) THEN doall(n-1)
   314   in  doall(nprems_of st)st  end;
   315 
   316 (*For n subgoals, performs tac(n) ORELSE ... ORELSE tac(1)  *)
   317 fun SOMEGOAL tac st =
   318   let fun find 0 = no_tac
   319         | find n = tac(n) ORELSE find(n-1)
   320   in  find(nprems_of st)st  end;
   321 
   322 (*For n subgoals, performs tac(1) ORELSE ... ORELSE tac(n).
   323   More appropriate than SOMEGOAL in some cases.*)
   324 fun FIRSTGOAL tac st =
   325   let fun find (i,n) = if i>n then no_tac else  tac(i) ORELSE find (i+1,n)
   326   in  find(1, nprems_of st)st  end;
   327 
   328 (*Repeatedly solve some using tac. *)
   329 fun REPEAT_SOME tac = REPEAT1 (SOMEGOAL (REPEAT1 o tac));
   330 fun REPEAT_DETERM_SOME tac = REPEAT_DETERM1 (SOMEGOAL (REPEAT_DETERM1 o tac));
   331 
   332 (*Repeatedly solve the first possible subgoal using tac. *)
   333 fun REPEAT_FIRST tac = REPEAT1 (FIRSTGOAL (REPEAT1 o tac));
   334 fun REPEAT_DETERM_FIRST tac = REPEAT_DETERM1 (FIRSTGOAL (REPEAT_DETERM1 o tac));
   335 
   336 (*For n subgoals, tries to apply tac to n,...1  *)
   337 fun TRYALL tac = ALLGOALS (TRY o tac);
   338 
   339 
   340 (*Make a tactic for subgoal i, if there is one.  *)
   341 fun CSUBGOAL goalfun i st =
   342   (case SOME (Thm.cprem_of st i) handle THM _ => NONE of
   343     SOME goal => goalfun (goal, i) st
   344   | NONE => Seq.empty);
   345 
   346 fun SUBGOAL goalfun =
   347   CSUBGOAL (fn (goal, i) => goalfun (Thm.term_of goal, i));
   348 
   349 (*Returns all states that have changed in subgoal i, counted from the LAST
   350   subgoal.  For stac, for example.*)
   351 fun CHANGED_GOAL tac i st =
   352     let val np = nprems_of st
   353         val d = np-i                 (*distance from END*)
   354         val t = List.nth(prems_of st, i-1)
   355         fun diff st' =
   356             nprems_of st' - d <= 0   (*the subgoal no longer exists*)
   357             orelse
   358              not (Pattern.aeconv (t,
   359                                   List.nth(prems_of st',
   360                                            nprems_of st' - d - 1)))
   361     in  Seq.filter diff (tac i st)  end
   362     handle Subscript => Seq.empty  (*no subgoal i*);
   363 
   364 fun (tac1 THEN_ALL_NEW tac2) i st =
   365   st |> (tac1 i THEN (fn st' => Seq.INTERVAL tac2 i (i + nprems_of st' - nprems_of st) st'));
   366 
   367 (*repeatedly dig into any emerging subgoals*)
   368 fun REPEAT_ALL_NEW tac =
   369   tac THEN_ALL_NEW (TRY o (fn i => REPEAT_ALL_NEW tac i));
   370 
   371 
   372 (*Strips assumptions in goal yielding  ( [x1,...,xm], [H1,...,Hn], B )
   373     H1,...,Hn are the hypotheses;  x1...xm are variants of the parameters.
   374   Main difference from strip_assums concerns parameters:
   375     it replaces the bound variables by free variables.  *)
   376 fun strip_context_aux (params, Hs, Const("==>", _) $ H $ B) =
   377         strip_context_aux (params, H::Hs, B)
   378   | strip_context_aux (params, Hs, Const("all",_)$Abs(a,T,t)) =
   379         let val (b,u) = Syntax.variant_abs(a,T,t)
   380         in  strip_context_aux ((b,T)::params, Hs, u)  end
   381   | strip_context_aux (params, Hs, B) = (rev params, rev Hs, B);
   382 
   383 fun strip_context A = strip_context_aux ([],[],A);
   384 
   385 
   386 (**** METAHYPS -- tactical for using hypotheses as meta-level assumptions
   387        METAHYPS (fn prems => tac prems) i
   388 
   389 converts subgoal i, of the form !!x1...xm. [| A1;...;An] ==> A into a new
   390 proof state A==>A, supplying A1,...,An as meta-level assumptions (in
   391 "prems").  The parameters x1,...,xm become free variables.  If the
   392 resulting proof state is [| B1;...;Bk] ==> C (possibly assuming A1,...,An)
   393 then it is lifted back into the original context, yielding k subgoals.
   394 
   395 Replaces unknowns in the context by Frees having the prefix METAHYP_
   396 New unknowns in [| B1;...;Bk] ==> C are lifted over x1,...,xm.
   397 DOES NOT HANDLE TYPE UNKNOWNS.
   398 ****)
   399 
   400 local
   401 
   402   (*Left-to-right replacements: ctpairs = [...,(vi,ti),...].
   403     Instantiates distinct free variables by terms of same type.*)
   404   fun free_instantiate ctpairs =
   405     forall_elim_list (map snd ctpairs) o forall_intr_list (map fst ctpairs);
   406 
   407   fun free_of s ((a, i), T) =
   408     Free (s ^ (case i of 0 => a | _ => a ^ "_" ^ string_of_int i), T)
   409 
   410   fun mk_inst v = (Var v, free_of "METAHYP1_" v)
   411 in
   412 
   413 (*Common code for METAHYPS and metahyps_thms*)
   414 fun metahyps_split_prem prem =
   415   let (*find all vars in the hyps -- should find tvars also!*)
   416       val hyps_vars = fold Term.add_vars (Logic.strip_assums_hyp prem) []
   417       val insts = map mk_inst hyps_vars
   418       (*replace the hyps_vars by Frees*)
   419       val prem' = subst_atomic insts prem
   420       val (params,hyps,concl) = strip_context prem'
   421   in (insts,params,hyps,concl)  end;
   422 
   423 fun metahyps_aux_tac tacf (prem,gno) state =
   424   let val (insts,params,hyps,concl) = metahyps_split_prem prem
   425       val maxidx = Thm.maxidx_of state
   426       val cterm = Thm.cterm_of (Thm.theory_of_thm state)
   427       val chyps = map cterm hyps
   428       val hypths = map assume chyps
   429       val subprems = map (Thm.forall_elim_vars 0) hypths
   430       val fparams = map Free params
   431       val cparams = map cterm fparams
   432       fun swap_ctpair (t,u) = (cterm u, cterm t)
   433       (*Subgoal variables: make Free; lift type over params*)
   434       fun mk_subgoal_inst concl_vars (v, T) =
   435           if member (op =) concl_vars (v, T)
   436           then ((v, T), true, free_of "METAHYP2_" (v, T))
   437           else ((v, T), false, free_of "METAHYP2_" (v, map #2 params ---> T))
   438       (*Instantiate subgoal vars by Free applied to params*)
   439       fun mk_ctpair (v, in_concl, u) =
   440           if in_concl then (cterm (Var v), cterm u)
   441           else (cterm (Var v), cterm (list_comb (u, fparams)))
   442       (*Restore Vars with higher type and index*)
   443       fun mk_subgoal_swap_ctpair (((a, i), T), in_concl, u as Free (_, U)) =
   444           if in_concl then (cterm u, cterm (Var ((a, i), T)))
   445           else (cterm u, cterm (Var ((a, i + maxidx), U)))
   446       (*Embed B in the original context of params and hyps*)
   447       fun embed B = list_all_free (params, Logic.list_implies (hyps, B))
   448       (*Strip the context using elimination rules*)
   449       fun elim Bhyp = implies_elim_list (forall_elim_list cparams Bhyp) hypths
   450       (*A form of lifting that discharges assumptions.*)
   451       fun relift st =
   452         let val prop = Thm.prop_of st
   453             val subgoal_vars = (*Vars introduced in the subgoals*)
   454               fold Term.add_vars (Logic.strip_imp_prems prop) []
   455             and concl_vars = Term.add_vars (Logic.strip_imp_concl prop) []
   456             val subgoal_insts = map (mk_subgoal_inst concl_vars) subgoal_vars
   457             val st' = Thm.instantiate ([], map mk_ctpair subgoal_insts) st
   458             val emBs = map (cterm o embed) (prems_of st')
   459             val Cth  = implies_elim_list st' (map (elim o assume) emBs)
   460         in  (*restore the unknowns to the hypotheses*)
   461             free_instantiate (map swap_ctpair insts @
   462                               map mk_subgoal_swap_ctpair subgoal_insts)
   463                 (*discharge assumptions from state in same order*)
   464                 (implies_intr_list emBs
   465                   (forall_intr_list cparams (implies_intr_list chyps Cth)))
   466         end
   467       (*function to replace the current subgoal*)
   468       fun next st = bicompose false (false, relift st, nprems_of st)
   469                     gno state
   470   in Seq.maps next (tacf subprems (trivial (cterm concl))) end;
   471 
   472 end;
   473 
   474 (*Returns the theorem list that METAHYPS would supply to its tactic*)
   475 fun metahyps_thms i state =
   476   let val prem = Logic.nth_prem (i, Thm.prop_of state)
   477       and cterm = cterm_of (Thm.theory_of_thm state)
   478       val (_,_,hyps,_) = metahyps_split_prem prem
   479   in SOME (map (Thm.forall_elim_vars 0 o Thm.assume o cterm) hyps) end
   480   handle TERM ("nth_prem", [A]) => NONE;
   481 
   482 local
   483 
   484 fun print_vars_terms thy (n,thm) =
   485   let
   486     fun typed ty = " has type: " ^ Syntax.string_of_typ_global thy ty;
   487     fun find_vars thy (Const (c, ty)) =
   488           if null (Term.add_tvarsT ty []) then I
   489           else insert (op =) (c ^ typed ty)
   490       | find_vars thy (Var (xi, ty)) = insert (op =) (Term.string_of_vname xi ^ typed ty)
   491       | find_vars _ (Free _) = I
   492       | find_vars _ (Bound _) = I
   493       | find_vars thy (Abs (_, _, t)) = find_vars thy t
   494       | find_vars thy (t1 $ t2) =
   495           find_vars thy t1 #> find_vars thy t1;
   496     val prem = Logic.nth_prem (n, Thm.prop_of thm)
   497     val tms = find_vars thy prem []
   498   in
   499     (warning "Found schematic vars in assumptions:"; warning (cat_lines tms))
   500   end;
   501 
   502 in
   503 
   504 fun METAHYPS tacf n thm = SUBGOAL (metahyps_aux_tac tacf) n thm
   505   handle THM("assume: variables",_,_) => (print_vars_terms (theory_of_thm thm) (n,thm); Seq.empty)
   506 
   507 end;
   508 
   509 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
   510 fun PRIMSEQ thmfun st =  thmfun st handle THM _ => Seq.empty;
   511 
   512 (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
   513 fun PRIMITIVE thmfun = PRIMSEQ (Seq.single o thmfun);
   514 
   515 (*Inverse (more or less) of PRIMITIVE*)
   516 fun SINGLE tacf = Option.map fst o Seq.pull o tacf
   517 
   518 (*Conversions as tactics*)
   519 fun CONVERSION cv i st = Seq.single (Conv.gconv_rule cv i st)
   520   handle THM _ => Seq.empty
   521     | CTERM _ => Seq.empty
   522     | TERM _ => Seq.empty
   523     | TYPE _ => Seq.empty;
   524 
   525 end;
   526 
   527 open Tactical;