src/HOL/Finite_Set.thy
author hoelzl
Wed Jul 27 19:34:30 2011 +0200 (2011-07-27)
changeset 43991 f4a7697011c5
parent 43866 8a50dc70cbff
child 44744 bdf8eb8f126b
child 44831 4ea848959340
permissions -rw-r--r--
finite vimage on arbitrary domains
     1 (*  Title:      HOL/Finite_Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3                 with contributions by Jeremy Avigad
     4 *)
     5 
     6 header {* Finite sets *}
     7 
     8 theory Finite_Set
     9 imports Option Power
    10 begin
    11 
    12 subsection {* Predicate for finite sets *}
    13 
    14 inductive finite :: "'a set \<Rightarrow> bool"
    15   where
    16     emptyI [simp, intro!]: "finite {}"
    17   | insertI [simp, intro!]: "finite A \<Longrightarrow> finite (insert a A)"
    18 
    19 lemma finite_induct [case_names empty insert, induct set: finite]:
    20   -- {* Discharging @{text "x \<notin> F"} entails extra work. *}
    21   assumes "finite F"
    22   assumes "P {}"
    23     and insert: "\<And>x F. finite F \<Longrightarrow> x \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert x F)"
    24   shows "P F"
    25 using `finite F` proof induct
    26   show "P {}" by fact
    27   fix x F assume F: "finite F" and P: "P F"
    28   show "P (insert x F)"
    29   proof cases
    30     assume "x \<in> F"
    31     hence "insert x F = F" by (rule insert_absorb)
    32     with P show ?thesis by (simp only:)
    33   next
    34     assume "x \<notin> F"
    35     from F this P show ?thesis by (rule insert)
    36   qed
    37 qed
    38 
    39 
    40 subsubsection {* Choice principles *}
    41 
    42 lemma ex_new_if_finite: -- "does not depend on def of finite at all"
    43   assumes "\<not> finite (UNIV :: 'a set)" and "finite A"
    44   shows "\<exists>a::'a. a \<notin> A"
    45 proof -
    46   from assms have "A \<noteq> UNIV" by blast
    47   then show ?thesis by blast
    48 qed
    49 
    50 text {* A finite choice principle. Does not need the SOME choice operator. *}
    51 
    52 lemma finite_set_choice:
    53   "finite A \<Longrightarrow> \<forall>x\<in>A. \<exists>y. P x y \<Longrightarrow> \<exists>f. \<forall>x\<in>A. P x (f x)"
    54 proof (induct rule: finite_induct)
    55   case empty then show ?case by simp
    56 next
    57   case (insert a A)
    58   then obtain f b where f: "ALL x:A. P x (f x)" and ab: "P a b" by auto
    59   show ?case (is "EX f. ?P f")
    60   proof
    61     show "?P(%x. if x = a then b else f x)" using f ab by auto
    62   qed
    63 qed
    64 
    65 
    66 subsubsection {* Finite sets are the images of initial segments of natural numbers *}
    67 
    68 lemma finite_imp_nat_seg_image_inj_on:
    69   assumes "finite A" 
    70   shows "\<exists>(n::nat) f. A = f ` {i. i < n} \<and> inj_on f {i. i < n}"
    71 using assms proof induct
    72   case empty
    73   show ?case
    74   proof
    75     show "\<exists>f. {} = f ` {i::nat. i < 0} \<and> inj_on f {i. i < 0}" by simp 
    76   qed
    77 next
    78   case (insert a A)
    79   have notinA: "a \<notin> A" by fact
    80   from insert.hyps obtain n f
    81     where "A = f ` {i::nat. i < n}" "inj_on f {i. i < n}" by blast
    82   hence "insert a A = f(n:=a) ` {i. i < Suc n}"
    83         "inj_on (f(n:=a)) {i. i < Suc n}" using notinA
    84     by (auto simp add: image_def Ball_def inj_on_def less_Suc_eq)
    85   thus ?case by blast
    86 qed
    87 
    88 lemma nat_seg_image_imp_finite:
    89   "A = f ` {i::nat. i < n} \<Longrightarrow> finite A"
    90 proof (induct n arbitrary: A)
    91   case 0 thus ?case by simp
    92 next
    93   case (Suc n)
    94   let ?B = "f ` {i. i < n}"
    95   have finB: "finite ?B" by(rule Suc.hyps[OF refl])
    96   show ?case
    97   proof cases
    98     assume "\<exists>k<n. f n = f k"
    99     hence "A = ?B" using Suc.prems by(auto simp:less_Suc_eq)
   100     thus ?thesis using finB by simp
   101   next
   102     assume "\<not>(\<exists> k<n. f n = f k)"
   103     hence "A = insert (f n) ?B" using Suc.prems by(auto simp:less_Suc_eq)
   104     thus ?thesis using finB by simp
   105   qed
   106 qed
   107 
   108 lemma finite_conv_nat_seg_image:
   109   "finite A \<longleftrightarrow> (\<exists>(n::nat) f. A = f ` {i::nat. i < n})"
   110   by (blast intro: nat_seg_image_imp_finite dest: finite_imp_nat_seg_image_inj_on)
   111 
   112 lemma finite_imp_inj_to_nat_seg:
   113   assumes "finite A"
   114   shows "\<exists>f n::nat. f ` A = {i. i < n} \<and> inj_on f A"
   115 proof -
   116   from finite_imp_nat_seg_image_inj_on[OF `finite A`]
   117   obtain f and n::nat where bij: "bij_betw f {i. i<n} A"
   118     by (auto simp:bij_betw_def)
   119   let ?f = "the_inv_into {i. i<n} f"
   120   have "inj_on ?f A & ?f ` A = {i. i<n}"
   121     by (fold bij_betw_def) (rule bij_betw_the_inv_into[OF bij])
   122   thus ?thesis by blast
   123 qed
   124 
   125 lemma finite_Collect_less_nat [iff]:
   126   "finite {n::nat. n < k}"
   127   by (fastsimp simp: finite_conv_nat_seg_image)
   128 
   129 lemma finite_Collect_le_nat [iff]:
   130   "finite {n::nat. n \<le> k}"
   131   by (simp add: le_eq_less_or_eq Collect_disj_eq)
   132 
   133 
   134 subsubsection {* Finiteness and common set operations *}
   135 
   136 lemma rev_finite_subset:
   137   "finite B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> finite A"
   138 proof (induct arbitrary: A rule: finite_induct)
   139   case empty
   140   then show ?case by simp
   141 next
   142   case (insert x F A)
   143   have A: "A \<subseteq> insert x F" and r: "A - {x} \<subseteq> F \<Longrightarrow> finite (A - {x})" by fact+
   144   show "finite A"
   145   proof cases
   146     assume x: "x \<in> A"
   147     with A have "A - {x} \<subseteq> F" by (simp add: subset_insert_iff)
   148     with r have "finite (A - {x})" .
   149     hence "finite (insert x (A - {x}))" ..
   150     also have "insert x (A - {x}) = A" using x by (rule insert_Diff)
   151     finally show ?thesis .
   152   next
   153     show "A \<subseteq> F ==> ?thesis" by fact
   154     assume "x \<notin> A"
   155     with A show "A \<subseteq> F" by (simp add: subset_insert_iff)
   156   qed
   157 qed
   158 
   159 lemma finite_subset:
   160   "A \<subseteq> B \<Longrightarrow> finite B \<Longrightarrow> finite A"
   161   by (rule rev_finite_subset)
   162 
   163 lemma finite_UnI:
   164   assumes "finite F" and "finite G"
   165   shows "finite (F \<union> G)"
   166   using assms by induct simp_all
   167 
   168 lemma finite_Un [iff]:
   169   "finite (F \<union> G) \<longleftrightarrow> finite F \<and> finite G"
   170   by (blast intro: finite_UnI finite_subset [of _ "F \<union> G"])
   171 
   172 lemma finite_insert [simp]: "finite (insert a A) \<longleftrightarrow> finite A"
   173 proof -
   174   have "finite {a} \<and> finite A \<longleftrightarrow> finite A" by simp
   175   then have "finite ({a} \<union> A) \<longleftrightarrow> finite A" by (simp only: finite_Un)
   176   then show ?thesis by simp
   177 qed
   178 
   179 lemma finite_Int [simp, intro]:
   180   "finite F \<or> finite G \<Longrightarrow> finite (F \<inter> G)"
   181   by (blast intro: finite_subset)
   182 
   183 lemma finite_Collect_conjI [simp, intro]:
   184   "finite {x. P x} \<or> finite {x. Q x} \<Longrightarrow> finite {x. P x \<and> Q x}"
   185   by (simp add: Collect_conj_eq)
   186 
   187 lemma finite_Collect_disjI [simp]:
   188   "finite {x. P x \<or> Q x} \<longleftrightarrow> finite {x. P x} \<and> finite {x. Q x}"
   189   by (simp add: Collect_disj_eq)
   190 
   191 lemma finite_Diff [simp, intro]:
   192   "finite A \<Longrightarrow> finite (A - B)"
   193   by (rule finite_subset, rule Diff_subset)
   194 
   195 lemma finite_Diff2 [simp]:
   196   assumes "finite B"
   197   shows "finite (A - B) \<longleftrightarrow> finite A"
   198 proof -
   199   have "finite A \<longleftrightarrow> finite((A - B) \<union> (A \<inter> B))" by (simp add: Un_Diff_Int)
   200   also have "\<dots> \<longleftrightarrow> finite (A - B)" using `finite B` by simp
   201   finally show ?thesis ..
   202 qed
   203 
   204 lemma finite_Diff_insert [iff]:
   205   "finite (A - insert a B) \<longleftrightarrow> finite (A - B)"
   206 proof -
   207   have "finite (A - B) \<longleftrightarrow> finite (A - B - {a})" by simp
   208   moreover have "A - insert a B = A - B - {a}" by auto
   209   ultimately show ?thesis by simp
   210 qed
   211 
   212 lemma finite_compl[simp]:
   213   "finite (A :: 'a set) \<Longrightarrow> finite (- A) \<longleftrightarrow> finite (UNIV :: 'a set)"
   214   by (simp add: Compl_eq_Diff_UNIV)
   215 
   216 lemma finite_Collect_not[simp]:
   217   "finite {x :: 'a. P x} \<Longrightarrow> finite {x. \<not> P x} \<longleftrightarrow> finite (UNIV :: 'a set)"
   218   by (simp add: Collect_neg_eq)
   219 
   220 lemma finite_Union [simp, intro]:
   221   "finite A \<Longrightarrow> (\<And>M. M \<in> A \<Longrightarrow> finite M) \<Longrightarrow> finite(\<Union>A)"
   222   by (induct rule: finite_induct) simp_all
   223 
   224 lemma finite_UN_I [intro]:
   225   "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> finite (B a)) \<Longrightarrow> finite (\<Union>a\<in>A. B a)"
   226   by (induct rule: finite_induct) simp_all
   227 
   228 lemma finite_UN [simp]:
   229   "finite A \<Longrightarrow> finite (UNION A B) \<longleftrightarrow> (\<forall>x\<in>A. finite (B x))"
   230   by (blast intro: finite_subset)
   231 
   232 lemma finite_Inter [intro]:
   233   "\<exists>A\<in>M. finite A \<Longrightarrow> finite (\<Inter>M)"
   234   by (blast intro: Inter_lower finite_subset)
   235 
   236 lemma finite_INT [intro]:
   237   "\<exists>x\<in>I. finite (A x) \<Longrightarrow> finite (\<Inter>x\<in>I. A x)"
   238   by (blast intro: INT_lower finite_subset)
   239 
   240 lemma finite_imageI [simp, intro]:
   241   "finite F \<Longrightarrow> finite (h ` F)"
   242   by (induct rule: finite_induct) simp_all
   243 
   244 lemma finite_image_set [simp]:
   245   "finite {x. P x} \<Longrightarrow> finite { f x | x. P x }"
   246   by (simp add: image_Collect [symmetric])
   247 
   248 lemma finite_imageD:
   249   assumes "finite (f ` A)" and "inj_on f A"
   250   shows "finite A"
   251 using assms proof (induct "f ` A" arbitrary: A)
   252   case empty then show ?case by simp
   253 next
   254   case (insert x B)
   255   then have B_A: "insert x B = f ` A" by simp
   256   then obtain y where "x = f y" and "y \<in> A" by blast
   257   from B_A `x \<notin> B` have "B = f ` A - {x}" by blast
   258   with B_A `x \<notin> B` `x = f y` `inj_on f A` `y \<in> A` have "B = f ` (A - {y})" by (simp add: inj_on_image_set_diff)
   259   moreover from `inj_on f A` have "inj_on f (A - {y})" by (rule inj_on_diff)
   260   ultimately have "finite (A - {y})" by (rule insert.hyps)
   261   then show "finite A" by simp
   262 qed
   263 
   264 lemma finite_surj:
   265   "finite A \<Longrightarrow> B \<subseteq> f ` A \<Longrightarrow> finite B"
   266   by (erule finite_subset) (rule finite_imageI)
   267 
   268 lemma finite_range_imageI:
   269   "finite (range g) \<Longrightarrow> finite (range (\<lambda>x. f (g x)))"
   270   by (drule finite_imageI) (simp add: range_composition)
   271 
   272 lemma finite_subset_image:
   273   assumes "finite B"
   274   shows "B \<subseteq> f ` A \<Longrightarrow> \<exists>C\<subseteq>A. finite C \<and> B = f ` C"
   275 using assms proof induct
   276   case empty then show ?case by simp
   277 next
   278   case insert then show ?case
   279     by (clarsimp simp del: image_insert simp add: image_insert [symmetric])
   280        blast
   281 qed
   282 
   283 lemma finite_vimage_IntI:
   284   "finite F \<Longrightarrow> inj_on h A \<Longrightarrow> finite (h -` F \<inter> A)"
   285   apply (induct rule: finite_induct)
   286    apply simp_all
   287   apply (subst vimage_insert)
   288   apply (simp add: finite_subset [OF inj_on_vimage_singleton] Int_Un_distrib2)
   289   done
   290 
   291 lemma finite_vimageI:
   292   "finite F \<Longrightarrow> inj h \<Longrightarrow> finite (h -` F)"
   293   using finite_vimage_IntI[of F h UNIV] by auto
   294 
   295 lemma finite_vimageD:
   296   assumes fin: "finite (h -` F)" and surj: "surj h"
   297   shows "finite F"
   298 proof -
   299   have "finite (h ` (h -` F))" using fin by (rule finite_imageI)
   300   also have "h ` (h -` F) = F" using surj by (rule surj_image_vimage_eq)
   301   finally show "finite F" .
   302 qed
   303 
   304 lemma finite_vimage_iff: "bij h \<Longrightarrow> finite (h -` F) \<longleftrightarrow> finite F"
   305   unfolding bij_def by (auto elim: finite_vimageD finite_vimageI)
   306 
   307 lemma finite_Collect_bex [simp]:
   308   assumes "finite A"
   309   shows "finite {x. \<exists>y\<in>A. Q x y} \<longleftrightarrow> (\<forall>y\<in>A. finite {x. Q x y})"
   310 proof -
   311   have "{x. \<exists>y\<in>A. Q x y} = (\<Union>y\<in>A. {x. Q x y})" by auto
   312   with assms show ?thesis by simp
   313 qed
   314 
   315 lemma finite_Collect_bounded_ex [simp]:
   316   assumes "finite {y. P y}"
   317   shows "finite {x. \<exists>y. P y \<and> Q x y} \<longleftrightarrow> (\<forall>y. P y \<longrightarrow> finite {x. Q x y})"
   318 proof -
   319   have "{x. EX y. P y & Q x y} = (\<Union>y\<in>{y. P y}. {x. Q x y})" by auto
   320   with assms show ?thesis by simp
   321 qed
   322 
   323 lemma finite_Plus:
   324   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A <+> B)"
   325   by (simp add: Plus_def)
   326 
   327 lemma finite_PlusD: 
   328   fixes A :: "'a set" and B :: "'b set"
   329   assumes fin: "finite (A <+> B)"
   330   shows "finite A" "finite B"
   331 proof -
   332   have "Inl ` A \<subseteq> A <+> B" by auto
   333   then have "finite (Inl ` A :: ('a + 'b) set)" using fin by (rule finite_subset)
   334   then show "finite A" by (rule finite_imageD) (auto intro: inj_onI)
   335 next
   336   have "Inr ` B \<subseteq> A <+> B" by auto
   337   then have "finite (Inr ` B :: ('a + 'b) set)" using fin by (rule finite_subset)
   338   then show "finite B" by (rule finite_imageD) (auto intro: inj_onI)
   339 qed
   340 
   341 lemma finite_Plus_iff [simp]:
   342   "finite (A <+> B) \<longleftrightarrow> finite A \<and> finite B"
   343   by (auto intro: finite_PlusD finite_Plus)
   344 
   345 lemma finite_Plus_UNIV_iff [simp]:
   346   "finite (UNIV :: ('a + 'b) set) \<longleftrightarrow> finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set)"
   347   by (subst UNIV_Plus_UNIV [symmetric]) (rule finite_Plus_iff)
   348 
   349 lemma finite_SigmaI [simp, intro]:
   350   "finite A \<Longrightarrow> (\<And>a. a\<in>A \<Longrightarrow> finite (B a)) ==> finite (SIGMA a:A. B a)"
   351   by (unfold Sigma_def) blast
   352 
   353 lemma finite_cartesian_product:
   354   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A \<times> B)"
   355   by (rule finite_SigmaI)
   356 
   357 lemma finite_Prod_UNIV:
   358   "finite (UNIV :: 'a set) \<Longrightarrow> finite (UNIV :: 'b set) \<Longrightarrow> finite (UNIV :: ('a \<times> 'b) set)"
   359   by (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product)
   360 
   361 lemma finite_cartesian_productD1:
   362   assumes "finite (A \<times> B)" and "B \<noteq> {}"
   363   shows "finite A"
   364 proof -
   365   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   366     by (auto simp add: finite_conv_nat_seg_image)
   367   then have "fst ` (A \<times> B) = fst ` f ` {i::nat. i < n}" by simp
   368   with `B \<noteq> {}` have "A = (fst \<circ> f) ` {i::nat. i < n}"
   369     by (simp add: image_compose)
   370   then have "\<exists>n f. A = f ` {i::nat. i < n}" by blast
   371   then show ?thesis
   372     by (auto simp add: finite_conv_nat_seg_image)
   373 qed
   374 
   375 lemma finite_cartesian_productD2:
   376   assumes "finite (A \<times> B)" and "A \<noteq> {}"
   377   shows "finite B"
   378 proof -
   379   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   380     by (auto simp add: finite_conv_nat_seg_image)
   381   then have "snd ` (A \<times> B) = snd ` f ` {i::nat. i < n}" by simp
   382   with `A \<noteq> {}` have "B = (snd \<circ> f) ` {i::nat. i < n}"
   383     by (simp add: image_compose)
   384   then have "\<exists>n f. B = f ` {i::nat. i < n}" by blast
   385   then show ?thesis
   386     by (auto simp add: finite_conv_nat_seg_image)
   387 qed
   388 
   389 lemma finite_Pow_iff [iff]:
   390   "finite (Pow A) \<longleftrightarrow> finite A"
   391 proof
   392   assume "finite (Pow A)"
   393   then have "finite ((%x. {x}) ` A)" by (blast intro: finite_subset)
   394   then show "finite A" by (rule finite_imageD [unfolded inj_on_def]) simp
   395 next
   396   assume "finite A"
   397   then show "finite (Pow A)"
   398     by induct (simp_all add: Pow_insert)
   399 qed
   400 
   401 corollary finite_Collect_subsets [simp, intro]:
   402   "finite A \<Longrightarrow> finite {B. B \<subseteq> A}"
   403   by (simp add: Pow_def [symmetric])
   404 
   405 lemma finite_UnionD: "finite(\<Union>A) \<Longrightarrow> finite A"
   406   by (blast intro: finite_subset [OF subset_Pow_Union])
   407 
   408 
   409 subsubsection {* Further induction rules on finite sets *}
   410 
   411 lemma finite_ne_induct [case_names singleton insert, consumes 2]:
   412   assumes "finite F" and "F \<noteq> {}"
   413   assumes "\<And>x. P {x}"
   414     and "\<And>x F. finite F \<Longrightarrow> F \<noteq> {} \<Longrightarrow> x \<notin> F \<Longrightarrow> P F  \<Longrightarrow> P (insert x F)"
   415   shows "P F"
   416 using assms proof induct
   417   case empty then show ?case by simp
   418 next
   419   case (insert x F) then show ?case by cases auto
   420 qed
   421 
   422 lemma finite_subset_induct [consumes 2, case_names empty insert]:
   423   assumes "finite F" and "F \<subseteq> A"
   424   assumes empty: "P {}"
   425     and insert: "\<And>a F. finite F \<Longrightarrow> a \<in> A \<Longrightarrow> a \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert a F)"
   426   shows "P F"
   427 using `finite F` `F \<subseteq> A` proof induct
   428   show "P {}" by fact
   429 next
   430   fix x F
   431   assume "finite F" and "x \<notin> F" and
   432     P: "F \<subseteq> A \<Longrightarrow> P F" and i: "insert x F \<subseteq> A"
   433   show "P (insert x F)"
   434   proof (rule insert)
   435     from i show "x \<in> A" by blast
   436     from i have "F \<subseteq> A" by blast
   437     with P show "P F" .
   438     show "finite F" by fact
   439     show "x \<notin> F" by fact
   440   qed
   441 qed
   442 
   443 lemma finite_empty_induct:
   444   assumes "finite A"
   445   assumes "P A"
   446     and remove: "\<And>a A. finite A \<Longrightarrow> a \<in> A \<Longrightarrow> P A \<Longrightarrow> P (A - {a})"
   447   shows "P {}"
   448 proof -
   449   have "\<And>B. B \<subseteq> A \<Longrightarrow> P (A - B)"
   450   proof -
   451     fix B :: "'a set"
   452     assume "B \<subseteq> A"
   453     with `finite A` have "finite B" by (rule rev_finite_subset)
   454     from this `B \<subseteq> A` show "P (A - B)"
   455     proof induct
   456       case empty
   457       from `P A` show ?case by simp
   458     next
   459       case (insert b B)
   460       have "P (A - B - {b})"
   461       proof (rule remove)
   462         from `finite A` show "finite (A - B)" by induct auto
   463         from insert show "b \<in> A - B" by simp
   464         from insert show "P (A - B)" by simp
   465       qed
   466       also have "A - B - {b} = A - insert b B" by (rule Diff_insert [symmetric])
   467       finally show ?case .
   468     qed
   469   qed
   470   then have "P (A - A)" by blast
   471   then show ?thesis by simp
   472 qed
   473 
   474 
   475 subsection {* Class @{text finite}  *}
   476 
   477 class finite =
   478   assumes finite_UNIV: "finite (UNIV \<Colon> 'a set)"
   479 begin
   480 
   481 lemma finite [simp]: "finite (A \<Colon> 'a set)"
   482   by (rule subset_UNIV finite_UNIV finite_subset)+
   483 
   484 lemma finite_code [code]: "finite (A \<Colon> 'a set) \<longleftrightarrow> True"
   485   by simp
   486 
   487 end
   488 
   489 instance unit :: finite proof
   490 qed (simp add: UNIV_unit)
   491 
   492 instance bool :: finite proof
   493 qed (simp add: UNIV_bool)
   494 
   495 instance prod :: (finite, finite) finite proof
   496 qed (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product finite)
   497 
   498 lemma finite_option_UNIV [simp]:
   499   "finite (UNIV :: 'a option set) = finite (UNIV :: 'a set)"
   500   by (auto simp add: UNIV_option_conv elim: finite_imageD intro: inj_Some)
   501 
   502 instance option :: (finite) finite proof
   503 qed (simp add: UNIV_option_conv)
   504 
   505 lemma inj_graph: "inj (%f. {(x, y). y = f x})"
   506   by (rule inj_onI, auto simp add: set_eq_iff fun_eq_iff)
   507 
   508 instance "fun" :: (finite, finite) finite
   509 proof
   510   show "finite (UNIV :: ('a => 'b) set)"
   511   proof (rule finite_imageD)
   512     let ?graph = "%f::'a => 'b. {(x, y). y = f x}"
   513     have "range ?graph \<subseteq> Pow UNIV" by simp
   514     moreover have "finite (Pow (UNIV :: ('a * 'b) set))"
   515       by (simp only: finite_Pow_iff finite)
   516     ultimately show "finite (range ?graph)"
   517       by (rule finite_subset)
   518     show "inj ?graph" by (rule inj_graph)
   519   qed
   520 qed
   521 
   522 instance sum :: (finite, finite) finite proof
   523 qed (simp only: UNIV_Plus_UNIV [symmetric] finite_Plus finite)
   524 
   525 
   526 subsection {* A basic fold functional for finite sets *}
   527 
   528 text {* The intended behaviour is
   529 @{text "fold f z {x\<^isub>1, ..., x\<^isub>n} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
   530 if @{text f} is ``left-commutative'':
   531 *}
   532 
   533 locale comp_fun_commute =
   534   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
   535   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
   536 begin
   537 
   538 lemma fun_left_comm: "f x (f y z) = f y (f x z)"
   539   using comp_fun_commute by (simp add: fun_eq_iff)
   540 
   541 end
   542 
   543 inductive fold_graph :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> bool"
   544 for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" and z :: 'b where
   545   emptyI [intro]: "fold_graph f z {} z" |
   546   insertI [intro]: "x \<notin> A \<Longrightarrow> fold_graph f z A y
   547       \<Longrightarrow> fold_graph f z (insert x A) (f x y)"
   548 
   549 inductive_cases empty_fold_graphE [elim!]: "fold_graph f z {} x"
   550 
   551 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b" where
   552   "fold f z A = (THE y. fold_graph f z A y)"
   553 
   554 text{*A tempting alternative for the definiens is
   555 @{term "if finite A then THE y. fold_graph f z A y else e"}.
   556 It allows the removal of finiteness assumptions from the theorems
   557 @{text fold_comm}, @{text fold_reindex} and @{text fold_distrib}.
   558 The proofs become ugly. It is not worth the effort. (???) *}
   559 
   560 lemma finite_imp_fold_graph: "finite A \<Longrightarrow> \<exists>x. fold_graph f z A x"
   561 by (induct rule: finite_induct) auto
   562 
   563 
   564 subsubsection{*From @{const fold_graph} to @{term fold}*}
   565 
   566 context comp_fun_commute
   567 begin
   568 
   569 lemma fold_graph_insertE_aux:
   570   "fold_graph f z A y \<Longrightarrow> a \<in> A \<Longrightarrow> \<exists>y'. y = f a y' \<and> fold_graph f z (A - {a}) y'"
   571 proof (induct set: fold_graph)
   572   case (insertI x A y) show ?case
   573   proof (cases "x = a")
   574     assume "x = a" with insertI show ?case by auto
   575   next
   576     assume "x \<noteq> a"
   577     then obtain y' where y: "y = f a y'" and y': "fold_graph f z (A - {a}) y'"
   578       using insertI by auto
   579     have "f x y = f a (f x y')"
   580       unfolding y by (rule fun_left_comm)
   581     moreover have "fold_graph f z (insert x A - {a}) (f x y')"
   582       using y' and `x \<noteq> a` and `x \<notin> A`
   583       by (simp add: insert_Diff_if fold_graph.insertI)
   584     ultimately show ?case by fast
   585   qed
   586 qed simp
   587 
   588 lemma fold_graph_insertE:
   589   assumes "fold_graph f z (insert x A) v" and "x \<notin> A"
   590   obtains y where "v = f x y" and "fold_graph f z A y"
   591 using assms by (auto dest: fold_graph_insertE_aux [OF _ insertI1])
   592 
   593 lemma fold_graph_determ:
   594   "fold_graph f z A x \<Longrightarrow> fold_graph f z A y \<Longrightarrow> y = x"
   595 proof (induct arbitrary: y set: fold_graph)
   596   case (insertI x A y v)
   597   from `fold_graph f z (insert x A) v` and `x \<notin> A`
   598   obtain y' where "v = f x y'" and "fold_graph f z A y'"
   599     by (rule fold_graph_insertE)
   600   from `fold_graph f z A y'` have "y' = y" by (rule insertI)
   601   with `v = f x y'` show "v = f x y" by simp
   602 qed fast
   603 
   604 lemma fold_equality:
   605   "fold_graph f z A y \<Longrightarrow> fold f z A = y"
   606 by (unfold fold_def) (blast intro: fold_graph_determ)
   607 
   608 lemma fold_graph_fold:
   609   assumes "finite A"
   610   shows "fold_graph f z A (fold f z A)"
   611 proof -
   612   from assms have "\<exists>x. fold_graph f z A x" by (rule finite_imp_fold_graph)
   613   moreover note fold_graph_determ
   614   ultimately have "\<exists>!x. fold_graph f z A x" by (rule ex_ex1I)
   615   then have "fold_graph f z A (The (fold_graph f z A))" by (rule theI')
   616   then show ?thesis by (unfold fold_def)
   617 qed
   618 
   619 text{* The base case for @{text fold}: *}
   620 
   621 lemma (in -) fold_empty [simp]: "fold f z {} = z"
   622 by (unfold fold_def) blast
   623 
   624 text{* The various recursion equations for @{const fold}: *}
   625 
   626 lemma fold_insert [simp]:
   627   assumes "finite A" and "x \<notin> A"
   628   shows "fold f z (insert x A) = f x (fold f z A)"
   629 proof (rule fold_equality)
   630   from `finite A` have "fold_graph f z A (fold f z A)" by (rule fold_graph_fold)
   631   with `x \<notin> A`show "fold_graph f z (insert x A) (f x (fold f z A))" by (rule fold_graph.insertI)
   632 qed
   633 
   634 lemma fold_fun_comm:
   635   "finite A \<Longrightarrow> f x (fold f z A) = fold f (f x z) A"
   636 proof (induct rule: finite_induct)
   637   case empty then show ?case by simp
   638 next
   639   case (insert y A) then show ?case
   640     by (simp add: fun_left_comm[of x])
   641 qed
   642 
   643 lemma fold_insert2:
   644   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   645 by (simp add: fold_fun_comm)
   646 
   647 lemma fold_rec:
   648   assumes "finite A" and "x \<in> A"
   649   shows "fold f z A = f x (fold f z (A - {x}))"
   650 proof -
   651   have A: "A = insert x (A - {x})" using `x \<in> A` by blast
   652   then have "fold f z A = fold f z (insert x (A - {x}))" by simp
   653   also have "\<dots> = f x (fold f z (A - {x}))"
   654     by (rule fold_insert) (simp add: `finite A`)+
   655   finally show ?thesis .
   656 qed
   657 
   658 lemma fold_insert_remove:
   659   assumes "finite A"
   660   shows "fold f z (insert x A) = f x (fold f z (A - {x}))"
   661 proof -
   662   from `finite A` have "finite (insert x A)" by auto
   663   moreover have "x \<in> insert x A" by auto
   664   ultimately have "fold f z (insert x A) = f x (fold f z (insert x A - {x}))"
   665     by (rule fold_rec)
   666   then show ?thesis by simp
   667 qed
   668 
   669 end
   670 
   671 text{* A simplified version for idempotent functions: *}
   672 
   673 locale comp_fun_idem = comp_fun_commute +
   674   assumes comp_fun_idem: "f x o f x = f x"
   675 begin
   676 
   677 lemma fun_left_idem: "f x (f x z) = f x z"
   678   using comp_fun_idem by (simp add: fun_eq_iff)
   679 
   680 lemma fold_insert_idem:
   681   assumes fin: "finite A"
   682   shows "fold f z (insert x A) = f x (fold f z A)"
   683 proof cases
   684   assume "x \<in> A"
   685   then obtain B where "A = insert x B" and "x \<notin> B" by (rule set_insert)
   686   then show ?thesis using assms by (simp add:fun_left_idem)
   687 next
   688   assume "x \<notin> A" then show ?thesis using assms by simp
   689 qed
   690 
   691 declare fold_insert[simp del] fold_insert_idem[simp]
   692 
   693 lemma fold_insert_idem2:
   694   "finite A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   695 by(simp add:fold_fun_comm)
   696 
   697 end
   698 
   699 
   700 subsubsection {* Expressing set operations via @{const fold} *}
   701 
   702 lemma (in comp_fun_commute) comp_comp_fun_commute:
   703   "comp_fun_commute (f \<circ> g)"
   704 proof
   705 qed (simp_all add: comp_fun_commute)
   706 
   707 lemma (in comp_fun_idem) comp_comp_fun_idem:
   708   "comp_fun_idem (f \<circ> g)"
   709   by (rule comp_fun_idem.intro, rule comp_comp_fun_commute, unfold_locales)
   710     (simp_all add: comp_fun_idem)
   711 
   712 lemma comp_fun_idem_insert:
   713   "comp_fun_idem insert"
   714 proof
   715 qed auto
   716 
   717 lemma comp_fun_idem_remove:
   718   "comp_fun_idem (\<lambda>x A. A - {x})"
   719 proof
   720 qed auto
   721 
   722 lemma (in semilattice_inf) comp_fun_idem_inf:
   723   "comp_fun_idem inf"
   724 proof
   725 qed (auto simp add: inf_left_commute)
   726 
   727 lemma (in semilattice_sup) comp_fun_idem_sup:
   728   "comp_fun_idem sup"
   729 proof
   730 qed (auto simp add: sup_left_commute)
   731 
   732 lemma union_fold_insert:
   733   assumes "finite A"
   734   shows "A \<union> B = fold insert B A"
   735 proof -
   736   interpret comp_fun_idem insert by (fact comp_fun_idem_insert)
   737   from `finite A` show ?thesis by (induct A arbitrary: B) simp_all
   738 qed
   739 
   740 lemma minus_fold_remove:
   741   assumes "finite A"
   742   shows "B - A = fold (\<lambda>x A. A - {x}) B A"
   743 proof -
   744   interpret comp_fun_idem "\<lambda>x A. A - {x}" by (fact comp_fun_idem_remove)
   745   from `finite A` show ?thesis by (induct A arbitrary: B) auto
   746 qed
   747 
   748 context complete_lattice
   749 begin
   750 
   751 lemma inf_Inf_fold_inf:
   752   assumes "finite A"
   753   shows "inf B (Inf A) = fold inf B A"
   754 proof -
   755   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   756   from `finite A` show ?thesis by (induct A arbitrary: B)
   757     (simp_all add: Inf_insert inf_commute fold_fun_comm)
   758 qed
   759 
   760 lemma sup_Sup_fold_sup:
   761   assumes "finite A"
   762   shows "sup B (Sup A) = fold sup B A"
   763 proof -
   764   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   765   from `finite A` show ?thesis by (induct A arbitrary: B)
   766     (simp_all add: Sup_insert sup_commute fold_fun_comm)
   767 qed
   768 
   769 lemma Inf_fold_inf:
   770   assumes "finite A"
   771   shows "Inf A = fold inf top A"
   772   using assms inf_Inf_fold_inf [of A top] by (simp add: inf_absorb2)
   773 
   774 lemma Sup_fold_sup:
   775   assumes "finite A"
   776   shows "Sup A = fold sup bot A"
   777   using assms sup_Sup_fold_sup [of A bot] by (simp add: sup_absorb2)
   778 
   779 lemma inf_INFI_fold_inf:
   780   assumes "finite A"
   781   shows "inf B (INFI A f) = fold (inf \<circ> f) B A" (is "?inf = ?fold") 
   782 proof (rule sym)
   783   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   784   interpret comp_fun_idem "inf \<circ> f" by (fact comp_comp_fun_idem)
   785   from `finite A` show "?fold = ?inf"
   786     by (induct A arbitrary: B)
   787       (simp_all add: INFI_def Inf_insert inf_left_commute)
   788 qed
   789 
   790 lemma sup_SUPR_fold_sup:
   791   assumes "finite A"
   792   shows "sup B (SUPR A f) = fold (sup \<circ> f) B A" (is "?sup = ?fold") 
   793 proof (rule sym)
   794   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   795   interpret comp_fun_idem "sup \<circ> f" by (fact comp_comp_fun_idem)
   796   from `finite A` show "?fold = ?sup"
   797     by (induct A arbitrary: B)
   798       (simp_all add: SUPR_def Sup_insert sup_left_commute)
   799 qed
   800 
   801 lemma INFI_fold_inf:
   802   assumes "finite A"
   803   shows "INFI A f = fold (inf \<circ> f) top A"
   804   using assms inf_INFI_fold_inf [of A top] by simp
   805 
   806 lemma SUPR_fold_sup:
   807   assumes "finite A"
   808   shows "SUPR A f = fold (sup \<circ> f) bot A"
   809   using assms sup_SUPR_fold_sup [of A bot] by simp
   810 
   811 end
   812 
   813 
   814 subsection {* The derived combinator @{text fold_image} *}
   815 
   816 definition fold_image :: "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b"
   817   where "fold_image f g = fold (\<lambda>x y. f (g x) y)"
   818 
   819 lemma fold_image_empty[simp]: "fold_image f g z {} = z"
   820   by (simp add:fold_image_def)
   821 
   822 context ab_semigroup_mult
   823 begin
   824 
   825 lemma fold_image_insert[simp]:
   826   assumes "finite A" and "a \<notin> A"
   827   shows "fold_image times g z (insert a A) = g a * (fold_image times g z A)"
   828 proof -
   829   interpret comp_fun_commute "%x y. (g x) * y" proof
   830   qed (simp add: fun_eq_iff mult_ac)
   831   show ?thesis using assms by (simp add: fold_image_def)
   832 qed
   833 
   834 lemma fold_image_reindex:
   835   assumes "finite A"
   836   shows "inj_on h A \<Longrightarrow> fold_image times g z (h ` A) = fold_image times (g \<circ> h) z A"
   837   using assms by induct auto
   838 
   839 lemma fold_image_cong:
   840   assumes "finite A" and g_h: "\<And>x. x\<in>A \<Longrightarrow> g x = h x"
   841   shows "fold_image times g z A = fold_image times h z A"
   842 proof -
   843   from `finite A`
   844   have "\<And>C. C <= A --> (ALL x:C. g x = h x) --> fold_image times g z C = fold_image times h z C"
   845   proof (induct arbitrary: C)
   846     case empty then show ?case by simp
   847   next
   848     case (insert x F) then show ?case apply -
   849     apply (simp add: subset_insert_iff, clarify)
   850     apply (subgoal_tac "finite C")
   851       prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
   852     apply (subgoal_tac "C = insert x (C - {x})")
   853       prefer 2 apply blast
   854     apply (erule ssubst)
   855     apply (simp add: Ball_def del: insert_Diff_single)
   856     done
   857   qed
   858   with g_h show ?thesis by simp
   859 qed
   860 
   861 end
   862 
   863 context comm_monoid_mult
   864 begin
   865 
   866 lemma fold_image_1:
   867   "finite S \<Longrightarrow> (\<forall>x\<in>S. f x = 1) \<Longrightarrow> fold_image op * f 1 S = 1"
   868   apply (induct rule: finite_induct)
   869   apply simp by auto
   870 
   871 lemma fold_image_Un_Int:
   872   "finite A ==> finite B ==>
   873     fold_image times g 1 A * fold_image times g 1 B =
   874     fold_image times g 1 (A Un B) * fold_image times g 1 (A Int B)"
   875   apply (induct rule: finite_induct)
   876 by (induct set: finite) 
   877    (auto simp add: mult_ac insert_absorb Int_insert_left)
   878 
   879 lemma fold_image_Un_one:
   880   assumes fS: "finite S" and fT: "finite T"
   881   and I0: "\<forall>x \<in> S\<inter>T. f x = 1"
   882   shows "fold_image (op *) f 1 (S \<union> T) = fold_image (op *) f 1 S * fold_image (op *) f 1 T"
   883 proof-
   884   have "fold_image op * f 1 (S \<inter> T) = 1" 
   885     apply (rule fold_image_1)
   886     using fS fT I0 by auto 
   887   with fold_image_Un_Int[OF fS fT] show ?thesis by simp
   888 qed
   889 
   890 corollary fold_Un_disjoint:
   891   "finite A ==> finite B ==> A Int B = {} ==>
   892    fold_image times g 1 (A Un B) =
   893    fold_image times g 1 A * fold_image times g 1 B"
   894 by (simp add: fold_image_Un_Int)
   895 
   896 lemma fold_image_UN_disjoint:
   897   "\<lbrakk> finite I; ALL i:I. finite (A i);
   898      ALL i:I. ALL j:I. i \<noteq> j --> A i Int A j = {} \<rbrakk>
   899    \<Longrightarrow> fold_image times g 1 (UNION I A) =
   900        fold_image times (%i. fold_image times g 1 (A i)) 1 I"
   901 apply (induct rule: finite_induct)
   902 apply simp
   903 apply atomize
   904 apply (subgoal_tac "ALL i:F. x \<noteq> i")
   905  prefer 2 apply blast
   906 apply (subgoal_tac "A x Int UNION F A = {}")
   907  prefer 2 apply blast
   908 apply (simp add: fold_Un_disjoint)
   909 done
   910 
   911 lemma fold_image_Sigma: "finite A ==> ALL x:A. finite (B x) ==>
   912   fold_image times (%x. fold_image times (g x) 1 (B x)) 1 A =
   913   fold_image times (split g) 1 (SIGMA x:A. B x)"
   914 apply (subst Sigma_def)
   915 apply (subst fold_image_UN_disjoint, assumption, simp)
   916  apply blast
   917 apply (erule fold_image_cong)
   918 apply (subst fold_image_UN_disjoint, simp, simp)
   919  apply blast
   920 apply simp
   921 done
   922 
   923 lemma fold_image_distrib: "finite A \<Longrightarrow>
   924    fold_image times (%x. g x * h x) 1 A =
   925    fold_image times g 1 A *  fold_image times h 1 A"
   926 by (erule finite_induct) (simp_all add: mult_ac)
   927 
   928 lemma fold_image_related: 
   929   assumes Re: "R e e" 
   930   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
   931   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
   932   shows "R (fold_image (op *) h e S) (fold_image (op *) g e S)"
   933   using fS by (rule finite_subset_induct) (insert assms, auto)
   934 
   935 lemma  fold_image_eq_general:
   936   assumes fS: "finite S"
   937   and h: "\<forall>y\<in>S'. \<exists>!x. x\<in> S \<and> h(x) = y" 
   938   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2(h x) = f1 x"
   939   shows "fold_image (op *) f1 e S = fold_image (op *) f2 e S'"
   940 proof-
   941   from h f12 have hS: "h ` S = S'" by auto
   942   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
   943     from f12 h H  have "x = y" by auto }
   944   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
   945   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
   946   from hS have "fold_image (op *) f2 e S' = fold_image (op *) f2 e (h ` S)" by simp
   947   also have "\<dots> = fold_image (op *) (f2 o h) e S" 
   948     using fold_image_reindex[OF fS hinj, of f2 e] .
   949   also have "\<dots> = fold_image (op *) f1 e S " using th fold_image_cong[OF fS, of "f2 o h" f1 e]
   950     by blast
   951   finally show ?thesis ..
   952 qed
   953 
   954 lemma fold_image_eq_general_inverses:
   955   assumes fS: "finite S" 
   956   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
   957   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x  \<and> g (h x) = f x"
   958   shows "fold_image (op *) f e S = fold_image (op *) g e T"
   959   (* metis solves it, but not yet available here *)
   960   apply (rule fold_image_eq_general[OF fS, of T h g f e])
   961   apply (rule ballI)
   962   apply (frule kh)
   963   apply (rule ex1I[])
   964   apply blast
   965   apply clarsimp
   966   apply (drule hk) apply simp
   967   apply (rule sym)
   968   apply (erule conjunct1[OF conjunct2[OF hk]])
   969   apply (rule ballI)
   970   apply (drule  hk)
   971   apply blast
   972   done
   973 
   974 end
   975 
   976 
   977 subsection {* A fold functional for non-empty sets *}
   978 
   979 text{* Does not require start value. *}
   980 
   981 inductive
   982   fold1Set :: "('a => 'a => 'a) => 'a set => 'a => bool"
   983   for f :: "'a => 'a => 'a"
   984 where
   985   fold1Set_insertI [intro]:
   986    "\<lbrakk> fold_graph f a A x; a \<notin> A \<rbrakk> \<Longrightarrow> fold1Set f (insert a A) x"
   987 
   988 definition fold1 :: "('a => 'a => 'a) => 'a set => 'a" where
   989   "fold1 f A == THE x. fold1Set f A x"
   990 
   991 lemma fold1Set_nonempty:
   992   "fold1Set f A x \<Longrightarrow> A \<noteq> {}"
   993 by(erule fold1Set.cases, simp_all)
   994 
   995 inductive_cases empty_fold1SetE [elim!]: "fold1Set f {} x"
   996 
   997 inductive_cases insert_fold1SetE [elim!]: "fold1Set f (insert a X) x"
   998 
   999 
  1000 lemma fold1Set_sing [iff]: "(fold1Set f {a} b) = (a = b)"
  1001 by (blast elim: fold_graph.cases)
  1002 
  1003 lemma fold1_singleton [simp]: "fold1 f {a} = a"
  1004 by (unfold fold1_def) blast
  1005 
  1006 lemma finite_nonempty_imp_fold1Set:
  1007   "\<lbrakk> finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> EX x. fold1Set f A x"
  1008 apply (induct A rule: finite_induct)
  1009 apply (auto dest: finite_imp_fold_graph [of _ f])
  1010 done
  1011 
  1012 text{*First, some lemmas about @{const fold_graph}.*}
  1013 
  1014 context ab_semigroup_mult
  1015 begin
  1016 
  1017 lemma comp_fun_commute: "comp_fun_commute (op *)" proof
  1018 qed (simp add: fun_eq_iff mult_ac)
  1019 
  1020 lemma fold_graph_insert_swap:
  1021 assumes fold: "fold_graph times (b::'a) A y" and "b \<notin> A"
  1022 shows "fold_graph times z (insert b A) (z * y)"
  1023 proof -
  1024   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1025 from assms show ?thesis
  1026 proof (induct rule: fold_graph.induct)
  1027   case emptyI show ?case by (subst mult_commute [of z b], fast)
  1028 next
  1029   case (insertI x A y)
  1030     have "fold_graph times z (insert x (insert b A)) (x * (z * y))"
  1031       using insertI by force  --{*how does @{term id} get unfolded?*}
  1032     thus ?case by (simp add: insert_commute mult_ac)
  1033 qed
  1034 qed
  1035 
  1036 lemma fold_graph_permute_diff:
  1037 assumes fold: "fold_graph times b A x"
  1038 shows "!!a. \<lbrakk>a \<in> A; b \<notin> A\<rbrakk> \<Longrightarrow> fold_graph times a (insert b (A-{a})) x"
  1039 using fold
  1040 proof (induct rule: fold_graph.induct)
  1041   case emptyI thus ?case by simp
  1042 next
  1043   case (insertI x A y)
  1044   have "a = x \<or> a \<in> A" using insertI by simp
  1045   thus ?case
  1046   proof
  1047     assume "a = x"
  1048     with insertI show ?thesis
  1049       by (simp add: id_def [symmetric], blast intro: fold_graph_insert_swap)
  1050   next
  1051     assume ainA: "a \<in> A"
  1052     hence "fold_graph times a (insert x (insert b (A - {a}))) (x * y)"
  1053       using insertI by force
  1054     moreover
  1055     have "insert x (insert b (A - {a})) = insert b (insert x A - {a})"
  1056       using ainA insertI by blast
  1057     ultimately show ?thesis by simp
  1058   qed
  1059 qed
  1060 
  1061 lemma fold1_eq_fold:
  1062 assumes "finite A" "a \<notin> A" shows "fold1 times (insert a A) = fold times a A"
  1063 proof -
  1064   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1065   from assms show ?thesis
  1066 apply (simp add: fold1_def fold_def)
  1067 apply (rule the_equality)
  1068 apply (best intro: fold_graph_determ theI dest: finite_imp_fold_graph [of _ times])
  1069 apply (rule sym, clarify)
  1070 apply (case_tac "Aa=A")
  1071  apply (best intro: fold_graph_determ)
  1072 apply (subgoal_tac "fold_graph times a A x")
  1073  apply (best intro: fold_graph_determ)
  1074 apply (subgoal_tac "insert aa (Aa - {a}) = A")
  1075  prefer 2 apply (blast elim: equalityE)
  1076 apply (auto dest: fold_graph_permute_diff [where a=a])
  1077 done
  1078 qed
  1079 
  1080 lemma nonempty_iff: "(A \<noteq> {}) = (\<exists>x B. A = insert x B & x \<notin> B)"
  1081 apply safe
  1082  apply simp
  1083  apply (drule_tac x=x in spec)
  1084  apply (drule_tac x="A-{x}" in spec, auto)
  1085 done
  1086 
  1087 lemma fold1_insert:
  1088   assumes nonempty: "A \<noteq> {}" and A: "finite A" "x \<notin> A"
  1089   shows "fold1 times (insert x A) = x * fold1 times A"
  1090 proof -
  1091   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1092   from nonempty obtain a A' where "A = insert a A' & a ~: A'"
  1093     by (auto simp add: nonempty_iff)
  1094   with A show ?thesis
  1095     by (simp add: insert_commute [of x] fold1_eq_fold eq_commute)
  1096 qed
  1097 
  1098 end
  1099 
  1100 context ab_semigroup_idem_mult
  1101 begin
  1102 
  1103 lemma comp_fun_idem: "comp_fun_idem (op *)" proof
  1104 qed (simp_all add: fun_eq_iff mult_left_commute)
  1105 
  1106 lemma fold1_insert_idem [simp]:
  1107   assumes nonempty: "A \<noteq> {}" and A: "finite A" 
  1108   shows "fold1 times (insert x A) = x * fold1 times A"
  1109 proof -
  1110   interpret comp_fun_idem "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a"
  1111     by (rule comp_fun_idem)
  1112   from nonempty obtain a A' where A': "A = insert a A' & a ~: A'"
  1113     by (auto simp add: nonempty_iff)
  1114   show ?thesis
  1115   proof cases
  1116     assume a: "a = x"
  1117     show ?thesis
  1118     proof cases
  1119       assume "A' = {}"
  1120       with A' a show ?thesis by simp
  1121     next
  1122       assume "A' \<noteq> {}"
  1123       with A A' a show ?thesis
  1124         by (simp add: fold1_insert mult_assoc [symmetric])
  1125     qed
  1126   next
  1127     assume "a \<noteq> x"
  1128     with A A' show ?thesis
  1129       by (simp add: insert_commute fold1_eq_fold)
  1130   qed
  1131 qed
  1132 
  1133 lemma hom_fold1_commute:
  1134 assumes hom: "!!x y. h (x * y) = h x * h y"
  1135 and N: "finite N" "N \<noteq> {}" shows "h (fold1 times N) = fold1 times (h ` N)"
  1136 using N proof (induct rule: finite_ne_induct)
  1137   case singleton thus ?case by simp
  1138 next
  1139   case (insert n N)
  1140   then have "h (fold1 times (insert n N)) = h (n * fold1 times N)" by simp
  1141   also have "\<dots> = h n * h (fold1 times N)" by(rule hom)
  1142   also have "h (fold1 times N) = fold1 times (h ` N)" by(rule insert)
  1143   also have "times (h n) \<dots> = fold1 times (insert (h n) (h ` N))"
  1144     using insert by(simp)
  1145   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1146   finally show ?case .
  1147 qed
  1148 
  1149 lemma fold1_eq_fold_idem:
  1150   assumes "finite A"
  1151   shows "fold1 times (insert a A) = fold times a A"
  1152 proof (cases "a \<in> A")
  1153   case False
  1154   with assms show ?thesis by (simp add: fold1_eq_fold)
  1155 next
  1156   interpret comp_fun_idem times by (fact comp_fun_idem)
  1157   case True then obtain b B
  1158     where A: "A = insert a B" and "a \<notin> B" by (rule set_insert)
  1159   with assms have "finite B" by auto
  1160   then have "fold times a (insert a B) = fold times (a * a) B"
  1161     using `a \<notin> B` by (rule fold_insert2)
  1162   then show ?thesis
  1163     using `a \<notin> B` `finite B` by (simp add: fold1_eq_fold A)
  1164 qed
  1165 
  1166 end
  1167 
  1168 
  1169 text{* Now the recursion rules for definitions: *}
  1170 
  1171 lemma fold1_singleton_def: "g = fold1 f \<Longrightarrow> g {a} = a"
  1172 by simp
  1173 
  1174 lemma (in ab_semigroup_mult) fold1_insert_def:
  1175   "\<lbrakk> g = fold1 times; finite A; x \<notin> A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1176 by (simp add:fold1_insert)
  1177 
  1178 lemma (in ab_semigroup_idem_mult) fold1_insert_idem_def:
  1179   "\<lbrakk> g = fold1 times; finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1180 by simp
  1181 
  1182 subsubsection{* Determinacy for @{term fold1Set} *}
  1183 
  1184 (*Not actually used!!*)
  1185 (*
  1186 context ab_semigroup_mult
  1187 begin
  1188 
  1189 lemma fold_graph_permute:
  1190   "[|fold_graph times id b (insert a A) x; a \<notin> A; b \<notin> A|]
  1191    ==> fold_graph times id a (insert b A) x"
  1192 apply (cases "a=b") 
  1193 apply (auto dest: fold_graph_permute_diff) 
  1194 done
  1195 
  1196 lemma fold1Set_determ:
  1197   "fold1Set times A x ==> fold1Set times A y ==> y = x"
  1198 proof (clarify elim!: fold1Set.cases)
  1199   fix A x B y a b
  1200   assume Ax: "fold_graph times id a A x"
  1201   assume By: "fold_graph times id b B y"
  1202   assume anotA:  "a \<notin> A"
  1203   assume bnotB:  "b \<notin> B"
  1204   assume eq: "insert a A = insert b B"
  1205   show "y=x"
  1206   proof cases
  1207     assume same: "a=b"
  1208     hence "A=B" using anotA bnotB eq by (blast elim!: equalityE)
  1209     thus ?thesis using Ax By same by (blast intro: fold_graph_determ)
  1210   next
  1211     assume diff: "a\<noteq>b"
  1212     let ?D = "B - {a}"
  1213     have B: "B = insert a ?D" and A: "A = insert b ?D"
  1214      and aB: "a \<in> B" and bA: "b \<in> A"
  1215       using eq anotA bnotB diff by (blast elim!:equalityE)+
  1216     with aB bnotB By
  1217     have "fold_graph times id a (insert b ?D) y" 
  1218       by (auto intro: fold_graph_permute simp add: insert_absorb)
  1219     moreover
  1220     have "fold_graph times id a (insert b ?D) x"
  1221       by (simp add: A [symmetric] Ax) 
  1222     ultimately show ?thesis by (blast intro: fold_graph_determ) 
  1223   qed
  1224 qed
  1225 
  1226 lemma fold1Set_equality: "fold1Set times A y ==> fold1 times A = y"
  1227   by (unfold fold1_def) (blast intro: fold1Set_determ)
  1228 
  1229 end
  1230 *)
  1231 
  1232 declare
  1233   empty_fold_graphE [rule del]  fold_graph.intros [rule del]
  1234   empty_fold1SetE [rule del]  insert_fold1SetE [rule del]
  1235   -- {* No more proofs involve these relations. *}
  1236 
  1237 subsubsection {* Lemmas about @{text fold1} *}
  1238 
  1239 context ab_semigroup_mult
  1240 begin
  1241 
  1242 lemma fold1_Un:
  1243 assumes A: "finite A" "A \<noteq> {}"
  1244 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow> A Int B = {} \<Longrightarrow>
  1245        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1246 using A by (induct rule: finite_ne_induct)
  1247   (simp_all add: fold1_insert mult_assoc)
  1248 
  1249 lemma fold1_in:
  1250   assumes A: "finite (A)" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x,y}"
  1251   shows "fold1 times A \<in> A"
  1252 using A
  1253 proof (induct rule:finite_ne_induct)
  1254   case singleton thus ?case by simp
  1255 next
  1256   case insert thus ?case using elem by (force simp add:fold1_insert)
  1257 qed
  1258 
  1259 end
  1260 
  1261 lemma (in ab_semigroup_idem_mult) fold1_Un2:
  1262 assumes A: "finite A" "A \<noteq> {}"
  1263 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow>
  1264        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1265 using A
  1266 proof(induct rule:finite_ne_induct)
  1267   case singleton thus ?case by simp
  1268 next
  1269   case insert thus ?case by (simp add: mult_assoc)
  1270 qed
  1271 
  1272 
  1273 subsection {* Locales as mini-packages for fold operations *}
  1274 
  1275 subsubsection {* The natural case *}
  1276 
  1277 locale folding =
  1278   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1279   fixes F :: "'a set \<Rightarrow> 'b \<Rightarrow> 'b"
  1280   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
  1281   assumes eq_fold: "finite A \<Longrightarrow> F A s = fold f s A"
  1282 begin
  1283 
  1284 lemma empty [simp]:
  1285   "F {} = id"
  1286   by (simp add: eq_fold fun_eq_iff)
  1287 
  1288 lemma insert [simp]:
  1289   assumes "finite A" and "x \<notin> A"
  1290   shows "F (insert x A) = F A \<circ> f x"
  1291 proof -
  1292   interpret comp_fun_commute f proof
  1293   qed (insert comp_fun_commute, simp add: fun_eq_iff)
  1294   from fold_insert2 assms
  1295   have "\<And>s. fold f s (insert x A) = fold f (f x s) A" .
  1296   with `finite A` show ?thesis by (simp add: eq_fold fun_eq_iff)
  1297 qed
  1298 
  1299 lemma remove:
  1300   assumes "finite A" and "x \<in> A"
  1301   shows "F A = F (A - {x}) \<circ> f x"
  1302 proof -
  1303   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1304     by (auto dest: mk_disjoint_insert)
  1305   moreover from `finite A` this have "finite B" by simp
  1306   ultimately show ?thesis by simp
  1307 qed
  1308 
  1309 lemma insert_remove:
  1310   assumes "finite A"
  1311   shows "F (insert x A) = F (A - {x}) \<circ> f x"
  1312   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1313 
  1314 lemma commute_left_comp:
  1315   "f y \<circ> (f x \<circ> g) = f x \<circ> (f y \<circ> g)"
  1316   by (simp add: o_assoc comp_fun_commute)
  1317 
  1318 lemma comp_fun_commute':
  1319   assumes "finite A"
  1320   shows "f x \<circ> F A = F A \<circ> f x"
  1321   using assms by (induct A)
  1322     (simp, simp del: o_apply add: o_assoc, simp del: o_apply add: o_assoc [symmetric] comp_fun_commute)
  1323 
  1324 lemma commute_left_comp':
  1325   assumes "finite A"
  1326   shows "f x \<circ> (F A \<circ> g) = F A \<circ> (f x \<circ> g)"
  1327   using assms by (simp add: o_assoc comp_fun_commute')
  1328 
  1329 lemma comp_fun_commute'':
  1330   assumes "finite A" and "finite B"
  1331   shows "F B \<circ> F A = F A \<circ> F B"
  1332   using assms by (induct A)
  1333     (simp_all add: o_assoc, simp add: o_assoc [symmetric] comp_fun_commute')
  1334 
  1335 lemma commute_left_comp'':
  1336   assumes "finite A" and "finite B"
  1337   shows "F B \<circ> (F A \<circ> g) = F A \<circ> (F B \<circ> g)"
  1338   using assms by (simp add: o_assoc comp_fun_commute'')
  1339 
  1340 lemmas comp_fun_commutes = o_assoc [symmetric] comp_fun_commute commute_left_comp
  1341   comp_fun_commute' commute_left_comp' comp_fun_commute'' commute_left_comp''
  1342 
  1343 lemma union_inter:
  1344   assumes "finite A" and "finite B"
  1345   shows "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B"
  1346   using assms by (induct A)
  1347     (simp_all del: o_apply add: insert_absorb Int_insert_left comp_fun_commutes,
  1348       simp add: o_assoc)
  1349 
  1350 lemma union:
  1351   assumes "finite A" and "finite B"
  1352   and "A \<inter> B = {}"
  1353   shows "F (A \<union> B) = F A \<circ> F B"
  1354 proof -
  1355   from union_inter `finite A` `finite B` have "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B" .
  1356   with `A \<inter> B = {}` show ?thesis by simp
  1357 qed
  1358 
  1359 end
  1360 
  1361 
  1362 subsubsection {* The natural case with idempotency *}
  1363 
  1364 locale folding_idem = folding +
  1365   assumes idem_comp: "f x \<circ> f x = f x"
  1366 begin
  1367 
  1368 lemma idem_left_comp:
  1369   "f x \<circ> (f x \<circ> g) = f x \<circ> g"
  1370   by (simp add: o_assoc idem_comp)
  1371 
  1372 lemma in_comp_idem:
  1373   assumes "finite A" and "x \<in> A"
  1374   shows "F A \<circ> f x = F A"
  1375 using assms by (induct A)
  1376   (auto simp add: comp_fun_commutes idem_comp, simp add: commute_left_comp' [symmetric] comp_fun_commute')
  1377 
  1378 lemma subset_comp_idem:
  1379   assumes "finite A" and "B \<subseteq> A"
  1380   shows "F A \<circ> F B = F A"
  1381 proof -
  1382   from assms have "finite B" by (blast dest: finite_subset)
  1383   then show ?thesis using `B \<subseteq> A` by (induct B)
  1384     (simp_all add: o_assoc in_comp_idem `finite A`)
  1385 qed
  1386 
  1387 declare insert [simp del]
  1388 
  1389 lemma insert_idem [simp]:
  1390   assumes "finite A"
  1391   shows "F (insert x A) = F A \<circ> f x"
  1392   using assms by (cases "x \<in> A") (simp_all add: insert in_comp_idem insert_absorb)
  1393 
  1394 lemma union_idem:
  1395   assumes "finite A" and "finite B"
  1396   shows "F (A \<union> B) = F A \<circ> F B"
  1397 proof -
  1398   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1399   then have "F (A \<union> B) \<circ> F (A \<inter> B) = F (A \<union> B)" by (rule subset_comp_idem)
  1400   with assms show ?thesis by (simp add: union_inter)
  1401 qed
  1402 
  1403 end
  1404 
  1405 
  1406 subsubsection {* The image case with fixed function *}
  1407 
  1408 no_notation times (infixl "*" 70)
  1409 no_notation Groups.one ("1")
  1410 
  1411 locale folding_image_simple = comm_monoid +
  1412   fixes g :: "('b \<Rightarrow> 'a)"
  1413   fixes F :: "'b set \<Rightarrow> 'a"
  1414   assumes eq_fold_g: "finite A \<Longrightarrow> F A = fold_image f g 1 A"
  1415 begin
  1416 
  1417 lemma empty [simp]:
  1418   "F {} = 1"
  1419   by (simp add: eq_fold_g)
  1420 
  1421 lemma insert [simp]:
  1422   assumes "finite A" and "x \<notin> A"
  1423   shows "F (insert x A) = g x * F A"
  1424 proof -
  1425   interpret comp_fun_commute "%x y. (g x) * y" proof
  1426   qed (simp add: ac_simps fun_eq_iff)
  1427   with assms have "fold_image (op *) g 1 (insert x A) = g x * fold_image (op *) g 1 A"
  1428     by (simp add: fold_image_def)
  1429   with `finite A` show ?thesis by (simp add: eq_fold_g)
  1430 qed
  1431 
  1432 lemma remove:
  1433   assumes "finite A" and "x \<in> A"
  1434   shows "F A = g x * F (A - {x})"
  1435 proof -
  1436   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1437     by (auto dest: mk_disjoint_insert)
  1438   moreover from `finite A` this have "finite B" by simp
  1439   ultimately show ?thesis by simp
  1440 qed
  1441 
  1442 lemma insert_remove:
  1443   assumes "finite A"
  1444   shows "F (insert x A) = g x * F (A - {x})"
  1445   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1446 
  1447 lemma neutral:
  1448   assumes "finite A" and "\<forall>x\<in>A. g x = 1"
  1449   shows "F A = 1"
  1450   using assms by (induct A) simp_all
  1451 
  1452 lemma union_inter:
  1453   assumes "finite A" and "finite B"
  1454   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1455 using assms proof (induct A)
  1456   case empty then show ?case by simp
  1457 next
  1458   case (insert x A) then show ?case
  1459     by (auto simp add: insert_absorb Int_insert_left commute [of _ "g x"] assoc left_commute)
  1460 qed
  1461 
  1462 corollary union_inter_neutral:
  1463   assumes "finite A" and "finite B"
  1464   and I0: "\<forall>x \<in> A\<inter>B. g x = 1"
  1465   shows "F (A \<union> B) = F A * F B"
  1466   using assms by (simp add: union_inter [symmetric] neutral)
  1467 
  1468 corollary union_disjoint:
  1469   assumes "finite A" and "finite B"
  1470   assumes "A \<inter> B = {}"
  1471   shows "F (A \<union> B) = F A * F B"
  1472   using assms by (simp add: union_inter_neutral)
  1473 
  1474 end
  1475 
  1476 
  1477 subsubsection {* The image case with flexible function *}
  1478 
  1479 locale folding_image = comm_monoid +
  1480   fixes F :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b set \<Rightarrow> 'a"
  1481   assumes eq_fold: "\<And>g. finite A \<Longrightarrow> F g A = fold_image f g 1 A"
  1482 
  1483 sublocale folding_image < folding_image_simple "op *" 1 g "F g" proof
  1484 qed (fact eq_fold)
  1485 
  1486 context folding_image
  1487 begin
  1488 
  1489 lemma reindex: (* FIXME polymorhism *)
  1490   assumes "finite A" and "inj_on h A"
  1491   shows "F g (h ` A) = F (g \<circ> h) A"
  1492   using assms by (induct A) auto
  1493 
  1494 lemma cong:
  1495   assumes "finite A" and "\<And>x. x \<in> A \<Longrightarrow> g x = h x"
  1496   shows "F g A = F h A"
  1497 proof -
  1498   from assms have "ALL C. C <= A --> (ALL x:C. g x = h x) --> F g C = F h C"
  1499   apply - apply (erule finite_induct) apply simp
  1500   apply (simp add: subset_insert_iff, clarify)
  1501   apply (subgoal_tac "finite C")
  1502   prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
  1503   apply (subgoal_tac "C = insert x (C - {x})")
  1504   prefer 2 apply blast
  1505   apply (erule ssubst)
  1506   apply (drule spec)
  1507   apply (erule (1) notE impE)
  1508   apply (simp add: Ball_def del: insert_Diff_single)
  1509   done
  1510   with assms show ?thesis by simp
  1511 qed
  1512 
  1513 lemma UNION_disjoint:
  1514   assumes "finite I" and "\<forall>i\<in>I. finite (A i)"
  1515   and "\<forall>i\<in>I. \<forall>j\<in>I. i \<noteq> j \<longrightarrow> A i \<inter> A j = {}"
  1516   shows "F g (UNION I A) = F (F g \<circ> A) I"
  1517 apply (insert assms)
  1518 apply (induct rule: finite_induct)
  1519 apply simp
  1520 apply atomize
  1521 apply (subgoal_tac "\<forall>i\<in>Fa. x \<noteq> i")
  1522  prefer 2 apply blast
  1523 apply (subgoal_tac "A x Int UNION Fa A = {}")
  1524  prefer 2 apply blast
  1525 apply (simp add: union_disjoint)
  1526 done
  1527 
  1528 lemma distrib:
  1529   assumes "finite A"
  1530   shows "F (\<lambda>x. g x * h x) A = F g A * F h A"
  1531   using assms by (rule finite_induct) (simp_all add: assoc commute left_commute)
  1532 
  1533 lemma related: 
  1534   assumes Re: "R 1 1" 
  1535   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1536   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1537   shows "R (F h S) (F g S)"
  1538   using fS by (rule finite_subset_induct) (insert assms, auto)
  1539 
  1540 lemma eq_general:
  1541   assumes fS: "finite S"
  1542   and h: "\<forall>y\<in>S'. \<exists>!x. x \<in> S \<and> h x = y" 
  1543   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2 (h x) = f1 x"
  1544   shows "F f1 S = F f2 S'"
  1545 proof-
  1546   from h f12 have hS: "h ` S = S'" by blast
  1547   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1548     from f12 h H  have "x = y" by auto }
  1549   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1550   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1551   from hS have "F f2 S' = F f2 (h ` S)" by simp
  1552   also have "\<dots> = F (f2 o h) S" using reindex [OF fS hinj, of f2] .
  1553   also have "\<dots> = F f1 S " using th cong [OF fS, of "f2 o h" f1]
  1554     by blast
  1555   finally show ?thesis ..
  1556 qed
  1557 
  1558 lemma eq_general_inverses:
  1559   assumes fS: "finite S" 
  1560   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1561   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x \<and> g (h x) = j x"
  1562   shows "F j S = F g T"
  1563   (* metis solves it, but not yet available here *)
  1564   apply (rule eq_general [OF fS, of T h g j])
  1565   apply (rule ballI)
  1566   apply (frule kh)
  1567   apply (rule ex1I[])
  1568   apply blast
  1569   apply clarsimp
  1570   apply (drule hk) apply simp
  1571   apply (rule sym)
  1572   apply (erule conjunct1[OF conjunct2[OF hk]])
  1573   apply (rule ballI)
  1574   apply (drule hk)
  1575   apply blast
  1576   done
  1577 
  1578 end
  1579 
  1580 
  1581 subsubsection {* The image case with fixed function and idempotency *}
  1582 
  1583 locale folding_image_simple_idem = folding_image_simple +
  1584   assumes idem: "x * x = x"
  1585 
  1586 sublocale folding_image_simple_idem < semilattice proof
  1587 qed (fact idem)
  1588 
  1589 context folding_image_simple_idem
  1590 begin
  1591 
  1592 lemma in_idem:
  1593   assumes "finite A" and "x \<in> A"
  1594   shows "g x * F A = F A"
  1595   using assms by (induct A) (auto simp add: left_commute)
  1596 
  1597 lemma subset_idem:
  1598   assumes "finite A" and "B \<subseteq> A"
  1599   shows "F B * F A = F A"
  1600 proof -
  1601   from assms have "finite B" by (blast dest: finite_subset)
  1602   then show ?thesis using `B \<subseteq> A` by (induct B)
  1603     (auto simp add: assoc in_idem `finite A`)
  1604 qed
  1605 
  1606 declare insert [simp del]
  1607 
  1608 lemma insert_idem [simp]:
  1609   assumes "finite A"
  1610   shows "F (insert x A) = g x * F A"
  1611   using assms by (cases "x \<in> A") (simp_all add: insert in_idem insert_absorb)
  1612 
  1613 lemma union_idem:
  1614   assumes "finite A" and "finite B"
  1615   shows "F (A \<union> B) = F A * F B"
  1616 proof -
  1617   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1618   then have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (rule subset_idem)
  1619   with assms show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1620 qed
  1621 
  1622 end
  1623 
  1624 
  1625 subsubsection {* The image case with flexible function and idempotency *}
  1626 
  1627 locale folding_image_idem = folding_image +
  1628   assumes idem: "x * x = x"
  1629 
  1630 sublocale folding_image_idem < folding_image_simple_idem "op *" 1 g "F g" proof
  1631 qed (fact idem)
  1632 
  1633 
  1634 subsubsection {* The neutral-less case *}
  1635 
  1636 locale folding_one = abel_semigroup +
  1637   fixes F :: "'a set \<Rightarrow> 'a"
  1638   assumes eq_fold: "finite A \<Longrightarrow> F A = fold1 f A"
  1639 begin
  1640 
  1641 lemma singleton [simp]:
  1642   "F {x} = x"
  1643   by (simp add: eq_fold)
  1644 
  1645 lemma eq_fold':
  1646   assumes "finite A" and "x \<notin> A"
  1647   shows "F (insert x A) = fold (op *) x A"
  1648 proof -
  1649   interpret ab_semigroup_mult "op *" proof qed (simp_all add: ac_simps)
  1650   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold)
  1651 qed
  1652 
  1653 lemma insert [simp]:
  1654   assumes "finite A" and "x \<notin> A" and "A \<noteq> {}"
  1655   shows "F (insert x A) = x * F A"
  1656 proof -
  1657   from `A \<noteq> {}` obtain b where "b \<in> A" by blast
  1658   then obtain B where *: "A = insert b B" "b \<notin> B" by (blast dest: mk_disjoint_insert)
  1659   with `finite A` have "finite B" by simp
  1660   interpret fold: folding "op *" "\<lambda>a b. fold (op *) b a" proof
  1661   qed (simp_all add: fun_eq_iff ac_simps)
  1662   thm fold.comp_fun_commute' [of B b, simplified fun_eq_iff, simplified]
  1663   from `finite B` fold.comp_fun_commute' [of B x]
  1664     have "op * x \<circ> (\<lambda>b. fold op * b B) = (\<lambda>b. fold op * b B) \<circ> op * x" by simp
  1665   then have A: "x * fold op * b B = fold op * (b * x) B" by (simp add: fun_eq_iff commute)
  1666   from `finite B` * fold.insert [of B b]
  1667     have "(\<lambda>x. fold op * x (insert b B)) = (\<lambda>x. fold op * x B) \<circ> op * b" by simp
  1668   then have B: "fold op * x (insert b B) = fold op * (b * x) B" by (simp add: fun_eq_iff)
  1669   from A B assms * show ?thesis by (simp add: eq_fold' del: fold.insert)
  1670 qed
  1671 
  1672 lemma remove:
  1673   assumes "finite A" and "x \<in> A"
  1674   shows "F A = (if A - {x} = {} then x else x * F (A - {x}))"
  1675 proof -
  1676   from assms obtain B where "A = insert x B" and "x \<notin> B" by (blast dest: mk_disjoint_insert)
  1677   with assms show ?thesis by simp
  1678 qed
  1679 
  1680 lemma insert_remove:
  1681   assumes "finite A"
  1682   shows "F (insert x A) = (if A - {x} = {} then x else x * F (A - {x}))"
  1683   using assms by (cases "x \<in> A") (simp_all add: insert_absorb remove)
  1684 
  1685 lemma union_disjoint:
  1686   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}" and "A \<inter> B = {}"
  1687   shows "F (A \<union> B) = F A * F B"
  1688   using assms by (induct A rule: finite_ne_induct) (simp_all add: ac_simps)
  1689 
  1690 lemma union_inter:
  1691   assumes "finite A" and "finite B" and "A \<inter> B \<noteq> {}"
  1692   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1693 proof -
  1694   from assms have "A \<noteq> {}" and "B \<noteq> {}" by auto
  1695   from `finite A` `A \<noteq> {}` `A \<inter> B \<noteq> {}` show ?thesis proof (induct A rule: finite_ne_induct)
  1696     case (singleton x) then show ?case by (simp add: insert_absorb ac_simps)
  1697   next
  1698     case (insert x A) show ?case proof (cases "x \<in> B")
  1699       case True then have "B \<noteq> {}" by auto
  1700       with insert True `finite B` show ?thesis by (cases "A \<inter> B = {}")
  1701         (simp_all add: insert_absorb ac_simps union_disjoint)
  1702     next
  1703       case False with insert have "F (A \<union> B) * F (A \<inter> B) = F A * F B" by simp
  1704       moreover from False `finite B` insert have "finite (A \<union> B)" "x \<notin> A \<union> B" "A \<union> B \<noteq> {}"
  1705         by auto
  1706       ultimately show ?thesis using False `finite A` `x \<notin> A` `A \<noteq> {}` by (simp add: assoc)
  1707     qed
  1708   qed
  1709 qed
  1710 
  1711 lemma closed:
  1712   assumes "finite A" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x, y}"
  1713   shows "F A \<in> A"
  1714 using `finite A` `A \<noteq> {}` proof (induct rule: finite_ne_induct)
  1715   case singleton then show ?case by simp
  1716 next
  1717   case insert with elem show ?case by force
  1718 qed
  1719 
  1720 end
  1721 
  1722 
  1723 subsubsection {* The neutral-less case with idempotency *}
  1724 
  1725 locale folding_one_idem = folding_one +
  1726   assumes idem: "x * x = x"
  1727 
  1728 sublocale folding_one_idem < semilattice proof
  1729 qed (fact idem)
  1730 
  1731 context folding_one_idem
  1732 begin
  1733 
  1734 lemma in_idem:
  1735   assumes "finite A" and "x \<in> A"
  1736   shows "x * F A = F A"
  1737 proof -
  1738   from assms have "A \<noteq> {}" by auto
  1739   with `finite A` show ?thesis using `x \<in> A` by (induct A rule: finite_ne_induct) (auto simp add: ac_simps)
  1740 qed
  1741 
  1742 lemma subset_idem:
  1743   assumes "finite A" "B \<noteq> {}" and "B \<subseteq> A"
  1744   shows "F B * F A = F A"
  1745 proof -
  1746   from assms have "finite B" by (blast dest: finite_subset)
  1747   then show ?thesis using `B \<noteq> {}` `B \<subseteq> A` by (induct B rule: finite_ne_induct)
  1748     (simp_all add: assoc in_idem `finite A`)
  1749 qed
  1750 
  1751 lemma eq_fold_idem':
  1752   assumes "finite A"
  1753   shows "F (insert a A) = fold (op *) a A"
  1754 proof -
  1755   interpret ab_semigroup_idem_mult "op *" proof qed (simp_all add: ac_simps)
  1756   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold_idem)
  1757 qed
  1758 
  1759 lemma insert_idem [simp]:
  1760   assumes "finite A" and "A \<noteq> {}"
  1761   shows "F (insert x A) = x * F A"
  1762 proof (cases "x \<in> A")
  1763   case False from `finite A` `x \<notin> A` `A \<noteq> {}` show ?thesis by (rule insert)
  1764 next
  1765   case True
  1766   from `finite A` `A \<noteq> {}` show ?thesis by (simp add: in_idem insert_absorb True)
  1767 qed
  1768   
  1769 lemma union_idem:
  1770   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}"
  1771   shows "F (A \<union> B) = F A * F B"
  1772 proof (cases "A \<inter> B = {}")
  1773   case True with assms show ?thesis by (simp add: union_disjoint)
  1774 next
  1775   case False
  1776   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1777   with False have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (auto intro: subset_idem)
  1778   with assms False show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1779 qed
  1780 
  1781 lemma hom_commute:
  1782   assumes hom: "\<And>x y. h (x * y) = h x * h y"
  1783   and N: "finite N" "N \<noteq> {}" shows "h (F N) = F (h ` N)"
  1784 using N proof (induct rule: finite_ne_induct)
  1785   case singleton thus ?case by simp
  1786 next
  1787   case (insert n N)
  1788   then have "h (F (insert n N)) = h (n * F N)" by simp
  1789   also have "\<dots> = h n * h (F N)" by (rule hom)
  1790   also have "h (F N) = F (h ` N)" by(rule insert)
  1791   also have "h n * \<dots> = F (insert (h n) (h ` N))"
  1792     using insert by(simp)
  1793   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1794   finally show ?case .
  1795 qed
  1796 
  1797 end
  1798 
  1799 notation times (infixl "*" 70)
  1800 notation Groups.one ("1")
  1801 
  1802 
  1803 subsection {* Finite cardinality *}
  1804 
  1805 text {* This definition, although traditional, is ugly to work with:
  1806 @{text "card A == LEAST n. EX f. A = {f i | i. i < n}"}.
  1807 But now that we have @{text fold_image} things are easy:
  1808 *}
  1809 
  1810 definition card :: "'a set \<Rightarrow> nat" where
  1811   "card A = (if finite A then fold_image (op +) (\<lambda>x. 1) 0 A else 0)"
  1812 
  1813 interpretation card: folding_image_simple "op +" 0 "\<lambda>x. 1" card proof
  1814 qed (simp add: card_def)
  1815 
  1816 lemma card_infinite [simp]:
  1817   "\<not> finite A \<Longrightarrow> card A = 0"
  1818   by (simp add: card_def)
  1819 
  1820 lemma card_empty:
  1821   "card {} = 0"
  1822   by (fact card.empty)
  1823 
  1824 lemma card_insert_disjoint:
  1825   "finite A ==> x \<notin> A ==> card (insert x A) = Suc (card A)"
  1826   by simp
  1827 
  1828 lemma card_insert_if:
  1829   "finite A ==> card (insert x A) = (if x \<in> A then card A else Suc (card A))"
  1830   by auto (simp add: card.insert_remove card.remove)
  1831 
  1832 lemma card_ge_0_finite:
  1833   "card A > 0 \<Longrightarrow> finite A"
  1834   by (rule ccontr) simp
  1835 
  1836 lemma card_0_eq [simp, no_atp]:
  1837   "finite A \<Longrightarrow> card A = 0 \<longleftrightarrow> A = {}"
  1838   by (auto dest: mk_disjoint_insert)
  1839 
  1840 lemma finite_UNIV_card_ge_0:
  1841   "finite (UNIV :: 'a set) \<Longrightarrow> card (UNIV :: 'a set) > 0"
  1842   by (rule ccontr) simp
  1843 
  1844 lemma card_eq_0_iff:
  1845   "card A = 0 \<longleftrightarrow> A = {} \<or> \<not> finite A"
  1846   by auto
  1847 
  1848 lemma card_gt_0_iff:
  1849   "0 < card A \<longleftrightarrow> A \<noteq> {} \<and> finite A"
  1850   by (simp add: neq0_conv [symmetric] card_eq_0_iff) 
  1851 
  1852 lemma card_Suc_Diff1: "finite A ==> x: A ==> Suc (card (A - {x})) = card A"
  1853 apply(rule_tac t = A in insert_Diff [THEN subst], assumption)
  1854 apply(simp del:insert_Diff_single)
  1855 done
  1856 
  1857 lemma card_Diff_singleton:
  1858   "finite A ==> x: A ==> card (A - {x}) = card A - 1"
  1859 by (simp add: card_Suc_Diff1 [symmetric])
  1860 
  1861 lemma card_Diff_singleton_if:
  1862   "finite A ==> card (A-{x}) = (if x : A then card A - 1 else card A)"
  1863 by (simp add: card_Diff_singleton)
  1864 
  1865 lemma card_Diff_insert[simp]:
  1866 assumes "finite A" and "a:A" and "a ~: B"
  1867 shows "card(A - insert a B) = card(A - B) - 1"
  1868 proof -
  1869   have "A - insert a B = (A - B) - {a}" using assms by blast
  1870   then show ?thesis using assms by(simp add:card_Diff_singleton)
  1871 qed
  1872 
  1873 lemma card_insert: "finite A ==> card (insert x A) = Suc (card (A - {x}))"
  1874 by (simp add: card_insert_if card_Suc_Diff1 del:card_Diff_insert)
  1875 
  1876 lemma card_insert_le: "finite A ==> card A <= card (insert x A)"
  1877 by (simp add: card_insert_if)
  1878 
  1879 lemma card_Collect_less_nat[simp]: "card{i::nat. i < n} = n"
  1880 by (induct n) (simp_all add:less_Suc_eq Collect_disj_eq)
  1881 
  1882 lemma card_Collect_le_nat[simp]: "card{i::nat. i <= n} = Suc n"
  1883 using card_Collect_less_nat[of "Suc n"] by(simp add: less_Suc_eq_le)
  1884 
  1885 lemma card_mono:
  1886   assumes "finite B" and "A \<subseteq> B"
  1887   shows "card A \<le> card B"
  1888 proof -
  1889   from assms have "finite A" by (auto intro: finite_subset)
  1890   then show ?thesis using assms proof (induct A arbitrary: B)
  1891     case empty then show ?case by simp
  1892   next
  1893     case (insert x A)
  1894     then have "x \<in> B" by simp
  1895     from insert have "A \<subseteq> B - {x}" and "finite (B - {x})" by auto
  1896     with insert.hyps have "card A \<le> card (B - {x})" by auto
  1897     with `finite A` `x \<notin> A` `finite B` `x \<in> B` show ?case by simp (simp only: card.remove)
  1898   qed
  1899 qed
  1900 
  1901 lemma card_seteq: "finite B ==> (!!A. A <= B ==> card B <= card A ==> A = B)"
  1902 apply (induct rule: finite_induct)
  1903 apply simp
  1904 apply clarify
  1905 apply (subgoal_tac "finite A & A - {x} <= F")
  1906  prefer 2 apply (blast intro: finite_subset, atomize)
  1907 apply (drule_tac x = "A - {x}" in spec)
  1908 apply (simp add: card_Diff_singleton_if split add: split_if_asm)
  1909 apply (case_tac "card A", auto)
  1910 done
  1911 
  1912 lemma psubset_card_mono: "finite B ==> A < B ==> card A < card B"
  1913 apply (simp add: psubset_eq linorder_not_le [symmetric])
  1914 apply (blast dest: card_seteq)
  1915 done
  1916 
  1917 lemma card_Un_Int: "finite A ==> finite B
  1918     ==> card A + card B = card (A Un B) + card (A Int B)"
  1919   by (fact card.union_inter [symmetric])
  1920 
  1921 lemma card_Un_disjoint: "finite A ==> finite B
  1922     ==> A Int B = {} ==> card (A Un B) = card A + card B"
  1923   by (fact card.union_disjoint)
  1924 
  1925 lemma card_Diff_subset:
  1926   assumes "finite B" and "B \<subseteq> A"
  1927   shows "card (A - B) = card A - card B"
  1928 proof (cases "finite A")
  1929   case False with assms show ?thesis by simp
  1930 next
  1931   case True with assms show ?thesis by (induct B arbitrary: A) simp_all
  1932 qed
  1933 
  1934 lemma card_Diff_subset_Int:
  1935   assumes AB: "finite (A \<inter> B)" shows "card (A - B) = card A - card (A \<inter> B)"
  1936 proof -
  1937   have "A - B = A - A \<inter> B" by auto
  1938   thus ?thesis
  1939     by (simp add: card_Diff_subset AB) 
  1940 qed
  1941 
  1942 lemma diff_card_le_card_Diff:
  1943 assumes "finite B" shows "card A - card B \<le> card(A - B)"
  1944 proof-
  1945   have "card A - card B \<le> card A - card (A \<inter> B)"
  1946     using card_mono[OF assms Int_lower2, of A] by arith
  1947   also have "\<dots> = card(A-B)" using assms by(simp add: card_Diff_subset_Int)
  1948   finally show ?thesis .
  1949 qed
  1950 
  1951 lemma card_Diff1_less: "finite A ==> x: A ==> card (A - {x}) < card A"
  1952 apply (rule Suc_less_SucD)
  1953 apply (simp add: card_Suc_Diff1 del:card_Diff_insert)
  1954 done
  1955 
  1956 lemma card_Diff2_less:
  1957   "finite A ==> x: A ==> y: A ==> card (A - {x} - {y}) < card A"
  1958 apply (case_tac "x = y")
  1959  apply (simp add: card_Diff1_less del:card_Diff_insert)
  1960 apply (rule less_trans)
  1961  prefer 2 apply (auto intro!: card_Diff1_less simp del:card_Diff_insert)
  1962 done
  1963 
  1964 lemma card_Diff1_le: "finite A ==> card (A - {x}) <= card A"
  1965 apply (case_tac "x : A")
  1966  apply (simp_all add: card_Diff1_less less_imp_le)
  1967 done
  1968 
  1969 lemma card_psubset: "finite B ==> A \<subseteq> B ==> card A < card B ==> A < B"
  1970 by (erule psubsetI, blast)
  1971 
  1972 lemma insert_partition:
  1973   "\<lbrakk> x \<notin> F; \<forall>c1 \<in> insert x F. \<forall>c2 \<in> insert x F. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {} \<rbrakk>
  1974   \<Longrightarrow> x \<inter> \<Union> F = {}"
  1975 by auto
  1976 
  1977 lemma finite_psubset_induct[consumes 1, case_names psubset]:
  1978   assumes fin: "finite A" 
  1979   and     major: "\<And>A. finite A \<Longrightarrow> (\<And>B. B \<subset> A \<Longrightarrow> P B) \<Longrightarrow> P A" 
  1980   shows "P A"
  1981 using fin
  1982 proof (induct A taking: card rule: measure_induct_rule)
  1983   case (less A)
  1984   have fin: "finite A" by fact
  1985   have ih: "\<And>B. \<lbrakk>card B < card A; finite B\<rbrakk> \<Longrightarrow> P B" by fact
  1986   { fix B 
  1987     assume asm: "B \<subset> A"
  1988     from asm have "card B < card A" using psubset_card_mono fin by blast
  1989     moreover
  1990     from asm have "B \<subseteq> A" by auto
  1991     then have "finite B" using fin finite_subset by blast
  1992     ultimately 
  1993     have "P B" using ih by simp
  1994   }
  1995   with fin show "P A" using major by blast
  1996 qed
  1997 
  1998 text{* main cardinality theorem *}
  1999 lemma card_partition [rule_format]:
  2000   "finite C ==>
  2001      finite (\<Union> C) -->
  2002      (\<forall>c\<in>C. card c = k) -->
  2003      (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 --> c1 \<inter> c2 = {}) -->
  2004      k * card(C) = card (\<Union> C)"
  2005 apply (erule finite_induct, simp)
  2006 apply (simp add: card_Un_disjoint insert_partition 
  2007        finite_subset [of _ "\<Union> (insert x F)"])
  2008 done
  2009 
  2010 lemma card_eq_UNIV_imp_eq_UNIV:
  2011   assumes fin: "finite (UNIV :: 'a set)"
  2012   and card: "card A = card (UNIV :: 'a set)"
  2013   shows "A = (UNIV :: 'a set)"
  2014 proof
  2015   show "A \<subseteq> UNIV" by simp
  2016   show "UNIV \<subseteq> A"
  2017   proof
  2018     fix x
  2019     show "x \<in> A"
  2020     proof (rule ccontr)
  2021       assume "x \<notin> A"
  2022       then have "A \<subset> UNIV" by auto
  2023       with fin have "card A < card (UNIV :: 'a set)" by (fact psubset_card_mono)
  2024       with card show False by simp
  2025     qed
  2026   qed
  2027 qed
  2028 
  2029 text{*The form of a finite set of given cardinality*}
  2030 
  2031 lemma card_eq_SucD:
  2032 assumes "card A = Suc k"
  2033 shows "\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={})"
  2034 proof -
  2035   have fin: "finite A" using assms by (auto intro: ccontr)
  2036   moreover have "card A \<noteq> 0" using assms by auto
  2037   ultimately obtain b where b: "b \<in> A" by auto
  2038   show ?thesis
  2039   proof (intro exI conjI)
  2040     show "A = insert b (A-{b})" using b by blast
  2041     show "b \<notin> A - {b}" by blast
  2042     show "card (A - {b}) = k" and "k = 0 \<longrightarrow> A - {b} = {}"
  2043       using assms b fin by(fastsimp dest:mk_disjoint_insert)+
  2044   qed
  2045 qed
  2046 
  2047 lemma card_Suc_eq:
  2048   "(card A = Suc k) =
  2049    (\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={}))"
  2050 apply(rule iffI)
  2051  apply(erule card_eq_SucD)
  2052 apply(auto)
  2053 apply(subst card_insert)
  2054  apply(auto intro:ccontr)
  2055 done
  2056 
  2057 lemma finite_fun_UNIVD2:
  2058   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
  2059   shows "finite (UNIV :: 'b set)"
  2060 proof -
  2061   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary))"
  2062     by(rule finite_imageI)
  2063   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary)"
  2064     by(rule UNIV_eq_I) auto
  2065   ultimately show "finite (UNIV :: 'b set)" by simp
  2066 qed
  2067 
  2068 lemma card_UNIV_unit: "card (UNIV :: unit set) = 1"
  2069   unfolding UNIV_unit by simp
  2070 
  2071 
  2072 subsubsection {* Cardinality of image *}
  2073 
  2074 lemma card_image_le: "finite A ==> card (f ` A) <= card A"
  2075 apply (induct rule: finite_induct)
  2076  apply simp
  2077 apply (simp add: le_SucI card_insert_if)
  2078 done
  2079 
  2080 lemma card_image:
  2081   assumes "inj_on f A"
  2082   shows "card (f ` A) = card A"
  2083 proof (cases "finite A")
  2084   case True then show ?thesis using assms by (induct A) simp_all
  2085 next
  2086   case False then have "\<not> finite (f ` A)" using assms by (auto dest: finite_imageD)
  2087   with False show ?thesis by simp
  2088 qed
  2089 
  2090 lemma bij_betw_same_card: "bij_betw f A B \<Longrightarrow> card A = card B"
  2091 by(auto simp: card_image bij_betw_def)
  2092 
  2093 lemma endo_inj_surj: "finite A ==> f ` A \<subseteq> A ==> inj_on f A ==> f ` A = A"
  2094 by (simp add: card_seteq card_image)
  2095 
  2096 lemma eq_card_imp_inj_on:
  2097   "[| finite A; card(f ` A) = card A |] ==> inj_on f A"
  2098 apply (induct rule:finite_induct)
  2099 apply simp
  2100 apply(frule card_image_le[where f = f])
  2101 apply(simp add:card_insert_if split:if_splits)
  2102 done
  2103 
  2104 lemma inj_on_iff_eq_card:
  2105   "finite A ==> inj_on f A = (card(f ` A) = card A)"
  2106 by(blast intro: card_image eq_card_imp_inj_on)
  2107 
  2108 
  2109 lemma card_inj_on_le:
  2110   "[|inj_on f A; f ` A \<subseteq> B; finite B |] ==> card A \<le> card B"
  2111 apply (subgoal_tac "finite A") 
  2112  apply (force intro: card_mono simp add: card_image [symmetric])
  2113 apply (blast intro: finite_imageD dest: finite_subset) 
  2114 done
  2115 
  2116 lemma card_bij_eq:
  2117   "[|inj_on f A; f ` A \<subseteq> B; inj_on g B; g ` B \<subseteq> A;
  2118      finite A; finite B |] ==> card A = card B"
  2119 by (auto intro: le_antisym card_inj_on_le)
  2120 
  2121 lemma bij_betw_finite:
  2122   assumes "bij_betw f A B"
  2123   shows "finite A \<longleftrightarrow> finite B"
  2124 using assms unfolding bij_betw_def
  2125 using finite_imageD[of f A] by auto
  2126 
  2127 
  2128 subsubsection {* Pigeonhole Principles *}
  2129 
  2130 lemma pigeonhole: "card A > card(f ` A) \<Longrightarrow> ~ inj_on f A "
  2131 by (auto dest: card_image less_irrefl_nat)
  2132 
  2133 lemma pigeonhole_infinite:
  2134 assumes  "~ finite A" and "finite(f`A)"
  2135 shows "EX a0:A. ~finite{a:A. f a = f a0}"
  2136 proof -
  2137   have "finite(f`A) \<Longrightarrow> ~ finite A \<Longrightarrow> EX a0:A. ~finite{a:A. f a = f a0}"
  2138   proof(induct "f`A" arbitrary: A rule: finite_induct)
  2139     case empty thus ?case by simp
  2140   next
  2141     case (insert b F)
  2142     show ?case
  2143     proof cases
  2144       assume "finite{a:A. f a = b}"
  2145       hence "~ finite(A - {a:A. f a = b})" using `\<not> finite A` by simp
  2146       also have "A - {a:A. f a = b} = {a:A. f a \<noteq> b}" by blast
  2147       finally have "~ finite({a:A. f a \<noteq> b})" .
  2148       from insert(3)[OF _ this]
  2149       show ?thesis using insert(2,4) by simp (blast intro: rev_finite_subset)
  2150     next
  2151       assume 1: "~finite{a:A. f a = b}"
  2152       hence "{a \<in> A. f a = b} \<noteq> {}" by force
  2153       thus ?thesis using 1 by blast
  2154     qed
  2155   qed
  2156   from this[OF assms(2,1)] show ?thesis .
  2157 qed
  2158 
  2159 lemma pigeonhole_infinite_rel:
  2160 assumes "~finite A" and "finite B" and "ALL a:A. EX b:B. R a b"
  2161 shows "EX b:B. ~finite{a:A. R a b}"
  2162 proof -
  2163    let ?F = "%a. {b:B. R a b}"
  2164    from finite_Pow_iff[THEN iffD2, OF `finite B`]
  2165    have "finite(?F ` A)" by(blast intro: rev_finite_subset)
  2166    from pigeonhole_infinite[where f = ?F, OF assms(1) this]
  2167    obtain a0 where "a0\<in>A" and 1: "\<not> finite {a\<in>A. ?F a = ?F a0}" ..
  2168    obtain b0 where "b0 : B" and "R a0 b0" using `a0:A` assms(3) by blast
  2169    { assume "finite{a:A. R a b0}"
  2170      then have "finite {a\<in>A. ?F a = ?F a0}"
  2171        using `b0 : B` `R a0 b0` by(blast intro: rev_finite_subset)
  2172    }
  2173    with 1 `b0 : B` show ?thesis by blast
  2174 qed
  2175 
  2176 
  2177 subsubsection {* Cardinality of sums *}
  2178 
  2179 lemma card_Plus:
  2180   assumes "finite A" and "finite B"
  2181   shows "card (A <+> B) = card A + card B"
  2182 proof -
  2183   have "Inl`A \<inter> Inr`B = {}" by fast
  2184   with assms show ?thesis
  2185     unfolding Plus_def
  2186     by (simp add: card_Un_disjoint card_image)
  2187 qed
  2188 
  2189 lemma card_Plus_conv_if:
  2190   "card (A <+> B) = (if finite A \<and> finite B then card A + card B else 0)"
  2191   by (auto simp add: card_Plus)
  2192 
  2193 
  2194 subsubsection {* Cardinality of the Powerset *}
  2195 
  2196 lemma card_Pow: "finite A ==> card (Pow A) = Suc (Suc 0) ^ card A"  (* FIXME numeral 2 (!?) *)
  2197 apply (induct rule: finite_induct)
  2198  apply (simp_all add: Pow_insert)
  2199 apply (subst card_Un_disjoint, blast)
  2200   apply (blast, blast)
  2201 apply (subgoal_tac "inj_on (insert x) (Pow F)")
  2202  apply (simp add: card_image Pow_insert)
  2203 apply (unfold inj_on_def)
  2204 apply (blast elim!: equalityE)
  2205 done
  2206 
  2207 text {* Relates to equivalence classes.  Based on a theorem of F. Kamm\"uller.  *}
  2208 
  2209 lemma dvd_partition:
  2210   "finite (Union C) ==>
  2211     ALL c : C. k dvd card c ==>
  2212     (ALL c1: C. ALL c2: C. c1 \<noteq> c2 --> c1 Int c2 = {}) ==>
  2213   k dvd card (Union C)"
  2214 apply (frule finite_UnionD)
  2215 apply (rotate_tac -1)
  2216 apply (induct rule: finite_induct)
  2217 apply simp_all
  2218 apply clarify
  2219 apply (subst card_Un_disjoint)
  2220    apply (auto simp add: disjoint_eq_subset_Compl)
  2221 done
  2222 
  2223 
  2224 subsubsection {* Relating injectivity and surjectivity *}
  2225 
  2226 lemma finite_surj_inj: "finite A \<Longrightarrow> A \<subseteq> f ` A \<Longrightarrow> inj_on f A"
  2227 apply(rule eq_card_imp_inj_on, assumption)
  2228 apply(frule finite_imageI)
  2229 apply(drule (1) card_seteq)
  2230  apply(erule card_image_le)
  2231 apply simp
  2232 done
  2233 
  2234 lemma finite_UNIV_surj_inj: fixes f :: "'a \<Rightarrow> 'a"
  2235 shows "finite(UNIV:: 'a set) \<Longrightarrow> surj f \<Longrightarrow> inj f"
  2236 by (blast intro: finite_surj_inj subset_UNIV)
  2237 
  2238 lemma finite_UNIV_inj_surj: fixes f :: "'a \<Rightarrow> 'a"
  2239 shows "finite(UNIV:: 'a set) \<Longrightarrow> inj f \<Longrightarrow> surj f"
  2240 by(fastsimp simp:surj_def dest!: endo_inj_surj)
  2241 
  2242 corollary infinite_UNIV_nat[iff]: "~finite(UNIV::nat set)"
  2243 proof
  2244   assume "finite(UNIV::nat set)"
  2245   with finite_UNIV_inj_surj[of Suc]
  2246   show False by simp (blast dest: Suc_neq_Zero surjD)
  2247 qed
  2248 
  2249 (* Often leads to bogus ATP proofs because of reduced type information, hence no_atp *)
  2250 lemma infinite_UNIV_char_0[no_atp]:
  2251   "\<not> finite (UNIV::'a::semiring_char_0 set)"
  2252 proof
  2253   assume "finite (UNIV::'a set)"
  2254   with subset_UNIV have "finite (range of_nat::'a set)"
  2255     by (rule finite_subset)
  2256   moreover have "inj (of_nat::nat \<Rightarrow> 'a)"
  2257     by (simp add: inj_on_def)
  2258   ultimately have "finite (UNIV::nat set)"
  2259     by (rule finite_imageD)
  2260   then show "False"
  2261     by simp
  2262 qed
  2263 
  2264 end