src/Pure/Isar/proof.ML
author wenzelm
Mon Apr 17 14:04:46 2000 +0200 (2000-04-17)
changeset 8722 f745b34dcde3
parent 8718 3ba75b7e1168
child 8807 0046be1769f9
permissions -rw-r--r--
tuned msg;
     1 (*  Title:      Pure/Isar/proof.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Proof states and methods.
     6 *)
     7 
     8 signature BASIC_PROOF =
     9 sig
    10   val FINDGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    11   val HEADGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    12 end;
    13 
    14 signature PROOF =
    15 sig
    16   include BASIC_PROOF
    17   type context
    18   type state
    19   exception STATE of string * state
    20   val check_result: string -> state -> 'a Seq.seq -> 'a Seq.seq
    21   val init_state: theory -> state
    22   val context_of: state -> context
    23   val theory_of: state -> theory
    24   val sign_of: state -> Sign.sg
    25   val warn_extra_tfrees: state -> state -> state
    26   val reset_thms: string -> state -> state
    27   val the_facts: state -> thm list
    28   val get_goal: state -> term * (thm list * thm)
    29   val goal_facts: (state -> thm list) -> state -> state
    30   val use_facts: state -> state
    31   val reset_facts: state -> state
    32   val assert_forward: state -> state
    33   val assert_backward: state -> state
    34   val assert_no_chain: state -> state
    35   val enter_forward: state -> state
    36   val show_hyps: bool ref
    37   val pretty_thm: thm -> Pretty.T
    38   val pretty_thms: thm list -> Pretty.T
    39   val verbose: bool ref
    40   val print_state: int -> state -> unit
    41   val level: state -> int
    42   type method
    43   val method: (thm list -> tactic) -> method
    44   val method_cases: (thm list -> thm -> (thm * (string * RuleCases.T) list) Seq.seq) -> method
    45   val refine: (context -> method) -> state -> state Seq.seq
    46   val refine_end: (context -> method) -> state -> state Seq.seq
    47   val export_thm: context -> thm -> thm
    48   val match_bind: (string list * string) list -> state -> state
    49   val match_bind_i: (term list * term) list -> state -> state
    50   val let_bind: (string list * string) list -> state -> state
    51   val let_bind_i: (term list * term) list -> state -> state
    52   val have_thmss: thm list -> string -> context attribute list ->
    53     (thm list * context attribute list) list -> state -> state
    54   val simple_have_thms: string -> thm list -> state -> state
    55   val fix: (string list * string option) list -> state -> state
    56   val fix_i: (string list * typ option) list -> state -> state
    57   val assm: (int -> tactic) * (int -> tactic)
    58     -> (string * context attribute list * (string * (string list * string list)) list) list
    59     -> state -> state
    60   val assm_i: (int -> tactic) * (int -> tactic)
    61     -> (string * context attribute list * (term * (term list * term list)) list) list
    62     -> state -> state
    63   val assume: (string * context attribute list * (string * (string list * string list)) list) list
    64     -> state -> state
    65   val assume_i: (string * context attribute list * (term * (term list * term list)) list) list
    66     -> state -> state
    67   val presume: (string * context attribute list * (string * (string list * string list)) list) list
    68     -> state -> state
    69   val presume_i: (string * context attribute list * (term * (term list * term list)) list) list
    70     -> state -> state
    71   val invoke_case: string * context attribute list -> state -> state
    72   val theorem: bstring -> theory attribute list -> string * (string list * string list)
    73     -> theory -> state
    74   val theorem_i: bstring -> theory attribute list -> term * (term list * term list)
    75     -> theory -> state
    76   val lemma: bstring -> theory attribute list -> string * (string list * string list)
    77     -> theory -> state
    78   val lemma_i: bstring -> theory attribute list -> term * (term list * term list)
    79     -> theory -> state
    80   val chain: state -> state
    81   val from_facts: thm list -> state -> state
    82   val show: (state -> state Seq.seq) -> string -> context attribute list
    83     -> string * (string list * string list) -> state -> state
    84   val show_i: (state -> state Seq.seq) -> string -> context attribute list
    85     -> term * (term list * term list) -> state -> state
    86   val have: (state -> state Seq.seq) -> string -> context attribute list
    87     -> string * (string list * string list) -> state -> state
    88   val have_i: (state -> state Seq.seq) -> string -> context attribute list
    89     -> term * (term list * term list) -> state -> state
    90   val at_bottom: state -> bool
    91   val local_qed: (state -> state Seq.seq)
    92     -> ({kind: string, name: string, thm: thm} -> unit) * (thm -> unit) -> state -> state Seq.seq
    93   val global_qed: (state -> state Seq.seq) -> state
    94     -> (theory * {kind: string, name: string, thm: thm}) Seq.seq
    95   val begin_block: state -> state
    96   val end_block: state -> state Seq.seq
    97   val next_block: state -> state
    98 end;
    99 
   100 signature PRIVATE_PROOF =
   101 sig
   102   include PROOF
   103   val put_data: Object.kind -> ('a -> Object.T) -> 'a -> state -> state
   104 end;
   105 
   106 structure Proof: PRIVATE_PROOF =
   107 struct
   108 
   109 
   110 (** proof state **)
   111 
   112 type context = ProofContext.context;
   113 
   114 
   115 (* type goal *)
   116 
   117 datatype kind =
   118   Theorem of theory attribute list |    (*top-level theorem*)
   119   Lemma of theory attribute list |      (*top-level lemma*)
   120   Goal of context attribute list |      (*intermediate result, solving subgoal*)
   121   Aux of context attribute list ;       (*intermediate result*)
   122 
   123 val kind_name =
   124   fn Theorem _ => "theorem" | Lemma _ => "lemma" | Goal _ => "show" | Aux _ => "have";
   125 
   126 type goal =
   127  (kind *        (*result kind*)
   128   string *      (*result name*)
   129   term) *       (*result statement*)
   130  (thm list *    (*use facts*)
   131   thm);         (*goal: subgoals ==> statement*)
   132 
   133 
   134 (* type mode *)
   135 
   136 datatype mode = Forward | ForwardChain | Backward;
   137 val mode_name = (fn Forward => "state" | ForwardChain => "chain" | Backward => "prove");
   138 
   139 
   140 (* datatype state *)
   141 
   142 datatype node =
   143   Node of
   144    {context: context,
   145     facts: thm list option,
   146     mode: mode,
   147     goal: (goal * (state -> state Seq.seq)) option}
   148 and state =
   149   State of
   150     node *              (*current*)
   151     node list;          (*parents wrt. block structure*)
   152 
   153 fun make_node (context, facts, mode, goal) =
   154   Node {context = context, facts = facts, mode = mode, goal = goal};
   155 
   156 
   157 exception STATE of string * state;
   158 
   159 fun err_malformed name state =
   160   raise STATE (name ^ ": internal error -- malformed proof state", state);
   161 
   162 fun check_result msg state sq =
   163   (case Seq.pull sq of
   164     None => raise STATE (msg, state)
   165   | Some s_sq => Seq.cons s_sq);
   166 
   167 
   168 fun map_current f (State (Node {context, facts, mode, goal}, nodes)) =
   169   State (make_node (f (context, facts, mode, goal)), nodes);
   170 
   171 fun init_state thy =
   172   State (make_node (ProofContext.init thy, None, Forward, None), []);
   173 
   174 
   175 
   176 (** basic proof state operations **)
   177 
   178 (* context *)
   179 
   180 fun context_of (State (Node {context, ...}, _)) = context;
   181 val theory_of = ProofContext.theory_of o context_of;
   182 val sign_of = ProofContext.sign_of o context_of;
   183 
   184 fun map_context f = map_current (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   185 
   186 fun map_context_result f (state as State (Node {context, facts, mode, goal}, nodes)) =
   187   let val (context', result) = f context
   188   in (State (make_node (context', facts, mode, goal), nodes), result) end;
   189 
   190 
   191 fun put_data kind f = map_context o ProofContext.put_data kind f;
   192 val warn_extra_tfrees = map_context o ProofContext.warn_extra_tfrees o context_of;
   193 val auto_bind_goal = map_context o ProofContext.auto_bind_goal;
   194 val auto_bind_facts = map_context oo ProofContext.auto_bind_facts;
   195 val put_thms = map_context o ProofContext.put_thms;
   196 val put_thmss = map_context o ProofContext.put_thmss;
   197 val reset_thms = map_context o ProofContext.reset_thms;
   198 val assumptions = ProofContext.assumptions o context_of;
   199 val get_case = ProofContext.get_case o context_of;
   200 
   201 
   202 (* facts *)
   203 
   204 fun the_facts (State (Node {facts = Some facts, ...}, _)) = facts
   205   | the_facts state = raise STATE ("No current facts available", state);
   206 
   207 fun assert_facts state = (the_facts state; state);
   208 fun get_facts (State (Node {facts, ...}, _)) = facts;
   209 
   210 
   211 val thisN = "this";
   212 
   213 fun put_facts facts state =
   214   state
   215   |> map_current (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal))
   216   |> (case facts of None => reset_thms thisN | Some ths => put_thms (thisN, ths));
   217 
   218 val reset_facts = put_facts None;
   219 
   220 fun have_facts (name, facts) state =
   221   state
   222   |> put_facts (Some facts)
   223   |> put_thms (name, facts);
   224 
   225 fun these_facts (state, ths) = have_facts ths state;
   226 
   227 
   228 (* goal *)
   229 
   230 fun find_goal i (state as State (Node {goal = Some goal, ...}, _)) = (context_of state, (i, goal))
   231   | find_goal i (State (Node {goal = None, ...}, node :: nodes)) =
   232       find_goal (i + 1) (State (node, nodes))
   233   | find_goal _ (state as State (_, [])) = err_malformed "find_goal" state;
   234 
   235 fun get_goal state =
   236   let val (_, (_, (((_, _, t), goal), _))) = find_goal 0 state
   237   in (t, goal) end;
   238 
   239 fun put_goal goal = map_current (fn (ctxt, facts, mode, _) => (ctxt, facts, mode, goal));
   240 
   241 fun map_goal f g (State (Node {context, facts, mode, goal = Some goal}, nodes)) =
   242       State (make_node (f context, facts, mode, Some (g goal)), nodes)
   243   | map_goal f g (State (nd, node :: nodes)) =
   244       let val State (node', nodes') = map_goal f g (State (node, nodes))
   245       in map_context f (State (nd, node' :: nodes')) end
   246   | map_goal _ _ state = state;
   247 
   248 fun goal_facts get state =
   249   state
   250   |> map_goal I (fn ((result, (_, thm)), f) => ((result, (get state, thm)), f));
   251 
   252 fun use_facts state =
   253   state
   254   |> goal_facts the_facts
   255   |> reset_facts;
   256 
   257 
   258 (* mode *)
   259 
   260 fun get_mode (State (Node {mode, ...}, _)) = mode;
   261 fun put_mode mode = map_current (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   262 
   263 val enter_forward = put_mode Forward;
   264 val enter_forward_chain = put_mode ForwardChain;
   265 val enter_backward = put_mode Backward;
   266 
   267 fun assert_mode pred state =
   268   let val mode = get_mode state in
   269     if pred mode then state
   270     else raise STATE ("Illegal application of proof command in " ^ mode_name mode ^ " mode", state)
   271   end;
   272 
   273 fun is_chain state = get_mode state = ForwardChain;
   274 val assert_forward = assert_mode (equal Forward);
   275 val assert_forward_or_chain = assert_mode (equal Forward orf equal ForwardChain);
   276 val assert_backward = assert_mode (equal Backward);
   277 val assert_no_chain = assert_mode (not_equal ForwardChain);
   278 
   279 
   280 (* blocks *)
   281 
   282 fun level (State (_, nodes)) = length nodes;
   283 
   284 fun open_block (State (node, nodes)) = State (node, node :: nodes);
   285 
   286 fun new_block state =
   287   state
   288   |> open_block
   289   |> put_goal None;
   290 
   291 fun close_block (state as State (_, node :: nodes)) = State (node, nodes)
   292   | close_block state = raise STATE ("Unbalanced block parentheses", state);
   293 
   294 
   295 
   296 (** print_state **)
   297 
   298 val show_hyps = ProofContext.show_hyps;
   299 val pretty_thm = ProofContext.pretty_thm;
   300 
   301 fun pretty_thms [th] = pretty_thm th
   302   | pretty_thms ths = Pretty.blk (0, Pretty.fbreaks (map pretty_thm ths));
   303 
   304 
   305 val verbose = ProofContext.verbose;
   306 
   307 fun pretty_facts _ None = []
   308   | pretty_facts s (Some ths) =
   309       [Pretty.big_list (s ^ "this:") (map pretty_thm ths), Pretty.str ""];
   310 
   311 fun print_state nr (state as State (Node {context, facts, mode, goal = _}, nodes)) =
   312   let
   313     val ref (_, _, begin_goal) = Goals.current_goals_markers;
   314 
   315     fun levels_up 0 = ""
   316       | levels_up 1 = ", 1 level up"
   317       | levels_up i = ", " ^ string_of_int i ^ " levels up";
   318 
   319     fun pretty_goal (_, (i, (((kind, name, _), (goal_facts, thm)), _))) =
   320       pretty_facts "using "
   321         (if mode <> Backward orelse null goal_facts then None else Some goal_facts) @
   322       [Pretty.str ("goal (" ^ kind_name kind ^ (if name = "" then "" else " " ^ name) ^
   323         levels_up (i div 2) ^ "):")] @
   324       Locale.pretty_goals_marker begin_goal (! goals_limit) thm;
   325 
   326     val ctxt_prts =
   327       if ! verbose orelse mode = Forward then ProofContext.pretty_context context
   328       else if mode = Backward then ProofContext.pretty_prems context
   329       else [];
   330 
   331     val prts =
   332      [Pretty.str ("proof (" ^ mode_name mode ^ "): step " ^ string_of_int nr ^
   333         (if ! verbose then ", depth " ^ string_of_int (length nodes div 2)
   334         else "")), Pretty.str ""] @
   335      (if null ctxt_prts then [] else ctxt_prts @ [Pretty.str ""]) @
   336      (if ! verbose orelse mode = Forward then
   337        (pretty_facts "" facts @ pretty_goal (find_goal 0 state))
   338       else if mode = ForwardChain then pretty_facts "picking " facts
   339       else pretty_goal (find_goal 0 state))
   340   in Pretty.writeln (Pretty.chunks prts) end;
   341 
   342 
   343 
   344 (** proof steps **)
   345 
   346 (* datatype method *)
   347 
   348 datatype method =
   349   Method of thm list -> thm -> (thm * (string * RuleCases.T) list) Seq.seq;
   350 
   351 fun method tac = Method (fn facts => fn st => Seq.map (rpair []) (tac facts st));
   352 val method_cases = Method;
   353 
   354 
   355 (* refine goal *)
   356 
   357 local
   358 
   359 fun check_sign sg state =
   360   if Sign.subsig (sg, sign_of state) then state
   361   else raise STATE ("Bad signature of result: " ^ Sign.str_of_sg sg, state);
   362 
   363 fun gen_refine current_context meth_fun state =
   364   let
   365     val (goal_ctxt, (_, ((result, (facts, thm)), f))) = find_goal 0 state;
   366     val Method meth = meth_fun (if current_context then context_of state else goal_ctxt);
   367 
   368     fun refn (thm', cases) =
   369       state
   370       |> check_sign (Thm.sign_of_thm thm')
   371       |> map_goal (ProofContext.add_cases cases) (K ((result, (facts, thm')), f));
   372   in Seq.map refn (meth facts thm) end;
   373 
   374 in
   375 
   376 val refine = gen_refine true;
   377 val refine_end = gen_refine false;
   378 
   379 end;
   380 
   381 
   382 (* export results *)
   383 
   384 fun RANGE [] _ = all_tac
   385   | RANGE (tac :: tacs) i = RANGE tacs (i + 1) THEN tac i;
   386 
   387 fun FINDGOAL tac st =
   388   let fun find (i, n) = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1, n))
   389   in find (1, Thm.nprems_of st) st end;
   390 
   391 fun HEADGOAL tac = tac 1;
   392 
   393 fun export_goal print_rule raw_rule inner state =
   394   let
   395     val (outer, (_, ((result, (facts, thm)), f))) = find_goal 0 state;
   396     val (exp, tacs) = ProofContext.export_wrt inner (Some outer);
   397     val rule = exp raw_rule;
   398     val _ = print_rule rule;
   399     val thmq = FINDGOAL (Tactic.rtac rule THEN' RANGE (map #1 tacs)) thm;
   400   in Seq.map (fn th => map_goal I (K ((result, (facts, th)), f)) state) thmq end;
   401 
   402 
   403 fun export_thm inner thm =
   404   let val (exp, tacs) = ProofContext.export_wrt inner None in
   405     (case Seq.chop (2, RANGE (map #2 tacs) 1 (exp thm)) of
   406       ([thm'], _) => thm'
   407     | ([], _) => raise THM ("export: failed", 0, [thm])
   408     | _ => raise THM ("export: more than one result", 0, [thm]))
   409   end;
   410 
   411 fun transfer_facts inner_state state =
   412   (case get_facts inner_state of
   413     None => Seq.single (reset_facts state)
   414   | Some thms =>
   415       let
   416         val (exp, tacs) =
   417           ProofContext.export_wrt (context_of inner_state) (Some (context_of state));
   418         val thmqs = map (RANGE (map #2 tacs) 1 o exp) thms;
   419       in Seq.map (fn ths => put_facts (Some ths) state) (Seq.commute thmqs) end);
   420 
   421 
   422 (* prepare result *)
   423 
   424 fun prep_result state t raw_thm =
   425   let
   426     val ctxt = context_of state;
   427     fun err msg = raise STATE (msg, state);
   428 
   429     val ngoals = Thm.nprems_of raw_thm;
   430     val _ =
   431       if ngoals = 0 then ()
   432       else (Locale.print_goals ngoals raw_thm; err (string_of_int ngoals ^ " unsolved goal(s)!"));
   433 
   434     val thm = raw_thm RS Drule.rev_triv_goal;
   435     val {hyps, prop, sign, ...} = Thm.rep_thm thm;
   436     val tsig = Sign.tsig_of sign;
   437 
   438     val casms = map #1 (assumptions state);
   439     val bad_hyps = Library.gen_rems Term.aconv (hyps, map (Thm.term_of o Drule.mk_cgoal) casms);
   440   in
   441     if not (null bad_hyps) then
   442       err ("Additional hypotheses:\n" ^ cat_lines (map (Sign.string_of_term sign) bad_hyps))
   443     else if not (t aconv prop) then
   444       err ("Proved a different theorem: " ^ Sign.string_of_term sign prop)
   445     else thm
   446   end;
   447 
   448 
   449 
   450 (*** structured proof commands ***)
   451 
   452 (** context **)
   453 
   454 (* bind *)
   455 
   456 fun gen_bind f x state =
   457   state
   458   |> assert_forward
   459   |> map_context (f x)
   460   |> reset_facts;
   461 
   462 val match_bind = gen_bind (ProofContext.match_bind false);
   463 val match_bind_i = gen_bind (ProofContext.match_bind_i false);
   464 val let_bind = gen_bind (ProofContext.match_bind true);
   465 val let_bind_i = gen_bind (ProofContext.match_bind_i true);
   466 
   467 
   468 (* have_thmss *)
   469 
   470 fun have_thmss ths name atts ths_atts state =
   471   state
   472   |> assert_forward
   473   |> map_context_result (ProofContext.have_thmss ths name atts ths_atts)
   474   |> these_facts;
   475 
   476 fun simple_have_thms name thms = have_thmss [] name [] [(thms, [])];
   477 
   478 
   479 (* fix *)
   480 
   481 fun gen_fix f xs state =
   482   state
   483   |> assert_forward
   484   |> map_context (f xs)
   485   |> reset_facts;
   486 
   487 val fix = gen_fix ProofContext.fix;
   488 val fix_i = gen_fix ProofContext.fix_i;
   489 
   490 
   491 (* assume *)
   492 
   493 local
   494 
   495 fun gen_assume f tac args state =
   496   state
   497   |> assert_forward
   498   |> map_context_result (f tac args)
   499   |> (fn (st, (factss, prems)) =>
   500     foldl these_facts (st, factss)
   501     |> put_thms ("prems", prems)
   502     |> put_facts (Some (flat (map #2 factss))));
   503 
   504 val hard_asm_tac = Tactic.etac Drule.triv_goal;
   505 val soft_asm_tac = Tactic.rtac Drule.triv_goal
   506   THEN' Tactic.rtac asm_rl;     (* FIXME hack to norm goal *)
   507 
   508 in
   509 
   510 val assm = gen_assume ProofContext.assume;
   511 val assm_i = gen_assume ProofContext.assume_i;
   512 val assume = assm (hard_asm_tac, soft_asm_tac);
   513 val assume_i = assm_i (hard_asm_tac, soft_asm_tac);
   514 val presume = assm (soft_asm_tac, soft_asm_tac);
   515 val presume_i = assm_i (soft_asm_tac, soft_asm_tac);
   516 
   517 end;
   518 
   519 
   520 (* invoke_case *)
   521 
   522 fun invoke_case (name, atts) state =
   523   let val (vars, props) = get_case state name in
   524     state
   525     |> fix_i (map (fn (x, T) => ([x], Some T)) vars)
   526     |> assume_i [(name, atts, map (fn t => (t, ([], []))) props)]
   527   end;
   528 
   529 
   530 
   531 (** goals **)
   532 
   533 (* forward chaining *)
   534 
   535 fun chain state =
   536   state
   537   |> assert_forward
   538   |> assert_facts
   539   |> enter_forward_chain;
   540 
   541 fun from_facts facts state =
   542   state
   543   |> put_facts (Some facts)
   544   |> chain;
   545 
   546 
   547 (* setup goals *)
   548 
   549 fun setup_goal opt_block prepp kind after_qed name atts raw_propp state =
   550   let
   551     val (state', (prop, gen_binds)) =
   552       state
   553       |> assert_forward_or_chain
   554       |> enter_forward
   555       |> opt_block
   556       |> map_context_result (fn ct => prepp (ct, raw_propp));
   557     val cprop = Thm.cterm_of (sign_of state') prop;
   558     val goal = Drule.mk_triv_goal cprop;
   559   in
   560     state'
   561     |> put_goal (Some (((kind atts, name, prop), ([], goal)), after_qed o map_context gen_binds))
   562     |> auto_bind_goal prop
   563     |> (if is_chain state then use_facts else reset_facts)
   564     |> new_block
   565     |> enter_backward
   566   end;
   567 
   568 
   569 (*global goals*)
   570 fun global_goal prepp kind name atts x thy =
   571   setup_goal I prepp kind Seq.single name atts x (init_state thy);
   572 
   573 val theorem = global_goal ProofContext.bind_propp Theorem;
   574 val theorem_i = global_goal ProofContext.bind_propp_i Theorem;
   575 val lemma = global_goal ProofContext.bind_propp Lemma;
   576 val lemma_i = global_goal ProofContext.bind_propp_i Lemma;
   577 
   578 
   579 (*local goals*)
   580 fun local_goal prepp kind f name atts args state =
   581   state
   582   |> setup_goal open_block prepp kind f name atts args
   583   |> warn_extra_tfrees state;
   584 
   585 val show   = local_goal ProofContext.bind_propp Goal;
   586 val show_i = local_goal ProofContext.bind_propp_i Goal;
   587 val have   = local_goal ProofContext.bind_propp Aux;
   588 val have_i = local_goal ProofContext.bind_propp_i Aux;
   589 
   590 
   591 
   592 (** conclusions **)
   593 
   594 (* current goal *)
   595 
   596 fun current_goal (State (Node {context, goal = Some goal, ...}, _)) = (context, goal)
   597   | current_goal state = raise STATE ("No current goal!", state);
   598 
   599 fun assert_current_goal true (state as State (Node {goal = None, ...}, _)) =
   600       raise STATE ("No goal in this block!", state)
   601   | assert_current_goal false (state as State (Node {goal = Some _, ...}, _)) =
   602       raise STATE ("Goal present in this block!", state)
   603   | assert_current_goal _ state = state;
   604 
   605 fun assert_bottom true (state as State (_, _ :: _)) =
   606       raise STATE ("Not at bottom of proof!", state)
   607   | assert_bottom false (state as State (_, [])) =
   608       raise STATE ("Already at bottom of proof!", state)
   609   | assert_bottom _ state = state;
   610 
   611 val at_bottom = can (assert_bottom true o close_block);
   612 
   613 fun end_proof bot state =
   614   state
   615   |> assert_forward
   616   |> close_block
   617   |> assert_bottom bot
   618   |> assert_current_goal true
   619   |> goal_facts (K []);
   620 
   621 
   622 (* local_qed *)
   623 
   624 fun finish_local (print_result, print_rule) state =
   625   let
   626     val (goal_ctxt, (((kind, name, t), (_, raw_thm)), after_qed)) = current_goal state;
   627     val outer_state = state |> close_block;
   628     val outer_ctxt = context_of outer_state;
   629 
   630     val result = prep_result state t raw_thm;
   631     val (atts, opt_solve) =
   632       (case kind of
   633         Goal atts => (atts, export_goal print_rule result goal_ctxt)
   634       | Aux atts => (atts, Seq.single)
   635       | _ => err_malformed "finish_local" state);
   636   in
   637     print_result {kind = kind_name kind, name = name, thm = result};
   638     outer_state
   639     |> auto_bind_facts name [ProofContext.generalize goal_ctxt outer_ctxt t]
   640     |> have_thmss [] name atts [Thm.no_attributes
   641         [#1 (ProofContext.export_wrt goal_ctxt (Some outer_ctxt)) result]]
   642     |> opt_solve
   643     |> (Seq.flat o Seq.map after_qed)
   644   end;
   645 
   646 fun local_qed finalize print state =
   647   state
   648   |> end_proof false
   649   |> finalize
   650   |> (Seq.flat o Seq.map (finish_local print));
   651 
   652 
   653 (* global_qed *)
   654 
   655 fun finish_global state =
   656   let
   657     val (_, (((kind, name, t), (_, raw_thm)), _)) = current_goal state;   (*ignores after_qed!*)
   658     val result = Drule.standard (prep_result state t raw_thm);
   659 
   660     val atts =
   661       (case kind of
   662         Theorem atts => atts
   663       | Lemma atts => atts @ [Drule.tag_lemma]
   664       | _ => err_malformed "finish_global" state);
   665 
   666     val (thy', result') = PureThy.store_thm ((name, result), atts) (theory_of state);
   667   in (thy', {kind = kind_name kind, name = name, thm = result'}) end;
   668 
   669 (*Note: should inspect first result only, backtracking may destroy theory*)
   670 fun global_qed finalize state =
   671   state
   672   |> end_proof true
   673   |> finalize
   674   |> Seq.map finish_global;
   675 
   676 
   677 
   678 (** blocks **)
   679 
   680 (* begin_block *)
   681 
   682 fun begin_block state =
   683   state
   684   |> assert_forward
   685   |> new_block
   686   |> open_block;
   687 
   688 
   689 (* end_block *)
   690 
   691 fun end_block state =
   692   state
   693   |> assert_forward
   694   |> close_block
   695   |> assert_current_goal false
   696   |> close_block
   697   |> transfer_facts state;
   698 
   699 
   700 (* next_block *)
   701 
   702 fun next_block state =
   703   state
   704   |> assert_forward
   705   |> close_block
   706   |> new_block
   707   |> reset_facts;
   708 
   709 
   710 end;
   711 
   712 
   713 structure BasicProof: BASIC_PROOF = Proof;
   714 open BasicProof;