src/Pure/sign.ML
author haftmann
Thu Nov 20 14:55:25 2008 +0100 (2008-11-20)
changeset 28861 f53abb0733ee
parent 28792 1d80cee865de
child 28863 32e83a854e5e
permissions -rw-r--r--
using name bindings
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN =
    10 sig
    11   val rep_sg: theory ->
    12    {naming: NameSpace.naming,
    13     syn: Syntax.syntax,
    14     tsig: Type.tsig,
    15     consts: Consts.T}
    16   val naming_of: theory -> NameSpace.naming
    17   val base_name: string -> bstring
    18   val name_decl: (string * 'a -> theory -> 'b * theory)
    19     -> Name.binding * 'a -> theory -> (string * 'b) * theory
    20   val full_name: theory -> bstring -> string
    21   val full_binding: theory -> Name.binding -> string
    22   val full_name_path: theory -> string -> bstring -> string
    23   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    24   val syn_of: theory -> Syntax.syntax
    25   val tsig_of: theory -> Type.tsig
    26   val classes_of: theory -> Sorts.algebra
    27   val all_classes: theory -> class list
    28   val super_classes: theory -> class -> class list
    29   val minimize_sort: theory -> sort -> sort
    30   val complete_sort: theory -> sort -> sort
    31   val defaultS: theory -> sort
    32   val subsort: theory -> sort * sort -> bool
    33   val of_sort: theory -> typ * sort -> bool
    34   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    35   val is_logtype: theory -> string -> bool
    36   val typ_instance: theory -> typ * typ -> bool
    37   val typ_equiv: theory -> typ * typ -> bool
    38   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    39   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    40   val consts_of: theory -> Consts.T
    41   val the_const_constraint: theory -> string -> typ
    42   val const_type: theory -> string -> typ option
    43   val the_const_type: theory -> string -> typ
    44   val declared_tyname: theory -> string -> bool
    45   val declared_const: theory -> string -> bool
    46   val const_monomorphic: theory -> string -> bool
    47   val const_syntax_name: theory -> string -> string
    48   val const_typargs: theory -> string * typ -> typ list
    49   val const_instance: theory -> string * typ list -> typ
    50   val mk_const: theory -> string * typ list -> term
    51   val class_space: theory -> NameSpace.T
    52   val type_space: theory -> NameSpace.T
    53   val const_space: theory -> NameSpace.T
    54   val intern_class: theory -> xstring -> string
    55   val extern_class: theory -> string -> xstring
    56   val intern_type: theory -> xstring -> string
    57   val extern_type: theory -> string -> xstring
    58   val intern_const: theory -> xstring -> string
    59   val extern_const: theory -> string -> xstring
    60   val intern_sort: theory -> sort -> sort
    61   val extern_sort: theory -> sort -> sort
    62   val intern_typ: theory -> typ -> typ
    63   val extern_typ: theory -> typ -> typ
    64   val intern_term: theory -> term -> term
    65   val extern_term: (string -> xstring) -> theory -> term -> term
    66   val intern_tycons: theory -> typ -> typ
    67   val arity_number: theory -> string -> int
    68   val arity_sorts: theory -> string -> sort -> sort list
    69   val certify_class: theory -> class -> class
    70   val certify_sort: theory -> sort -> sort
    71   val certify_typ: theory -> typ -> typ
    72   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    73   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    74   val certify_term: theory -> term -> term * typ * int
    75   val certify_prop: theory -> term -> term * typ * int
    76   val cert_term: theory -> term -> term
    77   val cert_prop: theory -> term -> term
    78   val no_frees: Pretty.pp -> term -> term
    79   val no_vars: Pretty.pp -> term -> term
    80   val cert_def: Proof.context -> term -> (string * typ) * term
    81   val read_class: theory -> xstring -> class
    82   val read_arity: theory -> xstring * string list * string -> arity
    83   val cert_arity: theory -> arity -> arity
    84   val add_defsort: string -> theory -> theory
    85   val add_defsort_i: sort -> theory -> theory
    86   val add_types: (bstring * int * mixfix) list -> theory -> theory
    87   val add_nonterminals: bstring list -> theory -> theory
    88   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    89   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    90   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    91   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    92   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    93   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    94   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    95   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    96   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    97   val declare_const: Properties.T -> (Name.binding * typ) * mixfix -> theory -> term * theory
    98   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    99   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
   100   val add_abbrev: string -> Properties.T -> Name.binding * term -> theory -> (term * term) * theory
   101   val revert_abbrev: string -> string -> theory -> theory
   102   val add_const_constraint: string * typ option -> theory -> theory
   103   val primitive_class: string * class list -> theory -> theory
   104   val primitive_classrel: class * class -> theory -> theory
   105   val primitive_arity: arity -> theory -> theory
   106   val add_trfuns:
   107     (string * (ast list -> ast)) list *
   108     (string * (term list -> term)) list *
   109     (string * (term list -> term)) list *
   110     (string * (ast list -> ast)) list -> theory -> theory
   111   val add_trfunsT:
   112     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   113   val add_advanced_trfuns:
   114     (string * (Proof.context -> ast list -> ast)) list *
   115     (string * (Proof.context -> term list -> term)) list *
   116     (string * (Proof.context -> term list -> term)) list *
   117     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   118   val add_advanced_trfunsT:
   119     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   120   val add_tokentrfuns:
   121     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   122   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   123     -> theory -> theory
   124   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   125   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   126   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   127   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   128   val add_path: string -> theory -> theory
   129   val parent_path: theory -> theory
   130   val root_path: theory -> theory
   131   val absolute_path: theory -> theory
   132   val local_path: theory -> theory
   133   val no_base_names: theory -> theory
   134   val qualified_names: theory -> theory
   135   val sticky_prefix: string -> theory -> theory
   136   val restore_naming: theory -> theory -> theory
   137   val hide_class: bool -> string -> theory -> theory
   138   val hide_type: bool -> string -> theory -> theory
   139   val hide_const: bool -> string -> theory -> theory
   140 end
   141 
   142 structure Sign: SIGN =
   143 struct
   144 
   145 (** datatype sign **)
   146 
   147 datatype sign = Sign of
   148  {naming: NameSpace.naming,     (*common naming conventions*)
   149   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   150   tsig: Type.tsig,              (*order-sorted signature of types*)
   151   consts: Consts.T};            (*polymorphic constants*)
   152 
   153 fun make_sign (naming, syn, tsig, consts) =
   154   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   155 
   156 structure SignData = TheoryDataFun
   157 (
   158   type T = sign;
   159   val copy = I;
   160   fun extend (Sign {syn, tsig, consts, ...}) =
   161     make_sign (NameSpace.default_naming, syn, tsig, consts);
   162 
   163   val empty =
   164     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   165 
   166   fun merge pp (sign1, sign2) =
   167     let
   168       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   169       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   170 
   171       val naming = NameSpace.default_naming;
   172       val syn = Syntax.merge_syntaxes syn1 syn2;
   173       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   174       val consts = Consts.merge (consts1, consts2);
   175     in make_sign (naming, syn, tsig, consts) end;
   176 );
   177 
   178 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   179 
   180 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   181   make_sign (f (naming, syn, tsig, consts)));
   182 
   183 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   184 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   185 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   186 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   187 
   188 
   189 (* naming *)
   190 
   191 val naming_of = #naming o rep_sg;
   192 val base_name = NameSpace.base;
   193 
   194 fun name_decl decl (b, x) thy =
   195   let
   196     val naming = naming_of thy;
   197     val (naming', name) = Name.namify naming b;
   198   in
   199     thy
   200     |> map_naming (K naming')
   201     |> decl (Name.name_of b, x)
   202     |>> pair name
   203     ||> map_naming (K naming)
   204   end;
   205 
   206 val namify = Name.namify o naming_of;
   207 val full_name = NameSpace.full o naming_of;
   208 val full_binding = NameSpace.full_binding o naming_of;
   209 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   210 val declare_name = NameSpace.declare o naming_of;
   211 
   212 
   213 (* syntax *)
   214 
   215 val syn_of = #syn o rep_sg;
   216 
   217 
   218 (* type signature *)
   219 
   220 val tsig_of = #tsig o rep_sg;
   221 
   222 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   223 val all_classes = Sorts.all_classes o classes_of;
   224 val super_classes = Sorts.super_classes o classes_of;
   225 val minimize_sort = Sorts.minimize_sort o classes_of;
   226 val complete_sort = Sorts.complete_sort o classes_of;
   227 
   228 val defaultS = Type.defaultS o tsig_of;
   229 val subsort = Type.subsort o tsig_of;
   230 val of_sort = Type.of_sort o tsig_of;
   231 val witness_sorts = Type.witness_sorts o tsig_of;
   232 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   233 
   234 val typ_instance = Type.typ_instance o tsig_of;
   235 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   236 val typ_match = Type.typ_match o tsig_of;
   237 val typ_unify = Type.unify o tsig_of;
   238 
   239 
   240 (* polymorphic constants *)
   241 
   242 val consts_of = #consts o rep_sg;
   243 val the_const_constraint = Consts.the_constraint o consts_of;
   244 val the_const_type = Consts.the_type o consts_of;
   245 val const_type = try o the_const_type;
   246 val const_monomorphic = Consts.is_monomorphic o consts_of;
   247 val const_syntax_name = Consts.syntax_name o consts_of;
   248 val const_typargs = Consts.typargs o consts_of;
   249 val const_instance = Consts.instance o consts_of;
   250 
   251 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   252 
   253 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   254 val declared_const = can o the_const_constraint;
   255 
   256 
   257 
   258 (** intern / extern names **)
   259 
   260 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   261 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   262 val const_space = Consts.space_of o consts_of;
   263 
   264 val intern_class = NameSpace.intern o class_space;
   265 val extern_class = NameSpace.extern o class_space;
   266 val intern_type = NameSpace.intern o type_space;
   267 val extern_type = NameSpace.extern o type_space;
   268 val intern_const = NameSpace.intern o const_space;
   269 val extern_const = NameSpace.extern o const_space;
   270 
   271 val intern_sort = map o intern_class;
   272 val extern_sort = map o extern_class;
   273 
   274 local
   275 
   276 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   277   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   278   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   279 
   280 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   281   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   282   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   283   | map_term _ _ _ (t as Bound _) = t
   284   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   285   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   286 
   287 val add_classesT = Term.fold_atyps
   288   (fn TFree (_, S) => fold (insert (op =)) S
   289     | TVar (_, S) => fold (insert (op =)) S
   290     | _ => I);
   291 
   292 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   293   | add_tyconsT _ = I;
   294 
   295 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   296 
   297 fun mapping add_names f t =
   298   let
   299     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   300     val tab = map_filter f' (add_names t []);
   301     fun get x = the_default x (AList.lookup (op =) tab x);
   302   in get end;
   303 
   304 fun typ_mapping f g thy T =
   305   T |> map_typ
   306     (mapping add_classesT (f thy) T)
   307     (mapping add_tyconsT (g thy) T);
   308 
   309 fun term_mapping f g h thy t =
   310   t |> map_term
   311     (mapping (Term.fold_types add_classesT) (f thy) t)
   312     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   313     (mapping add_consts (h thy) t);
   314 
   315 in
   316 
   317 val intern_typ = typ_mapping intern_class intern_type;
   318 val extern_typ = typ_mapping extern_class extern_type;
   319 val intern_term = term_mapping intern_class intern_type intern_const;
   320 fun extern_term h = term_mapping extern_class extern_type (K h);
   321 val intern_tycons = typ_mapping (K I) intern_type;
   322 
   323 end;
   324 
   325 
   326 
   327 (** certify entities **)    (*exception TYPE*)
   328 
   329 (* certify wrt. type signature *)
   330 
   331 val arity_number = Type.arity_number o tsig_of;
   332 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   333 
   334 val certify_class         = Type.cert_class o tsig_of;
   335 val certify_sort          = Type.cert_sort o tsig_of;
   336 val certify_typ           = Type.cert_typ o tsig_of;
   337 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   338 
   339 
   340 (* certify term/prop *)
   341 
   342 local
   343 
   344 fun type_check pp tm =
   345   let
   346     fun err_appl why bs t T u U =
   347       let
   348         val xs = map Free bs;           (*we do not rename here*)
   349         val t' = subst_bounds (xs, t);
   350         val u' = subst_bounds (xs, u);
   351         val msg = cat_lines
   352           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   353       in raise TYPE (msg, [T, U], [t', u']) end;
   354 
   355     fun typ_of (_, Const (_, T)) = T
   356       | typ_of (_, Free  (_, T)) = T
   357       | typ_of (_, Var (_, T)) = T
   358       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   359           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   360       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   361       | typ_of (bs, t $ u) =
   362           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   363             (case T of
   364               Type ("fun", [T1, T2]) =>
   365                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   366             | _ => err_appl "Operator not of function type" bs t T u U)
   367           end;
   368   in typ_of ([], tm) end;
   369 
   370 fun err msg = raise TYPE (msg, [], []);
   371 
   372 fun check_vars (t $ u) = (check_vars t; check_vars u)
   373   | check_vars (Abs (_, _, t)) = check_vars t
   374   | check_vars (Free (x, _)) =
   375       if NameSpace.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   376   | check_vars (Var (xi as (_, i), _)) =
   377       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   378   | check_vars _ = ();
   379 
   380 in
   381 
   382 fun certify' prop pp do_expand consts thy tm =
   383   let
   384     val _ = check_vars tm;
   385     val tm' = Term.map_types (certify_typ thy) tm;
   386     val T = type_check pp tm';
   387     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   388     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   389   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   390 
   391 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   392 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   393 
   394 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   395 val cert_term = #1 oo certify_term;
   396 val cert_prop = #1 oo certify_prop;
   397 
   398 end;
   399 
   400 
   401 (* specifications *)
   402 
   403 fun no_variables kind add addT mk mkT pp tm =
   404   (case (add tm [], addT tm []) of
   405     ([], []) => tm
   406   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   407       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   408        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   409 
   410 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   411 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   412 
   413 fun cert_def ctxt tm =
   414   let val ((lhs, rhs), _) = tm
   415     |> no_vars (Syntax.pp ctxt)
   416     |> Logic.strip_imp_concl
   417     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   418   in (Term.dest_Const (Term.head_of lhs), rhs) end
   419   handle TERM (msg, _) => error msg;
   420 
   421 
   422 
   423 (** read and certify entities **)    (*exception ERROR*)
   424 
   425 (* classes *)
   426 
   427 fun read_class thy c = certify_class thy (intern_class thy c)
   428   handle TYPE (msg, _, _) => error msg;
   429 
   430 
   431 (* type arities *)
   432 
   433 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   434   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   435   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   436 
   437 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   438 val cert_arity = prep_arity (K I) certify_sort;
   439 
   440 
   441 
   442 (** signature extension functions **)  (*exception ERROR/TYPE*)
   443 
   444 (* add default sort *)
   445 
   446 fun gen_add_defsort prep_sort s thy =
   447   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   448 
   449 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   450 val add_defsort_i = gen_add_defsort certify_sort;
   451 
   452 
   453 (* add type constructors *)
   454 
   455 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   456   let
   457     val syn' = Syntax.update_type_gram types syn;
   458     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   459     val tags = [(Markup.theory_nameN, Context.theory_name thy)];
   460     val tsig' = fold (Type.add_type naming tags) decls tsig;
   461   in (naming, syn', tsig', consts) end);
   462 
   463 
   464 (* add nonterminals *)
   465 
   466 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   467   let
   468     val syn' = Syntax.update_consts ns syn;
   469     val tsig' = fold (Type.add_nonterminal naming []) ns tsig;
   470   in (naming, syn', tsig', consts) end);
   471 
   472 
   473 (* add type abbreviations *)
   474 
   475 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   476   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   477     let
   478       val ctxt = ProofContext.init thy;
   479       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   480       val a' = Syntax.type_name a mx;
   481       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   482         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   483       val tsig' = Type.add_abbrev naming [] abbr tsig;
   484     in (naming, syn', tsig', consts) end);
   485 
   486 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   487 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   488 
   489 
   490 (* modify syntax *)
   491 
   492 fun gen_syntax change_gram parse_typ mode args thy =
   493   let
   494     val ctxt = ProofContext.init thy;
   495     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   496       handle ERROR msg =>
   497         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   498   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   499 
   500 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   501 
   502 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   503 val add_modesyntax_i = gen_add_syntax (K I);
   504 val add_syntax = add_modesyntax Syntax.mode_default;
   505 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   506 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   507 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   508 
   509 fun notation add mode args thy =
   510   let
   511     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   512     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   513       | const_syntax _ = NONE;
   514   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   515 
   516 
   517 (* add constants *)
   518 
   519 local
   520 
   521 fun gen_add_consts parse_typ authentic tags raw_args thy =
   522   let
   523     val ctxt = ProofContext.init thy;
   524     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   525     fun prep (raw_b, raw_T, raw_mx) =
   526       let
   527         val (mx_name, mx) = Syntax.const_mixfix (Name.name_of raw_b) raw_mx;
   528         val b = Name.map_name (K mx_name) raw_b;
   529         val c = full_binding thy b;
   530         val c_syn = if authentic then Syntax.constN ^ c else Name.name_of b;
   531         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   532           cat_error msg ("in declaration of constant " ^ quote (Name.display b));
   533         val T' = Logic.varifyT T;
   534       in ((b, T'), (c_syn, T', mx), Const (c, T)) end;
   535     val args = map prep raw_args;
   536     val tags' = tags |> Properties.put (Markup.theory_nameN, Context.theory_name thy);
   537   in
   538     thy
   539     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   540     |> add_syntax_i (map #2 args)
   541     |> pair (map #3 args)
   542   end;
   543 
   544 fun bindify (name, T, mx) = (Name.binding name, T, mx);
   545 
   546 in
   547 
   548 fun add_consts args = snd o gen_add_consts Syntax.parse_typ false [] (map bindify args);
   549 fun add_consts_i args = snd o gen_add_consts (K I) false [] (map bindify args);
   550 
   551 fun declare_const tags ((b, T), mx) thy =
   552   let
   553     val pos = Name.pos_of b;
   554     val tags' = Position.default_properties pos tags;
   555     val ([const as Const (c, _)], thy') = gen_add_consts (K I) true tags' [(b, T, mx)] thy;
   556     val _ = Position.report (Markup.const_decl c) pos;
   557   in (const, thy') end;
   558 
   559 end;
   560 
   561 
   562 (* abbreviations *)
   563 
   564 fun add_abbrev mode tags (b, raw_t) thy =
   565   let
   566     val pp = Syntax.pp_global thy;
   567     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   568     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   569       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Name.display b));
   570     val (res, consts') = consts_of thy
   571       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (b, t);
   572   in (res, thy |> map_consts (K consts')) end;
   573 
   574 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   575 
   576 
   577 (* add constraints *)
   578 
   579 fun add_const_constraint (c, opt_T) thy =
   580   let
   581     fun prepT raw_T =
   582       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   583       in cert_term thy (Const (c, T)); T end
   584       handle TYPE (msg, _, _) => error msg;
   585   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   586 
   587 
   588 (* primitive classes and arities *)
   589 
   590 fun primitive_class (bclass, classes) thy =
   591   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   592     let
   593       val syn' = Syntax.update_consts [bclass] syn;
   594       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   595     in (naming, syn', tsig', consts) end)
   596   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   597 
   598 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   599 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   600 
   601 
   602 (* add translation functions *)
   603 
   604 local
   605 
   606 fun mk trs = map Syntax.mk_trfun trs;
   607 
   608 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   609   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   610 
   611 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   612 
   613 in
   614 
   615 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   616 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   617 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   618 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   619 
   620 end;
   621 
   622 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   623 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   624 
   625 
   626 (* translation rules *)
   627 
   628 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   629   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   630   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   631 
   632 val add_trrules = gen_trrules Syntax.update_trrules;
   633 val del_trrules = gen_trrules Syntax.remove_trrules;
   634 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   635 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   636 
   637 
   638 (* naming *)
   639 
   640 val add_path        = map_naming o NameSpace.add_path;
   641 val no_base_names   = map_naming NameSpace.no_base_names;
   642 val qualified_names = map_naming NameSpace.qualified_names;
   643 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   644 val restore_naming  = map_naming o K o naming_of;
   645 
   646 val parent_path   = add_path "..";
   647 val root_path     = add_path "/";
   648 val absolute_path = add_path "//";
   649 
   650 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   651 
   652 
   653 (* hide names *)
   654 
   655 val hide_class = map_tsig oo Type.hide_class;
   656 val hide_type = map_tsig oo Type.hide_type;
   657 val hide_const = map_consts oo Consts.hide;
   658 
   659 end;