src/HOL/Orderings.thy
author haftmann
Wed Feb 14 10:06:12 2007 +0100 (2007-02-14)
changeset 22316 f662831459de
parent 22295 5f8a2898668c
child 22344 eddeabf16b5d
permissions -rw-r--r--
added class "preorder"
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports HOL
    10 begin
    11 
    12 subsection {* Order syntax *}
    13 
    14 class ord =
    15   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubseteq>" 50)
    16     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubset>" 50)
    17 begin
    18 
    19 notation
    20   less_eq  ("op \<^loc><=") and
    21   less_eq  ("(_/ \<^loc><= _)" [51, 51] 50) and
    22   less  ("op \<^loc><") and
    23   less  ("(_/ \<^loc>< _)"  [51, 51] 50)
    24   
    25 notation (xsymbols)
    26   less_eq  ("op \<^loc>\<le>") and
    27   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    28 
    29 notation (HTML output)
    30   less_eq  ("op \<^loc>\<le>") and
    31   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    32 
    33 abbreviation (input)
    34   greater  (infix "\<^loc>>" 50) where
    35   "x \<^loc>> y \<equiv> y \<^loc>< x"
    36 
    37 abbreviation (input)
    38   greater_eq  (infix "\<^loc>>=" 50) where
    39   "x \<^loc>>= y \<equiv> y \<^loc><= x"
    40 
    41 notation (input)
    42   greater_eq  (infix "\<^loc>\<ge>" 50)
    43 
    44 end
    45 
    46 notation
    47   less_eq  ("op <=") and
    48   less_eq  ("(_/ <= _)" [51, 51] 50) and
    49   less  ("op <") and
    50   less  ("(_/ < _)"  [51, 51] 50)
    51   
    52 notation (xsymbols)
    53   less_eq  ("op \<le>") and
    54   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    55 
    56 notation (HTML output)
    57   less_eq  ("op \<le>") and
    58   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    59 
    60 abbreviation (input)
    61   greater  (infix ">" 50) where
    62   "x > y \<equiv> y < x"
    63 
    64 abbreviation (input)
    65   greater_eq  (infix ">=" 50) where
    66   "x >= y \<equiv> y <= x"
    67 
    68 notation (input)
    69   greater_eq  (infix "\<ge>" 50)
    70 
    71 
    72 subsection {* Quasiorders (preorders) *}
    73 
    74 class preorder = ord +
    75   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    76   and refl [iff]: "x \<sqsubseteq> x"
    77   and trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    78 begin
    79 
    80 text {* Reflexivity. *}
    81 
    82 lemma eq_refl: "x = y \<Longrightarrow> x \<sqsubseteq> y"
    83     -- {* This form is useful with the classical reasoner. *}
    84   by (erule ssubst) (rule refl)
    85 
    86 lemma less_irrefl [iff]: "\<not> x \<sqsubset> x"
    87   by (simp add: less_le)
    88 
    89 lemma le_less: "x \<sqsubseteq> y \<longleftrightarrow> x \<sqsubset> y \<or> x = y"
    90     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    91   by (simp add: less_le) blast
    92 
    93 lemma le_imp_less_or_eq: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubset> y \<or> x = y"
    94   unfolding less_le by blast
    95 
    96 lemma less_imp_le: "x \<sqsubset> y \<Longrightarrow> x \<sqsubseteq> y"
    97   unfolding less_le by blast
    98 
    99 lemma less_imp_neq: "x \<sqsubset> y \<Longrightarrow> x \<noteq> y"
   100   by (erule contrapos_pn, erule subst, rule less_irrefl)
   101 
   102 
   103 text {* Useful for simplification, but too risky to include by default. *}
   104 
   105 lemma less_imp_not_eq: "x \<sqsubset> y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   106   by auto
   107 
   108 lemma less_imp_not_eq2: "x \<sqsubset> y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   109   by auto
   110 
   111 
   112 text {* Transitivity rules for calculational reasoning *}
   113 
   114 lemma neq_le_trans: "\<lbrakk> a \<noteq> b; a \<sqsubseteq> b \<rbrakk> \<Longrightarrow> a \<sqsubset> b"
   115   by (simp add: less_le)
   116 
   117 lemma le_neq_trans: "\<lbrakk> a \<sqsubseteq> b; a \<noteq> b \<rbrakk> \<Longrightarrow> a \<sqsubset> b"
   118   by (simp add: less_le)
   119 
   120 end
   121 
   122 
   123 subsection {* Partial orderings *}
   124 
   125 class order = preorder + 
   126   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
   127 
   128 context order
   129 begin
   130 
   131 text {* Asymmetry. *}
   132 
   133 lemma less_not_sym: "x \<sqsubset> y \<Longrightarrow> \<not> (y \<sqsubset> x)"
   134   by (simp add: less_le antisym)
   135 
   136 lemma less_asym: "x \<sqsubset> y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<sqsubset> x) \<Longrightarrow> P"
   137   by (drule less_not_sym, erule contrapos_np) simp
   138 
   139 lemma eq_iff: "x = y \<longleftrightarrow> x \<sqsubseteq> y \<and> y \<sqsubseteq> x"
   140   by (blast intro: antisym)
   141 
   142 lemma antisym_conv: "y \<sqsubseteq> x \<Longrightarrow> x \<sqsubseteq> y \<longleftrightarrow> x = y"
   143   by (blast intro: antisym)
   144 
   145 lemma less_imp_neq: "x \<sqsubset> y \<Longrightarrow> x \<noteq> y"
   146   by (erule contrapos_pn, erule subst, rule less_irrefl)
   147 
   148 
   149 text {* Transitivity. *}
   150 
   151 lemma less_trans: "\<lbrakk> x \<sqsubset> y; y \<sqsubset> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   152   by (simp add: less_le) (blast intro: trans antisym)
   153 
   154 lemma le_less_trans: "\<lbrakk> x \<sqsubseteq> y; y \<sqsubset> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   155   by (simp add: less_le) (blast intro: trans antisym)
   156 
   157 lemma less_le_trans: "\<lbrakk> x \<sqsubset> y; y \<sqsubseteq> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   158   by (simp add: less_le) (blast intro: trans antisym)
   159 
   160 
   161 text {* Useful for simplification, but too risky to include by default. *}
   162 
   163 lemma less_imp_not_less: "x \<sqsubset> y \<Longrightarrow> (\<not> y \<sqsubset> x) \<longleftrightarrow> True"
   164   by (blast elim: less_asym)
   165 
   166 lemma less_imp_triv: "x \<sqsubset> y \<Longrightarrow> (y \<sqsubset> x \<longrightarrow> P) \<longleftrightarrow> True"
   167   by (blast elim: less_asym)
   168 
   169 
   170 text {* Transitivity rules for calculational reasoning *}
   171 
   172 lemma less_asym': "\<lbrakk> a \<sqsubset> b; b \<sqsubset> a \<rbrakk> \<Longrightarrow> P"
   173   by (rule less_asym)
   174 
   175 end
   176 
   177 
   178 subsection {* Linear (total) orders *}
   179 
   180 class linorder = order +
   181   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   182 begin
   183 
   184 lemma less_linear: "x \<sqsubset> y \<or> x = y \<or> y \<sqsubset> x"
   185   unfolding less_le using less_le linear by blast 
   186 
   187 lemma le_less_linear: "x \<sqsubseteq> y \<or> y \<sqsubset> x"
   188   by (simp add: le_less less_linear)
   189 
   190 lemma le_cases [case_names le ge]:
   191   "\<lbrakk> x \<sqsubseteq> y \<Longrightarrow> P; y \<sqsubseteq> x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   192   using linear by blast
   193 
   194 lemma cases [case_names less equal greater]:
   195     "\<lbrakk> x \<sqsubset> y \<Longrightarrow> P; x = y \<Longrightarrow> P; y \<sqsubset> x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   196   using less_linear by blast
   197 
   198 lemma not_less: "\<not> x \<sqsubset> y \<longleftrightarrow> y \<sqsubseteq> x"
   199   apply (simp add: less_le)
   200   using linear apply (blast intro: antisym)
   201   done
   202 
   203 lemma not_le: "\<not> x \<sqsubseteq> y \<longleftrightarrow> y \<sqsubset> x"
   204   apply (simp add: less_le)
   205   using linear apply (blast intro: antisym)
   206   done
   207 
   208 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<sqsubset> y \<or> y \<sqsubset> x"
   209   by (cut_tac x = x and y = y in less_linear, auto)
   210 
   211 lemma neqE: "\<lbrakk> x \<noteq> y; x \<sqsubset> y \<Longrightarrow> R; y \<sqsubset> x \<Longrightarrow> R\<rbrakk> \<Longrightarrow> R"
   212   by (simp add: neq_iff) blast
   213 
   214 lemma antisym_conv1: "\<not> x \<sqsubset> y \<Longrightarrow> x \<sqsubseteq> y \<longleftrightarrow> x = y"
   215   by (blast intro: antisym dest: not_less [THEN iffD1])
   216 
   217 lemma antisym_conv2: "x \<sqsubseteq> y \<Longrightarrow> \<not> x \<sqsubset> y \<longleftrightarrow> x = y"
   218   by (blast intro: antisym dest: not_less [THEN iffD1])
   219 
   220 lemma antisym_conv3: "\<not> y \<sqsubset> x \<Longrightarrow> \<not> x \<sqsubset> y \<longleftrightarrow> x = y"
   221   by (blast intro: antisym dest: not_less [THEN iffD1])
   222 
   223 text{*Replacing the old Nat.leI*}
   224 lemma leI: "\<not> x \<sqsubset> y \<Longrightarrow> y \<sqsubseteq> x"
   225   unfolding not_less .
   226 
   227 lemma leD: "y \<sqsubseteq> x \<Longrightarrow> \<not> x \<sqsubset> y"
   228   unfolding not_less .
   229 
   230 (*FIXME inappropriate name (or delete altogether)*)
   231 lemma not_leE: "\<not> y \<sqsubseteq> x \<Longrightarrow> x \<sqsubset> y"
   232   unfolding not_le .
   233 
   234 (* min/max *)
   235 
   236 definition
   237   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   238   "min a b = (if a \<sqsubseteq> b then a else b)"
   239 
   240 definition
   241   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   242   "max a b = (if a \<sqsubseteq> b then b else a)"
   243 
   244 lemma min_le_iff_disj:
   245   "min x y \<sqsubseteq> z \<longleftrightarrow> x \<sqsubseteq> z \<or> y \<sqsubseteq> z"
   246   unfolding min_def using linear by (auto intro: trans)
   247 
   248 lemma le_max_iff_disj:
   249   "z \<sqsubseteq> max x y \<longleftrightarrow> z \<sqsubseteq> x \<or> z \<sqsubseteq> y"
   250   unfolding max_def using linear by (auto intro: trans)
   251 
   252 lemma min_less_iff_disj:
   253   "min x y \<sqsubset> z \<longleftrightarrow> x \<sqsubset> z \<or> y \<sqsubset> z"
   254   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   255 
   256 lemma less_max_iff_disj:
   257   "z \<sqsubset> max x y \<longleftrightarrow> z \<sqsubset> x \<or> z \<sqsubset> y"
   258   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   259 
   260 lemma min_less_iff_conj [simp]:
   261   "z \<sqsubset> min x y \<longleftrightarrow> z \<sqsubset> x \<and> z \<sqsubset> y"
   262   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   263 
   264 lemma max_less_iff_conj [simp]:
   265   "max x y \<sqsubset> z \<longleftrightarrow> x \<sqsubset> z \<and> y \<sqsubset> z"
   266   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   267 
   268 lemma split_min:
   269   "P (min i j) \<longleftrightarrow> (i \<sqsubseteq> j \<longrightarrow> P i) \<and> (\<not> i \<sqsubseteq> j \<longrightarrow> P j)"
   270   by (simp add: min_def)
   271 
   272 lemma split_max:
   273   "P (max i j) \<longleftrightarrow> (i \<sqsubseteq> j \<longrightarrow> P j) \<and> (\<not> i \<sqsubseteq> j \<longrightarrow> P i)"
   274   by (simp add: max_def)
   275 
   276 end
   277 
   278 
   279 subsection {* Name duplicates *}
   280 
   281 lemmas order_refl [iff] = preorder_class.refl
   282 lemmas order_trans = preorder_class.trans
   283 lemmas order_less_le = preorder_class.less_le
   284 lemmas order_eq_refl = preorder_class.eq_refl
   285 lemmas order_less_irrefl = preorder_class.less_irrefl
   286 lemmas order_le_less = preorder_class.le_less
   287 lemmas order_le_imp_less_or_eq = preorder_class.le_imp_less_or_eq
   288 lemmas order_less_imp_le = preorder_class.less_imp_le
   289 lemmas order_less_imp_not_eq = preorder_class.less_imp_not_eq
   290 lemmas order_less_imp_not_eq2 = preorder_class.less_imp_not_eq2
   291 lemmas order_neq_le_trans = preorder_class.neq_le_trans
   292 lemmas order_le_neq_trans = preorder_class.le_neq_trans
   293 
   294 lemmas order_antisym = order_class.antisym
   295 lemmas order_less_not_sym = order_class.less_not_sym
   296 lemmas order_less_asym = order_class.less_asym
   297 lemmas order_eq_iff = order_class.eq_iff
   298 lemmas order_antisym_conv = order_class.antisym_conv
   299 lemmas less_imp_neq = order_class.less_imp_neq
   300 lemmas order_less_trans = order_class.less_trans
   301 lemmas order_le_less_trans = order_class.le_less_trans
   302 lemmas order_less_le_trans = order_class.less_le_trans
   303 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   304 lemmas order_less_imp_triv = order_class.less_imp_triv
   305 lemmas order_less_asym' = order_class.less_asym'
   306 
   307 lemmas linorder_linear = linorder_class.linear
   308 lemmas linorder_less_linear = linorder_class.less_linear
   309 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   310 lemmas linorder_le_cases = linorder_class.le_cases
   311 lemmas linorder_cases = linorder_class.cases
   312 lemmas linorder_not_less = linorder_class.not_less
   313 lemmas linorder_not_le = linorder_class.not_le
   314 lemmas linorder_neq_iff = linorder_class.neq_iff
   315 lemmas linorder_neqE = linorder_class.neqE
   316 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   317 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   318 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   319 lemmas leI = linorder_class.leI
   320 lemmas leD = linorder_class.leD
   321 lemmas not_leE = linorder_class.not_leE
   322 
   323 
   324 subsection {* Reasoning tools setup *}
   325 
   326 ML {*
   327 local
   328 
   329 fun decomp_gen sort thy (Trueprop $ t) =
   330   let
   331     fun of_sort t =
   332       let
   333         val T = type_of t
   334       in
   335         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   336         T <> HOLogic.natT andalso T <> HOLogic.intT
   337           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   338       end;
   339     fun dec (Const ("Not", _) $ t) = (case dec t
   340           of NONE => NONE
   341            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   342       | dec (Const ("op =",  _) $ t1 $ t2) =
   343           if of_sort t1
   344           then SOME (t1, "=", t2)
   345           else NONE
   346       | dec (Const ("Orderings.less_eq",  _) $ t1 $ t2) =
   347           if of_sort t1
   348           then SOME (t1, "<=", t2)
   349           else NONE
   350       | dec (Const ("Orderings.less",  _) $ t1 $ t2) =
   351           if of_sort t1
   352           then SOME (t1, "<", t2)
   353           else NONE
   354       | dec _ = NONE;
   355   in dec t end;
   356 
   357 in
   358 
   359 (* The setting up of Quasi_Tac serves as a demo.  Since there is no
   360    class for quasi orders, the tactics Quasi_Tac.trans_tac and
   361    Quasi_Tac.quasi_tac are not of much use. *)
   362 
   363 structure Quasi_Tac = Quasi_Tac_Fun (
   364 struct
   365   val le_trans = thm "order_trans";
   366   val le_refl = thm "order_refl";
   367   val eqD1 = thm "order_eq_refl";
   368   val eqD2 = thm "sym" RS thm "order_eq_refl";
   369   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   370   val less_imp_le = thm "order_less_imp_le";
   371   val le_neq_trans = thm "order_le_neq_trans";
   372   val neq_le_trans = thm "order_neq_le_trans";
   373   val less_imp_neq = thm "less_imp_neq";
   374   val decomp_trans = decomp_gen ["Orderings.order"];
   375   val decomp_quasi = decomp_gen ["Orderings.order"];
   376 end);
   377 
   378 structure Order_Tac = Order_Tac_Fun (
   379 struct
   380   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   381   val le_refl = thm "order_refl";
   382   val less_imp_le = thm "order_less_imp_le";
   383   val not_lessI = thm "linorder_not_less" RS thm "iffD2";
   384   val not_leI = thm "linorder_not_le" RS thm "iffD2";
   385   val not_lessD = thm "linorder_not_less" RS thm "iffD1";
   386   val not_leD = thm "linorder_not_le" RS thm "iffD1";
   387   val eqI = thm "order_antisym";
   388   val eqD1 = thm "order_eq_refl";
   389   val eqD2 = thm "sym" RS thm "order_eq_refl";
   390   val less_trans = thm "order_less_trans";
   391   val less_le_trans = thm "order_less_le_trans";
   392   val le_less_trans = thm "order_le_less_trans";
   393   val le_trans = thm "order_trans";
   394   val le_neq_trans = thm "order_le_neq_trans";
   395   val neq_le_trans = thm "order_neq_le_trans";
   396   val less_imp_neq = thm "less_imp_neq";
   397   val eq_neq_eq_imp_neq = thm "eq_neq_eq_imp_neq";
   398   val not_sym = thm "not_sym";
   399   val decomp_part = decomp_gen ["Orderings.order"];
   400   val decomp_lin = decomp_gen ["Orderings.linorder"];
   401 end);
   402 
   403 end;
   404 *}
   405 
   406 setup {*
   407 let
   408 
   409 val order_antisym_conv = thm "order_antisym_conv"
   410 val linorder_antisym_conv1 = thm "linorder_antisym_conv1"
   411 val linorder_antisym_conv2 = thm "linorder_antisym_conv2"
   412 val linorder_antisym_conv3 = thm "linorder_antisym_conv3"
   413 
   414 fun prp t thm = (#prop (rep_thm thm) = t);
   415 
   416 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   417   let val prems = prems_of_ss ss;
   418       val less = Const("Orderings.less",T);
   419       val t = HOLogic.mk_Trueprop(le $ s $ r);
   420   in case find_first (prp t) prems of
   421        NONE =>
   422          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   423          in case find_first (prp t) prems of
   424               NONE => NONE
   425             | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv1))
   426          end
   427      | SOME thm => SOME(mk_meta_eq(thm RS order_antisym_conv))
   428   end
   429   handle THM _ => NONE;
   430 
   431 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   432   let val prems = prems_of_ss ss;
   433       val le = Const("Orderings.less_eq",T);
   434       val t = HOLogic.mk_Trueprop(le $ r $ s);
   435   in case find_first (prp t) prems of
   436        NONE =>
   437          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   438          in case find_first (prp t) prems of
   439               NONE => NONE
   440             | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv3))
   441          end
   442      | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv2))
   443   end
   444   handle THM _ => NONE;
   445 
   446 fun add_simprocs procs thy =
   447   (Simplifier.change_simpset_of thy (fn ss => ss
   448     addsimprocs (map (fn (name, raw_ts, proc) =>
   449       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   450 fun add_solver name tac thy =
   451   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   452     (mk_solver name (K tac))); thy);
   453 
   454 in
   455   add_simprocs [
   456        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   457        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   458      ]
   459   #> add_solver "Trans_linear" Order_Tac.linear_tac
   460   #> add_solver "Trans_partial" Order_Tac.partial_tac
   461   (* Adding the transitivity reasoners also as safe solvers showed a slight
   462      speed up, but the reasoning strength appears to be not higher (at least
   463      no breaking of additional proofs in the entire HOL distribution, as
   464      of 5 March 2004, was observed). *)
   465 end
   466 *}
   467 
   468 
   469 subsection {* Bounded quantifiers *}
   470 
   471 syntax
   472   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   473   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   474   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   475   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   476 
   477   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   478   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   479   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   480   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   481 
   482 syntax (xsymbols)
   483   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   484   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   485   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   486   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   487 
   488   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   489   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   490   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   491   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   492 
   493 syntax (HOL)
   494   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   495   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   496   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   497   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   498 
   499 syntax (HTML output)
   500   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   501   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   502   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   503   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   504 
   505   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   506   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   507   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   508   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   509 
   510 translations
   511   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   512   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   513   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   514   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   515   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   516   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   517   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   518   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   519 
   520 print_translation {*
   521 let
   522   val syntax_name = Sign.const_syntax_name (the_context ());
   523   val binder_name = Syntax.binder_name o syntax_name;
   524   val All_binder = binder_name "All";
   525   val Ex_binder = binder_name "Ex";
   526   val impl = syntax_name "op -->";
   527   val conj = syntax_name "op &";
   528   val less = syntax_name "Orderings.less";
   529   val less_eq = syntax_name "Orderings.less_eq";
   530 
   531   val trans =
   532    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   533     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   534     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   535     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   536 
   537   fun mk v v' c n P =
   538     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   539     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   540 
   541   fun tr' q = (q,
   542     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   543       (case AList.lookup (op =) trans (q, c, d) of
   544         NONE => raise Match
   545       | SOME (l, g) =>
   546           (case (t, u) of
   547             (Const ("_bound", _) $ Free (v', _), n) => mk v v' l n P
   548           | (n, Const ("_bound", _) $ Free (v', _)) => mk v v' g n P
   549           | _ => raise Match))
   550      | _ => raise Match);
   551 in [tr' All_binder, tr' Ex_binder] end
   552 *}
   553 
   554 
   555 subsection {* Transitivity reasoning *}
   556 
   557 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   558   by (rule subst)
   559 
   560 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   561   by (rule ssubst)
   562 
   563 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   564   by (rule subst)
   565 
   566 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   567   by (rule ssubst)
   568 
   569 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   570   (!!x y. x < y ==> f x < f y) ==> f a < c"
   571 proof -
   572   assume r: "!!x y. x < y ==> f x < f y"
   573   assume "a < b" hence "f a < f b" by (rule r)
   574   also assume "f b < c"
   575   finally (order_less_trans) show ?thesis .
   576 qed
   577 
   578 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   579   (!!x y. x < y ==> f x < f y) ==> a < f c"
   580 proof -
   581   assume r: "!!x y. x < y ==> f x < f y"
   582   assume "a < f b"
   583   also assume "b < c" hence "f b < f c" by (rule r)
   584   finally (order_less_trans) show ?thesis .
   585 qed
   586 
   587 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   588   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   589 proof -
   590   assume r: "!!x y. x <= y ==> f x <= f y"
   591   assume "a <= b" hence "f a <= f b" by (rule r)
   592   also assume "f b < c"
   593   finally (order_le_less_trans) show ?thesis .
   594 qed
   595 
   596 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   597   (!!x y. x < y ==> f x < f y) ==> a < f c"
   598 proof -
   599   assume r: "!!x y. x < y ==> f x < f y"
   600   assume "a <= f b"
   601   also assume "b < c" hence "f b < f c" by (rule r)
   602   finally (order_le_less_trans) show ?thesis .
   603 qed
   604 
   605 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   606   (!!x y. x < y ==> f x < f y) ==> f a < c"
   607 proof -
   608   assume r: "!!x y. x < y ==> f x < f y"
   609   assume "a < b" hence "f a < f b" by (rule r)
   610   also assume "f b <= c"
   611   finally (order_less_le_trans) show ?thesis .
   612 qed
   613 
   614 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   615   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   616 proof -
   617   assume r: "!!x y. x <= y ==> f x <= f y"
   618   assume "a < f b"
   619   also assume "b <= c" hence "f b <= f c" by (rule r)
   620   finally (order_less_le_trans) show ?thesis .
   621 qed
   622 
   623 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   624   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   625 proof -
   626   assume r: "!!x y. x <= y ==> f x <= f y"
   627   assume "a <= f b"
   628   also assume "b <= c" hence "f b <= f c" by (rule r)
   629   finally (order_trans) show ?thesis .
   630 qed
   631 
   632 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   633   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   634 proof -
   635   assume r: "!!x y. x <= y ==> f x <= f y"
   636   assume "a <= b" hence "f a <= f b" by (rule r)
   637   also assume "f b <= c"
   638   finally (order_trans) show ?thesis .
   639 qed
   640 
   641 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   642   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   643 proof -
   644   assume r: "!!x y. x <= y ==> f x <= f y"
   645   assume "a <= b" hence "f a <= f b" by (rule r)
   646   also assume "f b = c"
   647   finally (ord_le_eq_trans) show ?thesis .
   648 qed
   649 
   650 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   651   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   652 proof -
   653   assume r: "!!x y. x <= y ==> f x <= f y"
   654   assume "a = f b"
   655   also assume "b <= c" hence "f b <= f c" by (rule r)
   656   finally (ord_eq_le_trans) show ?thesis .
   657 qed
   658 
   659 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   660   (!!x y. x < y ==> f x < f y) ==> f a < c"
   661 proof -
   662   assume r: "!!x y. x < y ==> f x < f y"
   663   assume "a < b" hence "f a < f b" by (rule r)
   664   also assume "f b = c"
   665   finally (ord_less_eq_trans) show ?thesis .
   666 qed
   667 
   668 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   669   (!!x y. x < y ==> f x < f y) ==> a < f c"
   670 proof -
   671   assume r: "!!x y. x < y ==> f x < f y"
   672   assume "a = f b"
   673   also assume "b < c" hence "f b < f c" by (rule r)
   674   finally (ord_eq_less_trans) show ?thesis .
   675 qed
   676 
   677 text {*
   678   Note that this list of rules is in reverse order of priorities.
   679 *}
   680 
   681 lemmas order_trans_rules [trans] =
   682   order_less_subst2
   683   order_less_subst1
   684   order_le_less_subst2
   685   order_le_less_subst1
   686   order_less_le_subst2
   687   order_less_le_subst1
   688   order_subst2
   689   order_subst1
   690   ord_le_eq_subst
   691   ord_eq_le_subst
   692   ord_less_eq_subst
   693   ord_eq_less_subst
   694   forw_subst
   695   back_subst
   696   rev_mp
   697   mp
   698   order_neq_le_trans
   699   order_le_neq_trans
   700   order_less_trans
   701   order_less_asym'
   702   order_le_less_trans
   703   order_less_le_trans
   704   order_trans
   705   order_antisym
   706   ord_le_eq_trans
   707   ord_eq_le_trans
   708   ord_less_eq_trans
   709   ord_eq_less_trans
   710   trans
   711 
   712 
   713 (* FIXME cleanup *)
   714 
   715 text {* These support proving chains of decreasing inequalities
   716     a >= b >= c ... in Isar proofs. *}
   717 
   718 lemma xt1:
   719   "a = b ==> b > c ==> a > c"
   720   "a > b ==> b = c ==> a > c"
   721   "a = b ==> b >= c ==> a >= c"
   722   "a >= b ==> b = c ==> a >= c"
   723   "(x::'a::order) >= y ==> y >= x ==> x = y"
   724   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   725   "(x::'a::order) > y ==> y >= z ==> x > z"
   726   "(x::'a::order) >= y ==> y > z ==> x > z"
   727   "(a::'a::order) > b ==> b > a ==> ?P"
   728   "(x::'a::order) > y ==> y > z ==> x > z"
   729   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   730   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   731   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   732   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   733   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   734   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   735 by auto
   736 
   737 lemma xt2:
   738   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   739 by (subgoal_tac "f b >= f c", force, force)
   740 
   741 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   742     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   743 by (subgoal_tac "f a >= f b", force, force)
   744 
   745 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   746   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   747 by (subgoal_tac "f b >= f c", force, force)
   748 
   749 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   750     (!!x y. x > y ==> f x > f y) ==> f a > c"
   751 by (subgoal_tac "f a > f b", force, force)
   752 
   753 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   754     (!!x y. x > y ==> f x > f y) ==> a > f c"
   755 by (subgoal_tac "f b > f c", force, force)
   756 
   757 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   758     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   759 by (subgoal_tac "f a >= f b", force, force)
   760 
   761 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   762     (!!x y. x > y ==> f x > f y) ==> a > f c"
   763 by (subgoal_tac "f b > f c", force, force)
   764 
   765 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   766     (!!x y. x > y ==> f x > f y) ==> f a > c"
   767 by (subgoal_tac "f a > f b", force, force)
   768 
   769 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   770 
   771 (* 
   772   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   773   for the wrong thing in an Isar proof.
   774 
   775   The extra transitivity rules can be used as follows: 
   776 
   777 lemma "(a::'a::order) > z"
   778 proof -
   779   have "a >= b" (is "_ >= ?rhs")
   780     sorry
   781   also have "?rhs >= c" (is "_ >= ?rhs")
   782     sorry
   783   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   784     sorry
   785   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   786     sorry
   787   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   788     sorry
   789   also (xtrans) have "?rhs > z"
   790     sorry
   791   finally (xtrans) show ?thesis .
   792 qed
   793 
   794   Alternatively, one can use "declare xtrans [trans]" and then
   795   leave out the "(xtrans)" above.
   796 *)
   797 
   798 subsection {* Order on bool *}
   799 
   800 instance bool :: linorder 
   801   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   802   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   803   by default (auto simp add: le_bool_def less_bool_def)
   804 
   805 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   806   by (simp add: le_bool_def)
   807 
   808 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   809   by (simp add: le_bool_def)
   810 
   811 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   812   by (simp add: le_bool_def)
   813 
   814 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   815   by (simp add: le_bool_def)
   816 
   817 subsection {* Monotonicity, syntactic least value operator and min/max *}
   818 
   819 locale mono =
   820   fixes f
   821   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   822 
   823 lemmas monoI [intro?] = mono.intro
   824   and monoD [dest?] = mono.mono
   825 
   826 constdefs
   827   Least :: "('a::ord => bool) => 'a"               (binder "LEAST " 10)
   828   "Least P == THE x. P x & (ALL y. P y --> x <= y)"
   829     -- {* We can no longer use LeastM because the latter requires Hilbert-AC. *}
   830 
   831 lemma LeastI2_order:
   832   "[| P (x::'a::order);
   833       !!y. P y ==> x <= y;
   834       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   835    ==> Q (Least P)"
   836   apply (unfold Least_def)
   837   apply (rule theI2)
   838     apply (blast intro: order_antisym)+
   839   done
   840 
   841 lemma Least_equality:
   842     "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   843   apply (simp add: Least_def)
   844   apply (rule the_equality)
   845   apply (auto intro!: order_antisym)
   846   done
   847 
   848 constdefs
   849   min :: "['a::ord, 'a] => 'a"
   850   "min a b == (if a <= b then a else b)"
   851   max :: "['a::ord, 'a] => 'a"
   852   "max a b == (if a <= b then b else a)"
   853 
   854 lemma min_linorder:
   855   "linorder.min (op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool) = min"
   856   by rule+ (simp add: min_def linorder_class.min_def)
   857 
   858 lemma max_linorder:
   859   "linorder.max (op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool) = max"
   860   by rule+ (simp add: max_def linorder_class.max_def)
   861 
   862 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj [unfolded min_linorder]
   863 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj [unfolded max_linorder]
   864 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj [unfolded min_linorder]
   865 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj [unfolded max_linorder]
   866 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj [unfolded min_linorder]
   867 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj [unfolded max_linorder]
   868 lemmas split_min = linorder_class.split_min [unfolded min_linorder]
   869 lemmas split_max = linorder_class.split_max [unfolded max_linorder]
   870 
   871 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   872   by (simp add: min_def)
   873 
   874 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   875   by (simp add: max_def)
   876 
   877 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   878   apply (simp add: min_def)
   879   apply (blast intro: order_antisym)
   880   done
   881 
   882 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   883   apply (simp add: max_def)
   884   apply (blast intro: order_antisym)
   885   done
   886 
   887 lemma min_of_mono:
   888     "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   889   by (simp add: min_def)
   890 
   891 lemma max_of_mono:
   892     "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   893   by (simp add: max_def)
   894 
   895 
   896 subsection {* Basic ML bindings *}
   897 
   898 ML {*
   899 val leD = thm "leD";
   900 val leI = thm "leI";
   901 val linorder_neqE = thm "linorder_neqE";
   902 val linorder_neq_iff = thm "linorder_neq_iff";
   903 val linorder_not_le = thm "linorder_not_le";
   904 val linorder_not_less = thm "linorder_not_less";
   905 val monoD = thm "monoD";
   906 val monoI = thm "monoI";
   907 val order_antisym = thm "order_antisym";
   908 val order_less_irrefl = thm "order_less_irrefl";
   909 val order_refl = thm "order_refl";
   910 val order_trans = thm "order_trans";
   911 val split_max = thm "split_max";
   912 val split_min = thm "split_min";
   913 *}
   914 
   915 ML {*
   916 structure HOL =
   917 struct
   918   val thy = theory "HOL";
   919 end;
   920 *}  -- "belongs to theory HOL"
   921 
   922 end