src/HOL/Nitpick.thy
author blanchet
Tue Mar 22 19:04:32 2011 +0100 (2011-03-22)
changeset 42064 f4e53c8630c0
parent 41797 0c6093d596d6
child 44013 5cfc1c36ae97
permissions -rw-r--r--
added first-order TPTP version of Nitpick to Isabelle, so that its sources stay in sync with Isabelle and it is easier to install new versions for SystemOnTPTP and CASC -- the tool is called "isabelle nitrox" but is deliberately omitted from the tool list unless the component is explicitly enabled, to avoid clutter
     1 (*  Title:      HOL/Nitpick.thy
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2008, 2009, 2010
     4 
     5 Nitpick: Yet another counterexample generator for Isabelle/HOL.
     6 *)
     7 
     8 header {* Nitpick: Yet Another Counterexample Generator for Isabelle/HOL *}
     9 
    10 theory Nitpick
    11 imports Map Quotient SAT Record
    12 uses ("Tools/Nitpick/kodkod.ML")
    13      ("Tools/Nitpick/kodkod_sat.ML")
    14      ("Tools/Nitpick/nitpick_util.ML")
    15      ("Tools/Nitpick/nitpick_hol.ML")
    16      ("Tools/Nitpick/nitpick_preproc.ML")
    17      ("Tools/Nitpick/nitpick_mono.ML")
    18      ("Tools/Nitpick/nitpick_scope.ML")
    19      ("Tools/Nitpick/nitpick_peephole.ML")
    20      ("Tools/Nitpick/nitpick_rep.ML")
    21      ("Tools/Nitpick/nitpick_nut.ML")
    22      ("Tools/Nitpick/nitpick_kodkod.ML")
    23      ("Tools/Nitpick/nitpick_model.ML")
    24      ("Tools/Nitpick/nitpick.ML")
    25      ("Tools/Nitpick/nitpick_isar.ML")
    26      ("Tools/Nitpick/nitpick_tests.ML")
    27      ("Tools/Nitpick/nitrox.ML")
    28 begin
    29 
    30 typedecl iota (* for Nitrox *)
    31 typedecl bisim_iterator
    32 
    33 axiomatization unknown :: 'a
    34            and is_unknown :: "'a \<Rightarrow> bool"
    35            and bisim :: "bisim_iterator \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
    36            and bisim_iterator_max :: bisim_iterator
    37            and Quot :: "'a \<Rightarrow> 'b"
    38            and safe_The :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    39 
    40 datatype ('a, 'b) fun_box = FunBox "('a \<Rightarrow> 'b)"
    41 datatype ('a, 'b) pair_box = PairBox 'a 'b
    42 
    43 typedecl unsigned_bit
    44 typedecl signed_bit
    45 
    46 datatype 'a word = Word "('a set)"
    47 
    48 text {*
    49 Alternative definitions.
    50 *}
    51 
    52 lemma Ex1_unfold [nitpick_unfold, no_atp]:
    53 "Ex1 P \<equiv> \<exists>x. P = {x}"
    54 apply (rule eq_reflection)
    55 apply (simp add: Ex1_def set_eq_iff)
    56 apply (rule iffI)
    57  apply (erule exE)
    58  apply (erule conjE)
    59  apply (rule_tac x = x in exI)
    60  apply (rule allI)
    61  apply (rename_tac y)
    62  apply (erule_tac x = y in allE)
    63 by (auto simp: mem_def)
    64 
    65 lemma rtrancl_unfold [nitpick_unfold, no_atp]: "r\<^sup>* \<equiv> (r\<^sup>+)\<^sup>="
    66 by simp
    67 
    68 lemma rtranclp_unfold [nitpick_unfold, no_atp]:
    69 "rtranclp r a b \<equiv> (a = b \<or> tranclp r a b)"
    70 by (rule eq_reflection) (auto dest: rtranclpD)
    71 
    72 lemma tranclp_unfold [nitpick_unfold, no_atp]:
    73 "tranclp r a b \<equiv> trancl (split r) (a, b)"
    74 by (simp add: trancl_def Collect_def mem_def)
    75 
    76 definition prod :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
    77 "prod A B = {(a, b). a \<in> A \<and> b \<in> B}"
    78 
    79 definition refl' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    80 "refl' r \<equiv> \<forall>x. (x, x) \<in> r"
    81 
    82 definition wf' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    83 "wf' r \<equiv> acyclic r \<and> (finite r \<or> unknown)"
    84 
    85 axiomatization wf_wfrec :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b"
    86 
    87 definition wf_wfrec' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    88 [nitpick_simp]: "wf_wfrec' R F x = F (Recdef.cut (wf_wfrec R F) R x) x"
    89 
    90 definition wfrec' ::  "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    91 "wfrec' R F x \<equiv> if wf R then wf_wfrec' R F x
    92                 else THE y. wfrec_rel R (%f x. F (Recdef.cut f R x) x) x y"
    93 
    94 definition card' :: "('a \<Rightarrow> bool) \<Rightarrow> nat" where
    95 "card' A \<equiv> if finite A then length (SOME xs. set xs = A \<and> distinct xs) else 0"
    96 
    97 definition setsum' :: "('a \<Rightarrow> 'b\<Colon>comm_monoid_add) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b" where
    98 "setsum' f A \<equiv> if finite A then listsum (map f (SOME xs. set xs = A \<and> distinct xs)) else 0"
    99 
   100 inductive fold_graph' :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b \<Rightarrow> bool" where
   101 "fold_graph' f z {} z" |
   102 "\<lbrakk>x \<in> A; fold_graph' f z (A - {x}) y\<rbrakk> \<Longrightarrow> fold_graph' f z A (f x y)"
   103 
   104 text {*
   105 The following lemmas are not strictly necessary but they help the
   106 \textit{special\_level} optimization.
   107 *}
   108 
   109 lemma The_psimp [nitpick_psimp, no_atp]:
   110 "P = {x} \<Longrightarrow> The P = x"
   111 by (subgoal_tac "{x} = (\<lambda>y. y = x)") (auto simp: mem_def)
   112 
   113 lemma Eps_psimp [nitpick_psimp, no_atp]:
   114 "\<lbrakk>P x; \<not> P y; Eps P = y\<rbrakk> \<Longrightarrow> Eps P = x"
   115 apply (case_tac "P (Eps P)")
   116  apply auto
   117 apply (erule contrapos_np)
   118 by (rule someI)
   119 
   120 lemma unit_case_unfold [nitpick_unfold, no_atp]:
   121 "unit_case x u \<equiv> x"
   122 apply (subgoal_tac "u = ()")
   123  apply (simp only: unit.cases)
   124 by simp
   125 
   126 declare unit.cases [nitpick_simp del]
   127 
   128 lemma nat_case_unfold [nitpick_unfold, no_atp]:
   129 "nat_case x f n \<equiv> if n = 0 then x else f (n - 1)"
   130 apply (rule eq_reflection)
   131 by (case_tac n) auto
   132 
   133 declare nat.cases [nitpick_simp del]
   134 
   135 lemma list_size_simp [nitpick_simp, no_atp]:
   136 "list_size f xs = (if xs = [] then 0
   137                    else Suc (f (hd xs) + list_size f (tl xs)))"
   138 "size xs = (if xs = [] then 0 else Suc (size (tl xs)))"
   139 by (case_tac xs) auto
   140 
   141 text {*
   142 Auxiliary definitions used to provide an alternative representation for
   143 @{text rat} and @{text real}.
   144 *}
   145 
   146 function nat_gcd :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   147 [simp del]: "nat_gcd x y = (if y = 0 then x else nat_gcd y (x mod y))"
   148 by auto
   149 termination
   150 apply (relation "measure (\<lambda>(x, y). x + y + (if y > x then 1 else 0))")
   151  apply auto
   152  apply (metis mod_less_divisor xt1(9))
   153 by (metis mod_mod_trivial mod_self nat_neq_iff xt1(10))
   154 
   155 definition nat_lcm :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   156 "nat_lcm x y = x * y div (nat_gcd x y)"
   157 
   158 definition int_gcd :: "int \<Rightarrow> int \<Rightarrow> int" where
   159 "int_gcd x y = int (nat_gcd (nat (abs x)) (nat (abs y)))"
   160 
   161 definition int_lcm :: "int \<Rightarrow> int \<Rightarrow> int" where
   162 "int_lcm x y = int (nat_lcm (nat (abs x)) (nat (abs y)))"
   163 
   164 definition Frac :: "int \<times> int \<Rightarrow> bool" where
   165 "Frac \<equiv> \<lambda>(a, b). b > 0 \<and> int_gcd a b = 1"
   166 
   167 axiomatization Abs_Frac :: "int \<times> int \<Rightarrow> 'a"
   168            and Rep_Frac :: "'a \<Rightarrow> int \<times> int"
   169 
   170 definition zero_frac :: 'a where
   171 "zero_frac \<equiv> Abs_Frac (0, 1)"
   172 
   173 definition one_frac :: 'a where
   174 "one_frac \<equiv> Abs_Frac (1, 1)"
   175 
   176 definition num :: "'a \<Rightarrow> int" where
   177 "num \<equiv> fst o Rep_Frac"
   178 
   179 definition denom :: "'a \<Rightarrow> int" where
   180 "denom \<equiv> snd o Rep_Frac"
   181 
   182 function norm_frac :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
   183 [simp del]: "norm_frac a b = (if b < 0 then norm_frac (- a) (- b)
   184                               else if a = 0 \<or> b = 0 then (0, 1)
   185                               else let c = int_gcd a b in (a div c, b div c))"
   186 by pat_completeness auto
   187 termination by (relation "measure (\<lambda>(_, b). if b < 0 then 1 else 0)") auto
   188 
   189 definition frac :: "int \<Rightarrow> int \<Rightarrow> 'a" where
   190 "frac a b \<equiv> Abs_Frac (norm_frac a b)"
   191 
   192 definition plus_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   193 [nitpick_simp]:
   194 "plus_frac q r = (let d = int_lcm (denom q) (denom r) in
   195                     frac (num q * (d div denom q) + num r * (d div denom r)) d)"
   196 
   197 definition times_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   198 [nitpick_simp]:
   199 "times_frac q r = frac (num q * num r) (denom q * denom r)"
   200 
   201 definition uminus_frac :: "'a \<Rightarrow> 'a" where
   202 "uminus_frac q \<equiv> Abs_Frac (- num q, denom q)"
   203 
   204 definition number_of_frac :: "int \<Rightarrow> 'a" where
   205 "number_of_frac n \<equiv> Abs_Frac (n, 1)"
   206 
   207 definition inverse_frac :: "'a \<Rightarrow> 'a" where
   208 "inverse_frac q \<equiv> frac (denom q) (num q)"
   209 
   210 definition less_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   211 [nitpick_simp]:
   212 "less_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) < 0"
   213 
   214 definition less_eq_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   215 [nitpick_simp]:
   216 "less_eq_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) \<le> 0"
   217 
   218 definition of_frac :: "'a \<Rightarrow> 'b\<Colon>{inverse,ring_1}" where
   219 "of_frac q \<equiv> of_int (num q) / of_int (denom q)"
   220 
   221 use "Tools/Nitpick/kodkod.ML"
   222 use "Tools/Nitpick/kodkod_sat.ML"
   223 use "Tools/Nitpick/nitpick_util.ML"
   224 use "Tools/Nitpick/nitpick_hol.ML"
   225 use "Tools/Nitpick/nitpick_mono.ML"
   226 use "Tools/Nitpick/nitpick_preproc.ML"
   227 use "Tools/Nitpick/nitpick_scope.ML"
   228 use "Tools/Nitpick/nitpick_peephole.ML"
   229 use "Tools/Nitpick/nitpick_rep.ML"
   230 use "Tools/Nitpick/nitpick_nut.ML"
   231 use "Tools/Nitpick/nitpick_kodkod.ML"
   232 use "Tools/Nitpick/nitpick_model.ML"
   233 use "Tools/Nitpick/nitpick.ML"
   234 use "Tools/Nitpick/nitpick_isar.ML"
   235 use "Tools/Nitpick/nitpick_tests.ML"
   236 use "Tools/Nitpick/nitrox.ML"
   237 
   238 setup {* Nitpick_Isar.setup *}
   239 
   240 hide_const (open) unknown is_unknown bisim bisim_iterator_max Quot safe_The
   241     FunBox PairBox Word prod refl' wf' wf_wfrec wf_wfrec' wfrec' card' setsum'
   242     fold_graph' nat_gcd nat_lcm int_gcd int_lcm Frac Abs_Frac Rep_Frac zero_frac
   243     one_frac num denom norm_frac frac plus_frac times_frac uminus_frac
   244     number_of_frac inverse_frac less_frac less_eq_frac of_frac
   245 hide_type (open) iota bisim_iterator fun_box pair_box unsigned_bit signed_bit
   246     word
   247 hide_fact (open) Ex1_unfold rtrancl_unfold rtranclp_unfold tranclp_unfold
   248     prod_def refl'_def wf'_def wf_wfrec'_def wfrec'_def card'_def setsum'_def
   249     fold_graph'_def The_psimp Eps_psimp unit_case_unfold nat_case_unfold
   250     list_size_simp nat_gcd_def nat_lcm_def int_gcd_def int_lcm_def Frac_def
   251     zero_frac_def one_frac_def num_def denom_def norm_frac_def frac_def
   252     plus_frac_def times_frac_def uminus_frac_def number_of_frac_def
   253     inverse_frac_def less_frac_def less_eq_frac_def of_frac_def
   254 
   255 end