src/HOL/Number_Theory/Residues.thy
author nipkow
Mon Oct 17 17:33:07 2016 +0200 (2016-10-17)
changeset 64272 f76b6dda2e56
parent 63633 2accfb71e33b
child 64282 261d42f0bfac
permissions -rw-r--r--
setprod -> prod
     1 (*  Title:      HOL/Number_Theory/Residues.thy
     2     Author:     Jeremy Avigad
     3 
     4 An algebraic treatment of residue rings, and resulting proofs of
     5 Euler's theorem and Wilson's theorem.
     6 *)
     7 
     8 section \<open>Residue rings\<close>
     9 
    10 theory Residues
    11 imports Cong MiscAlgebra
    12 begin
    13 
    14 subsection \<open>A locale for residue rings\<close>
    15 
    16 definition residue_ring :: "int \<Rightarrow> int ring"
    17 where
    18   "residue_ring m =
    19     \<lparr>carrier = {0..m - 1},
    20      mult = \<lambda>x y. (x * y) mod m,
    21      one = 1,
    22      zero = 0,
    23      add = \<lambda>x y. (x + y) mod m\<rparr>"
    24 
    25 locale residues =
    26   fixes m :: int and R (structure)
    27   assumes m_gt_one: "m > 1"
    28   defines "R \<equiv> residue_ring m"
    29 begin
    30 
    31 lemma abelian_group: "abelian_group R"
    32   apply (insert m_gt_one)
    33   apply (rule abelian_groupI)
    34   apply (unfold R_def residue_ring_def)
    35   apply (auto simp add: mod_add_right_eq [symmetric] ac_simps)
    36   apply (case_tac "x = 0")
    37   apply force
    38   apply (subgoal_tac "(x + (m - x)) mod m = 0")
    39   apply (erule bexI)
    40   apply auto
    41   done
    42 
    43 lemma comm_monoid: "comm_monoid R"
    44   apply (insert m_gt_one)
    45   apply (unfold R_def residue_ring_def)
    46   apply (rule comm_monoidI)
    47   apply auto
    48   apply (subgoal_tac "x * y mod m * z mod m = z * (x * y mod m) mod m")
    49   apply (erule ssubst)
    50   apply (subst mod_mult_right_eq [symmetric])+
    51   apply (simp_all only: ac_simps)
    52   done
    53 
    54 lemma cring: "cring R"
    55   apply (rule cringI)
    56   apply (rule abelian_group)
    57   apply (rule comm_monoid)
    58   apply (unfold R_def residue_ring_def, auto)
    59   apply (subst mod_add_eq [symmetric])
    60   apply (subst mult.commute)
    61   apply (subst mod_mult_right_eq [symmetric])
    62   apply (simp add: field_simps)
    63   done
    64 
    65 end
    66 
    67 sublocale residues < cring
    68   by (rule cring)
    69 
    70 
    71 context residues
    72 begin
    73 
    74 text \<open>
    75   These lemmas translate back and forth between internal and
    76   external concepts.
    77 \<close>
    78 
    79 lemma res_carrier_eq: "carrier R = {0..m - 1}"
    80   unfolding R_def residue_ring_def by auto
    81 
    82 lemma res_add_eq: "x \<oplus> y = (x + y) mod m"
    83   unfolding R_def residue_ring_def by auto
    84 
    85 lemma res_mult_eq: "x \<otimes> y = (x * y) mod m"
    86   unfolding R_def residue_ring_def by auto
    87 
    88 lemma res_zero_eq: "\<zero> = 0"
    89   unfolding R_def residue_ring_def by auto
    90 
    91 lemma res_one_eq: "\<one> = 1"
    92   unfolding R_def residue_ring_def units_of_def by auto
    93 
    94 lemma res_units_eq: "Units R = {x. 0 < x \<and> x < m \<and> coprime x m}"
    95   apply (insert m_gt_one)
    96   apply (unfold Units_def R_def residue_ring_def)
    97   apply auto
    98   apply (subgoal_tac "x \<noteq> 0")
    99   apply auto
   100   apply (metis invertible_coprime_int)
   101   apply (subst (asm) coprime_iff_invertible'_int)
   102   apply (auto simp add: cong_int_def mult.commute)
   103   done
   104 
   105 lemma res_neg_eq: "\<ominus> x = (- x) mod m"
   106   apply (insert m_gt_one)
   107   apply (unfold R_def a_inv_def m_inv_def residue_ring_def)
   108   apply auto
   109   apply (rule the_equality)
   110   apply auto
   111   apply (subst mod_add_right_eq [symmetric])
   112   apply auto
   113   apply (subst mod_add_left_eq [symmetric])
   114   apply auto
   115   apply (subgoal_tac "y mod m = - x mod m")
   116   apply simp
   117   apply (metis minus_add_cancel mod_mult_self1 mult.commute)
   118   done
   119 
   120 lemma finite [iff]: "finite (carrier R)"
   121   by (subst res_carrier_eq) auto
   122 
   123 lemma finite_Units [iff]: "finite (Units R)"
   124   by (subst res_units_eq) auto
   125 
   126 text \<open>
   127   The function \<open>a \<mapsto> a mod m\<close> maps the integers to the
   128   residue classes. The following lemmas show that this mapping
   129   respects addition and multiplication on the integers.
   130 \<close>
   131 
   132 lemma mod_in_carrier [iff]: "a mod m \<in> carrier R"
   133   unfolding res_carrier_eq
   134   using insert m_gt_one by auto
   135 
   136 lemma add_cong: "(x mod m) \<oplus> (y mod m) = (x + y) mod m"
   137   unfolding R_def residue_ring_def
   138   apply auto
   139   apply presburger
   140   done
   141 
   142 lemma mult_cong: "(x mod m) \<otimes> (y mod m) = (x * y) mod m"
   143   unfolding R_def residue_ring_def
   144   by auto (metis mod_mult_eq)
   145 
   146 lemma zero_cong: "\<zero> = 0"
   147   unfolding R_def residue_ring_def by auto
   148 
   149 lemma one_cong: "\<one> = 1 mod m"
   150   using m_gt_one unfolding R_def residue_ring_def by auto
   151 
   152 (* FIXME revise algebra library to use 1? *)
   153 lemma pow_cong: "(x mod m) (^) n = x^n mod m"
   154   apply (insert m_gt_one)
   155   apply (induct n)
   156   apply (auto simp add: nat_pow_def one_cong)
   157   apply (metis mult.commute mult_cong)
   158   done
   159 
   160 lemma neg_cong: "\<ominus> (x mod m) = (- x) mod m"
   161   by (metis mod_minus_eq res_neg_eq)
   162 
   163 lemma (in residues) prod_cong: "finite A \<Longrightarrow> (\<Otimes>i\<in>A. (f i) mod m) = (\<Prod>i\<in>A. f i) mod m"
   164   by (induct set: finite) (auto simp: one_cong mult_cong)
   165 
   166 lemma (in residues) sum_cong: "finite A \<Longrightarrow> (\<Oplus>i\<in>A. (f i) mod m) = (\<Sum>i\<in>A. f i) mod m"
   167   by (induct set: finite) (auto simp: zero_cong add_cong)
   168 
   169 lemma mod_in_res_units [simp]:
   170   assumes "1 < m" and "coprime a m"
   171   shows "a mod m \<in> Units R"
   172 proof (cases "a mod m = 0")
   173   case True with assms show ?thesis
   174     by (auto simp add: res_units_eq gcd_red_int [symmetric])
   175 next
   176   case False
   177   from assms have "0 < m" by simp
   178   with pos_mod_sign [of m a] have "0 \<le> a mod m" .
   179   with False have "0 < a mod m" by simp
   180   with assms show ?thesis
   181     by (auto simp add: res_units_eq gcd_red_int [symmetric] ac_simps)
   182 qed
   183 
   184 lemma res_eq_to_cong: "(a mod m) = (b mod m) \<longleftrightarrow> [a = b] (mod m)"
   185   unfolding cong_int_def by auto
   186 
   187 
   188 text \<open>Simplifying with these will translate a ring equation in R to a congruence.\<close>
   189 lemmas res_to_cong_simps = add_cong mult_cong pow_cong one_cong
   190     prod_cong sum_cong neg_cong res_eq_to_cong
   191 
   192 text \<open>Other useful facts about the residue ring.\<close>
   193 lemma one_eq_neg_one: "\<one> = \<ominus> \<one> \<Longrightarrow> m = 2"
   194   apply (simp add: res_one_eq res_neg_eq)
   195   apply (metis add.commute add_diff_cancel mod_mod_trivial one_add_one uminus_add_conv_diff
   196     zero_neq_one zmod_zminus1_eq_if)
   197   done
   198 
   199 end
   200 
   201 
   202 subsection \<open>Prime residues\<close>
   203 
   204 locale residues_prime =
   205   fixes p :: nat and R (structure)
   206   assumes p_prime [intro]: "prime p"
   207   defines "R \<equiv> residue_ring (int p)"
   208 
   209 sublocale residues_prime < residues p
   210   apply (unfold R_def residues_def)
   211   using p_prime apply auto
   212   apply (metis (full_types) of_nat_1 of_nat_less_iff prime_gt_1_nat)
   213   done
   214 
   215 context residues_prime
   216 begin
   217 
   218 lemma is_field: "field R"
   219   apply (rule cring.field_intro2)
   220   apply (rule cring)
   221   apply (auto simp add: res_carrier_eq res_one_eq res_zero_eq res_units_eq)
   222   apply (rule classical)
   223   apply (erule notE)
   224   apply (subst gcd.commute)
   225   apply (rule prime_imp_coprime_int)
   226   apply (simp add: p_prime)
   227   apply (rule notI)
   228   apply (frule zdvd_imp_le)
   229   apply auto
   230   done
   231 
   232 lemma res_prime_units_eq: "Units R = {1..p - 1}"
   233   apply (subst res_units_eq)
   234   apply auto
   235   apply (subst gcd.commute)
   236   apply (auto simp add: p_prime prime_imp_coprime_int zdvd_not_zless)
   237   done
   238 
   239 end
   240 
   241 sublocale residues_prime < field
   242   by (rule is_field)
   243 
   244 
   245 section \<open>Test cases: Euler's theorem and Wilson's theorem\<close>
   246 
   247 subsection \<open>Euler's theorem\<close>
   248 
   249 text \<open>The definition of the phi function.\<close>
   250 
   251 definition phi :: "int \<Rightarrow> nat"
   252   where "phi m = card {x. 0 < x \<and> x < m \<and> gcd x m = 1}"
   253 
   254 lemma phi_def_nat: "phi m = card {x. 0 < x \<and> x < nat m \<and> gcd x (nat m) = 1}"
   255   apply (simp add: phi_def)
   256   apply (rule bij_betw_same_card [of nat])
   257   apply (auto simp add: inj_on_def bij_betw_def image_def)
   258   apply (metis dual_order.irrefl dual_order.strict_trans leI nat_1 transfer_nat_int_gcd(1))
   259   apply (metis One_nat_def of_nat_0 of_nat_1 of_nat_less_0_iff int_nat_eq nat_int
   260     transfer_int_nat_gcd(1) of_nat_less_iff)
   261   done
   262 
   263 lemma prime_phi:
   264   assumes "2 \<le> p" "phi p = p - 1"
   265   shows "prime p"
   266 proof -
   267   have *: "{x. 0 < x \<and> x < p \<and> coprime x p} = {1..p - 1}"
   268     using assms unfolding phi_def_nat
   269     by (intro card_seteq) fastforce+
   270   have False if **: "1 < x" "x < p" and "x dvd p" for x :: nat
   271   proof -
   272     from * have cop: "x \<in> {1..p - 1} \<Longrightarrow> coprime x p"
   273       by blast
   274     have "coprime x p"
   275       apply (rule cop)
   276       using ** apply auto
   277       done
   278     with \<open>x dvd p\<close> \<open>1 < x\<close> show ?thesis
   279       by auto
   280   qed
   281   then show ?thesis
   282     using \<open>2 \<le> p\<close>
   283     by (simp add: prime_nat_iff)
   284        (metis One_nat_def dvd_pos_nat nat_dvd_not_less nat_neq_iff not_gr0
   285               not_numeral_le_zero one_dvd)
   286 qed
   287 
   288 lemma phi_zero [simp]: "phi 0 = 0"
   289   unfolding phi_def
   290 (* Auto hangs here. Once again, where is the simplification rule
   291    1 \<equiv> Suc 0 coming from? *)
   292   apply (auto simp add: card_eq_0_iff)
   293 (* Add card_eq_0_iff as a simp rule? delete card_empty_imp? *)
   294   done
   295 
   296 lemma phi_one [simp]: "phi 1 = 0"
   297   by (auto simp add: phi_def card_eq_0_iff)
   298 
   299 lemma (in residues) phi_eq: "phi m = card (Units R)"
   300   by (simp add: phi_def res_units_eq)
   301 
   302 lemma (in residues) euler_theorem1:
   303   assumes a: "gcd a m = 1"
   304   shows "[a^phi m = 1] (mod m)"
   305 proof -
   306   from a m_gt_one have [simp]: "a mod m \<in> Units R"
   307     by (intro mod_in_res_units)
   308   from phi_eq have "(a mod m) (^) (phi m) = (a mod m) (^) (card (Units R))"
   309     by simp
   310   also have "\<dots> = \<one>"
   311     by (intro units_power_order_eq_one) auto
   312   finally show ?thesis
   313     by (simp add: res_to_cong_simps)
   314 qed
   315 
   316 (* In fact, there is a two line proof!
   317 
   318 lemma (in residues) euler_theorem1:
   319   assumes a: "gcd a m = 1"
   320   shows "[a^phi m = 1] (mod m)"
   321 proof -
   322   have "(a mod m) (^) (phi m) = \<one>"
   323     by (simp add: phi_eq units_power_order_eq_one a m_gt_one)
   324   then show ?thesis
   325     by (simp add: res_to_cong_simps)
   326 qed
   327 
   328 *)
   329 
   330 text \<open>Outside the locale, we can relax the restriction \<open>m > 1\<close>.\<close>
   331 lemma euler_theorem:
   332   assumes "m \<ge> 0"
   333     and "gcd a m = 1"
   334   shows "[a^phi m = 1] (mod m)"
   335 proof (cases "m = 0 | m = 1")
   336   case True
   337   then show ?thesis by auto
   338 next
   339   case False
   340   with assms show ?thesis
   341     by (intro residues.euler_theorem1, unfold residues_def, auto)
   342 qed
   343 
   344 lemma (in residues_prime) phi_prime: "phi p = nat p - 1"
   345   apply (subst phi_eq)
   346   apply (subst res_prime_units_eq)
   347   apply auto
   348   done
   349 
   350 lemma phi_prime: "prime (int p) \<Longrightarrow> phi p = nat p - 1"
   351   apply (rule residues_prime.phi_prime)
   352   apply simp
   353   apply (erule residues_prime.intro)
   354   done
   355 
   356 lemma fermat_theorem:
   357   fixes a :: int
   358   assumes "prime (int p)"
   359     and "\<not> p dvd a"
   360   shows "[a^(p - 1) = 1] (mod p)"
   361 proof -
   362   from assms have "[a ^ phi p = 1] (mod p)"
   363     by (auto intro!: euler_theorem intro!: prime_imp_coprime_int[of p]
   364              simp: gcd.commute[of _ "int p"])
   365   also have "phi p = nat p - 1"
   366     by (rule phi_prime) (rule assms)
   367   finally show ?thesis
   368     by (metis nat_int)
   369 qed
   370 
   371 lemma fermat_theorem_nat:
   372   assumes "prime (int p)" and "\<not> p dvd a"
   373   shows "[a ^ (p - 1) = 1] (mod p)"
   374   using fermat_theorem [of p a] assms
   375   by (metis of_nat_1 of_nat_power transfer_int_nat_cong zdvd_int)
   376 
   377 
   378 subsection \<open>Wilson's theorem\<close>
   379 
   380 lemma (in field) inv_pair_lemma: "x \<in> Units R \<Longrightarrow> y \<in> Units R \<Longrightarrow>
   381     {x, inv x} \<noteq> {y, inv y} \<Longrightarrow> {x, inv x} \<inter> {y, inv y} = {}"
   382   apply auto
   383   apply (metis Units_inv_inv)+
   384   done
   385 
   386 lemma (in residues_prime) wilson_theorem1:
   387   assumes a: "p > 2"
   388   shows "[fact (p - 1) = (-1::int)] (mod p)"
   389 proof -
   390   let ?Inverse_Pairs = "{{x, inv x}| x. x \<in> Units R - {\<one>, \<ominus> \<one>}}"
   391   have UR: "Units R = {\<one>, \<ominus> \<one>} \<union> \<Union>?Inverse_Pairs"
   392     by auto
   393   have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) \<otimes> (\<Otimes>i\<in>\<Union>?Inverse_Pairs. i)"
   394     apply (subst UR)
   395     apply (subst finprod_Un_disjoint)
   396     apply (auto intro: funcsetI)
   397     using inv_one apply auto[1]
   398     using inv_eq_neg_one_eq apply auto
   399     done
   400   also have "(\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) = \<ominus> \<one>"
   401     apply (subst finprod_insert)
   402     apply auto
   403     apply (frule one_eq_neg_one)
   404     using a apply force
   405     done
   406   also have "(\<Otimes>i\<in>(\<Union>?Inverse_Pairs). i) = (\<Otimes>A\<in>?Inverse_Pairs. (\<Otimes>y\<in>A. y))"
   407     apply (subst finprod_Union_disjoint)
   408     apply auto
   409     apply (metis Units_inv_inv)+
   410     done
   411   also have "\<dots> = \<one>"
   412     apply (rule finprod_one)
   413     apply auto
   414     apply (subst finprod_insert)
   415     apply auto
   416     apply (metis inv_eq_self)
   417     done
   418   finally have "(\<Otimes>i\<in>Units R. i) = \<ominus> \<one>"
   419     by simp
   420   also have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>Units R. i mod p)"
   421     apply (rule finprod_cong')
   422     apply auto
   423     apply (subst (asm) res_prime_units_eq)
   424     apply auto
   425     done
   426   also have "\<dots> = (\<Prod>i\<in>Units R. i) mod p"
   427     apply (rule prod_cong)
   428     apply auto
   429     done
   430   also have "\<dots> = fact (p - 1) mod p"
   431     apply (simp add: fact_prod)
   432     apply (insert assms)
   433     apply (subst res_prime_units_eq)
   434     apply (simp add: int_prod zmod_int prod_int_eq)
   435     done
   436   finally have "fact (p - 1) mod p = \<ominus> \<one>" .
   437   then show ?thesis
   438     by (metis of_nat_fact Divides.transfer_int_nat_functions(2)
   439       cong_int_def res_neg_eq res_one_eq)
   440 qed
   441 
   442 lemma wilson_theorem:
   443   assumes "prime p"
   444   shows "[fact (p - 1) = - 1] (mod p)"
   445 proof (cases "p = 2")
   446   case True
   447   then show ?thesis
   448     by (simp add: cong_int_def fact_prod)
   449 next
   450   case False
   451   then show ?thesis
   452     using assms prime_ge_2_nat
   453     by (metis residues_prime.wilson_theorem1 residues_prime.intro le_eq_less_or_eq)
   454 qed
   455 
   456 end