src/HOL/Set.thy
author nipkow
Sun Dec 22 10:43:43 2002 +0100 (2002-12-22)
changeset 13763 f94b569cd610
parent 13653 ef123b9e8089
child 13764 3e180bf68496
permissions -rw-r--r--
added print translations tha avoid eta contraction for important binders.
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* Set theory for higher-order logic *}
     8 
     9 theory Set = HOL:
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 typedecl 'a set
    19 arities set :: (type) type
    20 
    21 consts
    22   "{}"          :: "'a set"                             ("{}")
    23   UNIV          :: "'a set"
    24   insert        :: "'a => 'a set => 'a set"
    25   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    26   Int           :: "'a set => 'a set => 'a set"          (infixl 70)
    27   Un            :: "'a set => 'a set => 'a set"          (infixl 65)
    28   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    29   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    30   Union         :: "'a set set => 'a set"                -- "union of a set"
    31   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    32   Pow           :: "'a set => 'a set set"                -- "powerset"
    33   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    34   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    35   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    36 
    37 syntax
    38   "op :"        :: "'a => 'a set => bool"                ("op :")
    39 consts
    40   "op :"        :: "'a => 'a set => bool"                ("(_/ : _)" [50, 51] 50)  -- "membership"
    41 
    42 local
    43 
    44 instance set :: (type) ord ..
    45 instance set :: (type) minus ..
    46 
    47 
    48 subsection {* Additional concrete syntax *}
    49 
    50 syntax
    51   range         :: "('a => 'b) => 'b set"             -- "of function"
    52 
    53   "op ~:"       :: "'a => 'a set => bool"                 ("op ~:")  -- "non-membership"
    54   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ ~: _)" [50, 51] 50)
    55 
    56   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    57   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    58   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    59 
    60   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" 10)
    61   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" 10)
    62   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" 10)
    63   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" 10)
    64 
    65   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    66   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (HOL)
    69   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    70   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    71 
    72 translations
    73   "range f"     == "f`UNIV"
    74   "x ~: y"      == "~ (x : y)"
    75   "{x, xs}"     == "insert x {xs}"
    76   "{x}"         == "insert x {}"
    77   "{x. P}"      => "Collect (%x. P)"
    78   "UN x y. B"   == "UN x. UN y. B"
    79   "UN x. B"     == "UNION UNIV (%x. B)"
    80   "INT x y. B"  == "INT x. INT y. B"
    81   "INT x. B"    == "INTER UNIV (%x. B)"
    82   "UN x:A. B"   => "UNION A (%x. B)"
    83   "INT x:A. B"  => "INTER A (%x. B)"
    84   "ALL x:A. P"  => "Ball A (%x. P)"
    85   "EX x:A. P"   => "Bex A (%x. P)"
    86 
    87 syntax (output)
    88   "_setle"      :: "'a set => 'a set => bool"             ("op <=")
    89   "_setle"      :: "'a set => 'a set => bool"             ("(_/ <= _)" [50, 51] 50)
    90   "_setless"    :: "'a set => 'a set => bool"             ("op <")
    91   "_setless"    :: "'a set => 'a set => bool"             ("(_/ < _)" [50, 51] 50)
    92 
    93 syntax (xsymbols)
    94   "_setle"      :: "'a set => 'a set => bool"             ("op \<subseteq>")
    95   "_setle"      :: "'a set => 'a set => bool"             ("(_/ \<subseteq> _)" [50, 51] 50)
    96   "_setless"    :: "'a set => 'a set => bool"             ("op \<subset>")
    97   "_setless"    :: "'a set => 'a set => bool"             ("(_/ \<subset> _)" [50, 51] 50)
    98   "op Int"      :: "'a set => 'a set => 'a set"           (infixl "\<inter>" 70)
    99   "op Un"       :: "'a set => 'a set => 'a set"           (infixl "\<union>" 65)
   100   "op :"        :: "'a => 'a set => bool"                 ("op \<in>")
   101   "op :"        :: "'a => 'a set => bool"                 ("(_/ \<in> _)" [50, 51] 50)
   102   "op ~:"       :: "'a => 'a set => bool"                 ("op \<notin>")
   103   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ \<notin> _)" [50, 51] 50)
   104   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" 10)
   105   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" 10)
   106   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" 10)
   107   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" 10)
   108   Union         :: "'a set set => 'a set"                 ("\<Union>_" [90] 90)
   109   Inter         :: "'a set set => 'a set"                 ("\<Inter>_" [90] 90)
   110   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   111   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   112 
   113 translations
   114   "op \<subseteq>" => "op <= :: _ set => _ set => bool"
   115   "op \<subset>" => "op <  :: _ set => _ set => bool"
   116 
   117 
   118 typed_print_translation {*
   119   let
   120     fun le_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   121           list_comb (Syntax.const "_setle", ts)
   122       | le_tr' _ _ _ = raise Match;
   123 
   124     fun less_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   125           list_comb (Syntax.const "_setless", ts)
   126       | less_tr' _ _ _ = raise Match;
   127   in [("op <=", le_tr'), ("op <", less_tr')] end
   128 *}
   129 
   130 text {*
   131   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   132   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   133   only translated if @{text "[0..n] subset bvs(e)"}.
   134 *}
   135 
   136 parse_translation {*
   137   let
   138     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   139 
   140     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   141       | nvars _ = 1;
   142 
   143     fun setcompr_tr [e, idts, b] =
   144       let
   145         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   146         val P = Syntax.const "op &" $ eq $ b;
   147         val exP = ex_tr [idts, P];
   148       in Syntax.const "Collect" $ Abs ("", dummyT, exP) end;
   149 
   150   in [("@SetCompr", setcompr_tr)] end;
   151 *}
   152 
   153 (* To avoid eta-contraction of body: *)
   154 print_translation {*
   155 let
   156   fun btr' syn [A,Abs abs] =
   157     let val (x,t) = atomic_abs_tr' abs
   158     in Syntax.const syn $ x $ A $ t end
   159 in
   160 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   161  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   162 end
   163 *}
   164 
   165 print_translation {*
   166 let
   167   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   168 
   169   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   170     let
   171       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   172         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   173             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   174             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   175 
   176         fun tr' (_ $ abs) =
   177           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   178           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   179     in if check (P, 0) then tr' P
   180        else let val (x,t) = atomic_abs_tr' abs
   181             in Syntax.const "@Coll" $ x $ t end
   182     end;
   183   in [("Collect", setcompr_tr')] end;
   184 *}
   185 
   186 
   187 subsection {* Rules and definitions *}
   188 
   189 text {* Isomorphisms between predicates and sets. *}
   190 
   191 axioms
   192   mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   193   Collect_mem_eq [simp]: "{x. x:A} = A"
   194 
   195 defs
   196   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   197   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   198 
   199 defs (overloaded)
   200   subset_def:   "A <= B         == ALL x:A. x:B"
   201   psubset_def:  "A < B          == (A::'a set) <= B & ~ A=B"
   202   Compl_def:    "- A            == {x. ~x:A}"
   203   set_diff_def: "A - B          == {x. x:A & ~x:B}"
   204 
   205 defs
   206   Un_def:       "A Un B         == {x. x:A | x:B}"
   207   Int_def:      "A Int B        == {x. x:A & x:B}"
   208   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   209   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   210   Inter_def:    "Inter S        == (INT x:S. x)"
   211   Union_def:    "Union S        == (UN x:S. x)"
   212   Pow_def:      "Pow A          == {B. B <= A}"
   213   empty_def:    "{}             == {x. False}"
   214   UNIV_def:     "UNIV           == {x. True}"
   215   insert_def:   "insert a B     == {x. x=a} Un B"
   216   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   217 
   218 
   219 subsection {* Lemmas and proof tool setup *}
   220 
   221 subsubsection {* Relating predicates and sets *}
   222 
   223 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   224   by simp
   225 
   226 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   227   by simp
   228 
   229 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   230   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   231    apply (rule Collect_mem_eq)
   232   apply (rule Collect_mem_eq)
   233   done
   234 
   235 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   236   by simp
   237 
   238 lemmas CollectE = CollectD [elim_format]
   239 
   240 
   241 subsubsection {* Bounded quantifiers *}
   242 
   243 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   244   by (simp add: Ball_def)
   245 
   246 lemmas strip = impI allI ballI
   247 
   248 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   249   by (simp add: Ball_def)
   250 
   251 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   252   by (unfold Ball_def) blast
   253 
   254 text {*
   255   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   256   @{prop "a:A"}; creates assumption @{prop "P a"}.
   257 *}
   258 
   259 ML {*
   260   local val ballE = thm "ballE"
   261   in fun ball_tac i = etac ballE i THEN contr_tac (i + 1) end;
   262 *}
   263 
   264 text {*
   265   Gives better instantiation for bound:
   266 *}
   267 
   268 ML_setup {*
   269   claset_ref() := claset() addbefore ("bspec", datac (thm "bspec") 1);
   270 *}
   271 
   272 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   273   -- {* Normally the best argument order: @{prop "P x"} constrains the
   274     choice of @{prop "x:A"}. *}
   275   by (unfold Bex_def) blast
   276 
   277 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   278   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   279   by (unfold Bex_def) blast
   280 
   281 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   282   by (unfold Bex_def) blast
   283 
   284 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   285   by (unfold Bex_def) blast
   286 
   287 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   288   -- {* Trival rewrite rule. *}
   289   by (simp add: Ball_def)
   290 
   291 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   292   -- {* Dual form for existentials. *}
   293   by (simp add: Bex_def)
   294 
   295 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   296   by blast
   297 
   298 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   299   by blast
   300 
   301 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   302   by blast
   303 
   304 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   305   by blast
   306 
   307 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   308   by blast
   309 
   310 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   311   by blast
   312 
   313 ML_setup {*
   314   local
   315     val Ball_def = thm "Ball_def";
   316     val Bex_def = thm "Bex_def";
   317 
   318     val prove_bex_tac =
   319       rewrite_goals_tac [Bex_def] THEN Quantifier1.prove_one_point_ex_tac;
   320     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   321 
   322     val prove_ball_tac =
   323       rewrite_goals_tac [Ball_def] THEN Quantifier1.prove_one_point_all_tac;
   324     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   325   in
   326     val defBEX_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   327       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   328     val defBALL_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   329       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   330   end;
   331 
   332   Addsimprocs [defBALL_regroup, defBEX_regroup];
   333 *}
   334 
   335 
   336 subsubsection {* Congruence rules *}
   337 
   338 lemma ball_cong [cong]:
   339   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   340     (ALL x:A. P x) = (ALL x:B. Q x)"
   341   by (simp add: Ball_def)
   342 
   343 lemma bex_cong [cong]:
   344   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   345     (EX x:A. P x) = (EX x:B. Q x)"
   346   by (simp add: Bex_def cong: conj_cong)
   347 
   348 
   349 subsubsection {* Subsets *}
   350 
   351 lemma subsetI [intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   352   by (simp add: subset_def)
   353 
   354 text {*
   355   \medskip Map the type @{text "'a set => anything"} to just @{typ
   356   'a}; for overloading constants whose first argument has type @{typ
   357   "'a set"}.
   358 *}
   359 
   360 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   361   -- {* Rule in Modus Ponens style. *}
   362   by (unfold subset_def) blast
   363 
   364 declare subsetD [intro?] -- FIXME
   365 
   366 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   367   -- {* The same, with reversed premises for use with @{text erule} --
   368       cf @{text rev_mp}. *}
   369   by (rule subsetD)
   370 
   371 declare rev_subsetD [intro?] -- FIXME
   372 
   373 text {*
   374   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   375 *}
   376 
   377 ML {*
   378   local val rev_subsetD = thm "rev_subsetD"
   379   in fun impOfSubs th = th RSN (2, rev_subsetD) end;
   380 *}
   381 
   382 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   383   -- {* Classical elimination rule. *}
   384   by (unfold subset_def) blast
   385 
   386 text {*
   387   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   388   creates the assumption @{prop "c \<in> B"}.
   389 *}
   390 
   391 ML {*
   392   local val subsetCE = thm "subsetCE"
   393   in fun set_mp_tac i = etac subsetCE i THEN mp_tac i end;
   394 *}
   395 
   396 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   397   by blast
   398 
   399 lemma subset_refl: "A \<subseteq> A"
   400   by fast
   401 
   402 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   403   by blast
   404 
   405 
   406 subsubsection {* Equality *}
   407 
   408 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   409   -- {* Anti-symmetry of the subset relation. *}
   410   by (rules intro: set_ext subsetD)
   411 
   412 lemmas equalityI [intro!] = subset_antisym
   413 
   414 text {*
   415   \medskip Equality rules from ZF set theory -- are they appropriate
   416   here?
   417 *}
   418 
   419 lemma equalityD1: "A = B ==> A \<subseteq> B"
   420   by (simp add: subset_refl)
   421 
   422 lemma equalityD2: "A = B ==> B \<subseteq> A"
   423   by (simp add: subset_refl)
   424 
   425 text {*
   426   \medskip Be careful when adding this to the claset as @{text
   427   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   428   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   429 *}
   430 
   431 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   432   by (simp add: subset_refl)
   433 
   434 lemma equalityCE [elim]:
   435     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   436   by blast
   437 
   438 text {*
   439   \medskip Lemma for creating induction formulae -- for "pattern
   440   matching" on @{text p}.  To make the induction hypotheses usable,
   441   apply @{text spec} or @{text bspec} to put universal quantifiers over the free
   442   variables in @{text p}.
   443 *}
   444 
   445 lemma setup_induction: "p:A ==> (!!z. z:A ==> p = z --> R) ==> R"
   446   by simp
   447 
   448 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   449   by simp
   450 
   451 
   452 subsubsection {* The universal set -- UNIV *}
   453 
   454 lemma UNIV_I [simp]: "x : UNIV"
   455   by (simp add: UNIV_def)
   456 
   457 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   458 
   459 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   460   by simp
   461 
   462 lemma subset_UNIV: "A \<subseteq> UNIV"
   463   by (rule subsetI) (rule UNIV_I)
   464 
   465 text {*
   466   \medskip Eta-contracting these two rules (to remove @{text P})
   467   causes them to be ignored because of their interaction with
   468   congruence rules.
   469 *}
   470 
   471 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   472   by (simp add: Ball_def)
   473 
   474 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   475   by (simp add: Bex_def)
   476 
   477 
   478 subsubsection {* The empty set *}
   479 
   480 lemma empty_iff [simp]: "(c : {}) = False"
   481   by (simp add: empty_def)
   482 
   483 lemma emptyE [elim!]: "a : {} ==> P"
   484   by simp
   485 
   486 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   487     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   488   by blast
   489 
   490 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   491   by blast
   492 
   493 lemma equals0D: "A = {} ==> a \<notin> A"
   494     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   495   by blast
   496 
   497 lemma ball_empty [simp]: "Ball {} P = True"
   498   by (simp add: Ball_def)
   499 
   500 lemma bex_empty [simp]: "Bex {} P = False"
   501   by (simp add: Bex_def)
   502 
   503 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   504   by (blast elim: equalityE)
   505 
   506 
   507 subsubsection {* The Powerset operator -- Pow *}
   508 
   509 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   510   by (simp add: Pow_def)
   511 
   512 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   513   by (simp add: Pow_def)
   514 
   515 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   516   by (simp add: Pow_def)
   517 
   518 lemma Pow_bottom: "{} \<in> Pow B"
   519   by simp
   520 
   521 lemma Pow_top: "A \<in> Pow A"
   522   by (simp add: subset_refl)
   523 
   524 
   525 subsubsection {* Set complement *}
   526 
   527 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   528   by (unfold Compl_def) blast
   529 
   530 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   531   by (unfold Compl_def) blast
   532 
   533 text {*
   534   \medskip This form, with negated conclusion, works well with the
   535   Classical prover.  Negated assumptions behave like formulae on the
   536   right side of the notional turnstile ... *}
   537 
   538 lemma ComplD: "c : -A ==> c~:A"
   539   by (unfold Compl_def) blast
   540 
   541 lemmas ComplE [elim!] = ComplD [elim_format]
   542 
   543 
   544 subsubsection {* Binary union -- Un *}
   545 
   546 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   547   by (unfold Un_def) blast
   548 
   549 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   550   by simp
   551 
   552 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   553   by simp
   554 
   555 text {*
   556   \medskip Classical introduction rule: no commitment to @{prop A} vs
   557   @{prop B}.
   558 *}
   559 
   560 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   561   by auto
   562 
   563 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   564   by (unfold Un_def) blast
   565 
   566 
   567 subsubsection {* Binary intersection -- Int *}
   568 
   569 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   570   by (unfold Int_def) blast
   571 
   572 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   573   by simp
   574 
   575 lemma IntD1: "c : A Int B ==> c:A"
   576   by simp
   577 
   578 lemma IntD2: "c : A Int B ==> c:B"
   579   by simp
   580 
   581 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   582   by simp
   583 
   584 
   585 subsubsection {* Set difference *}
   586 
   587 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   588   by (unfold set_diff_def) blast
   589 
   590 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   591   by simp
   592 
   593 lemma DiffD1: "c : A - B ==> c : A"
   594   by simp
   595 
   596 lemma DiffD2: "c : A - B ==> c : B ==> P"
   597   by simp
   598 
   599 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   600   by simp
   601 
   602 
   603 subsubsection {* Augmenting a set -- insert *}
   604 
   605 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   606   by (unfold insert_def) blast
   607 
   608 lemma insertI1: "a : insert a B"
   609   by simp
   610 
   611 lemma insertI2: "a : B ==> a : insert b B"
   612   by simp
   613 
   614 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   615   by (unfold insert_def) blast
   616 
   617 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   618   -- {* Classical introduction rule. *}
   619   by auto
   620 
   621 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   622   by auto
   623 
   624 
   625 subsubsection {* Singletons, using insert *}
   626 
   627 lemma singletonI [intro!]: "a : {a}"
   628     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   629   by (rule insertI1)
   630 
   631 lemma singletonD: "b : {a} ==> b = a"
   632   by blast
   633 
   634 lemmas singletonE [elim!] = singletonD [elim_format]
   635 
   636 lemma singleton_iff: "(b : {a}) = (b = a)"
   637   by blast
   638 
   639 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   640   by blast
   641 
   642 lemma singleton_insert_inj_eq [iff]: "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   643   by blast
   644 
   645 lemma singleton_insert_inj_eq' [iff]: "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   646   by blast
   647 
   648 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   649   by fast
   650 
   651 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   652   by blast
   653 
   654 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   655   by blast
   656 
   657 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   658   by blast
   659 
   660 
   661 subsubsection {* Unions of families *}
   662 
   663 text {*
   664   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   665 *}
   666 
   667 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   668   by (unfold UNION_def) blast
   669 
   670 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   671   -- {* The order of the premises presupposes that @{term A} is rigid;
   672     @{term b} may be flexible. *}
   673   by auto
   674 
   675 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   676   by (unfold UNION_def) blast
   677 
   678 lemma UN_cong [cong]:
   679     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   680   by (simp add: UNION_def)
   681 
   682 
   683 subsubsection {* Intersections of families *}
   684 
   685 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   686 
   687 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   688   by (unfold INTER_def) blast
   689 
   690 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   691   by (unfold INTER_def) blast
   692 
   693 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   694   by auto
   695 
   696 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   697   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   698   by (unfold INTER_def) blast
   699 
   700 lemma INT_cong [cong]:
   701     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   702   by (simp add: INTER_def)
   703 
   704 
   705 subsubsection {* Union *}
   706 
   707 lemma Union_iff [simp]: "(A : Union C) = (EX X:C. A:X)"
   708   by (unfold Union_def) blast
   709 
   710 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   711   -- {* The order of the premises presupposes that @{term C} is rigid;
   712     @{term A} may be flexible. *}
   713   by auto
   714 
   715 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   716   by (unfold Union_def) blast
   717 
   718 
   719 subsubsection {* Inter *}
   720 
   721 lemma Inter_iff [simp]: "(A : Inter C) = (ALL X:C. A:X)"
   722   by (unfold Inter_def) blast
   723 
   724 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   725   by (simp add: Inter_def)
   726 
   727 text {*
   728   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   729   contains @{term A} as an element, but @{prop "A:X"} can hold when
   730   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   731 *}
   732 
   733 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   734   by auto
   735 
   736 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   737   -- {* ``Classical'' elimination rule -- does not require proving
   738     @{prop "X:C"}. *}
   739   by (unfold Inter_def) blast
   740 
   741 text {*
   742   \medskip Image of a set under a function.  Frequently @{term b} does
   743   not have the syntactic form of @{term "f x"}.
   744 *}
   745 
   746 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   747   by (unfold image_def) blast
   748 
   749 lemma imageI: "x : A ==> f x : f ` A"
   750   by (rule image_eqI) (rule refl)
   751 
   752 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   753   -- {* This version's more effective when we already have the
   754     required @{term x}. *}
   755   by (unfold image_def) blast
   756 
   757 lemma imageE [elim!]:
   758   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   759   -- {* The eta-expansion gives variable-name preservation. *}
   760   by (unfold image_def) blast
   761 
   762 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   763   by blast
   764 
   765 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   766   by blast
   767 
   768 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   769   -- {* This rewrite rule would confuse users if made default. *}
   770   by blast
   771 
   772 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   773   apply safe
   774    prefer 2 apply fast
   775   apply (rule_tac x = "{a. a : A & f a : B}" in exI)
   776   apply fast
   777   done
   778 
   779 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   780   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   781     @{text hypsubst}, but breaks too many existing proofs. *}
   782   by blast
   783 
   784 text {*
   785   \medskip Range of a function -- just a translation for image!
   786 *}
   787 
   788 lemma range_eqI: "b = f x ==> b \<in> range f"
   789   by simp
   790 
   791 lemma rangeI: "f x \<in> range f"
   792   by simp
   793 
   794 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   795   by blast
   796 
   797 
   798 subsubsection {* Set reasoning tools *}
   799 
   800 text {*
   801   Rewrite rules for boolean case-splitting: faster than @{text
   802   "split_if [split]"}.
   803 *}
   804 
   805 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   806   by (rule split_if)
   807 
   808 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   809   by (rule split_if)
   810 
   811 text {*
   812   Split ifs on either side of the membership relation.  Not for @{text
   813   "[simp]"} -- can cause goals to blow up!
   814 *}
   815 
   816 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   817   by (rule split_if)
   818 
   819 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   820   by (rule split_if)
   821 
   822 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   823 
   824 lemmas mem_simps =
   825   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   826   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   827   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   828 
   829 (*Would like to add these, but the existing code only searches for the
   830   outer-level constant, which in this case is just "op :"; we instead need
   831   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   832   apply, then the formula should be kept.
   833   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]),
   834    ("op Int", [IntD1,IntD2]),
   835    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   836  *)
   837 
   838 ML_setup {*
   839   val mksimps_pairs = [("Ball", [thm "bspec"])] @ mksimps_pairs;
   840   simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   841 *}
   842 
   843 declare subset_UNIV [simp] subset_refl [simp]
   844 
   845 
   846 subsubsection {* The ``proper subset'' relation *}
   847 
   848 lemma psubsetI [intro!]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   849   by (unfold psubset_def) blast
   850 
   851 lemma psubsetE [elim!]: 
   852     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   853   by (unfold psubset_def) blast
   854 
   855 lemma psubset_insert_iff:
   856   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
   857   by (auto simp add: psubset_def subset_insert_iff)
   858 
   859 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
   860   by (simp only: psubset_def)
   861 
   862 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
   863   by (simp add: psubset_eq)
   864 
   865 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
   866   by (auto simp add: psubset_eq)
   867 
   868 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
   869   by (auto simp add: psubset_eq)
   870 
   871 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
   872   by (unfold psubset_def) blast
   873 
   874 lemma atomize_ball:
   875     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
   876   by (simp only: Ball_def atomize_all atomize_imp)
   877 
   878 declare atomize_ball [symmetric, rulify]
   879 
   880 
   881 subsection {* Further set-theory lemmas *}
   882 
   883 subsubsection {* Derived rules involving subsets. *}
   884 
   885 text {* @{text insert}. *}
   886 
   887 lemma subset_insertI: "B \<subseteq> insert a B"
   888   apply (rule subsetI)
   889   apply (erule insertI2)
   890   done
   891 
   892 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
   893   by blast
   894 
   895 
   896 text {* \medskip Big Union -- least upper bound of a set. *}
   897 
   898 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   899   by (rules intro: subsetI UnionI)
   900 
   901 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   902   by (rules intro: subsetI elim: UnionE dest: subsetD)
   903 
   904 
   905 text {* \medskip General union. *}
   906 
   907 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   908   by blast
   909 
   910 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   911   by (rules intro: subsetI elim: UN_E dest: subsetD)
   912 
   913 
   914 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
   915 
   916 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   917   by blast
   918 
   919 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   920   by (rules intro: InterI subsetI dest: subsetD)
   921 
   922 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   923   by blast
   924 
   925 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   926   by (rules intro: INT_I subsetI dest: subsetD)
   927 
   928 
   929 text {* \medskip Finite Union -- the least upper bound of two sets. *}
   930 
   931 lemma Un_upper1: "A \<subseteq> A \<union> B"
   932   by blast
   933 
   934 lemma Un_upper2: "B \<subseteq> A \<union> B"
   935   by blast
   936 
   937 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
   938   by blast
   939 
   940 
   941 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
   942 
   943 lemma Int_lower1: "A \<inter> B \<subseteq> A"
   944   by blast
   945 
   946 lemma Int_lower2: "A \<inter> B \<subseteq> B"
   947   by blast
   948 
   949 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
   950   by blast
   951 
   952 
   953 text {* \medskip Set difference. *}
   954 
   955 lemma Diff_subset: "A - B \<subseteq> A"
   956   by blast
   957 
   958 
   959 text {* \medskip Monotonicity. *}
   960 
   961 lemma mono_Un: includes mono shows "f A \<union> f B \<subseteq> f (A \<union> B)"
   962   apply (rule Un_least)
   963    apply (rule Un_upper1 [THEN mono])
   964   apply (rule Un_upper2 [THEN mono])
   965   done
   966 
   967 lemma mono_Int: includes mono shows "f (A \<inter> B) \<subseteq> f A \<inter> f B"
   968   apply (rule Int_greatest)
   969    apply (rule Int_lower1 [THEN mono])
   970   apply (rule Int_lower2 [THEN mono])
   971   done
   972 
   973 
   974 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
   975 
   976 text {* @{text "{}"}. *}
   977 
   978 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
   979   -- {* supersedes @{text "Collect_False_empty"} *}
   980   by auto
   981 
   982 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
   983   by blast
   984 
   985 lemma not_psubset_empty [iff]: "\<not> (A < {})"
   986   by (unfold psubset_def) blast
   987 
   988 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
   989   by auto
   990 
   991 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
   992   by blast
   993 
   994 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
   995   by blast
   996 
   997 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
   998   by blast
   999 
  1000 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1001   by blast
  1002 
  1003 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1004   by blast
  1005 
  1006 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1007   by blast
  1008 
  1009 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1010   by blast
  1011 
  1012 
  1013 text {* \medskip @{text insert}. *}
  1014 
  1015 lemma insert_is_Un: "insert a A = {a} Un A"
  1016   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1017   by blast
  1018 
  1019 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1020   by blast
  1021 
  1022 lemmas empty_not_insert [simp] = insert_not_empty [symmetric, standard]
  1023 
  1024 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1025   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1026   -- {* with \emph{quadratic} running time *}
  1027   by blast
  1028 
  1029 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1030   by blast
  1031 
  1032 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1033   by blast
  1034 
  1035 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1036   by blast
  1037 
  1038 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1039   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1040   apply (rule_tac x = "A - {a}" in exI)
  1041   apply blast
  1042   done
  1043 
  1044 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1045   by auto
  1046 
  1047 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1048   by blast
  1049 
  1050 lemma insert_disjoint[simp]:
  1051  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1052 by blast
  1053 
  1054 lemma disjoint_insert[simp]:
  1055  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1056 by blast
  1057 
  1058 text {* \medskip @{text image}. *}
  1059 
  1060 lemma image_empty [simp]: "f`{} = {}"
  1061   by blast
  1062 
  1063 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1064   by blast
  1065 
  1066 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1067   by blast
  1068 
  1069 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1070   by blast
  1071 
  1072 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1073   by blast
  1074 
  1075 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1076   by blast
  1077 
  1078 lemma image_Collect: "f ` {x. P x} = {f x | x. P x}"
  1079   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS, *}
  1080   -- {* with its implicit quantifier and conjunction.  Also image enjoys better *}
  1081   -- {* equational properties than does the RHS. *}
  1082   by blast
  1083 
  1084 lemma if_image_distrib [simp]:
  1085   "(\<lambda>x. if P x then f x else g x) ` S
  1086     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1087   by (auto simp add: image_def)
  1088 
  1089 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1090   by (simp add: image_def)
  1091 
  1092 
  1093 text {* \medskip @{text range}. *}
  1094 
  1095 lemma full_SetCompr_eq: "{u. \<exists>x. u = f x} = range f"
  1096   by auto
  1097 
  1098 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1099   apply (subst image_image)
  1100   apply simp
  1101   done
  1102 
  1103 
  1104 text {* \medskip @{text Int} *}
  1105 
  1106 lemma Int_absorb [simp]: "A \<inter> A = A"
  1107   by blast
  1108 
  1109 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1110   by blast
  1111 
  1112 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1113   by blast
  1114 
  1115 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1116   by blast
  1117 
  1118 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1119   by blast
  1120 
  1121 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1122   -- {* Intersection is an AC-operator *}
  1123 
  1124 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1125   by blast
  1126 
  1127 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1128   by blast
  1129 
  1130 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1131   by blast
  1132 
  1133 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1134   by blast
  1135 
  1136 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1137   by blast
  1138 
  1139 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1140   by blast
  1141 
  1142 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1143   by blast
  1144 
  1145 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1146   by blast
  1147 
  1148 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1149   by blast
  1150 
  1151 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1152   by blast
  1153 
  1154 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1155   by blast
  1156 
  1157 lemma Int_UNIV [simp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1158   by blast
  1159 
  1160 lemma Int_subset_iff: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1161   by blast
  1162 
  1163 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1164   by blast
  1165 
  1166 
  1167 text {* \medskip @{text Un}. *}
  1168 
  1169 lemma Un_absorb [simp]: "A \<union> A = A"
  1170   by blast
  1171 
  1172 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1173   by blast
  1174 
  1175 lemma Un_commute: "A \<union> B = B \<union> A"
  1176   by blast
  1177 
  1178 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1179   by blast
  1180 
  1181 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1182   by blast
  1183 
  1184 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1185   -- {* Union is an AC-operator *}
  1186 
  1187 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1188   by blast
  1189 
  1190 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1191   by blast
  1192 
  1193 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1194   by blast
  1195 
  1196 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1197   by blast
  1198 
  1199 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1200   by blast
  1201 
  1202 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1203   by blast
  1204 
  1205 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1206   by blast
  1207 
  1208 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1209   by blast
  1210 
  1211 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1212   by blast
  1213 
  1214 lemma Int_insert_left:
  1215     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1216   by auto
  1217 
  1218 lemma Int_insert_right:
  1219     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1220   by auto
  1221 
  1222 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1223   by blast
  1224 
  1225 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1226   by blast
  1227 
  1228 lemma Un_Int_crazy:
  1229     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1230   by blast
  1231 
  1232 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1233   by blast
  1234 
  1235 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1236   by blast
  1237 
  1238 lemma Un_subset_iff: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1239   by blast
  1240 
  1241 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1242   by blast
  1243 
  1244 
  1245 text {* \medskip Set complement *}
  1246 
  1247 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1248   by blast
  1249 
  1250 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1251   by blast
  1252 
  1253 lemma Compl_partition: "A \<union> (-A) = UNIV"
  1254   by blast
  1255 
  1256 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1257   by blast
  1258 
  1259 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1260   by blast
  1261 
  1262 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1263   by blast
  1264 
  1265 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1266   by blast
  1267 
  1268 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1269   by blast
  1270 
  1271 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1272   by blast
  1273 
  1274 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1275   -- {* Halmos, Naive Set Theory, page 16. *}
  1276   by blast
  1277 
  1278 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1279   by blast
  1280 
  1281 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1282   by blast
  1283 
  1284 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1285   by blast
  1286 
  1287 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1288   by blast
  1289 
  1290 
  1291 text {* \medskip @{text Union}. *}
  1292 
  1293 lemma Union_empty [simp]: "Union({}) = {}"
  1294   by blast
  1295 
  1296 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1297   by blast
  1298 
  1299 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1300   by blast
  1301 
  1302 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1303   by blast
  1304 
  1305 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1306   by blast
  1307 
  1308 lemma Union_empty_conv [iff]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1309   by blast
  1310 
  1311 lemma empty_Union_conv [iff]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1312   by blast
  1313 
  1314 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1315   by blast
  1316 
  1317 
  1318 text {* \medskip @{text Inter}. *}
  1319 
  1320 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1321   by blast
  1322 
  1323 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1324   by blast
  1325 
  1326 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1327   by blast
  1328 
  1329 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1330   by blast
  1331 
  1332 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1333   by blast
  1334 
  1335 lemma Inter_UNIV_conv [iff]:
  1336   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1337   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1338   by(blast)+
  1339 
  1340 
  1341 text {*
  1342   \medskip @{text UN} and @{text INT}.
  1343 
  1344   Basic identities: *}
  1345 
  1346 lemma UN_empty [simp]: "(\<Union>x\<in>{}. B x) = {}"
  1347   by blast
  1348 
  1349 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1350   by blast
  1351 
  1352 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1353   by blast
  1354 
  1355 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1356   by blast
  1357 
  1358 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1359   by blast
  1360 
  1361 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1362   by blast
  1363 
  1364 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1365   by blast
  1366 
  1367 lemma UN_Un: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1368   by blast
  1369 
  1370 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1371   by blast
  1372 
  1373 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1374   by blast
  1375 
  1376 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1377   by blast
  1378 
  1379 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1380   by blast
  1381 
  1382 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1383   by blast
  1384 
  1385 lemma INT_insert_distrib:
  1386     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1387   by blast
  1388 
  1389 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1390   by blast
  1391 
  1392 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1393   by blast
  1394 
  1395 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1396   by blast
  1397 
  1398 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1399   by auto
  1400 
  1401 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1402   by auto
  1403 
  1404 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1405   by blast
  1406 
  1407 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1408   -- {* Look: it has an \emph{existential} quantifier *}
  1409   by blast
  1410 
  1411 lemma UNION_empty_conv[iff]:
  1412   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1413   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1414 by blast+
  1415 
  1416 lemma INTER_UNIV_conv[iff]:
  1417  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1418  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1419 by blast+
  1420 
  1421 
  1422 text {* \medskip Distributive laws: *}
  1423 
  1424 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1425   by blast
  1426 
  1427 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1428   by blast
  1429 
  1430 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1431   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1432   -- {* Union of a family of unions *}
  1433   by blast
  1434 
  1435 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1436   -- {* Equivalent version *}
  1437   by blast
  1438 
  1439 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1440   by blast
  1441 
  1442 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1443   by blast
  1444 
  1445 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1446   -- {* Equivalent version *}
  1447   by blast
  1448 
  1449 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1450   -- {* Halmos, Naive Set Theory, page 35. *}
  1451   by blast
  1452 
  1453 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1454   by blast
  1455 
  1456 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1457   by blast
  1458 
  1459 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1460   by blast
  1461 
  1462 
  1463 text {* \medskip Bounded quantifiers.
  1464 
  1465   The following are not added to the default simpset because
  1466   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1467 
  1468 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1469   by blast
  1470 
  1471 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1472   by blast
  1473 
  1474 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1475   by blast
  1476 
  1477 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1478   by blast
  1479 
  1480 
  1481 text {* \medskip Set difference. *}
  1482 
  1483 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1484   by blast
  1485 
  1486 lemma Diff_eq_empty_iff [simp]: "(A - B = {}) = (A \<subseteq> B)"
  1487   by blast
  1488 
  1489 lemma Diff_cancel [simp]: "A - A = {}"
  1490   by blast
  1491 
  1492 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1493   by (blast elim: equalityE)
  1494 
  1495 lemma empty_Diff [simp]: "{} - A = {}"
  1496   by blast
  1497 
  1498 lemma Diff_empty [simp]: "A - {} = A"
  1499   by blast
  1500 
  1501 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1502   by blast
  1503 
  1504 lemma Diff_insert0 [simp]: "x \<notin> A ==> A - insert x B = A - B"
  1505   by blast
  1506 
  1507 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1508   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1509   by blast
  1510 
  1511 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1512   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1513   by blast
  1514 
  1515 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1516   by auto
  1517 
  1518 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1519   by blast
  1520 
  1521 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1522   by blast
  1523 
  1524 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1525   by auto
  1526 
  1527 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1528   by blast
  1529 
  1530 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1531   by blast
  1532 
  1533 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1534   by blast
  1535 
  1536 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1537   by blast
  1538 
  1539 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1540   by blast
  1541 
  1542 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1543   by blast
  1544 
  1545 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1546   by blast
  1547 
  1548 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1549   by blast
  1550 
  1551 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1552   by blast
  1553 
  1554 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1555   by blast
  1556 
  1557 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1558   by blast
  1559 
  1560 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1561   by auto
  1562 
  1563 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1564   by blast
  1565 
  1566 
  1567 text {* \medskip Quantification over type @{typ bool}. *}
  1568 
  1569 lemma all_bool_eq: "(\<forall>b::bool. P b) = (P True & P False)"
  1570   apply auto
  1571   apply (tactic {* case_tac "b" 1 *})
  1572    apply auto
  1573   done
  1574 
  1575 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1576   by (rule conjI [THEN all_bool_eq [THEN iffD2], THEN spec])
  1577 
  1578 lemma ex_bool_eq: "(\<exists>b::bool. P b) = (P True | P False)"
  1579   apply auto
  1580   apply (tactic {* case_tac "b" 1 *})
  1581    apply auto
  1582   done
  1583 
  1584 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1585   by (auto simp add: split_if_mem2)
  1586 
  1587 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1588   apply auto
  1589   apply (tactic {* case_tac "b" 1 *})
  1590    apply auto
  1591   done
  1592 
  1593 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1594   apply auto
  1595   apply (tactic {* case_tac "b" 1 *})
  1596   apply auto
  1597   done
  1598 
  1599 
  1600 text {* \medskip @{text Pow} *}
  1601 
  1602 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1603   by (auto simp add: Pow_def)
  1604 
  1605 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1606   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1607 
  1608 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1609   by (blast intro: exI [where ?x = "- u", standard])
  1610 
  1611 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1612   by blast
  1613 
  1614 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1615   by blast
  1616 
  1617 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1618   by blast
  1619 
  1620 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1621   by blast
  1622 
  1623 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1624   by blast
  1625 
  1626 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1627   by blast
  1628 
  1629 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1630   by blast
  1631 
  1632 
  1633 text {* \medskip Miscellany. *}
  1634 
  1635 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1636   by blast
  1637 
  1638 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1639   by blast
  1640 
  1641 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1642   by (unfold psubset_def) blast
  1643 
  1644 lemma all_not_in_conv [iff]: "(\<forall>x. x \<notin> A) = (A = {})"
  1645   by blast
  1646 
  1647 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1648   by rules
  1649 
  1650 
  1651 text {* \medskip Miniscoping: pushing in big Unions and Intersections. *}
  1652 
  1653 lemma UN_simps [simp]:
  1654   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1655   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1656   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1657   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1658   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1659   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1660   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1661   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1662   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1663   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1664   by auto
  1665 
  1666 lemma INT_simps [simp]:
  1667   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1668   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1669   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1670   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1671   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1672   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1673   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1674   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1675   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1676   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1677   by auto
  1678 
  1679 lemma ball_simps [simp]:
  1680   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1681   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1682   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1683   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1684   "!!P. (ALL x:{}. P x) = True"
  1685   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1686   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1687   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1688   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1689   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1690   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1691   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1692   by auto
  1693 
  1694 lemma bex_simps [simp]:
  1695   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1696   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1697   "!!P. (EX x:{}. P x) = False"
  1698   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1699   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1700   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1701   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1702   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1703   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1704   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1705   by auto
  1706 
  1707 lemma ball_conj_distrib:
  1708   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1709   by blast
  1710 
  1711 lemma bex_disj_distrib:
  1712   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1713   by blast
  1714 
  1715 
  1716 subsubsection {* Monotonicity of various operations *}
  1717 
  1718 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1719   by blast
  1720 
  1721 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1722   by blast
  1723 
  1724 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1725   by blast
  1726 
  1727 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1728   by blast
  1729 
  1730 lemma UN_mono:
  1731   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1732     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1733   by (blast dest: subsetD)
  1734 
  1735 lemma INT_anti_mono:
  1736   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1737     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1738   -- {* The last inclusion is POSITIVE! *}
  1739   by (blast dest: subsetD)
  1740 
  1741 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1742   by blast
  1743 
  1744 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1745   by blast
  1746 
  1747 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1748   by blast
  1749 
  1750 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1751   by blast
  1752 
  1753 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1754   by blast
  1755 
  1756 text {* \medskip Monotonicity of implications. *}
  1757 
  1758 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1759   apply (rule impI)
  1760   apply (erule subsetD)
  1761   apply assumption
  1762   done
  1763 
  1764 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1765   by rules
  1766 
  1767 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1768   by rules
  1769 
  1770 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1771   by rules
  1772 
  1773 lemma imp_refl: "P --> P" ..
  1774 
  1775 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1776   by rules
  1777 
  1778 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1779   by rules
  1780 
  1781 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1782   by blast
  1783 
  1784 lemma Int_Collect_mono:
  1785     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1786   by blast
  1787 
  1788 lemmas basic_monos =
  1789   subset_refl imp_refl disj_mono conj_mono
  1790   ex_mono Collect_mono in_mono
  1791 
  1792 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1793   by rules
  1794 
  1795 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  1796   by rules
  1797 
  1798 lemma Least_mono:
  1799   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1800     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1801     -- {* Courtesy of Stephan Merz *}
  1802   apply clarify
  1803   apply (erule_tac P = "%x. x : S" in LeastI2)
  1804    apply fast
  1805   apply (rule LeastI2)
  1806   apply (auto elim: monoD intro!: order_antisym)
  1807   done
  1808 
  1809 
  1810 subsection {* Inverse image of a function *}
  1811 
  1812 constdefs
  1813   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  1814   "f -` B == {x. f x : B}"
  1815 
  1816 
  1817 subsubsection {* Basic rules *}
  1818 
  1819 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1820   by (unfold vimage_def) blast
  1821 
  1822 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1823   by simp
  1824 
  1825 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1826   by (unfold vimage_def) blast
  1827 
  1828 lemma vimageI2: "f a : A ==> a : f -` A"
  1829   by (unfold vimage_def) fast
  1830 
  1831 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1832   by (unfold vimage_def) blast
  1833 
  1834 lemma vimageD: "a : f -` A ==> f a : A"
  1835   by (unfold vimage_def) fast
  1836 
  1837 
  1838 subsubsection {* Equations *}
  1839 
  1840 lemma vimage_empty [simp]: "f -` {} = {}"
  1841   by blast
  1842 
  1843 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1844   by blast
  1845 
  1846 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1847   by blast
  1848 
  1849 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1850   by fast
  1851 
  1852 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  1853   by blast
  1854 
  1855 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  1856   by blast
  1857 
  1858 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  1859   by blast
  1860 
  1861 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1862   by blast
  1863 
  1864 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1865   by blast
  1866 
  1867 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1868   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1869   by blast
  1870 
  1871 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1872   by blast
  1873 
  1874 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1875   by blast
  1876 
  1877 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  1878   -- {* NOT suitable for rewriting *}
  1879   by blast
  1880 
  1881 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1882   -- {* monotonicity *}
  1883   by blast
  1884 
  1885 
  1886 subsection {* Transitivity rules for calculational reasoning *}
  1887 
  1888 lemma forw_subst: "a = b ==> P b ==> P a"
  1889   by (rule ssubst)
  1890 
  1891 lemma back_subst: "P a ==> a = b ==> P b"
  1892   by (rule subst)
  1893 
  1894 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  1895   by (rule subsetD)
  1896 
  1897 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  1898   by (rule subsetD)
  1899 
  1900 lemma order_neq_le_trans: "a ~= b ==> (a::'a::order) <= b ==> a < b"
  1901   by (simp add: order_less_le)
  1902 
  1903 lemma order_le_neq_trans: "(a::'a::order) <= b ==> a ~= b ==> a < b"
  1904   by (simp add: order_less_le)
  1905 
  1906 lemma order_less_asym': "(a::'a::order) < b ==> b < a ==> P"
  1907   by (rule order_less_asym)
  1908 
  1909 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
  1910   by (rule subst)
  1911 
  1912 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
  1913   by (rule ssubst)
  1914 
  1915 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
  1916   by (rule subst)
  1917 
  1918 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
  1919   by (rule ssubst)
  1920 
  1921 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
  1922   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1923 proof -
  1924   assume r: "!!x y. x < y ==> f x < f y"
  1925   assume "a < b" hence "f a < f b" by (rule r)
  1926   also assume "f b < c"
  1927   finally (order_less_trans) show ?thesis .
  1928 qed
  1929 
  1930 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
  1931   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1932 proof -
  1933   assume r: "!!x y. x < y ==> f x < f y"
  1934   assume "a < f b"
  1935   also assume "b < c" hence "f b < f c" by (rule r)
  1936   finally (order_less_trans) show ?thesis .
  1937 qed
  1938 
  1939 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
  1940   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
  1941 proof -
  1942   assume r: "!!x y. x <= y ==> f x <= f y"
  1943   assume "a <= b" hence "f a <= f b" by (rule r)
  1944   also assume "f b < c"
  1945   finally (order_le_less_trans) show ?thesis .
  1946 qed
  1947 
  1948 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
  1949   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1950 proof -
  1951   assume r: "!!x y. x < y ==> f x < f y"
  1952   assume "a <= f b"
  1953   also assume "b < c" hence "f b < f c" by (rule r)
  1954   finally (order_le_less_trans) show ?thesis .
  1955 qed
  1956 
  1957 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
  1958   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1959 proof -
  1960   assume r: "!!x y. x < y ==> f x < f y"
  1961   assume "a < b" hence "f a < f b" by (rule r)
  1962   also assume "f b <= c"
  1963   finally (order_less_le_trans) show ?thesis .
  1964 qed
  1965 
  1966 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
  1967   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
  1968 proof -
  1969   assume r: "!!x y. x <= y ==> f x <= f y"
  1970   assume "a < f b"
  1971   also assume "b <= c" hence "f b <= f c" by (rule r)
  1972   finally (order_less_le_trans) show ?thesis .
  1973 qed
  1974 
  1975 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
  1976   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  1977 proof -
  1978   assume r: "!!x y. x <= y ==> f x <= f y"
  1979   assume "a <= f b"
  1980   also assume "b <= c" hence "f b <= f c" by (rule r)
  1981   finally (order_trans) show ?thesis .
  1982 qed
  1983 
  1984 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
  1985   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  1986 proof -
  1987   assume r: "!!x y. x <= y ==> f x <= f y"
  1988   assume "a <= b" hence "f a <= f b" by (rule r)
  1989   also assume "f b <= c"
  1990   finally (order_trans) show ?thesis .
  1991 qed
  1992 
  1993 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
  1994   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  1995 proof -
  1996   assume r: "!!x y. x <= y ==> f x <= f y"
  1997   assume "a <= b" hence "f a <= f b" by (rule r)
  1998   also assume "f b = c"
  1999   finally (ord_le_eq_trans) show ?thesis .
  2000 qed
  2001 
  2002 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
  2003   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2004 proof -
  2005   assume r: "!!x y. x <= y ==> f x <= f y"
  2006   assume "a = f b"
  2007   also assume "b <= c" hence "f b <= f c" by (rule r)
  2008   finally (ord_eq_le_trans) show ?thesis .
  2009 qed
  2010 
  2011 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
  2012   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2013 proof -
  2014   assume r: "!!x y. x < y ==> f x < f y"
  2015   assume "a < b" hence "f a < f b" by (rule r)
  2016   also assume "f b = c"
  2017   finally (ord_less_eq_trans) show ?thesis .
  2018 qed
  2019 
  2020 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
  2021   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2022 proof -
  2023   assume r: "!!x y. x < y ==> f x < f y"
  2024   assume "a = f b"
  2025   also assume "b < c" hence "f b < f c" by (rule r)
  2026   finally (ord_eq_less_trans) show ?thesis .
  2027 qed
  2028 
  2029 text {*
  2030   Note that this list of rules is in reverse order of priorities.
  2031 *}
  2032 
  2033 lemmas basic_trans_rules [trans] =
  2034   order_less_subst2
  2035   order_less_subst1
  2036   order_le_less_subst2
  2037   order_le_less_subst1
  2038   order_less_le_subst2
  2039   order_less_le_subst1
  2040   order_subst2
  2041   order_subst1
  2042   ord_le_eq_subst
  2043   ord_eq_le_subst
  2044   ord_less_eq_subst
  2045   ord_eq_less_subst
  2046   forw_subst
  2047   back_subst
  2048   rev_mp
  2049   mp
  2050   set_rev_mp
  2051   set_mp
  2052   order_neq_le_trans
  2053   order_le_neq_trans
  2054   order_less_trans
  2055   order_less_asym'
  2056   order_le_less_trans
  2057   order_less_le_trans
  2058   order_trans
  2059   order_antisym
  2060   ord_le_eq_trans
  2061   ord_eq_le_trans
  2062   ord_less_eq_trans
  2063   ord_eq_less_trans
  2064   trans
  2065 
  2066 end