src/HOL/Tools/datatype_package.ML
author wenzelm
Wed Apr 04 23:29:38 2007 +0200 (2007-04-04)
changeset 22598 f31a869077f0
parent 22578 b0eb5652f210
child 22675 acf10be7dcca
permissions -rw-r--r--
rep_thm/cterm/ctyp: removed obsolete sign field;
renamed Variable.importT to importT_thms;
     1 (*  Title:      HOL/Tools/datatype_package.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer, TU Muenchen
     4 
     5 Datatype package for Isabelle/HOL.
     6 *)
     7 
     8 signature BASIC_DATATYPE_PACKAGE =
     9 sig
    10   val induct_tac : string -> int -> tactic
    11   val induct_thm_tac : thm -> string -> int -> tactic
    12   val case_tac : string -> int -> tactic
    13   val distinct_simproc : simproc
    14 end;
    15 
    16 signature DATATYPE_PACKAGE =
    17 sig
    18   include BASIC_DATATYPE_PACKAGE
    19   val quiet_mode : bool ref
    20   val add_datatype : bool -> string list -> (string list * bstring * mixfix *
    21     (bstring * string list * mixfix) list) list -> theory ->
    22       {distinct : thm list list,
    23        inject : thm list list,
    24        exhaustion : thm list,
    25        rec_thms : thm list,
    26        case_thms : thm list list,
    27        split_thms : (thm * thm) list,
    28        induction : thm,
    29        size : thm list,
    30        simps : thm list} * theory
    31   val add_datatype_i : bool -> bool -> string list -> (string list * bstring * mixfix *
    32     (bstring * typ list * mixfix) list) list -> theory ->
    33       {distinct : thm list list,
    34        inject : thm list list,
    35        exhaustion : thm list,
    36        rec_thms : thm list,
    37        case_thms : thm list list,
    38        split_thms : (thm * thm) list,
    39        induction : thm,
    40        size : thm list,
    41        simps : thm list} * theory
    42   val rep_datatype_i : string list option -> (thm list * attribute list) list list ->
    43     (thm list * attribute list) list list -> (thm list * attribute list) ->
    44     theory ->
    45       {distinct : thm list list,
    46        inject : thm list list,
    47        exhaustion : thm list,
    48        rec_thms : thm list,
    49        case_thms : thm list list,
    50        split_thms : (thm * thm) list,
    51        induction : thm,
    52        size : thm list,
    53        simps : thm list} * theory
    54   val rep_datatype : string list option -> (thmref * Attrib.src list) list list ->
    55     (thmref * Attrib.src list) list list -> thmref * Attrib.src list -> theory ->
    56       {distinct : thm list list,
    57        inject : thm list list,
    58        exhaustion : thm list,
    59        rec_thms : thm list,
    60        case_thms : thm list list,
    61        split_thms : (thm * thm) list,
    62        induction : thm,
    63        size : thm list,
    64        simps : thm list} * theory
    65   val get_datatypes : theory -> DatatypeAux.datatype_info Symtab.table
    66   val get_datatype : theory -> string -> DatatypeAux.datatype_info option
    67   val the_datatype : theory -> string -> DatatypeAux.datatype_info
    68   val get_datatype_spec : theory -> string -> ((string * sort) list * (string * typ list) list) option
    69   val get_datatype_constrs : theory -> string -> (string * typ) list option
    70   val print_datatypes : theory -> unit
    71   val setup: theory -> theory
    72 end;
    73 
    74 structure DatatypePackage : DATATYPE_PACKAGE =
    75 struct
    76 
    77 open DatatypeAux;
    78 
    79 val quiet_mode = quiet_mode;
    80 
    81 
    82 (* data kind 'HOL/datatypes' *)
    83 
    84 structure DatatypesData = TheoryDataFun
    85 (struct
    86   val name = "HOL/datatypes";
    87   type T = datatype_info Symtab.table;
    88 
    89   val empty = Symtab.empty;
    90   val copy = I;
    91   val extend = I;
    92   fun merge _ tabs : T = Symtab.merge (K true) tabs;
    93 
    94   fun print sg tab =
    95     Pretty.writeln (Pretty.strs ("datatypes:" ::
    96       map #1 (NameSpace.extern_table (Sign.type_space sg, tab))));
    97 end);
    98 
    99 val get_datatypes = DatatypesData.get;
   100 val put_datatypes = DatatypesData.put;
   101 val print_datatypes = DatatypesData.print;
   102 
   103 
   104 (** theory information about datatypes **)
   105 
   106 val get_datatype = Symtab.lookup o get_datatypes;
   107 
   108 fun the_datatype thy name = (case get_datatype thy name of
   109       SOME info => info
   110     | NONE => error ("Unknown datatype " ^ quote name));
   111 
   112 fun get_datatype_descr thy dtco =
   113   get_datatype thy dtco
   114   |> Option.map (fn info as { descr, index, ... } => 
   115        (info, (((fn SOME (_, dtys, cos) => (dtys, cos)) o AList.lookup (op =) descr) index)));
   116 
   117 fun get_datatype_spec thy dtco =
   118   let
   119     fun mk_cons typ_of_dtyp (co, tys) =
   120       (co, map typ_of_dtyp tys);
   121     fun mk_dtyp ({ sorts = raw_sorts, descr, ... } : DatatypeAux.datatype_info, (dtys, cos)) =
   122       let
   123         val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
   124           o DatatypeAux.dest_DtTFree) dtys;
   125         val typ_of_dtyp = DatatypeAux.typ_of_dtyp descr sorts;
   126         val tys = map typ_of_dtyp dtys;
   127       in (sorts, map (mk_cons typ_of_dtyp) cos) end;
   128   in Option.map mk_dtyp (get_datatype_descr thy dtco) end;
   129 
   130 fun get_datatype_constrs thy dtco =
   131   case get_datatype_spec thy dtco
   132    of SOME (sorts, cos) =>
   133         let
   134           fun subst (v, sort) = TVar ((v, 0), sort);
   135           fun subst_ty (TFree v) = subst v
   136             | subst_ty ty = ty;
   137           val dty = Type (dtco, map subst sorts);
   138           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   139         in SOME (map mk_co cos) end
   140     | NONE => NONE;
   141 
   142 fun find_tname var Bi =
   143   let val frees = map dest_Free (term_frees Bi)
   144       val params = rename_wrt_term Bi (Logic.strip_params Bi);
   145   in case AList.lookup (op =) (frees @ params) var of
   146        NONE => error ("No such variable in subgoal: " ^ quote var)
   147      | SOME(Type (tn, _)) => tn
   148      | _ => error ("Cannot determine type of " ^ quote var)
   149   end;
   150 
   151 fun infer_tname state i aterm =
   152   let
   153     val sign = Thm.theory_of_thm state;
   154     val (_, _, Bi, _) = Thm.dest_state (state, i)
   155     val params = Logic.strip_params Bi;   (*params of subgoal i*)
   156     val params = rev (rename_wrt_term Bi params);   (*as they are printed*)
   157     val (types, sorts) = types_sorts state;
   158     fun types' (a, ~1) = (case AList.lookup (op =) params a of NONE => types(a, ~1) | sm => sm)
   159       | types' ixn = types ixn;
   160     val (ct, _) = read_def_cterm (sign, types', sorts) [] false (aterm, TypeInfer.logicT);
   161   in case #T (rep_cterm ct) of
   162        Type (tn, _) => tn
   163      | _ => error ("Cannot determine type of " ^ quote aterm)
   164   end;
   165 
   166 (*Warn if the (induction) variable occurs Free among the premises, which
   167   usually signals a mistake.  But calls the tactic either way!*)
   168 fun occs_in_prems tacf vars =
   169   SUBGOAL (fn (Bi, i) =>
   170            (if exists (fn (a, _) => member (op =) vars a)
   171                       (fold Term.add_frees (#2 (strip_context Bi)) [])
   172              then warning "Induction variable occurs also among premises!"
   173              else ();
   174             tacf i));
   175 
   176 
   177 (* generic induction tactic for datatypes *)
   178 
   179 local
   180 
   181 fun prep_var (Var (ixn, _), SOME x) = SOME (ixn, x)
   182   | prep_var _ = NONE;
   183 
   184 fun prep_inst (concl, xs) = (*exception Library.UnequalLengths*)
   185   let val vs = InductAttrib.vars_of concl
   186   in map_filter prep_var (Library.drop (length vs - length xs, vs) ~~ xs) end;
   187 
   188 in
   189 
   190 fun gen_induct_tac inst_tac (varss, opt_rule) i state = 
   191   SUBGOAL (fn (Bi,_) =>
   192   let
   193     val (rule, rule_name) =
   194       case opt_rule of
   195           SOME r => (r, "Induction rule")
   196         | NONE =>
   197             let val tn = find_tname (hd (map_filter I (flat varss))) Bi
   198                 val thy = Thm.theory_of_thm state
   199             in (#induction (the_datatype thy tn), "Induction rule for type " ^ tn) 
   200             end
   201     val concls = HOLogic.dest_concls (Thm.concl_of rule);
   202     val insts = maps prep_inst (concls ~~ varss) handle Library.UnequalLengths =>
   203       error (rule_name ^ " has different numbers of variables");
   204   in occs_in_prems (inst_tac insts rule) (map #2 insts) i end)
   205   i state;
   206 
   207 fun induct_tac s =
   208   gen_induct_tac Tactic.res_inst_tac'
   209     (map (single o SOME) (Syntax.read_idents s), NONE);
   210 
   211 fun induct_thm_tac th s =
   212   gen_induct_tac Tactic.res_inst_tac'
   213     ([map SOME (Syntax.read_idents s)], SOME th);
   214 
   215 end;
   216 
   217 
   218 (* generic case tactic for datatypes *)
   219 
   220 fun case_inst_tac inst_tac t rule i state =
   221   let
   222     val _ $ Var (ixn, _) $ _ = HOLogic.dest_Trueprop
   223       (hd (Logic.strip_assums_hyp (hd (Thm.prems_of rule))));
   224   in inst_tac [(ixn, t)] rule i state end;
   225 
   226 fun gen_case_tac inst_tac (t, SOME rule) i state =
   227       case_inst_tac inst_tac t rule i state
   228   | gen_case_tac inst_tac (t, NONE) i state =
   229       let val tn = infer_tname state i t in
   230         if tn = HOLogic.boolN then inst_tac [(("P", 0), t)] case_split_thm i state
   231         else case_inst_tac inst_tac t
   232                (#exhaustion (the_datatype (Thm.theory_of_thm state) tn))
   233                i state
   234       end handle THM _ => Seq.empty;
   235 
   236 fun case_tac t = gen_case_tac Tactic.res_inst_tac' (t, NONE);
   237 
   238 
   239 
   240 (** Isar tactic emulations **)
   241 
   242 local
   243 
   244 val rule_spec = Scan.lift (Args.$$$ "rule" -- Args.$$$ ":");
   245 val opt_rule = Scan.option (rule_spec |-- Attrib.thm);
   246 
   247 val varss =
   248   Args.and_list (Scan.repeat (Scan.unless rule_spec (Scan.lift (Args.maybe Args.name))));
   249 
   250 val inst_tac = RuleInsts.bires_inst_tac false;
   251 
   252 fun induct_meth ctxt (varss, opt_rule) =
   253   gen_induct_tac (inst_tac ctxt) (varss, opt_rule);
   254 fun case_meth ctxt (varss, opt_rule) =
   255   gen_case_tac (inst_tac ctxt) (varss, opt_rule);
   256 
   257 in
   258 
   259 val tactic_emulations =
   260  [("induct_tac", Method.goal_args_ctxt' (varss -- opt_rule) induct_meth,
   261     "induct_tac emulation (dynamic instantiation)"),
   262   ("case_tac", Method.goal_args_ctxt' (Scan.lift Args.name -- opt_rule) case_meth,
   263     "case_tac emulation (dynamic instantiation)")];
   264 
   265 end;
   266 
   267 
   268 
   269 (** induct method setup **)
   270 
   271 (* case names *)
   272 
   273 local
   274 
   275 fun dt_recs (DtTFree _) = []
   276   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   277   | dt_recs (DtRec i) = [i];
   278 
   279 fun dt_cases (descr: descr) (_, args, constrs) =
   280   let
   281     fun the_bname i = Sign.base_name (#1 (the (AList.lookup (op =) descr i)));
   282     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   283   in map (fn (c, _) => space_implode "_" (Sign.base_name c :: bnames)) constrs end;
   284 
   285 
   286 fun induct_cases descr =
   287   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   288 
   289 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   290 
   291 in
   292 
   293 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   294 
   295 fun mk_case_names_exhausts descr new =
   296   map (RuleCases.case_names o exhaust_cases descr o #1)
   297     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   298 
   299 end;
   300 
   301 fun add_rules simps case_thms size_thms rec_thms inject distinct
   302                   weak_case_congs cong_att =
   303   PureThy.add_thmss [(("simps", simps), []),
   304     (("", flat case_thms @ size_thms @ 
   305           flat distinct @ rec_thms), [Simplifier.simp_add]),
   306     (("", size_thms @ rec_thms), [RecfunCodegen.add NONE]),
   307     (("", flat inject), [iff_add]),
   308     (("", map (fn th => th RS notE) (flat distinct)), [Classical.safe_elim NONE]),
   309     (("", weak_case_congs), [cong_att])]
   310   #> snd;
   311 
   312 
   313 (* add_cases_induct *)
   314 
   315 fun add_cases_induct infos induction thy =
   316   let
   317     val inducts = ProjectRule.projections (ProofContext.init thy) induction;
   318 
   319     fun named_rules (name, {index, exhaustion, ...}: datatype_info) =
   320       [(("", nth inducts index), [InductAttrib.induct_type name]),
   321        (("", exhaustion), [InductAttrib.cases_type name])];
   322     fun unnamed_rule i =
   323       (("", nth inducts i), [PureThy.kind_internal, InductAttrib.induct_type ""]);
   324   in
   325     thy |> PureThy.add_thms
   326       (maps named_rules infos @
   327         map unnamed_rule (length infos upto length inducts - 1)) |> snd
   328     |> PureThy.add_thmss [(("inducts", inducts), [])] |> snd
   329   end;
   330 
   331 
   332 
   333 (**** simplification procedure for showing distinctness of constructors ****)
   334 
   335 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   336   | stripT p = p;
   337 
   338 fun stripC (i, f $ x) = stripC (i + 1, f)
   339   | stripC p = p;
   340 
   341 val distinctN = "constr_distinct";
   342 
   343 exception ConstrDistinct of term;
   344 
   345 fun distinct_proc thy ss (t as Const ("op =", _) $ t1 $ t2) =
   346   (case (stripC (0, t1), stripC (0, t2)) of
   347      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   348          (case (stripT (0, T1), stripT (0, T2)) of
   349             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   350                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   351                    (case (get_datatype_descr thy) tname1 of
   352                       SOME (_, (_, constrs)) => let val cnames = map fst constrs
   353                         in if cname1 mem cnames andalso cname2 mem cnames then
   354                              let val eq_t = Logic.mk_equals (t, Const ("False", HOLogic.boolT));
   355                                  val eq_ct = cterm_of thy eq_t;
   356                                  val Datatype_thy = ThyInfo.the_theory "Datatype" thy;
   357                                  val [In0_inject, In1_inject, In0_not_In1, In1_not_In0] =
   358                                    map (get_thm Datatype_thy o Name)
   359                                      ["In0_inject", "In1_inject", "In0_not_In1", "In1_not_In0"]
   360                              in (case (#distinct (the_datatype thy tname1)) of
   361                                  QuickAndDirty => SOME (Thm.invoke_oracle
   362                                    Datatype_thy distinctN (thy, ConstrDistinct eq_t))
   363                                | FewConstrs thms =>
   364                                    SOME (Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   365                                      (EVERY [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   366                                        atac 2, resolve_tac thms 1, etac FalseE 1])))
   367                                | ManyConstrs (thm, simpset) =>
   368                                    SOME (Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   369                                      (EVERY [rtac eq_reflection 1, rtac iffI 1, dtac thm 1,
   370                                       full_simp_tac (Simplifier.inherit_context ss simpset) 1,
   371                                       REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   372                                       eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1,
   373                                       etac FalseE 1]))))
   374                              end
   375                            else NONE
   376                         end
   377                     | NONE => NONE)
   378                 else NONE
   379           | _ => NONE)
   380    | _ => NONE)
   381   | distinct_proc _ _ _ = NONE;
   382 
   383 val distinct_simproc =
   384   Simplifier.simproc HOL.thy distinctN ["s = t"] distinct_proc;
   385 
   386 val dist_ss = HOL_ss addsimprocs [distinct_simproc];
   387 
   388 val simproc_setup =
   389   Theory.add_oracle (distinctN, fn (_, ConstrDistinct t) => t) #>
   390   (fn thy => ((change_simpset_of thy) (fn ss => ss addsimprocs [distinct_simproc]); thy));
   391 
   392 
   393 (**** translation rules for case ****)
   394 
   395 fun case_tr ctxt [t, u] =
   396     let
   397       val thy = ProofContext.theory_of ctxt;
   398       fun case_error s name ts = raise TERM ("Error in case expression" ^
   399         getOpt (Option.map (curry op ^ " for datatype ") name, "") ^ ":\n" ^ s, ts);
   400       fun dest_case1 (Const ("_case1", _) $ t $ u) =
   401           (case strip_comb t of
   402             (Const (s, _), ts) =>
   403               (case try (unprefix Syntax.constN) s of
   404                 SOME c => (c, ts)
   405               | NONE => (Sign.intern_const thy s, ts))
   406           | (Free (s, _), ts) => (Sign.intern_const thy s, ts)
   407           | _ => case_error "Head is not a constructor" NONE [t, u], u)
   408         | dest_case1 t = raise TERM ("dest_case1", [t]);
   409       fun dest_case2 (Const ("_case2", _) $ t $ u) = t :: dest_case2 u
   410         | dest_case2 t = [t];
   411       val cases as ((cname, _), _) :: _ = map dest_case1 (dest_case2 u);
   412       val tab = Symtab.dest (get_datatypes thy);
   413       val (cases', default) = (case split_last cases of
   414           (cases', (("dummy_pattern", []), t)) => (cases', SOME t)
   415         | _ => (cases, NONE))
   416       fun abstr (Free (x, T)) body = Term.absfree (x, T, body)
   417         | abstr (Const ("_constrain", _) $ Free (x, T) $ tT) body =
   418             Syntax.const Syntax.constrainAbsC $ Term.absfree (x, T, body) $ tT
   419         | abstr (Const ("Pair", _) $ x $ y) body =
   420             Syntax.const "split" $ (abstr x o abstr y) body
   421         | abstr t _ = case_error "Illegal pattern" NONE [t];
   422     in case find_first (fn (_, {descr, index, ...}) =>
   423       exists (equal cname o fst) (#3 (snd (nth descr index)))) tab of
   424         NONE => case_error ("Not a datatype constructor: " ^ cname) NONE [u]
   425       | SOME (tname, {descr, sorts, case_name, index, ...}) =>
   426         let
   427           val _ = if exists (equal "dummy_pattern" o fst o fst) cases' then
   428             case_error "Illegal occurrence of '_' dummy pattern" (SOME tname) [u] else ();
   429           val (_, (_, dts, constrs)) = nth descr index;
   430           fun find_case (s, dt) cases =
   431             (case find_first (equal s o fst o fst) cases' of
   432                NONE => (list_abs (map (rpair dummyT)
   433                  (DatatypeProp.make_tnames (map (typ_of_dtyp descr sorts) dt)),
   434                  case default of
   435                    NONE => (warning ("No clause for constructor " ^ s ^
   436                      " in case expression"); Const ("HOL.undefined", dummyT))
   437                  | SOME t => t), cases)
   438              | SOME (c as ((_, vs), t)) =>
   439                  if length dt <> length vs then
   440                     case_error ("Wrong number of arguments for constructor " ^ s)
   441                       (SOME tname) vs
   442                  else (fold_rev abstr vs t, remove (op =) c cases))
   443           val (fs, cases'') = fold_map find_case constrs cases'
   444         in case (cases'', length constrs = length cases', default) of
   445             ([], true, SOME _) =>
   446               case_error "Extra '_' dummy pattern" (SOME tname) [u]
   447           | (_ :: _, _, _) =>
   448               let val extra = distinct (op =) (map (fst o fst) cases'')
   449               in case extra \\ map fst constrs of
   450                   [] => case_error ("More than one clause for constructor(s) " ^
   451                     commas extra) (SOME tname) [u]
   452                 | extra' => case_error ("Illegal constructor(s): " ^ commas extra')
   453                     (SOME tname) [u]
   454               end
   455           | _ => list_comb (Syntax.const case_name, fs) $ t
   456         end
   457     end
   458   | case_tr _ ts = raise TERM ("case_tr", ts);
   459 
   460 fun case_tr' constrs ctxt ts =
   461   if length ts <> length constrs + 1 then raise Match else
   462   let
   463     val consts = ProofContext.consts_of ctxt;
   464 
   465     val (fs, x) = split_last ts;
   466     fun strip_abs 0 t = ([], t)
   467       | strip_abs i (Abs p) =
   468         let val (x, u) = Syntax.atomic_abs_tr' p
   469         in apfst (cons x) (strip_abs (i-1) u) end
   470       | strip_abs i (Const ("split", _) $ t) = (case strip_abs (i+1) t of
   471           (v :: v' :: vs, u) => (Syntax.const "Pair" $ v $ v' :: vs, u));
   472     fun is_dependent i t =
   473       let val k = length (strip_abs_vars t) - i
   474       in k < 0 orelse exists (fn j => j >= k)
   475         (loose_bnos (strip_abs_body t))
   476       end;
   477     val cases = map (fn ((cname, dts), t) =>
   478       (Consts.extern_early consts cname,
   479        strip_abs (length dts) t, is_dependent (length dts) t))
   480       (constrs ~~ fs);
   481     fun count_cases (_, _, true) = I
   482       | count_cases (cname, (_, body), false) =
   483           AList.map_default (op = : term * term -> bool)
   484             (body, []) (cons cname)
   485     val cases' = sort (int_ord o swap o pairself (length o snd))
   486       (fold_rev count_cases cases []);
   487     fun mk_case1 (cname, (vs, body), _) = Syntax.const "_case1" $
   488       list_comb (Syntax.const cname, vs) $ body;
   489     fun is_undefined (Const ("HOL.undefined", _)) = true
   490       | is_undefined _ = false;
   491   in
   492     Syntax.const "_case_syntax" $ x $
   493       foldr1 (fn (t, u) => Syntax.const "_case2" $ t $ u) (map mk_case1
   494         (case find_first (is_undefined o fst) cases' of
   495            SOME (_, cnames) =>
   496            if length cnames = length constrs then [hd cases]
   497            else filter_out (fn (_, (_, body), _) => is_undefined body) cases
   498          | NONE => case cases' of
   499            [] => cases
   500          | (default, cnames) :: _ =>
   501            if length cnames = 1 then cases
   502            else if length cnames = length constrs then
   503              [hd cases, ("dummy_pattern", ([], default), false)]
   504            else
   505              filter_out (fn (cname, _, _) => member (op =) cnames cname) cases @
   506              [("dummy_pattern", ([], default), false)]))
   507   end;
   508 
   509 fun make_case_tr' case_names descr = maps
   510   (fn ((_, (_, _, constrs)), case_name) =>
   511     map (rpair (case_tr' constrs)) (NameSpace.accesses' case_name))
   512       (descr ~~ case_names);
   513 
   514 val trfun_setup =
   515   Theory.add_advanced_trfuns ([], [("_case_syntax", case_tr)], [], []);
   516 
   517 
   518 (* prepare types *)
   519 
   520 fun read_typ sign ((Ts, sorts), str) =
   521   let
   522     val T = Type.no_tvars (Sign.read_typ (sign, AList.lookup (op =)
   523       (map (apfst (rpair ~1)) sorts)) str) handle TYPE (msg, _, _) => error msg
   524   in (Ts @ [T], add_typ_tfrees (T, sorts)) end;
   525 
   526 fun cert_typ sign ((Ts, sorts), raw_T) =
   527   let
   528     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   529       TYPE (msg, _, _) => error msg;
   530     val sorts' = add_typ_tfrees (T, sorts)
   531   in (Ts @ [T],
   532       case duplicates (op =) (map fst sorts') of
   533          [] => sorts'
   534        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   535   end;
   536 
   537 
   538 (**** make datatype info ****)
   539 
   540 fun make_dt_info descr sorts induct reccomb_names rec_thms
   541     (((((((((i, (_, (tname, _, _))), case_name), case_thms),
   542       exhaustion_thm), distinct_thm), inject), nchotomy), case_cong), weak_case_cong) =
   543   (tname,
   544    {index = i,
   545     descr = descr,
   546     sorts = sorts,
   547     rec_names = reccomb_names,
   548     rec_rewrites = rec_thms,
   549     case_name = case_name,
   550     case_rewrites = case_thms,
   551     induction = induct,
   552     exhaustion = exhaustion_thm,
   553     distinct = distinct_thm,
   554     inject = inject,
   555     nchotomy = nchotomy,
   556     case_cong = case_cong,
   557     weak_case_cong = weak_case_cong});
   558 
   559 
   560 (********************* axiomatic introduction of datatypes ********************)
   561 
   562 fun add_axiom label t atts thy =
   563   thy
   564   |> PureThy.add_axioms_i [((label, t), atts)];
   565 
   566 fun add_axioms label ts atts thy =
   567   thy
   568   |> PureThy.add_axiomss_i [((label, ts), atts)];
   569 
   570 fun add_and_get_axioms_atts label tnames ts attss =
   571   fold_map (fn (tname, (atts, t)) => fn thy =>
   572     thy
   573     |> Theory.add_path tname
   574     |> add_axiom label t atts
   575     ||> Theory.parent_path
   576     |-> (fn [ax] => pair ax)) (tnames ~~ (attss ~~ ts));
   577 
   578 fun add_and_get_axioms label tnames ts =
   579   add_and_get_axioms_atts label tnames ts (replicate (length tnames) []);
   580 
   581 fun add_and_get_axiomss label tnames tss =
   582   fold_map (fn (tname, ts) => fn thy =>
   583     thy
   584     |> Theory.add_path tname
   585     |> add_axioms label ts []
   586     ||> Theory.parent_path
   587     |-> (fn [ax] => pair ax)) (tnames ~~ tss);
   588 
   589 fun specify_consts args thy =
   590   let
   591     val specs = map (fn (c, T, mx) =>
   592       Const (Sign.full_name thy (Syntax.const_name c mx), T)) args;
   593   in
   594     thy
   595     |> Sign.add_consts_i args
   596     |> Theory.add_finals_i false specs
   597   end;
   598 
   599 fun add_datatype_axm flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   600     case_names_induct case_names_exhausts thy =
   601   let
   602     val descr' = flat descr;
   603     val recTs = get_rec_types descr' sorts;
   604     val used = map fst (fold Term.add_tfreesT recTs []);
   605     val newTs = Library.take (length (hd descr), recTs);
   606 
   607     val no_size = exists (fn (_, (_, _, constrs)) => exists (fn (_, cargs) => exists
   608       (fn dt => is_rec_type dt andalso not (null (fst (strip_dtyp dt))))
   609         cargs) constrs) descr';
   610 
   611     (**** declare new types and constants ****)
   612 
   613     val tyvars = map (fn (_, (_, Ts, _)) => map dest_DtTFree Ts) (hd descr);
   614 
   615     val constr_decls = map (fn (((_, (_, _, constrs)), T), constr_syntax') =>
   616       map (fn ((_, cargs), (cname, mx)) =>
   617         (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   618           (constrs ~~ constr_syntax')) ((hd descr) ~~ newTs ~~ constr_syntax);
   619 
   620     val (rec_result_Ts, reccomb_fn_Ts) = DatatypeProp.make_primrec_Ts descr sorts used;
   621 
   622     val big_reccomb_name = (space_implode "_" new_type_names) ^ "_rec";
   623     val reccomb_names = if length descr' = 1 then [big_reccomb_name] else
   624       (map ((curry (op ^) (big_reccomb_name ^ "_")) o string_of_int)
   625         (1 upto (length descr')));
   626 
   627     val size_names = DatatypeProp.indexify_names
   628       (map (fn T => name_of_typ T ^ "_size") (Library.drop (length (hd descr), recTs)));
   629 
   630     val freeT = TFree (Name.variant used "'t", HOLogic.typeS);
   631     val case_fn_Ts = map (fn (i, (_, _, constrs)) =>
   632       map (fn (_, cargs) =>
   633         let val Ts = map (typ_of_dtyp descr' sorts) cargs
   634         in Ts ---> freeT end) constrs) (hd descr);
   635 
   636     val case_names = map (fn s => (s ^ "_case")) new_type_names;
   637 
   638     fun instance_size_class tyco thy =
   639       let
   640         val size_sort = ["Nat.size"];
   641         val n = Sign.arity_number thy tyco;
   642       in
   643         thy
   644         |> AxClass.prove_arity (tyco, replicate n HOLogic.typeS, size_sort)
   645              (ClassPackage.intro_classes_tac [])
   646       end
   647 
   648     val thy2' = thy
   649 
   650       (** new types **)
   651       |> fold2 (fn (name, mx) => fn tvs => TypedefPackage.add_typedecls [(name, tvs, mx)])
   652            types_syntax tyvars
   653       |> fold (fn (_, (name, _, _)) => instance_size_class name) descr'
   654       |> add_path flat_names (space_implode "_" new_type_names)
   655 
   656       (** primrec combinators **)
   657 
   658       |> specify_consts (map (fn ((name, T), T') =>
   659            (name, reccomb_fn_Ts @ [T] ---> T', NoSyn)) (reccomb_names ~~ recTs ~~ rec_result_Ts))
   660 
   661       (** case combinators **)
   662 
   663       |> specify_consts (map (fn ((name, T), Ts) =>
   664            (name, Ts @ [T] ---> freeT, NoSyn)) (case_names ~~ newTs ~~ case_fn_Ts));
   665 
   666     val reccomb_names' = map (Sign.full_name thy2') reccomb_names;
   667     val case_names' = map (Sign.full_name thy2') case_names;
   668 
   669     val thy2 = thy2'
   670 
   671       (** size functions **)
   672 
   673       |> (if no_size then I else specify_consts (map (fn (s, T) =>
   674         (Sign.base_name s, T --> HOLogic.natT, NoSyn))
   675           (size_names ~~ Library.drop (length (hd descr), recTs))))
   676 
   677       (** constructors **)
   678 
   679       |> parent_path flat_names
   680       |> fold (fn ((((_, (_, _, constrs)), T), tname),
   681         constr_syntax') =>
   682           add_path flat_names tname #>
   683             specify_consts (map (fn ((_, cargs), (cname, mx)) =>
   684               (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   685                 (constrs ~~ constr_syntax')) #>
   686           parent_path flat_names)
   687             (hd descr ~~ newTs ~~ new_type_names ~~ constr_syntax);
   688 
   689     (**** introduction of axioms ****)
   690 
   691     val rec_axs = DatatypeProp.make_primrecs new_type_names descr sorts thy2;
   692     val size_axs = if no_size then [] else DatatypeProp.make_size descr sorts thy2;
   693 
   694     val ((([induct], [rec_thms]), inject), thy3) =
   695       thy2
   696       |> Theory.add_path (space_implode "_" new_type_names)
   697       |> add_axiom "induct" (DatatypeProp.make_ind descr sorts) [case_names_induct]
   698       ||>> add_axioms "recs" rec_axs []
   699       ||> (if no_size then I else add_axioms "size" size_axs [] #> snd)
   700       ||> Theory.parent_path
   701       ||>> add_and_get_axiomss "inject" new_type_names
   702             (DatatypeProp.make_injs descr sorts);
   703     val size_thms = if no_size then [] else get_thms thy3 (Name "size");
   704     val (distinct, thy4) = add_and_get_axiomss "distinct" new_type_names
   705       (DatatypeProp.make_distincts new_type_names descr sorts thy3) thy3;
   706 
   707     val exhaust_ts = DatatypeProp.make_casedists descr sorts;
   708     val (exhaustion, thy5) = add_and_get_axioms_atts "exhaust" new_type_names
   709       exhaust_ts (map single case_names_exhausts) thy4;
   710     val (case_thms, thy6) = add_and_get_axiomss "cases" new_type_names
   711       (DatatypeProp.make_cases new_type_names descr sorts thy5) thy5;
   712     val (split_ts, split_asm_ts) = ListPair.unzip
   713       (DatatypeProp.make_splits new_type_names descr sorts thy6);
   714     val (split, thy7) = add_and_get_axioms "split" new_type_names split_ts thy6;
   715     val (split_asm, thy8) = add_and_get_axioms "split_asm" new_type_names
   716       split_asm_ts thy7;
   717     val (nchotomys, thy9) = add_and_get_axioms "nchotomy" new_type_names
   718       (DatatypeProp.make_nchotomys descr sorts) thy8;
   719     val (case_congs, thy10) = add_and_get_axioms "case_cong" new_type_names
   720       (DatatypeProp.make_case_congs new_type_names descr sorts thy9) thy9;
   721     val (weak_case_congs, thy11) = add_and_get_axioms "weak_case_cong" new_type_names
   722       (DatatypeProp.make_weak_case_congs new_type_names descr sorts thy10) thy10;
   723 
   724     val dt_infos = map (make_dt_info descr' sorts induct reccomb_names' rec_thms)
   725       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names' ~~ case_thms ~~
   726         exhaustion ~~ replicate (length (hd descr)) QuickAndDirty ~~ inject ~~
   727           nchotomys ~~ case_congs ~~ weak_case_congs);
   728 
   729     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   730     val split_thms = split ~~ split_asm;
   731 
   732     val thy12 =
   733       thy11
   734       |> Theory.add_advanced_trfuns ([], [], make_case_tr' case_names' (hd descr), [])
   735       |> Theory.add_path (space_implode "_" new_type_names)
   736       |> add_rules simps case_thms size_thms rec_thms inject distinct
   737           weak_case_congs Simplifier.cong_add
   738       |> put_datatypes (fold Symtab.update dt_infos dt_info)
   739       |> add_cases_induct dt_infos induct
   740       |> Theory.parent_path
   741       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms)
   742       |> snd
   743       |> DatatypeRealizer.add_dt_realizers sorts (map snd dt_infos)
   744       |> DatatypeHooks.all (map fst dt_infos);
   745   in
   746     ({distinct = distinct,
   747       inject = inject,
   748       exhaustion = exhaustion,
   749       rec_thms = rec_thms,
   750       case_thms = case_thms,
   751       split_thms = split_thms,
   752       induction = induct,
   753       size = size_thms,
   754       simps = simps}, thy12)
   755   end;
   756 
   757 
   758 (******************* definitional introduction of datatypes *******************)
   759 
   760 fun add_datatype_def flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   761     case_names_induct case_names_exhausts thy =
   762   let
   763     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   764 
   765     val ((inject, distinct, dist_rewrites, simproc_dists, induct), thy2) = thy |>
   766       DatatypeRepProofs.representation_proofs flat_names dt_info new_type_names descr sorts
   767         types_syntax constr_syntax case_names_induct;
   768 
   769     val (casedist_thms, thy3) = DatatypeAbsProofs.prove_casedist_thms new_type_names descr
   770       sorts induct case_names_exhausts thy2;
   771     val ((reccomb_names, rec_thms), thy4) = DatatypeAbsProofs.prove_primrec_thms
   772       flat_names new_type_names descr sorts dt_info inject dist_rewrites
   773       (Simplifier.theory_context thy3 dist_ss) induct thy3;
   774     val ((case_thms, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   775       flat_names new_type_names descr sorts reccomb_names rec_thms thy4;
   776     val (split_thms, thy7) = DatatypeAbsProofs.prove_split_thms new_type_names
   777       descr sorts inject dist_rewrites casedist_thms case_thms thy6;
   778     val (nchotomys, thy8) = DatatypeAbsProofs.prove_nchotomys new_type_names
   779       descr sorts casedist_thms thy7;
   780     val (case_congs, thy9) = DatatypeAbsProofs.prove_case_congs new_type_names
   781       descr sorts nchotomys case_thms thy8;
   782     val (weak_case_congs, thy10) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   783       descr sorts thy9;
   784     val (size_thms, thy11) = DatatypeAbsProofs.prove_size_thms flat_names new_type_names
   785       descr sorts reccomb_names rec_thms thy10;
   786 
   787     val dt_infos = map (make_dt_info (flat descr) sorts induct reccomb_names rec_thms)
   788       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names ~~ case_thms ~~
   789         casedist_thms ~~ simproc_dists ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   790 
   791     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   792 
   793     val thy12 =
   794       thy11
   795       |> Theory.add_advanced_trfuns ([], [], make_case_tr' case_names (hd descr), [])
   796       |> Theory.add_path (space_implode "_" new_type_names)
   797       |> add_rules simps case_thms size_thms rec_thms inject distinct
   798           weak_case_congs (Simplifier.attrib (op addcongs))
   799       |> put_datatypes (fold Symtab.update dt_infos dt_info)
   800       |> add_cases_induct dt_infos induct
   801       |> Theory.parent_path
   802       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms) |> snd
   803       |> DatatypeRealizer.add_dt_realizers sorts (map snd dt_infos)
   804       |> DatatypeHooks.all (map fst dt_infos);
   805   in
   806     ({distinct = distinct,
   807       inject = inject,
   808       exhaustion = casedist_thms,
   809       rec_thms = rec_thms,
   810       case_thms = case_thms,
   811       split_thms = split_thms,
   812       induction = induct,
   813       size = size_thms,
   814       simps = simps}, thy12)
   815   end;
   816 
   817 
   818 (*********************** declare existing type as datatype *********************)
   819 
   820 fun gen_rep_datatype apply_theorems alt_names raw_distinct raw_inject raw_induction thy0 =
   821   let
   822     val (((distinct, inject), [induction]), thy1) =
   823       thy0
   824       |> fold_map apply_theorems raw_distinct
   825       ||>> fold_map apply_theorems raw_inject
   826       ||>> apply_theorems [raw_induction];
   827 
   828     val ((_, [induction']), _) =
   829       Variable.importT_thms [induction] (Variable.thm_context induction);
   830 
   831     fun err t = error ("Ill-formed predicate in induction rule: " ^
   832       Sign.string_of_term thy1 t);
   833 
   834     fun get_typ (t as _ $ Var (_, Type (tname, Ts))) =
   835           ((tname, map dest_TFree Ts) handle TERM _ => err t)
   836       | get_typ t = err t;
   837 
   838     val dtnames = map get_typ (HOLogic.dest_conj (HOLogic.dest_Trueprop (Thm.concl_of induction')));
   839     val new_type_names = getOpt (alt_names, map fst dtnames);
   840 
   841     fun get_constr t = (case Logic.strip_assums_concl t of
   842         _ $ (_ $ t') => (case head_of t' of
   843             Const (cname, cT) => (case strip_type cT of
   844                 (Ts, Type (tname, _)) => (tname, (cname, map (dtyp_of_typ dtnames) Ts))
   845               | _ => err t)
   846           | _ => err t)
   847       | _ => err t);
   848 
   849     fun make_dt_spec [] _ _ = []
   850       | make_dt_spec ((tname, tvs)::dtnames') i constrs =
   851           let val (constrs', constrs'') = take_prefix (equal tname o fst) constrs
   852           in (i, (tname, map DtTFree tvs, map snd constrs'))::
   853             (make_dt_spec dtnames' (i + 1) constrs'')
   854           end;
   855 
   856     val descr = make_dt_spec dtnames 0 (map get_constr (prems_of induction'));
   857     val sorts = add_term_tfrees (concl_of induction', []);
   858     val dt_info = get_datatypes thy1;
   859 
   860     val (case_names_induct, case_names_exhausts) =
   861       (mk_case_names_induct descr, mk_case_names_exhausts descr (map #1 dtnames));
   862 
   863     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   864 
   865     val (casedist_thms, thy2) = thy1 |>
   866       DatatypeAbsProofs.prove_casedist_thms new_type_names [descr] sorts induction
   867         case_names_exhausts;
   868     val ((reccomb_names, rec_thms), thy3) = DatatypeAbsProofs.prove_primrec_thms
   869       false new_type_names [descr] sorts dt_info inject distinct
   870       (Simplifier.theory_context thy2 dist_ss) induction thy2;
   871     val ((case_thms, case_names), thy4) = DatatypeAbsProofs.prove_case_thms false
   872       new_type_names [descr] sorts reccomb_names rec_thms thy3;
   873     val (split_thms, thy5) = DatatypeAbsProofs.prove_split_thms
   874       new_type_names [descr] sorts inject distinct casedist_thms case_thms thy4;
   875     val (nchotomys, thy6) = DatatypeAbsProofs.prove_nchotomys new_type_names
   876       [descr] sorts casedist_thms thy5;
   877     val (case_congs, thy7) = DatatypeAbsProofs.prove_case_congs new_type_names
   878       [descr] sorts nchotomys case_thms thy6;
   879     val (weak_case_congs, thy8) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   880       [descr] sorts thy7;
   881     val (size_thms, thy9) =
   882       DatatypeAbsProofs.prove_size_thms false new_type_names
   883         [descr] sorts reccomb_names rec_thms thy8;
   884 
   885     val ((_, [induction']), thy10) =
   886       thy9
   887       |> store_thmss "inject" new_type_names inject
   888       ||>> store_thmss "distinct" new_type_names distinct
   889       ||> Theory.add_path (space_implode "_" new_type_names)
   890       ||>> PureThy.add_thms [(("induct", induction), [case_names_induct])];
   891 
   892     val dt_infos = map (make_dt_info descr sorts induction' reccomb_names rec_thms)
   893       ((0 upto length descr - 1) ~~ descr ~~ case_names ~~ case_thms ~~ casedist_thms ~~
   894         map FewConstrs distinct ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   895 
   896     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   897 
   898     val thy11 =
   899       thy10
   900       |> Theory.add_advanced_trfuns ([], [], make_case_tr' case_names descr, [])
   901       |> add_rules simps case_thms size_thms rec_thms inject distinct
   902            weak_case_congs (Simplifier.attrib (op addcongs))
   903       |> put_datatypes (fold Symtab.update dt_infos dt_info)
   904       |> add_cases_induct dt_infos induction'
   905       |> Theory.parent_path
   906       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms)
   907       |> snd
   908       |> DatatypeRealizer.add_dt_realizers sorts (map snd dt_infos)
   909       |> DatatypeHooks.all (map fst dt_infos);
   910   in
   911     ({distinct = distinct,
   912       inject = inject,
   913       exhaustion = casedist_thms,
   914       rec_thms = rec_thms,
   915       case_thms = case_thms,
   916       split_thms = split_thms,
   917       induction = induction',
   918       size = size_thms,
   919       simps = simps}, thy11)
   920   end;
   921 
   922 val rep_datatype = gen_rep_datatype IsarCmd.apply_theorems;
   923 val rep_datatype_i = gen_rep_datatype IsarCmd.apply_theorems_i;
   924 
   925 
   926 
   927 (******************************** add datatype ********************************)
   928 
   929 fun gen_add_datatype prep_typ err flat_names new_type_names dts thy =
   930   let
   931     val _ = Theory.requires thy "Datatype" "datatype definitions";
   932 
   933     (* this theory is used just for parsing *)
   934 
   935     val tmp_thy = thy |>
   936       Theory.copy |>
   937       Theory.add_types (map (fn (tvs, tname, mx, _) =>
   938         (tname, length tvs, mx)) dts);
   939 
   940     val (tyvars, _, _, _)::_ = dts;
   941     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   942       let val full_tname = Sign.full_name tmp_thy (Syntax.type_name tname mx)
   943       in (case duplicates (op =) tvs of
   944             [] => if eq_set (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   945                   else error ("Mutually recursive datatypes must have same type parameters")
   946           | dups => error ("Duplicate parameter(s) for datatype " ^ full_tname ^
   947               " : " ^ commas dups))
   948       end) dts);
   949 
   950     val _ = (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   951       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   952 
   953     fun prep_dt_spec (tvs, tname, mx, constrs) (dts', constr_syntax, sorts, i) =
   954       let
   955         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   956           let
   957             val (cargs', sorts'') = Library.foldl (prep_typ tmp_thy) (([], sorts'), cargs);
   958             val _ = (case fold (curry add_typ_tfree_names) cargs' [] \\ tvs of
   959                 [] => ()
   960               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   961           in (constrs @ [((if flat_names then Sign.full_name tmp_thy else
   962                 Sign.full_name_path tmp_thy tname) (Syntax.const_name cname mx'),
   963                    map (dtyp_of_typ new_dts) cargs')],
   964               constr_syntax' @ [(cname, mx')], sorts'')
   965           end handle ERROR msg =>
   966             cat_error msg ("The error above occured in constructor " ^ cname ^
   967               " of datatype " ^ tname);
   968 
   969         val (constrs', constr_syntax', sorts') =
   970           fold prep_constr constrs ([], [], sorts)
   971 
   972       in
   973         case duplicates (op =) (map fst constrs') of
   974            [] =>
   975              (dts' @ [(i, (Sign.full_name tmp_thy (Syntax.type_name tname mx),
   976                 map DtTFree tvs, constrs'))],
   977               constr_syntax @ [constr_syntax'], sorts', i + 1)
   978          | dups => error ("Duplicate constructors " ^ commas dups ^
   979              " in datatype " ^ tname)
   980       end;
   981 
   982     val (dts', constr_syntax, sorts', i) = fold prep_dt_spec dts ([], [], [], 0);
   983     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (tyvars \\ map fst sorts'));
   984     val dt_info = get_datatypes thy;
   985     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   986     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   987       if err then error ("Nonemptiness check failed for datatype " ^ s)
   988       else raise exn;
   989 
   990     val descr' = flat descr;
   991     val case_names_induct = mk_case_names_induct descr';
   992     val case_names_exhausts = mk_case_names_exhausts descr' (map #1 new_dts);
   993   in
   994     (if (!quick_and_dirty) then add_datatype_axm else add_datatype_def)
   995       flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   996       case_names_induct case_names_exhausts thy
   997   end;
   998 
   999 val add_datatype_i = gen_add_datatype cert_typ;
  1000 val add_datatype = gen_add_datatype read_typ true;
  1001 
  1002 
  1003 
  1004 (** package setup **)
  1005 
  1006 (* setup theory *)
  1007 
  1008 val setup =
  1009   DatatypesData.init #> Method.add_methods tactic_emulations #> simproc_setup #> trfun_setup;
  1010 
  1011 
  1012 (* outer syntax *)
  1013 
  1014 local structure P = OuterParse and K = OuterKeyword in
  1015 
  1016 val datatype_decl =
  1017   Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.name -- P.opt_infix --
  1018     (P.$$$ "=" |-- P.enum1 "|" (P.name -- Scan.repeat P.typ -- P.opt_mixfix));
  1019 
  1020 fun mk_datatype args =
  1021   let
  1022     val names = map (fn ((((NONE, _), t), _), _) => t | ((((SOME t, _), _), _), _) => t) args;
  1023     val specs = map (fn ((((_, vs), t), mx), cons) =>
  1024       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
  1025   in snd o add_datatype false names specs end;
  1026 
  1027 val datatypeP =
  1028   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
  1029     (P.and_list1 datatype_decl >> (Toplevel.theory o mk_datatype));
  1030 
  1031 
  1032 val rep_datatype_decl =
  1033   Scan.option (Scan.repeat1 P.name) --
  1034     Scan.optional (P.$$$ "distinct" |-- P.!!! (P.and_list1 SpecParse.xthms1)) [[]] --
  1035     Scan.optional (P.$$$ "inject" |-- P.!!! (P.and_list1 SpecParse.xthms1)) [[]] --
  1036     (P.$$$ "induction" |-- P.!!! SpecParse.xthm);
  1037 
  1038 fun mk_rep_datatype (((opt_ts, dss), iss), ind) = #2 o rep_datatype opt_ts dss iss ind;
  1039 
  1040 val rep_datatypeP =
  1041   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_decl
  1042     (rep_datatype_decl >> (Toplevel.theory o mk_rep_datatype));
  1043 
  1044 
  1045 val _ = OuterSyntax.add_keywords ["distinct", "inject", "induction"];
  1046 val _ = OuterSyntax.add_parsers [datatypeP, rep_datatypeP];
  1047 
  1048 end;
  1049 
  1050 
  1051 end;
  1052 
  1053 structure BasicDatatypePackage: BASIC_DATATYPE_PACKAGE = DatatypePackage;
  1054 open BasicDatatypePackage;
  1055