src/HOL/Set.ML
author oheimb
Wed Jan 31 10:15:55 2001 +0100 (2001-01-31)
changeset 11008 f7333f055ef6
parent 11007 438f31613093
child 11166 eca861fd1eb5
permissions -rw-r--r--
improved theory reference in comment
     1 (*  Title:      HOL/Set.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 val [prem] = Goal "(!!x. (x:A) = (x:B)) ==> A = B";
    23 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    24 by (rtac Collect_mem_eq 1);
    25 by (rtac Collect_mem_eq 1);
    26 qed "set_ext";
    27 
    28 val [prem] = Goal "(!!x. P(x)=Q(x)) ==> {x. P(x)} = {x. Q(x)}";
    29 by (rtac (prem RS ext RS arg_cong) 1);
    30 qed "Collect_cong";
    31 
    32 bind_thm ("CollectE", make_elim CollectD);
    33 
    34 AddSIs [CollectI];
    35 AddSEs [CollectE];
    36 
    37 
    38 section "Bounded quantifiers";
    39 
    40 val prems = Goalw [Ball_def]
    41     "[| !!x. x:A ==> P(x) |] ==> ALL x:A. P(x)";
    42 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    43 qed "ballI";
    44 
    45 bind_thms ("strip", [impI, allI, ballI]);
    46 
    47 Goalw [Ball_def] "[| ALL x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ALL x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ALL x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 AddXDs [bspec];
    63 (* gives better instantiation for bound: *)
    64 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    65 			 (dtac bspec THEN' atac) APPEND' tac2);
    66 
    67 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    68 Goalw [Bex_def] "[| P(x);  x:A |] ==> EX x:A. P(x)";
    69 by (Blast_tac 1);
    70 qed "bexI";
    71 
    72 (*The best argument order when there is only one x:A*)
    73 Goalw [Bex_def] "[| x:A;  P(x) |] ==> EX x:A. P(x)";
    74 by (Blast_tac 1);
    75 qed "rev_bexI";
    76 
    77 val prems = Goal 
    78    "[| ALL x:A. ~P(x) ==> P(a);  a:A |] ==> EX x:A. P(x)";
    79 by (rtac classical 1);
    80 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    81 qed "bexCI";
    82 
    83 val major::prems = Goalw [Bex_def]
    84     "[| EX x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    85 by (rtac (major RS exE) 1);
    86 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    87 qed "bexE";
    88 
    89 AddIs  [bexI];
    90 AddSEs [bexE];
    91 
    92 (*Trival rewrite rule*)
    93 Goal "(ALL x:A. P) = ((EX x. x:A) --> P)";
    94 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    95 qed "ball_triv";
    96 
    97 (*Dual form for existentials*)
    98 Goal "(EX x:A. P) = ((EX x. x:A) & P)";
    99 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   100 qed "bex_triv";
   101 
   102 Addsimps [ball_triv, bex_triv];
   103 
   104 (** Congruence rules **)
   105 
   106 val prems = Goalw [Ball_def]
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (ALL x:A. P(x)) = (ALL x:B. Q(x))";
   109 by (asm_simp_tac (simpset() addsimps prems) 1);
   110 qed "ball_cong";
   111 
   112 val prems = Goalw [Bex_def]
   113     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   114 \    (EX x:A. P(x)) = (EX x:B. Q(x))";
   115 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   116 qed "bex_cong";
   117 
   118 Addcongs [ball_cong,bex_cong];
   119 
   120 section "Subsets";
   121 
   122 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   123 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   124 qed "subsetI";
   125 
   126 (*Map the type ('a set => anything) to just 'a.
   127   For overloading constants whose first argument has type "'a set" *)
   128 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   129 
   130 (*While (:) is not, its type must be kept
   131   for overloading of = to work.*)
   132 Blast.overloaded ("op :", domain_type);
   133 
   134 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   135 overload_1st_set "Bex";
   136 
   137 (*Image: retain the type of the set being expressed*)
   138 Blast.overloaded ("image", domain_type);
   139 
   140 (*Rule in Modus Ponens style*)
   141 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   142 by (Blast_tac 1);
   143 qed "subsetD";
   144 AddXIs [subsetD];
   145 
   146 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   147 Goal "[| c:A;  A <= B |] ==> c:B";
   148 by (REPEAT (ares_tac [subsetD] 1)) ;
   149 qed "rev_subsetD";
   150 AddXIs [rev_subsetD];
   151 
   152 (*Converts A<=B to x:A ==> x:B*)
   153 fun impOfSubs th = th RSN (2, rev_subsetD);
   154 
   155 (*Classical elimination rule*)
   156 val major::prems = Goalw [subset_def] 
   157     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   158 by (rtac (major RS ballE) 1);
   159 by (REPEAT (eresolve_tac prems 1));
   160 qed "subsetCE";
   161 
   162 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   163 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   164 
   165 AddSIs [subsetI];
   166 AddEs  [subsetD, subsetCE];
   167 
   168 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   169 by (Blast_tac 1);
   170 qed "contra_subsetD";
   171 
   172 Goal "A <= (A::'a set)";
   173 by (Fast_tac 1);
   174 qed "subset_refl";
   175 
   176 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   177 by (Blast_tac 1);
   178 qed "subset_trans";
   179 
   180 
   181 section "Equality";
   182 
   183 (*Anti-symmetry of the subset relation*)
   184 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   185 by (rtac set_ext 1);
   186 by (blast_tac (claset() addIs [subsetD]) 1);
   187 qed "subset_antisym";
   188 bind_thm ("equalityI", subset_antisym);
   189 
   190 AddSIs [equalityI];
   191 
   192 (* Equality rules from ZF set theory -- are they appropriate here? *)
   193 Goal "A = B ==> A<=(B::'a set)";
   194 by (etac ssubst 1);
   195 by (rtac subset_refl 1);
   196 qed "equalityD1";
   197 
   198 Goal "A = B ==> B<=(A::'a set)";
   199 by (etac ssubst 1);
   200 by (rtac subset_refl 1);
   201 qed "equalityD2";
   202 
   203 (*Be careful when adding this to the claset as subset_empty is in the simpset:
   204   A={} goes to {}<=A and A<={} and then back to A={} !*)
   205 val prems = Goal
   206     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   207 by (resolve_tac prems 1);
   208 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   209 qed "equalityE";
   210 
   211 val major::prems = Goal
   212     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   213 by (rtac (major RS equalityE) 1);
   214 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   215 qed "equalityCE";
   216 
   217 AddEs [equalityCE];
   218 
   219 (*Lemma for creating induction formulae -- for "pattern matching" on p
   220   To make the induction hypotheses usable, apply "spec" or "bspec" to
   221   put universal quantifiers over the free variables in p. *)
   222 val prems = Goal 
   223     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   224 by (rtac mp 1);
   225 by (REPEAT (resolve_tac (refl::prems) 1));
   226 qed "setup_induction";
   227 
   228 Goal "A = B ==> (x : A) = (x : B)";
   229 by (Asm_simp_tac 1);
   230 qed "eqset_imp_iff";
   231 
   232 
   233 section "The universal set -- UNIV";
   234 
   235 Goalw [UNIV_def] "x : UNIV";
   236 by (rtac CollectI 1);
   237 by (rtac TrueI 1);
   238 qed "UNIV_I";
   239 
   240 Addsimps [UNIV_I];
   241 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   242 
   243 Goal "EX x. x : UNIV";
   244 by (Simp_tac 1);
   245 qed "UNIV_witness";
   246 AddXIs [UNIV_witness];
   247 
   248 Goal "A <= UNIV";
   249 by (rtac subsetI 1);
   250 by (rtac UNIV_I 1);
   251 qed "subset_UNIV";
   252 
   253 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   254     because of their interaction with congruence rules. **)
   255 
   256 Goalw [Ball_def] "Ball UNIV P = All P";
   257 by (Simp_tac 1);
   258 qed "ball_UNIV";
   259 
   260 Goalw [Bex_def] "Bex UNIV P = Ex P";
   261 by (Simp_tac 1);
   262 qed "bex_UNIV";
   263 Addsimps [ball_UNIV, bex_UNIV];
   264 
   265 
   266 section "The empty set -- {}";
   267 
   268 Goalw [empty_def] "(c : {}) = False";
   269 by (Blast_tac 1) ;
   270 qed "empty_iff";
   271 
   272 Addsimps [empty_iff];
   273 
   274 Goal "a:{} ==> P";
   275 by (Full_simp_tac 1);
   276 qed "emptyE";
   277 
   278 AddSEs [emptyE];
   279 
   280 Goal "{} <= A";
   281 by (Blast_tac 1) ;
   282 qed "empty_subsetI";
   283 
   284 (*One effect is to delete the ASSUMPTION {} <= A*)
   285 AddIffs [empty_subsetI];
   286 
   287 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   288 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   289 qed "equals0I";
   290 
   291 (*Use for reasoning about disjointness: A Int B = {} *)
   292 Goal "A={} ==> a ~: A";
   293 by (Blast_tac 1) ;
   294 qed "equals0D";
   295 
   296 Goalw [Ball_def] "Ball {} P = True";
   297 by (Simp_tac 1);
   298 qed "ball_empty";
   299 
   300 Goalw [Bex_def] "Bex {} P = False";
   301 by (Simp_tac 1);
   302 qed "bex_empty";
   303 Addsimps [ball_empty, bex_empty];
   304 
   305 Goal "UNIV ~= {}";
   306 by (blast_tac (claset() addEs [equalityE]) 1);
   307 qed "UNIV_not_empty";
   308 AddIffs [UNIV_not_empty];
   309 
   310 
   311 
   312 section "The Powerset operator -- Pow";
   313 
   314 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   315 by (Asm_simp_tac 1);
   316 qed "Pow_iff";
   317 
   318 AddIffs [Pow_iff]; 
   319 
   320 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   321 by (etac CollectI 1);
   322 qed "PowI";
   323 
   324 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   325 by (etac CollectD 1);
   326 qed "PowD";
   327 
   328 
   329 bind_thm ("Pow_bottom", empty_subsetI RS PowI);        (* {}: Pow(B) *)
   330 bind_thm ("Pow_top", subset_refl RS PowI);             (* A : Pow(A) *)
   331 
   332 
   333 section "Set complement";
   334 
   335 Goalw [Compl_def] "(c : -A) = (c~:A)";
   336 by (Blast_tac 1);
   337 qed "Compl_iff";
   338 
   339 Addsimps [Compl_iff];
   340 
   341 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   342 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   343 qed "ComplI";
   344 
   345 (*This form, with negated conclusion, works well with the Classical prover.
   346   Negated assumptions behave like formulae on the right side of the notional
   347   turnstile...*)
   348 Goalw [Compl_def] "c : -A ==> c~:A";
   349 by (etac CollectD 1);
   350 qed "ComplD";
   351 
   352 bind_thm ("ComplE", make_elim ComplD);
   353 
   354 AddSIs [ComplI];
   355 AddSEs [ComplE];
   356 
   357 
   358 section "Binary union -- Un";
   359 
   360 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   361 by (Blast_tac 1);
   362 qed "Un_iff";
   363 Addsimps [Un_iff];
   364 
   365 Goal "c:A ==> c : A Un B";
   366 by (Asm_simp_tac 1);
   367 qed "UnI1";
   368 
   369 Goal "c:B ==> c : A Un B";
   370 by (Asm_simp_tac 1);
   371 qed "UnI2";
   372 
   373 AddXIs [UnI1, UnI2];
   374 
   375 
   376 (*Classical introduction rule: no commitment to A vs B*)
   377 
   378 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   379 by (Simp_tac 1);
   380 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   381 qed "UnCI";
   382 
   383 val major::prems = Goalw [Un_def]
   384     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   385 by (rtac (major RS CollectD RS disjE) 1);
   386 by (REPEAT (eresolve_tac prems 1));
   387 qed "UnE";
   388 
   389 AddSIs [UnCI];
   390 AddSEs [UnE];
   391 
   392 
   393 section "Binary intersection -- Int";
   394 
   395 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   396 by (Blast_tac 1);
   397 qed "Int_iff";
   398 Addsimps [Int_iff];
   399 
   400 Goal "[| c:A;  c:B |] ==> c : A Int B";
   401 by (Asm_simp_tac 1);
   402 qed "IntI";
   403 
   404 Goal "c : A Int B ==> c:A";
   405 by (Asm_full_simp_tac 1);
   406 qed "IntD1";
   407 
   408 Goal "c : A Int B ==> c:B";
   409 by (Asm_full_simp_tac 1);
   410 qed "IntD2";
   411 
   412 val [major,minor] = Goal
   413     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   414 by (rtac minor 1);
   415 by (rtac (major RS IntD1) 1);
   416 by (rtac (major RS IntD2) 1);
   417 qed "IntE";
   418 
   419 AddSIs [IntI];
   420 AddSEs [IntE];
   421 
   422 section "Set difference";
   423 
   424 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   425 by (Blast_tac 1);
   426 qed "Diff_iff";
   427 Addsimps [Diff_iff];
   428 
   429 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   430 by (Asm_simp_tac 1) ;
   431 qed "DiffI";
   432 
   433 Goal "c : A - B ==> c : A";
   434 by (Asm_full_simp_tac 1) ;
   435 qed "DiffD1";
   436 
   437 Goal "[| c : A - B;  c : B |] ==> P";
   438 by (Asm_full_simp_tac 1) ;
   439 qed "DiffD2";
   440 
   441 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   442 by (resolve_tac prems 1);
   443 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   444 qed "DiffE";
   445 
   446 AddSIs [DiffI];
   447 AddSEs [DiffE];
   448 
   449 
   450 section "Augmenting a set -- insert";
   451 
   452 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   453 by (Blast_tac 1);
   454 qed "insert_iff";
   455 Addsimps [insert_iff];
   456 
   457 Goal "a : insert a B";
   458 by (Simp_tac 1);
   459 qed "insertI1";
   460 
   461 Goal "!!a. a : B ==> a : insert b B";
   462 by (Asm_simp_tac 1);
   463 qed "insertI2";
   464 
   465 val major::prems = Goalw [insert_def]
   466     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   467 by (rtac (major RS UnE) 1);
   468 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   469 qed "insertE";
   470 
   471 (*Classical introduction rule*)
   472 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   473 by (Simp_tac 1);
   474 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   475 qed "insertCI";
   476 
   477 AddSIs [insertCI]; 
   478 AddSEs [insertE];
   479 
   480 Goal "(A <= insert x B) = (if x:A then A-{x} <= B else A<=B)";
   481 by Auto_tac; 
   482 qed "subset_insert_iff";
   483 
   484 section "Singletons, using insert";
   485 
   486 Goal "a : {a}";
   487 by (rtac insertI1 1) ;
   488 qed "singletonI";
   489 
   490 Goal "b : {a} ==> b=a";
   491 by (Blast_tac 1);
   492 qed "singletonD";
   493 
   494 bind_thm ("singletonE", make_elim singletonD);
   495 
   496 Goal "(b : {a}) = (b=a)";
   497 by (Blast_tac 1);
   498 qed "singleton_iff";
   499 
   500 Goal "{a}={b} ==> a=b";
   501 by (blast_tac (claset() addEs [equalityE]) 1);
   502 qed "singleton_inject";
   503 
   504 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   505 AddSIs [singletonI];   
   506 AddSDs [singleton_inject];
   507 AddSEs [singletonE];
   508 
   509 Goal "{b} = insert a A = (a = b & A <= {b})";
   510 by (blast_tac (claset() addSEs [equalityE]) 1);
   511 qed "singleton_insert_inj_eq";
   512 
   513 Goal "(insert a A = {b}) = (a = b & A <= {b})";
   514 by (blast_tac (claset() addSEs [equalityE]) 1);
   515 qed "singleton_insert_inj_eq'";
   516 
   517 AddIffs [singleton_insert_inj_eq, singleton_insert_inj_eq'];
   518 
   519 Goal "A <= {x} ==> A={} | A = {x}";
   520 by (Fast_tac 1);
   521 qed "subset_singletonD";
   522 
   523 Goal "{x. x=a} = {a}";
   524 by (Blast_tac 1);
   525 qed "singleton_conv";
   526 Addsimps [singleton_conv];
   527 
   528 Goal "{x. a=x} = {a}";
   529 by (Blast_tac 1);
   530 qed "singleton_conv2";
   531 Addsimps [singleton_conv2];
   532 
   533 Goal "[| A - {x} <= B; x : A |] ==> A <= insert x B"; 
   534 by(Blast_tac 1);
   535 qed "diff_single_insert";
   536 
   537 
   538 section "Unions of families -- UNION x:A. B(x) is Union(B`A)";
   539 
   540 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   541 by (Blast_tac 1);
   542 qed "UN_iff";
   543 
   544 Addsimps [UN_iff];
   545 
   546 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   547 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   548 by Auto_tac;
   549 qed "UN_I";
   550 
   551 val major::prems = Goalw [UNION_def]
   552     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   553 by (rtac (major RS CollectD RS bexE) 1);
   554 by (REPEAT (ares_tac prems 1));
   555 qed "UN_E";
   556 
   557 AddIs  [UN_I];
   558 AddSEs [UN_E];
   559 
   560 val prems = Goalw [UNION_def]
   561     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   562 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   563 by (asm_simp_tac (simpset() addsimps prems) 1);
   564 qed "UN_cong";
   565 Addcongs [UN_cong];
   566 
   567 
   568 section "Intersections of families -- INTER x:A. B(x) is Inter(B`A)";
   569 
   570 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   571 by Auto_tac;
   572 qed "INT_iff";
   573 
   574 Addsimps [INT_iff];
   575 
   576 val prems = Goalw [INTER_def]
   577     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   578 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   579 qed "INT_I";
   580 
   581 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   582 by Auto_tac;
   583 qed "INT_D";
   584 
   585 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   586 val major::prems = Goalw [INTER_def]
   587     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   588 by (rtac (major RS CollectD RS ballE) 1);
   589 by (REPEAT (eresolve_tac prems 1));
   590 qed "INT_E";
   591 
   592 AddSIs [INT_I];
   593 AddEs  [INT_D, INT_E];
   594 
   595 val prems = Goalw [INTER_def]
   596     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   597 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   598 by (asm_simp_tac (simpset() addsimps prems) 1);
   599 qed "INT_cong";
   600 Addcongs [INT_cong];
   601 
   602 
   603 section "Union";
   604 
   605 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   606 by (Blast_tac 1);
   607 qed "Union_iff";
   608 
   609 Addsimps [Union_iff];
   610 
   611 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   612 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   613 by Auto_tac;
   614 qed "UnionI";
   615 
   616 val major::prems = Goalw [Union_def]
   617     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   618 by (rtac (major RS UN_E) 1);
   619 by (REPEAT (ares_tac prems 1));
   620 qed "UnionE";
   621 
   622 AddIs  [UnionI];
   623 AddSEs [UnionE];
   624 
   625 
   626 section "Inter";
   627 
   628 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   629 by (Blast_tac 1);
   630 qed "Inter_iff";
   631 
   632 Addsimps [Inter_iff];
   633 
   634 val prems = Goalw [Inter_def]
   635     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   636 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   637 qed "InterI";
   638 
   639 (*A "destruct" rule -- every X in C contains A as an element, but
   640   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   641 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   642 by Auto_tac;
   643 qed "InterD";
   644 
   645 (*"Classical" elimination rule -- does not require proving X:C *)
   646 val major::prems = Goalw [Inter_def]
   647     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   648 by (rtac (major RS INT_E) 1);
   649 by (REPEAT (eresolve_tac prems 1));
   650 qed "InterE";
   651 
   652 AddSIs [InterI];
   653 AddEs  [InterD, InterE];
   654 
   655 
   656 (*** Image of a set under a function ***)
   657 
   658 (*Frequently b does not have the syntactic form of f(x).*)
   659 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f`A";
   660 by (Blast_tac 1);
   661 qed "image_eqI";
   662 Addsimps [image_eqI];
   663 
   664 bind_thm ("imageI", refl RS image_eqI);
   665 
   666 (*This version's more effective when we already have the required x*)
   667 Goalw [image_def] "[| x:A;  b=f(x) |] ==> b : f`A";
   668 by (Blast_tac 1);
   669 qed "rev_image_eqI";
   670 
   671 (*The eta-expansion gives variable-name preservation.*)
   672 val major::prems = Goalw [image_def]
   673     "[| b : (%x. f(x))`A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   674 by (rtac (major RS CollectD RS bexE) 1);
   675 by (REPEAT (ares_tac prems 1));
   676 qed "imageE";
   677 
   678 AddIs  [image_eqI];
   679 AddSEs [imageE]; 
   680 
   681 Goal "f`(A Un B) = f`A Un f`B";
   682 by (Blast_tac 1);
   683 qed "image_Un";
   684 
   685 Goal "(z : f`A) = (EX x:A. z = f x)";
   686 by (Blast_tac 1);
   687 qed "image_iff";
   688 
   689 (*This rewrite rule would confuse users if made default.*)
   690 Goal "(f`A <= B) = (ALL x:A. f(x): B)";
   691 by (Blast_tac 1);
   692 qed "image_subset_iff";
   693 
   694 Goal "B <= f ` A = (? AA. AA <= A & B = f ` AA)";
   695 by Safe_tac;
   696 by  (Fast_tac 2);
   697 by (res_inst_tac [("x","{a. a : A & f a : B}")] exI 1);
   698 by (Fast_tac 1);
   699 qed "subset_image_iff";
   700 
   701 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   702   many existing proofs.*)
   703 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f`A <= B";
   704 by (blast_tac (claset() addIs prems) 1);
   705 qed "image_subsetI";
   706 
   707 (*** Range of a function -- just a translation for image! ***)
   708 
   709 Goal "b=f(x) ==> b : range(f)";
   710 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   711 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   712 
   713 bind_thm ("rangeI", UNIV_I RS imageI);
   714 
   715 val [major,minor] = Goal 
   716     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   717 by (rtac (major RS imageE) 1);
   718 by (etac minor 1);
   719 qed "rangeE";
   720 AddXEs [rangeE];
   721 
   722 
   723 (*** Set reasoning tools ***)
   724 
   725 
   726 (** Rewrite rules for boolean case-splitting: faster than 
   727 	addsplits[split_if]
   728 **)
   729 
   730 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   731 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   732 
   733 (*Split ifs on either side of the membership relation.
   734 	Not for Addsimps -- can cause goals to blow up!*)
   735 bind_thm ("split_if_mem1", inst "P" "%x. x : ?b" split_if);
   736 bind_thm ("split_if_mem2", inst "P" "%x. ?a : x" split_if);
   737 
   738 bind_thms ("split_ifs", [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   739 			 split_if_mem1, split_if_mem2]);
   740 
   741 
   742 (*Each of these has ALREADY been added to simpset() above.*)
   743 bind_thms ("mem_simps", [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   744                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff]);
   745 
   746 (*Would like to add these, but the existing code only searches for the 
   747   outer-level constant, which in this case is just "op :"; we instead need
   748   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   749   apply, then the formula should be kept.
   750   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]), 
   751    ("op Int", [IntD1,IntD2]),
   752    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   753  *)
   754 val mksimps_pairs =
   755   [("Ball",[bspec])] @ mksimps_pairs;
   756 
   757 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   758 
   759 Addsimps[subset_UNIV, subset_refl];
   760 
   761 
   762 (*** The 'proper subset' relation (<) ***)
   763 
   764 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   765 by (Blast_tac 1);
   766 qed "psubsetI";
   767 AddSIs [psubsetI];
   768 
   769 Goalw [psubset_def]
   770   "(A < insert x B) = (if x:B then A<B else if x:A then A-{x} < B else A<=B)";
   771 by (asm_simp_tac (simpset() addsimps [subset_insert_iff]) 1);
   772 by (Blast_tac 1); 
   773 qed "psubset_insert_iff";
   774 
   775 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   776 
   777 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   778 
   779 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   780 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   781 qed "psubset_subset_trans";
   782 
   783 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   784 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   785 qed "subset_psubset_trans";
   786 
   787 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   788 by (Blast_tac 1);
   789 qed "psubset_imp_ex_mem";
   790 
   791 
   792 (* rulify setup *)
   793 
   794 Goal "(!!x. x:A ==> P x) == Trueprop (ALL x:A. P x)";
   795 by (simp_tac (simpset () addsimps (Ball_def :: thms "atomize")) 1);
   796 qed "ball_eq";
   797 
   798 local
   799   val ss = HOL_basic_ss addsimps
   800     (Drule.norm_hhf_eq :: map Thm.symmetric (ball_eq :: thms "atomize"));
   801 in
   802 
   803 structure Rulify = RulifyFun
   804  (val make_meta = Simplifier.simplify ss
   805   val full_make_meta = Simplifier.full_simplify ss);
   806 
   807 structure BasicRulify: BASIC_RULIFY = Rulify;
   808 open BasicRulify;
   809 
   810 end;