src/Pure/Isar/theory_target.ML
author wenzelm
Sat Mar 13 19:35:53 2010 +0100 (2010-03-13)
changeset 35764 f7f88f2e004f
parent 35739 35a3b3721ffb
child 35765 09e238561460
permissions -rw-r--r--
minor tuning and simplification;
     1 (*  Title:      Pure/Isar/theory_target.ML
     2     Author:     Makarius
     3     Author:     Florian Haftmann, TU Muenchen
     4 
     5 Common theory/locale/class/instantiation/overloading targets.
     6 *)
     7 
     8 signature THEORY_TARGET =
     9 sig
    10   val peek: local_theory ->
    11    {target: string,
    12     is_locale: bool,
    13     is_class: bool,
    14     instantiation: string list * (string * sort) list * sort,
    15     overloading: (string * (string * typ) * bool) list}
    16   val init: string option -> theory -> local_theory
    17   val context_cmd: xstring -> theory -> local_theory
    18   val instantiation: string list * (string * sort) list * sort -> theory -> local_theory
    19   val instantiation_cmd: xstring list * xstring list * xstring -> theory -> local_theory
    20   val overloading: (string * (string * typ) * bool) list -> theory -> local_theory
    21   val overloading_cmd: (string * string * bool) list -> theory -> local_theory
    22 end;
    23 
    24 structure Theory_Target: THEORY_TARGET =
    25 struct
    26 
    27 (* context data *)
    28 
    29 datatype target = Target of {target: string, is_locale: bool,
    30   is_class: bool, instantiation: string list * (string * sort) list * sort,
    31   overloading: (string * (string * typ) * bool) list};
    32 
    33 fun make_target target is_locale is_class instantiation overloading =
    34   Target {target = target, is_locale = is_locale,
    35     is_class = is_class, instantiation = instantiation, overloading = overloading};
    36 
    37 val global_target = make_target "" false false ([], [], []) [];
    38 
    39 structure Data = Proof_Data
    40 (
    41   type T = target;
    42   fun init _ = global_target;
    43 );
    44 
    45 val peek = (fn Target args => args) o Data.get;
    46 
    47 
    48 (* pretty *)
    49 
    50 fun pretty_thy ctxt target is_class =
    51   let
    52     val thy = ProofContext.theory_of ctxt;
    53     val target_name = (if is_class then "class " else "locale ") ^ Locale.extern thy target;
    54     val fixes =
    55       map (fn (x, T) => (Binding.name x, SOME T, NoSyn)) (#1 (ProofContext.inferred_fixes ctxt));
    56     val assumes =
    57       map (fn A => (Attrib.empty_binding, [(Thm.term_of A, [])])) (Assumption.all_assms_of ctxt);
    58     val elems =
    59       (if null fixes then [] else [Element.Fixes fixes]) @
    60       (if null assumes then [] else [Element.Assumes assumes]);
    61   in
    62     if target = "" then []
    63     else if null elems then [Pretty.str target_name]
    64     else [Pretty.big_list (target_name ^ " =")
    65       (map (Pretty.chunks o Element.pretty_ctxt ctxt) elems)]
    66   end;
    67 
    68 fun pretty (Target {target, is_class, instantiation, overloading, ...}) ctxt =
    69   Pretty.block [Pretty.str "theory", Pretty.brk 1,
    70       Pretty.str (Context.theory_name (ProofContext.theory_of ctxt))] ::
    71     (if not (null overloading) then [Overloading.pretty ctxt]
    72      else if not (null (#1 instantiation)) then [Class_Target.pretty_instantiation ctxt]
    73      else pretty_thy ctxt target is_class);
    74 
    75 
    76 (* generic declarations *)
    77 
    78 local
    79 
    80 fun direct_decl decl =
    81   let val decl0 = Morphism.form decl in
    82     Local_Theory.theory (Context.theory_map decl0) #>
    83     Local_Theory.target (Context.proof_map decl0)
    84   end;
    85 
    86 fun target_decl add (Target {target, ...}) pervasive decl lthy =
    87   let
    88     val global_decl = Morphism.transform (Local_Theory.global_morphism lthy) decl;
    89     val target_decl = Morphism.transform (Local_Theory.target_morphism lthy) decl;
    90   in
    91     if target = "" then
    92       lthy
    93       |> direct_decl global_decl
    94     else
    95       lthy
    96       |> pervasive ? direct_decl global_decl
    97       |> Local_Theory.target (add target target_decl)
    98   end;
    99 
   100 in
   101 
   102 val type_syntax = target_decl Locale.add_type_syntax;
   103 val term_syntax = target_decl Locale.add_term_syntax;
   104 val declaration = target_decl Locale.add_declaration;
   105 
   106 end;
   107 
   108 fun class_target (Target {target, ...}) f =
   109   Local_Theory.raw_theory f #>
   110   Local_Theory.target (Class_Target.refresh_syntax target);
   111 
   112 
   113 (* notes *)
   114 
   115 fun import_export_proof ctxt (name, raw_th) =
   116   let
   117     val thy = ProofContext.theory_of ctxt;
   118     val thy_ctxt = ProofContext.init thy;
   119     val certT = Thm.ctyp_of thy;
   120     val cert = Thm.cterm_of thy;
   121 
   122     (*export assumes/defines*)
   123     val th = Goal.norm_result raw_th;
   124     val (defs, th') = Local_Defs.export ctxt thy_ctxt th;
   125     val assms = map (MetaSimplifier.rewrite_rule defs o Thm.assume) (Assumption.all_assms_of ctxt);
   126     val nprems = Thm.nprems_of th' - Thm.nprems_of th;
   127 
   128     (*export fixes*)
   129     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   130     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   131     val (th'' :: vs) = (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   132       |> Variable.export ctxt thy_ctxt
   133       |> Drule.zero_var_indexes_list;
   134 
   135     (*thm definition*)
   136     val result = PureThy.name_thm true true name th'';
   137 
   138     (*import fixes*)
   139     val (tvars, vars) =
   140       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   141       |>> map Logic.dest_type;
   142 
   143     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   144     val inst = filter (is_Var o fst) (vars ~~ frees);
   145     val cinstT = map (pairself certT o apfst TVar) instT;
   146     val cinst = map (pairself (cert o Term.map_types (Term_Subst.instantiateT instT))) inst;
   147     val result' = Thm.instantiate (cinstT, cinst) result;
   148 
   149     (*import assumes/defines*)
   150     val assm_tac = FIRST' (map (fn assm => Tactic.compose_tac (false, assm, 0)) assms);
   151     val result'' =
   152       (case SINGLE (Seq.INTERVAL assm_tac 1 nprems) result' of
   153         NONE => raise THM ("Failed to re-import result", 0, [result'])
   154       | SOME res => Local_Defs.contract ctxt defs (Thm.cprop_of th) res)
   155       |> Goal.norm_result
   156       |> PureThy.name_thm false false name;
   157 
   158   in (result'', result) end;
   159 
   160 fun notes (Target {target, is_locale, ...}) kind facts lthy =
   161   let
   162     val thy = ProofContext.theory_of lthy;
   163     val facts' = facts
   164       |> map (fn (a, bs) => (a, PureThy.burrow_fact (PureThy.name_multi
   165           (Local_Theory.full_name lthy (fst a))) bs))
   166       |> PureThy.map_facts (import_export_proof lthy);
   167     val local_facts = PureThy.map_facts #1 facts'
   168       |> Attrib.map_facts (Attrib.attribute_i thy);
   169     val target_facts = PureThy.map_facts #1 facts'
   170       |> is_locale ? Element.facts_map (Element.morph_ctxt (Local_Theory.target_morphism lthy));
   171     val global_facts = PureThy.map_facts #2 facts'
   172       |> Attrib.map_facts (if is_locale then K I else Attrib.attribute_i thy);
   173   in
   174     lthy
   175     |> Local_Theory.theory (PureThy.note_thmss kind global_facts #> snd)
   176     |> not is_locale ? Local_Theory.target (ProofContext.note_thmss kind global_facts #> snd)
   177     |> is_locale ? Local_Theory.target (Locale.add_thmss target kind target_facts)
   178     |> ProofContext.note_thmss kind local_facts
   179   end;
   180 
   181 
   182 (* consts *)
   183 
   184 fun fork_mixfix (Target {is_locale, is_class, ...}) mx =
   185   if not is_locale then (NoSyn, NoSyn, mx)
   186   else if not is_class then (NoSyn, mx, NoSyn)
   187   else (mx, NoSyn, NoSyn);
   188 
   189 fun locale_const (Target {target, is_class, ...}) (prmode as (mode, _)) ((b, mx), rhs) phi =
   190   let
   191     val b' = Morphism.binding phi b;
   192     val rhs' = Morphism.term phi rhs;
   193     val arg = (b', Term.close_schematic_term rhs');
   194     val same_shape = Term.aconv_untyped (rhs, rhs');
   195     (* FIXME workaround based on educated guess *)
   196     val prefix' = Binding.prefix_of b';
   197     val class_global =
   198       Binding.eq_name (b, b') andalso
   199       not (null prefix') andalso
   200       fst (snd (split_last prefix')) = Class_Target.class_prefix target;
   201   in
   202     not (is_class andalso (same_shape orelse class_global)) ?
   203       (Context.mapping_result
   204         (Sign.add_abbrev PrintMode.internal arg)
   205         (ProofContext.add_abbrev PrintMode.internal arg)
   206       #-> (fn (lhs' as Const (d, _), _) =>
   207           same_shape ?
   208             (Context.mapping (Sign.revert_abbrev mode d) (ProofContext.revert_abbrev mode d) #>
   209              Morphism.form (ProofContext.target_notation true prmode [(lhs', mx)]))))
   210   end;
   211 
   212 
   213 (* abbrev *)
   214 
   215 fun abbrev (ta as Target {target, is_locale, is_class, ...}) prmode ((b, mx), t) lthy =
   216   let
   217     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   218     val target_ctxt = Local_Theory.target_of lthy;
   219 
   220     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   221     val t' = Assumption.export_term lthy target_ctxt t;
   222     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   223     val u = fold_rev lambda xs t';
   224     val global_rhs =
   225       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   226   in
   227     lthy |>
   228      (if is_locale then
   229         Local_Theory.theory_result (Sign.add_abbrev PrintMode.internal (b, global_rhs))
   230         #-> (fn (lhs, _) =>
   231           let val lhs' = Term.list_comb (Logic.unvarify lhs, xs) in
   232             term_syntax ta false (locale_const ta prmode ((b, mx2), lhs')) #>
   233             is_class ? class_target ta (Class_Target.abbrev target prmode ((b, mx1), t'))
   234           end)
   235       else
   236         Local_Theory.theory
   237           (Sign.add_abbrev (#1 prmode) (b, global_rhs) #-> (fn (lhs, _) =>
   238            Sign.notation true prmode [(lhs, mx3)])))
   239     |> ProofContext.add_abbrev PrintMode.internal (b, t) |> snd
   240     |> Local_Defs.fixed_abbrev ((b, NoSyn), t)
   241   end;
   242 
   243 
   244 (* define *)
   245 
   246 local
   247 
   248 fun syntax_error c = error ("Illegal mixfix syntax for overloaded constant " ^ quote c);
   249 
   250 fun declare_const (ta as Target {target, is_locale, is_class, ...}) xs ((b, T), mx) lthy =
   251   let
   252     val params =
   253       rev (Variable.fixes_of (Local_Theory.target_of lthy))
   254       |> map_filter (fn (_, x) =>
   255         (case AList.lookup (op =) xs x of
   256           SOME T => SOME (x, T)
   257         | NONE => NONE));
   258     val U = map #2 params ---> T;
   259     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   260     val (const, lthy') = lthy |>
   261       (case Class_Target.instantiation_param lthy b of
   262         SOME c' =>
   263           if mx3 <> NoSyn then syntax_error c'
   264           else Local_Theory.theory_result (AxClass.declare_overloaded (c', U))
   265             ##> Class_Target.confirm_declaration b
   266       | NONE =>
   267           (case Overloading.operation lthy b of
   268             SOME (c', _) =>
   269               if mx3 <> NoSyn then syntax_error c'
   270               else Local_Theory.theory_result (Overloading.declare (c', U))
   271                 ##> Overloading.confirm b
   272           | NONE => Local_Theory.theory_result (Sign.declare_const ((b, U), mx3))));
   273     val t = Term.list_comb (const, map Free params);
   274   in
   275     lthy'
   276     |> is_locale ? term_syntax ta false (locale_const ta Syntax.mode_default ((b, mx2), t))
   277     |> is_class ? class_target ta (Class_Target.declare target ((b, mx1), t))
   278     |> Local_Defs.add_def ((b, NoSyn), t)
   279   end;
   280 
   281 in
   282 
   283 fun define ta ((b, mx), ((name, atts), rhs)) lthy =
   284   let
   285     val thy = ProofContext.theory_of lthy;
   286     val thy_ctxt = ProofContext.init thy;
   287 
   288     val name' = Thm.def_binding_optional b name;
   289 
   290     val crhs = Thm.cterm_of thy rhs;
   291     val (defs, rhs') = Local_Defs.export_cterm lthy thy_ctxt crhs ||> Thm.term_of;
   292     val rhs_conv = MetaSimplifier.rewrite true defs crhs;
   293 
   294     val xs = Variable.add_fixed (Local_Theory.target_of lthy) rhs' [];
   295     val T = Term.fastype_of rhs;
   296 
   297     (*const*)
   298     val ((lhs, local_def), lthy2) = lthy |> declare_const ta xs ((b, T), mx);
   299     val (_, lhs') = Logic.dest_equals (Thm.prop_of local_def);
   300 
   301     (*def*)
   302     val (global_def, lthy3) = lthy2
   303       |> Local_Theory.theory_result
   304         (case Overloading.operation lthy b of
   305           SOME (_, checked) => Overloading.define checked name' (fst (dest_Const lhs'), rhs')
   306         | NONE =>
   307             if is_some (Class_Target.instantiation_param lthy b)
   308             then AxClass.define_overloaded name' (fst (dest_Const lhs'), rhs')
   309             else Thm.add_def false false (name', Logic.mk_equals (lhs', rhs')));
   310     val def = Local_Defs.trans_terms lthy3
   311       [(*c == global.c xs*)     local_def,
   312        (*global.c xs == rhs'*)  global_def,
   313        (*rhs' == rhs*)          Thm.symmetric rhs_conv];
   314 
   315     (*note*)
   316     val ([(res_name, [res])], lthy4) = lthy3
   317       |> notes ta "" [((name', atts), [([def], [])])];
   318   in ((lhs, (res_name, res)), lthy4) end;
   319 
   320 end;
   321 
   322 
   323 (* init various targets *)
   324 
   325 local
   326 
   327 fun init_target _ NONE = global_target
   328   | init_target thy (SOME target) =
   329       if Locale.defined thy target
   330       then make_target target true (Class_Target.is_class thy target) ([], [], []) []
   331       else error ("No such locale: " ^ quote target);
   332 
   333 fun init_ctxt (Target {target, is_locale, is_class, instantiation, overloading}) =
   334   if not (null (#1 instantiation)) then Class_Target.init_instantiation instantiation
   335   else if not (null overloading) then Overloading.init overloading
   336   else if not is_locale then ProofContext.init
   337   else if not is_class then Locale.init target
   338   else Class_Target.init target;
   339 
   340 fun init_lthy (ta as Target {target, instantiation, overloading, ...}) =
   341   Data.put ta #>
   342   Local_Theory.init NONE (Long_Name.base_name target)
   343    {pretty = pretty ta,
   344     abbrev = abbrev ta,
   345     define = define ta,
   346     notes = notes ta,
   347     type_syntax = type_syntax ta,
   348     term_syntax = term_syntax ta,
   349     declaration = declaration ta,
   350     reinit = fn lthy => init_lthy_ctxt ta (ProofContext.theory_of lthy),
   351     exit = Local_Theory.target_of o
   352       (if not (null (#1 instantiation)) then Class_Target.conclude_instantiation
   353        else if not (null overloading) then Overloading.conclude
   354        else I)}
   355 and init_lthy_ctxt ta = init_lthy ta o init_ctxt ta;
   356 
   357 fun gen_overloading prep_const raw_ops thy =
   358   let
   359     val ctxt = ProofContext.init thy;
   360     val ops = raw_ops |> map (fn (name, const, checked) =>
   361       (name, Term.dest_Const (prep_const ctxt const), checked));
   362   in thy |> init_lthy_ctxt (make_target "" false false ([], [], []) ops) end;
   363 
   364 in
   365 
   366 fun init target thy = init_lthy_ctxt (init_target thy target) thy;
   367 
   368 fun context_cmd "-" thy = init NONE thy
   369   | context_cmd target thy = init (SOME (Locale.intern thy target)) thy;
   370 
   371 fun instantiation arities = init_lthy_ctxt (make_target "" false false arities []);
   372 fun instantiation_cmd arities thy = instantiation (Class_Target.read_multi_arity thy arities) thy;
   373 
   374 val overloading = gen_overloading (fn ctxt => Syntax.check_term ctxt o Const);
   375 val overloading_cmd = gen_overloading Syntax.read_term;
   376 
   377 end;
   378 
   379 end;
   380