src/Pure/theory.ML
author wenzelm
Wed Jan 21 22:26:49 2009 +0100 (2009-01-21)
changeset 29605 f2924219125e
parent 29581 b3b33e0298eb
child 29606 fedb8be05f24
permissions -rw-r--r--
eliminated obsolete var morphism;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, and begin/end wrappers.
     6 *)
     7 
     8 signature THEORY =
     9 sig
    10   val eq_thy: theory * theory -> bool
    11   val subthy: theory * theory -> bool
    12   val assert_super: theory -> theory -> theory
    13   val parents_of: theory -> theory list
    14   val ancestors_of: theory -> theory list
    15   val check_thy: theory -> theory_ref
    16   val deref: theory_ref -> theory
    17   val merge: theory * theory -> theory
    18   val merge_refs: theory_ref * theory_ref -> theory_ref
    19   val merge_list: theory list -> theory
    20   val checkpoint: theory -> theory
    21   val copy: theory -> theory
    22   val requires: theory -> string -> string -> unit
    23   val axiom_space: theory -> NameSpace.T
    24   val axiom_table: theory -> term Symtab.table
    25   val axioms_of: theory -> (string * term) list
    26   val all_axioms_of: theory -> (string * term) list
    27   val defs_of: theory -> Defs.T
    28   val at_begin: (theory -> theory option) -> theory -> theory
    29   val at_end: (theory -> theory option) -> theory -> theory
    30   val begin_theory: string -> theory list -> theory
    31   val end_theory: theory -> theory
    32   val add_axioms_i: (binding * term) list -> theory -> theory
    33   val add_axioms: (bstring * string) list -> theory -> theory
    34   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    35   val add_defs_i: bool -> bool -> (binding * term) list -> theory -> theory
    36   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    37   val add_finals_i: bool -> term list -> theory -> theory
    38   val add_finals: bool -> string list -> theory -> theory
    39   val specify_const: Properties.T -> (binding * typ) * mixfix -> theory -> term * theory
    40 end
    41 
    42 structure Theory: THEORY =
    43 struct
    44 
    45 
    46 (** theory context operations **)
    47 
    48 val eq_thy = Context.eq_thy;
    49 val subthy = Context.subthy;
    50 
    51 fun assert_super thy1 thy2 =
    52   if subthy (thy1, thy2) then thy2
    53   else raise THEORY ("Not a super theory", [thy1, thy2]);
    54 
    55 val parents_of = Context.parents_of;
    56 val ancestors_of = Context.ancestors_of;
    57 
    58 val check_thy = Context.check_thy;
    59 val deref = Context.deref;
    60 
    61 val merge = Context.merge;
    62 val merge_refs = Context.merge_refs;
    63 
    64 fun merge_list [] = raise THEORY ("Empty merge of theories", [])
    65   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    66 
    67 val checkpoint = Context.checkpoint_thy;
    68 val copy = Context.copy_thy;
    69 
    70 fun requires thy name what =
    71   if exists (fn thy' => Context.theory_name thy' = name) (thy :: ancestors_of thy) then ()
    72   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
    73 
    74 
    75 
    76 (** datatype thy **)
    77 
    78 type wrapper = (theory -> theory option) * stamp;
    79 
    80 fun apply_wrappers (wrappers: wrapper list) =
    81   perhaps (perhaps_loop (perhaps_apply (map fst wrappers)));
    82 
    83 datatype thy = Thy of
    84  {axioms: term NameSpace.table,
    85   defs: Defs.T,
    86   wrappers: wrapper list * wrapper list};
    87 
    88 fun make_thy (axioms, defs, wrappers) = Thy {axioms = axioms, defs = defs, wrappers = wrappers};
    89 
    90 fun err_dup_axm dup = error ("Duplicate axiom: " ^ quote dup);
    91 
    92 structure ThyData = TheoryDataFun
    93 (
    94   type T = thy;
    95   val empty = make_thy (NameSpace.empty_table, Defs.empty, ([], []));
    96   val copy = I;
    97 
    98   fun extend (Thy {axioms, defs, wrappers}) = make_thy (NameSpace.empty_table, defs, wrappers);
    99 
   100   fun merge pp (thy1, thy2) =
   101     let
   102       val Thy {axioms = _, defs = defs1, wrappers = (bgs1, ens1)} = thy1;
   103       val Thy {axioms = _, defs = defs2, wrappers = (bgs2, ens2)} = thy2;
   104 
   105       val axioms' = NameSpace.empty_table;
   106       val defs' = Defs.merge pp (defs1, defs2);
   107       val bgs' = Library.merge (eq_snd op =) (bgs1, bgs2);
   108       val ens' = Library.merge (eq_snd op =) (ens1, ens2);
   109     in make_thy (axioms', defs', (bgs', ens')) end;
   110 );
   111 
   112 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   113 
   114 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, wrappers}) =>
   115   make_thy (f (axioms, defs, wrappers)));
   116 
   117 
   118 fun map_axioms f = map_thy (fn (axioms, defs, wrappers) => (f axioms, defs, wrappers));
   119 fun map_defs f = map_thy (fn (axioms, defs, wrappers) => (axioms, f defs, wrappers));
   120 fun map_wrappers f = map_thy (fn (axioms, defs, wrappers) => (axioms, defs, f wrappers));
   121 
   122 
   123 (* basic operations *)
   124 
   125 val axiom_space = #1 o #axioms o rep_theory;
   126 val axiom_table = #2 o #axioms o rep_theory;
   127 
   128 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   129 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   130 
   131 val defs_of = #defs o rep_theory;
   132 
   133 
   134 (* begin/end theory *)
   135 
   136 val begin_wrappers = rev o #1 o #wrappers o rep_theory;
   137 val end_wrappers = rev o #2 o #wrappers o rep_theory;
   138 
   139 fun at_begin f = map_wrappers (apfst (cons (f, stamp ())));
   140 fun at_end f = map_wrappers (apsnd (cons (f, stamp ())));
   141 
   142 fun begin_theory name imports =
   143   let
   144     val thy = Context.begin_thy Syntax.pp_global name imports;
   145     val wrappers = begin_wrappers thy;
   146   in thy |> Sign.local_path |> apply_wrappers wrappers end;
   147 
   148 fun end_theory thy =
   149   thy |> apply_wrappers (end_wrappers thy) |> Context.finish_thy;
   150 
   151 
   152 
   153 (** add axioms **)
   154 
   155 (* prepare axioms *)
   156 
   157 fun err_in_axm msg name =
   158   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   159 
   160 fun cert_axm thy (b, raw_tm) =
   161   let
   162     val (t, T, _) = Sign.certify_prop thy raw_tm
   163       handle TYPE (msg, _, _) => error msg
   164         | TERM (msg, _) => error msg;
   165   in
   166     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   167     (b, Sign.no_vars (Syntax.pp_global thy) t)
   168   end;
   169 
   170 fun read_axm thy (bname, str) =
   171   cert_axm thy (Binding.name bname, Syntax.read_prop_global thy str)
   172     handle ERROR msg => err_in_axm msg bname;
   173 
   174 
   175 (* add_axioms(_i) *)
   176 
   177 local
   178 
   179 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   180   let
   181     val axms = map (apsnd Logic.varify o prep_axm thy) raw_axms;
   182     val axioms' = fold (snd oo NameSpace.bind (Sign.naming_of thy)) axms axioms
   183       handle Symtab.DUP dup => err_dup_axm dup;
   184   in axioms' end);
   185 
   186 in
   187 
   188 val add_axioms_i = gen_add_axioms cert_axm;
   189 val add_axioms = gen_add_axioms read_axm;
   190 
   191 end;
   192 
   193 
   194 
   195 (** add constant definitions **)
   196 
   197 (* dependencies *)
   198 
   199 fun dependencies thy unchecked is_def name lhs rhs =
   200   let
   201     val pp = Syntax.pp_global thy;
   202     val consts = Sign.consts_of thy;
   203     fun prep const =
   204       let val Const (c, T) = Sign.no_vars pp (Const const)
   205       in (c, Consts.typargs consts (c, Logic.varifyT T)) end;
   206 
   207     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   208     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   209       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   210     val _ =
   211       if null rhs_extras then ()
   212       else error ("Specification depends on extra type variables: " ^
   213         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   214         "\nThe error(s) above occurred in " ^ quote name);
   215   in Defs.define pp unchecked is_def name (prep lhs) (map prep rhs) end;
   216 
   217 fun add_deps a raw_lhs raw_rhs thy =
   218   let
   219     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   220     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   221   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   222 
   223 fun specify_const tags decl thy =
   224   let val (t as Const const, thy') = Sign.declare_const tags decl thy
   225   in (t, add_deps "" const [] thy') end;
   226 
   227 
   228 (* check_overloading *)
   229 
   230 fun check_overloading thy overloaded (c, T) =
   231   let
   232     val declT = Sign.the_const_constraint thy c
   233       handle TYPE (msg, _, _) => error msg;
   234     val T' = Logic.varifyT T;
   235 
   236     fun message txt =
   237       [Pretty.block [Pretty.str "Specification of constant ",
   238         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ_global thy T)],
   239         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   240   in
   241     if Sign.typ_instance thy (declT, T') then ()
   242     else if Type.raw_instance (declT, T') then
   243       error (Library.setmp show_sorts true
   244         message "imposes additional sort constraints on the constant declaration")
   245     else if overloaded then ()
   246     else warning (message "is strictly less general than the declared type");
   247     (c, T)
   248   end;
   249 
   250 
   251 (* check_def *)
   252 
   253 fun check_def thy unchecked overloaded (b, tm) defs =
   254   let
   255     val ctxt = ProofContext.init thy;
   256     val name = Sign.full_name thy b;
   257     val (lhs_const, rhs) = Sign.cert_def ctxt tm;
   258     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   259     val _ = check_overloading thy overloaded lhs_const;
   260   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   261   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   262    [Pretty.str ("The error(s) above occurred in definition " ^ quote (Binding.display b) ^ ":"),
   263     Pretty.fbrk, Pretty.quote (Syntax.pretty_term_global thy tm)]));
   264 
   265 
   266 (* add_defs(_i) *)
   267 
   268 local
   269 
   270 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   271   let val axms = map (prep_axm thy) raw_axms in
   272     thy
   273     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   274     |> add_axioms_i axms
   275   end;
   276 
   277 in
   278 
   279 val add_defs_i = gen_add_defs cert_axm;
   280 val add_defs = gen_add_defs read_axm;
   281 
   282 end;
   283 
   284 
   285 (* add_finals(_i) *)
   286 
   287 local
   288 
   289 fun gen_add_finals prep_term overloaded args thy =
   290   let
   291     fun const_of (Const const) = const
   292       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   293       | const_of _ = error "Attempt to finalize non-constant term";
   294     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   295     val finalize = specify o check_overloading thy overloaded o const_of o
   296       Sign.cert_term thy o prep_term thy;
   297   in thy |> map_defs (fold finalize args) end;
   298 
   299 in
   300 
   301 val add_finals_i = gen_add_finals (K I);
   302 val add_finals = gen_add_finals Syntax.read_term_global;
   303 
   304 end;
   305 
   306 end;