src/Pure/library.ML
author haftmann
Wed Dec 09 21:38:12 2009 +0100 (2009-12-09)
changeset 34059 f3f0e20923a7
parent 33955 fff6f11b1f09
child 35976 ea3d4691a8c6
permissions -rw-r--r--
take and drop as projections of chop
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf mem mem_int mem_string
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception SYS_ERROR of string
    33   val sys_error: string -> 'a
    34   exception ERROR of string
    35   val error: string -> 'a
    36   val cat_error: string -> string -> 'a
    37   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    38 
    39   (*pairs*)
    40   val pair: 'a -> 'b -> 'a * 'b
    41   val rpair: 'a -> 'b -> 'b * 'a
    42   val fst: 'a * 'b -> 'a
    43   val snd: 'a * 'b -> 'b
    44   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    46   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    47   val swap: 'a * 'b -> 'b * 'a
    48   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    49   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    50   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    51 
    52   (*booleans*)
    53   val equal: ''a -> ''a -> bool
    54   val not_equal: ''a -> ''a -> bool
    55   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    56   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    57   val exists: ('a -> bool) -> 'a list -> bool
    58   val forall: ('a -> bool) -> 'a list -> bool
    59   val setmp_noncritical: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    60   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    61   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    62 
    63   (*lists*)
    64   exception UnequalLengths
    65   val single: 'a -> 'a list
    66   val the_single: 'a list -> 'a
    67   val singleton: ('a list -> 'b list) -> 'a -> 'b
    68   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    69   val apply: ('a -> 'a) list -> 'a -> 'a
    70   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    71   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    72   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    73   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    74   val flat: 'a list list -> 'a list
    75   val unflat: 'a list list -> 'b list -> 'b list list
    76   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    77   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    78   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    79   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    80   val maps: ('a -> 'b list) -> 'a list -> 'b list
    81   val filter: ('a -> bool) -> 'a list -> 'a list
    82   val filter_out: ('a -> bool) -> 'a list -> 'a list
    83   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    84   val take: int -> 'a list -> 'a list
    85   val drop: int -> 'a list -> 'a list
    86   val chop: int -> 'a list -> 'a list * 'a list
    87   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    88   val nth: 'a list -> int -> 'a
    89   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    90   val nth_drop: int -> 'a list -> 'a list
    91   val nth_list: 'a list list -> int -> 'a list
    92   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    93   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    94   val map_range: (int -> 'a) -> int -> 'a list
    95   val split_last: 'a list -> 'a list * 'a
    96   val find_index: ('a -> bool) -> 'a list -> int
    97   val find_first: ('a -> bool) -> 'a list -> 'a option
    98   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    99   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   100   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   101   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   102   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   103   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   104   val ~~ : 'a list * 'b list -> ('a * 'b) list
   105   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   106   val split_list: ('a * 'b) list -> 'a list * 'b list
   107   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   108   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   109   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   110   val separate: 'a -> 'a list -> 'a list
   111   val surround: 'a -> 'a list -> 'a list
   112   val replicate: int -> 'a -> 'a list
   113   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   116   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   117   val prefixes1: 'a list -> 'a list list
   118   val prefixes: 'a list -> 'a list list
   119   val suffixes1: 'a list -> 'a list list
   120   val suffixes: 'a list -> 'a list list
   121 
   122   (*integers*)
   123   val upto: int * int -> int list
   124   val downto: int * int -> int list
   125   val radixpand: int * int -> int list
   126   val radixstring: int * string * int -> string
   127   val string_of_int: int -> string
   128   val signed_string_of_int: int -> string
   129   val string_of_indexname: string * int -> string
   130   val read_radix_int: int -> string list -> int * string list
   131   val read_int: string list -> int * string list
   132   val oct_char: string -> string
   133 
   134   (*strings*)
   135   val nth_string: string -> int -> string
   136   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   137   val exists_string: (string -> bool) -> string -> bool
   138   val forall_string: (string -> bool) -> string -> bool
   139   val first_field: string -> string -> (string * string) option
   140   val enclose: string -> string -> string -> string
   141   val unenclose: string -> string
   142   val quote: string -> string
   143   val space_implode: string -> string list -> string
   144   val commas: string list -> string
   145   val commas_quote: string list -> string
   146   val cat_lines: string list -> string
   147   val space_explode: string -> string -> string list
   148   val split_lines: string -> string list
   149   val prefix_lines: string -> string -> string
   150   val prefix: string -> string -> string
   151   val suffix: string -> string -> string
   152   val unprefix: string -> string -> string
   153   val unsuffix: string -> string -> string
   154   val replicate_string: int -> string -> string
   155   val translate_string: (string -> string) -> string -> string
   156   val match_string: string -> string -> bool
   157 
   158   (*lists as sets -- see also Pure/General/ord_list.ML*)
   159   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   160   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   161   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   162   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   163   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   164   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   165   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   166   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   167   val mem: ''a * ''a list -> bool
   168   val mem_int: int * int list -> bool
   169   val mem_string: string * string list -> bool
   170   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   171   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   172   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   173   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   174   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   175 
   176   (*lists as multisets*)
   177   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   178   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   179   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   180 
   181   (*orders*)
   182   val is_equal: order -> bool
   183   val rev_order: order -> order
   184   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   185   val bool_ord: bool * bool -> order
   186   val int_ord: int * int -> order
   187   val string_ord: string * string -> order
   188   val fast_string_ord: string * string -> order
   189   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   190   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   191   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   192   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   193   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   194   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   195   val sort_strings: string list -> string list
   196   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   197   val tag_list: int -> 'a list -> (int * 'a) list
   198   val untag_list: (int * 'a) list -> 'a list
   199   val order_list: (int * 'a) list -> 'a list
   200 
   201   (*random numbers*)
   202   exception RANDOM
   203   val random: unit -> real
   204   val random_range: int -> int -> int
   205   val one_of: 'a list -> 'a
   206   val frequency: (int * 'a) list -> 'a
   207 
   208   (*misc*)
   209   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   210   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   211     'a -> 'b -> 'c * 'b
   212   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   213   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   214   val gensym: string -> string
   215   type stamp
   216   val stamp: unit -> stamp
   217   type serial
   218   val serial: unit -> serial
   219   val serial_string: unit -> string
   220   structure Object: sig type T end
   221 end;
   222 
   223 signature LIBRARY =
   224 sig
   225   include BASIC_LIBRARY
   226   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   227   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   228   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   229   val last_elem: 'a list -> 'a
   230 end;
   231 
   232 structure Library: LIBRARY =
   233 struct
   234 
   235 (* functions *)
   236 
   237 fun undefined _ = raise Match;
   238 
   239 fun I x = x;
   240 fun K x = fn _ => x;
   241 fun curry f x y = f (x, y);
   242 fun uncurry f (x, y) = f x y;
   243 
   244 (*conditional application*)
   245 fun b ? f = fn x => if b then f x else x;
   246 
   247 (*composition with multiple args*)
   248 fun (f oo g) x y = f (g x y);
   249 fun (f ooo g) x y z = f (g x y z);
   250 fun (f oooo g) x y z w = f (g x y z w);
   251 
   252 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   253 fun funpow (0 : int) _ = I
   254   | funpow n f = f #> funpow (n - 1) f;
   255 
   256 fun funpow_yield (0 : int) _ x = ([], x)
   257   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   258 
   259 (* errors *)
   260 
   261 exception SYS_ERROR of string;
   262 fun sys_error msg = raise SYS_ERROR msg;
   263 
   264 exception ERROR of string;
   265 fun error msg = raise ERROR msg;
   266 
   267 fun cat_error "" msg = error msg
   268   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   269 
   270 fun assert_all pred list msg =
   271   let
   272     fun ass [] = ()
   273       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   274   in ass list end;
   275 
   276 
   277 (* pairs *)
   278 
   279 fun pair x y = (x, y);
   280 fun rpair x y = (y, x);
   281 
   282 fun fst (x, y) = x;
   283 fun snd (x, y) = y;
   284 
   285 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   286 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   287 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   288 
   289 fun swap (x, y) = (y, x);
   290 
   291 fun apfst f (x, y) = (f x, y);
   292 fun apsnd f (x, y) = (x, f y);
   293 fun pairself f (x, y) = (f x, f y);
   294 
   295 
   296 (* booleans *)
   297 
   298 (*polymorphic equality*)
   299 fun equal x y = x = y;
   300 fun not_equal x y = x <> y;
   301 
   302 (*combining predicates*)
   303 fun p orf q = fn x => p x orelse q x;
   304 fun p andf q = fn x => p x andalso q x;
   305 
   306 val exists = List.exists;
   307 val forall = List.all;
   308 
   309 
   310 (* flags *)
   311 
   312 (*temporarily set flag during execution*)
   313 fun setmp_noncritical flag value f x =
   314   uninterruptible (fn restore_attributes => fn () =>
   315     let
   316       val orig_value = ! flag;
   317       val _ = flag := value;
   318       val result = Exn.capture (restore_attributes f) x;
   319       val _ = flag := orig_value;
   320     in Exn.release result end) ();
   321 
   322 fun setmp_CRITICAL flag value f x =
   323   NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   324 
   325 fun setmp_thread_data tag orig_data data f x =
   326   uninterruptible (fn restore_attributes => fn () =>
   327     let
   328       val _ = Thread.setLocal (tag, data);
   329       val result = Exn.capture (restore_attributes f) x;
   330       val _ = Thread.setLocal (tag, orig_data);
   331     in Exn.release result end) ();
   332 
   333 
   334 
   335 (** lists **)
   336 
   337 exception UnequalLengths;
   338 
   339 fun single x = [x];
   340 
   341 fun the_single [x] = x
   342   | the_single _ = raise Empty;
   343 
   344 fun singleton f x = the_single (f [x]);
   345 
   346 fun yield_singleton f x = f [x] #>> the_single;
   347 
   348 fun apply [] x = x
   349   | apply (f :: fs) x = apply fs (f x);
   350 
   351 fun perhaps_apply funs arg =
   352   let
   353     fun app [] res = res
   354       | app (f :: fs) (changed, x) =
   355           (case f x of
   356             NONE => app fs (changed, x)
   357           | SOME x' => app fs (true, x'));
   358   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   359 
   360 fun perhaps_loop f arg =
   361   let
   362     fun loop (changed, x) =
   363       (case f x of
   364         NONE => (changed, x)
   365       | SOME x' => loop (true, x'));
   366   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   367 
   368 
   369 (* fold -- old versions *)
   370 
   371 (*the following versions of fold are designed to fit nicely with infixes*)
   372 
   373 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   374     for operators that associate to the left (TAIL RECURSIVE)*)
   375 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   376   let fun itl (e, [])  = e
   377         | itl (e, a::l) = itl (f(e, a), l)
   378   in  itl end;
   379 
   380 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   381     for operators that associate to the right (not tail recursive)*)
   382 fun foldr f (l, e) =
   383   let fun itr [] = e
   384         | itr (a::l) = f(a, itr l)
   385   in  itr l  end;
   386 
   387 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   388     for operators that associate to the left (TAIL RECURSIVE)*)
   389 fun foldl1 f [] = raise Empty
   390   | foldl1 f (x :: xs) = foldl f (x, xs);
   391 
   392 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   393     for n > 0, operators that associate to the right (not tail recursive)*)
   394 fun foldr1 f [] = raise Empty
   395   | foldr1 f l =
   396       let fun itr [x] = x
   397             | itr (x::l) = f(x, itr l)
   398       in  itr l  end;
   399 
   400 fun foldl_map f =
   401   let
   402     fun fold_aux (x, []) = (x, [])
   403       | fold_aux (x, y :: ys) =
   404           let
   405             val (x', y') = f (x, y);
   406             val (x'', ys') = fold_aux (x', ys);
   407           in (x'', y' :: ys') end;
   408   in fold_aux end;
   409 
   410 
   411 (* basic list functions *)
   412 
   413 fun eq_list eq (list1, list2) =
   414   let
   415     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   416       | eq_lst _ = true;
   417   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   418 
   419 fun maps f [] = []
   420   | maps f (x :: xs) = f x @ maps f xs;
   421 
   422 val filter = List.filter;
   423 fun filter_out f = filter (not o f);
   424 val map_filter = List.mapPartial;
   425 
   426 fun take (0: int) xs = []
   427   | take _ [] = []
   428   | take n (x :: xs) = x :: take (n - 1) xs;
   429 
   430 fun drop (0: int) xs = xs
   431   | drop _ [] = []
   432   | drop n (x :: xs) = drop (n - 1) xs;
   433 
   434 fun chop (0: int) xs = ([], xs)
   435   | chop _ [] = ([], [])
   436   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   437 
   438 fun dropwhile P [] = []
   439   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   440 
   441 (*return nth element of a list, where 0 designates the first element;
   442   raise Subscript if list too short*)
   443 fun nth xs i = List.nth (xs, i);
   444 
   445 fun nth_list xss i = nth xss i handle Subscript => [];
   446 
   447 fun nth_map 0 f (x :: xs) = f x :: xs
   448   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   449   | nth_map (_: int) _ [] = raise Subscript;
   450 
   451 fun nth_drop n xs =
   452   List.take (xs, n) @ List.drop (xs, n + 1);
   453 
   454 fun map_index f =
   455   let
   456     fun mapp (_: int) [] = []
   457       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   458   in mapp 0 end;
   459 
   460 fun fold_index f =
   461   let
   462     fun fold_aux (_: int) [] y = y
   463       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   464   in fold_aux 0 end;
   465 
   466 fun map_range f i =
   467   let
   468     fun mapp (k: int) =
   469       if k < i then f k :: mapp (k + 1) else [];
   470   in mapp 0 end;
   471 
   472 val last_elem = List.last;
   473 
   474 (*rear decomposition*)
   475 fun split_last [] = raise Empty
   476   | split_last [x] = ([], x)
   477   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   478 
   479 (*find position of first element satisfying a predicate*)
   480 fun find_index pred =
   481   let fun find (_: int) [] = ~1
   482         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   483   in find 0 end;
   484 
   485 (*find first element satisfying predicate*)
   486 val find_first = List.find;
   487 
   488 (*get first element by lookup function*)
   489 fun get_first _ [] = NONE
   490   | get_first f (x :: xs) =
   491       (case f x of
   492         NONE => get_first f xs
   493       | some => some);
   494 
   495 fun get_index f =
   496   let
   497     fun get (_: int) [] = NONE
   498       | get i (x :: xs) =
   499           case f x
   500            of NONE => get (i + 1) xs
   501             | SOME y => SOME (i, y)
   502   in get 0 end;
   503 
   504 val flat = List.concat;
   505 
   506 fun unflat (xs :: xss) ys =
   507       let val (ps, qs) = chop (length xs) ys
   508       in ps :: unflat xss qs end
   509   | unflat [] [] = []
   510   | unflat _ _ = raise UnequalLengths;
   511 
   512 fun burrow f xss = unflat xss (f (flat xss));
   513 
   514 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   515 
   516 fun fold_burrow f xss s =
   517   apfst (unflat xss) (f (flat xss) s);
   518 
   519 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   520 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   521   | separate _ xs = xs;
   522 
   523 fun surround s (x :: xs) = s :: x :: surround s xs
   524   | surround s [] = [s];
   525 
   526 (*make the list [x, x, ..., x] of length n*)
   527 fun replicate (n: int) x =
   528   let fun rep (0, xs) = xs
   529         | rep (n, xs) = rep (n - 1, x :: xs)
   530   in
   531     if n < 0 then raise Subscript
   532     else rep (n, [])
   533   end;
   534 
   535 
   536 (* direct product *)
   537 
   538 fun map_product f _ [] = []
   539   | map_product f [] _ = []
   540   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   541 
   542 fun fold_product f _ [] z = z
   543   | fold_product f [] _ z = z
   544   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   545 
   546 
   547 (* lists of pairs *)
   548 
   549 exception UnequalLengths;
   550 
   551 fun map2 _ [] [] = []
   552   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   553   | map2 _ _ _ = raise UnequalLengths;
   554 
   555 fun fold2 f [] [] z = z
   556   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   557   | fold2 f _ _ _ = raise UnequalLengths;
   558 
   559 fun map_split f [] = ([], [])
   560   | map_split f (x :: xs) =
   561       let
   562         val (y, w) = f x;
   563         val (ys, ws) = map_split f xs;
   564       in (y :: ys, w :: ws) end;
   565 
   566 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   567   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   568   | zip_options _ [] = []
   569   | zip_options [] _ = raise UnequalLengths;
   570 
   571 (*combine two lists forming a list of pairs:
   572   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   573 fun [] ~~ [] = []
   574   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   575   | _ ~~ _ = raise UnequalLengths;
   576 
   577 (*inverse of ~~; the old 'split':
   578   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   579 val split_list = ListPair.unzip;
   580 
   581 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   582 
   583 
   584 (* prefixes, suffixes *)
   585 
   586 fun is_prefix _ [] _ = true
   587   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   588   | is_prefix eq _ _ = false;
   589 
   590 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   591    where xi is the first element that does not satisfy the predicate*)
   592 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   593   let fun take (rxs, []) = (rev rxs, [])
   594         | take (rxs, x :: xs) =
   595             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   596   in  take([], xs)  end;
   597 
   598 fun chop_prefix eq ([], ys) = ([], ([], ys))
   599   | chop_prefix eq (xs, []) = ([], (xs, []))
   600   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   601       if eq (x, y) then
   602         let val (ps', xys'') = chop_prefix eq (xs', ys')
   603         in (x :: ps', xys'') end
   604       else ([], (xs, ys));
   605 
   606 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   607    where xi is the last element that does not satisfy the predicate*)
   608 fun take_suffix _ [] = ([], [])
   609   | take_suffix pred (x :: xs) =
   610       (case take_suffix pred xs of
   611         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   612       | (prfx, sffx) => (x :: prfx, sffx));
   613 
   614 fun prefixes1 [] = []
   615   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   616 
   617 fun prefixes xs = [] :: prefixes1 xs;
   618 
   619 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   620 fun suffixes xs = [] :: suffixes1 xs;
   621 
   622 
   623 
   624 (** integers **)
   625 
   626 (* lists of integers *)
   627 
   628 (*make the list [from, from + 1, ..., to]*)
   629 fun ((i: int) upto j) =
   630   if i > j then [] else i :: (i + 1 upto j);
   631 
   632 (*make the list [from, from - 1, ..., to]*)
   633 fun ((i: int) downto j) =
   634   if i < j then [] else i :: (i - 1 downto j);
   635 
   636 
   637 (* convert integers to strings *)
   638 
   639 (*expand the number in the given base;
   640   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   641 fun radixpand (base, num) : int list =
   642   let
   643     fun radix (n, tail) =
   644       if n < base then n :: tail
   645       else radix (n div base, (n mod base) :: tail)
   646   in radix (num, []) end;
   647 
   648 (*expands a number into a string of characters starting from "zerochar";
   649   example: radixstring (2, "0", 8) gives "1000"*)
   650 fun radixstring (base, zerochar, num) =
   651   let val offset = ord zerochar;
   652       fun chrof n = chr (offset + n)
   653   in implode (map chrof (radixpand (base, num))) end;
   654 
   655 
   656 val string_of_int = Int.toString;
   657 
   658 fun signed_string_of_int i =
   659   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   660 
   661 fun string_of_indexname (a, 0) = a
   662   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   663 
   664 
   665 (* read integers *)
   666 
   667 fun read_radix_int radix cs =
   668   let
   669     val zero = ord "0";
   670     val limit = zero + radix;
   671     fun scan (num, []) = (num, [])
   672       | scan (num, c :: cs) =
   673         if zero <= ord c andalso ord c < limit then
   674           scan (radix * num + (ord c - zero), cs)
   675         else (num, c :: cs);
   676   in scan (0, cs) end;
   677 
   678 val read_int = read_radix_int 10;
   679 
   680 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   681 
   682 
   683 
   684 (** strings **)
   685 
   686 (* functions tuned for strings, avoiding explode *)
   687 
   688 fun nth_string str i =
   689   (case try String.substring (str, i, 1) of
   690     SOME s => s
   691   | NONE => raise Subscript);
   692 
   693 fun fold_string f str x0 =
   694   let
   695     val n = size str;
   696     fun iter (x, i) =
   697       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   698   in iter (x0, 0) end;
   699 
   700 fun exists_string pred str =
   701   let
   702     val n = size str;
   703     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   704   in ex 0 end;
   705 
   706 fun forall_string pred = not o exists_string (not o pred);
   707 
   708 fun first_field sep str =
   709   let
   710     val n = size sep;
   711     val len = size str;
   712     fun find i =
   713       if i + n > len then NONE
   714       else if String.substring (str, i, n) = sep then SOME i
   715       else find (i + 1);
   716   in
   717     (case find 0 of
   718       NONE => NONE
   719     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   720   end;
   721 
   722 (*enclose in brackets*)
   723 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   724 fun unenclose str = String.substring (str, 1, size str - 2);
   725 
   726 (*simple quoting (does not escape special chars)*)
   727 val quote = enclose "\"" "\"";
   728 
   729 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   730 fun space_implode a bs = implode (separate a bs);
   731 
   732 val commas = space_implode ", ";
   733 val commas_quote = commas o map quote;
   734 
   735 (*concatenate messages, one per line, into a string*)
   736 val cat_lines = space_implode "\n";
   737 
   738 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   739 fun space_explode _ "" = []
   740   | space_explode sep s = String.fields (fn c => str c = sep) s;
   741 
   742 val split_lines = space_explode "\n";
   743 
   744 fun prefix_lines "" txt = txt
   745   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   746 
   747 fun prefix prfx s = prfx ^ s;
   748 fun suffix sffx s = s ^ sffx;
   749 
   750 fun unprefix prfx s =
   751   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   752   else raise Fail "unprefix";
   753 
   754 fun unsuffix sffx s =
   755   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   756   else raise Fail "unsuffix";
   757 
   758 fun replicate_string (0: int) _ = ""
   759   | replicate_string 1 a = a
   760   | replicate_string k a =
   761       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   762       else replicate_string (k div 2) (a ^ a) ^ a;
   763 
   764 fun translate_string f = String.translate (f o String.str);
   765 
   766 (*crude matching of str against simple glob pat*)
   767 fun match_string pat str =
   768   let
   769     fun match [] _ = true
   770       | match (p :: ps) s =
   771           size p <= size s andalso
   772             (case try (unprefix p) s of
   773               SOME s' => match ps s'
   774             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   775   in match (space_explode "*" pat) str end;
   776 
   777 (** lists as sets -- see also Pure/General/ord_list.ML **)
   778 
   779 (* canonical operations *)
   780 
   781 fun member eq list x =
   782   let
   783     fun memb [] = false
   784       | memb (y :: ys) = eq (x, y) orelse memb ys;
   785   in memb list end;
   786 
   787 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   788 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   789 fun update eq x xs = cons x (remove eq x xs);
   790 
   791 fun inter eq xs = filter (member eq xs);
   792 
   793 fun union eq = fold (insert eq);
   794 fun subtract eq = fold (remove eq);
   795 
   796 fun merge eq (xs, ys) =
   797   if pointer_eq (xs, ys) then xs
   798   else if null xs then ys
   799   else fold_rev (insert eq) ys xs;
   800 
   801 
   802 (* old-style infixes *)
   803 
   804 fun x mem xs = member (op =) xs x;
   805 fun (x: int) mem_int xs = member (op =) xs x;
   806 fun (x: string) mem_string xs = member (op =) xs x;
   807 
   808 
   809 (* subset and set equality *)
   810 
   811 fun subset eq (xs, ys) = forall (member eq ys) xs;
   812 
   813 fun eq_set eq (xs, ys) =
   814   eq_list eq (xs, ys) orelse
   815     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   816 
   817 
   818 (*makes a list of the distinct members of the input; preserves order, takes
   819   first of equal elements*)
   820 fun distinct eq lst =
   821   let
   822     fun dist (rev_seen, []) = rev rev_seen
   823       | dist (rev_seen, x :: xs) =
   824           if member eq rev_seen x then dist (rev_seen, xs)
   825           else dist (x :: rev_seen, xs);
   826   in dist ([], lst) end;
   827 
   828 (*returns a list containing all repeated elements exactly once; preserves
   829   order, takes first of equal elements*)
   830 fun duplicates eq lst =
   831   let
   832     fun dups (rev_dups, []) = rev rev_dups
   833       | dups (rev_dups, x :: xs) =
   834           if member eq rev_dups x orelse not (member eq xs x) then
   835             dups (rev_dups, xs)
   836           else dups (x :: rev_dups, xs);
   837   in dups ([], lst) end;
   838 
   839 fun has_duplicates eq =
   840   let
   841     fun dups [] = false
   842       | dups (x :: xs) = member eq xs x orelse dups xs;
   843   in dups end;
   844 
   845 
   846 (* matrices *)
   847 
   848 fun map_transpose f xss =
   849   let
   850     val n = case distinct (op =) (map length xss)
   851      of [] => 0
   852       | [n] => n
   853       | _ => raise UnequalLengths;
   854   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   855 
   856 
   857 
   858 (** lists as multisets **)
   859 
   860 fun remove1 eq x [] = []
   861   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   862 
   863 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   864 
   865 fun submultiset _ ([], _)  = true
   866   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   867 
   868 
   869 
   870 (** orders **)
   871 
   872 fun is_equal EQUAL = true
   873   | is_equal _ = false;
   874 
   875 fun rev_order LESS = GREATER
   876   | rev_order EQUAL = EQUAL
   877   | rev_order GREATER = LESS;
   878 
   879 (*assume rel is a linear strict order*)
   880 fun make_ord rel (x, y) =
   881   if rel (x, y) then LESS
   882   else if rel (y, x) then GREATER
   883   else EQUAL;
   884 
   885 fun bool_ord (false, true) = LESS
   886   | bool_ord (true, false) = GREATER
   887   | bool_ord _ = EQUAL;
   888 
   889 val int_ord = Int.compare;
   890 val string_ord = String.compare;
   891 
   892 fun fast_string_ord (s1, s2) =
   893   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   894 
   895 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   896   | option_ord _ (NONE, NONE) = EQUAL
   897   | option_ord _ (NONE, SOME _) = LESS
   898   | option_ord _ (SOME _, NONE) = GREATER;
   899 
   900 (*lexicographic product*)
   901 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   902   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   903 
   904 (*dictionary order -- in general NOT well-founded!*)
   905 fun dict_ord elem_ord (x :: xs, y :: ys) =
   906       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   907   | dict_ord _ ([], []) = EQUAL
   908   | dict_ord _ ([], _ :: _) = LESS
   909   | dict_ord _ (_ :: _, []) = GREATER;
   910 
   911 (*lexicographic product of lists*)
   912 fun list_ord elem_ord (xs, ys) =
   913   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   914 
   915 
   916 (* sorting *)
   917 
   918 (*quicksort -- stable, i.e. does not reorder equal elements*)
   919 fun quicksort unique ord =
   920   let
   921     fun qsort [] = []
   922       | qsort (xs as [_]) = xs
   923       | qsort (xs as [x, y]) =
   924           (case ord (x, y) of
   925             LESS => xs
   926           | EQUAL => if unique then [x] else xs
   927           | GREATER => [y, x])
   928       | qsort xs =
   929           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   930           in qsort lts @ eqs @ qsort gts end
   931     and part _ [] = ([], [], [])
   932       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   933     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   934       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   935       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   936       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   937   in qsort end;
   938 
   939 fun sort ord = quicksort false ord;
   940 fun sort_distinct ord = quicksort true ord;
   941 
   942 val sort_strings = sort string_ord;
   943 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   944 
   945 
   946 (* items tagged by integer index *)
   947 
   948 (*insert tags*)
   949 fun tag_list k [] = []
   950   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   951 
   952 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   953 fun untag_list [] = []
   954   | untag_list [(k: int, x)] = [x]
   955   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   956       if k = k' then untag_list rest
   957       else x :: untag_list rest;
   958 
   959 (*return list elements in original order*)
   960 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   961 
   962 
   963 
   964 (** random numbers **)
   965 
   966 exception RANDOM;
   967 
   968 fun rmod x y = x - y * Real.realFloor (x / y);
   969 
   970 local
   971   val a = 16807.0;
   972   val m = 2147483647.0;
   973   val random_seed = Unsynchronized.ref 1.0;
   974 in
   975 
   976 fun random () = CRITICAL (fn () =>
   977   let val r = rmod (a * ! random_seed) m
   978   in (random_seed := r; r) end);
   979 
   980 end;
   981 
   982 fun random_range l h =
   983   if h < l orelse l < 0 then raise RANDOM
   984   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   985 
   986 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   987 
   988 fun frequency xs =
   989   let
   990     val sum = foldl op + (0, map fst xs);
   991     fun pick n ((k: int, x) :: xs) =
   992       if n <= k then x else pick (n - k) xs
   993   in pick (random_range 1 sum) xs end;
   994 
   995 
   996 
   997 (** misc **)
   998 
   999 fun divide_and_conquer decomp x =
  1000   let val (ys, recomb) = decomp x
  1001   in recomb (map (divide_and_conquer decomp) ys) end;
  1002 
  1003 fun divide_and_conquer' decomp x s =
  1004   let val ((ys, recomb), s') = decomp x s
  1005   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1006 
  1007 
  1008 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1009    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1010 fun partition_list p i j =
  1011   let fun part k xs =
  1012             if k>j then
  1013               (case xs of [] => []
  1014                          | _ => raise Fail "partition_list")
  1015             else
  1016             let val (ns, rest) = List.partition (p k) xs;
  1017             in  ns :: part(k+1)rest  end
  1018   in  part (i: int) end;
  1019 
  1020 fun partition_eq (eq:'a * 'a -> bool) =
  1021   let
  1022     fun part [] = []
  1023       | part (x :: ys) =
  1024           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1025           in (x::xs)::(part xs') end
  1026   in part end;
  1027 
  1028 
  1029 
  1030 (* generating identifiers *)
  1031 
  1032 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1033 local
  1034 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1035 fun gensym_char i =
  1036   if i<26 then chr (ord "A" + i)
  1037   else if i<52 then chr (ord "a" + i - 26)
  1038   else chr (ord "0" + i - 52);
  1039 
  1040 val char_vec = Vector.tabulate (62, gensym_char);
  1041 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1042 
  1043 val gensym_seed = Unsynchronized.ref (0: int);
  1044 
  1045 in
  1046   fun gensym pre =
  1047     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1048 end;
  1049 
  1050 
  1051 (* stamps and serial numbers *)
  1052 
  1053 type stamp = unit Unsynchronized.ref;
  1054 val stamp: unit -> stamp = Unsynchronized.ref;
  1055 
  1056 type serial = int;
  1057 val serial = Multithreading.serial;
  1058 val serial_string = string_of_int o serial;
  1059 
  1060 
  1061 (* generic objects *)
  1062 
  1063 (*note that the builtin exception datatype may be extended by new
  1064   constructors at any time*)
  1065 structure Object = struct type T = exn end;
  1066 
  1067 end;
  1068 
  1069 structure Basic_Library: BASIC_LIBRARY = Library;
  1070 open Basic_Library;