src/HOL/Tools/inductive_package.ML
author berghofe
Wed Feb 25 11:20:34 2009 +0100 (2009-02-25)
changeset 30089 f631fb528277
parent 29868 787349bb53e9
child 30190 479806475f3c
permissions -rw-r--r--
Use LocalTheory.full_name instead of Sign.full_name, because the latter does
not work properly for locales.
     1 (*  Title:      HOL/Tools/inductive_package.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 (Co)Inductive Definition module for HOL.
     6 
     7 Features:
     8   * least or greatest fixedpoints
     9   * mutually recursive definitions
    10   * definitions involving arbitrary monotone operators
    11   * automatically proves introduction and elimination rules
    12 
    13   Introduction rules have the form
    14   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    15   where M is some monotone operator (usually the identity)
    16   Q x is any side condition on the free variables
    17   ti, t are any terms
    18   Pj, Pk are two of the predicates being defined in mutual recursion
    19 *)
    20 
    21 signature BASIC_INDUCTIVE_PACKAGE =
    22 sig
    23   type inductive_result
    24   val morph_result: morphism -> inductive_result -> inductive_result
    25   type inductive_info
    26   val the_inductive: Proof.context -> string -> inductive_info
    27   val print_inductives: Proof.context -> unit
    28   val mono_add: attribute
    29   val mono_del: attribute
    30   val get_monos: Proof.context -> thm list
    31   val mk_cases: Proof.context -> term -> thm
    32   val inductive_forall_name: string
    33   val inductive_forall_def: thm
    34   val rulify: thm -> thm
    35   val inductive_cases: (Attrib.binding * string list) list -> local_theory ->
    36     thm list list * local_theory
    37   val inductive_cases_i: (Attrib.binding * term list) list -> local_theory ->
    38     thm list list * local_theory
    39   type inductive_flags
    40   val add_inductive_i:
    41     inductive_flags -> ((binding * typ) * mixfix) list ->
    42     (string * typ) list -> (Attrib.binding * term) list -> thm list -> local_theory ->
    43     inductive_result * local_theory
    44   val add_inductive: bool -> bool ->
    45     (binding * string option * mixfix) list ->
    46     (binding * string option * mixfix) list ->
    47     (Attrib.binding * string) list ->
    48     (Facts.ref * Attrib.src list) list ->
    49     bool -> local_theory -> inductive_result * local_theory
    50   val add_inductive_global: string -> inductive_flags ->
    51     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    52     thm list -> theory -> inductive_result * theory
    53   val arities_of: thm -> (string * int) list
    54   val params_of: thm -> term list
    55   val partition_rules: thm -> thm list -> (string * thm list) list
    56   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    57   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    58   val infer_intro_vars: thm -> int -> thm list -> term list list
    59   val setup: theory -> theory
    60 end;
    61 
    62 signature INDUCTIVE_PACKAGE =
    63 sig
    64   include BASIC_INDUCTIVE_PACKAGE
    65   type add_ind_def
    66   val declare_rules: string -> binding -> bool -> bool -> string list ->
    67     thm list -> binding list -> Attrib.src list list -> (thm * string list) list ->
    68     thm -> local_theory -> thm list * thm list * thm * local_theory
    69   val add_ind_def: add_ind_def
    70   val gen_add_inductive_i: add_ind_def -> inductive_flags ->
    71     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    72     thm list -> local_theory -> inductive_result * local_theory
    73   val gen_add_inductive: add_ind_def -> bool -> bool ->
    74     (binding * string option * mixfix) list ->
    75     (binding * string option * mixfix) list ->
    76     (Attrib.binding * string) list -> (Facts.ref * Attrib.src list) list ->
    77     bool -> local_theory -> inductive_result * local_theory
    78   val gen_ind_decl: add_ind_def -> bool ->
    79     OuterParse.token list -> (bool -> local_theory -> local_theory) * OuterParse.token list
    80 end;
    81 
    82 structure InductivePackage: INDUCTIVE_PACKAGE =
    83 struct
    84 
    85 
    86 (** theory context references **)
    87 
    88 val inductive_forall_name = "HOL.induct_forall";
    89 val inductive_forall_def = thm "induct_forall_def";
    90 val inductive_conj_name = "HOL.induct_conj";
    91 val inductive_conj_def = thm "induct_conj_def";
    92 val inductive_conj = thms "induct_conj";
    93 val inductive_atomize = thms "induct_atomize";
    94 val inductive_rulify = thms "induct_rulify";
    95 val inductive_rulify_fallback = thms "induct_rulify_fallback";
    96 
    97 val notTrueE = TrueI RSN (2, notE);
    98 val notFalseI = Seq.hd (atac 1 notI);
    99 val simp_thms' = map (fn s => mk_meta_eq (the (find_first
   100   (equal (OldGoals.read_prop @{theory HOL} s) o prop_of) simp_thms)))
   101   ["(~True) = False", "(~False) = True",
   102    "(True --> ?P) = ?P", "(False --> ?P) = True",
   103    "(?P & True) = ?P", "(True & ?P) = ?P"];
   104 
   105 
   106 
   107 (** context data **)
   108 
   109 type inductive_result =
   110   {preds: term list, elims: thm list, raw_induct: thm,
   111    induct: thm, intrs: thm list};
   112 
   113 fun morph_result phi {preds, elims, raw_induct: thm, induct, intrs} =
   114   let
   115     val term = Morphism.term phi;
   116     val thm = Morphism.thm phi;
   117     val fact = Morphism.fact phi;
   118   in
   119    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   120     induct = thm induct, intrs = fact intrs}
   121   end;
   122 
   123 type inductive_info =
   124   {names: string list, coind: bool} * inductive_result;
   125 
   126 structure InductiveData = GenericDataFun
   127 (
   128   type T = inductive_info Symtab.table * thm list;
   129   val empty = (Symtab.empty, []);
   130   val extend = I;
   131   fun merge _ ((tab1, monos1), (tab2, monos2)) =
   132     (Symtab.merge (K true) (tab1, tab2), Thm.merge_thms (monos1, monos2));
   133 );
   134 
   135 val get_inductives = InductiveData.get o Context.Proof;
   136 
   137 fun print_inductives ctxt =
   138   let
   139     val (tab, monos) = get_inductives ctxt;
   140     val space = Consts.space_of (ProofContext.consts_of ctxt);
   141   in
   142     [Pretty.strs ("(co)inductives:" :: map #1 (NameSpace.extern_table (space, tab))),
   143      Pretty.big_list "monotonicity rules:" (map (ProofContext.pretty_thm ctxt) monos)]
   144     |> Pretty.chunks |> Pretty.writeln
   145   end;
   146 
   147 
   148 (* get and put data *)
   149 
   150 fun the_inductive ctxt name =
   151   (case Symtab.lookup (#1 (get_inductives ctxt)) name of
   152     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   153   | SOME info => info);
   154 
   155 fun put_inductives names info = InductiveData.map
   156   (apfst (fold (fn name => Symtab.update (name, info)) names));
   157 
   158 
   159 
   160 (** monotonicity rules **)
   161 
   162 val get_monos = #2 o get_inductives;
   163 val map_monos = InductiveData.map o apsnd;
   164 
   165 fun mk_mono thm =
   166   let
   167     val concl = concl_of thm;
   168     fun eq2mono thm' = [thm' RS (thm' RS eq_to_mono)] @
   169       (case concl of
   170           (_ $ (_ $ (Const ("Not", _) $ _) $ _)) => []
   171         | _ => [thm' RS (thm' RS eq_to_mono2)]);
   172     fun dest_less_concl thm = dest_less_concl (thm RS le_funD)
   173       handle THM _ => thm RS le_boolD
   174   in
   175     case concl of
   176       Const ("==", _) $ _ $ _ => eq2mono (thm RS meta_eq_to_obj_eq)
   177     | _ $ (Const ("op =", _) $ _ $ _) => eq2mono thm
   178     | _ $ (Const ("HOL.ord_class.less_eq", _) $ _ $ _) =>
   179       [dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   180          (resolve_tac [le_funI, le_boolI'])) thm))]
   181     | _ => [thm]
   182   end handle THM _ => error ("Bad monotonicity theorem:\n" ^ Display.string_of_thm thm);
   183 
   184 val mono_add = Thm.declaration_attribute (map_monos o fold Thm.add_thm o mk_mono);
   185 val mono_del = Thm.declaration_attribute (map_monos o fold Thm.del_thm o mk_mono);
   186 
   187 
   188 
   189 (** misc utilities **)
   190 
   191 fun message quiet_mode s = if quiet_mode then () else writeln s;
   192 fun clean_message quiet_mode s = if ! quick_and_dirty then () else message quiet_mode s;
   193 
   194 fun coind_prefix true = "co"
   195   | coind_prefix false = "";
   196 
   197 fun log (b:int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   198 
   199 fun make_bool_args f g [] i = []
   200   | make_bool_args f g (x :: xs) i =
   201       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   202 
   203 fun make_bool_args' xs =
   204   make_bool_args (K HOLogic.false_const) (K HOLogic.true_const) xs;
   205 
   206 fun find_arg T x [] = sys_error "find_arg"
   207   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   208       apsnd (cons p) (find_arg T x ps)
   209   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   210       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   211       else apsnd (cons p) (find_arg T x ps);
   212 
   213 fun make_args Ts xs =
   214   map (fn (T, (NONE, ())) => Const (@{const_name undefined}, T) | (_, (SOME t, ())) => t)
   215     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   216 
   217 fun make_args' Ts xs Us =
   218   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   219 
   220 fun dest_predicate cs params t =
   221   let
   222     val k = length params;
   223     val (c, ts) = strip_comb t;
   224     val (xs, ys) = chop k ts;
   225     val i = find_index_eq c cs;
   226   in
   227     if xs = params andalso i >= 0 then
   228       SOME (c, i, ys, chop (length ys)
   229         (List.drop (binder_types (fastype_of c), k)))
   230     else NONE
   231   end;
   232 
   233 fun mk_names a 0 = []
   234   | mk_names a 1 = [a]
   235   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   236 
   237 
   238 
   239 (** process rules **)
   240 
   241 local
   242 
   243 fun err_in_rule ctxt name t msg =
   244   error (cat_lines ["Ill-formed introduction rule " ^ quote name,
   245     Syntax.string_of_term ctxt t, msg]);
   246 
   247 fun err_in_prem ctxt name t p msg =
   248   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   249     "in introduction rule " ^ quote name, Syntax.string_of_term ctxt t, msg]);
   250 
   251 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   252 
   253 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   254 
   255 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   256 
   257 fun atomize_term thy = MetaSimplifier.rewrite_term thy inductive_atomize [];
   258 
   259 in
   260 
   261 fun check_rule ctxt cs params ((binding, att), rule) =
   262   let
   263     val err_name = Binding.display binding;
   264     val params' = Term.variant_frees rule (Logic.strip_params rule);
   265     val frees = rev (map Free params');
   266     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   267     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   268     val rule' = Logic.list_implies (prems, concl);
   269     val aprems = map (atomize_term (ProofContext.theory_of ctxt)) prems;
   270     val arule = list_all_free (params', Logic.list_implies (aprems, concl));
   271 
   272     fun check_ind err t = case dest_predicate cs params t of
   273         NONE => err (bad_app ^
   274           commas (map (Syntax.string_of_term ctxt) params))
   275       | SOME (_, _, ys, _) =>
   276           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   277           then err bad_ind_occ else ();
   278 
   279     fun check_prem' prem t =
   280       if head_of t mem cs then
   281         check_ind (err_in_prem ctxt err_name rule prem) t
   282       else (case t of
   283           Abs (_, _, t) => check_prem' prem t
   284         | t $ u => (check_prem' prem t; check_prem' prem u)
   285         | _ => ());
   286 
   287     fun check_prem (prem, aprem) =
   288       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   289       else err_in_prem ctxt err_name rule prem "Non-atomic premise";
   290   in
   291     (case concl of
   292        Const ("Trueprop", _) $ t =>
   293          if head_of t mem cs then
   294            (check_ind (err_in_rule ctxt err_name rule') t;
   295             List.app check_prem (prems ~~ aprems))
   296          else err_in_rule ctxt err_name rule' bad_concl
   297      | _ => err_in_rule ctxt err_name rule' bad_concl);
   298     ((binding, att), arule)
   299   end;
   300 
   301 val rulify =
   302   hol_simplify inductive_conj
   303   #> hol_simplify inductive_rulify
   304   #> hol_simplify inductive_rulify_fallback
   305   #> MetaSimplifier.norm_hhf;
   306 
   307 end;
   308 
   309 
   310 
   311 (** proofs for (co)inductive predicates **)
   312 
   313 (* prove monotonicity *)
   314 
   315 fun prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt =
   316  (message (quiet_mode orelse skip_mono andalso !quick_and_dirty orelse fork_mono)
   317     "  Proving monotonicity ...";
   318   (if skip_mono then SkipProof.prove else if fork_mono then Goal.prove_future else Goal.prove) ctxt
   319     [] []
   320     (HOLogic.mk_Trueprop
   321       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   322     (fn _ => EVERY [rtac @{thm monoI} 1,
   323       REPEAT (resolve_tac [le_funI, le_boolI'] 1),
   324       REPEAT (FIRST
   325         [atac 1,
   326          resolve_tac (List.concat (map mk_mono monos) @ get_monos ctxt) 1,
   327          etac le_funE 1, dtac le_boolD 1])]));
   328 
   329 
   330 (* prove introduction rules *)
   331 
   332 fun prove_intrs quiet_mode coind mono fp_def k params intr_ts rec_preds_defs ctxt =
   333   let
   334     val _ = clean_message quiet_mode "  Proving the introduction rules ...";
   335 
   336     val unfold = funpow k (fn th => th RS fun_cong)
   337       (mono RS (fp_def RS
   338         (if coind then def_gfp_unfold else def_lfp_unfold)));
   339 
   340     fun select_disj 1 1 = []
   341       | select_disj _ 1 = [rtac disjI1]
   342       | select_disj n i = (rtac disjI2)::(select_disj (n - 1) (i - 1));
   343 
   344     val rules = [refl, TrueI, notFalseI, exI, conjI];
   345 
   346     val intrs = map_index (fn (i, intr) => rulify
   347       (SkipProof.prove ctxt (map (fst o dest_Free) params) [] intr (fn _ => EVERY
   348        [rewrite_goals_tac rec_preds_defs,
   349         rtac (unfold RS iffD2) 1,
   350         EVERY1 (select_disj (length intr_ts) (i + 1)),
   351         (*Not ares_tac, since refl must be tried before any equality assumptions;
   352           backtracking may occur if the premises have extra variables!*)
   353         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)]))) intr_ts
   354 
   355   in (intrs, unfold) end;
   356 
   357 
   358 (* prove elimination rules *)
   359 
   360 fun prove_elims quiet_mode cs params intr_ts intr_names unfold rec_preds_defs ctxt =
   361   let
   362     val _ = clean_message quiet_mode "  Proving the elimination rules ...";
   363 
   364     val ([pname], ctxt') = ctxt |>
   365       Variable.add_fixes (map (fst o dest_Free) params) |> snd |>
   366       Variable.variant_fixes ["P"];
   367     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   368 
   369     fun dest_intr r =
   370       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   371        Logic.strip_assums_hyp r, Logic.strip_params r);
   372 
   373     val intrs = map dest_intr intr_ts ~~ intr_names;
   374 
   375     val rules1 = [disjE, exE, FalseE];
   376     val rules2 = [conjE, FalseE, notTrueE];
   377 
   378     fun prove_elim c =
   379       let
   380         val Ts = List.drop (binder_types (fastype_of c), length params);
   381         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   382         val frees = map Free (anames ~~ Ts);
   383 
   384         fun mk_elim_prem ((_, _, us, _), ts, params') =
   385           list_all (params',
   386             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   387               (frees ~~ us) @ ts, P));
   388         val c_intrs = (List.filter (equal c o #1 o #1 o #1) intrs);
   389         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   390            map mk_elim_prem (map #1 c_intrs)
   391       in
   392         (SkipProof.prove ctxt'' [] prems P
   393           (fn {prems, ...} => EVERY
   394             [cut_facts_tac [hd prems] 1,
   395              rewrite_goals_tac rec_preds_defs,
   396              dtac (unfold RS iffD1) 1,
   397              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   398              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   399              EVERY (map (fn prem =>
   400                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   401           |> rulify
   402           |> singleton (ProofContext.export ctxt'' ctxt),
   403          map #2 c_intrs)
   404       end
   405 
   406    in map prove_elim cs end;
   407 
   408 
   409 (* derivation of simplified elimination rules *)
   410 
   411 local
   412 
   413 (*delete needless equality assumptions*)
   414 val refl_thin = Goal.prove_global @{theory HOL} [] [] @{prop "!!P. a = a ==> P ==> P"}
   415   (fn _ => assume_tac 1);
   416 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   417 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   418 
   419 fun simp_case_tac ss i =
   420   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   421 
   422 in
   423 
   424 fun mk_cases ctxt prop =
   425   let
   426     val thy = ProofContext.theory_of ctxt;
   427     val ss = Simplifier.local_simpset_of ctxt;
   428 
   429     fun err msg =
   430       error (Pretty.string_of (Pretty.block
   431         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   432 
   433     val elims = Induct.find_casesP ctxt prop;
   434 
   435     val cprop = Thm.cterm_of thy prop;
   436     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   437     fun mk_elim rl =
   438       Thm.implies_intr cprop (Tactic.rule_by_tactic tac (Thm.assume cprop RS rl))
   439       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   440   in
   441     (case get_first (try mk_elim) elims of
   442       SOME r => r
   443     | NONE => err "Proposition not an inductive predicate:")
   444   end;
   445 
   446 end;
   447 
   448 
   449 (* inductive_cases *)
   450 
   451 fun gen_inductive_cases prep_att prep_prop args lthy =
   452   let
   453     val thy = ProofContext.theory_of lthy;
   454     val facts = args |> map (fn ((a, atts), props) =>
   455       ((a, map (prep_att thy) atts),
   456         map (Thm.no_attributes o single o mk_cases lthy o prep_prop lthy) props));
   457   in lthy |> LocalTheory.notes Thm.theoremK facts |>> map snd end;
   458 
   459 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   460 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   461 
   462 
   463 fun ind_cases src = Method.syntax (Scan.lift (Scan.repeat1 Args.name_source --
   464     Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.name) [])) src
   465   #> (fn ((raw_props, fixes), ctxt) =>
   466     let
   467       val (_, ctxt') = Variable.add_fixes fixes ctxt;
   468       val props = Syntax.read_props ctxt' raw_props;
   469       val ctxt'' = fold Variable.declare_term props ctxt';
   470       val rules = ProofContext.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   471     in Method.erule 0 rules end);
   472 
   473 
   474 
   475 (* prove induction rule *)
   476 
   477 fun prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono
   478     fp_def rec_preds_defs ctxt =
   479   let
   480     val _ = clean_message quiet_mode "  Proving the induction rule ...";
   481     val thy = ProofContext.theory_of ctxt;
   482 
   483     (* predicates for induction rule *)
   484 
   485     val (pnames, ctxt') = ctxt |>
   486       Variable.add_fixes (map (fst o dest_Free) params) |> snd |>
   487       Variable.variant_fixes (mk_names "P" (length cs));
   488     val preds = map Free (pnames ~~
   489       map (fn c => List.drop (binder_types (fastype_of c), length params) --->
   490         HOLogic.boolT) cs);
   491 
   492     (* transform an introduction rule into a premise for induction rule *)
   493 
   494     fun mk_ind_prem r =
   495       let
   496         fun subst s = (case dest_predicate cs params s of
   497             SOME (_, i, ys, (_, Ts)) =>
   498               let
   499                 val k = length Ts;
   500                 val bs = map Bound (k - 1 downto 0);
   501                 val P = list_comb (List.nth (preds, i),
   502                   map (incr_boundvars k) ys @ bs);
   503                 val Q = list_abs (mk_names "x" k ~~ Ts,
   504                   HOLogic.mk_binop inductive_conj_name
   505                     (list_comb (incr_boundvars k s, bs), P))
   506               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   507           | NONE => (case s of
   508               (t $ u) => (fst (subst t) $ fst (subst u), NONE)
   509             | (Abs (a, T, t)) => (Abs (a, T, fst (subst t)), NONE)
   510             | _ => (s, NONE)));
   511 
   512         fun mk_prem (s, prems) = (case subst s of
   513               (_, SOME (t, u)) => t :: u :: prems
   514             | (t, _) => t :: prems);
   515 
   516         val SOME (_, i, ys, _) = dest_predicate cs params
   517           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))
   518 
   519       in list_all_free (Logic.strip_params r,
   520         Logic.list_implies (map HOLogic.mk_Trueprop (foldr mk_prem
   521           [] (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r))),
   522             HOLogic.mk_Trueprop (list_comb (List.nth (preds, i), ys))))
   523       end;
   524 
   525     val ind_prems = map mk_ind_prem intr_ts;
   526 
   527 
   528     (* make conclusions for induction rules *)
   529 
   530     val Tss = map (binder_types o fastype_of) preds;
   531     val (xnames, ctxt'') =
   532       Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   533     val mutual_ind_concl = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   534         (map (fn (((xnames, Ts), c), P) =>
   535            let val frees = map Free (xnames ~~ Ts)
   536            in HOLogic.mk_imp
   537              (list_comb (c, params @ frees), list_comb (P, frees))
   538            end) (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   539 
   540 
   541     (* make predicate for instantiation of abstract induction rule *)
   542 
   543     val ind_pred = fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   544       (map_index (fn (i, P) => foldr HOLogic.mk_imp
   545          (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))
   546          (make_bool_args HOLogic.mk_not I bs i)) preds));
   547 
   548     val ind_concl = HOLogic.mk_Trueprop
   549       (HOLogic.mk_binrel "HOL.ord_class.less_eq" (rec_const, ind_pred));
   550 
   551     val raw_fp_induct = (mono RS (fp_def RS def_lfp_induct));
   552 
   553     val induct = SkipProof.prove ctxt'' [] ind_prems ind_concl
   554       (fn {prems, ...} => EVERY
   555         [rewrite_goals_tac [inductive_conj_def],
   556          DETERM (rtac raw_fp_induct 1),
   557          REPEAT (resolve_tac [le_funI, le_boolI] 1),
   558          rewrite_goals_tac (inf_fun_eq :: inf_bool_eq :: simp_thms'),
   559          (*This disjE separates out the introduction rules*)
   560          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   561          (*Now break down the individual cases.  No disjE here in case
   562            some premise involves disjunction.*)
   563          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   564          REPEAT (FIRSTGOAL
   565            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   566          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   567              (inductive_conj_def :: rec_preds_defs @ simp_thms') prem,
   568            conjI, refl] 1)) prems)]);
   569 
   570     val lemma = SkipProof.prove ctxt'' [] []
   571       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   572         [rewrite_goals_tac rec_preds_defs,
   573          REPEAT (EVERY
   574            [REPEAT (resolve_tac [conjI, impI] 1),
   575             REPEAT (eresolve_tac [le_funE, le_boolE] 1),
   576             atac 1,
   577             rewrite_goals_tac simp_thms',
   578             atac 1])])
   579 
   580   in singleton (ProofContext.export ctxt'' ctxt) (induct RS lemma) end;
   581 
   582 
   583 
   584 (** specification of (co)inductive predicates **)
   585 
   586 fun mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts monos params cnames_syn ctxt =
   587   let
   588     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   589 
   590     val argTs = fold (fn c => fn Ts => Ts @
   591       (List.drop (binder_types (fastype_of c), length params) \\ Ts)) cs [];
   592     val k = log 2 1 (length cs);
   593     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   594     val p :: xs = map Free (Variable.variant_frees ctxt intr_ts
   595       (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   596     val bs = map Free (Variable.variant_frees ctxt (p :: xs @ intr_ts)
   597       (map (rpair HOLogic.boolT) (mk_names "b" k)));
   598 
   599     fun subst t = (case dest_predicate cs params t of
   600         SOME (_, i, ts, (Ts, Us)) =>
   601           let
   602             val l = length Us;
   603             val zs = map Bound (l - 1 downto 0)
   604           in
   605             list_abs (map (pair "z") Us, list_comb (p,
   606               make_bool_args' bs i @ make_args argTs
   607                 ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   608           end
   609       | NONE => (case t of
   610           t1 $ t2 => subst t1 $ subst t2
   611         | Abs (x, T, u) => Abs (x, T, subst u)
   612         | _ => t));
   613 
   614     (* transform an introduction rule into a conjunction  *)
   615     (*   [| p_i t; ... |] ==> p_j u                       *)
   616     (* is transformed into                                *)
   617     (*   b_j & x_j = u & p b_j t & ...                    *)
   618 
   619     fun transform_rule r =
   620       let
   621         val SOME (_, i, ts, (Ts, _)) = dest_predicate cs params
   622           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   623         val ps = make_bool_args HOLogic.mk_not I bs i @
   624           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   625           map (subst o HOLogic.dest_Trueprop)
   626             (Logic.strip_assums_hyp r)
   627       in foldr (fn ((x, T), P) => HOLogic.exists_const T $ (Abs (x, T, P)))
   628         (if null ps then HOLogic.true_const else foldr1 HOLogic.mk_conj ps)
   629         (Logic.strip_params r)
   630       end
   631 
   632     (* make a disjunction of all introduction rules *)
   633 
   634     val fp_fun = fold_rev lambda (p :: bs @ xs)
   635       (if null intr_ts then HOLogic.false_const
   636        else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   637 
   638     (* add definiton of recursive predicates to theory *)
   639 
   640     val rec_name =
   641       if Binding.is_empty alt_name then
   642         Binding.name (space_implode "_" (map (Binding.base_name o fst) cnames_syn))
   643       else alt_name;
   644 
   645     val ((rec_const, (_, fp_def)), ctxt') = ctxt |>
   646       LocalTheory.define Thm.internalK
   647         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   648          (Attrib.empty_binding, fold_rev lambda params
   649            (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)));
   650     val fp_def' = Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   651       (cterm_of (ProofContext.theory_of ctxt') (list_comb (rec_const, params)));
   652     val specs = if length cs < 2 then [] else
   653       map_index (fn (i, (name_mx, c)) =>
   654         let
   655           val Ts = List.drop (binder_types (fastype_of c), length params);
   656           val xs = map Free (Variable.variant_frees ctxt intr_ts
   657             (mk_names "x" (length Ts) ~~ Ts))
   658         in
   659           (name_mx, (Attrib.empty_binding, fold_rev lambda (params @ xs)
   660             (list_comb (rec_const, params @ make_bool_args' bs i @
   661               make_args argTs (xs ~~ Ts)))))
   662         end) (cnames_syn ~~ cs);
   663     val (consts_defs, ctxt'') = fold_map (LocalTheory.define Thm.internalK) specs ctxt';
   664     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   665 
   666     val mono = prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt'';
   667     val ((_, [mono']), ctxt''') =
   668       LocalTheory.note Thm.internalK (Attrib.empty_binding, [mono]) ctxt'';
   669 
   670   in (ctxt''', rec_name, mono', fp_def', map (#2 o #2) consts_defs,
   671     list_comb (rec_const, params), preds, argTs, bs, xs)
   672   end;
   673 
   674 fun declare_rules kind rec_binding coind no_ind cnames intrs intr_bindings intr_atts
   675       elims raw_induct ctxt =
   676   let
   677     val rec_name = Binding.base_name rec_binding;
   678     val rec_qualified = Binding.qualify rec_name;
   679     val intr_names = map Binding.base_name intr_bindings;
   680     val ind_case_names = RuleCases.case_names intr_names;
   681     val induct =
   682       if coind then
   683         (raw_induct, [RuleCases.case_names [rec_name],
   684           RuleCases.case_conclusion (rec_name, intr_names),
   685           RuleCases.consumes 1, Induct.coinduct_pred (hd cnames)])
   686       else if no_ind orelse length cnames > 1 then
   687         (raw_induct, [ind_case_names, RuleCases.consumes 0])
   688       else (raw_induct RSN (2, rev_mp), [ind_case_names, RuleCases.consumes 1]);
   689 
   690     val (intrs', ctxt1) =
   691       ctxt |>
   692       LocalTheory.notes kind
   693         (map rec_qualified intr_bindings ~~ intr_atts ~~ map (fn th => [([th],
   694            [Attrib.internal (K (ContextRules.intro_query NONE)),
   695             Attrib.internal (K Nitpick_Ind_Intro_Thms.add)])]) intrs) |>>
   696       map (hd o snd);
   697     val (((_, elims'), (_, [induct'])), ctxt2) =
   698       ctxt1 |>
   699       LocalTheory.note kind ((rec_qualified (Binding.name "intros"), []), intrs') ||>>
   700       fold_map (fn (name, (elim, cases)) =>
   701         LocalTheory.note kind ((Binding.name (NameSpace.qualified (Sign.base_name name) "cases"),
   702           [Attrib.internal (K (RuleCases.case_names cases)),
   703            Attrib.internal (K (RuleCases.consumes 1)),
   704            Attrib.internal (K (Induct.cases_pred name)),
   705            Attrib.internal (K (ContextRules.elim_query NONE))]), [elim]) #>
   706         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   707       LocalTheory.note kind
   708         ((rec_qualified (Binding.name (coind_prefix coind ^ "induct")),
   709           map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   710 
   711     val ctxt3 = if no_ind orelse coind then ctxt2 else
   712       let val inducts = cnames ~~ ProjectRule.projects ctxt2 (1 upto length cnames) induct'
   713       in
   714         ctxt2 |>
   715         LocalTheory.notes kind [((rec_qualified (Binding.name "inducts"), []),
   716           inducts |> map (fn (name, th) => ([th],
   717             [Attrib.internal (K ind_case_names),
   718              Attrib.internal (K (RuleCases.consumes 1)),
   719              Attrib.internal (K (Induct.induct_pred name))])))] |> snd
   720       end
   721   in (intrs', elims', induct', ctxt3) end;
   722 
   723 type inductive_flags =
   724   {quiet_mode: bool, verbose: bool, kind: string, alt_name: binding,
   725    coind: bool, no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool}
   726 
   727 type add_ind_def =
   728   inductive_flags ->
   729   term list -> (Attrib.binding * term) list -> thm list ->
   730   term list -> (binding * mixfix) list ->
   731   local_theory -> inductive_result * local_theory
   732 
   733 fun add_ind_def {quiet_mode, verbose, kind, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono}
   734     cs intros monos params cnames_syn ctxt =
   735   let
   736     val _ = null cnames_syn andalso error "No inductive predicates given";
   737     val names = map (Binding.base_name o fst) cnames_syn;
   738     val _ = message (quiet_mode andalso not verbose)
   739       ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^ commas_quote names);
   740 
   741     val cnames = map (LocalTheory.full_name ctxt o #1) cnames_syn;  (* FIXME *)
   742     val ((intr_names, intr_atts), intr_ts) =
   743       apfst split_list (split_list (map (check_rule ctxt cs params) intros));
   744 
   745     val (ctxt1, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   746       argTs, bs, xs) = mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts
   747         monos params cnames_syn ctxt;
   748 
   749     val (intrs, unfold) = prove_intrs quiet_mode coind mono fp_def (length bs + length xs)
   750       params intr_ts rec_preds_defs ctxt1;
   751     val elims = if no_elim then [] else
   752       prove_elims quiet_mode cs params intr_ts (map Binding.base_name intr_names)
   753         unfold rec_preds_defs ctxt1;
   754     val raw_induct = zero_var_indexes
   755       (if no_ind then Drule.asm_rl else
   756        if coind then
   757          singleton (ProofContext.export
   758            (snd (Variable.add_fixes (map (fst o dest_Free) params) ctxt1)) ctxt1)
   759            (rotate_prems ~1 (ObjectLogic.rulify
   760              (fold_rule rec_preds_defs
   761                (rewrite_rule [le_fun_def, le_bool_def, sup_fun_eq, sup_bool_eq]
   762                 (mono RS (fp_def RS def_coinduct))))))
   763        else
   764          prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono fp_def
   765            rec_preds_defs ctxt1);
   766 
   767     val (intrs', elims', induct, ctxt2) = declare_rules kind rec_name coind no_ind
   768       cnames intrs intr_names intr_atts elims raw_induct ctxt1;
   769 
   770     val result =
   771       {preds = preds,
   772        intrs = intrs',
   773        elims = elims',
   774        raw_induct = rulify raw_induct,
   775        induct = induct};
   776 
   777     val ctxt3 = ctxt2
   778       |> LocalTheory.declaration (fn phi =>
   779         let val result' = morph_result phi result;
   780         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   781   in (result, ctxt3) end;
   782 
   783 
   784 (* external interfaces *)
   785 
   786 fun gen_add_inductive_i mk_def
   787     (flags as {quiet_mode, verbose, kind, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono})
   788     cnames_syn pnames spec monos lthy =
   789   let
   790     val thy = ProofContext.theory_of lthy;
   791     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   792 
   793 
   794     (* abbrevs *)
   795 
   796     val (_, ctxt1) = Variable.add_fixes (map (Binding.base_name o fst o fst) cnames_syn) lthy;
   797 
   798     fun get_abbrev ((name, atts), t) =
   799       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   800         let
   801           val _ = Binding.is_empty name andalso null atts orelse
   802             error "Abbreviations may not have names or attributes";
   803           val ((x, T), rhs) = LocalDefs.abs_def (snd (LocalDefs.cert_def ctxt1 t));
   804           val var =
   805             (case find_first (fn ((c, _), _) => Binding.base_name c = x) cnames_syn of
   806               NONE => error ("Undeclared head of abbreviation " ^ quote x)
   807             | SOME ((b, T'), mx) =>
   808                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
   809                 else (b, mx));
   810         in SOME (var, rhs) end
   811       else NONE;
   812 
   813     val abbrevs = map_filter get_abbrev spec;
   814     val bs = map (Binding.base_name o fst o fst) abbrevs;
   815 
   816 
   817     (* predicates *)
   818 
   819     val pre_intros = filter_out (is_some o get_abbrev) spec;
   820     val cnames_syn' = filter_out (member (op =) bs o Binding.base_name o fst o fst) cnames_syn;
   821     val cs = map (Free o apfst Binding.base_name o fst) cnames_syn';
   822     val ps = map Free pnames;
   823 
   824     val (_, ctxt2) = lthy |> Variable.add_fixes (map (Binding.base_name o fst o fst) cnames_syn');
   825     val _ = map (fn abbr => LocalDefs.fixed_abbrev abbr ctxt2) abbrevs;
   826     val ctxt3 = ctxt2 |> fold (snd oo LocalDefs.fixed_abbrev) abbrevs;
   827     val expand = Assumption.export_term ctxt3 lthy #> ProofContext.cert_term lthy;
   828 
   829     fun close_rule r = list_all_free (rev (fold_aterms
   830       (fn t as Free (v as (s, _)) =>
   831           if Variable.is_fixed ctxt1 s orelse
   832             member (op =) ps t then I else insert (op =) v
   833         | _ => I) r []), r);
   834 
   835     val intros = map (apsnd (Syntax.check_term lthy #> close_rule #> expand)) pre_intros;
   836     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
   837   in
   838     lthy
   839     |> mk_def flags cs intros monos ps preds
   840     ||> fold (snd oo LocalTheory.abbrev Syntax.mode_default) abbrevs
   841   end;
   842 
   843 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos int lthy =
   844   let
   845     val ((vars, specs), _) = lthy |> ProofContext.set_mode ProofContext.mode_abbrev
   846       |> Specification.read_specification
   847           (cnames_syn @ pnames_syn) (map (fn (a, s) => [(a, [s])]) intro_srcs);
   848     val (cs, ps) = chop (length cnames_syn) vars;
   849     val intrs = map (apsnd the_single) specs;
   850     val monos = Attrib.eval_thms lthy raw_monos;
   851     val flags = {quiet_mode = false, verbose = verbose, kind = Thm.theoremK,
   852       alt_name = Binding.empty, coind = coind, no_elim = false, no_ind = false,
   853       skip_mono = false, fork_mono = not int};
   854   in
   855     lthy
   856     |> LocalTheory.set_group (serial_string ())
   857     |> gen_add_inductive_i mk_def flags cs (map (apfst Binding.base_name o fst) ps) intrs monos
   858   end;
   859 
   860 val add_inductive_i = gen_add_inductive_i add_ind_def;
   861 val add_inductive = gen_add_inductive add_ind_def;
   862 
   863 fun add_inductive_global group flags cnames_syn pnames pre_intros monos thy =
   864   let
   865     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
   866     val ctxt' = thy
   867       |> TheoryTarget.init NONE
   868       |> LocalTheory.set_group group
   869       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
   870       |> LocalTheory.exit;
   871     val info = #2 (the_inductive ctxt' name);
   872   in (info, ProofContext.theory_of ctxt') end;
   873 
   874 
   875 (* read off arities of inductive predicates from raw induction rule *)
   876 fun arities_of induct =
   877   map (fn (_ $ t $ u) =>
   878       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
   879     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
   880 
   881 (* read off parameters of inductive predicate from raw induction rule *)
   882 fun params_of induct =
   883   let
   884     val (_ $ t $ u :: _) =
   885       HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
   886     val (_, ts) = strip_comb t;
   887     val (_, us) = strip_comb u
   888   in
   889     List.take (ts, length ts - length us)
   890   end;
   891 
   892 val pname_of_intr =
   893   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
   894 
   895 (* partition introduction rules according to predicate name *)
   896 fun gen_partition_rules f induct intros =
   897   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
   898     (map (rpair [] o fst) (arities_of induct));
   899 
   900 val partition_rules = gen_partition_rules I;
   901 fun partition_rules' induct = gen_partition_rules fst induct;
   902 
   903 fun unpartition_rules intros xs =
   904   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
   905     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
   906 
   907 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
   908 fun infer_intro_vars elim arity intros =
   909   let
   910     val thy = theory_of_thm elim;
   911     val _ :: cases = prems_of elim;
   912     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
   913     fun mtch (t, u) =
   914       let
   915         val params = Logic.strip_params t;
   916         val vars = map (Var o apfst (rpair 0))
   917           (Name.variant_list used (map fst params) ~~ map snd params);
   918         val ts = map (curry subst_bounds (rev vars))
   919           (List.drop (Logic.strip_assums_hyp t, arity));
   920         val us = Logic.strip_imp_prems u;
   921         val tab = fold (Pattern.first_order_match thy) (ts ~~ us)
   922           (Vartab.empty, Vartab.empty);
   923       in
   924         map (Envir.subst_vars tab) vars
   925       end
   926   in
   927     map (mtch o apsnd prop_of) (cases ~~ intros)
   928   end;
   929 
   930 
   931 
   932 (** package setup **)
   933 
   934 (* setup theory *)
   935 
   936 val setup =
   937   Method.add_methods [("ind_cases", ind_cases,
   938     "dynamic case analysis on predicates")] #>
   939   Attrib.add_attributes [("mono", Attrib.add_del_args mono_add mono_del,
   940     "declaration of monotonicity rule")];
   941 
   942 
   943 (* outer syntax *)
   944 
   945 local structure P = OuterParse and K = OuterKeyword in
   946 
   947 val _ = OuterKeyword.keyword "monos";
   948 
   949 (* FIXME eliminate *)
   950 fun flatten_specification specs = specs |> maps
   951   (fn (a, (concl, [])) => concl |> map
   952         (fn ((b, atts), [B]) =>
   953               if Binding.is_empty a then ((b, atts), B)
   954               else if Binding.is_empty b then ((a, atts), B)
   955               else error "Illegal nested case names"
   956           | ((b, _), _) => error "Illegal simultaneous specification")
   957     | (a, _) => error ("Illegal local specification parameters for " ^ quote (Binding.base_name a)));
   958 
   959 fun gen_ind_decl mk_def coind =
   960   P.fixes -- P.for_fixes --
   961   Scan.optional (P.$$$ "where" |-- P.!!! SpecParse.specification) [] --
   962   Scan.optional (P.$$$ "monos" |-- P.!!! SpecParse.xthms1) []
   963   >> (fn (((preds, params), specs), monos) =>
   964       (snd oo gen_add_inductive mk_def true coind preds params (flatten_specification specs) monos));
   965 
   966 val ind_decl = gen_ind_decl add_ind_def;
   967 
   968 val _ = OuterSyntax.local_theory' "inductive" "define inductive predicates" K.thy_decl (ind_decl false);
   969 val _ = OuterSyntax.local_theory' "coinductive" "define coinductive predicates" K.thy_decl (ind_decl true);
   970 
   971 val _ =
   972   OuterSyntax.local_theory "inductive_cases"
   973     "create simplified instances of elimination rules (improper)" K.thy_script
   974     (P.and_list1 SpecParse.spec >> (fn specs => snd o inductive_cases specs));
   975 
   976 end;
   977 
   978 end;