src/HOL/Nitpick.thy
author blanchet
Tue Dec 07 11:56:01 2010 +0100 (2010-12-07)
changeset 41046 f2e94005d283
parent 39365 9cab71c20613
child 41052 3db267a01c1d
permissions -rw-r--r--
fix special handling of set products
     1 (*  Title:      HOL/Nitpick.thy
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2008, 2009, 2010
     4 
     5 Nitpick: Yet another counterexample generator for Isabelle/HOL.
     6 *)
     7 
     8 header {* Nitpick: Yet Another Counterexample Generator for Isabelle/HOL *}
     9 
    10 theory Nitpick
    11 imports Map Quotient SAT Record
    12 uses ("Tools/Nitpick/kodkod.ML")
    13      ("Tools/Nitpick/kodkod_sat.ML")
    14      ("Tools/Nitpick/nitpick_util.ML")
    15      ("Tools/Nitpick/nitpick_hol.ML")
    16      ("Tools/Nitpick/nitpick_preproc.ML")
    17      ("Tools/Nitpick/nitpick_mono.ML")
    18      ("Tools/Nitpick/nitpick_scope.ML")
    19      ("Tools/Nitpick/nitpick_peephole.ML")
    20      ("Tools/Nitpick/nitpick_rep.ML")
    21      ("Tools/Nitpick/nitpick_nut.ML")
    22      ("Tools/Nitpick/nitpick_kodkod.ML")
    23      ("Tools/Nitpick/nitpick_model.ML")
    24      ("Tools/Nitpick/nitpick.ML")
    25      ("Tools/Nitpick/nitpick_isar.ML")
    26      ("Tools/Nitpick/nitpick_tests.ML")
    27 begin
    28 
    29 typedecl bisim_iterator
    30 
    31 axiomatization unknown :: 'a
    32            and is_unknown :: "'a \<Rightarrow> bool"
    33            and bisim :: "bisim_iterator \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
    34            and bisim_iterator_max :: bisim_iterator
    35            and Quot :: "'a \<Rightarrow> 'b"
    36            and safe_The :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    37 
    38 datatype ('a, 'b) fin_fun = FinFun "('a \<Rightarrow> 'b)"
    39 datatype ('a, 'b) fun_box = FunBox "('a \<Rightarrow> 'b)"
    40 datatype ('a, 'b) pair_box = PairBox 'a 'b
    41 
    42 typedecl unsigned_bit
    43 typedecl signed_bit
    44 
    45 datatype 'a word = Word "('a set)"
    46 
    47 text {*
    48 Alternative definitions.
    49 *}
    50 
    51 lemma If_def [nitpick_def, no_atp]:
    52 "(if P then Q else R) \<equiv> (P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R)"
    53 by (rule eq_reflection) (rule if_bool_eq_conj)
    54 
    55 lemma Ex1_def [nitpick_def, no_atp]:
    56 "Ex1 P \<equiv> \<exists>x. P = {x}"
    57 apply (rule eq_reflection)
    58 apply (simp add: Ex1_def set_eq_iff)
    59 apply (rule iffI)
    60  apply (erule exE)
    61  apply (erule conjE)
    62  apply (rule_tac x = x in exI)
    63  apply (rule allI)
    64  apply (rename_tac y)
    65  apply (erule_tac x = y in allE)
    66 by (auto simp: mem_def)
    67 
    68 lemma rtrancl_def [nitpick_def, no_atp]: "r\<^sup>* \<equiv> (r\<^sup>+)\<^sup>="
    69 by simp
    70 
    71 lemma rtranclp_def [nitpick_def, no_atp]:
    72 "rtranclp r a b \<equiv> (a = b \<or> tranclp r a b)"
    73 by (rule eq_reflection) (auto dest: rtranclpD)
    74 
    75 lemma tranclp_def [nitpick_def, no_atp]:
    76 "tranclp r a b \<equiv> trancl (split r) (a, b)"
    77 by (simp add: trancl_def Collect_def mem_def)
    78 
    79 definition prod :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
    80 "prod A B = {(a, b). a \<in> A \<and> b \<in> B}"
    81 
    82 definition refl' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    83 "refl' r \<equiv> \<forall>x. (x, x) \<in> r"
    84 
    85 definition wf' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    86 "wf' r \<equiv> acyclic r \<and> (finite r \<or> unknown)"
    87 
    88 axiomatization wf_wfrec :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b"
    89 
    90 definition wf_wfrec' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    91 [nitpick_simp]: "wf_wfrec' R F x = F (Recdef.cut (wf_wfrec R F) R x) x"
    92 
    93 definition wfrec' ::  "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    94 "wfrec' R F x \<equiv> if wf R then wf_wfrec' R F x
    95                 else THE y. wfrec_rel R (%f x. F (Recdef.cut f R x) x) x y"
    96 
    97 definition card' :: "('a \<Rightarrow> bool) \<Rightarrow> nat" where
    98 "card' A \<equiv> if finite A then length (SOME xs. set xs = A \<and> distinct xs) else 0"
    99 
   100 definition setsum' :: "('a \<Rightarrow> 'b\<Colon>comm_monoid_add) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b" where
   101 "setsum' f A \<equiv> if finite A then listsum (map f (SOME xs. set xs = A \<and> distinct xs)) else 0"
   102 
   103 inductive fold_graph' :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b \<Rightarrow> bool" where
   104 "fold_graph' f z {} z" |
   105 "\<lbrakk>x \<in> A; fold_graph' f z (A - {x}) y\<rbrakk> \<Longrightarrow> fold_graph' f z A (f x y)"
   106 
   107 text {*
   108 The following lemmas are not strictly necessary but they help the
   109 \textit{special\_level} optimization.
   110 *}
   111 
   112 lemma The_psimp [nitpick_psimp, no_atp]:
   113 "P = {x} \<Longrightarrow> The P = x"
   114 by (subgoal_tac "{x} = (\<lambda>y. y = x)") (auto simp: mem_def)
   115 
   116 lemma Eps_psimp [nitpick_psimp, no_atp]:
   117 "\<lbrakk>P x; \<not> P y; Eps P = y\<rbrakk> \<Longrightarrow> Eps P = x"
   118 apply (case_tac "P (Eps P)")
   119  apply auto
   120 apply (erule contrapos_np)
   121 by (rule someI)
   122 
   123 lemma unit_case_def [nitpick_def, no_atp]:
   124 "unit_case x u \<equiv> x"
   125 apply (subgoal_tac "u = ()")
   126  apply (simp only: unit.cases)
   127 by simp
   128 
   129 declare unit.cases [nitpick_simp del]
   130 
   131 lemma nat_case_def [nitpick_def, no_atp]:
   132 "nat_case x f n \<equiv> if n = 0 then x else f (n - 1)"
   133 apply (rule eq_reflection)
   134 by (case_tac n) auto
   135 
   136 declare nat.cases [nitpick_simp del]
   137 
   138 lemma list_size_simp [nitpick_simp, no_atp]:
   139 "list_size f xs = (if xs = [] then 0
   140                    else Suc (f (hd xs) + list_size f (tl xs)))"
   141 "size xs = (if xs = [] then 0 else Suc (size (tl xs)))"
   142 by (case_tac xs) auto
   143 
   144 text {*
   145 Auxiliary definitions used to provide an alternative representation for
   146 @{text rat} and @{text real}.
   147 *}
   148 
   149 function nat_gcd :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   150 [simp del]: "nat_gcd x y = (if y = 0 then x else nat_gcd y (x mod y))"
   151 by auto
   152 termination
   153 apply (relation "measure (\<lambda>(x, y). x + y + (if y > x then 1 else 0))")
   154  apply auto
   155  apply (metis mod_less_divisor xt1(9))
   156 by (metis mod_mod_trivial mod_self nat_neq_iff xt1(10))
   157 
   158 definition nat_lcm :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   159 "nat_lcm x y = x * y div (nat_gcd x y)"
   160 
   161 definition int_gcd :: "int \<Rightarrow> int \<Rightarrow> int" where
   162 "int_gcd x y = int (nat_gcd (nat (abs x)) (nat (abs y)))"
   163 
   164 definition int_lcm :: "int \<Rightarrow> int \<Rightarrow> int" where
   165 "int_lcm x y = int (nat_lcm (nat (abs x)) (nat (abs y)))"
   166 
   167 definition Frac :: "int \<times> int \<Rightarrow> bool" where
   168 "Frac \<equiv> \<lambda>(a, b). b > 0 \<and> int_gcd a b = 1"
   169 
   170 axiomatization Abs_Frac :: "int \<times> int \<Rightarrow> 'a"
   171            and Rep_Frac :: "'a \<Rightarrow> int \<times> int"
   172 
   173 definition zero_frac :: 'a where
   174 "zero_frac \<equiv> Abs_Frac (0, 1)"
   175 
   176 definition one_frac :: 'a where
   177 "one_frac \<equiv> Abs_Frac (1, 1)"
   178 
   179 definition num :: "'a \<Rightarrow> int" where
   180 "num \<equiv> fst o Rep_Frac"
   181 
   182 definition denom :: "'a \<Rightarrow> int" where
   183 "denom \<equiv> snd o Rep_Frac"
   184 
   185 function norm_frac :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
   186 [simp del]: "norm_frac a b = (if b < 0 then norm_frac (- a) (- b)
   187                               else if a = 0 \<or> b = 0 then (0, 1)
   188                               else let c = int_gcd a b in (a div c, b div c))"
   189 by pat_completeness auto
   190 termination by (relation "measure (\<lambda>(_, b). if b < 0 then 1 else 0)") auto
   191 
   192 definition frac :: "int \<Rightarrow> int \<Rightarrow> 'a" where
   193 "frac a b \<equiv> Abs_Frac (norm_frac a b)"
   194 
   195 definition plus_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   196 [nitpick_simp]:
   197 "plus_frac q r = (let d = int_lcm (denom q) (denom r) in
   198                     frac (num q * (d div denom q) + num r * (d div denom r)) d)"
   199 
   200 definition times_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   201 [nitpick_simp]:
   202 "times_frac q r = frac (num q * num r) (denom q * denom r)"
   203 
   204 definition uminus_frac :: "'a \<Rightarrow> 'a" where
   205 "uminus_frac q \<equiv> Abs_Frac (- num q, denom q)"
   206 
   207 definition number_of_frac :: "int \<Rightarrow> 'a" where
   208 "number_of_frac n \<equiv> Abs_Frac (n, 1)"
   209 
   210 definition inverse_frac :: "'a \<Rightarrow> 'a" where
   211 "inverse_frac q \<equiv> frac (denom q) (num q)"
   212 
   213 definition less_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   214 [nitpick_simp]:
   215 "less_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) < 0"
   216 
   217 definition less_eq_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   218 [nitpick_simp]:
   219 "less_eq_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) \<le> 0"
   220 
   221 definition of_frac :: "'a \<Rightarrow> 'b\<Colon>{inverse,ring_1}" where
   222 "of_frac q \<equiv> of_int (num q) / of_int (denom q)"
   223 
   224 use "Tools/Nitpick/kodkod.ML"
   225 use "Tools/Nitpick/kodkod_sat.ML"
   226 use "Tools/Nitpick/nitpick_util.ML"
   227 use "Tools/Nitpick/nitpick_hol.ML"
   228 use "Tools/Nitpick/nitpick_mono.ML"
   229 use "Tools/Nitpick/nitpick_preproc.ML"
   230 use "Tools/Nitpick/nitpick_scope.ML"
   231 use "Tools/Nitpick/nitpick_peephole.ML"
   232 use "Tools/Nitpick/nitpick_rep.ML"
   233 use "Tools/Nitpick/nitpick_nut.ML"
   234 use "Tools/Nitpick/nitpick_kodkod.ML"
   235 use "Tools/Nitpick/nitpick_model.ML"
   236 use "Tools/Nitpick/nitpick.ML"
   237 use "Tools/Nitpick/nitpick_isar.ML"
   238 use "Tools/Nitpick/nitpick_tests.ML"
   239 
   240 setup {* Nitpick_Isar.setup *}
   241 
   242 hide_const (open) unknown is_unknown bisim bisim_iterator_max Quot safe_The
   243     FinFun FunBox PairBox Word prod refl' wf' wf_wfrec wf_wfrec' wfrec' card'
   244     setsum' fold_graph' nat_gcd nat_lcm int_gcd int_lcm Frac Abs_Frac Rep_Frac
   245     zero_frac one_frac num denom norm_frac frac plus_frac times_frac uminus_frac
   246     number_of_frac inverse_frac less_frac less_eq_frac of_frac
   247 hide_type (open) bisim_iterator fin_fun fun_box pair_box unsigned_bit signed_bit
   248     word
   249 hide_fact (open) If_def Ex1_def rtrancl_def rtranclp_def tranclp_def prod_def
   250     refl'_def wf'_def wf_wfrec'_def wfrec'_def card'_def setsum'_def
   251     fold_graph'_def The_psimp Eps_psimp unit_case_def nat_case_def
   252     list_size_simp nat_gcd_def nat_lcm_def int_gcd_def int_lcm_def Frac_def
   253     zero_frac_def one_frac_def num_def denom_def norm_frac_def frac_def
   254     plus_frac_def times_frac_def uminus_frac_def number_of_frac_def
   255     inverse_frac_def less_frac_def less_eq_frac_def of_frac_def
   256 
   257 end