src/HOL/WF.ML
author wenzelm
Thu Mar 11 13:20:35 1999 +0100 (1999-03-11)
changeset 6349 f7750d816c21
parent 5579 32f99ca617b7
child 6433 228237ec56e5
permissions -rw-r--r--
removed foo_build_completed -- now handled by session management (via usedir);
     1 (*  Title:      HOL/wf.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, with minor changes by Konrad Slind
     4     Copyright   1992  University of Cambridge/1995 TU Munich
     5 
     6 Wellfoundedness, induction, and  recursion
     7 *)
     8 
     9 val H_cong = read_instantiate [("f","H")] (standard(refl RS cong RS cong));
    10 val H_cong1 = refl RS H_cong;
    11 
    12 val [prem] = Goalw [wf_def]
    13  "[| !!P x. [| !x. (!y. (y,x) : r --> P(y)) --> P(x) |] ==> P(x) |] ==> wf(r)";
    14 by (Clarify_tac 1);
    15 by (rtac prem 1);
    16 by (assume_tac 1);
    17 qed "wfUNIVI";
    18 
    19 (*Restriction to domain A.  If r is well-founded over A then wf(r)*)
    20 val [prem1,prem2] = Goalw [wf_def]
    21  "[| r <= A Times A;  \
    22 \    !!x P. [| ! x. (! y. (y,x) : r --> P(y)) --> P(x);  x:A |] ==> P(x) |]  \
    23 \ ==>  wf(r)";
    24 by (Clarify_tac 1);
    25 by (rtac allE 1);
    26 by (assume_tac 1);
    27 by (best_tac (claset() addSEs [prem1 RS subsetD RS SigmaE2] addIs [prem2]) 1);
    28 qed "wfI";
    29 
    30 val major::prems = Goalw [wf_def]
    31     "[| wf(r);          \
    32 \       !!x.[| ! y. (y,x): r --> P(y) |] ==> P(x) \
    33 \    |]  ==>  P(a)";
    34 by (rtac (major RS spec RS mp RS spec) 1);
    35 by (blast_tac (claset() addIs prems) 1);
    36 qed "wf_induct";
    37 
    38 (*Perform induction on i, then prove the wf(r) subgoal using prems. *)
    39 fun wf_ind_tac a prems i = 
    40     EVERY [res_inst_tac [("a",a)] wf_induct i,
    41            rename_last_tac a ["1"] (i+1),
    42            ares_tac prems i];
    43 
    44 Goal "wf(r) ==> ! x. (a,x):r --> (x,a)~:r";
    45 by (wf_ind_tac "a" [] 1);
    46 by (Blast_tac 1);
    47 qed_spec_mp "wf_not_sym";
    48 
    49 (* [| wf(r);  (a,x):r;  ~P ==> (x,a):r |] ==> P *)
    50 bind_thm ("wf_asym", wf_not_sym RS swap);
    51 
    52 Goal "[| wf(r);  (a,a): r |] ==> P";
    53 by (blast_tac (claset() addEs [wf_asym]) 1);
    54 qed "wf_irrefl";
    55 
    56 (*transitive closure of a wf relation is wf! *)
    57 Goal "wf(r) ==> wf(r^+)";
    58 by (stac wf_def 1);
    59 by (Clarify_tac 1);
    60 (*must retain the universal formula for later use!*)
    61 by (rtac allE 1 THEN assume_tac 1);
    62 by (etac mp 1);
    63 by (eres_inst_tac [("a","x")] wf_induct 1);
    64 by (rtac (impI RS allI) 1);
    65 by (etac tranclE 1);
    66 by (Blast_tac 1);
    67 by (Blast_tac 1);
    68 qed "wf_trancl";
    69 
    70 
    71 val wf_converse_trancl = prove_goal thy 
    72 "!!X. wf (r^-1) ==> wf ((r^+)^-1)" (K [
    73 	stac (trancl_converse RS sym) 1,
    74 	etac wf_trancl 1]);
    75 
    76 (*----------------------------------------------------------------------------
    77  * Minimal-element characterization of well-foundedness
    78  *---------------------------------------------------------------------------*)
    79 
    80 Goalw [wf_def] "wf r ==> x:Q --> (? z:Q. ! y. (y,z):r --> y~:Q)";
    81 by (dtac spec 1);
    82 by (etac (mp RS spec) 1);
    83 by (Blast_tac 1);
    84 val lemma1 = result();
    85 
    86 Goalw [wf_def] "(! Q x. x:Q --> (? z:Q. ! y. (y,z):r --> y~:Q)) ==> wf r";
    87 by (Clarify_tac 1);
    88 by (dres_inst_tac [("x", "{x. ~ P x}")] spec 1);
    89 by (Blast_tac 1);
    90 val lemma2 = result();
    91 
    92 Goal "wf r = (! Q x. x:Q --> (? z:Q. ! y. (y,z):r --> y~:Q))";
    93 by (blast_tac (claset() addSIs [lemma1, lemma2]) 1);
    94 qed "wf_eq_minimal";
    95 
    96 (*---------------------------------------------------------------------------
    97  * Wellfoundedness of subsets
    98  *---------------------------------------------------------------------------*)
    99 
   100 Goal "[| wf(r);  p<=r |] ==> wf(p)";
   101 by (full_simp_tac (simpset() addsimps [wf_eq_minimal]) 1);
   102 by (Fast_tac 1);
   103 qed "wf_subset";
   104 
   105 (*---------------------------------------------------------------------------
   106  * Wellfoundedness of the empty relation.
   107  *---------------------------------------------------------------------------*)
   108 
   109 Goal "wf({})";
   110 by (simp_tac (simpset() addsimps [wf_def]) 1);
   111 qed "wf_empty";
   112 AddIffs [wf_empty];
   113 
   114 (*---------------------------------------------------------------------------
   115  * Wellfoundedness of `insert'
   116  *---------------------------------------------------------------------------*)
   117 
   118 Goal "wf(insert (y,x) r) = (wf(r) & (x,y) ~: r^*)";
   119 by (rtac iffI 1);
   120  by (blast_tac (claset() addEs [wf_trancl RS wf_irrefl] 
   121 	addIs [rtrancl_into_trancl1,wf_subset,impOfSubs rtrancl_mono]) 1);
   122 by (asm_full_simp_tac (simpset() addsimps [wf_eq_minimal]) 1);
   123 by Safe_tac;
   124 by (EVERY1[rtac allE, atac, etac impE, Blast_tac]);
   125 by (etac bexE 1);
   126 by (rename_tac "a" 1);
   127 by (case_tac "a = x" 1);
   128  by (res_inst_tac [("x","a")]bexI 2);
   129   by (assume_tac 3);
   130  by (Blast_tac 2);
   131 by (case_tac "y:Q" 1);
   132  by (Blast_tac 2);
   133 by (res_inst_tac [("x","{z. z:Q & (z,y) : r^*}")] allE 1);
   134  by (assume_tac 1);
   135 by (thin_tac "! Q. (? x. x : Q) --> ?P Q" 1);	(*essential for speed*)
   136 (*Blast_tac with new substOccur fails*)
   137 by (best_tac (claset() addIs [rtrancl_into_rtrancl2]) 1);
   138 qed "wf_insert";
   139 AddIffs [wf_insert];
   140 
   141 (*---------------------------------------------------------------------------
   142  * Wellfoundedness of `disjoint union'
   143  *---------------------------------------------------------------------------*)
   144 
   145 (*Intuition behind this proof for the case of binary union:
   146 
   147   Goal: find an (R u S)-min element of a nonempty subset A.
   148   by case distinction:
   149   1. There is a step a -R-> b with a,b : A.
   150      Pick an R-min element z of the (nonempty) set {a:A | EX b:A. a -R-> b}.
   151      By definition, there is z':A s.t. z -R-> z'. Because z is R-min in the
   152      subset, z' must be R-min in A. Because z' has an R-predecessor, it cannot
   153      have an S-successor and is thus S-min in A as well.
   154   2. There is no such step.
   155      Pick an S-min element of A. In this case it must be an R-min
   156      element of A as well.
   157 
   158 *)
   159 
   160 Goal "[| !i:I. wf(r i); \
   161 \        !i:I.!j:I. r i ~= r j --> Domain(r i) Int Range(r j) = {} & \
   162 \                                  Domain(r j) Int Range(r i) = {} \
   163 \     |] ==> wf(UN i:I. r i)";
   164 by (asm_full_simp_tac (HOL_basic_ss addsimps [wf_eq_minimal]) 1);
   165 by (Clarify_tac 1);
   166 by (rename_tac "A a" 1);
   167 by (case_tac "? i:I. ? a:A. ? b:A. (b,a) : r i" 1);
   168  by (Clarify_tac 1);
   169  by (EVERY1[dtac bspec, atac,
   170            eres_inst_tac[("x","{a. a:A & (? b:A. (b,a) : r i)}")]allE]);
   171  by (EVERY1[etac allE,etac impE]);
   172   by (Blast_tac 1);
   173  by (Clarify_tac 1);
   174  by (rename_tac "z'" 1);
   175  by (res_inst_tac [("x","z'")] bexI 1);
   176   by (assume_tac 2);
   177  by (Clarify_tac 1);
   178  by (rename_tac "j" 1);
   179  by (case_tac "r j = r i" 1);
   180   by (EVERY1[etac allE,etac impE,atac]);
   181   by (Asm_full_simp_tac 1);
   182   by (Blast_tac 1);
   183  by (blast_tac (claset() addEs [equalityE]) 1);
   184 by (Asm_full_simp_tac 1);
   185 by (fast_tac (claset() delWrapper "bspec") 1); (*faster than Blast_tac*)
   186 qed "wf_UN";
   187 
   188 Goalw [Union_def]
   189  "[| !r:R. wf r; \
   190 \    !r:R.!s:R. r ~= s --> Domain r Int Range s = {} & \
   191 \                          Domain s Int Range r = {} \
   192 \ |] ==> wf(Union R)";
   193 by (rtac wf_UN 1);
   194 by (Blast_tac 1);
   195 by (Blast_tac 1);
   196 qed "wf_Union";
   197 
   198 Goal "[| wf r; wf s; Domain r Int Range s = {}; Domain s Int Range r = {} \
   199 \     |] ==> wf(r Un s)";
   200 by (rtac (simplify (simpset()) (read_instantiate[("R","{r,s}")]wf_Union)) 1);
   201 by (Blast_tac 1);
   202 by (Blast_tac 1);
   203 qed "wf_Un";
   204 
   205 (*---------------------------------------------------------------------------
   206  * Wellfoundedness of `image'
   207  *---------------------------------------------------------------------------*)
   208 
   209 Goal "[| wf r; inj f |] ==> wf(prod_fun f f `` r)";
   210 by (asm_full_simp_tac (HOL_basic_ss addsimps [wf_eq_minimal]) 1);
   211 by (Clarify_tac 1);
   212 by (case_tac "? p. f p : Q" 1);
   213 by (eres_inst_tac [("x","{p. f p : Q}")]allE 1);
   214 by (fast_tac (claset() addDs [injD]) 1);
   215 by (Blast_tac 1);
   216 qed "wf_prod_fun_image";
   217 
   218 (*** acyclic ***)
   219 
   220 val acyclicI = prove_goalw WF.thy [acyclic_def] 
   221 "!!r. !x. (x, x) ~: r^+ ==> acyclic r" (K [atac 1]);
   222 
   223 Goalw [acyclic_def]
   224  "wf r ==> acyclic r";
   225 by (blast_tac (claset() addEs [wf_trancl RS wf_irrefl]) 1);
   226 qed "wf_acyclic";
   227 
   228 Goalw [acyclic_def] "acyclic(insert (y,x) r) = (acyclic r & (x,y) ~: r^*)";
   229 by (simp_tac (simpset() addsimps [trancl_insert]) 1);
   230 by (blast_tac (claset() addIs [rtrancl_trans]) 1);
   231 qed "acyclic_insert";
   232 AddIffs [acyclic_insert];
   233 
   234 Goalw [acyclic_def] "acyclic(r^-1) = acyclic r";
   235 by (simp_tac (simpset() addsimps [trancl_converse]) 1);
   236 qed "acyclic_converse";
   237 
   238 (** cut **)
   239 
   240 (*This rewrite rule works upon formulae; thus it requires explicit use of
   241   H_cong to expose the equality*)
   242 Goalw [cut_def]
   243     "(cut f r x = cut g r x) = (!y. (y,x):r --> f(y)=g(y))";
   244 by (simp_tac (HOL_ss addsimps [expand_fun_eq]) 1);
   245 qed "cuts_eq";
   246 
   247 Goalw [cut_def] "(x,a):r ==> (cut f r a)(x) = f(x)";
   248 by (asm_simp_tac HOL_ss 1);
   249 qed "cut_apply";
   250 
   251 (*** is_recfun ***)
   252 
   253 Goalw [is_recfun_def,cut_def]
   254     "[| is_recfun r H a f;  ~(b,a):r |] ==> f(b) = arbitrary";
   255 by (etac ssubst 1);
   256 by (asm_simp_tac HOL_ss 1);
   257 qed "is_recfun_undef";
   258 
   259 (*** NOTE! some simplifications need a different finish_tac!! ***)
   260 fun indhyp_tac hyps =
   261     (cut_facts_tac hyps THEN'
   262        DEPTH_SOLVE_1 o (ares_tac [TrueI] ORELSE'
   263                         eresolve_tac [transD, mp, allE]));
   264 val wf_super_ss = HOL_ss addSolver indhyp_tac;
   265 
   266 Goalw [is_recfun_def,cut_def]
   267     "[| wf(r);  trans(r);  is_recfun r H a f;  is_recfun r H b g |] ==> \
   268     \ (x,a):r --> (x,b):r --> f(x)=g(x)";
   269 by (etac wf_induct 1);
   270 by (REPEAT (rtac impI 1 ORELSE etac ssubst 1));
   271 by (asm_simp_tac (wf_super_ss addcongs [if_cong]) 1);
   272 qed_spec_mp "is_recfun_equal";
   273 
   274 
   275 val prems as [wfr,transr,recfa,recgb,_] = goalw WF.thy [cut_def]
   276     "[| wf(r);  trans(r); \
   277 \       is_recfun r H a f;  is_recfun r H b g;  (b,a):r |] ==> \
   278 \    cut f r b = g";
   279 val gundef = recgb RS is_recfun_undef
   280 and fisg   = recgb RS (recfa RS (transr RS (wfr RS is_recfun_equal)));
   281 by (cut_facts_tac prems 1);
   282 by (rtac ext 1);
   283 by (asm_simp_tac (wf_super_ss addsimps [gundef,fisg]) 1);
   284 qed "is_recfun_cut";
   285 
   286 (*** Main Existence Lemma -- Basic Properties of the_recfun ***)
   287 
   288 Goalw [the_recfun_def]
   289     "is_recfun r H a f ==> is_recfun r H a (the_recfun r H a)";
   290 by (eres_inst_tac [("P", "is_recfun r H a")] selectI 1);
   291 qed "is_the_recfun";
   292 
   293 Goal "[| wf(r);  trans(r) |] ==> is_recfun r H a (the_recfun r H a)";
   294 by (wf_ind_tac "a" [] 1);
   295 by (res_inst_tac [("f","cut (%y. H (the_recfun r H y) y) r a1")]
   296                  is_the_recfun 1);
   297 by (rewtac is_recfun_def);
   298 by (stac cuts_eq 1);
   299 by (Clarify_tac 1);
   300 by (rtac (refl RSN (2,H_cong)) 1);
   301 by (subgoal_tac
   302          "the_recfun r H y = cut(%x. H(cut(the_recfun r H y) r x) x) r y" 1);
   303  by (etac allE 2);
   304  by (dtac impE 2);
   305    by (atac 2);
   306   by (atac 3);
   307  by (atac 2);
   308 by (etac ssubst 1);
   309 by (simp_tac (HOL_ss addsimps [cuts_eq]) 1);
   310 by (Clarify_tac 1);
   311 by (stac cut_apply 1);
   312  by (fast_tac (claset() addDs [transD]) 1);
   313 by (rtac (refl RSN (2,H_cong)) 1);
   314 by (fold_tac [is_recfun_def]);
   315 by (asm_simp_tac (wf_super_ss addsimps[is_recfun_cut]) 1);
   316 qed "unfold_the_recfun";
   317 
   318 val unwind1_the_recfun = rewrite_rule[is_recfun_def] unfold_the_recfun;
   319 
   320 (*--------------Old proof-----------------------------------------------------
   321 val prems = Goal
   322     "[| wf(r);  trans(r) |] ==> is_recfun r H a (the_recfun r H a)";
   323 by (cut_facts_tac prems 1);
   324 by (wf_ind_tac "a" prems 1);
   325 by (res_inst_tac [("f", "cut (%y. wftrec r H y) r a1")] is_the_recfun 1); 
   326 by (rewrite_goals_tac [is_recfun_def, wftrec_def]);
   327 by (stac cuts_eq 1);
   328 (*Applying the substitution: must keep the quantified assumption!!*)
   329 by (EVERY1 [Clarify_tac, rtac H_cong1, rtac allE, atac,
   330             etac (mp RS ssubst), atac]); 
   331 by (fold_tac [is_recfun_def]);
   332 by (asm_simp_tac (wf_super_ss addsimps[cut_apply,is_recfun_cut,cuts_eq]) 1);
   333 qed "unfold_the_recfun";
   334 ---------------------------------------------------------------------------*)
   335 
   336 (** Removal of the premise trans(r) **)
   337 val th = rewrite_rule[is_recfun_def]
   338                      (trans_trancl RSN (2,(wf_trancl RS unfold_the_recfun)));
   339 
   340 Goalw [wfrec_def]
   341     "wf(r) ==> wfrec r H a = H (cut (wfrec r H) r a) a";
   342 by (rtac H_cong 1);
   343 by (rtac refl 2);
   344 by (simp_tac (HOL_ss addsimps [cuts_eq]) 1);
   345 by (rtac allI 1);
   346 by (rtac impI 1);
   347 by (simp_tac(HOL_ss addsimps [wfrec_def]) 1);
   348 by (res_inst_tac [("a1","a")] (th RS ssubst) 1);
   349 by (atac 1);
   350 by (forward_tac[wf_trancl] 1);
   351 by (forward_tac[r_into_trancl] 1);
   352 by (asm_simp_tac (HOL_ss addsimps [cut_apply]) 1);
   353 by (rtac H_cong 1);    (*expose the equality of cuts*)
   354 by (rtac refl 2);
   355 by (simp_tac (HOL_ss addsimps [cuts_eq, cut_apply, r_into_trancl]) 1);
   356 by (Clarify_tac 1);
   357 by (res_inst_tac [("r","r^+")] is_recfun_equal 1);
   358 by (atac 1);
   359 by (rtac trans_trancl 1);
   360 by (rtac unfold_the_recfun 1);
   361 by (atac 1);
   362 by (rtac trans_trancl 1);
   363 by (rtac unfold_the_recfun 1);
   364 by (atac 1);
   365 by (rtac trans_trancl 1);
   366 by (rtac transD 1);
   367 by (rtac trans_trancl 1);
   368 by (forw_inst_tac [("p","(ya,y)")] r_into_trancl 1);
   369 by (atac 1);
   370 by (atac 1);
   371 by (forw_inst_tac [("p","(ya,y)")] r_into_trancl 1);
   372 by (atac 1);
   373 qed "wfrec";
   374 
   375 (*--------------Old proof-----------------------------------------------------
   376 Goalw [wfrec_def]
   377     "wf(r) ==> wfrec r H a = H (cut (wfrec r H) r a) a";
   378 by (etac (wf_trancl RS wftrec RS ssubst) 1);
   379 by (rtac trans_trancl 1);
   380 by (rtac (refl RS H_cong) 1);    (*expose the equality of cuts*)
   381 by (simp_tac (HOL_ss addsimps [cuts_eq, cut_apply, r_into_trancl]) 1);
   382 qed "wfrec";
   383 ---------------------------------------------------------------------------*)
   384 
   385 (*---------------------------------------------------------------------------
   386  * This form avoids giant explosions in proofs.  NOTE USE OF == 
   387  *---------------------------------------------------------------------------*)
   388 val rew::prems = goal thy
   389     "[| f==wfrec r H;  wf(r) |] ==> f(a) = H (cut f r a) a";
   390 by (rewtac rew);
   391 by (REPEAT (resolve_tac (prems@[wfrec]) 1));
   392 qed "def_wfrec";
   393 
   394 
   395 (**** TFL variants ****)
   396 
   397 Goal "!R. wf R --> (!P. (!x. (!y. (y,x):R --> P y) --> P x) --> (!x. P x))";
   398 by (Clarify_tac 1);
   399 by (res_inst_tac [("r","R"),("P","P"), ("a","x")] wf_induct 1);
   400 by (assume_tac 1);
   401 by (Blast_tac 1);
   402 qed"tfl_wf_induct";
   403 
   404 Goal "!f R. (x,a):R --> (cut f R a)(x) = f(x)";
   405 by (Clarify_tac 1);
   406 by (rtac cut_apply 1);
   407 by (assume_tac 1);
   408 qed"tfl_cut_apply";
   409 
   410 Goal "!M R f. (f=wfrec R M) --> wf R --> (!x. f x = M (cut f R x) x)";
   411 by (Clarify_tac 1);
   412 by (etac wfrec 1);
   413 qed "tfl_wfrec";