src/HOL/Library/Numeral_Type.thy
author huffman
Thu Feb 19 16:51:46 2009 -0800 (2009-02-19)
changeset 29997 f6756c097c2d
parent 29629 5111ce425e7a
child 29998 19e1ef628b25
permissions -rw-r--r--
number_ring instances for numeral types
     1 (*  Title:      HOL/Library/Numeral_Type.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Numeral Syntax for Types *}
     6 
     7 theory Numeral_Type
     8 imports Plain "~~/src/HOL/Presburger"
     9 begin
    10 
    11 subsection {* Preliminary lemmas *}
    12 (* These should be moved elsewhere *)
    13 
    14 lemma (in type_definition) univ:
    15   "UNIV = Abs ` A"
    16 proof
    17   show "Abs ` A \<subseteq> UNIV" by (rule subset_UNIV)
    18   show "UNIV \<subseteq> Abs ` A"
    19   proof
    20     fix x :: 'b
    21     have "x = Abs (Rep x)" by (rule Rep_inverse [symmetric])
    22     moreover have "Rep x \<in> A" by (rule Rep)
    23     ultimately show "x \<in> Abs ` A" by (rule image_eqI)
    24   qed
    25 qed
    26 
    27 lemma (in type_definition) card: "card (UNIV :: 'b set) = card A"
    28   by (simp add: univ card_image inj_on_def Abs_inject)
    29 
    30 
    31 subsection {* Cardinalities of types *}
    32 
    33 syntax "_type_card" :: "type => nat" ("(1CARD/(1'(_')))")
    34 
    35 translations "CARD(t)" => "CONST card (CONST UNIV \<Colon> t set)"
    36 
    37 typed_print_translation {*
    38 let
    39   fun card_univ_tr' show_sorts _ [Const (@{const_name UNIV}, Type(_,[T,_]))] =
    40     Syntax.const "_type_card" $ Syntax.term_of_typ show_sorts T;
    41 in [(@{const_syntax card}, card_univ_tr')]
    42 end
    43 *}
    44 
    45 lemma card_unit: "CARD(unit) = 1"
    46   unfolding UNIV_unit by simp
    47 
    48 lemma card_bool: "CARD(bool) = 2"
    49   unfolding UNIV_bool by simp
    50 
    51 lemma card_prod: "CARD('a::finite \<times> 'b::finite) = CARD('a) * CARD('b)"
    52   unfolding UNIV_Times_UNIV [symmetric] by (simp only: card_cartesian_product)
    53 
    54 lemma card_sum: "CARD('a::finite + 'b::finite) = CARD('a) + CARD('b)"
    55   unfolding UNIV_Plus_UNIV [symmetric] by (simp only: finite card_Plus)
    56 
    57 lemma card_option: "CARD('a::finite option) = Suc CARD('a)"
    58   unfolding insert_None_conv_UNIV [symmetric]
    59   apply (subgoal_tac "(None::'a option) \<notin> range Some")
    60   apply (simp add: card_image)
    61   apply fast
    62   done
    63 
    64 lemma card_set: "CARD('a::finite set) = 2 ^ CARD('a)"
    65   unfolding Pow_UNIV [symmetric]
    66   by (simp only: card_Pow finite numeral_2_eq_2)
    67 
    68 lemma card_finite_pos [simp]: "0 < CARD('a::finite)"
    69   unfolding neq0_conv [symmetric] by simp
    70 
    71 
    72 subsection {* Numeral Types *}
    73 
    74 typedef (open) num0 = "UNIV :: nat set" ..
    75 typedef (open) num1 = "UNIV :: unit set" ..
    76 
    77 typedef (open) 'a bit0 = "{0 ..< 2 * int CARD('a::finite)}"
    78 proof
    79   show "0 \<in> {0 ..< 2 * int CARD('a)}"
    80     by simp
    81 qed
    82 
    83 typedef (open) 'a bit1 = "{0 ..< 1 + 2 * int CARD('a::finite)}"
    84 proof
    85   show "0 \<in> {0 ..< 1 + 2 * int CARD('a)}"
    86     by simp
    87 qed
    88 
    89 instance num1 :: finite
    90 proof
    91   show "finite (UNIV::num1 set)"
    92     unfolding type_definition.univ [OF type_definition_num1]
    93     using finite by (rule finite_imageI)
    94 qed
    95 
    96 instance bit0 :: (finite) finite
    97 proof
    98   show "finite (UNIV::'a bit0 set)"
    99     unfolding type_definition.univ [OF type_definition_bit0]
   100     by simp
   101 qed
   102 
   103 instance bit1 :: (finite) finite
   104 proof
   105   show "finite (UNIV::'a bit1 set)"
   106     unfolding type_definition.univ [OF type_definition_bit1]
   107     by simp
   108 qed
   109 
   110 lemma card_num1: "CARD(num1) = 1"
   111   unfolding type_definition.card [OF type_definition_num1]
   112   by (simp only: card_unit)
   113 
   114 lemma card_bit0: "CARD('a::finite bit0) = 2 * CARD('a)"
   115   unfolding type_definition.card [OF type_definition_bit0]
   116   by simp
   117 
   118 lemma card_bit1: "CARD('a::finite bit1) = Suc (2 * CARD('a))"
   119   unfolding type_definition.card [OF type_definition_bit1]
   120   by simp
   121 
   122 lemma card_num0: "CARD (num0) = 0"
   123   by (simp add: infinite_UNIV_nat card_eq_0_iff type_definition.card [OF type_definition_num0])
   124 
   125 lemmas card_univ_simps [simp] =
   126   card_unit
   127   card_bool
   128   card_prod
   129   card_sum
   130   card_option
   131   card_set
   132   card_num1
   133   card_bit0
   134   card_bit1
   135   card_num0
   136 
   137 
   138 subsection {* Locale for modular arithmetic subtypes *}
   139 
   140 locale mod_type =
   141   fixes n :: int
   142   and Rep :: "'a::{zero,one,plus,times,uminus,minus,power} \<Rightarrow> int"
   143   and Abs :: "int \<Rightarrow> 'a::{zero,one,plus,times,uminus,minus,power}"
   144   assumes type: "type_definition Rep Abs {0..<n}"
   145   and size1: "1 < n"
   146   and zero_def: "0 = Abs 0"
   147   and one_def:  "1 = Abs 1"
   148   and add_def:  "x + y = Abs ((Rep x + Rep y) mod n)"
   149   and mult_def: "x * y = Abs ((Rep x * Rep y) mod n)"
   150   and diff_def: "x - y = Abs ((Rep x - Rep y) mod n)"
   151   and minus_def: "- x = Abs ((- Rep x) mod n)"
   152   and power_def: "x ^ k = Abs (Rep x ^ k mod n)"
   153 begin
   154 
   155 lemma size0: "0 < n"
   156 by (cut_tac size1, simp)
   157 
   158 lemmas definitions =
   159   zero_def one_def add_def mult_def minus_def diff_def power_def
   160 
   161 lemma Rep_less_n: "Rep x < n"
   162 by (rule type_definition.Rep [OF type, simplified, THEN conjunct2])
   163 
   164 lemma Rep_le_n: "Rep x \<le> n"
   165 by (rule Rep_less_n [THEN order_less_imp_le])
   166 
   167 lemma Rep_inject_sym: "x = y \<longleftrightarrow> Rep x = Rep y"
   168 by (rule type_definition.Rep_inject [OF type, symmetric])
   169 
   170 lemma Rep_inverse: "Abs (Rep x) = x"
   171 by (rule type_definition.Rep_inverse [OF type])
   172 
   173 lemma Abs_inverse: "m \<in> {0..<n} \<Longrightarrow> Rep (Abs m) = m"
   174 by (rule type_definition.Abs_inverse [OF type])
   175 
   176 lemma Rep_Abs_mod: "Rep (Abs (m mod n)) = m mod n"
   177 by (simp add: Abs_inverse IntDiv.pos_mod_conj [OF size0])
   178 
   179 lemma Rep_Abs_0: "Rep (Abs 0) = 0"
   180 by (simp add: Abs_inverse size0)
   181 
   182 lemma Rep_0: "Rep 0 = 0"
   183 by (simp add: zero_def Rep_Abs_0)
   184 
   185 lemma Rep_Abs_1: "Rep (Abs 1) = 1"
   186 by (simp add: Abs_inverse size1)
   187 
   188 lemma Rep_1: "Rep 1 = 1"
   189 by (simp add: one_def Rep_Abs_1)
   190 
   191 lemma Rep_mod: "Rep x mod n = Rep x"
   192 apply (rule_tac x=x in type_definition.Abs_cases [OF type])
   193 apply (simp add: type_definition.Abs_inverse [OF type])
   194 apply (simp add: mod_pos_pos_trivial)
   195 done
   196 
   197 lemmas Rep_simps =
   198   Rep_inject_sym Rep_inverse Rep_Abs_mod Rep_mod Rep_Abs_0 Rep_Abs_1
   199 
   200 lemma comm_ring_1: "OFCLASS('a, comm_ring_1_class)"
   201 apply (intro_classes, unfold definitions)
   202 apply (simp_all add: Rep_simps zmod_simps ring_simps)
   203 done
   204 
   205 lemma recpower: "OFCLASS('a, recpower_class)"
   206 apply (intro_classes, unfold definitions)
   207 apply (simp_all add: Rep_simps zmod_simps add_ac mult_assoc
   208                      mod_pos_pos_trivial size1)
   209 done
   210 
   211 end
   212 
   213 locale mod_ring = mod_type +
   214   constrains n :: int
   215   and Rep :: "'a::{number_ring,power} \<Rightarrow> int"
   216   and Abs :: "int \<Rightarrow> 'a::{number_ring,power}"
   217 begin
   218 
   219 lemma of_nat_eq: "of_nat k = Abs (int k mod n)"
   220 apply (induct k)
   221 apply (simp add: zero_def)
   222 apply (simp add: Rep_simps add_def one_def zmod_simps add_ac)
   223 done
   224 
   225 lemma of_int_eq: "of_int z = Abs (z mod n)"
   226 apply (cases z rule: int_diff_cases)
   227 apply (simp add: Rep_simps of_nat_eq diff_def zmod_simps)
   228 done
   229 
   230 lemma Rep_number_of:
   231   "Rep (number_of w) = number_of w mod n"
   232 by (simp add: number_of_eq of_int_eq Rep_Abs_mod)
   233 
   234 lemma iszero_number_of:
   235   "iszero (number_of w::'a) \<longleftrightarrow> number_of w mod n = 0"
   236 by (simp add: Rep_simps number_of_eq of_int_eq iszero_def zero_def)
   237 
   238 lemma cases:
   239   assumes 1: "\<And>z. \<lbrakk>(x::'a) = of_int z; 0 \<le> z; z < n\<rbrakk> \<Longrightarrow> P"
   240   shows "P"
   241 apply (cases x rule: type_definition.Abs_cases [OF type])
   242 apply (rule_tac z="y" in 1)
   243 apply (simp_all add: of_int_eq mod_pos_pos_trivial)
   244 done
   245 
   246 lemma induct:
   247   "(\<And>z. \<lbrakk>0 \<le> z; z < n\<rbrakk> \<Longrightarrow> P (of_int z)) \<Longrightarrow> P (x::'a)"
   248 by (cases x rule: cases) simp
   249 
   250 end
   251 
   252 
   253 subsection {* Number ring instances *}
   254 
   255 instantiation
   256   bit0 and bit1 :: (finite) "{zero,one,plus,times,uminus,minus,power}"
   257 begin
   258 
   259 definition Abs_bit0' :: "int \<Rightarrow> 'a bit0" where
   260   "Abs_bit0' x = Abs_bit0 (x mod (2 * int CARD('a)))"
   261 
   262 definition Abs_bit1' :: "int \<Rightarrow> 'a bit1" where
   263   "Abs_bit1' x = Abs_bit1 (x mod (1 + 2 * int CARD('a)))"
   264 
   265 definition "0 = Abs_bit0 0"
   266 definition "1 = Abs_bit0 1"
   267 definition "x + y = Abs_bit0' (Rep_bit0 x + Rep_bit0 y)"
   268 definition "x * y = Abs_bit0' (Rep_bit0 x * Rep_bit0 y)"
   269 definition "x - y = Abs_bit0' (Rep_bit0 x - Rep_bit0 y)"
   270 definition "- x = Abs_bit0' (- Rep_bit0 x)"
   271 definition "x ^ k = Abs_bit0' (Rep_bit0 x ^ k)"
   272 
   273 definition "0 = Abs_bit1 0"
   274 definition "1 = Abs_bit1 1"
   275 definition "x + y = Abs_bit1' (Rep_bit1 x + Rep_bit1 y)"
   276 definition "x * y = Abs_bit1' (Rep_bit1 x * Rep_bit1 y)"
   277 definition "x - y = Abs_bit1' (Rep_bit1 x - Rep_bit1 y)"
   278 definition "- x = Abs_bit1' (- Rep_bit1 x)"
   279 definition "x ^ k = Abs_bit1' (Rep_bit1 x ^ k)"
   280 
   281 instance ..
   282 
   283 end
   284 
   285 interpretation bit0!:
   286   mod_type "2 * int CARD('a::finite)"
   287            "Rep_bit0 :: 'a::finite bit0 \<Rightarrow> int"
   288            "Abs_bit0 :: int \<Rightarrow> 'a::finite bit0"
   289 apply (rule mod_type.intro)
   290 apply (rule type_definition_bit0)
   291 using card_finite_pos [where ?'a='a] apply arith
   292 apply (rule zero_bit0_def)
   293 apply (rule one_bit0_def)
   294 apply (rule plus_bit0_def [unfolded Abs_bit0'_def])
   295 apply (rule times_bit0_def [unfolded Abs_bit0'_def])
   296 apply (rule minus_bit0_def [unfolded Abs_bit0'_def])
   297 apply (rule uminus_bit0_def [unfolded Abs_bit0'_def])
   298 apply (rule power_bit0_def [unfolded Abs_bit0'_def])
   299 done
   300 
   301 interpretation bit1!:
   302   mod_type "1 + 2 * int CARD('a::finite)"
   303            "Rep_bit1 :: 'a::finite bit1 \<Rightarrow> int"
   304            "Abs_bit1 :: int \<Rightarrow> 'a::finite bit1"
   305 apply (rule mod_type.intro)
   306 apply (rule type_definition_bit1)
   307 apply simp
   308 apply (rule zero_bit1_def)
   309 apply (rule one_bit1_def)
   310 apply (rule plus_bit1_def [unfolded Abs_bit1'_def])
   311 apply (rule times_bit1_def [unfolded Abs_bit1'_def])
   312 apply (rule minus_bit1_def [unfolded Abs_bit1'_def])
   313 apply (rule uminus_bit1_def [unfolded Abs_bit1'_def])
   314 apply (rule power_bit1_def [unfolded Abs_bit1'_def])
   315 done
   316 
   317 instance bit0 :: (finite) "{comm_ring_1,recpower}"
   318   by (rule bit0.comm_ring_1 bit0.recpower)+
   319 
   320 instance bit1 :: (finite) "{comm_ring_1,recpower}"
   321   by (rule bit1.comm_ring_1 bit1.recpower)+
   322 
   323 instantiation bit0 and bit1 :: (finite) number_ring
   324 begin
   325 
   326 definition "(number_of w :: _ bit0) = of_int w"
   327 
   328 definition "(number_of w :: _ bit1) = of_int w"
   329 
   330 instance proof
   331 qed (rule number_of_bit0_def number_of_bit1_def)+
   332 
   333 end
   334 
   335 interpretation bit0!:
   336   mod_ring "2 * int CARD('a::finite)"
   337            "Rep_bit0 :: 'a::finite bit0 \<Rightarrow> int"
   338            "Abs_bit0 :: int \<Rightarrow> 'a::finite bit0"
   339   ..
   340 
   341 interpretation bit1!:
   342   mod_ring "1 + 2 * int CARD('a::finite)"
   343            "Rep_bit1 :: 'a::finite bit1 \<Rightarrow> int"
   344            "Abs_bit1 :: int \<Rightarrow> 'a::finite bit1"
   345   ..
   346 
   347 text {* Set up cases, induction, and arithmetic *}
   348 
   349 lemmas bit0_cases [cases type: bit0, case_names of_int] = bit0.cases
   350 lemmas bit1_cases [cases type: bit1, case_names of_int] = bit1.cases
   351 
   352 lemmas bit0_induct [induct type: bit0, case_names of_int] = bit0.induct
   353 lemmas bit1_induct [induct type: bit1, case_names of_int] = bit1.induct
   354 
   355 lemmas bit0_iszero_number_of [simp] = bit0.iszero_number_of
   356 lemmas bit1_iszero_number_of [simp] = bit1.iszero_number_of
   357 
   358 declare power_Suc [where ?'a="'a::finite bit0", standard, simp]
   359 declare power_Suc [where ?'a="'a::finite bit1", standard, simp]
   360 
   361 
   362 subsection {* Syntax *}
   363 
   364 syntax
   365   "_NumeralType" :: "num_const => type"  ("_")
   366   "_NumeralType0" :: type ("0")
   367   "_NumeralType1" :: type ("1")
   368 
   369 translations
   370   "_NumeralType1" == (type) "num1"
   371   "_NumeralType0" == (type) "num0"
   372 
   373 parse_translation {*
   374 let
   375 
   376 val num1_const = Syntax.const "Numeral_Type.num1";
   377 val num0_const = Syntax.const "Numeral_Type.num0";
   378 val B0_const = Syntax.const "Numeral_Type.bit0";
   379 val B1_const = Syntax.const "Numeral_Type.bit1";
   380 
   381 fun mk_bintype n =
   382   let
   383     fun mk_bit n = if n = 0 then B0_const else B1_const;
   384     fun bin_of n =
   385       if n = 1 then num1_const
   386       else if n = 0 then num0_const
   387       else if n = ~1 then raise TERM ("negative type numeral", [])
   388       else
   389         let val (q, r) = Integer.div_mod n 2;
   390         in mk_bit r $ bin_of q end;
   391   in bin_of n end;
   392 
   393 fun numeral_tr (*"_NumeralType"*) [Const (str, _)] =
   394       mk_bintype (valOf (Int.fromString str))
   395   | numeral_tr (*"_NumeralType"*) ts = raise TERM ("numeral_tr", ts);
   396 
   397 in [("_NumeralType", numeral_tr)] end;
   398 *}
   399 
   400 print_translation {*
   401 let
   402 fun int_of [] = 0
   403   | int_of (b :: bs) = b + 2 * int_of bs;
   404 
   405 fun bin_of (Const ("num0", _)) = []
   406   | bin_of (Const ("num1", _)) = [1]
   407   | bin_of (Const ("bit0", _) $ bs) = 0 :: bin_of bs
   408   | bin_of (Const ("bit1", _) $ bs) = 1 :: bin_of bs
   409   | bin_of t = raise TERM("bin_of", [t]);
   410 
   411 fun bit_tr' b [t] =
   412   let
   413     val rev_digs = b :: bin_of t handle TERM _ => raise Match
   414     val i = int_of rev_digs;
   415     val num = string_of_int (abs i);
   416   in
   417     Syntax.const "_NumeralType" $ Syntax.free num
   418   end
   419   | bit_tr' b _ = raise Match;
   420 
   421 in [("bit0", bit_tr' 0), ("bit1", bit_tr' 1)] end;
   422 *}
   423 
   424 
   425 subsection {* Classes with at least 1 and 2  *}
   426 
   427 text {* Class finite already captures "at least 1" *}
   428 
   429 lemma zero_less_card_finite [simp]:
   430   "0 < CARD('a::finite)"
   431 proof (cases "CARD('a::finite) = 0")
   432   case False thus ?thesis by (simp del: card_0_eq)
   433 next
   434   case True
   435   thus ?thesis by (simp add: finite)
   436 qed
   437 
   438 lemma one_le_card_finite [simp]:
   439   "Suc 0 <= CARD('a::finite)"
   440   by (simp add: less_Suc_eq_le [symmetric] zero_less_card_finite)
   441 
   442 
   443 text {* Class for cardinality "at least 2" *}
   444 
   445 class card2 = finite + 
   446   assumes two_le_card: "2 <= CARD('a)"
   447 
   448 lemma one_less_card: "Suc 0 < CARD('a::card2)"
   449   using two_le_card [where 'a='a] by simp
   450 
   451 instance bit0 :: (finite) card2
   452   by intro_classes (simp add: one_le_card_finite)
   453 
   454 instance bit1 :: (finite) card2
   455   by intro_classes (simp add: one_le_card_finite)
   456 
   457 subsection {* Examples *}
   458 
   459 lemma "CARD(0) = 0" by simp
   460 lemma "CARD(17) = 17" by simp
   461 lemma "8 * 11 ^ 3 - 6 = (2::5)" by simp
   462 
   463 end