src/HOL/Orderings.thy
author haftmann
Sun Feb 26 15:28:48 2012 +0100 (2012-02-26)
changeset 46689 f559866a7aa2
parent 46631 2c5c003cee35
child 46691 72d81e789106
permissions -rw-r--r--
marked candidates for rule declarations
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* Abstract orderings *}
     6 
     7 theory Orderings
     8 imports HOL
     9 uses
    10   "~~/src/Provers/order.ML"
    11   "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    12 begin
    13 
    14 subsection {* Syntactic orders *}
    15 
    16 class ord =
    17   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    18     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    19 begin
    20 
    21 notation
    22   less_eq  ("op <=") and
    23   less_eq  ("(_/ <= _)" [51, 51] 50) and
    24   less  ("op <") and
    25   less  ("(_/ < _)"  [51, 51] 50)
    26   
    27 notation (xsymbols)
    28   less_eq  ("op \<le>") and
    29   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    30 
    31 notation (HTML output)
    32   less_eq  ("op \<le>") and
    33   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    34 
    35 abbreviation (input)
    36   greater_eq  (infix ">=" 50) where
    37   "x >= y \<equiv> y <= x"
    38 
    39 notation (input)
    40   greater_eq  (infix "\<ge>" 50)
    41 
    42 abbreviation (input)
    43   greater  (infix ">" 50) where
    44   "x > y \<equiv> y < x"
    45 
    46 end
    47 
    48 
    49 subsection {* Quasi orders *}
    50 
    51 class preorder = ord +
    52   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
    53   and order_refl [iff]: "x \<le> x"
    54   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
    55 begin
    56 
    57 text {* Reflexivity. *}
    58 
    59 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
    60     -- {* This form is useful with the classical reasoner. *}
    61 by (erule ssubst) (rule order_refl)
    62 
    63 lemma less_irrefl [iff]: "\<not> x < x"
    64 by (simp add: less_le_not_le)
    65 
    66 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
    67 unfolding less_le_not_le by blast
    68 
    69 
    70 text {* Asymmetry. *}
    71 
    72 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
    73 by (simp add: less_le_not_le)
    74 
    75 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
    76 by (drule less_not_sym, erule contrapos_np) simp
    77 
    78 
    79 text {* Transitivity. *}
    80 
    81 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    82 by (auto simp add: less_le_not_le intro: order_trans) 
    83 
    84 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    85 by (auto simp add: less_le_not_le intro: order_trans) 
    86 
    87 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
    88 by (auto simp add: less_le_not_le intro: order_trans) 
    89 
    90 
    91 text {* Useful for simplification, but too risky to include by default. *}
    92 
    93 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
    94 by (blast elim: less_asym)
    95 
    96 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
    97 by (blast elim: less_asym)
    98 
    99 
   100 text {* Transitivity rules for calculational reasoning *}
   101 
   102 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   103 by (rule less_asym)
   104 
   105 
   106 text {* Dual order *}
   107 
   108 lemma dual_preorder:
   109   "class.preorder (op \<ge>) (op >)"
   110 proof qed (auto simp add: less_le_not_le intro: order_trans)
   111 
   112 end
   113 
   114 
   115 subsection {* Partial orders *}
   116 
   117 class order = preorder +
   118   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   119 begin
   120 
   121 text {* Reflexivity. *}
   122 
   123 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   124 by (auto simp add: less_le_not_le intro: antisym)
   125 
   126 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   127     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
   128 by (simp add: less_le) blast
   129 
   130 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   131 unfolding less_le by blast
   132 
   133 
   134 text {* Useful for simplification, but too risky to include by default. *}
   135 
   136 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   137 by auto
   138 
   139 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   140 by auto
   141 
   142 
   143 text {* Transitivity rules for calculational reasoning *}
   144 
   145 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   146 by (simp add: less_le)
   147 
   148 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   149 by (simp add: less_le)
   150 
   151 
   152 text {* Asymmetry. *}
   153 
   154 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   155 by (blast intro: antisym)
   156 
   157 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   158 by (blast intro: antisym)
   159 
   160 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   161 by (erule contrapos_pn, erule subst, rule less_irrefl)
   162 
   163 
   164 text {* Least value operator *}
   165 
   166 definition (in ord)
   167   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   168   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   169 
   170 lemma Least_equality:
   171   assumes "P x"
   172     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   173   shows "Least P = x"
   174 unfolding Least_def by (rule the_equality)
   175   (blast intro: assms antisym)+
   176 
   177 lemma LeastI2_order:
   178   assumes "P x"
   179     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   180     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   181   shows "Q (Least P)"
   182 unfolding Least_def by (rule theI2)
   183   (blast intro: assms antisym)+
   184 
   185 
   186 text {* Dual order *}
   187 
   188 lemma dual_order:
   189   "class.order (op \<ge>) (op >)"
   190 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   191 
   192 end
   193 
   194 
   195 subsection {* Linear (total) orders *}
   196 
   197 class linorder = order +
   198   assumes linear: "x \<le> y \<or> y \<le> x"
   199 begin
   200 
   201 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   202 unfolding less_le using less_le linear by blast
   203 
   204 lemma le_less_linear: "x \<le> y \<or> y < x"
   205 by (simp add: le_less less_linear)
   206 
   207 lemma le_cases [case_names le ge]:
   208   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   209 using linear by blast
   210 
   211 lemma linorder_cases [case_names less equal greater]:
   212   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   213 using less_linear by blast
   214 
   215 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   216 apply (simp add: less_le)
   217 using linear apply (blast intro: antisym)
   218 done
   219 
   220 lemma not_less_iff_gr_or_eq:
   221  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   222 apply(simp add:not_less le_less)
   223 apply blast
   224 done
   225 
   226 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   227 apply (simp add: less_le)
   228 using linear apply (blast intro: antisym)
   229 done
   230 
   231 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   232 by (cut_tac x = x and y = y in less_linear, auto)
   233 
   234 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   235 by (simp add: neq_iff) blast
   236 
   237 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   238 by (blast intro: antisym dest: not_less [THEN iffD1])
   239 
   240 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   241 by (blast intro: antisym dest: not_less [THEN iffD1])
   242 
   243 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   244 by (blast intro: antisym dest: not_less [THEN iffD1])
   245 
   246 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   247 unfolding not_less .
   248 
   249 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   250 unfolding not_less .
   251 
   252 (*FIXME inappropriate name (or delete altogether)*)
   253 lemma not_leE: "\<not> y \<le> x \<Longrightarrow> x < y"
   254 unfolding not_le .
   255 
   256 
   257 text {* Dual order *}
   258 
   259 lemma dual_linorder:
   260   "class.linorder (op \<ge>) (op >)"
   261 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   262 
   263 
   264 text {* min/max *}
   265 
   266 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   267   "min a b = (if a \<le> b then a else b)"
   268 
   269 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   270   "max a b = (if a \<le> b then b else a)"
   271 
   272 lemma min_le_iff_disj:
   273   "min x y \<le> z \<longleftrightarrow> x \<le> z \<or> y \<le> z"
   274 unfolding min_def using linear by (auto intro: order_trans)
   275 
   276 lemma le_max_iff_disj:
   277   "z \<le> max x y \<longleftrightarrow> z \<le> x \<or> z \<le> y"
   278 unfolding max_def using linear by (auto intro: order_trans)
   279 
   280 lemma min_less_iff_disj:
   281   "min x y < z \<longleftrightarrow> x < z \<or> y < z"
   282 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   283 
   284 lemma less_max_iff_disj:
   285   "z < max x y \<longleftrightarrow> z < x \<or> z < y"
   286 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   287 
   288 lemma min_less_iff_conj [simp]:
   289   "z < min x y \<longleftrightarrow> z < x \<and> z < y"
   290 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   291 
   292 lemma max_less_iff_conj [simp]:
   293   "max x y < z \<longleftrightarrow> x < z \<and> y < z"
   294 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   295 
   296 lemma split_min [no_atp]:
   297   "P (min i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P i) \<and> (\<not> i \<le> j \<longrightarrow> P j)"
   298 by (simp add: min_def)
   299 
   300 lemma split_max [no_atp]:
   301   "P (max i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P j) \<and> (\<not> i \<le> j \<longrightarrow> P i)"
   302 by (simp add: max_def)
   303 
   304 end
   305 
   306 
   307 subsection {* Reasoning tools setup *}
   308 
   309 ML {*
   310 
   311 signature ORDERS =
   312 sig
   313   val print_structures: Proof.context -> unit
   314   val setup: theory -> theory
   315   val order_tac: Proof.context -> thm list -> int -> tactic
   316 end;
   317 
   318 structure Orders: ORDERS =
   319 struct
   320 
   321 (** Theory and context data **)
   322 
   323 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   324   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   325 
   326 structure Data = Generic_Data
   327 (
   328   type T = ((string * term list) * Order_Tac.less_arith) list;
   329     (* Order structures:
   330        identifier of the structure, list of operations and record of theorems
   331        needed to set up the transitivity reasoner,
   332        identifier and operations identify the structure uniquely. *)
   333   val empty = [];
   334   val extend = I;
   335   fun merge data = AList.join struct_eq (K fst) data;
   336 );
   337 
   338 fun print_structures ctxt =
   339   let
   340     val structs = Data.get (Context.Proof ctxt);
   341     fun pretty_term t = Pretty.block
   342       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   343         Pretty.str "::", Pretty.brk 1,
   344         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   345     fun pretty_struct ((s, ts), _) = Pretty.block
   346       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   347        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   348   in
   349     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   350   end;
   351 
   352 
   353 (** Method **)
   354 
   355 fun struct_tac ((s, [eq, le, less]), thms) ctxt prems =
   356   let
   357     fun decomp thy (@{const Trueprop} $ t) =
   358       let
   359         fun excluded t =
   360           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   361           let val T = type_of t
   362           in
   363             T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   364           end;
   365         fun rel (bin_op $ t1 $ t2) =
   366               if excluded t1 then NONE
   367               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   368               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   369               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   370               else NONE
   371           | rel _ = NONE;
   372         fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   373               of NONE => NONE
   374                | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   375           | dec x = rel x;
   376       in dec t end
   377       | decomp thy _ = NONE;
   378   in
   379     case s of
   380       "order" => Order_Tac.partial_tac decomp thms ctxt prems
   381     | "linorder" => Order_Tac.linear_tac decomp thms ctxt prems
   382     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   383   end
   384 
   385 fun order_tac ctxt prems =
   386   FIRST' (map (fn s => CHANGED o struct_tac s ctxt prems) (Data.get (Context.Proof ctxt)));
   387 
   388 
   389 (** Attribute **)
   390 
   391 fun add_struct_thm s tag =
   392   Thm.declaration_attribute
   393     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   394 fun del_struct s =
   395   Thm.declaration_attribute
   396     (fn _ => Data.map (AList.delete struct_eq s));
   397 
   398 val attrib_setup =
   399   Attrib.setup @{binding order}
   400     (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   401       Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   402       Scan.repeat Args.term
   403       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   404            | ((NONE, n), ts) => del_struct (n, ts)))
   405     "theorems controlling transitivity reasoner";
   406 
   407 
   408 (** Diagnostic command **)
   409 
   410 val _ =
   411   Outer_Syntax.improper_command "print_orders"
   412     "print order structures available to transitivity reasoner" Keyword.diag
   413     (Scan.succeed (Toplevel.no_timing o Toplevel.unknown_context o
   414         Toplevel.keep (print_structures o Toplevel.context_of)));
   415 
   416 
   417 (** Setup **)
   418 
   419 val setup =
   420   Method.setup @{binding order} (Scan.succeed (fn ctxt => SIMPLE_METHOD' (order_tac ctxt [])))
   421     "transitivity reasoner" #>
   422   attrib_setup;
   423 
   424 end;
   425 
   426 *}
   427 
   428 setup Orders.setup
   429 
   430 
   431 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   432 
   433 context order
   434 begin
   435 
   436 (* The type constraint on @{term op =} below is necessary since the operation
   437    is not a parameter of the locale. *)
   438 
   439 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   440   
   441 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   442   
   443 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   444   
   445 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   446 
   447 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   448 
   449 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   450 
   451 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   452   
   453 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   454   
   455 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   456 
   457 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   458 
   459 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   460 
   461 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   462 
   463 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   464 
   465 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   466 
   467 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   468 
   469 end
   470 
   471 context linorder
   472 begin
   473 
   474 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   475 
   476 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   477 
   478 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   479 
   480 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   481 
   482 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   483 
   484 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   485 
   486 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   487 
   488 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   489 
   490 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   491 
   492 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   493 
   494 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   495 
   496 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   497 
   498 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   499 
   500 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   501 
   502 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   503 
   504 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   505 
   506 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   507 
   508 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   509 
   510 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   511 
   512 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   513 
   514 end
   515 
   516 
   517 setup {*
   518 let
   519 
   520 fun prp t thm = Thm.prop_of thm = t;  (* FIXME aconv!? *)
   521 
   522 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   523   let val prems = Simplifier.prems_of ss;
   524       val less = Const (@{const_name less}, T);
   525       val t = HOLogic.mk_Trueprop(le $ s $ r);
   526   in case find_first (prp t) prems of
   527        NONE =>
   528          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   529          in case find_first (prp t) prems of
   530               NONE => NONE
   531             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   532          end
   533      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   534   end
   535   handle THM _ => NONE;
   536 
   537 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   538   let val prems = Simplifier.prems_of ss;
   539       val le = Const (@{const_name less_eq}, T);
   540       val t = HOLogic.mk_Trueprop(le $ r $ s);
   541   in case find_first (prp t) prems of
   542        NONE =>
   543          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   544          in case find_first (prp t) prems of
   545               NONE => NONE
   546             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   547          end
   548      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   549   end
   550   handle THM _ => NONE;
   551 
   552 fun add_simprocs procs thy =
   553   Simplifier.map_simpset_global (fn ss => ss
   554     addsimprocs (map (fn (name, raw_ts, proc) =>
   555       Simplifier.simproc_global thy name raw_ts proc) procs)) thy;
   556 
   557 fun add_solver name tac =
   558   Simplifier.map_simpset_global (fn ss => ss addSolver
   559     mk_solver name (fn ss => tac (Simplifier.the_context ss) (Simplifier.prems_of ss)));
   560 
   561 in
   562   add_simprocs [
   563        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   564        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   565      ]
   566   #> add_solver "Transitivity" Orders.order_tac
   567   (* Adding the transitivity reasoners also as safe solvers showed a slight
   568      speed up, but the reasoning strength appears to be not higher (at least
   569      no breaking of additional proofs in the entire HOL distribution, as
   570      of 5 March 2004, was observed). *)
   571 end
   572 *}
   573 
   574 
   575 subsection {* Bounded quantifiers *}
   576 
   577 syntax
   578   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   579   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   580   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   581   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   582 
   583   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   584   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   585   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   586   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   587 
   588 syntax (xsymbols)
   589   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   590   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   591   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   592   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   593 
   594   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   595   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   596   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   597   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   598 
   599 syntax (HOL)
   600   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   601   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   602   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   603   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   604 
   605 syntax (HTML output)
   606   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   607   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   608   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   609   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   610 
   611   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   612   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   613   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   614   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   615 
   616 translations
   617   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   618   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   619   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   620   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   621   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   622   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   623   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   624   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   625 
   626 print_translation {*
   627 let
   628   val All_binder = Mixfix.binder_name @{const_syntax All};
   629   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   630   val impl = @{const_syntax HOL.implies};
   631   val conj = @{const_syntax HOL.conj};
   632   val less = @{const_syntax less};
   633   val less_eq = @{const_syntax less_eq};
   634 
   635   val trans =
   636    [((All_binder, impl, less),
   637     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   638     ((All_binder, impl, less_eq),
   639     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   640     ((Ex_binder, conj, less),
   641     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   642     ((Ex_binder, conj, less_eq),
   643     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   644 
   645   fun matches_bound v t =
   646     (case t of
   647       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   648     | _ => false);
   649   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   650   fun mk v c n P = Syntax.const c $ Syntax_Trans.mark_bound v $ n $ P;
   651 
   652   fun tr' q = (q,
   653     fn [Const (@{syntax_const "_bound"}, _) $ Free (v, _),
   654         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   655         (case AList.lookup (op =) trans (q, c, d) of
   656           NONE => raise Match
   657         | SOME (l, g) =>
   658             if matches_bound v t andalso not (contains_var v u) then mk v l u P
   659             else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   660             else raise Match)
   661      | _ => raise Match);
   662 in [tr' All_binder, tr' Ex_binder] end
   663 *}
   664 
   665 
   666 subsection {* Transitivity reasoning *}
   667 
   668 context ord
   669 begin
   670 
   671 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   672   by (rule subst)
   673 
   674 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   675   by (rule ssubst)
   676 
   677 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   678   by (rule subst)
   679 
   680 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   681   by (rule ssubst)
   682 
   683 end
   684 
   685 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   686   (!!x y. x < y ==> f x < f y) ==> f a < c"
   687 proof -
   688   assume r: "!!x y. x < y ==> f x < f y"
   689   assume "a < b" hence "f a < f b" by (rule r)
   690   also assume "f b < c"
   691   finally (less_trans) show ?thesis .
   692 qed
   693 
   694 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   695   (!!x y. x < y ==> f x < f y) ==> a < f c"
   696 proof -
   697   assume r: "!!x y. x < y ==> f x < f y"
   698   assume "a < f b"
   699   also assume "b < c" hence "f b < f c" by (rule r)
   700   finally (less_trans) show ?thesis .
   701 qed
   702 
   703 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   704   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   705 proof -
   706   assume r: "!!x y. x <= y ==> f x <= f y"
   707   assume "a <= b" hence "f a <= f b" by (rule r)
   708   also assume "f b < c"
   709   finally (le_less_trans) show ?thesis .
   710 qed
   711 
   712 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   713   (!!x y. x < y ==> f x < f y) ==> a < f c"
   714 proof -
   715   assume r: "!!x y. x < y ==> f x < f y"
   716   assume "a <= f b"
   717   also assume "b < c" hence "f b < f c" by (rule r)
   718   finally (le_less_trans) show ?thesis .
   719 qed
   720 
   721 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   722   (!!x y. x < y ==> f x < f y) ==> f a < c"
   723 proof -
   724   assume r: "!!x y. x < y ==> f x < f y"
   725   assume "a < b" hence "f a < f b" by (rule r)
   726   also assume "f b <= c"
   727   finally (less_le_trans) show ?thesis .
   728 qed
   729 
   730 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   731   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   732 proof -
   733   assume r: "!!x y. x <= y ==> f x <= f y"
   734   assume "a < f b"
   735   also assume "b <= c" hence "f b <= f c" by (rule r)
   736   finally (less_le_trans) show ?thesis .
   737 qed
   738 
   739 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   740   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   741 proof -
   742   assume r: "!!x y. x <= y ==> f x <= f y"
   743   assume "a <= f b"
   744   also assume "b <= c" hence "f b <= f c" by (rule r)
   745   finally (order_trans) show ?thesis .
   746 qed
   747 
   748 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   749   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   750 proof -
   751   assume r: "!!x y. x <= y ==> f x <= f y"
   752   assume "a <= b" hence "f a <= f b" by (rule r)
   753   also assume "f b <= c"
   754   finally (order_trans) show ?thesis .
   755 qed
   756 
   757 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   758   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   759 proof -
   760   assume r: "!!x y. x <= y ==> f x <= f y"
   761   assume "a <= b" hence "f a <= f b" by (rule r)
   762   also assume "f b = c"
   763   finally (ord_le_eq_trans) show ?thesis .
   764 qed
   765 
   766 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   767   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   768 proof -
   769   assume r: "!!x y. x <= y ==> f x <= f y"
   770   assume "a = f b"
   771   also assume "b <= c" hence "f b <= f c" by (rule r)
   772   finally (ord_eq_le_trans) show ?thesis .
   773 qed
   774 
   775 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   776   (!!x y. x < y ==> f x < f y) ==> f a < c"
   777 proof -
   778   assume r: "!!x y. x < y ==> f x < f y"
   779   assume "a < b" hence "f a < f b" by (rule r)
   780   also assume "f b = c"
   781   finally (ord_less_eq_trans) show ?thesis .
   782 qed
   783 
   784 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   785   (!!x y. x < y ==> f x < f y) ==> a < f c"
   786 proof -
   787   assume r: "!!x y. x < y ==> f x < f y"
   788   assume "a = f b"
   789   also assume "b < c" hence "f b < f c" by (rule r)
   790   finally (ord_eq_less_trans) show ?thesis .
   791 qed
   792 
   793 text {*
   794   Note that this list of rules is in reverse order of priorities.
   795 *}
   796 
   797 lemmas [trans] =
   798   order_less_subst2
   799   order_less_subst1
   800   order_le_less_subst2
   801   order_le_less_subst1
   802   order_less_le_subst2
   803   order_less_le_subst1
   804   order_subst2
   805   order_subst1
   806   ord_le_eq_subst
   807   ord_eq_le_subst
   808   ord_less_eq_subst
   809   ord_eq_less_subst
   810   forw_subst
   811   back_subst
   812   rev_mp
   813   mp
   814 
   815 lemmas (in order) [trans] =
   816   neq_le_trans
   817   le_neq_trans
   818 
   819 lemmas (in preorder) [trans] =
   820   less_trans
   821   less_asym'
   822   le_less_trans
   823   less_le_trans
   824   order_trans
   825 
   826 lemmas (in order) [trans] =
   827   antisym
   828 
   829 lemmas (in ord) [trans] =
   830   ord_le_eq_trans
   831   ord_eq_le_trans
   832   ord_less_eq_trans
   833   ord_eq_less_trans
   834 
   835 lemmas [trans] =
   836   trans
   837 
   838 lemmas order_trans_rules =
   839   order_less_subst2
   840   order_less_subst1
   841   order_le_less_subst2
   842   order_le_less_subst1
   843   order_less_le_subst2
   844   order_less_le_subst1
   845   order_subst2
   846   order_subst1
   847   ord_le_eq_subst
   848   ord_eq_le_subst
   849   ord_less_eq_subst
   850   ord_eq_less_subst
   851   forw_subst
   852   back_subst
   853   rev_mp
   854   mp
   855   neq_le_trans
   856   le_neq_trans
   857   less_trans
   858   less_asym'
   859   le_less_trans
   860   less_le_trans
   861   order_trans
   862   antisym
   863   ord_le_eq_trans
   864   ord_eq_le_trans
   865   ord_less_eq_trans
   866   ord_eq_less_trans
   867   trans
   868 
   869 text {* These support proving chains of decreasing inequalities
   870     a >= b >= c ... in Isar proofs. *}
   871 
   872 lemma xt1 [no_atp]:
   873   "a = b ==> b > c ==> a > c"
   874   "a > b ==> b = c ==> a > c"
   875   "a = b ==> b >= c ==> a >= c"
   876   "a >= b ==> b = c ==> a >= c"
   877   "(x::'a::order) >= y ==> y >= x ==> x = y"
   878   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   879   "(x::'a::order) > y ==> y >= z ==> x > z"
   880   "(x::'a::order) >= y ==> y > z ==> x > z"
   881   "(a::'a::order) > b ==> b > a ==> P"
   882   "(x::'a::order) > y ==> y > z ==> x > z"
   883   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   884   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   885   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   886   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   887   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   888   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   889   by auto
   890 
   891 lemma xt2 [no_atp]:
   892   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   893 by (subgoal_tac "f b >= f c", force, force)
   894 
   895 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
   896     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   897 by (subgoal_tac "f a >= f b", force, force)
   898 
   899 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   900   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   901 by (subgoal_tac "f b >= f c", force, force)
   902 
   903 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   904     (!!x y. x > y ==> f x > f y) ==> f a > c"
   905 by (subgoal_tac "f a > f b", force, force)
   906 
   907 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
   908     (!!x y. x > y ==> f x > f y) ==> a > f c"
   909 by (subgoal_tac "f b > f c", force, force)
   910 
   911 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   912     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   913 by (subgoal_tac "f a >= f b", force, force)
   914 
   915 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   916     (!!x y. x > y ==> f x > f y) ==> a > f c"
   917 by (subgoal_tac "f b > f c", force, force)
   918 
   919 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   920     (!!x y. x > y ==> f x > f y) ==> f a > c"
   921 by (subgoal_tac "f a > f b", force, force)
   922 
   923 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9 [no_atp]
   924 
   925 (* 
   926   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   927   for the wrong thing in an Isar proof.
   928 
   929   The extra transitivity rules can be used as follows: 
   930 
   931 lemma "(a::'a::order) > z"
   932 proof -
   933   have "a >= b" (is "_ >= ?rhs")
   934     sorry
   935   also have "?rhs >= c" (is "_ >= ?rhs")
   936     sorry
   937   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   938     sorry
   939   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   940     sorry
   941   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   942     sorry
   943   also (xtrans) have "?rhs > z"
   944     sorry
   945   finally (xtrans) show ?thesis .
   946 qed
   947 
   948   Alternatively, one can use "declare xtrans [trans]" and then
   949   leave out the "(xtrans)" above.
   950 *)
   951 
   952 
   953 subsection {* Monotonicity, least value operator and min/max *}
   954 
   955 context order
   956 begin
   957 
   958 definition mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   959   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
   960 
   961 lemma monoI [intro?]:
   962   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   963   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
   964   unfolding mono_def by iprover
   965 
   966 lemma monoD [dest?]:
   967   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
   968   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   969   unfolding mono_def by iprover
   970 
   971 definition strict_mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool" where
   972   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
   973 
   974 lemma strict_monoI [intro?]:
   975   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
   976   shows "strict_mono f"
   977   using assms unfolding strict_mono_def by auto
   978 
   979 lemma strict_monoD [dest?]:
   980   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
   981   unfolding strict_mono_def by auto
   982 
   983 lemma strict_mono_mono [dest?]:
   984   assumes "strict_mono f"
   985   shows "mono f"
   986 proof (rule monoI)
   987   fix x y
   988   assume "x \<le> y"
   989   show "f x \<le> f y"
   990   proof (cases "x = y")
   991     case True then show ?thesis by simp
   992   next
   993     case False with `x \<le> y` have "x < y" by simp
   994     with assms strict_monoD have "f x < f y" by auto
   995     then show ?thesis by simp
   996   qed
   997 qed
   998 
   999 end
  1000 
  1001 context linorder
  1002 begin
  1003 
  1004 lemma strict_mono_eq:
  1005   assumes "strict_mono f"
  1006   shows "f x = f y \<longleftrightarrow> x = y"
  1007 proof
  1008   assume "f x = f y"
  1009   show "x = y" proof (cases x y rule: linorder_cases)
  1010     case less with assms strict_monoD have "f x < f y" by auto
  1011     with `f x = f y` show ?thesis by simp
  1012   next
  1013     case equal then show ?thesis .
  1014   next
  1015     case greater with assms strict_monoD have "f y < f x" by auto
  1016     with `f x = f y` show ?thesis by simp
  1017   qed
  1018 qed simp
  1019 
  1020 lemma strict_mono_less_eq:
  1021   assumes "strict_mono f"
  1022   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1023 proof
  1024   assume "x \<le> y"
  1025   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1026 next
  1027   assume "f x \<le> f y"
  1028   show "x \<le> y" proof (rule ccontr)
  1029     assume "\<not> x \<le> y" then have "y < x" by simp
  1030     with assms strict_monoD have "f y < f x" by auto
  1031     with `f x \<le> f y` show False by simp
  1032   qed
  1033 qed
  1034   
  1035 lemma strict_mono_less:
  1036   assumes "strict_mono f"
  1037   shows "f x < f y \<longleftrightarrow> x < y"
  1038   using assms
  1039     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1040 
  1041 lemma min_of_mono:
  1042   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1043   shows "mono f \<Longrightarrow> min (f m) (f n) = f (min m n)"
  1044   by (auto simp: mono_def Orderings.min_def min_def intro: Orderings.antisym)
  1045 
  1046 lemma max_of_mono:
  1047   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1048   shows "mono f \<Longrightarrow> max (f m) (f n) = f (max m n)"
  1049   by (auto simp: mono_def Orderings.max_def max_def intro: Orderings.antisym)
  1050 
  1051 end
  1052 
  1053 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1054 by (simp add: min_def)
  1055 
  1056 lemma max_absorb2: "x \<le> y ==> max x y = y"
  1057 by (simp add: max_def)
  1058 
  1059 lemma min_absorb2: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> min x y = y"
  1060 by (simp add:min_def)
  1061 
  1062 lemma max_absorb1: "(y\<Colon>'a\<Colon>order) \<le> x \<Longrightarrow> max x y = x"
  1063 by (simp add: max_def)
  1064 
  1065 
  1066 
  1067 subsection {* (Unique) top and bottom elements *}
  1068 
  1069 class bot = order +
  1070   fixes bot :: 'a ("\<bottom>")
  1071   assumes bot_least [simp]: "\<bottom> \<le> a"
  1072 begin
  1073 
  1074 lemma le_bot:
  1075   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1076   by (auto intro: antisym)
  1077 
  1078 lemma bot_unique:
  1079   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1080   by (auto intro: antisym)
  1081 
  1082 lemma not_less_bot [simp]:
  1083   "\<not> (a < \<bottom>)"
  1084   using bot_least [of a] by (auto simp: le_less)
  1085 
  1086 lemma bot_less:
  1087   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1088   by (auto simp add: less_le_not_le intro!: antisym)
  1089 
  1090 end
  1091 
  1092 class top = order +
  1093   fixes top :: 'a ("\<top>")
  1094   assumes top_greatest [simp]: "a \<le> \<top>"
  1095 begin
  1096 
  1097 lemma top_le:
  1098   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1099   by (rule antisym) auto
  1100 
  1101 lemma top_unique:
  1102   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1103   by (auto intro: antisym)
  1104 
  1105 lemma not_top_less [simp]: "\<not> (\<top> < a)"
  1106   using top_greatest [of a] by (auto simp: le_less)
  1107 
  1108 lemma less_top:
  1109   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1110   by (auto simp add: less_le_not_le intro!: antisym)
  1111 
  1112 end
  1113 
  1114 
  1115 subsection {* Dense orders *}
  1116 
  1117 class dense_linorder = linorder + 
  1118   assumes gt_ex: "\<exists>y. x < y" 
  1119   and lt_ex: "\<exists>y. y < x"
  1120   and dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1121 begin
  1122 
  1123 lemma dense_le:
  1124   fixes y z :: 'a
  1125   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1126   shows "y \<le> z"
  1127 proof (rule ccontr)
  1128   assume "\<not> ?thesis"
  1129   hence "z < y" by simp
  1130   from dense[OF this]
  1131   obtain x where "x < y" and "z < x" by safe
  1132   moreover have "x \<le> z" using assms[OF `x < y`] .
  1133   ultimately show False by auto
  1134 qed
  1135 
  1136 lemma dense_le_bounded:
  1137   fixes x y z :: 'a
  1138   assumes "x < y"
  1139   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1140   shows "y \<le> z"
  1141 proof (rule dense_le)
  1142   fix w assume "w < y"
  1143   from dense[OF `x < y`] obtain u where "x < u" "u < y" by safe
  1144   from linear[of u w]
  1145   show "w \<le> z"
  1146   proof (rule disjE)
  1147     assume "u \<le> w"
  1148     from less_le_trans[OF `x < u` `u \<le> w`] `w < y`
  1149     show "w \<le> z" by (rule *)
  1150   next
  1151     assume "w \<le> u"
  1152     from `w \<le> u` *[OF `x < u` `u < y`]
  1153     show "w \<le> z" by (rule order_trans)
  1154   qed
  1155 qed
  1156 
  1157 end
  1158 
  1159 subsection {* Wellorders *}
  1160 
  1161 class wellorder = linorder +
  1162   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1163 begin
  1164 
  1165 lemma wellorder_Least_lemma:
  1166   fixes k :: 'a
  1167   assumes "P k"
  1168   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1169 proof -
  1170   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1171   using assms proof (induct k rule: less_induct)
  1172     case (less x) then have "P x" by simp
  1173     show ?case proof (rule classical)
  1174       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1175       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1176       proof (rule classical)
  1177         fix y
  1178         assume "P y" and "\<not> x \<le> y"
  1179         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1180           by (auto simp add: not_le)
  1181         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1182           by auto
  1183         then show "x \<le> y" by auto
  1184       qed
  1185       with `P x` have Least: "(LEAST a. P a) = x"
  1186         by (rule Least_equality)
  1187       with `P x` show ?thesis by simp
  1188     qed
  1189   qed
  1190   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1191 qed
  1192 
  1193 -- "The following 3 lemmas are due to Brian Huffman"
  1194 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1195   by (erule exE) (erule LeastI)
  1196 
  1197 lemma LeastI2:
  1198   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1199   by (blast intro: LeastI)
  1200 
  1201 lemma LeastI2_ex:
  1202   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1203   by (blast intro: LeastI_ex)
  1204 
  1205 lemma LeastI2_wellorder:
  1206   assumes "P a"
  1207   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1208   shows "Q (Least P)"
  1209 proof (rule LeastI2_order)
  1210   show "P (Least P)" using `P a` by (rule LeastI)
  1211 next
  1212   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1213 next
  1214   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1215 qed
  1216 
  1217 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1218 apply (simp (no_asm_use) add: not_le [symmetric])
  1219 apply (erule contrapos_nn)
  1220 apply (erule Least_le)
  1221 done
  1222 
  1223 end
  1224 
  1225 
  1226 subsection {* Order on @{typ bool} *}
  1227 
  1228 instantiation bool :: "{bot, top, linorder}"
  1229 begin
  1230 
  1231 definition
  1232   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1233 
  1234 definition
  1235   [simp]: "(P\<Colon>bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1236 
  1237 definition
  1238   [simp]: "\<bottom> \<longleftrightarrow> False"
  1239 
  1240 definition
  1241   [simp]: "\<top> \<longleftrightarrow> True"
  1242 
  1243 instance proof
  1244 qed auto
  1245 
  1246 end
  1247 
  1248 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1249   by simp
  1250 
  1251 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1252   by simp
  1253 
  1254 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1255   by simp
  1256 
  1257 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1258   by simp
  1259 
  1260 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1261   by simp
  1262 
  1263 lemma top_boolI: \<top>
  1264   by simp
  1265 
  1266 lemma [code]:
  1267   "False \<le> b \<longleftrightarrow> True"
  1268   "True \<le> b \<longleftrightarrow> b"
  1269   "False < b \<longleftrightarrow> b"
  1270   "True < b \<longleftrightarrow> False"
  1271   by simp_all
  1272 
  1273 
  1274 subsection {* Order on @{typ "_ \<Rightarrow> _"} *}
  1275 
  1276 instantiation "fun" :: (type, ord) ord
  1277 begin
  1278 
  1279 definition
  1280   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1281 
  1282 definition
  1283   "(f\<Colon>'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1284 
  1285 instance ..
  1286 
  1287 end
  1288 
  1289 instance "fun" :: (type, preorder) preorder proof
  1290 qed (auto simp add: le_fun_def less_fun_def
  1291   intro: order_trans antisym)
  1292 
  1293 instance "fun" :: (type, order) order proof
  1294 qed (auto simp add: le_fun_def intro: antisym)
  1295 
  1296 instantiation "fun" :: (type, bot) bot
  1297 begin
  1298 
  1299 definition
  1300   "\<bottom> = (\<lambda>x. \<bottom>)"
  1301 
  1302 lemma bot_apply (* CANDIDATE [simp, code] *):
  1303   "\<bottom> x = \<bottom>"
  1304   by (simp add: bot_fun_def)
  1305 
  1306 instance proof
  1307 qed (simp add: le_fun_def bot_apply)
  1308 
  1309 end
  1310 
  1311 instantiation "fun" :: (type, top) top
  1312 begin
  1313 
  1314 definition
  1315   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1316 declare top_fun_def_raw [no_atp]
  1317 
  1318 lemma top_apply (* CANDIDATE [simp, code] *):
  1319   "\<top> x = \<top>"
  1320   by (simp add: top_fun_def)
  1321 
  1322 instance proof
  1323 qed (simp add: le_fun_def top_apply)
  1324 
  1325 end
  1326 
  1327 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1328   unfolding le_fun_def by simp
  1329 
  1330 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1331   unfolding le_fun_def by simp
  1332 
  1333 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1334   unfolding le_fun_def by simp
  1335 
  1336 
  1337 subsection {* Order on unary and binary predicates *}
  1338 
  1339 lemma predicate1I:
  1340   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1341   shows "P \<le> Q"
  1342   apply (rule le_funI)
  1343   apply (rule le_boolI)
  1344   apply (rule PQ)
  1345   apply assumption
  1346   done
  1347 
  1348 lemma predicate1D:
  1349   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1350   apply (erule le_funE)
  1351   apply (erule le_boolE)
  1352   apply assumption+
  1353   done
  1354 
  1355 lemma rev_predicate1D:
  1356   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1357   by (rule predicate1D)
  1358 
  1359 lemma predicate2I:
  1360   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1361   shows "P \<le> Q"
  1362   apply (rule le_funI)+
  1363   apply (rule le_boolI)
  1364   apply (rule PQ)
  1365   apply assumption
  1366   done
  1367 
  1368 lemma predicate2D:
  1369   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1370   apply (erule le_funE)+
  1371   apply (erule le_boolE)
  1372   apply assumption+
  1373   done
  1374 
  1375 lemma rev_predicate2D:
  1376   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1377   by (rule predicate2D)
  1378 
  1379 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1380   by (simp add: bot_fun_def)
  1381 
  1382 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1383   by (simp add: bot_fun_def)
  1384 
  1385 lemma top1I: "\<top> x"
  1386   by (simp add: top_fun_def)
  1387 
  1388 lemma top2I: "\<top> x y"
  1389   by (simp add: top_fun_def)
  1390 
  1391 
  1392 subsection {* Name duplicates *}
  1393 
  1394 lemmas order_eq_refl = preorder_class.eq_refl
  1395 lemmas order_less_irrefl = preorder_class.less_irrefl
  1396 lemmas order_less_imp_le = preorder_class.less_imp_le
  1397 lemmas order_less_not_sym = preorder_class.less_not_sym
  1398 lemmas order_less_asym = preorder_class.less_asym
  1399 lemmas order_less_trans = preorder_class.less_trans
  1400 lemmas order_le_less_trans = preorder_class.le_less_trans
  1401 lemmas order_less_le_trans = preorder_class.less_le_trans
  1402 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1403 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1404 lemmas order_less_asym' = preorder_class.less_asym'
  1405 
  1406 lemmas order_less_le = order_class.less_le
  1407 lemmas order_le_less = order_class.le_less
  1408 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1409 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1410 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1411 lemmas order_neq_le_trans = order_class.neq_le_trans
  1412 lemmas order_le_neq_trans = order_class.le_neq_trans
  1413 lemmas order_antisym = order_class.antisym
  1414 lemmas order_eq_iff = order_class.eq_iff
  1415 lemmas order_antisym_conv = order_class.antisym_conv
  1416 
  1417 lemmas linorder_linear = linorder_class.linear
  1418 lemmas linorder_less_linear = linorder_class.less_linear
  1419 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1420 lemmas linorder_le_cases = linorder_class.le_cases
  1421 lemmas linorder_not_less = linorder_class.not_less
  1422 lemmas linorder_not_le = linorder_class.not_le
  1423 lemmas linorder_neq_iff = linorder_class.neq_iff
  1424 lemmas linorder_neqE = linorder_class.neqE
  1425 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1426 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1427 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1428 
  1429 no_notation
  1430   top ("\<top>") and
  1431   bot ("\<bottom>")
  1432 
  1433 end