src/HOL/SEQ.thy
author huffman
Mon May 03 20:42:58 2010 -0700 (2010-05-03)
changeset 36657 f376af79f6b7
parent 36625 2ba6525f9905
child 36660 1cc4ab4b7ff7
permissions -rw-r--r--
remove unneeded constant Zseq
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits
    14 begin
    15 
    16 definition
    17   LIMSEQ :: "[nat \<Rightarrow> 'a::metric_space, 'a] \<Rightarrow> bool"
    18     ("((_)/ ----> (_))" [60, 60] 60) where
    19     --{*Standard definition of convergence of sequence*}
    20   [code del]: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
    21 
    22 definition
    23   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    24     --{*Standard definition of limit using choice operator*}
    25   "lim X = (THE L. X ----> L)"
    26 
    27 definition
    28   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    29     --{*Standard definition of convergence*}
    30   "convergent X = (\<exists>L. X ----> L)"
    31 
    32 definition
    33   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    34     --{*Standard definition for bounded sequence*}
    35   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    36 
    37 definition
    38   monoseq :: "(nat=>real)=>bool" where
    39     --{*Definition of monotonicity. 
    40         The use of disjunction here complicates proofs considerably. 
    41         One alternative is to add a Boolean argument to indicate the direction. 
    42         Another is to develop the notions of increasing and decreasing first.*}
    43   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    44 
    45 definition
    46   incseq :: "(nat=>real)=>bool" where
    47     --{*Increasing sequence*}
    48   [code del]: "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    49 
    50 definition
    51   decseq :: "(nat=>real)=>bool" where
    52     --{*Increasing sequence*}
    53   [code del]: "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    54 
    55 definition
    56   subseq :: "(nat => nat) => bool" where
    57     --{*Definition of subsequence*}
    58   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    59 
    60 definition
    61   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    62     --{*Standard definition of the Cauchy condition*}
    63   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    64 
    65 
    66 subsection {* Bounded Sequences *}
    67 
    68 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    69 unfolding Bseq_def
    70 proof (intro exI conjI allI)
    71   show "0 < max K 1" by simp
    72 next
    73   fix n::nat
    74   have "norm (X n) \<le> K" by (rule K)
    75   thus "norm (X n) \<le> max K 1" by simp
    76 qed
    77 
    78 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    79 unfolding Bseq_def by auto
    80 
    81 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    82 proof (rule BseqI')
    83   let ?A = "norm ` X ` {..N}"
    84   have 1: "finite ?A" by simp
    85   fix n::nat
    86   show "norm (X n) \<le> max K (Max ?A)"
    87   proof (cases rule: linorder_le_cases)
    88     assume "n \<ge> N"
    89     hence "norm (X n) \<le> K" using K by simp
    90     thus "norm (X n) \<le> max K (Max ?A)" by simp
    91   next
    92     assume "n \<le> N"
    93     hence "norm (X n) \<in> ?A" by simp
    94     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
    95     thus "norm (X n) \<le> max K (Max ?A)" by simp
    96   qed
    97 qed
    98 
    99 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   100 unfolding Bseq_def by auto
   101 
   102 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   103 apply (erule BseqE)
   104 apply (rule_tac N="k" and K="K" in BseqI2')
   105 apply clarify
   106 apply (drule_tac x="n - k" in spec, simp)
   107 done
   108 
   109 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   110 unfolding Bfun_def eventually_sequentially
   111 apply (rule iffI)
   112 apply (simp add: Bseq_def)
   113 apply (auto intro: BseqI2')
   114 done
   115 
   116 
   117 subsection {* Limits of Sequences *}
   118 
   119 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   120   by simp
   121 
   122 lemma LIMSEQ_conv_tendsto: "(X ----> L) \<longleftrightarrow> (X ---> L) sequentially"
   123 unfolding LIMSEQ_def tendsto_iff eventually_sequentially ..
   124 
   125 lemma LIMSEQ_iff:
   126   fixes L :: "'a::real_normed_vector"
   127   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   128 unfolding LIMSEQ_def dist_norm ..
   129 
   130 lemma LIMSEQ_iff_nz: "X ----> L = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
   131   by (auto simp add: LIMSEQ_def) (metis Suc_leD zero_less_Suc)  
   132 
   133 lemma LIMSEQ_Zfun_iff: "((\<lambda>n. X n) ----> L) = Zfun (\<lambda>n. X n - L) sequentially"
   134 by (simp only: LIMSEQ_iff Zfun_def eventually_sequentially)
   135 
   136 lemma metric_LIMSEQ_I:
   137   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   138 by (simp add: LIMSEQ_def)
   139 
   140 lemma metric_LIMSEQ_D:
   141   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   142 by (simp add: LIMSEQ_def)
   143 
   144 lemma LIMSEQ_I:
   145   fixes L :: "'a::real_normed_vector"
   146   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   147 by (simp add: LIMSEQ_iff)
   148 
   149 lemma LIMSEQ_D:
   150   fixes L :: "'a::real_normed_vector"
   151   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   152 by (simp add: LIMSEQ_iff)
   153 
   154 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   155 by (simp add: LIMSEQ_def)
   156 
   157 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   158 apply (safe intro!: LIMSEQ_const)
   159 apply (rule ccontr)
   160 apply (drule_tac r="dist k l" in metric_LIMSEQ_D)
   161 apply (simp add: zero_less_dist_iff)
   162 apply auto
   163 done
   164 
   165 lemma LIMSEQ_norm:
   166   fixes a :: "'a::real_normed_vector"
   167   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   168 unfolding LIMSEQ_conv_tendsto by (rule tendsto_norm)
   169 
   170 lemma LIMSEQ_ignore_initial_segment:
   171   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   172 apply (rule metric_LIMSEQ_I)
   173 apply (drule (1) metric_LIMSEQ_D)
   174 apply (erule exE, rename_tac N)
   175 apply (rule_tac x=N in exI)
   176 apply simp
   177 done
   178 
   179 lemma LIMSEQ_offset:
   180   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   181 apply (rule metric_LIMSEQ_I)
   182 apply (drule (1) metric_LIMSEQ_D)
   183 apply (erule exE, rename_tac N)
   184 apply (rule_tac x="N + k" in exI)
   185 apply clarify
   186 apply (drule_tac x="n - k" in spec)
   187 apply (simp add: le_diff_conv2)
   188 done
   189 
   190 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   191 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   192 
   193 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   194 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   195 
   196 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   197 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   198 
   199 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   200   unfolding LIMSEQ_def
   201   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   202 
   203 lemma LIMSEQ_add:
   204   fixes a b :: "'a::real_normed_vector"
   205   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   206 unfolding LIMSEQ_conv_tendsto by (rule tendsto_add)
   207 
   208 lemma LIMSEQ_minus:
   209   fixes a :: "'a::real_normed_vector"
   210   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   211 unfolding LIMSEQ_conv_tendsto by (rule tendsto_minus)
   212 
   213 lemma LIMSEQ_minus_cancel:
   214   fixes a :: "'a::real_normed_vector"
   215   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   216 by (drule LIMSEQ_minus, simp)
   217 
   218 lemma LIMSEQ_diff:
   219   fixes a b :: "'a::real_normed_vector"
   220   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   221 unfolding LIMSEQ_conv_tendsto by (rule tendsto_diff)
   222 
   223 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   224 apply (rule ccontr)
   225 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   226 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   227 apply (clarify, rename_tac M N)
   228 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   229 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   230 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   231 apply (subst dist_commute, rule dist_triangle)
   232 done
   233 
   234 lemma (in bounded_linear) LIMSEQ:
   235   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   236 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   237 
   238 lemma (in bounded_bilinear) LIMSEQ:
   239   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   240 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   241 
   242 lemma LIMSEQ_mult:
   243   fixes a b :: "'a::real_normed_algebra"
   244   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   245 by (rule mult.LIMSEQ)
   246 
   247 lemma increasing_LIMSEQ:
   248   fixes f :: "nat \<Rightarrow> real"
   249   assumes inc: "!!n. f n \<le> f (Suc n)"
   250       and bdd: "!!n. f n \<le> l"
   251       and en: "!!e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   252   shows "f ----> l"
   253 proof (auto simp add: LIMSEQ_def)
   254   fix e :: real
   255   assume e: "0 < e"
   256   then obtain N where "l \<le> f N + e/2"
   257     by (metis half_gt_zero e en that)
   258   hence N: "l < f N + e" using e
   259     by simp
   260   { fix k
   261     have [simp]: "!!n. \<bar>f n - l\<bar> = l - f n"
   262       by (simp add: bdd) 
   263     have "\<bar>f (N+k) - l\<bar> < e"
   264     proof (induct k)
   265       case 0 show ?case using N
   266         by simp   
   267     next
   268       case (Suc k) thus ?case using N inc [of "N+k"]
   269         by simp
   270     qed 
   271   } note 1 = this
   272   { fix n
   273     have "N \<le> n \<Longrightarrow> \<bar>f n - l\<bar> < e" using 1 [of "n-N"]
   274       by simp 
   275   } note [intro] = this
   276   show " \<exists>no. \<forall>n\<ge>no. dist (f n) l < e"
   277     by (auto simp add: dist_real_def) 
   278   qed
   279 
   280 lemma Bseq_inverse_lemma:
   281   fixes x :: "'a::real_normed_div_algebra"
   282   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   283 apply (subst nonzero_norm_inverse, clarsimp)
   284 apply (erule (1) le_imp_inverse_le)
   285 done
   286 
   287 lemma Bseq_inverse:
   288   fixes a :: "'a::real_normed_div_algebra"
   289   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   290 unfolding LIMSEQ_conv_tendsto Bseq_conv_Bfun
   291 by (rule Bfun_inverse)
   292 
   293 lemma LIMSEQ_inverse:
   294   fixes a :: "'a::real_normed_div_algebra"
   295   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   296 unfolding LIMSEQ_conv_tendsto
   297 by (rule tendsto_inverse)
   298 
   299 lemma LIMSEQ_divide:
   300   fixes a b :: "'a::real_normed_field"
   301   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   302 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   303 
   304 lemma LIMSEQ_pow:
   305   fixes a :: "'a::{power, real_normed_algebra}"
   306   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   307 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   308 
   309 lemma LIMSEQ_setsum:
   310   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   311   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   312   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   313 using n unfolding LIMSEQ_conv_tendsto by (rule tendsto_setsum)
   314 
   315 lemma LIMSEQ_setprod:
   316   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   317   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   318   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   319 proof (cases "finite S")
   320   case True
   321   thus ?thesis using n
   322   proof (induct)
   323     case empty
   324     show ?case
   325       by (simp add: LIMSEQ_const)
   326   next
   327     case insert
   328     thus ?case
   329       by (simp add: LIMSEQ_mult)
   330   qed
   331 next
   332   case False
   333   thus ?thesis
   334     by (simp add: setprod_def LIMSEQ_const)
   335 qed
   336 
   337 lemma LIMSEQ_add_const:
   338   fixes a :: "'a::real_normed_vector"
   339   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   340 by (simp add: LIMSEQ_add LIMSEQ_const)
   341 
   342 (* FIXME: delete *)
   343 lemma LIMSEQ_add_minus:
   344   fixes a b :: "'a::real_normed_vector"
   345   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   346 by (simp only: LIMSEQ_add LIMSEQ_minus)
   347 
   348 lemma LIMSEQ_diff_const:
   349   fixes a b :: "'a::real_normed_vector"
   350   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   351 by (simp add: LIMSEQ_diff LIMSEQ_const)
   352 
   353 lemma LIMSEQ_diff_approach_zero:
   354   fixes L :: "'a::real_normed_vector"
   355   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   356 by (drule (1) LIMSEQ_add, simp)
   357 
   358 lemma LIMSEQ_diff_approach_zero2:
   359   fixes L :: "'a::real_normed_vector"
   360   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
   361 by (drule (1) LIMSEQ_diff, simp)
   362 
   363 text{*A sequence tends to zero iff its abs does*}
   364 lemma LIMSEQ_norm_zero:
   365   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   366   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   367 by (simp add: LIMSEQ_iff)
   368 
   369 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   370 by (simp add: LIMSEQ_iff)
   371 
   372 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   373 by (drule LIMSEQ_norm, simp)
   374 
   375 text{*An unbounded sequence's inverse tends to 0*}
   376 
   377 lemma LIMSEQ_inverse_zero:
   378   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   379 apply (rule LIMSEQ_I)
   380 apply (drule_tac x="inverse r" in spec, safe)
   381 apply (rule_tac x="N" in exI, safe)
   382 apply (drule_tac x="n" in spec, safe)
   383 apply (frule positive_imp_inverse_positive)
   384 apply (frule (1) less_imp_inverse_less)
   385 apply (subgoal_tac "0 < X n", simp)
   386 apply (erule (1) order_less_trans)
   387 done
   388 
   389 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   390 
   391 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   392 apply (rule LIMSEQ_inverse_zero, safe)
   393 apply (cut_tac x = r in reals_Archimedean2)
   394 apply (safe, rule_tac x = n in exI)
   395 apply (auto simp add: real_of_nat_Suc)
   396 done
   397 
   398 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   399 infinity is now easily proved*}
   400 
   401 lemma LIMSEQ_inverse_real_of_nat_add:
   402      "(%n. r + inverse(real(Suc n))) ----> r"
   403 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   404 
   405 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   406      "(%n. r + -inverse(real(Suc n))) ----> r"
   407 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   408 
   409 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   410      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   411 by (cut_tac b=1 in
   412         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   413 
   414 lemma LIMSEQ_le_const:
   415   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   416 apply (rule ccontr, simp only: linorder_not_le)
   417 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   418 apply clarsimp
   419 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   420 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   421 apply simp
   422 done
   423 
   424 lemma LIMSEQ_le_const2:
   425   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   426 apply (subgoal_tac "- a \<le> - x", simp)
   427 apply (rule LIMSEQ_le_const)
   428 apply (erule LIMSEQ_minus)
   429 apply simp
   430 done
   431 
   432 lemma LIMSEQ_le:
   433   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   434 apply (subgoal_tac "0 \<le> y - x", simp)
   435 apply (rule LIMSEQ_le_const)
   436 apply (erule (1) LIMSEQ_diff)
   437 apply (simp add: le_diff_eq)
   438 done
   439 
   440 
   441 subsection {* Convergence *}
   442 
   443 lemma limI: "X ----> L ==> lim X = L"
   444 apply (simp add: lim_def)
   445 apply (blast intro: LIMSEQ_unique)
   446 done
   447 
   448 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   449 by (simp add: convergent_def)
   450 
   451 lemma convergentI: "(X ----> L) ==> convergent X"
   452 by (auto simp add: convergent_def)
   453 
   454 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   455 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   456 
   457 lemma convergent_const: "convergent (\<lambda>n. c)"
   458 by (rule convergentI, rule LIMSEQ_const)
   459 
   460 lemma convergent_add:
   461   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
   462   assumes "convergent (\<lambda>n. X n)"
   463   assumes "convergent (\<lambda>n. Y n)"
   464   shows "convergent (\<lambda>n. X n + Y n)"
   465 using assms unfolding convergent_def by (fast intro: LIMSEQ_add)
   466 
   467 lemma convergent_setsum:
   468   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
   469   assumes "finite A" and "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
   470   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
   471 using assms
   472 by (induct A set: finite, simp_all add: convergent_const convergent_add)
   473 
   474 lemma (in bounded_linear) convergent:
   475   assumes "convergent (\<lambda>n. X n)"
   476   shows "convergent (\<lambda>n. f (X n))"
   477 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   478 
   479 lemma (in bounded_bilinear) convergent:
   480   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
   481   shows "convergent (\<lambda>n. X n ** Y n)"
   482 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   483 
   484 lemma convergent_minus_iff:
   485   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   486   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   487 apply (simp add: convergent_def)
   488 apply (auto dest: LIMSEQ_minus)
   489 apply (drule LIMSEQ_minus, auto)
   490 done
   491 
   492 lemma lim_le:
   493   fixes x :: real
   494   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   495   shows "lim f \<le> x"
   496 proof (rule classical)
   497   assume "\<not> lim f \<le> x"
   498   hence 0: "0 < lim f - x" by arith
   499   have 1: "f----> lim f"
   500     by (metis convergent_LIMSEQ_iff f) 
   501   thus ?thesis
   502     proof (simp add: LIMSEQ_iff)
   503       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   504       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   505         by (metis 0)
   506       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   507         by blast
   508       thus "lim f \<le> x"
   509         by (metis add_cancel_end add_minus_cancel diff_def linorder_linear 
   510                   linorder_not_le minus_diff_eq abs_diff_less_iff fn_le) 
   511     qed
   512 qed
   513 
   514 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   515 
   516 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   517   unfolding Ex1_def
   518   apply (rule_tac x="nat_rec e f" in exI)
   519   apply (rule conjI)+
   520 apply (rule def_nat_rec_0, simp)
   521 apply (rule allI, rule def_nat_rec_Suc, simp)
   522 apply (rule allI, rule impI, rule ext)
   523 apply (erule conjE)
   524 apply (induct_tac x)
   525 apply simp
   526 apply (erule_tac x="n" in allE)
   527 apply (simp)
   528 done
   529 
   530 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   531 
   532 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   533 apply (simp add: subseq_def)
   534 apply (auto dest!: less_imp_Suc_add)
   535 apply (induct_tac k)
   536 apply (auto intro: less_trans)
   537 done
   538 
   539 lemma monoseq_Suc:
   540    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   541                  | (\<forall>n. X (Suc n) \<le> X n))"
   542 apply (simp add: monoseq_def)
   543 apply (auto dest!: le_imp_less_or_eq)
   544 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   545 apply (induct_tac "ka")
   546 apply (auto intro: order_trans)
   547 apply (erule contrapos_np)
   548 apply (induct_tac "k")
   549 apply (auto intro: order_trans)
   550 done
   551 
   552 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   553 by (simp add: monoseq_def)
   554 
   555 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   556 by (simp add: monoseq_def)
   557 
   558 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   559 by (simp add: monoseq_Suc)
   560 
   561 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   562 by (simp add: monoseq_Suc)
   563 
   564 lemma monoseq_minus: assumes "monoseq a"
   565   shows "monoseq (\<lambda> n. - a n)"
   566 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   567   case True
   568   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   569   thus ?thesis by (rule monoI2)
   570 next
   571   case False
   572   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   573   thus ?thesis by (rule monoI1)
   574 qed
   575 
   576 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   577   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   578          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   579 proof -
   580   { fix x n fix a :: "nat \<Rightarrow> real"
   581     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   582     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   583     have "a n \<le> x"
   584     proof (rule ccontr)
   585       assume "\<not> a n \<le> x" hence "x < a n" by auto
   586       hence "0 < a n - x" by auto
   587       from `a ----> x`[THEN LIMSEQ_D, OF this]
   588       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   589       hence "norm (a (max no n) - x) < a n - x" by auto
   590       moreover
   591       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   592       hence "x < a (max no n)" by auto
   593       ultimately
   594       have "a (max no n) < a n" by auto
   595       with monotone[where m=n and n="max no n"]
   596       show False by (auto simp:max_def split:split_if_asm)
   597     qed
   598   } note top_down = this
   599   { fix x n m fix a :: "nat \<Rightarrow> real"
   600     assume "a ----> x" and "monoseq a" and "a m < x"
   601     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   602     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   603       case True with top_down and `a ----> x` show ?thesis by auto
   604     next
   605       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   606       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   607       hence False using `a m < x` by auto
   608       thus ?thesis ..
   609     qed
   610   } note when_decided = this
   611 
   612   show ?thesis
   613   proof (cases "\<exists> m. a m \<noteq> x")
   614     case True then obtain m where "a m \<noteq> x" by auto
   615     show ?thesis
   616     proof (cases "a m < x")
   617       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   618       show ?thesis by blast
   619     next
   620       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   621       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   622       show ?thesis by auto
   623     qed
   624   qed auto
   625 qed
   626 
   627 text{* for any sequence, there is a mootonic subsequence *}
   628 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   629 proof-
   630   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   631     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   632     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   633     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   634     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   635       using H apply - 
   636       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   637       unfolding order_le_less by blast 
   638     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   639     {fix n
   640       have "?P (f (Suc n)) (f n)" 
   641         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   642         using H apply - 
   643       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   644       unfolding order_le_less by blast 
   645     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   646   note fSuc = this
   647     {fix p q assume pq: "p \<ge> f q"
   648       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   649         by (cases q, simp_all) }
   650     note pqth = this
   651     {fix q
   652       have "f (Suc q) > f q" apply (induct q) 
   653         using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   654     note fss = this
   655     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   656     {fix a b 
   657       have "f a \<le> f (a + b)"
   658       proof(induct b)
   659         case 0 thus ?case by simp
   660       next
   661         case (Suc b)
   662         from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   663       qed}
   664     note fmon0 = this
   665     have "monoseq (\<lambda>n. s (f n))" 
   666     proof-
   667       {fix n
   668         have "s (f n) \<ge> s (f (Suc n))" 
   669         proof(cases n)
   670           case 0
   671           assume n0: "n = 0"
   672           from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   673           from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   674         next
   675           case (Suc m)
   676           assume m: "n = Suc m"
   677           from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   678           from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   679         qed}
   680       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   681     qed
   682     with th1 have ?thesis by blast}
   683   moreover
   684   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   685     {fix p assume p: "p \<ge> Suc N" 
   686       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   687       have "m \<noteq> p" using m(2) by auto 
   688       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   689     note th0 = this
   690     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   691     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   692     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   693       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   694     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   695       using N apply - 
   696       apply (erule allE[where x="Suc N"], clarsimp)
   697       apply (rule_tac x="m" in exI)
   698       apply auto
   699       apply (subgoal_tac "Suc N \<noteq> m")
   700       apply simp
   701       apply (rule ccontr, simp)
   702       done
   703     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   704     {fix n
   705       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   706         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   707       proof (induct n)
   708         case 0 thus ?case
   709           using f0 N apply auto 
   710           apply (erule allE[where x="f 0"], clarsimp) 
   711           apply (rule_tac x="m" in exI, simp)
   712           by (subgoal_tac "f 0 \<noteq> m", auto)
   713       next
   714         case (Suc n)
   715         from Suc.hyps have Nfn: "N < f n" by blast
   716         from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   717         with Nfn have mN: "m > N" by arith
   718         note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   719         
   720         from key have th0: "f (Suc n) > N" by simp
   721         from N[rule_format, OF th0]
   722         obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   723         have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   724         hence "m' > f (Suc n)" using m'(1) by simp
   725         with key m'(2) show ?case by auto
   726       qed}
   727     note fSuc = this
   728     {fix n
   729       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   730       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   731     note thf = this
   732     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   733     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   734       apply -
   735       apply (rule disjI1)
   736       apply auto
   737       apply (rule order_less_imp_le)
   738       apply blast
   739       done
   740     then have ?thesis  using sqf by blast}
   741   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   742 qed
   743 
   744 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   745 proof(induct n)
   746   case 0 thus ?case by simp
   747 next
   748   case (Suc n)
   749   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   750   have "n < f (Suc n)" by arith 
   751   thus ?case by arith
   752 qed
   753 
   754 lemma LIMSEQ_subseq_LIMSEQ:
   755   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   756 apply (auto simp add: LIMSEQ_def) 
   757 apply (drule_tac x=r in spec, clarify)  
   758 apply (rule_tac x=no in exI, clarify) 
   759 apply (blast intro: seq_suble le_trans dest!: spec) 
   760 done
   761 
   762 subsection {* Bounded Monotonic Sequences *}
   763 
   764 
   765 text{*Bounded Sequence*}
   766 
   767 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   768 by (simp add: Bseq_def)
   769 
   770 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   771 by (auto simp add: Bseq_def)
   772 
   773 lemma lemma_NBseq_def:
   774      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   775       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   776 proof auto
   777   fix K :: real
   778   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   779   then have "K \<le> real (Suc n)" by auto
   780   assume "\<forall>m. norm (X m) \<le> K"
   781   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   782   proof
   783     fix m :: 'a
   784     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   785     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   786   qed
   787   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   788 next
   789   fix N :: nat
   790   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   791   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   792   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   793 qed
   794 
   795 
   796 text{* alternative definition for Bseq *}
   797 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   798 apply (simp add: Bseq_def)
   799 apply (simp (no_asm) add: lemma_NBseq_def)
   800 done
   801 
   802 lemma lemma_NBseq_def2:
   803      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   804 apply (subst lemma_NBseq_def, auto)
   805 apply (rule_tac x = "Suc N" in exI)
   806 apply (rule_tac [2] x = N in exI)
   807 apply (auto simp add: real_of_nat_Suc)
   808  prefer 2 apply (blast intro: order_less_imp_le)
   809 apply (drule_tac x = n in spec, simp)
   810 done
   811 
   812 (* yet another definition for Bseq *)
   813 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   814 by (simp add: Bseq_def lemma_NBseq_def2)
   815 
   816 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   817 
   818 lemma Bseq_isUb:
   819   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   820 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   821 
   822 
   823 text{* Use completeness of reals (supremum property)
   824    to show that any bounded sequence has a least upper bound*}
   825 
   826 lemma Bseq_isLub:
   827   "!!(X::nat=>real). Bseq X ==>
   828    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   829 by (blast intro: reals_complete Bseq_isUb)
   830 
   831 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   832 
   833 lemma lemma_converg1:
   834      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   835                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   836                |] ==> \<forall>n \<ge> ma. X n = X ma"
   837 apply safe
   838 apply (drule_tac y = "X n" in isLubD2)
   839 apply (blast dest: order_antisym)+
   840 done
   841 
   842 text{* The best of both worlds: Easier to prove this result as a standard
   843    theorem and then use equivalence to "transfer" it into the
   844    equivalent nonstandard form if needed!*}
   845 
   846 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   847 apply (simp add: LIMSEQ_def)
   848 apply (rule_tac x = "X m" in exI, safe)
   849 apply (rule_tac x = m in exI, safe)
   850 apply (drule spec, erule impE, auto)
   851 done
   852 
   853 lemma lemma_converg2:
   854    "!!(X::nat=>real).
   855     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   856 apply safe
   857 apply (drule_tac y = "X m" in isLubD2)
   858 apply (auto dest!: order_le_imp_less_or_eq)
   859 done
   860 
   861 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   862 by (rule setleI [THEN isUbI], auto)
   863 
   864 text{* FIXME: @{term "U - T < U"} is redundant *}
   865 lemma lemma_converg4: "!!(X::nat=> real).
   866                [| \<forall>m. X m ~= U;
   867                   isLub UNIV {x. \<exists>n. X n = x} U;
   868                   0 < T;
   869                   U + - T < U
   870                |] ==> \<exists>m. U + -T < X m & X m < U"
   871 apply (drule lemma_converg2, assumption)
   872 apply (rule ccontr, simp)
   873 apply (simp add: linorder_not_less)
   874 apply (drule lemma_converg3)
   875 apply (drule isLub_le_isUb, assumption)
   876 apply (auto dest: order_less_le_trans)
   877 done
   878 
   879 text{*A standard proof of the theorem for monotone increasing sequence*}
   880 
   881 lemma Bseq_mono_convergent:
   882      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   883 apply (simp add: convergent_def)
   884 apply (frule Bseq_isLub, safe)
   885 apply (case_tac "\<exists>m. X m = U", auto)
   886 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   887 (* second case *)
   888 apply (rule_tac x = U in exI)
   889 apply (subst LIMSEQ_iff, safe)
   890 apply (frule lemma_converg2, assumption)
   891 apply (drule lemma_converg4, auto)
   892 apply (rule_tac x = m in exI, safe)
   893 apply (subgoal_tac "X m \<le> X n")
   894  prefer 2 apply blast
   895 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   896 done
   897 
   898 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   899 by (simp add: Bseq_def)
   900 
   901 text{*Main monotonicity theorem*}
   902 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   903 apply (simp add: monoseq_def, safe)
   904 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   905 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   906 apply (auto intro!: Bseq_mono_convergent)
   907 done
   908 
   909 subsubsection{*Increasing and Decreasing Series*}
   910 
   911 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   912   by (simp add: incseq_def monoseq_def) 
   913 
   914 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   915   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   916 proof
   917   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   918   thus ?thesis by simp
   919 next
   920   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   921   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
   922     by (auto simp add: incseq_def intro: order_antisym)
   923   have X: "!!n. X n = X 0"
   924     by (blast intro: const [of 0]) 
   925   have "X = (\<lambda>n. X 0)"
   926     by (blast intro: ext X)
   927   hence "L = X 0" using LIMSEQ_const [of "X 0"]
   928     by (auto intro: LIMSEQ_unique lim) 
   929   thus ?thesis
   930     by (blast intro: eq_refl X)
   931 qed
   932 
   933 lemma incseq_SucI:
   934   assumes "\<And>n. X n \<le> X (Suc n)"
   935   shows "incseq X" unfolding incseq_def
   936 proof safe
   937   fix m n :: nat
   938   { fix d m :: nat
   939     have "X m \<le> X (m + d)"
   940     proof (induct d)
   941       case (Suc d)
   942       also have "X (m + d) \<le> X (m + Suc d)"
   943         using assms by simp
   944       finally show ?case .
   945     qed simp }
   946   note this[of m "n - m"]
   947   moreover assume "m \<le> n"
   948   ultimately show "X m \<le> X n" by simp
   949 qed
   950 
   951 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   952   by (simp add: decseq_def monoseq_def)
   953 
   954 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
   955   by (simp add: decseq_def incseq_def)
   956 
   957 
   958 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
   959 proof -
   960   have inc: "incseq (\<lambda>n. - X n)" using dec
   961     by (simp add: decseq_eq_incseq)
   962   have "- X n \<le> - L" 
   963     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
   964   thus ?thesis
   965     by simp
   966 qed
   967 
   968 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   969 
   970 text{*alternative formulation for boundedness*}
   971 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   972 apply (unfold Bseq_def, safe)
   973 apply (rule_tac [2] x = "k + norm x" in exI)
   974 apply (rule_tac x = K in exI, simp)
   975 apply (rule exI [where x = 0], auto)
   976 apply (erule order_less_le_trans, simp)
   977 apply (drule_tac x=n in spec, fold diff_def)
   978 apply (drule order_trans [OF norm_triangle_ineq2])
   979 apply simp
   980 done
   981 
   982 text{*alternative formulation for boundedness*}
   983 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   984 apply safe
   985 apply (simp add: Bseq_def, safe)
   986 apply (rule_tac x = "K + norm (X N)" in exI)
   987 apply auto
   988 apply (erule order_less_le_trans, simp)
   989 apply (rule_tac x = N in exI, safe)
   990 apply (drule_tac x = n in spec)
   991 apply (rule order_trans [OF norm_triangle_ineq], simp)
   992 apply (auto simp add: Bseq_iff2)
   993 done
   994 
   995 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   996 apply (simp add: Bseq_def)
   997 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   998 apply (drule_tac x = n in spec, arith)
   999 done
  1000 
  1001 
  1002 subsection {* Cauchy Sequences *}
  1003 
  1004 lemma metric_CauchyI:
  1005   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1006 by (simp add: Cauchy_def)
  1007 
  1008 lemma metric_CauchyD:
  1009   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1010 by (simp add: Cauchy_def)
  1011 
  1012 lemma Cauchy_iff:
  1013   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1014   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1015 unfolding Cauchy_def dist_norm ..
  1016 
  1017 lemma Cauchy_iff2:
  1018      "Cauchy X =
  1019       (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1020 apply (simp add: Cauchy_iff, auto)
  1021 apply (drule reals_Archimedean, safe)
  1022 apply (drule_tac x = n in spec, auto)
  1023 apply (rule_tac x = M in exI, auto)
  1024 apply (drule_tac x = m in spec, simp)
  1025 apply (drule_tac x = na in spec, auto)
  1026 done
  1027 
  1028 lemma CauchyI:
  1029   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1030   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1031 by (simp add: Cauchy_iff)
  1032 
  1033 lemma CauchyD:
  1034   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1035   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1036 by (simp add: Cauchy_iff)
  1037 
  1038 lemma Cauchy_subseq_Cauchy:
  1039   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1040 apply (auto simp add: Cauchy_def)
  1041 apply (drule_tac x=e in spec, clarify)
  1042 apply (rule_tac x=M in exI, clarify)
  1043 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1044 done
  1045 
  1046 subsubsection {* Cauchy Sequences are Bounded *}
  1047 
  1048 text{*A Cauchy sequence is bounded -- this is the standard
  1049   proof mechanization rather than the nonstandard proof*}
  1050 
  1051 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1052           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1053 apply (clarify, drule spec, drule (1) mp)
  1054 apply (simp only: norm_minus_commute)
  1055 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1056 apply simp
  1057 done
  1058 
  1059 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1060 apply (simp add: Cauchy_iff)
  1061 apply (drule spec, drule mp, rule zero_less_one, safe)
  1062 apply (drule_tac x="M" in spec, simp)
  1063 apply (drule lemmaCauchy)
  1064 apply (rule_tac k="M" in Bseq_offset)
  1065 apply (simp add: Bseq_def)
  1066 apply (rule_tac x="1 + norm (X M)" in exI)
  1067 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1068 apply (simp add: order_less_imp_le)
  1069 done
  1070 
  1071 subsubsection {* Cauchy Sequences are Convergent *}
  1072 
  1073 class complete_space =
  1074   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1075 
  1076 class banach = real_normed_vector + complete_space
  1077 
  1078 theorem LIMSEQ_imp_Cauchy:
  1079   assumes X: "X ----> a" shows "Cauchy X"
  1080 proof (rule metric_CauchyI)
  1081   fix e::real assume "0 < e"
  1082   hence "0 < e/2" by simp
  1083   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1084   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1085   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1086   proof (intro exI allI impI)
  1087     fix m assume "N \<le> m"
  1088     hence m: "dist (X m) a < e/2" using N by fast
  1089     fix n assume "N \<le> n"
  1090     hence n: "dist (X n) a < e/2" using N by fast
  1091     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1092       by (rule dist_triangle2)
  1093     also from m n have "\<dots> < e" by simp
  1094     finally show "dist (X m) (X n) < e" .
  1095   qed
  1096 qed
  1097 
  1098 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1099 unfolding convergent_def
  1100 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1101 
  1102 lemma Cauchy_convergent_iff:
  1103   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1104   shows "Cauchy X = convergent X"
  1105 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1106 
  1107 lemma convergent_subseq_convergent:
  1108   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1109   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1110   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1111 
  1112 text {*
  1113 Proof that Cauchy sequences converge based on the one from
  1114 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1115 *}
  1116 
  1117 text {*
  1118   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1119   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1120 *}
  1121 
  1122 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1123 by (simp add: isUbI setleI)
  1124 
  1125 locale real_Cauchy =
  1126   fixes X :: "nat \<Rightarrow> real"
  1127   assumes X: "Cauchy X"
  1128   fixes S :: "real set"
  1129   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1130 
  1131 lemma real_CauchyI:
  1132   assumes "Cauchy X"
  1133   shows "real_Cauchy X"
  1134   proof qed (fact assms)
  1135 
  1136 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1137 by (unfold S_def, auto)
  1138 
  1139 lemma (in real_Cauchy) bound_isUb:
  1140   assumes N: "\<forall>n\<ge>N. X n < x"
  1141   shows "isUb UNIV S x"
  1142 proof (rule isUb_UNIV_I)
  1143   fix y::real assume "y \<in> S"
  1144   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1145     by (simp add: S_def)
  1146   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1147   hence "y < X (max M N)" by simp
  1148   also have "\<dots> < x" using N by simp
  1149   finally show "y \<le> x"
  1150     by (rule order_less_imp_le)
  1151 qed
  1152 
  1153 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1154 proof (rule reals_complete)
  1155   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1156     using CauchyD [OF X zero_less_one] by auto
  1157   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1158   show "\<exists>x. x \<in> S"
  1159   proof
  1160     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1161       by (simp add: abs_diff_less_iff)
  1162     thus "X N - 1 \<in> S" by (rule mem_S)
  1163   qed
  1164   show "\<exists>u. isUb UNIV S u"
  1165   proof
  1166     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1167       by (simp add: abs_diff_less_iff)
  1168     thus "isUb UNIV S (X N + 1)"
  1169       by (rule bound_isUb)
  1170   qed
  1171 qed
  1172 
  1173 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1174   assumes x: "isLub UNIV S x"
  1175   shows "X ----> x"
  1176 proof (rule LIMSEQ_I)
  1177   fix r::real assume "0 < r"
  1178   hence r: "0 < r/2" by simp
  1179   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1180     using CauchyD [OF X r] by auto
  1181   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1182   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1183     by (simp only: real_norm_def abs_diff_less_iff)
  1184 
  1185   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1186   hence "X N - r/2 \<in> S" by (rule mem_S)
  1187   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1188 
  1189   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1190   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1191   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1192 
  1193   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1194   proof (intro exI allI impI)
  1195     fix n assume n: "N \<le> n"
  1196     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1197     thus "norm (X n - x) < r" using 1 2
  1198       by (simp add: abs_diff_less_iff)
  1199   qed
  1200 qed
  1201 
  1202 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1203 proof -
  1204   obtain x where "isLub UNIV S x"
  1205     using isLub_ex by fast
  1206   hence "X ----> x"
  1207     by (rule isLub_imp_LIMSEQ)
  1208   thus ?thesis ..
  1209 qed
  1210 
  1211 lemma real_Cauchy_convergent:
  1212   fixes X :: "nat \<Rightarrow> real"
  1213   shows "Cauchy X \<Longrightarrow> convergent X"
  1214 unfolding convergent_def
  1215 by (rule real_Cauchy.LIMSEQ_ex)
  1216  (rule real_CauchyI)
  1217 
  1218 instance real :: banach
  1219 by intro_classes (rule real_Cauchy_convergent)
  1220 
  1221 
  1222 subsection {* Power Sequences *}
  1223 
  1224 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1225 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1226   also fact that bounded and monotonic sequence converges.*}
  1227 
  1228 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1229 apply (simp add: Bseq_def)
  1230 apply (rule_tac x = 1 in exI)
  1231 apply (simp add: power_abs)
  1232 apply (auto dest: power_mono)
  1233 done
  1234 
  1235 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1236 apply (clarify intro!: mono_SucI2)
  1237 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1238 done
  1239 
  1240 lemma convergent_realpow:
  1241   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1242 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1243 
  1244 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1245   fixes x :: real
  1246   assumes x: "0 \<le> x"
  1247   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1248 apply (induct n)
  1249 apply simp
  1250 apply simp
  1251 apply (rule order_trans)
  1252 prefer 2
  1253 apply (erule mult_left_mono)
  1254 apply (rule add_increasing [OF x], simp)
  1255 apply (simp add: real_of_nat_Suc)
  1256 apply (simp add: ring_distribs)
  1257 apply (simp add: mult_nonneg_nonneg x)
  1258 done
  1259 
  1260 lemma LIMSEQ_inverse_realpow_zero:
  1261   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1262 proof (rule LIMSEQ_inverse_zero [rule_format])
  1263   fix y :: real
  1264   assume x: "1 < x"
  1265   hence "0 < x - 1" by simp
  1266   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1267     by (rule reals_Archimedean3)
  1268   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1269   then obtain N::nat where "y < real N * (x - 1)" ..
  1270   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1271   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1272     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1273   also have "\<dots> = x ^ N" by simp
  1274   finally have "y < x ^ N" .
  1275   hence "\<forall>n\<ge>N. y < x ^ n"
  1276     apply clarify
  1277     apply (erule order_less_le_trans)
  1278     apply (erule power_increasing)
  1279     apply (rule order_less_imp_le [OF x])
  1280     done
  1281   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1282 qed
  1283 
  1284 lemma LIMSEQ_realpow_zero:
  1285   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1286 proof (cases)
  1287   assume "x = 0"
  1288   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1289   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1290 next
  1291   assume "0 \<le> x" and "x \<noteq> 0"
  1292   hence x0: "0 < x" by simp
  1293   assume x1: "x < 1"
  1294   from x0 x1 have "1 < inverse x"
  1295     by (rule real_inverse_gt_one)
  1296   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1297     by (rule LIMSEQ_inverse_realpow_zero)
  1298   thus ?thesis by (simp add: power_inverse)
  1299 qed
  1300 
  1301 lemma LIMSEQ_power_zero:
  1302   fixes x :: "'a::{real_normed_algebra_1}"
  1303   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1304 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1305 apply (simp only: LIMSEQ_Zfun_iff, erule Zfun_le)
  1306 apply (simp add: power_abs norm_power_ineq)
  1307 done
  1308 
  1309 lemma LIMSEQ_divide_realpow_zero:
  1310   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1311 apply (cut_tac a = a and x1 = "inverse x" in
  1312         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1313 apply (auto simp add: divide_inverse power_inverse)
  1314 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1315 done
  1316 
  1317 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1318 
  1319 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1320 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1321 
  1322 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1323 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1324 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1325 done
  1326 
  1327 end