src/HOL/Real/RealDef.thy
author nipkow
Sat Jun 23 19:33:22 2007 +0200 (2007-06-23)
changeset 23477 f4b83f03cac9
parent 23438 dd824e86fa8a
child 23482 2f4be6844f7c
permissions -rw-r--r--
tuned and renamed group_eq_simps and ring_eq_simps
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 definition
    17   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    18   "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 instance real :: "{ord, zero, one, plus, times, minus, inverse}" ..
    24 
    25 definition
    26 
    27   (** these don't use the overloaded "real" function: users don't see them **)
    28 
    29   real_of_preal :: "preal => real" where
    30   "real_of_preal m = Abs_Real(realrel``{(m + 1, 1)})"
    31 
    32 consts
    33    (*overloaded constant for injecting other types into "real"*)
    34    real :: "'a => real"
    35 
    36 
    37 defs (overloaded)
    38 
    39   real_zero_def:
    40   "0 == Abs_Real(realrel``{(1, 1)})"
    41 
    42   real_one_def:
    43   "1 == Abs_Real(realrel``{(1 + 1, 1)})"
    44 
    45   real_minus_def:
    46   "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    47 
    48   real_add_def:
    49    "z + w ==
    50        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    51 		 { Abs_Real(realrel``{(x+u, y+v)}) })"
    52 
    53   real_diff_def:
    54    "r - (s::real) == r + - s"
    55 
    56   real_mult_def:
    57     "z * w ==
    58        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    59 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    60 
    61   real_inverse_def:
    62   "inverse (R::real) == (THE S. (R = 0 & S = 0) | S * R = 1)"
    63 
    64   real_divide_def:
    65   "R / (S::real) == R * inverse S"
    66 
    67   real_le_def:
    68    "z \<le> (w::real) == 
    69     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    70 
    71   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)"
    72 
    73   real_abs_def:  "abs (r::real) == (if r < 0 then - r else r)"
    74 
    75 
    76 subsection {* Equivalence relation over positive reals *}
    77 
    78 lemma preal_trans_lemma:
    79   assumes "x + y1 = x1 + y"
    80       and "x + y2 = x2 + y"
    81   shows "x1 + y2 = x2 + (y1::preal)"
    82 proof -
    83   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    84   also have "... = (x2 + y) + x1"  by (simp add: prems)
    85   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    86   also have "... = x2 + (x + y1)"  by (simp add: prems)
    87   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    88   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    89   thus ?thesis by (rule add_right_imp_eq)
    90 qed
    91 
    92 
    93 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    94 by (simp add: realrel_def)
    95 
    96 lemma equiv_realrel: "equiv UNIV realrel"
    97 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
    98 apply (blast dest: preal_trans_lemma) 
    99 done
   100 
   101 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   102   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   103 lemmas equiv_realrel_iff = 
   104        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   105 
   106 declare equiv_realrel_iff [simp]
   107 
   108 
   109 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   110 by (simp add: Real_def realrel_def quotient_def, blast)
   111 
   112 declare Abs_Real_inject [simp]
   113 declare Abs_Real_inverse [simp]
   114 
   115 
   116 text{*Case analysis on the representation of a real number as an equivalence
   117       class of pairs of positive reals.*}
   118 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   119      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   120 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   121 apply (drule arg_cong [where f=Abs_Real])
   122 apply (auto simp add: Rep_Real_inverse)
   123 done
   124 
   125 
   126 subsection {* Addition and Subtraction *}
   127 
   128 lemma real_add_congruent2_lemma:
   129      "[|a + ba = aa + b; ab + bc = ac + bb|]
   130       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   131 apply (simp add: add_assoc)
   132 apply (rule add_left_commute [of ab, THEN ssubst])
   133 apply (simp add: add_assoc [symmetric])
   134 apply (simp add: add_ac)
   135 done
   136 
   137 lemma real_add:
   138      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   139       Abs_Real (realrel``{(x+u, y+v)})"
   140 proof -
   141   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   142         respects2 realrel"
   143     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   144   thus ?thesis
   145     by (simp add: real_add_def UN_UN_split_split_eq
   146                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   147 qed
   148 
   149 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   150 proof -
   151   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   152     by (simp add: congruent_def add_commute) 
   153   thus ?thesis
   154     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   155 qed
   156 
   157 instance real :: ab_group_add
   158 proof
   159   fix x y z :: real
   160   show "(x + y) + z = x + (y + z)"
   161     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   162   show "x + y = y + x"
   163     by (cases x, cases y, simp add: real_add add_commute)
   164   show "0 + x = x"
   165     by (cases x, simp add: real_add real_zero_def add_ac)
   166   show "- x + x = 0"
   167     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   168   show "x - y = x + - y"
   169     by (simp add: real_diff_def)
   170 qed
   171 
   172 
   173 subsection {* Multiplication *}
   174 
   175 lemma real_mult_congruent2_lemma:
   176      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   177           x * x1 + y * y1 + (x * y2 + y * x2) =
   178           x * x2 + y * y2 + (x * y1 + y * x1)"
   179 apply (simp add: add_left_commute add_assoc [symmetric])
   180 apply (simp add: add_assoc right_distrib [symmetric])
   181 apply (simp add: add_commute)
   182 done
   183 
   184 lemma real_mult_congruent2:
   185     "(%p1 p2.
   186         (%(x1,y1). (%(x2,y2). 
   187           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   188      respects2 realrel"
   189 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   190 apply (simp add: mult_commute add_commute)
   191 apply (auto simp add: real_mult_congruent2_lemma)
   192 done
   193 
   194 lemma real_mult:
   195       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   196        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   197 by (simp add: real_mult_def UN_UN_split_split_eq
   198          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   199 
   200 lemma real_mult_commute: "(z::real) * w = w * z"
   201 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   202 
   203 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   204 apply (cases z1, cases z2, cases z3)
   205 apply (simp add: real_mult right_distrib add_ac mult_ac)
   206 done
   207 
   208 lemma real_mult_1: "(1::real) * z = z"
   209 apply (cases z)
   210 apply (simp add: real_mult real_one_def right_distrib
   211                   mult_1_right mult_ac add_ac)
   212 done
   213 
   214 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   215 apply (cases z1, cases z2, cases w)
   216 apply (simp add: real_add real_mult right_distrib add_ac mult_ac)
   217 done
   218 
   219 text{*one and zero are distinct*}
   220 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   221 proof -
   222   have "(1::preal) < 1 + 1"
   223     by (simp add: preal_self_less_add_left)
   224   thus ?thesis
   225     by (simp add: real_zero_def real_one_def)
   226 qed
   227 
   228 instance real :: comm_ring_1
   229 proof
   230   fix x y z :: real
   231   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   232   show "x * y = y * x" by (rule real_mult_commute)
   233   show "1 * x = x" by (rule real_mult_1)
   234   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   235   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   236 qed
   237 
   238 subsection {* Inverse and Division *}
   239 
   240 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   241 by (simp add: real_zero_def add_commute)
   242 
   243 text{*Instead of using an existential quantifier and constructing the inverse
   244 within the proof, we could define the inverse explicitly.*}
   245 
   246 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   247 apply (simp add: real_zero_def real_one_def, cases x)
   248 apply (cut_tac x = xa and y = y in linorder_less_linear)
   249 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   250 apply (rule_tac
   251         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   252        in exI)
   253 apply (rule_tac [2]
   254         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   255        in exI)
   256 apply (auto simp add: real_mult preal_mult_inverse_right ring_simps)
   257 done
   258 
   259 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   260 apply (simp add: real_inverse_def)
   261 apply (drule real_mult_inverse_left_ex, safe)
   262 apply (rule theI, assumption, rename_tac z)
   263 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   264 apply (simp add: mult_commute)
   265 apply (rule mult_assoc)
   266 done
   267 
   268 
   269 subsection{*The Real Numbers form a Field*}
   270 
   271 instance real :: field
   272 proof
   273   fix x y z :: real
   274   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   275   show "x / y = x * inverse y" by (simp add: real_divide_def)
   276 qed
   277 
   278 
   279 text{*Inverse of zero!  Useful to simplify certain equations*}
   280 
   281 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   282 by (simp add: real_inverse_def)
   283 
   284 instance real :: division_by_zero
   285 proof
   286   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   287 qed
   288 
   289 
   290 subsection{*The @{text "\<le>"} Ordering*}
   291 
   292 lemma real_le_refl: "w \<le> (w::real)"
   293 by (cases w, force simp add: real_le_def)
   294 
   295 text{*The arithmetic decision procedure is not set up for type preal.
   296   This lemma is currently unused, but it could simplify the proofs of the
   297   following two lemmas.*}
   298 lemma preal_eq_le_imp_le:
   299   assumes eq: "a+b = c+d" and le: "c \<le> a"
   300   shows "b \<le> (d::preal)"
   301 proof -
   302   have "c+d \<le> a+d" by (simp add: prems)
   303   hence "a+b \<le> a+d" by (simp add: prems)
   304   thus "b \<le> d" by simp
   305 qed
   306 
   307 lemma real_le_lemma:
   308   assumes l: "u1 + v2 \<le> u2 + v1"
   309       and "x1 + v1 = u1 + y1"
   310       and "x2 + v2 = u2 + y2"
   311   shows "x1 + y2 \<le> x2 + (y1::preal)"
   312 proof -
   313   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   314   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   315   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   316   finally show ?thesis by simp
   317 qed
   318 
   319 lemma real_le: 
   320      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   321       (x1 + y2 \<le> x2 + y1)"
   322 apply (simp add: real_le_def)
   323 apply (auto intro: real_le_lemma)
   324 done
   325 
   326 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   327 by (cases z, cases w, simp add: real_le)
   328 
   329 lemma real_trans_lemma:
   330   assumes "x + v \<le> u + y"
   331       and "u + v' \<le> u' + v"
   332       and "x2 + v2 = u2 + y2"
   333   shows "x + v' \<le> u' + (y::preal)"
   334 proof -
   335   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   336   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   337   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   338   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   339   finally show ?thesis by simp
   340 qed
   341 
   342 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   343 apply (cases i, cases j, cases k)
   344 apply (simp add: real_le)
   345 apply (blast intro: real_trans_lemma)
   346 done
   347 
   348 (* Axiom 'order_less_le' of class 'order': *)
   349 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   350 by (simp add: real_less_def)
   351 
   352 instance real :: order
   353 proof qed
   354  (assumption |
   355   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   356 
   357 (* Axiom 'linorder_linear' of class 'linorder': *)
   358 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   359 apply (cases z, cases w)
   360 apply (auto simp add: real_le real_zero_def add_ac)
   361 done
   362 
   363 
   364 instance real :: linorder
   365   by (intro_classes, rule real_le_linear)
   366 
   367 
   368 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   369 apply (cases x, cases y) 
   370 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   371                       add_ac)
   372 apply (simp_all add: add_assoc [symmetric])
   373 done
   374 
   375 lemma real_add_left_mono: 
   376   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   377 proof -
   378   have "z + x - (z + y) = (z + -z) + (x - y)"
   379     by (simp add: diff_minus add_ac) 
   380   with le show ?thesis 
   381     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   382 qed
   383 
   384 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   385 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   386 
   387 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   388 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   389 
   390 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   391 apply (cases x, cases y)
   392 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   393                  linorder_not_le [where 'a = preal] 
   394                   real_zero_def real_le real_mult)
   395   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   396 apply (auto dest!: less_add_left_Ex
   397      simp add: add_ac mult_ac
   398           right_distrib preal_self_less_add_left)
   399 done
   400 
   401 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   402 apply (rule real_sum_gt_zero_less)
   403 apply (drule real_less_sum_gt_zero [of x y])
   404 apply (drule real_mult_order, assumption)
   405 apply (simp add: right_distrib)
   406 done
   407 
   408 instance real :: distrib_lattice
   409   "inf x y \<equiv> min x y"
   410   "sup x y \<equiv> max x y"
   411   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   412 
   413 
   414 subsection{*The Reals Form an Ordered Field*}
   415 
   416 instance real :: ordered_field
   417 proof
   418   fix x y z :: real
   419   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   420   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   421   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   422 qed
   423 
   424 text{*The function @{term real_of_preal} requires many proofs, but it seems
   425 to be essential for proving completeness of the reals from that of the
   426 positive reals.*}
   427 
   428 lemma real_of_preal_add:
   429      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   430 by (simp add: real_of_preal_def real_add left_distrib add_ac)
   431 
   432 lemma real_of_preal_mult:
   433      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   434 by (simp add: real_of_preal_def real_mult right_distrib add_ac mult_ac)
   435 
   436 
   437 text{*Gleason prop 9-4.4 p 127*}
   438 lemma real_of_preal_trichotomy:
   439       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   440 apply (simp add: real_of_preal_def real_zero_def, cases x)
   441 apply (auto simp add: real_minus add_ac)
   442 apply (cut_tac x = x and y = y in linorder_less_linear)
   443 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   444 done
   445 
   446 lemma real_of_preal_leD:
   447       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   448 by (simp add: real_of_preal_def real_le)
   449 
   450 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   451 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   452 
   453 lemma real_of_preal_lessD:
   454       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   455 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   456 
   457 lemma real_of_preal_less_iff [simp]:
   458      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   459 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   460 
   461 lemma real_of_preal_le_iff:
   462      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   463 by (simp add: linorder_not_less [symmetric])
   464 
   465 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   466 apply (insert preal_self_less_add_left [of 1 m])
   467 apply (auto simp add: real_zero_def real_of_preal_def
   468                       real_less_def real_le_def add_ac)
   469 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   470 apply (simp add: add_ac)
   471 done
   472 
   473 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   474 by (simp add: real_of_preal_zero_less)
   475 
   476 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   477 proof -
   478   from real_of_preal_minus_less_zero
   479   show ?thesis by (blast dest: order_less_trans)
   480 qed
   481 
   482 
   483 subsection{*Theorems About the Ordering*}
   484 
   485 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   486 apply (auto simp add: real_of_preal_zero_less)
   487 apply (cut_tac x = x in real_of_preal_trichotomy)
   488 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   489 done
   490 
   491 lemma real_gt_preal_preal_Ex:
   492      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   493 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   494              intro: real_gt_zero_preal_Ex [THEN iffD1])
   495 
   496 lemma real_ge_preal_preal_Ex:
   497      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   498 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   499 
   500 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   501 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   502             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   503             simp add: real_of_preal_zero_less)
   504 
   505 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   506 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   507 
   508 
   509 subsection{*More Lemmas*}
   510 
   511 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   512 by auto
   513 
   514 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   515 by auto
   516 
   517 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   518   by (force elim: order_less_asym
   519             simp add: Ring_and_Field.mult_less_cancel_right)
   520 
   521 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   522 apply (simp add: mult_le_cancel_right)
   523 apply (blast intro: elim: order_less_asym)
   524 done
   525 
   526 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   527 by(simp add:mult_commute)
   528 
   529 (* FIXME: redundant, but used by Integration/Integral.thy in AFP *)
   530 lemma real_le_add_order: "[| 0 \<le> x; 0 \<le> y |] ==> (0::real) \<le> x + y"
   531 by (rule add_nonneg_nonneg)
   532 
   533 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   534 by (simp add: one_less_inverse_iff) (* TODO: generalize/move *)
   535 
   536 
   537 subsection{*Embedding the Integers into the Reals*}
   538 
   539 defs (overloaded)
   540   real_of_nat_def: "real z == of_nat z"
   541   real_of_int_def: "real z == of_int z"
   542 
   543 lemma real_eq_of_nat: "real = of_nat"
   544   apply (rule ext)
   545   apply (unfold real_of_nat_def)
   546   apply (rule refl)
   547   done
   548 
   549 lemma real_eq_of_int: "real = of_int"
   550   apply (rule ext)
   551   apply (unfold real_of_int_def)
   552   apply (rule refl)
   553   done
   554 
   555 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   556 by (simp add: real_of_int_def) 
   557 
   558 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   559 by (simp add: real_of_int_def) 
   560 
   561 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   562 by (simp add: real_of_int_def) 
   563 
   564 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   565 by (simp add: real_of_int_def) 
   566 
   567 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   568 by (simp add: real_of_int_def) 
   569 
   570 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   571 by (simp add: real_of_int_def) 
   572 
   573 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   574   apply (subst real_eq_of_int)+
   575   apply (rule of_int_setsum)
   576 done
   577 
   578 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   579     (PROD x:A. real(f x))"
   580   apply (subst real_eq_of_int)+
   581   apply (rule of_int_setprod)
   582 done
   583 
   584 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   585 by (simp add: real_of_int_def) 
   586 
   587 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   588 by (simp add: real_of_int_def) 
   589 
   590 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   591 by (simp add: real_of_int_def) 
   592 
   593 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   594 by (simp add: real_of_int_def) 
   595 
   596 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   597 by (simp add: real_of_int_def) 
   598 
   599 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   600 by (simp add: real_of_int_def) 
   601 
   602 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   603 by (simp add: real_of_int_def)
   604 
   605 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   606 by (simp add: real_of_int_def)
   607 
   608 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   609 by (auto simp add: abs_if)
   610 
   611 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   612   apply (subgoal_tac "real n + 1 = real (n + 1)")
   613   apply (simp del: real_of_int_add)
   614   apply auto
   615 done
   616 
   617 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   618   apply (subgoal_tac "real m + 1 = real (m + 1)")
   619   apply (simp del: real_of_int_add)
   620   apply simp
   621 done
   622 
   623 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   624     real (x div d) + (real (x mod d)) / (real d)"
   625 proof -
   626   assume "d ~= 0"
   627   have "x = (x div d) * d + x mod d"
   628     by auto
   629   then have "real x = real (x div d) * real d + real(x mod d)"
   630     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   631   then have "real x / real d = ... / real d"
   632     by simp
   633   then show ?thesis
   634     by (auto simp add: add_divide_distrib ring_simps prems)
   635 qed
   636 
   637 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   638     real(n div d) = real n / real d"
   639   apply (frule real_of_int_div_aux [of d n])
   640   apply simp
   641   apply (simp add: zdvd_iff_zmod_eq_0)
   642 done
   643 
   644 lemma real_of_int_div2:
   645   "0 <= real (n::int) / real (x) - real (n div x)"
   646   apply (case_tac "x = 0")
   647   apply simp
   648   apply (case_tac "0 < x")
   649   apply (simp add: compare_rls)
   650   apply (subst real_of_int_div_aux)
   651   apply simp
   652   apply simp
   653   apply (subst zero_le_divide_iff)
   654   apply auto
   655   apply (simp add: compare_rls)
   656   apply (subst real_of_int_div_aux)
   657   apply simp
   658   apply simp
   659   apply (subst zero_le_divide_iff)
   660   apply auto
   661 done
   662 
   663 lemma real_of_int_div3:
   664   "real (n::int) / real (x) - real (n div x) <= 1"
   665   apply(case_tac "x = 0")
   666   apply simp
   667   apply (simp add: compare_rls)
   668   apply (subst real_of_int_div_aux)
   669   apply assumption
   670   apply simp
   671   apply (subst divide_le_eq)
   672   apply clarsimp
   673   apply (rule conjI)
   674   apply (rule impI)
   675   apply (rule order_less_imp_le)
   676   apply simp
   677   apply (rule impI)
   678   apply (rule order_less_imp_le)
   679   apply simp
   680 done
   681 
   682 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   683   by (insert real_of_int_div2 [of n x], simp)
   684 
   685 subsection{*Embedding the Naturals into the Reals*}
   686 
   687 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   688 by (simp add: real_of_nat_def)
   689 
   690 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   691 by (simp add: real_of_nat_def)
   692 
   693 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   694 by (simp add: real_of_nat_def)
   695 
   696 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   697 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   698 by (simp add: real_of_nat_def)
   699 
   700 lemma real_of_nat_less_iff [iff]: 
   701      "(real (n::nat) < real m) = (n < m)"
   702 by (simp add: real_of_nat_def)
   703 
   704 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   705 by (simp add: real_of_nat_def)
   706 
   707 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   708 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   709 
   710 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   711 by (simp add: real_of_nat_def del: of_nat_Suc)
   712 
   713 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   714 by (simp add: real_of_nat_def of_nat_mult)
   715 
   716 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   717     (SUM x:A. real(f x))"
   718   apply (subst real_eq_of_nat)+
   719   apply (rule of_nat_setsum)
   720 done
   721 
   722 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   723     (PROD x:A. real(f x))"
   724   apply (subst real_eq_of_nat)+
   725   apply (rule of_nat_setprod)
   726 done
   727 
   728 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   729   apply (subst card_eq_setsum)
   730   apply (subst real_of_nat_setsum)
   731   apply simp
   732 done
   733 
   734 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   735 by (simp add: real_of_nat_def)
   736 
   737 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   738 by (simp add: real_of_nat_def)
   739 
   740 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   741 by (simp add: add: real_of_nat_def of_nat_diff)
   742 
   743 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   744 by (simp add: add: real_of_nat_def) 
   745 
   746 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   747 by (simp add: add: real_of_nat_def)
   748 
   749 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   750 by (simp add: add: real_of_nat_def)
   751 
   752 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat)) = (0 \<le> n)"
   753 by (simp add: add: real_of_nat_def)
   754 
   755 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   756   apply (subgoal_tac "real n + 1 = real (Suc n)")
   757   apply simp
   758   apply (auto simp add: real_of_nat_Suc)
   759 done
   760 
   761 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   762   apply (subgoal_tac "real m + 1 = real (Suc m)")
   763   apply (simp add: less_Suc_eq_le)
   764   apply (simp add: real_of_nat_Suc)
   765 done
   766 
   767 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   768     real (x div d) + (real (x mod d)) / (real d)"
   769 proof -
   770   assume "0 < d"
   771   have "x = (x div d) * d + x mod d"
   772     by auto
   773   then have "real x = real (x div d) * real d + real(x mod d)"
   774     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   775   then have "real x / real d = \<dots> / real d"
   776     by simp
   777   then show ?thesis
   778     by (auto simp add: add_divide_distrib ring_simps prems)
   779 qed
   780 
   781 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   782     real(n div d) = real n / real d"
   783   apply (frule real_of_nat_div_aux [of d n])
   784   apply simp
   785   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   786   apply assumption
   787 done
   788 
   789 lemma real_of_nat_div2:
   790   "0 <= real (n::nat) / real (x) - real (n div x)"
   791   apply(case_tac "x = 0")
   792   apply simp
   793   apply (simp add: compare_rls)
   794   apply (subst real_of_nat_div_aux)
   795   apply assumption
   796   apply simp
   797   apply (subst zero_le_divide_iff)
   798   apply simp
   799 done
   800 
   801 lemma real_of_nat_div3:
   802   "real (n::nat) / real (x) - real (n div x) <= 1"
   803   apply(case_tac "x = 0")
   804   apply simp
   805   apply (simp add: compare_rls)
   806   apply (subst real_of_nat_div_aux)
   807   apply assumption
   808   apply simp
   809 done
   810 
   811 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   812   by (insert real_of_nat_div2 [of n x], simp)
   813 
   814 lemma real_of_int_real_of_nat: "real (int n) = real n"
   815 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   816 
   817 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   818 by (simp add: real_of_int_def real_of_nat_def)
   819 
   820 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   821   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   822   apply force
   823   apply (simp only: real_of_int_real_of_nat)
   824 done
   825 
   826 subsection{*Numerals and Arithmetic*}
   827 
   828 instance real :: number ..
   829 
   830 defs (overloaded)
   831   real_number_of_def: "(number_of w :: real) == of_int w"
   832     --{*the type constraint is essential!*}
   833 
   834 instance real :: number_ring
   835 by (intro_classes, simp add: real_number_of_def) 
   836 
   837 text{*Collapse applications of @{term real} to @{term number_of}*}
   838 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   839 by (simp add:  real_of_int_def of_int_number_of_eq)
   840 
   841 lemma real_of_nat_number_of [simp]:
   842      "real (number_of v :: nat) =  
   843         (if neg (number_of v :: int) then 0  
   844          else (number_of v :: real))"
   845 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   846  
   847 
   848 use "real_arith.ML"
   849 
   850 setup real_arith_setup
   851 
   852 
   853 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   854 
   855 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   856 lemma real_0_le_divide_iff:
   857      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   858 by (simp add: real_divide_def zero_le_mult_iff, auto)
   859 
   860 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   861 by arith
   862 
   863 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   864 by auto
   865 
   866 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   867 by auto
   868 
   869 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   870 by auto
   871 
   872 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   873 by auto
   874 
   875 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   876 by auto
   877 
   878 
   879 (*
   880 FIXME: we should have this, as for type int, but many proofs would break.
   881 It replaces x+-y by x-y.
   882 declare real_diff_def [symmetric, simp]
   883 *)
   884 
   885 
   886 subsubsection{*Density of the Reals*}
   887 
   888 lemma real_lbound_gt_zero:
   889      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   890 apply (rule_tac x = " (min d1 d2) /2" in exI)
   891 apply (simp add: min_def)
   892 done
   893 
   894 
   895 text{*Similar results are proved in @{text Ring_and_Field}*}
   896 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   897   by auto
   898 
   899 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   900   by auto
   901 
   902 
   903 subsection{*Absolute Value Function for the Reals*}
   904 
   905 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   906 by (simp add: abs_if)
   907 
   908 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
   909 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   910 by (force simp add: OrderedGroup.abs_le_iff)
   911 
   912 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   913 by (simp add: abs_if)
   914 
   915 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   916 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
   917 
   918 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   919 by simp
   920  
   921 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   922 by simp
   923 
   924 subsection{*Code generation using Isabelle's rats*}
   925 
   926 types_code
   927   real ("Rat.rat")
   928 attach (term_of) {*
   929 fun term_of_real x =
   930  let 
   931   val rT = HOLogic.realT
   932   val (p, q) = Rat.quotient_of_rat x
   933  in if q = 1 then HOLogic.mk_number rT p
   934     else Const("HOL.divide",[rT,rT] ---> rT) $
   935            (HOLogic.mk_number rT p) $ (HOLogic.mk_number rT q)
   936 end;
   937 *}
   938 attach (test) {*
   939 fun gen_real i =
   940 let val p = random_range 0 i; val q = random_range 0 i;
   941     val r = if q=0 then Rat.rat_of_int i else Rat.rat_of_quotient(p,q)
   942 in if one_of [true,false] then r else Rat.neg r end;
   943 *}
   944 
   945 consts_code
   946   "0 :: real" ("Rat.zero")
   947   "1 :: real" ("Rat.one")
   948   "uminus :: real \<Rightarrow> real" ("Rat.neg")
   949   "op + :: real \<Rightarrow> real \<Rightarrow> real" ("Rat.add")
   950   "op * :: real \<Rightarrow> real \<Rightarrow> real" ("Rat.mult")
   951   "inverse :: real \<Rightarrow> real" ("Rat.inv")
   952   "op \<le> :: real \<Rightarrow> real \<Rightarrow> bool" ("Rat.le")
   953   "op < :: real \<Rightarrow> real \<Rightarrow> bool" ("(Rat.ord (_, _) = LESS)")
   954   "op = :: real \<Rightarrow> real \<Rightarrow> bool" ("curry Rat.eq")
   955   "real :: int \<Rightarrow> real" ("Rat.rat'_of'_int")
   956   "real :: nat \<Rightarrow> real" ("(Rat.rat'_of'_int o {*int*})")
   957 
   958 
   959 lemma [code, code unfold]:
   960   "number_of k = real (number_of k :: int)"
   961   by simp
   962 
   963 end