src/Pure/variable.ML
author wenzelm
Wed Jan 21 22:26:49 2009 +0100 (2009-01-21)
changeset 29605 f2924219125e
parent 29279 7456a64bc4f6
child 30756 1a9f93c1ed22
permissions -rw-r--r--
eliminated obsolete var morphism;
     1 (*  Title:      Pure/variable.ML
     2     Author:     Makarius
     3 
     4 Fixed type/term variables and polymorphic term abbreviations.
     5 *)
     6 
     7 signature VARIABLE =
     8 sig
     9   val is_body: Proof.context -> bool
    10   val set_body: bool -> Proof.context -> Proof.context
    11   val restore_body: Proof.context -> Proof.context -> Proof.context
    12   val names_of: Proof.context -> Name.context
    13   val fixes_of: Proof.context -> (string * string) list
    14   val binds_of: Proof.context -> (typ * term) Vartab.table
    15   val maxidx_of: Proof.context -> int
    16   val sorts_of: Proof.context -> sort list
    17   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    18   val is_declared: Proof.context -> string -> bool
    19   val is_fixed: Proof.context -> string -> bool
    20   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    21   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    22   val default_type: Proof.context -> string -> typ option
    23   val def_type: Proof.context -> bool -> indexname -> typ option
    24   val def_sort: Proof.context -> indexname -> sort option
    25   val declare_names: term -> Proof.context -> Proof.context
    26   val declare_constraints: term -> Proof.context -> Proof.context
    27   val declare_term: term -> Proof.context -> Proof.context
    28   val declare_typ: typ -> Proof.context -> Proof.context
    29   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    30   val declare_thm: thm -> Proof.context -> Proof.context
    31   val thm_context: thm -> Proof.context
    32   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    33   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    34   val expand_binds: Proof.context -> term -> term
    35   val lookup_const: Proof.context -> string -> string option
    36   val is_const: Proof.context -> string -> bool
    37   val declare_const: string * string -> Proof.context -> Proof.context
    38   val add_fixes: string list -> Proof.context -> string list * Proof.context
    39   val add_fixes_direct: string list -> Proof.context -> Proof.context
    40   val auto_fixes: term -> Proof.context -> Proof.context
    41   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    42   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    43   val export_terms: Proof.context -> Proof.context -> term list -> term list
    44   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    45   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    46   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    47   val export: Proof.context -> Proof.context -> thm list -> thm list
    48   val export_morphism: Proof.context -> Proof.context -> morphism
    49   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    50   val import_inst: bool -> term list -> Proof.context ->
    51     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    52   val importT_terms: term list -> Proof.context -> term list * Proof.context
    53   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    54   val importT_thms: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    55   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    56   val import_thms: bool -> thm list -> Proof.context ->
    57     ((ctyp list * cterm list) * thm list) * Proof.context
    58   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    59   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    60   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    61   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    62   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    63   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    64   val polymorphic: Proof.context -> term list -> term list
    65 end;
    66 
    67 structure Variable: VARIABLE =
    68 struct
    69 
    70 (** local context data **)
    71 
    72 datatype data = Data of
    73  {is_body: bool,                        (*inner body mode*)
    74   names: Name.context,                  (*type/term variable names*)
    75   consts: string Symtab.table,          (*consts within the local scope*)
    76   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    77   binds: (typ * term) Vartab.table,     (*term bindings*)
    78   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    79   maxidx: int,                          (*maximum var index*)
    80   sorts: sort OrdList.T,                (*declared sort occurrences*)
    81   constraints:
    82     typ Vartab.table *                  (*type constraints*)
    83     sort Vartab.table};                 (*default sorts*)
    84 
    85 fun make_data (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =
    86   Data {is_body = is_body, names = names, consts = consts, fixes = fixes, binds = binds,
    87     type_occs = type_occs, maxidx = maxidx, sorts = sorts, constraints = constraints};
    88 
    89 structure Data = ProofDataFun
    90 (
    91   type T = data;
    92   fun init thy =
    93     make_data (false, Name.context, Symtab.empty, [], Vartab.empty, Symtab.empty,
    94       ~1, [], (Vartab.empty, Vartab.empty));
    95 );
    96 
    97 fun map_data f =
    98   Data.map (fn Data {is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints} =>
    99     make_data (f (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints)));
   100 
   101 fun map_names f =
   102   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   103     (is_body, f names, consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   104 
   105 fun map_consts f =
   106   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   107     (is_body, names, f consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   108 
   109 fun map_fixes f =
   110   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   111     (is_body, names, consts, f fixes, binds, type_occs, maxidx, sorts, constraints));
   112 
   113 fun map_binds f =
   114   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   115     (is_body, names, consts, fixes, f binds, type_occs, maxidx, sorts, constraints));
   116 
   117 fun map_type_occs f =
   118   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   119     (is_body, names, consts, fixes, binds, f type_occs, maxidx, sorts, constraints));
   120 
   121 fun map_maxidx f =
   122   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   123     (is_body, names, consts, fixes, binds, type_occs, f maxidx, sorts, constraints));
   124 
   125 fun map_sorts f =
   126   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   127     (is_body, names, consts, fixes, binds, type_occs, maxidx, f sorts, constraints));
   128 
   129 fun map_constraints f =
   130   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   131     (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, f constraints));
   132 
   133 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   134 
   135 val is_body = #is_body o rep_data;
   136 
   137 fun set_body b =
   138   map_data (fn (_, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   139     (b, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   140 
   141 fun restore_body ctxt = set_body (is_body ctxt);
   142 
   143 val names_of = #names o rep_data;
   144 val fixes_of = #fixes o rep_data;
   145 val binds_of = #binds o rep_data;
   146 val type_occs_of = #type_occs o rep_data;
   147 val maxidx_of = #maxidx o rep_data;
   148 val sorts_of = #sorts o rep_data;
   149 val constraints_of = #constraints o rep_data;
   150 
   151 val is_declared = Name.is_declared o names_of;
   152 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   153 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   154 
   155 fun add_fixed ctxt = Term.fold_aterms
   156   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   157 
   158 
   159 
   160 (** declarations **)
   161 
   162 (* default sorts and types *)
   163 
   164 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   165 
   166 fun def_type ctxt pattern xi =
   167   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   168     (case Vartab.lookup types xi of
   169       NONE =>
   170         if pattern then NONE
   171         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   172     | some => some)
   173   end;
   174 
   175 val def_sort = Vartab.lookup o #2 o constraints_of;
   176 
   177 
   178 (* names *)
   179 
   180 fun declare_type_names t =
   181   map_names (fold_types (fold_atyps Term.declare_typ_names) t) #>
   182   map_maxidx (fold_types Term.maxidx_typ t);
   183 
   184 fun declare_names t =
   185   declare_type_names t #>
   186   map_names (fold_aterms Term.declare_term_frees t) #>
   187   map_maxidx (Term.maxidx_term t);
   188 
   189 
   190 (* type occurrences *)
   191 
   192 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   193 
   194 val decl_type_occs = fold_term_types
   195   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   196     | _ => decl_type_occsT);
   197 
   198 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   199 val declare_type_occs = map_type_occs o decl_type_occs;
   200 
   201 
   202 (* constraints *)
   203 
   204 fun constrain_tvar (xi, S) =
   205   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   206 
   207 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   208   let
   209     val types' = fold_aterms
   210       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   211         | Var v => Vartab.update v
   212         | _ => I) t types;
   213     val sorts' = fold_types (fold_atyps
   214       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   215         | TVar v => constrain_tvar v
   216         | _ => I)) t sorts;
   217   in (types', sorts') end)
   218   #> declare_type_occsT t
   219   #> declare_type_names t;
   220 
   221 
   222 (* common declarations *)
   223 
   224 fun declare_internal t =
   225   declare_names t #>
   226   declare_type_occs t #>
   227   map_sorts (Sorts.insert_term t);
   228 
   229 fun declare_term t =
   230   declare_internal t #>
   231   declare_constraints t;
   232 
   233 val declare_typ = declare_term o Logic.mk_type;
   234 
   235 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   236 
   237 val declare_thm = Thm.fold_terms declare_internal;
   238 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   239 
   240 
   241 (* renaming term/type frees *)
   242 
   243 fun variant_frees ctxt ts frees =
   244   let
   245     val names = names_of (fold declare_names ts ctxt);
   246     val xs = fst (Name.variants (map #1 frees) names);
   247   in xs ~~ map snd frees end;
   248 
   249 
   250 
   251 (** term bindings **)
   252 
   253 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   254   | add_bind ((x, i), SOME t) =
   255       let
   256         val u = Term.close_schematic_term t;
   257         val U = Term.fastype_of u;
   258       in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   259 
   260 val add_binds = fold add_bind;
   261 
   262 fun expand_binds ctxt =
   263   let
   264     val binds = binds_of ctxt;
   265     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   266   in Envir.beta_norm o Envir.expand_term get end;
   267 
   268 
   269 
   270 (** consts **)
   271 
   272 val lookup_const = Symtab.lookup o #consts o rep_data;
   273 val is_const = is_some oo lookup_const;
   274 
   275 val declare_fixed = map_consts o Symtab.delete_safe;
   276 val declare_const = map_consts o Symtab.update;
   277 
   278 
   279 
   280 (** fixes **)
   281 
   282 local
   283 
   284 fun no_dups [] = ()
   285   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   286 
   287 fun new_fixes names' xs xs' =
   288   map_names (K names') #>
   289   fold declare_fixed xs #>
   290   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   291   fold (declare_constraints o Syntax.free) xs' #>
   292   pair xs';
   293 
   294 in
   295 
   296 fun add_fixes xs ctxt =
   297   let
   298     val _ =
   299       (case filter (can Name.dest_skolem) xs of [] => ()
   300       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   301     val _ = no_dups (duplicates (op =) xs);
   302     val (ys, zs) = split_list (fixes_of ctxt);
   303     val names = names_of ctxt;
   304     val (xs', names') =
   305       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   306       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   307         (xs, fold Name.declare xs names));
   308   in ctxt |> new_fixes names' xs xs' end;
   309 
   310 fun variant_fixes raw_xs ctxt =
   311   let
   312     val names = names_of ctxt;
   313     val xs = map (fn x => Name.clean x |> can Name.dest_internal x ? Name.internal) raw_xs;
   314     val (xs', names') = Name.variants xs names |>> (is_body ctxt ? map Name.skolem);
   315   in ctxt |> new_fixes names' xs xs' end;
   316 
   317 end;
   318 
   319 
   320 fun add_fixes_direct xs ctxt = ctxt
   321   |> set_body false
   322   |> (snd o add_fixes xs)
   323   |> restore_body ctxt;
   324 
   325 fun fix_frees t ctxt = ctxt
   326   |> add_fixes_direct
   327       (rev (fold_aterms (fn Free (x, _) =>
   328         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   329 
   330 fun auto_fixes t ctxt =
   331   (if is_body ctxt then ctxt else fix_frees t ctxt)
   332   |> declare_term t;
   333 
   334 fun invent_types Ss ctxt =
   335   let
   336     val tfrees = Name.invents (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   337     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   338   in (tfrees, ctxt') end;
   339 
   340 
   341 
   342 (** export -- generalize type/term variables (beware of closure sizes) **)
   343 
   344 fun export_inst inner outer =
   345   let
   346     val declared_outer = is_declared outer;
   347     val fixes_inner = fixes_of inner;
   348     val fixes_outer = fixes_of outer;
   349 
   350     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   351     val still_fixed = not o member (op =) gen_fixes;
   352 
   353     val type_occs_inner = type_occs_of inner;
   354     fun gen_fixesT ts =
   355       Symtab.fold (fn (a, xs) =>
   356         if declared_outer a orelse exists still_fixed xs
   357         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   358   in (gen_fixesT, gen_fixes) end;
   359 
   360 fun exportT_inst inner outer = #1 (export_inst inner outer);
   361 
   362 fun exportT_terms inner outer =
   363   let val mk_tfrees = exportT_inst inner outer in
   364     fn ts => ts |> map
   365       (TermSubst.generalize (mk_tfrees ts, [])
   366         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   367   end;
   368 
   369 fun export_terms inner outer =
   370   let val (mk_tfrees, tfrees) = export_inst inner outer in
   371     fn ts => ts |> map
   372       (TermSubst.generalize (mk_tfrees ts, tfrees)
   373         (fold Term.maxidx_term ts ~1 + 1))
   374   end;
   375 
   376 fun export_prf inner outer prf =
   377   let
   378     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   379     val tfrees = mk_tfrees [];
   380     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   381     val gen_term = TermSubst.generalize_option (tfrees, frees) idx;
   382     val gen_typ = TermSubst.generalizeT_option tfrees idx;
   383   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   384 
   385 
   386 fun gen_export (mk_tfrees, frees) ths =
   387   let
   388     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   389     val maxidx = fold Thm.maxidx_thm ths ~1;
   390   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   391 
   392 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   393 fun export inner outer = gen_export (export_inst inner outer);
   394 
   395 fun export_morphism inner outer =
   396   let
   397     val fact = export inner outer;
   398     val term = singleton (export_terms inner outer);
   399     val typ = Logic.type_map term;
   400   in Morphism.morphism {binding = I, typ = typ, term = term, fact = fact} end;
   401 
   402 
   403 
   404 (** import -- fix schematic type/term variables **)
   405 
   406 fun importT_inst ts ctxt =
   407   let
   408     val tvars = rev (fold Term.add_tvars ts []);
   409     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   410   in (tvars ~~ map TFree tfrees, ctxt') end;
   411 
   412 fun import_inst is_open ts ctxt =
   413   let
   414     val ren = Name.clean #> (if is_open then I else Name.internal);
   415     val (instT, ctxt') = importT_inst ts ctxt;
   416     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   417     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   418     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   419   in ((instT, inst), ctxt'') end;
   420 
   421 fun importT_terms ts ctxt =
   422   let val (instT, ctxt') = importT_inst ts ctxt
   423   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   424 
   425 fun import_terms is_open ts ctxt =
   426   let val (inst, ctxt') = import_inst is_open ts ctxt
   427   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   428 
   429 fun importT_thms ths ctxt =
   430   let
   431     val thy = ProofContext.theory_of ctxt;
   432     val certT = Thm.ctyp_of thy;
   433     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   434     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   435     val ths' = map (Thm.instantiate (instT', [])) ths;
   436   in ((map #2 instT', ths'), ctxt') end;
   437 
   438 fun import_prf is_open prf ctxt =
   439   let
   440     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   441     val (insts, ctxt') = import_inst is_open ts ctxt;
   442   in (Proofterm.instantiate insts prf, ctxt') end;
   443 
   444 fun import_thms is_open ths ctxt =
   445   let
   446     val thy = ProofContext.theory_of ctxt;
   447     val cert = Thm.cterm_of thy;
   448     val certT = Thm.ctyp_of thy;
   449     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   450     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   451     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   452     val ths' = map (Thm.instantiate (instT', inst')) ths;
   453   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   454 
   455 
   456 (* import/export *)
   457 
   458 fun gen_trade imp exp f ctxt ths =
   459   let val ((_, ths'), ctxt') = imp ths ctxt
   460   in exp ctxt' ctxt (f ctxt' ths') end;
   461 
   462 val tradeT = gen_trade importT_thms exportT;
   463 val trade = gen_trade (import_thms true) export;
   464 
   465 
   466 (* focus on outermost parameters *)
   467 
   468 fun forall_elim_prop t prop =
   469   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   470   |> Thm.cprop_of |> Thm.dest_arg;
   471 
   472 fun focus goal ctxt =
   473   let
   474     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   475     val t = Thm.term_of goal;
   476     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   477     val (xs, Ts) = split_list ps;
   478     val (xs', ctxt') = variant_fixes xs ctxt;
   479     val ps' = ListPair.map (cert o Free) (xs', Ts);
   480     val goal' = fold forall_elim_prop ps' goal;
   481     val ctxt'' = ctxt' |> fold (declare_constraints o Thm.term_of) ps';
   482   in ((ps', goal'), ctxt'') end;
   483 
   484 fun focus_subgoal i st =
   485   let
   486     val all_vars = Thm.fold_terms Term.add_vars st [];
   487     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   488   in
   489     add_binds no_binds #>
   490     fold (declare_constraints o Var) all_vars #>
   491     focus (Thm.cprem_of st i)
   492   end;
   493 
   494 
   495 
   496 (** implicit polymorphism **)
   497 
   498 (* warn_extra_tfrees *)
   499 
   500 fun warn_extra_tfrees ctxt1 ctxt2 =
   501   let
   502     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   503     fun occs_free a x =
   504       (case def_type ctxt1 false (x, ~1) of
   505         SOME T => if occs_typ a T then I else cons (a, x)
   506       | NONE => cons (a, x));
   507 
   508     val occs1 = type_occs_of ctxt1;
   509     val occs2 = type_occs_of ctxt2;
   510     val extras = Symtab.fold (fn (a, xs) =>
   511       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   512     val tfrees = map #1 extras |> sort_distinct string_ord;
   513     val frees = map #2 extras |> sort_distinct string_ord;
   514   in
   515     if null extras then ()
   516     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   517       space_implode " or " (map quote frees))
   518   end;
   519 
   520 
   521 (* polymorphic terms *)
   522 
   523 fun polymorphic_types ctxt ts =
   524   let
   525     val ctxt' = fold declare_term ts ctxt;
   526     val occs = type_occs_of ctxt;
   527     val occs' = type_occs_of ctxt';
   528     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   529     val idx = maxidx_of ctxt' + 1;
   530     val Ts' = (fold o fold_types o fold_atyps)
   531       (fn T as TFree _ =>
   532           (case TermSubst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   533         | _ => I) ts [];
   534     val ts' = map (TermSubst.generalize (types, []) idx) ts;
   535   in (rev Ts', ts') end;
   536 
   537 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   538 
   539 end;