src/HOL/Hilbert_Choice.thy
author blanchet
Tue Oct 05 10:59:12 2010 +0200 (2010-10-05)
changeset 39950 f3c4849868b8
parent 39943 0ef551d47783
child 40702 cf26dd7395e4
permissions -rw-r--r--
got rid of overkill "meson_choice" attribute;
tuning
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     Author:     Lawrence C Paulson, Tobias Nipkow
     3     Copyright   2001  University of Cambridge
     4 *)
     5 
     6 header {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
     7 
     8 theory Hilbert_Choice
     9 imports Nat Wellfounded Plain
    10 uses ("Tools/choice_specification.ML")
    11 begin
    12 
    13 subsection {* Hilbert's epsilon *}
    14 
    15 axiomatization Eps :: "('a => bool) => 'a" where
    16   someI: "P x ==> P (Eps P)"
    17 
    18 syntax (epsilon)
    19   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
    20 syntax (HOL)
    21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
    22 syntax
    23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
    24 translations
    25   "SOME x. P" == "CONST Eps (%x. P)"
    26 
    27 print_translation {*
    28   [(@{const_syntax Eps}, fn [Abs abs] =>
    29       let val (x, t) = atomic_abs_tr' abs
    30       in Syntax.const @{syntax_const "_Eps"} $ x $ t end)]
    31 *} -- {* to avoid eta-contraction of body *}
    32 
    33 definition inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
    34 "inv_into A f == %x. SOME y. y : A & f y = x"
    35 
    36 abbreviation inv :: "('a => 'b) => ('b => 'a)" where
    37 "inv == inv_into UNIV"
    38 
    39 
    40 subsection {*Hilbert's Epsilon-operator*}
    41 
    42 text{*Easier to apply than @{text someI} if the witness comes from an
    43 existential formula*}
    44 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
    45 apply (erule exE)
    46 apply (erule someI)
    47 done
    48 
    49 text{*Easier to apply than @{text someI} because the conclusion has only one
    50 occurrence of @{term P}.*}
    51 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    52 by (blast intro: someI)
    53 
    54 text{*Easier to apply than @{text someI2} if the witness comes from an
    55 existential formula*}
    56 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    57 by (blast intro: someI2)
    58 
    59 lemma some_equality [intro]:
    60      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
    61 by (blast intro: someI2)
    62 
    63 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
    64 by blast
    65 
    66 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
    67 by (blast intro: someI)
    68 
    69 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
    70 apply (rule some_equality)
    71 apply (rule refl, assumption)
    72 done
    73 
    74 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
    75 apply (rule some_equality)
    76 apply (rule refl)
    77 apply (erule sym)
    78 done
    79 
    80 
    81 subsection{*Axiom of Choice, Proved Using the Description Operator*}
    82 
    83 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
    84 by (fast elim: someI)
    85 
    86 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    87 by (fast elim: someI)
    88 
    89 
    90 subsection {*Function Inverse*}
    91 
    92 lemma inv_def: "inv f = (%y. SOME x. f x = y)"
    93 by(simp add: inv_into_def)
    94 
    95 lemma inv_into_into: "x : f ` A ==> inv_into A f x : A"
    96 apply (simp add: inv_into_def)
    97 apply (fast intro: someI2)
    98 done
    99 
   100 lemma inv_id [simp]: "inv id = id"
   101 by (simp add: inv_into_def id_def)
   102 
   103 lemma inv_into_f_f [simp]:
   104   "[| inj_on f A;  x : A |] ==> inv_into A f (f x) = x"
   105 apply (simp add: inv_into_def inj_on_def)
   106 apply (blast intro: someI2)
   107 done
   108 
   109 lemma inv_f_f: "inj f ==> inv f (f x) = x"
   110 by simp
   111 
   112 lemma f_inv_into_f: "y : f`A  ==> f (inv_into A f y) = y"
   113 apply (simp add: inv_into_def)
   114 apply (fast intro: someI2)
   115 done
   116 
   117 lemma inv_into_f_eq: "[| inj_on f A; x : A; f x = y |] ==> inv_into A f y = x"
   118 apply (erule subst)
   119 apply (fast intro: inv_into_f_f)
   120 done
   121 
   122 lemma inv_f_eq: "[| inj f; f x = y |] ==> inv f y = x"
   123 by (simp add:inv_into_f_eq)
   124 
   125 lemma inj_imp_inv_eq: "[| inj f; ALL x. f(g x) = x |] ==> inv f = g"
   126 by (blast intro: ext inv_into_f_eq)
   127 
   128 text{*But is it useful?*}
   129 lemma inj_transfer:
   130   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
   131   shows "P x"
   132 proof -
   133   have "f x \<in> range f" by auto
   134   hence "P(inv f (f x))" by (rule minor)
   135   thus "P x" by (simp add: inv_into_f_f [OF injf])
   136 qed
   137 
   138 lemma inj_iff: "(inj f) = (inv f o f = id)"
   139 apply (simp add: o_def fun_eq_iff)
   140 apply (blast intro: inj_on_inverseI inv_into_f_f)
   141 done
   142 
   143 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
   144 by (simp add: inj_iff)
   145 
   146 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
   147 by (simp add: o_assoc[symmetric])
   148 
   149 lemma inv_into_image_cancel[simp]:
   150   "inj_on f A ==> S <= A ==> inv_into A f ` f ` S = S"
   151 by(fastsimp simp: image_def)
   152 
   153 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
   154 by (blast intro: surjI inv_into_f_f)
   155 
   156 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
   157 by (simp add: f_inv_into_f surj_range)
   158 
   159 lemma inv_into_injective:
   160   assumes eq: "inv_into A f x = inv_into A f y"
   161       and x: "x: f`A"
   162       and y: "y: f`A"
   163   shows "x=y"
   164 proof -
   165   have "f (inv_into A f x) = f (inv_into A f y)" using eq by simp
   166   thus ?thesis by (simp add: f_inv_into_f x y)
   167 qed
   168 
   169 lemma inj_on_inv_into: "B <= f`A ==> inj_on (inv_into A f) B"
   170 by (blast intro: inj_onI dest: inv_into_injective injD)
   171 
   172 lemma bij_betw_inv_into: "bij_betw f A B ==> bij_betw (inv_into A f) B A"
   173 by (auto simp add: bij_betw_def inj_on_inv_into)
   174 
   175 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
   176 by (simp add: inj_on_inv_into surj_range)
   177 
   178 lemma surj_iff: "(surj f) = (f o inv f = id)"
   179 apply (simp add: o_def fun_eq_iff)
   180 apply (blast intro: surjI surj_f_inv_f)
   181 done
   182 
   183 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
   184 apply (rule ext)
   185 apply (drule_tac x = "inv f x" in spec)
   186 apply (simp add: surj_f_inv_f)
   187 done
   188 
   189 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
   190 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
   191 
   192 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
   193 apply (rule ext)
   194 apply (auto simp add: inv_into_def)
   195 done
   196 
   197 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
   198 apply (rule inv_equality)
   199 apply (auto simp add: bij_def surj_f_inv_f)
   200 done
   201 
   202 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
   203     f(True)=f(False)=True.  Then it's consistent with axiom someI that
   204     inv f could be any function at all, including the identity function.
   205     If inv f=id then inv f is a bijection, but inj f, surj(f) and
   206     inv(inv f)=f all fail.
   207 **)
   208 
   209 lemma inv_into_comp:
   210   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   211   inv_into A (f o g) x = (inv_into A g o inv_into (g ` A) f) x"
   212 apply (rule inv_into_f_eq)
   213   apply (fast intro: comp_inj_on)
   214  apply (simp add: inv_into_into)
   215 apply (simp add: f_inv_into_f inv_into_into)
   216 done
   217 
   218 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
   219 apply (rule inv_equality)
   220 apply (auto simp add: bij_def surj_f_inv_f)
   221 done
   222 
   223 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
   224 by (simp add: image_eq_UN surj_f_inv_f)
   225 
   226 lemma image_inv_f_f: "inj f ==> (inv f) ` (f ` A) = A"
   227 by (simp add: image_eq_UN)
   228 
   229 lemma inv_image_comp: "inj f ==> inv f ` (f`X) = X"
   230 by (auto simp add: image_def)
   231 
   232 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
   233 apply auto
   234 apply (force simp add: bij_is_inj)
   235 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
   236 done
   237 
   238 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A" 
   239 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
   240 apply (blast intro: bij_is_inj [THEN inv_into_f_f, symmetric])
   241 done
   242 
   243 lemma finite_fun_UNIVD1:
   244   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
   245   and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
   246   shows "finite (UNIV :: 'a set)"
   247 proof -
   248   from fin have finb: "finite (UNIV :: 'b set)" by (rule finite_fun_UNIVD2)
   249   with card have "card (UNIV :: 'b set) \<ge> Suc (Suc 0)"
   250     by (cases "card (UNIV :: 'b set)") (auto simp add: card_eq_0_iff)
   251   then obtain n where "card (UNIV :: 'b set) = Suc (Suc n)" "n = card (UNIV :: 'b set) - Suc (Suc 0)" by auto
   252   then obtain b1 b2 where b1b2: "(b1 :: 'b) \<noteq> (b2 :: 'b)" by (auto simp add: card_Suc_eq)
   253   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))" by (rule finite_imageI)
   254   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
   255   proof (rule UNIV_eq_I)
   256     fix x :: 'a
   257     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1" by (simp add: inv_into_def)
   258     thus "x \<in> range (\<lambda>f\<Colon>'a \<Rightarrow> 'b. inv f b1)" by blast
   259   qed
   260   ultimately show "finite (UNIV :: 'a set)" by simp
   261 qed
   262 
   263 
   264 subsection {*Other Consequences of Hilbert's Epsilon*}
   265 
   266 text {*Hilbert's Epsilon and the @{term split} Operator*}
   267 
   268 text{*Looping simprule*}
   269 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
   270   by simp
   271 
   272 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
   273   by (simp add: split_def)
   274 
   275 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
   276   by blast
   277 
   278 
   279 text{*A relation is wellfounded iff it has no infinite descending chain*}
   280 lemma wf_iff_no_infinite_down_chain:
   281   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
   282 apply (simp only: wf_eq_minimal)
   283 apply (rule iffI)
   284  apply (rule notI)
   285  apply (erule exE)
   286  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
   287 apply (erule contrapos_np, simp, clarify)
   288 apply (subgoal_tac "\<forall>n. nat_rec x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
   289  apply (rule_tac x = "nat_rec x (%i y. @z. z:Q & (z,y) :r)" in exI)
   290  apply (rule allI, simp)
   291  apply (rule someI2_ex, blast, blast)
   292 apply (rule allI)
   293 apply (induct_tac "n", simp_all)
   294 apply (rule someI2_ex, blast+)
   295 done
   296 
   297 lemma wf_no_infinite_down_chainE:
   298   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
   299 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
   300 
   301 
   302 text{*A dynamically-scoped fact for TFL *}
   303 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
   304   by (blast intro: someI)
   305 
   306 
   307 subsection {* Least value operator *}
   308 
   309 definition
   310   LeastM :: "['a => 'b::ord, 'a => bool] => 'a" where
   311   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
   312 
   313 syntax
   314   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
   315 translations
   316   "LEAST x WRT m. P" == "CONST LeastM m (%x. P)"
   317 
   318 lemma LeastMI2:
   319   "P x ==> (!!y. P y ==> m x <= m y)
   320     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
   321     ==> Q (LeastM m P)"
   322   apply (simp add: LeastM_def)
   323   apply (rule someI2_ex, blast, blast)
   324   done
   325 
   326 lemma LeastM_equality:
   327   "P k ==> (!!x. P x ==> m k <= m x)
   328     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
   329   apply (rule LeastMI2, assumption, blast)
   330   apply (blast intro!: order_antisym)
   331   done
   332 
   333 lemma wf_linord_ex_has_least:
   334   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
   335     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
   336   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
   337   apply (drule_tac x = "m`Collect P" in spec, force)
   338   done
   339 
   340 lemma ex_has_least_nat:
   341     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
   342   apply (simp only: pred_nat_trancl_eq_le [symmetric])
   343   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
   344    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
   345   done
   346 
   347 lemma LeastM_nat_lemma:
   348     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
   349   apply (simp add: LeastM_def)
   350   apply (rule someI_ex)
   351   apply (erule ex_has_least_nat)
   352   done
   353 
   354 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1, standard]
   355 
   356 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
   357 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
   358 
   359 
   360 subsection {* Greatest value operator *}
   361 
   362 definition
   363   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a" where
   364   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
   365 
   366 definition
   367   Greatest :: "('a::ord => bool) => 'a" (binder "GREATEST " 10) where
   368   "Greatest == GreatestM (%x. x)"
   369 
   370 syntax
   371   "_GreatestM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"
   372       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   373 translations
   374   "GREATEST x WRT m. P" == "CONST GreatestM m (%x. P)"
   375 
   376 lemma GreatestMI2:
   377   "P x ==> (!!y. P y ==> m y <= m x)
   378     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
   379     ==> Q (GreatestM m P)"
   380   apply (simp add: GreatestM_def)
   381   apply (rule someI2_ex, blast, blast)
   382   done
   383 
   384 lemma GreatestM_equality:
   385  "P k ==> (!!x. P x ==> m x <= m k)
   386     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
   387   apply (rule_tac m = m in GreatestMI2, assumption, blast)
   388   apply (blast intro!: order_antisym)
   389   done
   390 
   391 lemma Greatest_equality:
   392   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
   393   apply (simp add: Greatest_def)
   394   apply (erule GreatestM_equality, blast)
   395   done
   396 
   397 lemma ex_has_greatest_nat_lemma:
   398   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
   399     ==> \<exists>y. P y & ~ (m y < m k + n)"
   400   apply (induct n, force)
   401   apply (force simp add: le_Suc_eq)
   402   done
   403 
   404 lemma ex_has_greatest_nat:
   405   "P k ==> \<forall>y. P y --> m y < b
   406     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
   407   apply (rule ccontr)
   408   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   409     apply (subgoal_tac [3] "m k <= b", auto)
   410   done
   411 
   412 lemma GreatestM_nat_lemma:
   413   "P k ==> \<forall>y. P y --> m y < b
   414     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
   415   apply (simp add: GreatestM_def)
   416   apply (rule someI_ex)
   417   apply (erule ex_has_greatest_nat, assumption)
   418   done
   419 
   420 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1, standard]
   421 
   422 lemma GreatestM_nat_le:
   423   "P x ==> \<forall>y. P y --> m y < b
   424     ==> (m x::nat) <= m (GreatestM m P)"
   425   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
   426   done
   427 
   428 
   429 text {* \medskip Specialization to @{text GREATEST}. *}
   430 
   431 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
   432   apply (simp add: Greatest_def)
   433   apply (rule GreatestM_natI, auto)
   434   done
   435 
   436 lemma Greatest_le:
   437     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
   438   apply (simp add: Greatest_def)
   439   apply (rule GreatestM_nat_le, auto)
   440   done
   441 
   442 
   443 subsection {* Specification package -- Hilbertized version *}
   444 
   445 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
   446   by (simp only: someI_ex)
   447 
   448 use "Tools/choice_specification.ML"
   449 
   450 end