src/HOL/Library/Float.thy
author kuncar
Tue Feb 18 23:03:50 2014 +0100 (2014-02-18)
changeset 55565 f663fc1e653b
parent 54784 54f1ce13c140
child 55945 e96383acecf9
permissions -rw-r--r--
simplify proofs because of the stronger reflexivity prover
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Johannes Hölzl, Fabian Immler
     3     Copyright   2012  TU München
     4 *)
     5 
     6 header {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main Lattice_Algebras
    10 begin
    11 
    12 definition "float = {m * 2 powr e | (m :: int) (e :: int). True}"
    13 
    14 typedef float = float
    15   morphisms real_of_float float_of
    16   unfolding float_def by auto
    17 
    18 defs (overloaded)
    19   real_of_float_def[code_unfold]: "real \<equiv> real_of_float"
    20 
    21 lemma type_definition_float': "type_definition real float_of float"
    22   using type_definition_float unfolding real_of_float_def .
    23 
    24 setup_lifting (no_code) type_definition_float'
    25 
    26 lemmas float_of_inject[simp]
    27 
    28 declare [[coercion "real :: float \<Rightarrow> real"]]
    29 
    30 lemma real_of_float_eq:
    31   fixes f1 f2 :: float shows "f1 = f2 \<longleftrightarrow> real f1 = real f2"
    32   unfolding real_of_float_def real_of_float_inject ..
    33 
    34 lemma float_of_real[simp]: "float_of (real x) = x"
    35   unfolding real_of_float_def by (rule real_of_float_inverse)
    36 
    37 lemma real_float[simp]: "x \<in> float \<Longrightarrow> real (float_of x) = x"
    38   unfolding real_of_float_def by (rule float_of_inverse)
    39 
    40 subsection {* Real operations preserving the representation as floating point number *}
    41 
    42 lemma floatI: fixes m e :: int shows "m * 2 powr e = x \<Longrightarrow> x \<in> float"
    43   by (auto simp: float_def)
    44 
    45 lemma zero_float[simp]: "0 \<in> float" by (auto simp: float_def)
    46 lemma one_float[simp]: "1 \<in> float" by (intro floatI[of 1 0]) simp
    47 lemma numeral_float[simp]: "numeral i \<in> float" by (intro floatI[of "numeral i" 0]) simp
    48 lemma neg_numeral_float[simp]: "- numeral i \<in> float" by (intro floatI[of "- numeral i" 0]) simp
    49 lemma real_of_int_float[simp]: "real (x :: int) \<in> float" by (intro floatI[of x 0]) simp
    50 lemma real_of_nat_float[simp]: "real (x :: nat) \<in> float" by (intro floatI[of x 0]) simp
    51 lemma two_powr_int_float[simp]: "2 powr (real (i::int)) \<in> float" by (intro floatI[of 1 i]) simp
    52 lemma two_powr_nat_float[simp]: "2 powr (real (i::nat)) \<in> float" by (intro floatI[of 1 i]) simp
    53 lemma two_powr_minus_int_float[simp]: "2 powr - (real (i::int)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    54 lemma two_powr_minus_nat_float[simp]: "2 powr - (real (i::nat)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    55 lemma two_powr_numeral_float[simp]: "2 powr numeral i \<in> float" by (intro floatI[of 1 "numeral i"]) simp
    56 lemma two_powr_neg_numeral_float[simp]: "2 powr - numeral i \<in> float" by (intro floatI[of 1 "- numeral i"]) simp
    57 lemma two_pow_float[simp]: "2 ^ n \<in> float" by (intro floatI[of 1 "n"]) (simp add: powr_realpow)
    58 lemma real_of_float_float[simp]: "real (f::float) \<in> float" by (cases f) simp
    59 
    60 lemma plus_float[simp]: "r \<in> float \<Longrightarrow> p \<in> float \<Longrightarrow> r + p \<in> float"
    61   unfolding float_def
    62 proof (safe, simp)
    63   fix e1 m1 e2 m2 :: int
    64   { fix e1 m1 e2 m2 :: int assume "e1 \<le> e2"
    65     then have "m1 * 2 powr e1 + m2 * 2 powr e2 = (m1 + m2 * 2 ^ nat (e2 - e1)) * 2 powr e1"
    66       by (simp add: powr_realpow[symmetric] powr_divide2[symmetric] field_simps)
    67     then have "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    68       by blast }
    69   note * = this
    70   show "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    71   proof (cases e1 e2 rule: linorder_le_cases)
    72     assume "e2 \<le> e1" from *[OF this, of m2 m1] show ?thesis by (simp add: ac_simps)
    73   qed (rule *)
    74 qed
    75 
    76 lemma uminus_float[simp]: "x \<in> float \<Longrightarrow> -x \<in> float"
    77   apply (auto simp: float_def)
    78   apply (rule_tac x="-x" in exI)
    79   apply (rule_tac x="xa" in exI)
    80   apply (simp add: field_simps)
    81   done
    82 
    83 lemma times_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x * y \<in> float"
    84   apply (auto simp: float_def)
    85   apply (rule_tac x="x * xa" in exI)
    86   apply (rule_tac x="xb + xc" in exI)
    87   apply (simp add: powr_add)
    88   done
    89 
    90 lemma minus_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x - y \<in> float"
    91   using plus_float [of x "- y"] by simp
    92 
    93 lemma abs_float[simp]: "x \<in> float \<Longrightarrow> abs x \<in> float"
    94   by (cases x rule: linorder_cases[of 0]) auto
    95 
    96 lemma sgn_of_float[simp]: "x \<in> float \<Longrightarrow> sgn x \<in> float"
    97   by (cases x rule: linorder_cases[of 0]) (auto intro!: uminus_float)
    98 
    99 lemma div_power_2_float[simp]: "x \<in> float \<Longrightarrow> x / 2^d \<in> float"
   100   apply (auto simp add: float_def)
   101   apply (rule_tac x="x" in exI)
   102   apply (rule_tac x="xa - d" in exI)
   103   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   104   done
   105 
   106 lemma div_power_2_int_float[simp]: "x \<in> float \<Longrightarrow> x / (2::int)^d \<in> float"
   107   apply (auto simp add: float_def)
   108   apply (rule_tac x="x" in exI)
   109   apply (rule_tac x="xa - d" in exI)
   110   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   111   done
   112 
   113 lemma div_numeral_Bit0_float[simp]:
   114   assumes x: "x / numeral n \<in> float" shows "x / (numeral (Num.Bit0 n)) \<in> float"
   115 proof -
   116   have "(x / numeral n) / 2^1 \<in> float"
   117     by (intro x div_power_2_float)
   118   also have "(x / numeral n) / 2^1 = x / (numeral (Num.Bit0 n))"
   119     by (induct n) auto
   120   finally show ?thesis .
   121 qed
   122 
   123 lemma div_neg_numeral_Bit0_float[simp]:
   124   assumes x: "x / numeral n \<in> float" shows "x / (- numeral (Num.Bit0 n)) \<in> float"
   125 proof -
   126   have "- (x / numeral (Num.Bit0 n)) \<in> float" using x by simp
   127   also have "- (x / numeral (Num.Bit0 n)) = x / - numeral (Num.Bit0 n)"
   128     by simp
   129   finally show ?thesis .
   130 qed
   131 
   132 lift_definition Float :: "int \<Rightarrow> int \<Rightarrow> float" is "\<lambda>(m::int) (e::int). m * 2 powr e" by simp
   133 declare Float.rep_eq[simp]
   134 
   135 lemma compute_real_of_float[code]:
   136   "real_of_float (Float m e) = (if e \<ge> 0 then m * 2 ^ nat e else m / 2 ^ (nat (-e)))"
   137 by (simp add: real_of_float_def[symmetric] powr_int)
   138 
   139 code_datatype Float
   140 
   141 subsection {* Arithmetic operations on floating point numbers *}
   142 
   143 instantiation float :: "{ring_1, linorder, linordered_ring, linordered_idom, numeral, equal}"
   144 begin
   145 
   146 lift_definition zero_float :: float is 0 by simp
   147 declare zero_float.rep_eq[simp]
   148 lift_definition one_float :: float is 1 by simp
   149 declare one_float.rep_eq[simp]
   150 lift_definition plus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op +" by simp
   151 declare plus_float.rep_eq[simp]
   152 lift_definition times_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op *" by simp
   153 declare times_float.rep_eq[simp]
   154 lift_definition minus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op -" by simp
   155 declare minus_float.rep_eq[simp]
   156 lift_definition uminus_float :: "float \<Rightarrow> float" is "uminus" by simp
   157 declare uminus_float.rep_eq[simp]
   158 
   159 lift_definition abs_float :: "float \<Rightarrow> float" is abs by simp
   160 declare abs_float.rep_eq[simp]
   161 lift_definition sgn_float :: "float \<Rightarrow> float" is sgn by simp
   162 declare sgn_float.rep_eq[simp]
   163 
   164 lift_definition equal_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op = :: real \<Rightarrow> real \<Rightarrow> bool" .
   165 
   166 lift_definition less_eq_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op \<le>" .
   167 declare less_eq_float.rep_eq[simp]
   168 lift_definition less_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op <" .
   169 declare less_float.rep_eq[simp]
   170 
   171 instance
   172   proof qed (transfer, fastforce simp add: field_simps intro: mult_left_mono mult_right_mono)+
   173 end
   174 
   175 lemma real_of_float_power[simp]: fixes f::float shows "real (f^n) = real f^n"
   176   by (induct n) simp_all
   177 
   178 lemma fixes x y::float
   179   shows real_of_float_min: "real (min x y) = min (real x) (real y)"
   180     and real_of_float_max: "real (max x y) = max (real x) (real y)"
   181   by (simp_all add: min_def max_def)
   182 
   183 instance float :: unbounded_dense_linorder
   184 proof
   185   fix a b :: float
   186   show "\<exists>c. a < c"
   187     apply (intro exI[of _ "a + 1"])
   188     apply transfer
   189     apply simp
   190     done
   191   show "\<exists>c. c < a"
   192     apply (intro exI[of _ "a - 1"])
   193     apply transfer
   194     apply simp
   195     done
   196   assume "a < b"
   197   then show "\<exists>c. a < c \<and> c < b"
   198     apply (intro exI[of _ "(a + b) * Float 1 -1"])
   199     apply transfer
   200     apply (simp add: powr_minus)
   201     done
   202 qed
   203 
   204 instantiation float :: lattice_ab_group_add
   205 begin
   206 
   207 definition inf_float::"float\<Rightarrow>float\<Rightarrow>float"
   208 where "inf_float a b = min a b"
   209 
   210 definition sup_float::"float\<Rightarrow>float\<Rightarrow>float"
   211 where "sup_float a b = max a b"
   212 
   213 instance
   214   by default
   215      (transfer, simp_all add: inf_float_def sup_float_def real_of_float_min real_of_float_max)+
   216 end
   217 
   218 lemma float_numeral[simp]: "real (numeral x :: float) = numeral x"
   219   apply (induct x)
   220   apply simp
   221   apply (simp_all only: numeral_Bit0 numeral_Bit1 real_of_float_eq real_float
   222                   plus_float.rep_eq one_float.rep_eq plus_float numeral_float one_float)
   223   done
   224 
   225 lemma transfer_numeral [transfer_rule]:
   226   "fun_rel (op =) pcr_float (numeral :: _ \<Rightarrow> real) (numeral :: _ \<Rightarrow> float)"
   227   unfolding fun_rel_def float.pcr_cr_eq  cr_float_def by simp
   228 
   229 lemma float_neg_numeral[simp]: "real (- numeral x :: float) = - numeral x"
   230   by simp
   231 
   232 lemma transfer_neg_numeral [transfer_rule]:
   233   "fun_rel (op =) pcr_float (- numeral :: _ \<Rightarrow> real) (- numeral :: _ \<Rightarrow> float)"
   234   unfolding fun_rel_def float.pcr_cr_eq cr_float_def by simp
   235 
   236 lemma
   237   shows float_of_numeral[simp]: "numeral k = float_of (numeral k)"
   238     and float_of_neg_numeral[simp]: "- numeral k = float_of (- numeral k)"
   239   unfolding real_of_float_eq by simp_all
   240 
   241 subsection {* Represent floats as unique mantissa and exponent *}
   242 
   243 lemma int_induct_abs[case_names less]:
   244   fixes j :: int
   245   assumes H: "\<And>n. (\<And>i. \<bar>i\<bar> < \<bar>n\<bar> \<Longrightarrow> P i) \<Longrightarrow> P n"
   246   shows "P j"
   247 proof (induct "nat \<bar>j\<bar>" arbitrary: j rule: less_induct)
   248   case less show ?case by (rule H[OF less]) simp
   249 qed
   250 
   251 lemma int_cancel_factors:
   252   fixes n :: int assumes "1 < r" shows "n = 0 \<or> (\<exists>k i. n = k * r ^ i \<and> \<not> r dvd k)"
   253 proof (induct n rule: int_induct_abs)
   254   case (less n)
   255   { fix m assume n: "n \<noteq> 0" "n = m * r"
   256     then have "\<bar>m \<bar> < \<bar>n\<bar>"
   257       by (metis abs_dvd_iff abs_ge_self assms comm_semiring_1_class.normalizing_semiring_rules(7)
   258                 dvd_imp_le_int dvd_refl dvd_triv_right linorder_neq_iff linorder_not_le
   259                 mult_eq_0_iff zdvd_mult_cancel1)
   260     from less[OF this] n have "\<exists>k i. n = k * r ^ Suc i \<and> \<not> r dvd k" by auto }
   261   then show ?case
   262     by (metis comm_semiring_1_class.normalizing_semiring_rules(12,7) dvdE power_0)
   263 qed
   264 
   265 lemma mult_powr_eq_mult_powr_iff_asym:
   266   fixes m1 m2 e1 e2 :: int
   267   assumes m1: "\<not> 2 dvd m1" and "e1 \<le> e2"
   268   shows "m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   269 proof
   270   have "m1 \<noteq> 0" using m1 unfolding dvd_def by auto
   271   assume eq: "m1 * 2 powr e1 = m2 * 2 powr e2"
   272   with `e1 \<le> e2` have "m1 = m2 * 2 powr nat (e2 - e1)"
   273     by (simp add: powr_divide2[symmetric] field_simps)
   274   also have "\<dots> = m2 * 2^nat (e2 - e1)"
   275     by (simp add: powr_realpow)
   276   finally have m1_eq: "m1 = m2 * 2^nat (e2 - e1)"
   277     unfolding real_of_int_inject .
   278   with m1 have "m1 = m2"
   279     by (cases "nat (e2 - e1)") (auto simp add: dvd_def)
   280   then show "m1 = m2 \<and> e1 = e2"
   281     using eq `m1 \<noteq> 0` by (simp add: powr_inj)
   282 qed simp
   283 
   284 lemma mult_powr_eq_mult_powr_iff:
   285   fixes m1 m2 e1 e2 :: int
   286   shows "\<not> 2 dvd m1 \<Longrightarrow> \<not> 2 dvd m2 \<Longrightarrow> m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   287   using mult_powr_eq_mult_powr_iff_asym[of m1 e1 e2 m2]
   288   using mult_powr_eq_mult_powr_iff_asym[of m2 e2 e1 m1]
   289   by (cases e1 e2 rule: linorder_le_cases) auto
   290 
   291 lemma floatE_normed:
   292   assumes x: "x \<in> float"
   293   obtains (zero) "x = 0"
   294    | (powr) m e :: int where "x = m * 2 powr e" "\<not> 2 dvd m" "x \<noteq> 0"
   295 proof atomize_elim
   296   { assume "x \<noteq> 0"
   297     from x obtain m e :: int where x: "x = m * 2 powr e" by (auto simp: float_def)
   298     with `x \<noteq> 0` int_cancel_factors[of 2 m] obtain k i where "m = k * 2 ^ i" "\<not> 2 dvd k"
   299       by auto
   300     with `\<not> 2 dvd k` x have "\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m"
   301       by (rule_tac exI[of _ "k"], rule_tac exI[of _ "e + int i"])
   302          (simp add: powr_add powr_realpow) }
   303   then show "x = 0 \<or> (\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m \<and> x \<noteq> 0)"
   304     by blast
   305 qed
   306 
   307 lemma float_normed_cases:
   308   fixes f :: float
   309   obtains (zero) "f = 0"
   310    | (powr) m e :: int where "real f = m * 2 powr e" "\<not> 2 dvd m" "f \<noteq> 0"
   311 proof (atomize_elim, induct f)
   312   case (float_of y) then show ?case
   313     by (cases rule: floatE_normed) (auto simp: zero_float_def)
   314 qed
   315 
   316 definition mantissa :: "float \<Rightarrow> int" where
   317   "mantissa f = fst (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   318    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   319 
   320 definition exponent :: "float \<Rightarrow> int" where
   321   "exponent f = snd (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   322    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   323 
   324 lemma
   325   shows exponent_0[simp]: "exponent (float_of 0) = 0" (is ?E)
   326     and mantissa_0[simp]: "mantissa (float_of 0) = 0" (is ?M)
   327 proof -
   328   have "\<And>p::int \<times> int. fst p = 0 \<and> snd p = 0 \<longleftrightarrow> p = (0, 0)" by auto
   329   then show ?E ?M
   330     by (auto simp add: mantissa_def exponent_def zero_float_def)
   331 qed
   332 
   333 lemma
   334   shows mantissa_exponent: "real f = mantissa f * 2 powr exponent f" (is ?E)
   335     and mantissa_not_dvd: "f \<noteq> (float_of 0) \<Longrightarrow> \<not> 2 dvd mantissa f" (is "_ \<Longrightarrow> ?D")
   336 proof cases
   337   assume [simp]: "f \<noteq> (float_of 0)"
   338   have "f = mantissa f * 2 powr exponent f \<and> \<not> 2 dvd mantissa f"
   339   proof (cases f rule: float_normed_cases)
   340     case (powr m e)
   341     then have "\<exists>p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   342      \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p)"
   343       by auto
   344     then show ?thesis
   345       unfolding exponent_def mantissa_def
   346       by (rule someI2_ex) (simp add: zero_float_def)
   347   qed (simp add: zero_float_def)
   348   then show ?E ?D by auto
   349 qed simp
   350 
   351 lemma mantissa_noteq_0: "f \<noteq> float_of 0 \<Longrightarrow> mantissa f \<noteq> 0"
   352   using mantissa_not_dvd[of f] by auto
   353 
   354 lemma
   355   fixes m e :: int
   356   defines "f \<equiv> float_of (m * 2 powr e)"
   357   assumes dvd: "\<not> 2 dvd m"
   358   shows mantissa_float: "mantissa f = m" (is "?M")
   359     and exponent_float: "m \<noteq> 0 \<Longrightarrow> exponent f = e" (is "_ \<Longrightarrow> ?E")
   360 proof cases
   361   assume "m = 0" with dvd show "mantissa f = m" by auto
   362 next
   363   assume "m \<noteq> 0"
   364   then have f_not_0: "f \<noteq> float_of 0" by (simp add: f_def)
   365   from mantissa_exponent[of f]
   366   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   367     by (auto simp add: f_def)
   368   then show "?M" "?E"
   369     using mantissa_not_dvd[OF f_not_0] dvd
   370     by (auto simp: mult_powr_eq_mult_powr_iff)
   371 qed
   372 
   373 subsection {* Compute arithmetic operations *}
   374 
   375 lemma Float_mantissa_exponent: "Float (mantissa f) (exponent f) = f"
   376   unfolding real_of_float_eq mantissa_exponent[of f] by simp
   377 
   378 lemma Float_cases[case_names Float, cases type: float]:
   379   fixes f :: float
   380   obtains (Float) m e :: int where "f = Float m e"
   381   using Float_mantissa_exponent[symmetric]
   382   by (atomize_elim) auto
   383 
   384 lemma denormalize_shift:
   385   assumes f_def: "f \<equiv> Float m e" and not_0: "f \<noteq> float_of 0"
   386   obtains i where "m = mantissa f * 2 ^ i" "e = exponent f - i"
   387 proof
   388   from mantissa_exponent[of f] f_def
   389   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   390     by simp
   391   then have eq: "m = mantissa f * 2 powr (exponent f - e)"
   392     by (simp add: powr_divide2[symmetric] field_simps)
   393   moreover
   394   have "e \<le> exponent f"
   395   proof (rule ccontr)
   396     assume "\<not> e \<le> exponent f"
   397     then have pos: "exponent f < e" by simp
   398     then have "2 powr (exponent f - e) = 2 powr - real (e - exponent f)"
   399       by simp
   400     also have "\<dots> = 1 / 2^nat (e - exponent f)"
   401       using pos by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
   402     finally have "m * 2^nat (e - exponent f) = real (mantissa f)"
   403       using eq by simp
   404     then have "mantissa f = m * 2^nat (e - exponent f)"
   405       unfolding real_of_int_inject by simp
   406     with `exponent f < e` have "2 dvd mantissa f"
   407       apply (intro dvdI[where k="m * 2^(nat (e-exponent f)) div 2"])
   408       apply (cases "nat (e - exponent f)")
   409       apply auto
   410       done
   411     then show False using mantissa_not_dvd[OF not_0] by simp
   412   qed
   413   ultimately have "real m = mantissa f * 2^nat (exponent f - e)"
   414     by (simp add: powr_realpow[symmetric])
   415   with `e \<le> exponent f`
   416   show "m = mantissa f * 2 ^ nat (exponent f - e)" "e = exponent f - nat (exponent f - e)"
   417     unfolding real_of_int_inject by auto
   418 qed
   419 
   420 lemma compute_float_zero[code_unfold, code]: "0 = Float 0 0"
   421   by transfer simp
   422 hide_fact (open) compute_float_zero
   423 
   424 lemma compute_float_one[code_unfold, code]: "1 = Float 1 0"
   425   by transfer simp
   426 hide_fact (open) compute_float_one
   427 
   428 definition normfloat :: "float \<Rightarrow> float" where
   429   [simp]: "normfloat x = x"
   430 
   431 lemma compute_normfloat[code]: "normfloat (Float m e) =
   432   (if m mod 2 = 0 \<and> m \<noteq> 0 then normfloat (Float (m div 2) (e + 1))
   433                            else if m = 0 then 0 else Float m e)"
   434   unfolding normfloat_def
   435   by transfer (auto simp add: powr_add zmod_eq_0_iff)
   436 hide_fact (open) compute_normfloat
   437 
   438 lemma compute_float_numeral[code_abbrev]: "Float (numeral k) 0 = numeral k"
   439   by transfer simp
   440 hide_fact (open) compute_float_numeral
   441 
   442 lemma compute_float_neg_numeral[code_abbrev]: "Float (- numeral k) 0 = - numeral k"
   443   by transfer simp
   444 hide_fact (open) compute_float_neg_numeral
   445 
   446 lemma compute_float_uminus[code]: "- Float m1 e1 = Float (- m1) e1"
   447   by transfer simp
   448 hide_fact (open) compute_float_uminus
   449 
   450 lemma compute_float_times[code]: "Float m1 e1 * Float m2 e2 = Float (m1 * m2) (e1 + e2)"
   451   by transfer (simp add: field_simps powr_add)
   452 hide_fact (open) compute_float_times
   453 
   454 lemma compute_float_plus[code]: "Float m1 e1 + Float m2 e2 =
   455   (if m1 = 0 then Float m2 e2 else if m2 = 0 then Float m1 e1 else
   456   if e1 \<le> e2 then Float (m1 + m2 * 2^nat (e2 - e1)) e1
   457               else Float (m2 + m1 * 2^nat (e1 - e2)) e2)"
   458   by transfer (simp add: field_simps powr_realpow[symmetric] powr_divide2[symmetric])
   459 hide_fact (open) compute_float_plus
   460 
   461 lemma compute_float_minus[code]: fixes f g::float shows "f - g = f + (-g)"
   462   by simp
   463 hide_fact (open) compute_float_minus
   464 
   465 lemma compute_float_sgn[code]: "sgn (Float m1 e1) = (if 0 < m1 then 1 else if m1 < 0 then -1 else 0)"
   466   by transfer (simp add: sgn_times)
   467 hide_fact (open) compute_float_sgn
   468 
   469 lift_definition is_float_pos :: "float \<Rightarrow> bool" is "op < 0 :: real \<Rightarrow> bool" .
   470 
   471 lemma compute_is_float_pos[code]: "is_float_pos (Float m e) \<longleftrightarrow> 0 < m"
   472   by transfer (auto simp add: zero_less_mult_iff not_le[symmetric, of _ 0])
   473 hide_fact (open) compute_is_float_pos
   474 
   475 lemma compute_float_less[code]: "a < b \<longleftrightarrow> is_float_pos (b - a)"
   476   by transfer (simp add: field_simps)
   477 hide_fact (open) compute_float_less
   478 
   479 lift_definition is_float_nonneg :: "float \<Rightarrow> bool" is "op \<le> 0 :: real \<Rightarrow> bool" .
   480 
   481 lemma compute_is_float_nonneg[code]: "is_float_nonneg (Float m e) \<longleftrightarrow> 0 \<le> m"
   482   by transfer (auto simp add: zero_le_mult_iff not_less[symmetric, of _ 0])
   483 hide_fact (open) compute_is_float_nonneg
   484 
   485 lemma compute_float_le[code]: "a \<le> b \<longleftrightarrow> is_float_nonneg (b - a)"
   486   by transfer (simp add: field_simps)
   487 hide_fact (open) compute_float_le
   488 
   489 lift_definition is_float_zero :: "float \<Rightarrow> bool"  is "op = 0 :: real \<Rightarrow> bool" .
   490 
   491 lemma compute_is_float_zero[code]: "is_float_zero (Float m e) \<longleftrightarrow> 0 = m"
   492   by transfer (auto simp add: is_float_zero_def)
   493 hide_fact (open) compute_is_float_zero
   494 
   495 lemma compute_float_abs[code]: "abs (Float m e) = Float (abs m) e"
   496   by transfer (simp add: abs_mult)
   497 hide_fact (open) compute_float_abs
   498 
   499 lemma compute_float_eq[code]: "equal_class.equal f g = is_float_zero (f - g)"
   500   by transfer simp
   501 hide_fact (open) compute_float_eq
   502 
   503 subsection {* Rounding Real numbers *}
   504 
   505 definition round_down :: "int \<Rightarrow> real \<Rightarrow> real" where
   506   "round_down prec x = floor (x * 2 powr prec) * 2 powr -prec"
   507 
   508 definition round_up :: "int \<Rightarrow> real \<Rightarrow> real" where
   509   "round_up prec x = ceiling (x * 2 powr prec) * 2 powr -prec"
   510 
   511 lemma round_down_float[simp]: "round_down prec x \<in> float"
   512   unfolding round_down_def
   513   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   514 
   515 lemma round_up_float[simp]: "round_up prec x \<in> float"
   516   unfolding round_up_def
   517   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   518 
   519 lemma round_up: "x \<le> round_up prec x"
   520   by (simp add: powr_minus_divide le_divide_eq round_up_def)
   521 
   522 lemma round_down: "round_down prec x \<le> x"
   523   by (simp add: powr_minus_divide divide_le_eq round_down_def)
   524 
   525 lemma round_up_0[simp]: "round_up p 0 = 0"
   526   unfolding round_up_def by simp
   527 
   528 lemma round_down_0[simp]: "round_down p 0 = 0"
   529   unfolding round_down_def by simp
   530 
   531 lemma round_up_diff_round_down:
   532   "round_up prec x - round_down prec x \<le> 2 powr -prec"
   533 proof -
   534   have "round_up prec x - round_down prec x =
   535     (ceiling (x * 2 powr prec) - floor (x * 2 powr prec)) * 2 powr -prec"
   536     by (simp add: round_up_def round_down_def field_simps)
   537   also have "\<dots> \<le> 1 * 2 powr -prec"
   538     by (rule mult_mono)
   539        (auto simp del: real_of_int_diff
   540              simp: real_of_int_diff[symmetric] real_of_int_le_one_cancel_iff ceiling_diff_floor_le_1)
   541   finally show ?thesis by simp
   542 qed
   543 
   544 lemma round_down_shift: "round_down p (x * 2 powr k) = 2 powr k * round_down (p + k) x"
   545   unfolding round_down_def
   546   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   547     (simp add: powr_add[symmetric])
   548 
   549 lemma round_up_shift: "round_up p (x * 2 powr k) = 2 powr k * round_up (p + k) x"
   550   unfolding round_up_def
   551   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   552     (simp add: powr_add[symmetric])
   553 
   554 subsection {* Rounding Floats *}
   555 
   556 lift_definition float_up :: "int \<Rightarrow> float \<Rightarrow> float" is round_up by simp
   557 declare float_up.rep_eq[simp]
   558 
   559 lemma round_up_correct:
   560   shows "round_up e f - f \<in> {0..2 powr -e}"
   561 unfolding atLeastAtMost_iff
   562 proof
   563   have "round_up e f - f \<le> round_up e f - round_down e f" using round_down by simp
   564   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   565   finally show "round_up e f - f \<le> 2 powr real (- e)"
   566     by simp
   567 qed (simp add: algebra_simps round_up)
   568 
   569 lemma float_up_correct:
   570   shows "real (float_up e f) - real f \<in> {0..2 powr -e}"
   571   by transfer (rule round_up_correct)
   572 
   573 lift_definition float_down :: "int \<Rightarrow> float \<Rightarrow> float" is round_down by simp
   574 declare float_down.rep_eq[simp]
   575 
   576 lemma round_down_correct:
   577   shows "f - (round_down e f) \<in> {0..2 powr -e}"
   578 unfolding atLeastAtMost_iff
   579 proof
   580   have "f - round_down e f \<le> round_up e f - round_down e f" using round_up by simp
   581   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   582   finally show "f - round_down e f \<le> 2 powr real (- e)"
   583     by simp
   584 qed (simp add: algebra_simps round_down)
   585 
   586 lemma float_down_correct:
   587   shows "real f - real (float_down e f) \<in> {0..2 powr -e}"
   588   by transfer (rule round_down_correct)
   589 
   590 lemma compute_float_down[code]:
   591   "float_down p (Float m e) =
   592     (if p + e < 0 then Float (m div 2^nat (-(p + e))) (-p) else Float m e)"
   593 proof cases
   594   assume "p + e < 0"
   595   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   596     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   597   also have "... = 1 / 2 powr p / 2 powr e"
   598     unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   599   finally show ?thesis
   600     using `p + e < 0`
   601     by transfer (simp add: ac_simps round_down_def floor_divide_eq_div[symmetric])
   602 next
   603   assume "\<not> p + e < 0"
   604   then have r: "real e + real p = real (nat (e + p))" by simp
   605   have r: "\<lfloor>(m * 2 powr e) * 2 powr real p\<rfloor> = (m * 2 powr e) * 2 powr real p"
   606     by (auto intro: exI[where x="m*2^nat (e+p)"]
   607              simp add: ac_simps powr_add[symmetric] r powr_realpow)
   608   with `\<not> p + e < 0` show ?thesis
   609     by transfer
   610        (auto simp add: round_down_def field_simps powr_add powr_minus inverse_eq_divide)
   611 qed
   612 hide_fact (open) compute_float_down
   613 
   614 lemma abs_round_down_le: "\<bar>f - (round_down e f)\<bar> \<le> 2 powr -e"
   615   using round_down_correct[of f e] by simp
   616 
   617 lemma abs_round_up_le: "\<bar>f - (round_up e f)\<bar> \<le> 2 powr -e"
   618   using round_up_correct[of e f] by simp
   619 
   620 lemma round_down_nonneg: "0 \<le> s \<Longrightarrow> 0 \<le> round_down p s"
   621   by (auto simp: round_down_def intro!: mult_nonneg_nonneg)
   622 
   623 lemma ceil_divide_floor_conv:
   624 assumes "b \<noteq> 0"
   625 shows "\<lceil>real a / real b\<rceil> = (if b dvd a then a div b else \<lfloor>real a / real b\<rfloor> + 1)"
   626 proof cases
   627   assume "\<not> b dvd a"
   628   hence "a mod b \<noteq> 0" by auto
   629   hence ne: "real (a mod b) / real b \<noteq> 0" using `b \<noteq> 0` by auto
   630   have "\<lceil>real a / real b\<rceil> = \<lfloor>real a / real b\<rfloor> + 1"
   631   apply (rule ceiling_eq) apply (auto simp: floor_divide_eq_div[symmetric])
   632   proof -
   633     have "real \<lfloor>real a / real b\<rfloor> \<le> real a / real b" by simp
   634     moreover have "real \<lfloor>real a / real b\<rfloor> \<noteq> real a / real b"
   635     apply (subst (2) real_of_int_div_aux) unfolding floor_divide_eq_div using ne `b \<noteq> 0` by auto
   636     ultimately show "real \<lfloor>real a / real b\<rfloor> < real a / real b" by arith
   637   qed
   638   thus ?thesis using `\<not> b dvd a` by simp
   639 qed (simp add: ceiling_def real_of_int_minus[symmetric] divide_minus_left[symmetric]
   640   floor_divide_eq_div dvd_neg_div del: divide_minus_left real_of_int_minus)
   641 
   642 lemma compute_float_up[code]:
   643   "float_up p (Float m e) =
   644     (let P = 2^nat (-(p + e)); r = m mod P in
   645       if p + e < 0 then Float (m div P + (if r = 0 then 0 else 1)) (-p) else Float m e)"
   646 proof cases
   647   assume "p + e < 0"
   648   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   649     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   650   also have "... = 1 / 2 powr p / 2 powr e"
   651   unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   652   finally have twopow_rewrite:
   653     "real ((2::int) ^ nat (- (p + e))) = 1 / 2 powr real p / 2 powr real e" .
   654   with `p + e < 0` have powr_rewrite:
   655     "2 powr real e * 2 powr real p = 1 / real ((2::int) ^ nat (- (p + e)))"
   656     unfolding powr_divide2 by simp
   657   show ?thesis
   658   proof cases
   659     assume "2^nat (-(p + e)) dvd m"
   660     with `p + e < 0` twopow_rewrite show ?thesis
   661       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div dvd_eq_mod_eq_0)
   662   next
   663     assume ndvd: "\<not> 2 ^ nat (- (p + e)) dvd m"
   664     have one_div: "real m * (1 / real ((2::int) ^ nat (- (p + e)))) =
   665       real m / real ((2::int) ^ nat (- (p + e)))"
   666       by (simp add: field_simps)
   667     have "real \<lceil>real m * (2 powr real e * 2 powr real p)\<rceil> =
   668       real \<lfloor>real m * (2 powr real e * 2 powr real p)\<rfloor> + 1"
   669       using ndvd unfolding powr_rewrite one_div
   670       by (subst ceil_divide_floor_conv) (auto simp: field_simps)
   671     thus ?thesis using `p + e < 0` twopow_rewrite
   672       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div[symmetric])
   673   qed
   674 next
   675   assume "\<not> p + e < 0"
   676   then have r1: "real e + real p = real (nat (e + p))" by simp
   677   have r: "\<lceil>(m * 2 powr e) * 2 powr real p\<rceil> = (m * 2 powr e) * 2 powr real p"
   678     by (auto simp add: ac_simps powr_add[symmetric] r1 powr_realpow
   679       intro: exI[where x="m*2^nat (e+p)"])
   680   then show ?thesis using `\<not> p + e < 0`
   681     by transfer
   682        (simp add: round_up_def floor_divide_eq_div field_simps powr_add powr_minus inverse_eq_divide)
   683 qed
   684 hide_fact (open) compute_float_up
   685 
   686 lemmas real_of_ints =
   687   real_of_int_zero
   688   real_of_one
   689   real_of_int_add
   690   real_of_int_minus
   691   real_of_int_diff
   692   real_of_int_mult
   693   real_of_int_power
   694   real_numeral
   695 lemmas real_of_nats =
   696   real_of_nat_zero
   697   real_of_nat_one
   698   real_of_nat_1
   699   real_of_nat_add
   700   real_of_nat_mult
   701   real_of_nat_power
   702 
   703 lemmas int_of_reals = real_of_ints[symmetric]
   704 lemmas nat_of_reals = real_of_nats[symmetric]
   705 
   706 lemma two_real_int: "(2::real) = real (2::int)" by simp
   707 lemma two_real_nat: "(2::real) = real (2::nat)" by simp
   708 
   709 lemma mult_cong: "a = c ==> b = d ==> a*b = c*d" by simp
   710 
   711 subsection {* Compute bitlen of integers *}
   712 
   713 definition bitlen :: "int \<Rightarrow> int" where
   714   "bitlen a = (if a > 0 then \<lfloor>log 2 a\<rfloor> + 1 else 0)"
   715 
   716 lemma bitlen_nonneg: "0 \<le> bitlen x"
   717 proof -
   718   {
   719     assume "0 > x"
   720     have "-1 = log 2 (inverse 2)" by (subst log_inverse) simp_all
   721     also have "... < log 2 (-x)" using `0 > x` by auto
   722     finally have "-1 < log 2 (-x)" .
   723   } thus "0 \<le> bitlen x" unfolding bitlen_def by (auto intro!: add_nonneg_nonneg)
   724 qed
   725 
   726 lemma bitlen_bounds:
   727   assumes "x > 0"
   728   shows "2 ^ nat (bitlen x - 1) \<le> x \<and> x < 2 ^ nat (bitlen x)"
   729 proof
   730   have "(2::real) ^ nat \<lfloor>log 2 (real x)\<rfloor> = 2 powr real (floor (log 2 (real x)))"
   731     using powr_realpow[symmetric, of 2 "nat \<lfloor>log 2 (real x)\<rfloor>"] `x > 0`
   732     using real_nat_eq_real[of "floor (log 2 (real x))"]
   733     by simp
   734   also have "... \<le> 2 powr log 2 (real x)"
   735     by simp
   736   also have "... = real x"
   737     using `0 < x` by simp
   738   finally have "2 ^ nat \<lfloor>log 2 (real x)\<rfloor> \<le> real x" by simp
   739   thus "2 ^ nat (bitlen x - 1) \<le> x" using `x > 0`
   740     by (simp add: bitlen_def)
   741 next
   742   have "x \<le> 2 powr (log 2 x)" using `x > 0` by simp
   743   also have "... < 2 ^ nat (\<lfloor>log 2 (real x)\<rfloor> + 1)"
   744     apply (simp add: powr_realpow[symmetric])
   745     using `x > 0` by simp
   746   finally show "x < 2 ^ nat (bitlen x)" using `x > 0`
   747     by (simp add: bitlen_def ac_simps int_of_reals del: real_of_ints)
   748 qed
   749 
   750 lemma bitlen_pow2[simp]:
   751   assumes "b > 0"
   752   shows "bitlen (b * 2 ^ c) = bitlen b + c"
   753 proof -
   754   from assms have "b * 2 ^ c > 0" by (auto intro: mult_pos_pos)
   755   thus ?thesis
   756     using floor_add[of "log 2 b" c] assms
   757     by (auto simp add: log_mult log_nat_power bitlen_def)
   758 qed
   759 
   760 lemma bitlen_Float:
   761   fixes m e
   762   defines "f \<equiv> Float m e"
   763   shows "bitlen (\<bar>mantissa f\<bar>) + exponent f = (if m = 0 then 0 else bitlen \<bar>m\<bar> + e)"
   764 proof (cases "m = 0")
   765   case True
   766   then show ?thesis by (simp add: f_def bitlen_def Float_def)
   767 next
   768   case False
   769   hence "f \<noteq> float_of 0"
   770     unfolding real_of_float_eq by (simp add: f_def)
   771   hence "mantissa f \<noteq> 0"
   772     by (simp add: mantissa_noteq_0)
   773   moreover
   774   obtain i where "m = mantissa f * 2 ^ i" "e = exponent f - int i"
   775     by (rule f_def[THEN denormalize_shift, OF `f \<noteq> float_of 0`])
   776   ultimately show ?thesis by (simp add: abs_mult)
   777 qed
   778 
   779 lemma compute_bitlen[code]:
   780   shows "bitlen x = (if x > 0 then bitlen (x div 2) + 1 else 0)"
   781 proof -
   782   { assume "2 \<le> x"
   783     then have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 (x - x mod 2)\<rfloor>"
   784       by (simp add: log_mult zmod_zdiv_equality')
   785     also have "\<dots> = \<lfloor>log 2 (real x)\<rfloor>"
   786     proof cases
   787       assume "x mod 2 = 0" then show ?thesis by simp
   788     next
   789       def n \<equiv> "\<lfloor>log 2 (real x)\<rfloor>"
   790       then have "0 \<le> n"
   791         using `2 \<le> x` by simp
   792       assume "x mod 2 \<noteq> 0"
   793       with `2 \<le> x` have "x mod 2 = 1" "\<not> 2 dvd x" by (auto simp add: dvd_eq_mod_eq_0)
   794       with `2 \<le> x` have "x \<noteq> 2^nat n" by (cases "nat n") auto
   795       moreover
   796       { have "real (2^nat n :: int) = 2 powr (nat n)"
   797           by (simp add: powr_realpow)
   798         also have "\<dots> \<le> 2 powr (log 2 x)"
   799           using `2 \<le> x` by (simp add: n_def del: powr_log_cancel)
   800         finally have "2^nat n \<le> x" using `2 \<le> x` by simp }
   801       ultimately have "2^nat n \<le> x - 1" by simp
   802       then have "2^nat n \<le> real (x - 1)"
   803         unfolding real_of_int_le_iff[symmetric] by simp
   804       { have "n = \<lfloor>log 2 (2^nat n)\<rfloor>"
   805           using `0 \<le> n` by (simp add: log_nat_power)
   806         also have "\<dots> \<le> \<lfloor>log 2 (x - 1)\<rfloor>"
   807           using `2^nat n \<le> real (x - 1)` `0 \<le> n` `2 \<le> x` by (auto intro: floor_mono)
   808         finally have "n \<le> \<lfloor>log 2 (x - 1)\<rfloor>" . }
   809       moreover have "\<lfloor>log 2 (x - 1)\<rfloor> \<le> n"
   810         using `2 \<le> x` by (auto simp add: n_def intro!: floor_mono)
   811       ultimately show "\<lfloor>log 2 (x - x mod 2)\<rfloor> = \<lfloor>log 2 x\<rfloor>"
   812         unfolding n_def `x mod 2 = 1` by auto
   813     qed
   814     finally have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 x\<rfloor>" . }
   815   moreover
   816   { assume "x < 2" "0 < x"
   817     then have "x = 1" by simp
   818     then have "\<lfloor>log 2 (real x)\<rfloor> = 0" by simp }
   819   ultimately show ?thesis
   820     unfolding bitlen_def
   821     by (auto simp: pos_imp_zdiv_pos_iff not_le)
   822 qed
   823 hide_fact (open) compute_bitlen
   824 
   825 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   826   shows "0 \<le> e + (bitlen m - 1)"
   827 proof -
   828   have "0 < Float m e" using assms by auto
   829   hence "0 < m" using powr_gt_zero[of 2 e]
   830     by (auto simp: zero_less_mult_iff)
   831   hence "m \<noteq> 0" by auto
   832   show ?thesis
   833   proof (cases "0 \<le> e")
   834     case True thus ?thesis using `0 < m`  by (simp add: bitlen_def)
   835   next
   836     have "(1::int) < 2" by simp
   837     case False let ?S = "2^(nat (-e))"
   838     have "inverse (2 ^ nat (- e)) = 2 powr e" using assms False powr_realpow[of 2 "nat (-e)"]
   839       by (auto simp: powr_minus field_simps inverse_eq_divide)
   840     hence "1 \<le> real m * inverse ?S" using assms False powr_realpow[of 2 "nat (-e)"]
   841       by (auto simp: powr_minus)
   842     hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   843     hence "?S \<le> real m" unfolding mult_assoc by auto
   844     hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   845     from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   846     have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric] by (rule order_le_less_trans)
   847     hence "-e < bitlen m" using False by auto
   848     thus ?thesis by auto
   849   qed
   850 qed
   851 
   852 lemma bitlen_div: assumes "0 < m" shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   853 proof -
   854   let ?B = "2^nat(bitlen m - 1)"
   855 
   856   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   857   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   858   thus "1 \<le> real m / ?B" by auto
   859 
   860   have "m \<noteq> 0" using assms by auto
   861   have "0 \<le> bitlen m - 1" using `0 < m` by (auto simp: bitlen_def)
   862 
   863   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   864   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using `0 < m` by (auto simp: bitlen_def)
   865   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   866   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   867   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   868   thus "real m / ?B < 2" by auto
   869 qed
   870 
   871 subsection {* Approximation of positive rationals *}
   872 
   873 lemma zdiv_zmult_twopow_eq: fixes a b::int shows "a div b div (2 ^ n) = a div (b * 2 ^ n)"
   874 by (simp add: zdiv_zmult2_eq)
   875 
   876 lemma div_mult_twopow_eq: fixes a b::nat shows "a div ((2::nat) ^ n) div b = a div (b * 2 ^ n)"
   877   by (cases "b=0") (simp_all add: div_mult2_eq[symmetric] ac_simps)
   878 
   879 lemma real_div_nat_eq_floor_of_divide:
   880   fixes a b::nat
   881   shows "a div b = real (floor (a/b))"
   882 by (metis floor_divide_eq_div real_of_int_of_nat_eq zdiv_int)
   883 
   884 definition "rat_precision prec x y = int prec - (bitlen x - bitlen y)"
   885 
   886 lift_definition lapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   887   is "\<lambda>prec (x::nat) (y::nat). round_down (rat_precision prec x y) (x / y)" by simp
   888 
   889 lemma compute_lapprox_posrat[code]:
   890   fixes prec x y
   891   shows "lapprox_posrat prec x y =
   892    (let
   893        l = rat_precision prec x y;
   894        d = if 0 \<le> l then x * 2^nat l div y else x div 2^nat (- l) div y
   895     in normfloat (Float d (- l)))"
   896     unfolding div_mult_twopow_eq normfloat_def
   897     by transfer
   898        (simp add: round_down_def powr_int real_div_nat_eq_floor_of_divide field_simps Let_def
   899              del: two_powr_minus_int_float)
   900 hide_fact (open) compute_lapprox_posrat
   901 
   902 lift_definition rapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   903   is "\<lambda>prec (x::nat) (y::nat). round_up (rat_precision prec x y) (x / y)" by simp
   904 
   905 (* TODO: optimize using zmod_zmult2_eq, pdivmod ? *)
   906 lemma compute_rapprox_posrat[code]:
   907   fixes prec x y
   908   defines "l \<equiv> rat_precision prec x y"
   909   shows "rapprox_posrat prec x y = (let
   910      l = l ;
   911      X = if 0 \<le> l then (x * 2^nat l, y) else (x, y * 2^nat(-l)) ;
   912      d = fst X div snd X ;
   913      m = fst X mod snd X
   914    in normfloat (Float (d + (if m = 0 \<or> y = 0 then 0 else 1)) (- l)))"
   915 proof (cases "y = 0")
   916   assume "y = 0" thus ?thesis unfolding normfloat_def by transfer simp
   917 next
   918   assume "y \<noteq> 0"
   919   show ?thesis
   920   proof (cases "0 \<le> l")
   921     assume "0 \<le> l"
   922     def x' == "x * 2 ^ nat l"
   923     have "int x * 2 ^ nat l = x'" by (simp add: x'_def int_mult int_power)
   924     moreover have "real x * 2 powr real l = real x'"
   925       by (simp add: powr_realpow[symmetric] `0 \<le> l` x'_def)
   926     ultimately show ?thesis
   927       unfolding normfloat_def
   928       using ceil_divide_floor_conv[of y x'] powr_realpow[of 2 "nat l"] `0 \<le> l` `y \<noteq> 0`
   929         l_def[symmetric, THEN meta_eq_to_obj_eq]
   930       by transfer
   931          (simp add: floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0 round_up_def)
   932    next
   933     assume "\<not> 0 \<le> l"
   934     def y' == "y * 2 ^ nat (- l)"
   935     from `y \<noteq> 0` have "y' \<noteq> 0" by (simp add: y'_def)
   936     have "int y * 2 ^ nat (- l) = y'" by (simp add: y'_def int_mult int_power)
   937     moreover have "real x * real (2::int) powr real l / real y = x / real y'"
   938       using `\<not> 0 \<le> l`
   939       by (simp add: powr_realpow[symmetric] powr_minus y'_def field_simps inverse_eq_divide)
   940     ultimately show ?thesis
   941       unfolding normfloat_def
   942       using ceil_divide_floor_conv[of y' x] `\<not> 0 \<le> l` `y' \<noteq> 0` `y \<noteq> 0`
   943         l_def[symmetric, THEN meta_eq_to_obj_eq]
   944       by transfer
   945          (simp add: round_up_def ceil_divide_floor_conv floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0)
   946   qed
   947 qed
   948 hide_fact (open) compute_rapprox_posrat
   949 
   950 lemma rat_precision_pos:
   951   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   952   shows "rat_precision n (int x) (int y) > 0"
   953 proof -
   954   { assume "0 < x" hence "log 2 x + 1 = log 2 (2 * x)" by (simp add: log_mult) }
   955   hence "bitlen (int x) < bitlen (int y)" using assms
   956     by (simp add: bitlen_def del: floor_add_one)
   957       (auto intro!: floor_mono simp add: floor_add_one[symmetric] simp del: floor_add floor_add_one)
   958   thus ?thesis
   959     using assms by (auto intro!: pos_add_strict simp add: field_simps rat_precision_def)
   960 qed
   961 
   962 lemma power_aux: assumes "x > 0" shows "(2::int) ^ nat (x - 1) \<le> 2 ^ nat x - 1"
   963 proof -
   964   def y \<equiv> "nat (x - 1)" moreover
   965   have "(2::int) ^ y \<le> (2 ^ (y + 1)) - 1" by simp
   966   ultimately show ?thesis using assms by simp
   967 qed
   968 
   969 lemma rapprox_posrat_less1:
   970   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   971   shows "real (rapprox_posrat n x y) < 1"
   972 proof -
   973   have powr1: "2 powr real (rat_precision n (int x) (int y)) =
   974     2 ^ nat (rat_precision n (int x) (int y))" using rat_precision_pos[of x y n] assms
   975     by (simp add: powr_realpow[symmetric])
   976   have "x * 2 powr real (rat_precision n (int x) (int y)) / y = (x / y) *
   977      2 powr real (rat_precision n (int x) (int y))" by simp
   978   also have "... < (1 / 2) * 2 powr real (rat_precision n (int x) (int y))"
   979     apply (rule mult_strict_right_mono) by (insert assms) auto
   980   also have "\<dots> = 2 powr real (rat_precision n (int x) (int y) - 1)"
   981     using powr_add [of 2 _ "- 1", simplified add_uminus_conv_diff] by (simp add: powr_minus)
   982   also have "\<dots> = 2 ^ nat (rat_precision n (int x) (int y) - 1)"
   983     using rat_precision_pos[of x y n] assms by (simp add: powr_realpow[symmetric])
   984   also have "\<dots> \<le> 2 ^ nat (rat_precision n (int x) (int y)) - 1"
   985     unfolding int_of_reals real_of_int_le_iff
   986     using rat_precision_pos[OF assms] by (rule power_aux)
   987   finally show ?thesis
   988     apply (transfer fixing: n x y)
   989     apply (simp add: round_up_def field_simps powr_minus inverse_eq_divide powr1)
   990     unfolding int_of_reals real_of_int_less_iff
   991     apply (simp add: ceiling_less_eq)
   992     done
   993 qed
   994 
   995 lift_definition lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   996   "\<lambda>prec (x::int) (y::int). round_down (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   997 
   998 lemma compute_lapprox_rat[code]:
   999   "lapprox_rat prec x y =
  1000     (if y = 0 then 0
  1001     else if 0 \<le> x then
  1002       (if 0 < y then lapprox_posrat prec (nat x) (nat y)
  1003       else - (rapprox_posrat prec (nat x) (nat (-y))))
  1004       else (if 0 < y
  1005         then - (rapprox_posrat prec (nat (-x)) (nat y))
  1006         else lapprox_posrat prec (nat (-x)) (nat (-y))))"
  1007   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
  1008 hide_fact (open) compute_lapprox_rat
  1009 
  1010 lift_definition rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
  1011   "\<lambda>prec (x::int) (y::int). round_up (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
  1012 
  1013 lemma compute_rapprox_rat[code]:
  1014   "rapprox_rat prec x y =
  1015     (if y = 0 then 0
  1016     else if 0 \<le> x then
  1017       (if 0 < y then rapprox_posrat prec (nat x) (nat y)
  1018       else - (lapprox_posrat prec (nat x) (nat (-y))))
  1019       else (if 0 < y
  1020         then - (lapprox_posrat prec (nat (-x)) (nat y))
  1021         else rapprox_posrat prec (nat (-x)) (nat (-y))))"
  1022   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
  1023 hide_fact (open) compute_rapprox_rat
  1024 
  1025 subsection {* Division *}
  1026 
  1027 definition "real_divl prec a b = round_down (int prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)"
  1028 
  1029 definition "real_divr prec a b = round_up (int prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)"
  1030 
  1031 lift_definition float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is real_divl
  1032   by (simp add: real_divl_def)
  1033 
  1034 lemma compute_float_divl[code]:
  1035   "float_divl prec (Float m1 s1) (Float m2 s2) = lapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1036 proof cases
  1037   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1038   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1039   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1040   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1041     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1042   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1043     by (simp add: field_simps powr_divide2[symmetric])
  1044 
  1045   show ?thesis
  1046     using not_0
  1047     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_down_shift real_divl_def,
  1048       simp add: field_simps)
  1049 qed (transfer, auto simp: real_divl_def)
  1050 hide_fact (open) compute_float_divl
  1051 
  1052 lift_definition float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is real_divr
  1053   by (simp add: real_divr_def)
  1054 
  1055 lemma compute_float_divr[code]:
  1056   "float_divr prec (Float m1 s1) (Float m2 s2) = rapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1057 proof cases
  1058   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1059   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1060   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1061   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1062     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1063   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1064     by (simp add: field_simps powr_divide2[symmetric])
  1065 
  1066   show ?thesis
  1067     using not_0
  1068     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_up_shift real_divr_def,
  1069       simp add: field_simps)
  1070 qed (transfer, auto simp: real_divr_def)
  1071 hide_fact (open) compute_float_divr
  1072 
  1073 subsection {* Lemmas needed by Approximate *}
  1074 
  1075 lemma Float_num[simp]: shows
  1076    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
  1077    "real (Float 1 -1) = 1/2" and "real (Float 1 -2) = 1/4" and "real (Float 1 -3) = 1/8" and
  1078    "real (Float -1 0) = -1" and "real (Float (number_of n) 0) = number_of n"
  1079 using two_powr_int_float[of 2] two_powr_int_float[of "-1"] two_powr_int_float[of "-2"] two_powr_int_float[of "-3"]
  1080 using powr_realpow[of 2 2] powr_realpow[of 2 3]
  1081 using powr_minus[of 2 1] powr_minus[of 2 2] powr_minus[of 2 3]
  1082 by auto
  1083 
  1084 lemma real_of_Float_int[simp]: "real (Float n 0) = real n" by simp
  1085 
  1086 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
  1087 
  1088 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
  1089 by arith
  1090 
  1091 lemma lapprox_rat:
  1092   shows "real (lapprox_rat prec x y) \<le> real x / real y"
  1093   using round_down by (simp add: lapprox_rat_def)
  1094 
  1095 lemma mult_div_le: fixes a b:: int assumes "b > 0" shows "a \<ge> b * (a div b)"
  1096 proof -
  1097   from zmod_zdiv_equality'[of a b]
  1098   have "a = b * (a div b) + a mod b" by simp
  1099   also have "... \<ge> b * (a div b) + 0" apply (rule add_left_mono) apply (rule pos_mod_sign)
  1100   using assms by simp
  1101   finally show ?thesis by simp
  1102 qed
  1103 
  1104 lemma lapprox_rat_nonneg:
  1105   fixes n x y
  1106   defines "p == int n - ((bitlen \<bar>x\<bar>) - (bitlen \<bar>y\<bar>))"
  1107   assumes "0 \<le> x" "0 < y"
  1108   shows "0 \<le> real (lapprox_rat n x y)"
  1109 using assms unfolding lapprox_rat_def p_def[symmetric] round_down_def real_of_int_minus[symmetric]
  1110    powr_int[of 2, simplified]
  1111   by (auto simp add: inverse_eq_divide intro!: mult_nonneg_nonneg divide_nonneg_pos mult_pos_pos)
  1112 
  1113 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1114   using round_up by (simp add: rapprox_rat_def)
  1115 
  1116 lemma rapprox_rat_le1:
  1117   fixes n x y
  1118   assumes xy: "0 \<le> x" "0 < y" "x \<le> y"
  1119   shows "real (rapprox_rat n x y) \<le> 1"
  1120 proof -
  1121   have "bitlen \<bar>x\<bar> \<le> bitlen \<bar>y\<bar>"
  1122     using xy unfolding bitlen_def by (auto intro!: floor_mono)
  1123   then have "0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>" by (simp add: rat_precision_def)
  1124   have "real \<lceil>real x / real y * 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>
  1125       \<le> real \<lceil>2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>"
  1126     using xy by (auto intro!: ceiling_mono simp: field_simps)
  1127   also have "\<dots> = 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"
  1128     using `0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>`
  1129     by (auto intro!: exI[of _ "2^nat (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"] simp: powr_int)
  1130   finally show ?thesis
  1131     by (simp add: rapprox_rat_def round_up_def)
  1132        (simp add: powr_minus inverse_eq_divide)
  1133 qed
  1134 
  1135 lemma rapprox_rat_nonneg_neg:
  1136   "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1137   unfolding rapprox_rat_def round_up_def
  1138   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff)
  1139 
  1140 lemma rapprox_rat_neg:
  1141   "x < 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1142   unfolding rapprox_rat_def round_up_def
  1143   by (auto simp: field_simps mult_le_0_iff)
  1144 
  1145 lemma rapprox_rat_nonpos_pos:
  1146   "x \<le> 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1147   unfolding rapprox_rat_def round_up_def
  1148   by (auto simp: field_simps mult_le_0_iff)
  1149 
  1150 lemma real_divl: "real_divl prec x y \<le> x / y"
  1151   by (simp add: real_divl_def round_down)
  1152 
  1153 lemma real_divr: "x / y \<le> real_divr prec x y"
  1154   using round_up by (simp add: real_divr_def)
  1155 
  1156 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1157   by transfer (rule real_divl)
  1158 
  1159 lemma real_divl_lower_bound:
  1160   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> 0 \<le> real_divl prec x y"
  1161   by (simp add: real_divl_def round_down_def zero_le_mult_iff zero_le_divide_iff)
  1162 
  1163 lemma float_divl_lower_bound:
  1164   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> 0 \<le> real (float_divl prec x y)"
  1165   by transfer (rule real_divl_lower_bound)
  1166 
  1167 lemma exponent_1: "exponent 1 = 0"
  1168   using exponent_float[of 1 0] by (simp add: one_float_def)
  1169 
  1170 lemma mantissa_1: "mantissa 1 = 1"
  1171   using mantissa_float[of 1 0] by (simp add: one_float_def)
  1172 
  1173 lemma bitlen_1: "bitlen 1 = 1"
  1174   by (simp add: bitlen_def)
  1175 
  1176 lemma mantissa_eq_zero_iff: "mantissa x = 0 \<longleftrightarrow> x = 0"
  1177 proof
  1178   assume "mantissa x = 0" hence z: "0 = real x" using mantissa_exponent by simp
  1179   show "x = 0" by (simp add: zero_float_def z)
  1180 qed (simp add: zero_float_def)
  1181 
  1182 lemma float_upper_bound: "x \<le> 2 powr (bitlen \<bar>mantissa x\<bar> + exponent x)"
  1183 proof (cases "x = 0", simp)
  1184   assume "x \<noteq> 0" hence "mantissa x \<noteq> 0" using mantissa_eq_zero_iff by auto
  1185   have "x = mantissa x * 2 powr (exponent x)" by (rule mantissa_exponent)
  1186   also have "mantissa x \<le> \<bar>mantissa x\<bar>" by simp
  1187   also have "... \<le> 2 powr (bitlen \<bar>mantissa x\<bar>)"
  1188     using bitlen_bounds[of "\<bar>mantissa x\<bar>"] bitlen_nonneg `mantissa x \<noteq> 0`
  1189     by (simp add: powr_int) (simp only: two_real_int int_of_reals real_of_int_abs[symmetric]
  1190       real_of_int_le_iff less_imp_le)
  1191   finally show ?thesis by (simp add: powr_add)
  1192 qed
  1193 
  1194 lemma real_divl_pos_less1_bound:
  1195   "0 < x \<Longrightarrow> x < 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real_divl prec 1 x"
  1196 proof (unfold real_divl_def)
  1197   fix prec :: nat and x :: real assume x: "0 < x" "x < 1" and prec: "1 \<le> prec"
  1198   def p \<equiv> "int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor>"
  1199   show "1 \<le> round_down (int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - \<lfloor>log 2 \<bar>1\<bar>\<rfloor>) (1 / x) "
  1200   proof cases
  1201     assume nonneg: "0 \<le> p"
  1202     hence "2 powr real (p) = floor (real ((2::int) ^ nat p)) * floor (1::real)"
  1203       by (simp add: powr_int del: real_of_int_power) simp
  1204     also have "floor (1::real) \<le> floor (1 / x)" using x prec by simp
  1205     also have "floor (real ((2::int) ^ nat p)) * floor (1 / x) \<le>
  1206       floor (real ((2::int) ^ nat p) * (1 / x))"
  1207       by (rule le_mult_floor) (auto simp: x prec less_imp_le)
  1208     finally have "2 powr real p \<le> floor (2 powr nat p / x)" by (simp add: powr_realpow)
  1209     thus ?thesis unfolding p_def[symmetric]
  1210       using x prec nonneg by (simp add: powr_minus inverse_eq_divide round_down_def)
  1211   next
  1212     assume neg: "\<not> 0 \<le> p"
  1213 
  1214     have "x = 2 powr (log 2 x)"
  1215       using x by simp
  1216     also have "2 powr (log 2 x) \<le> 2 powr p"
  1217     proof (rule powr_mono)
  1218       have "log 2 x \<le> \<lceil>log 2 x\<rceil>"
  1219         by simp
  1220       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + 1"
  1221         using ceiling_diff_floor_le_1[of "log 2 x"] by simp
  1222       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + prec"
  1223         using prec by simp
  1224       finally show "log 2 x \<le> real p"
  1225         using x by (simp add: p_def)
  1226     qed simp
  1227     finally have x_le: "x \<le> 2 powr p" .
  1228 
  1229     from neg have "2 powr real p \<le> 2 powr 0"
  1230       by (intro powr_mono) auto
  1231     also have "\<dots> \<le> \<lfloor>2 powr 0\<rfloor>" by simp
  1232     also have "\<dots> \<le> \<lfloor>2 powr real p / x\<rfloor>" unfolding real_of_int_le_iff
  1233       using x x_le by (intro floor_mono) (simp add:  pos_le_divide_eq mult_pos_pos)
  1234     finally show ?thesis
  1235       using prec x unfolding p_def[symmetric]
  1236       by (simp add: round_down_def powr_minus_divide pos_le_divide_eq mult_pos_pos)
  1237   qed
  1238 qed
  1239 
  1240 lemma float_divl_pos_less1_bound:
  1241   "0 < real x \<Longrightarrow> real x < 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real (float_divl prec 1 x)"
  1242   by (transfer, rule real_divl_pos_less1_bound)
  1243 
  1244 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1245   by transfer (rule real_divr)
  1246 
  1247 lemma real_divr_pos_less1_lower_bound: assumes "0 < x" and "x < 1" shows "1 \<le> real_divr prec 1 x"
  1248 proof -
  1249   have "1 \<le> 1 / x" using `0 < x` and `x < 1` by auto
  1250   also have "\<dots> \<le> real_divr prec 1 x" using real_divr[where x=1 and y=x] by auto
  1251   finally show ?thesis by auto
  1252 qed
  1253 
  1254 lemma float_divr_pos_less1_lower_bound: "0 < x \<Longrightarrow> x < 1 \<Longrightarrow> 1 \<le> float_divr prec 1 x"
  1255   by transfer (rule real_divr_pos_less1_lower_bound)
  1256 
  1257 lemma real_divr_nonpos_pos_upper_bound:
  1258   "x \<le> 0 \<Longrightarrow> 0 < y \<Longrightarrow> real_divr prec x y \<le> 0"
  1259   by (auto simp: field_simps mult_le_0_iff divide_le_0_iff round_up_def real_divr_def)
  1260 
  1261 lemma float_divr_nonpos_pos_upper_bound:
  1262   "real x \<le> 0 \<Longrightarrow> 0 < real y \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1263   by transfer (rule real_divr_nonpos_pos_upper_bound)
  1264 
  1265 lemma real_divr_nonneg_neg_upper_bound:
  1266   "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> real_divr prec x y \<le> 0"
  1267   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff divide_le_0_iff round_up_def real_divr_def)
  1268 
  1269 lemma float_divr_nonneg_neg_upper_bound:
  1270   "0 \<le> real x \<Longrightarrow> real y < 0 \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1271   by transfer (rule real_divr_nonneg_neg_upper_bound)
  1272 
  1273 definition truncate_down::"nat \<Rightarrow> real \<Rightarrow> real" where
  1274   "truncate_down prec x = round_down (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x"
  1275 
  1276 lemma truncate_down: "truncate_down prec x \<le> x"
  1277   using round_down by (simp add: truncate_down_def)
  1278 
  1279 lemma truncate_down_le: "x \<le> y \<Longrightarrow> truncate_down prec x \<le> y"
  1280   by (rule order_trans[OF truncate_down])
  1281 
  1282 definition truncate_up::"nat \<Rightarrow> real \<Rightarrow> real" where
  1283   "truncate_up prec x = round_up (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x"
  1284 
  1285 lemma truncate_up: "x \<le> truncate_up prec x"
  1286   using round_up by (simp add: truncate_up_def)
  1287 
  1288 lemma truncate_up_le: "x \<le> y \<Longrightarrow> x \<le> truncate_up prec y"
  1289   by (rule order_trans[OF _ truncate_up])
  1290 
  1291 lemma truncate_up_zero[simp]: "truncate_up prec 0 = 0"
  1292   by (simp add: truncate_up_def)
  1293 
  1294 lift_definition float_round_up :: "nat \<Rightarrow> float \<Rightarrow> float" is truncate_up
  1295   by (simp add: truncate_up_def)
  1296 
  1297 lemma float_round_up: "real x \<le> real (float_round_up prec x)"
  1298   using truncate_up by transfer simp
  1299 
  1300 lift_definition float_round_down :: "nat \<Rightarrow> float \<Rightarrow> float" is truncate_down
  1301   by (simp add: truncate_down_def)
  1302 
  1303 lemma float_round_down: "real (float_round_down prec x) \<le> real x"
  1304   using truncate_down by transfer simp
  1305 
  1306 lemma floor_add2[simp]: "\<lfloor> real i + x \<rfloor> = i + \<lfloor> x \<rfloor>"
  1307   using floor_add[of x i] by (simp del: floor_add add: ac_simps)
  1308 
  1309 lemma compute_float_round_down[code]:
  1310   "float_round_down prec (Float m e) = (let d = bitlen (abs m) - int prec in
  1311     if 0 < d then let P = 2^nat d ; n = m div P in Float n (e + d)
  1312              else Float m e)"
  1313   using Float.compute_float_down[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1314   by transfer (simp add: field_simps abs_mult log_mult bitlen_def truncate_down_def
  1315     cong del: if_weak_cong)
  1316 hide_fact (open) compute_float_round_down
  1317 
  1318 lemma compute_float_round_up[code]:
  1319   "float_round_up prec (Float m e) = (let d = (bitlen (abs m) - int prec) in
  1320      if 0 < d then let P = 2^nat d ; n = m div P ; r = m mod P
  1321                    in Float (n + (if r = 0 then 0 else 1)) (e + d)
  1322               else Float m e)"
  1323   using Float.compute_float_up[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1324   unfolding Let_def
  1325   by transfer (simp add: field_simps abs_mult log_mult bitlen_def truncate_up_def
  1326     cong del: if_weak_cong)
  1327 hide_fact (open) compute_float_round_up
  1328 
  1329 lemma round_up_mono: "x \<le> y \<Longrightarrow> round_up p x \<le> round_up p y"
  1330   by (auto intro!: ceiling_mono simp: round_up_def)
  1331 
  1332 lemma truncate_up_nonneg_mono:
  1333   assumes "0 \<le> x" "x \<le> y"
  1334   shows "truncate_up prec x \<le> truncate_up prec y"
  1335 proof -
  1336   {
  1337     assume "\<lfloor>log 2 x\<rfloor> = \<lfloor>log 2 y\<rfloor>"
  1338     hence ?thesis
  1339       using assms
  1340       by (auto simp: truncate_up_def round_up_def intro!: ceiling_mono)
  1341   } moreover {
  1342     assume "0 < x"
  1343     hence "log 2 x \<le> log 2 y" using assms by auto
  1344     moreover
  1345     assume "\<lfloor>log 2 x\<rfloor> \<noteq> \<lfloor>log 2 y\<rfloor>"
  1346     ultimately have logless: "log 2 x < log 2 y" and flogless: "\<lfloor>log 2 x\<rfloor> < \<lfloor>log 2 y\<rfloor>"
  1347       unfolding atomize_conj
  1348       by (metis floor_less_cancel linorder_cases not_le)
  1349     have "truncate_up prec x =
  1350       real \<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> * 2 powr - real (int prec - \<lfloor>log 2 x\<rfloor> - 1)"
  1351       using assms by (simp add: truncate_up_def round_up_def)
  1352     also have "\<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> \<le> (2 ^ prec)"
  1353     proof (unfold ceiling_le_eq)
  1354       have "x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> x * (2 powr real prec / (2 powr log 2 x))"
  1355         using real_of_int_floor_add_one_ge[of "log 2 x"] assms
  1356         by (auto simp add: algebra_simps powr_divide2 intro!: mult_left_mono)
  1357       thus "x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> real ((2::int) ^ prec)"
  1358         using `0 < x` by (simp add: powr_realpow)
  1359     qed
  1360     hence "real \<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> \<le> 2 powr int prec"
  1361       by (auto simp: powr_realpow)
  1362     also
  1363     have "2 powr - real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> 2 powr - real (int prec - \<lfloor>log 2 y\<rfloor>)"
  1364       using logless flogless by (auto intro!: floor_mono)
  1365     also have "2 powr real (int prec) \<le> 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>))"
  1366       using assms `0 < x`
  1367       by (auto simp: algebra_simps)
  1368     finally have "truncate_up prec x \<le> 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>)) * 2 powr - real (int prec - \<lfloor>log 2 y\<rfloor>)"
  1369       by simp
  1370     also have "\<dots> = 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>) - real (int prec - \<lfloor>log 2 y\<rfloor>))"
  1371       by (subst powr_add[symmetric]) simp
  1372     also have "\<dots> = y"
  1373       using `0 < x` assms
  1374       by (simp add: powr_add)
  1375     also have "\<dots> \<le> truncate_up prec y"
  1376       by (rule truncate_up)
  1377     finally have ?thesis .
  1378   } moreover {
  1379     assume "~ 0 < x"
  1380     hence ?thesis
  1381       using assms
  1382       by (auto intro!: truncate_up_le)
  1383   } ultimately show ?thesis
  1384     by blast
  1385 qed
  1386 
  1387 lemma truncate_up_nonpos: "x \<le> 0 \<Longrightarrow> truncate_up prec x \<le> 0"
  1388   by (auto simp: truncate_up_def round_up_def intro!: mult_nonpos_nonneg)
  1389 
  1390 lemma truncate_down_nonpos: "x \<le> 0 \<Longrightarrow> truncate_down prec x \<le> 0"
  1391   by (auto simp: truncate_down_def round_down_def intro!: mult_nonpos_nonneg
  1392     order_le_less_trans[of _ 0, OF mult_nonpos_nonneg])
  1393 
  1394 lemma truncate_up_switch_sign_mono:
  1395   assumes "x \<le> 0" "0 \<le> y"
  1396   shows "truncate_up prec x \<le> truncate_up prec y"
  1397 proof -
  1398   note truncate_up_nonpos[OF `x \<le> 0`]
  1399   also note truncate_up_le[OF `0 \<le> y`]
  1400   finally show ?thesis .
  1401 qed
  1402 
  1403 lemma truncate_down_zeroprec_mono:
  1404   assumes "0 < x" "x \<le> y"
  1405   shows "truncate_down 0 x \<le> truncate_down 0 y"
  1406 proof -
  1407   have "x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1) = x * inverse (2 powr ((real \<lfloor>log 2 x\<rfloor> + 1)))"
  1408     by (simp add: powr_divide2[symmetric] powr_add powr_minus inverse_eq_divide)
  1409   also have "\<dots> = 2 powr (log 2 x - (real \<lfloor>log 2 x\<rfloor>) - 1)"
  1410     using `0 < x`
  1411     by (auto simp: inverse_eq_divide field_simps powr_add powr_divide2[symmetric])
  1412   also have "\<dots> < 2 powr 0"
  1413     using real_of_int_floor_add_one_gt
  1414     unfolding neg_less_iff_less
  1415     by (intro powr_less_mono) (auto simp: algebra_simps)
  1416   finally have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> < 1"
  1417     unfolding less_ceiling_eq real_of_int_minus real_of_one
  1418     by simp
  1419   moreover
  1420   have "0 \<le> \<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor>"
  1421     using `x > 0` by (auto intro: mult_nonneg_nonneg)
  1422   ultimately have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> \<in> {0 ..< 1}"
  1423     by simp
  1424   also have "\<dots> \<subseteq> {0}" by auto
  1425   finally have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> = 0" by simp
  1426   with assms show ?thesis
  1427     by (auto simp: truncate_down_def round_down_def intro!: mult_nonneg_nonneg)
  1428 qed
  1429 
  1430 lemma truncate_down_nonneg: "0 \<le> y \<Longrightarrow> 0 \<le> truncate_down prec y"
  1431   by (auto simp: truncate_down_def round_down_def intro!: mult_nonneg_nonneg)
  1432 
  1433 lemma truncate_down_zero: "truncate_down prec 0 = 0"
  1434   by (auto simp: truncate_down_def round_down_def intro!: mult_nonneg_nonneg)
  1435 
  1436 lemma truncate_down_switch_sign_mono:
  1437   assumes "x \<le> 0" "0 \<le> y"
  1438   assumes "x \<le> y"
  1439   shows "truncate_down prec x \<le> truncate_down prec y"
  1440 proof -
  1441   note truncate_down_nonpos[OF `x \<le> 0`]
  1442   also note truncate_down_nonneg[OF `0 \<le> y`]
  1443   finally show ?thesis .
  1444 qed
  1445 
  1446 lemma truncate_up_uminus_truncate_down:
  1447   "truncate_up prec x = - truncate_down prec (- x)"
  1448   "truncate_up prec (-x) = - truncate_down prec x"
  1449   by (auto simp: truncate_up_def round_up_def truncate_down_def round_down_def ceiling_def)
  1450 
  1451 lemma truncate_down_uminus_truncate_up:
  1452   "truncate_down prec x = - truncate_up prec (- x)"
  1453   "truncate_down prec (-x) = - truncate_up prec x"
  1454   by (auto simp: truncate_up_def round_up_def truncate_down_def round_down_def ceiling_def)
  1455 
  1456 lemma truncate_down_nonneg_mono:
  1457   assumes "0 \<le> x" "x \<le> y"
  1458   shows "truncate_down prec x \<le> truncate_down prec y"
  1459 proof -
  1460   {
  1461     assume "0 < x" "prec = 0"
  1462     with assms have ?thesis
  1463       by (simp add: truncate_down_zeroprec_mono)
  1464   } moreover {
  1465     assume "~ 0 < x"
  1466     with assms have "x = 0" "0 \<le> y" by simp_all
  1467     hence ?thesis
  1468       by (auto simp add: truncate_down_zero intro!: truncate_down_nonneg)
  1469   } moreover {
  1470     assume "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> = \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1471     hence ?thesis
  1472       using assms
  1473       by (auto simp: truncate_down_def round_down_def intro!: floor_mono)
  1474   } moreover {
  1475     assume "0 < x"
  1476     hence "log 2 x \<le> log 2 y" "0 < y" "0 \<le> y" using assms by auto
  1477     moreover
  1478     assume "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> \<noteq> \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1479     ultimately have logless: "log 2 x < log 2 y" and flogless: "\<lfloor>log 2 x\<rfloor> < \<lfloor>log 2 y\<rfloor>"
  1480       unfolding atomize_conj abs_of_pos[OF `0 < x`] abs_of_pos[OF `0 < y`]
  1481       by (metis floor_less_cancel linorder_cases not_le)
  1482     assume "prec \<noteq> 0" hence [simp]: "prec \<ge> Suc 0" by auto
  1483     have "2 powr (prec - 1) \<le> y * 2 powr real (prec - 1) / (2 powr log 2 y)"
  1484       using `0 < y`
  1485       by simp
  1486     also have "\<dots> \<le> y * 2 powr real prec / (2 powr (real \<lfloor>log 2 y\<rfloor> + 1))"
  1487       using `0 \<le> y` `0 \<le> x` assms(2)
  1488       by (auto intro!: powr_mono mult_nonneg_nonneg mult_pos_pos divide_left_mono
  1489         simp: real_of_nat_diff powr_add
  1490         powr_divide2[symmetric])
  1491     also have "\<dots> = y * 2 powr real prec / (2 powr real \<lfloor>log 2 y\<rfloor> * 2)"
  1492       by (auto simp: powr_add)
  1493     finally have "(2 ^ (prec - 1)) \<le> \<lfloor>y * 2 powr real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1)\<rfloor>"
  1494       using `0 \<le> y`
  1495       by (auto simp: powr_divide2[symmetric] le_floor_eq powr_realpow)
  1496     hence "(2 ^ (prec - 1)) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1) \<le> truncate_down prec y"
  1497       by (auto simp: truncate_down_def round_down_def)
  1498     moreover
  1499     {
  1500       have "x = 2 powr (log 2 \<bar>x\<bar>)" using `0 < x` by simp
  1501       also have "\<dots> \<le> (2 ^ (prec )) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1)"
  1502         using real_of_int_floor_add_one_ge[of "log 2 \<bar>x\<bar>"]
  1503         by (auto simp: powr_realpow[symmetric] powr_add[symmetric] algebra_simps)
  1504       also
  1505       have "2 powr - real (int prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) \<le> 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor>)"
  1506         using logless flogless `x > 0` `y > 0`
  1507         by (auto intro!: floor_mono)
  1508       finally have "x \<le> (2 ^ (prec - 1)) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1)"
  1509         by (auto simp: powr_realpow[symmetric] powr_divide2[symmetric] assms real_of_nat_diff)
  1510     } ultimately have ?thesis
  1511       by (metis dual_order.trans truncate_down)
  1512   } ultimately show ?thesis by blast
  1513 qed
  1514 
  1515 lemma truncate_down_mono: "x \<le> y \<Longrightarrow> truncate_down p x \<le> truncate_down p y"
  1516   apply (cases "0 \<le> x")
  1517   apply (rule truncate_down_nonneg_mono, assumption+)
  1518   apply (simp add: truncate_down_uminus_truncate_up)
  1519   apply (cases "0 \<le> y")
  1520   apply (auto intro: truncate_up_nonneg_mono truncate_up_switch_sign_mono)
  1521   done
  1522 
  1523 lemma truncate_up_mono: "x \<le> y \<Longrightarrow> truncate_up p x \<le> truncate_up p y"
  1524   by (simp add: truncate_up_uminus_truncate_down truncate_down_mono)
  1525 
  1526 lemma Float_le_zero_iff: "Float a b \<le> 0 \<longleftrightarrow> a \<le> 0"
  1527  apply (auto simp: zero_float_def mult_le_0_iff)
  1528  using powr_gt_zero[of 2 b] by simp
  1529 
  1530 lemma real_of_float_pprt[simp]: fixes a::float shows "real (pprt a) = pprt (real a)"
  1531   unfolding pprt_def sup_float_def max_def sup_real_def by auto
  1532 
  1533 lemma real_of_float_nprt[simp]: fixes a::float shows "real (nprt a) = nprt (real a)"
  1534   unfolding nprt_def inf_float_def min_def inf_real_def by auto
  1535 
  1536 lift_definition int_floor_fl :: "float \<Rightarrow> int" is floor .
  1537 
  1538 lemma compute_int_floor_fl[code]:
  1539   "int_floor_fl (Float m e) = (if 0 \<le> e then m * 2 ^ nat e else m div (2 ^ (nat (-e))))"
  1540   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1541 hide_fact (open) compute_int_floor_fl
  1542 
  1543 lift_definition floor_fl :: "float \<Rightarrow> float" is "\<lambda>x. real (floor x)" by simp
  1544 
  1545 lemma compute_floor_fl[code]:
  1546   "floor_fl (Float m e) = (if 0 \<le> e then Float m e else Float (m div (2 ^ (nat (-e)))) 0)"
  1547   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1548 hide_fact (open) compute_floor_fl
  1549 
  1550 lemma floor_fl: "real (floor_fl x) \<le> real x" by transfer simp
  1551 
  1552 lemma int_floor_fl: "real (int_floor_fl x) \<le> real x" by transfer simp
  1553 
  1554 lemma floor_pos_exp: "exponent (floor_fl x) \<ge> 0"
  1555 proof (cases "floor_fl x = float_of 0")
  1556   case True
  1557   then show ?thesis by (simp add: floor_fl_def)
  1558 next
  1559   case False
  1560   have eq: "floor_fl x = Float \<lfloor>real x\<rfloor> 0" by transfer simp
  1561   obtain i where "\<lfloor>real x\<rfloor> = mantissa (floor_fl x) * 2 ^ i" "0 = exponent (floor_fl x) - int i"
  1562     by (rule denormalize_shift[OF eq[THEN eq_reflection] False])
  1563   then show ?thesis by simp
  1564 qed
  1565 
  1566 end
  1567