src/HOL/Power.thy
author wenzelm
Wed Aug 10 22:05:36 2016 +0200 (2016-08-10)
changeset 63654 f90e3926e627
parent 63648 f9f3006a5579
child 63924 f91766530e13
permissions -rw-r--r--
misc tuning and modernization;
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section \<open>Exponentiation\<close>
     7 
     8 theory Power
     9   imports Num
    10 begin
    11 
    12 subsection \<open>Powers for Arbitrary Monoids\<close>
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a"  (infixr "^" 80)
    18   where
    19     power_0: "a ^ 0 = 1"
    20   | power_Suc: "a ^ Suc n = a * a ^ n"
    21 
    22 notation (latex output)
    23   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    24 
    25 text \<open>Special syntax for squares.\<close>
    26 abbreviation power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999)
    27   where "x\<^sup>2 \<equiv> x ^ 2"
    28 
    29 end
    30 
    31 context monoid_mult
    32 begin
    33 
    34 subclass power .
    35 
    36 lemma power_one [simp]: "1 ^ n = 1"
    37   by (induct n) simp_all
    38 
    39 lemma power_one_right [simp]: "a ^ 1 = a"
    40   by simp
    41 
    42 lemma power_Suc0_right [simp]: "a ^ Suc 0 = a"
    43   by simp
    44 
    45 lemma power_commutes: "a ^ n * a = a * a ^ n"
    46   by (induct n) (simp_all add: mult.assoc)
    47 
    48 lemma power_Suc2: "a ^ Suc n = a ^ n * a"
    49   by (simp add: power_commutes)
    50 
    51 lemma power_add: "a ^ (m + n) = a ^ m * a ^ n"
    52   by (induct m) (simp_all add: algebra_simps)
    53 
    54 lemma power_mult: "a ^ (m * n) = (a ^ m) ^ n"
    55   by (induct n) (simp_all add: power_add)
    56 
    57 lemma power2_eq_square: "a\<^sup>2 = a * a"
    58   by (simp add: numeral_2_eq_2)
    59 
    60 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    61   by (simp add: numeral_3_eq_3 mult.assoc)
    62 
    63 lemma power_even_eq: "a ^ (2 * n) = (a ^ n)\<^sup>2"
    64   by (subst mult.commute) (simp add: power_mult)
    65 
    66 lemma power_odd_eq: "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    67   by (simp add: power_even_eq)
    68 
    69 lemma power_numeral_even: "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    70   by (simp only: numeral_Bit0 power_add Let_def)
    71 
    72 lemma power_numeral_odd: "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    73   by (simp only: numeral_Bit1 One_nat_def add_Suc_right add_0_right
    74       power_Suc power_add Let_def mult.assoc)
    75 
    76 lemma funpow_times_power: "(times x ^^ f x) = times (x ^ f x)"
    77 proof (induct "f x" arbitrary: f)
    78   case 0
    79   then show ?case by (simp add: fun_eq_iff)
    80 next
    81   case (Suc n)
    82   define g where "g x = f x - 1" for x
    83   with Suc have "n = g x" by simp
    84   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
    85   moreover from Suc g_def have "f x = g x + 1" by simp
    86   ultimately show ?case
    87     by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
    88 qed
    89 
    90 lemma power_commuting_commutes:
    91   assumes "x * y = y * x"
    92   shows "x ^ n * y = y * x ^n"
    93 proof (induct n)
    94   case 0
    95   then show ?case by simp
    96 next
    97   case (Suc n)
    98   have "x ^ Suc n * y = x ^ n * y * x"
    99     by (subst power_Suc2) (simp add: assms ac_simps)
   100   also have "\<dots> = y * x ^ Suc n"
   101     by (simp only: Suc power_Suc2) (simp add: ac_simps)
   102   finally show ?case .
   103 qed
   104 
   105 lemma power_minus_mult: "0 < n \<Longrightarrow> a ^ (n - 1) * a = a ^ n"
   106   by (simp add: power_commutes split: nat_diff_split)
   107 
   108 end
   109 
   110 context comm_monoid_mult
   111 begin
   112 
   113 lemma power_mult_distrib [field_simps]: "(a * b) ^ n = (a ^ n) * (b ^ n)"
   114   by (induct n) (simp_all add: ac_simps)
   115 
   116 end
   117 
   118 text \<open>Extract constant factors from powers.\<close>
   119 declare power_mult_distrib [where a = "numeral w" for w, simp]
   120 declare power_mult_distrib [where b = "numeral w" for w, simp]
   121 
   122 lemma power_add_numeral [simp]: "a^numeral m * a^numeral n = a^numeral (m + n)"
   123   for a :: "'a::monoid_mult"
   124   by (simp add: power_add [symmetric])
   125 
   126 lemma power_add_numeral2 [simp]: "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   127   for a :: "'a::monoid_mult"
   128   by (simp add: mult.assoc [symmetric])
   129 
   130 lemma power_mult_numeral [simp]: "(a^numeral m)^numeral n = a^numeral (m * n)"
   131   for a :: "'a::monoid_mult"
   132   by (simp only: numeral_mult power_mult)
   133 
   134 context semiring_numeral
   135 begin
   136 
   137 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   138   by (simp only: sqr_conv_mult numeral_mult)
   139 
   140 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   141   by (induct l)
   142     (simp_all only: numeral_class.numeral.simps pow.simps
   143       numeral_sqr numeral_mult power_add power_one_right)
   144 
   145 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   146   by (rule numeral_pow [symmetric])
   147 
   148 end
   149 
   150 context semiring_1
   151 begin
   152 
   153 lemma of_nat_power [simp]: "of_nat (m ^ n) = of_nat m ^ n"
   154   by (induct n) simp_all
   155 
   156 lemma zero_power: "0 < n \<Longrightarrow> 0 ^ n = 0"
   157   by (cases n) simp_all
   158 
   159 lemma power_zero_numeral [simp]: "0 ^ numeral k = 0"
   160   by (simp add: numeral_eq_Suc)
   161 
   162 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   163   by (rule power_zero_numeral)
   164 
   165 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   166   by (rule power_one)
   167 
   168 lemma power_0_Suc [simp]: "0 ^ Suc n = 0"
   169   by simp
   170 
   171 text \<open>It looks plausible as a simprule, but its effect can be strange.\<close>
   172 lemma power_0_left: "0 ^ n = (if n = 0 then 1 else 0)"
   173   by (cases n) simp_all
   174 
   175 end
   176 
   177 context comm_semiring_1
   178 begin
   179 
   180 text \<open>The divides relation.\<close>
   181 
   182 lemma le_imp_power_dvd:
   183   assumes "m \<le> n"
   184   shows "a ^ m dvd a ^ n"
   185 proof
   186   from assms have "a ^ n = a ^ (m + (n - m))" by simp
   187   also have "\<dots> = a ^ m * a ^ (n - m)" by (rule power_add)
   188   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   189 qed
   190 
   191 lemma power_le_dvd: "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   192   by (rule dvd_trans [OF le_imp_power_dvd])
   193 
   194 lemma dvd_power_same: "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   195   by (induct n) (auto simp add: mult_dvd_mono)
   196 
   197 lemma dvd_power_le: "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   198   by (rule power_le_dvd [OF dvd_power_same])
   199 
   200 lemma dvd_power [simp]:
   201   fixes n :: nat
   202   assumes "n > 0 \<or> x = 1"
   203   shows "x dvd (x ^ n)"
   204   using assms
   205 proof
   206   assume "0 < n"
   207   then have "x ^ n = x ^ Suc (n - 1)" by simp
   208   then show "x dvd (x ^ n)" by simp
   209 next
   210   assume "x = 1"
   211   then show "x dvd (x ^ n)" by simp
   212 qed
   213 
   214 end
   215 
   216 context semiring_1_no_zero_divisors
   217 begin
   218 
   219 subclass power .
   220 
   221 lemma power_eq_0_iff [simp]: "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   222   by (induct n) auto
   223 
   224 lemma power_not_zero: "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   225   by (induct n) auto
   226 
   227 lemma zero_eq_power2 [simp]: "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   228   unfolding power2_eq_square by simp
   229 
   230 end
   231 
   232 context ring_1
   233 begin
   234 
   235 lemma power_minus: "(- a) ^ n = (- 1) ^ n * a ^ n"
   236 proof (induct n)
   237   case 0
   238   show ?case by simp
   239 next
   240   case (Suc n)
   241   then show ?case
   242     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   243 qed
   244 
   245 lemma power_minus': "NO_MATCH 1 x \<Longrightarrow> (-x) ^ n = (-1)^n * x ^ n"
   246   by (rule power_minus)
   247 
   248 lemma power_minus_Bit0: "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   249   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   250     power_one_right mult_minus_left mult_minus_right minus_minus)
   251 
   252 lemma power_minus_Bit1: "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   253   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   254 
   255 lemma power2_minus [simp]: "(- a)\<^sup>2 = a\<^sup>2"
   256   by (fact power_minus_Bit0)
   257 
   258 lemma power_minus1_even [simp]: "(- 1) ^ (2*n) = 1"
   259 proof (induct n)
   260   case 0
   261   show ?case by simp
   262 next
   263   case (Suc n)
   264   then show ?case by (simp add: power_add power2_eq_square)
   265 qed
   266 
   267 lemma power_minus1_odd: "(- 1) ^ Suc (2*n) = -1"
   268   by simp
   269 
   270 lemma power_minus_even [simp]: "(-a) ^ (2*n) = a ^ (2*n)"
   271   by (simp add: power_minus [of a])
   272 
   273 end
   274 
   275 context ring_1_no_zero_divisors
   276 begin
   277 
   278 lemma power2_eq_1_iff: "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   279   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
   280 
   281 end
   282 
   283 context idom
   284 begin
   285 
   286 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   287   unfolding power2_eq_square by (rule square_eq_iff)
   288 
   289 end
   290 
   291 context algebraic_semidom
   292 begin
   293 
   294 lemma div_power: "b dvd a \<Longrightarrow> (a div b) ^ n = a ^ n div b ^ n"
   295   by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
   296 
   297 lemma is_unit_power_iff: "is_unit (a ^ n) \<longleftrightarrow> is_unit a \<or> n = 0"
   298   by (induct n) (auto simp add: is_unit_mult_iff)
   299 
   300 end
   301 
   302 context normalization_semidom
   303 begin
   304 
   305 lemma normalize_power: "normalize (a ^ n) = normalize a ^ n"
   306   by (induct n) (simp_all add: normalize_mult)
   307 
   308 lemma unit_factor_power: "unit_factor (a ^ n) = unit_factor a ^ n"
   309   by (induct n) (simp_all add: unit_factor_mult)
   310 
   311 end
   312 
   313 context division_ring
   314 begin
   315 
   316 text \<open>Perhaps these should be simprules.\<close>
   317 lemma power_inverse [field_simps, divide_simps]: "inverse a ^ n = inverse (a ^ n)"
   318 proof (cases "a = 0")
   319   case True
   320   then show ?thesis by (simp add: power_0_left)
   321 next
   322   case False
   323   then have "inverse (a ^ n) = inverse a ^ n"
   324     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
   325   then show ?thesis by simp
   326 qed
   327 
   328 lemma power_one_over [field_simps, divide_simps]: "(1 / a) ^ n = 1 / a ^ n"
   329   using power_inverse [of a] by (simp add: divide_inverse)
   330 
   331 end
   332 
   333 context field
   334 begin
   335 
   336 lemma power_diff:
   337   assumes "a \<noteq> 0"
   338   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   339   by (induct m n rule: diff_induct) (simp_all add: assms power_not_zero)
   340 
   341 lemma power_divide [field_simps, divide_simps]: "(a / b) ^ n = a ^ n / b ^ n"
   342   by (induct n) simp_all
   343 
   344 end
   345 
   346 
   347 subsection \<open>Exponentiation on ordered types\<close>
   348 
   349 context linordered_semidom
   350 begin
   351 
   352 lemma zero_less_power [simp]: "0 < a \<Longrightarrow> 0 < a ^ n"
   353   by (induct n) simp_all
   354 
   355 lemma zero_le_power [simp]: "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   356   by (induct n) simp_all
   357 
   358 lemma power_mono: "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   359   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   360 
   361 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   362   using power_mono [of 1 a n] by simp
   363 
   364 lemma power_le_one: "0 \<le> a \<Longrightarrow> a \<le> 1 \<Longrightarrow> a ^ n \<le> 1"
   365   using power_mono [of a 1 n] by simp
   366 
   367 lemma power_gt1_lemma:
   368   assumes gt1: "1 < a"
   369   shows "1 < a * a ^ n"
   370 proof -
   371   from gt1 have "0 \<le> a"
   372     by (fact order_trans [OF zero_le_one less_imp_le])
   373   from gt1 have "1 * 1 < a * 1" by simp
   374   also from gt1 have "\<dots> \<le> a * a ^ n"
   375     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le zero_le_one order_refl)
   376   finally show ?thesis by simp
   377 qed
   378 
   379 lemma power_gt1: "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   380   by (simp add: power_gt1_lemma)
   381 
   382 lemma one_less_power [simp]: "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   383   by (cases n) (simp_all add: power_gt1_lemma)
   384 
   385 lemma power_le_imp_le_exp:
   386   assumes gt1: "1 < a"
   387   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   388 proof (induct m arbitrary: n)
   389   case 0
   390   show ?case by simp
   391 next
   392   case (Suc m)
   393   show ?case
   394   proof (cases n)
   395     case 0
   396     with Suc have "a * a ^ m \<le> 1" by simp
   397     with gt1 show ?thesis
   398       by (force simp only: power_gt1_lemma not_less [symmetric])
   399   next
   400     case (Suc n)
   401     with Suc.prems Suc.hyps show ?thesis
   402       by (force dest: mult_left_le_imp_le simp add: less_trans [OF zero_less_one gt1])
   403   qed
   404 qed
   405 
   406 lemma of_nat_zero_less_power_iff [simp]: "of_nat x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
   407   by (induct n) auto
   408 
   409 text \<open>Surely we can strengthen this? It holds for \<open>0<a<1\<close> too.\<close>
   410 lemma power_inject_exp [simp]: "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   411   by (force simp add: order_antisym power_le_imp_le_exp)
   412 
   413 text \<open>
   414   Can relax the first premise to @{term "0<a"} in the case of the
   415   natural numbers.
   416 \<close>
   417 lemma power_less_imp_less_exp: "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   418   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"] power_le_imp_le_exp)
   419 
   420 lemma power_strict_mono [rule_format]: "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   421   by (induct n) (auto simp: mult_strict_mono le_less_trans [of 0 a b])
   422 
   423 text\<open>Lemma for \<open>power_strict_decreasing\<close>\<close>
   424 lemma power_Suc_less: "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   425   by (induct n) (auto simp: mult_strict_left_mono)
   426 
   427 lemma power_strict_decreasing [rule_format]: "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   428 proof (induct N)
   429   case 0
   430   then show ?case by simp
   431 next
   432   case (Suc N)
   433   then show ?case
   434     apply (auto simp add: power_Suc_less less_Suc_eq)
   435     apply (subgoal_tac "a * a^N < 1 * a^n")
   436      apply simp
   437     apply (rule mult_strict_mono)
   438        apply auto
   439     done
   440 qed
   441 
   442 text \<open>Proof resembles that of \<open>power_strict_decreasing\<close>.\<close>
   443 lemma power_decreasing: "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<Longrightarrow> a ^ N \<le> a ^ n"
   444 proof (induct N)
   445   case 0
   446   then show ?case by simp
   447 next
   448   case (Suc N)
   449   then show ?case
   450     apply (auto simp add: le_Suc_eq)
   451     apply (subgoal_tac "a * a^N \<le> 1 * a^n")
   452      apply simp
   453     apply (rule mult_mono)
   454        apply auto
   455     done
   456 qed
   457 
   458 lemma power_Suc_less_one: "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   459   using power_strict_decreasing [of 0 "Suc n" a] by simp
   460 
   461 text \<open>Proof again resembles that of \<open>power_strict_decreasing\<close>.\<close>
   462 lemma power_increasing: "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   463 proof (induct N)
   464   case 0
   465   then show ?case by simp
   466 next
   467   case (Suc N)
   468   then show ?case
   469     apply (auto simp add: le_Suc_eq)
   470     apply (subgoal_tac "1 * a^n \<le> a * a^N")
   471      apply simp
   472     apply (rule mult_mono)
   473        apply (auto simp add: order_trans [OF zero_le_one])
   474     done
   475 qed
   476 
   477 text \<open>Lemma for \<open>power_strict_increasing\<close>.\<close>
   478 lemma power_less_power_Suc: "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   479   by (induct n) (auto simp: mult_strict_left_mono less_trans [OF zero_less_one])
   480 
   481 lemma power_strict_increasing: "n < N \<Longrightarrow> 1 < a \<Longrightarrow> a ^ n < a ^ N"
   482 proof (induct N)
   483   case 0
   484   then show ?case by simp
   485 next
   486   case (Suc N)
   487   then show ?case
   488     apply (auto simp add: power_less_power_Suc less_Suc_eq)
   489     apply (subgoal_tac "1 * a^n < a * a^N")
   490      apply simp
   491     apply (rule mult_strict_mono)
   492     apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   493     done
   494 qed
   495 
   496 lemma power_increasing_iff [simp]: "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   497   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   498 
   499 lemma power_strict_increasing_iff [simp]: "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   500   by (blast intro: power_less_imp_less_exp power_strict_increasing)
   501 
   502 lemma power_le_imp_le_base:
   503   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   504     and "0 \<le> b"
   505   shows "a \<le> b"
   506 proof (rule ccontr)
   507   assume "\<not> ?thesis"
   508   then have "b < a" by (simp only: linorder_not_le)
   509   then have "b ^ Suc n < a ^ Suc n"
   510     by (simp only: assms(2) power_strict_mono)
   511   with le show False
   512     by (simp add: linorder_not_less [symmetric])
   513 qed
   514 
   515 lemma power_less_imp_less_base:
   516   assumes less: "a ^ n < b ^ n"
   517   assumes nonneg: "0 \<le> b"
   518   shows "a < b"
   519 proof (rule contrapos_pp [OF less])
   520   assume "\<not> ?thesis"
   521   then have "b \<le> a" by (simp only: linorder_not_less)
   522   from this nonneg have "b ^ n \<le> a ^ n" by (rule power_mono)
   523   then show "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   524 qed
   525 
   526 lemma power_inject_base: "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   527   by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   528 
   529 lemma power_eq_imp_eq_base: "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   530   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   531 
   532 lemma power_eq_iff_eq_base: "0 < n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a ^ n = b ^ n \<longleftrightarrow> a = b"
   533   using power_eq_imp_eq_base [of a n b] by auto
   534 
   535 lemma power2_le_imp_le: "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   536   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   537 
   538 lemma power2_less_imp_less: "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   539   by (rule power_less_imp_less_base)
   540 
   541 lemma power2_eq_imp_eq: "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   542   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   543 
   544 lemma power_Suc_le_self: "0 \<le> a \<Longrightarrow> a \<le> 1 \<Longrightarrow> a ^ Suc n \<le> a"
   545   using power_decreasing [of 1 "Suc n" a] by simp
   546 
   547 end
   548 
   549 context linordered_ring_strict
   550 begin
   551 
   552 lemma sum_squares_eq_zero_iff: "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   553   by (simp add: add_nonneg_eq_0_iff)
   554 
   555 lemma sum_squares_le_zero_iff: "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   556   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   557 
   558 lemma sum_squares_gt_zero_iff: "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   559   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   560 
   561 end
   562 
   563 context linordered_idom
   564 begin
   565 
   566 lemma power_abs: "\<bar>a ^ n\<bar> = \<bar>a\<bar> ^ n"
   567   by (induct n) (auto simp add: abs_mult)
   568 
   569 lemma abs_power_minus [simp]: "\<bar>(-a) ^ n\<bar> = \<bar>a ^ n\<bar>"
   570   by (simp add: power_abs)
   571 
   572 lemma zero_less_power_abs_iff [simp]: "0 < \<bar>a\<bar> ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   573 proof (induct n)
   574   case 0
   575   show ?case by simp
   576 next
   577   case Suc
   578   then show ?case by (auto simp: zero_less_mult_iff)
   579 qed
   580 
   581 lemma zero_le_power_abs [simp]: "0 \<le> \<bar>a\<bar> ^ n"
   582   by (rule zero_le_power [OF abs_ge_zero])
   583 
   584 lemma zero_le_power2 [simp]: "0 \<le> a\<^sup>2"
   585   by (simp add: power2_eq_square)
   586 
   587 lemma zero_less_power2 [simp]: "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   588   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   589 
   590 lemma power2_less_0 [simp]: "\<not> a\<^sup>2 < 0"
   591   by (force simp add: power2_eq_square mult_less_0_iff)
   592 
   593 lemma power2_less_eq_zero_iff [simp]: "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   594   by (simp add: le_less)
   595 
   596 lemma abs_power2 [simp]: "\<bar>a\<^sup>2\<bar> = a\<^sup>2"
   597   by (simp add: power2_eq_square)
   598 
   599 lemma power2_abs [simp]: "\<bar>a\<bar>\<^sup>2 = a\<^sup>2"
   600   by (simp add: power2_eq_square)
   601 
   602 lemma odd_power_less_zero: "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   603 proof (induct n)
   604   case 0
   605   then show ?case by simp
   606 next
   607   case (Suc n)
   608   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   609     by (simp add: ac_simps power_add power2_eq_square)
   610   then show ?case
   611     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   612 qed
   613 
   614 lemma odd_0_le_power_imp_0_le: "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   615   using odd_power_less_zero [of a n]
   616   by (force simp add: linorder_not_less [symmetric])
   617 
   618 lemma zero_le_even_power'[simp]: "0 \<le> a ^ (2*n)"
   619 proof (induct n)
   620   case 0
   621   show ?case by simp
   622 next
   623   case (Suc n)
   624   have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)"
   625     by (simp add: ac_simps power_add power2_eq_square)
   626   then show ?case
   627     by (simp add: Suc zero_le_mult_iff)
   628 qed
   629 
   630 lemma sum_power2_ge_zero: "0 \<le> x\<^sup>2 + y\<^sup>2"
   631   by (intro add_nonneg_nonneg zero_le_power2)
   632 
   633 lemma not_sum_power2_lt_zero: "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   634   unfolding not_less by (rule sum_power2_ge_zero)
   635 
   636 lemma sum_power2_eq_zero_iff: "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   637   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   638 
   639 lemma sum_power2_le_zero_iff: "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   640   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   641 
   642 lemma sum_power2_gt_zero_iff: "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   643   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   644 
   645 lemma abs_le_square_iff: "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   646   (is "?lhs \<longleftrightarrow> ?rhs")
   647 proof
   648   assume ?lhs
   649   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono) simp
   650   then show ?rhs by simp
   651 next
   652   assume ?rhs
   653   then show ?lhs
   654     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   655 qed
   656 
   657 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> \<bar>x\<bar> \<le> 1"
   658   using abs_le_square_iff [of x 1] by simp
   659 
   660 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> \<bar>x\<bar> = 1"
   661   by (auto simp add: abs_if power2_eq_1_iff)
   662 
   663 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> \<bar>x\<bar> < 1"
   664   using  abs_square_eq_1 [of x] abs_square_le_1 [of x] by (auto simp add: le_less)
   665 
   666 end
   667 
   668 
   669 subsection \<open>Miscellaneous rules\<close>
   670 
   671 lemma (in linordered_semidom) self_le_power: "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
   672   using power_increasing [of 1 n a] power_one_right [of a] by auto
   673 
   674 lemma (in power) power_eq_if: "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   675   unfolding One_nat_def by (cases m) simp_all
   676 
   677 lemma (in comm_semiring_1) power2_sum: "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   678   by (simp add: algebra_simps power2_eq_square mult_2_right)
   679 
   680 context comm_ring_1
   681 begin
   682 
   683 lemma power2_diff: "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   684   by (simp add: algebra_simps power2_eq_square mult_2_right)
   685 
   686 lemma power2_commute: "(x - y)\<^sup>2 = (y - x)\<^sup>2"
   687   by (simp add: algebra_simps power2_eq_square)
   688 
   689 lemma minus_power_mult_self: "(- a) ^ n * (- a) ^ n = a ^ (2 * n)"
   690   by (simp add: power_mult_distrib [symmetric])
   691     (simp add: power2_eq_square [symmetric] power_mult [symmetric])
   692 
   693 lemma minus_one_mult_self [simp]: "(- 1) ^ n * (- 1) ^ n = 1"
   694   using minus_power_mult_self [of 1 n] by simp
   695 
   696 lemma left_minus_one_mult_self [simp]: "(- 1) ^ n * ((- 1) ^ n * a) = a"
   697   by (simp add: mult.assoc [symmetric])
   698 
   699 end
   700 
   701 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
   702 
   703 lemmas zero_compare_simps =
   704   add_strict_increasing add_strict_increasing2 add_increasing
   705   zero_le_mult_iff zero_le_divide_iff
   706   zero_less_mult_iff zero_less_divide_iff
   707   mult_le_0_iff divide_le_0_iff
   708   mult_less_0_iff divide_less_0_iff
   709   zero_le_power2 power2_less_0
   710 
   711 
   712 subsection \<open>Exponentiation for the Natural Numbers\<close>
   713 
   714 lemma nat_one_le_power [simp]: "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   715   by (rule one_le_power [of i n, unfolded One_nat_def])
   716 
   717 lemma nat_zero_less_power_iff [simp]: "x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
   718   for x :: nat
   719   by (induct n) auto
   720 
   721 lemma nat_power_eq_Suc_0_iff [simp]: "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   722   by (induct m) auto
   723 
   724 lemma power_Suc_0 [simp]: "Suc 0 ^ n = Suc 0"
   725   by simp
   726 
   727 text \<open>
   728   Valid for the naturals, but what if \<open>0 < i < 1\<close>? Premises cannot be
   729   weakened: consider the case where \<open>i = 0\<close>, \<open>m = 1\<close> and \<open>n = 0\<close>.
   730 \<close>
   731 
   732 lemma nat_power_less_imp_less:
   733   fixes i :: nat
   734   assumes nonneg: "0 < i"
   735   assumes less: "i ^ m < i ^ n"
   736   shows "m < n"
   737 proof (cases "i = 1")
   738   case True
   739   with less power_one [where 'a = nat] show ?thesis by simp
   740 next
   741   case False
   742   with nonneg have "1 < i" by auto
   743   from power_strict_increasing_iff [OF this] less show ?thesis ..
   744 qed
   745 
   746 lemma power_dvd_imp_le: "i ^ m dvd i ^ n \<Longrightarrow> 1 < i \<Longrightarrow> m \<le> n"
   747   for i m n :: nat
   748   apply (rule power_le_imp_le_exp)
   749    apply assumption
   750   apply (erule dvd_imp_le)
   751   apply simp
   752   done
   753 
   754 lemma power2_nat_le_eq_le: "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   755   for m n :: nat
   756   by (auto intro: power2_le_imp_le power_mono)
   757 
   758 lemma power2_nat_le_imp_le:
   759   fixes m n :: nat
   760   assumes "m\<^sup>2 \<le> n"
   761   shows "m \<le> n"
   762 proof (cases m)
   763   case 0
   764   then show ?thesis by simp
   765 next
   766   case (Suc k)
   767   show ?thesis
   768   proof (rule ccontr)
   769     assume "\<not> ?thesis"
   770     then have "n < m" by simp
   771     with assms Suc show False
   772       by (simp add: power2_eq_square)
   773   qed
   774 qed
   775 
   776 
   777 subsubsection \<open>Cardinality of the Powerset\<close>
   778 
   779 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   780   unfolding UNIV_bool by simp
   781 
   782 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   783 proof (induct rule: finite_induct)
   784   case empty
   785   show ?case by auto
   786 next
   787   case (insert x A)
   788   then have "inj_on (insert x) (Pow A)"
   789     unfolding inj_on_def by (blast elim!: equalityE)
   790   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A"
   791     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   792   with insert show ?case
   793     apply (simp add: Pow_insert)
   794     apply (subst card_Un_disjoint)
   795        apply auto
   796     done
   797 qed
   798 
   799 
   800 subsection \<open>Code generator tweak\<close>
   801 
   802 code_identifier
   803   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   804 
   805 end