src/HOL/Library/Multiset.thy
author nipkow
Tue Sep 07 10:05:19 2010 +0200 (2010-09-07)
changeset 39198 f967a16dfcdd
parent 38857 97775f3e8722
child 39301 e1bd8a54c40f
permissions -rw-r--r--
expand_fun_eq -> ext_iff
expand_set_eq -> set_ext_iff
Naming in line now with multisets
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3 *)
     4 
     5 header {* (Finite) multisets *}
     6 
     7 theory Multiset
     8 imports Main
     9 begin
    10 
    11 subsection {* The type of multisets *}
    12 
    13 typedef 'a multiset = "{f :: 'a => nat. finite {x. f x > 0}}"
    14   morphisms count Abs_multiset
    15 proof
    16   show "(\<lambda>x. 0::nat) \<in> ?multiset" by simp
    17 qed
    18 
    19 lemmas multiset_typedef = Abs_multiset_inverse count_inverse count
    20 
    21 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
    22   "a :# M == 0 < count M a"
    23 
    24 notation (xsymbols)
    25   Melem (infix "\<in>#" 50)
    26 
    27 lemma multiset_ext_iff:
    28   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    29   by (simp only: count_inject [symmetric] ext_iff)
    30 
    31 lemma multiset_ext:
    32   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    33   using multiset_ext_iff by auto
    34 
    35 text {*
    36  \medskip Preservation of the representing set @{term multiset}.
    37 *}
    38 
    39 lemma const0_in_multiset:
    40   "(\<lambda>a. 0) \<in> multiset"
    41   by (simp add: multiset_def)
    42 
    43 lemma only1_in_multiset:
    44   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    45   by (simp add: multiset_def)
    46 
    47 lemma union_preserves_multiset:
    48   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    49   by (simp add: multiset_def)
    50 
    51 lemma diff_preserves_multiset:
    52   assumes "M \<in> multiset"
    53   shows "(\<lambda>a. M a - N a) \<in> multiset"
    54 proof -
    55   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    56     by auto
    57   with assms show ?thesis
    58     by (auto simp add: multiset_def intro: finite_subset)
    59 qed
    60 
    61 lemma MCollect_preserves_multiset:
    62   assumes "M \<in> multiset"
    63   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    64 proof -
    65   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    66     by auto
    67   with assms show ?thesis
    68     by (auto simp add: multiset_def intro: finite_subset)
    69 qed
    70 
    71 lemmas in_multiset = const0_in_multiset only1_in_multiset
    72   union_preserves_multiset diff_preserves_multiset MCollect_preserves_multiset
    73 
    74 
    75 subsection {* Representing multisets *}
    76 
    77 text {* Multiset comprehension *}
    78 
    79 definition MCollect :: "'a multiset => ('a => bool) => 'a multiset" where
    80   "MCollect M P = Abs_multiset (\<lambda>x. if P x then count M x else 0)"
    81 
    82 syntax
    83   "_MCollect" :: "pttrn => 'a multiset => bool => 'a multiset"    ("(1{# _ :# _./ _#})")
    84 translations
    85   "{#x :# M. P#}" == "CONST MCollect M (\<lambda>x. P)"
    86 
    87 
    88 text {* Multiset enumeration *}
    89 
    90 instantiation multiset :: (type) "{zero, plus}"
    91 begin
    92 
    93 definition Mempty_def:
    94   "0 = Abs_multiset (\<lambda>a. 0)"
    95 
    96 abbreviation Mempty :: "'a multiset" ("{#}") where
    97   "Mempty \<equiv> 0"
    98 
    99 definition union_def:
   100   "M + N = Abs_multiset (\<lambda>a. count M a + count N a)"
   101 
   102 instance ..
   103 
   104 end
   105 
   106 definition single :: "'a => 'a multiset" where
   107   "single a = Abs_multiset (\<lambda>b. if b = a then 1 else 0)"
   108 
   109 syntax
   110   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
   111 translations
   112   "{#x, xs#}" == "{#x#} + {#xs#}"
   113   "{#x#}" == "CONST single x"
   114 
   115 lemma count_empty [simp]: "count {#} a = 0"
   116   by (simp add: Mempty_def in_multiset multiset_typedef)
   117 
   118 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   119   by (simp add: single_def in_multiset multiset_typedef)
   120 
   121 
   122 subsection {* Basic operations *}
   123 
   124 subsubsection {* Union *}
   125 
   126 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   127   by (simp add: union_def in_multiset multiset_typedef)
   128 
   129 instance multiset :: (type) cancel_comm_monoid_add proof
   130 qed (simp_all add: multiset_ext_iff)
   131 
   132 
   133 subsubsection {* Difference *}
   134 
   135 instantiation multiset :: (type) minus
   136 begin
   137 
   138 definition diff_def:
   139   "M - N = Abs_multiset (\<lambda>a. count M a - count N a)"
   140 
   141 instance ..
   142 
   143 end
   144 
   145 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   146   by (simp add: diff_def in_multiset multiset_typedef)
   147 
   148 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   149 by(simp add: multiset_ext_iff)
   150 
   151 lemma diff_cancel[simp]: "A - A = {#}"
   152 by (rule multiset_ext) simp
   153 
   154 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   155 by(simp add: multiset_ext_iff)
   156 
   157 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   158 by(simp add: multiset_ext_iff)
   159 
   160 lemma insert_DiffM:
   161   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   162   by (clarsimp simp: multiset_ext_iff)
   163 
   164 lemma insert_DiffM2 [simp]:
   165   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   166   by (clarsimp simp: multiset_ext_iff)
   167 
   168 lemma diff_right_commute:
   169   "(M::'a multiset) - N - Q = M - Q - N"
   170   by (auto simp add: multiset_ext_iff)
   171 
   172 lemma diff_add:
   173   "(M::'a multiset) - (N + Q) = M - N - Q"
   174 by (simp add: multiset_ext_iff)
   175 
   176 lemma diff_union_swap:
   177   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   178   by (auto simp add: multiset_ext_iff)
   179 
   180 lemma diff_union_single_conv:
   181   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   182   by (simp add: multiset_ext_iff)
   183 
   184 
   185 subsubsection {* Equality of multisets *}
   186 
   187 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   188   by (simp add: multiset_ext_iff)
   189 
   190 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   191   by (auto simp add: multiset_ext_iff)
   192 
   193 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   194   by (auto simp add: multiset_ext_iff)
   195 
   196 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   197   by (auto simp add: multiset_ext_iff)
   198 
   199 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   200   by (auto simp add: multiset_ext_iff)
   201 
   202 lemma diff_single_trivial:
   203   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   204   by (auto simp add: multiset_ext_iff)
   205 
   206 lemma diff_single_eq_union:
   207   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   208   by auto
   209 
   210 lemma union_single_eq_diff:
   211   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   212   by (auto dest: sym)
   213 
   214 lemma union_single_eq_member:
   215   "M + {#x#} = N \<Longrightarrow> x \<in># N"
   216   by auto
   217 
   218 lemma union_is_single:
   219   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")proof
   220   assume ?rhs then show ?lhs by auto
   221 next
   222   assume ?lhs thus ?rhs
   223     by(simp add: multiset_ext_iff split:if_splits) (metis add_is_1)
   224 qed
   225 
   226 lemma single_is_union:
   227   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   228   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   229 
   230 lemma add_eq_conv_diff:
   231   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
   232 (* shorter: by (simp add: multiset_ext_iff) fastsimp *)
   233 proof
   234   assume ?rhs then show ?lhs
   235   by (auto simp add: add_assoc add_commute [of "{#b#}"])
   236     (drule sym, simp add: add_assoc [symmetric])
   237 next
   238   assume ?lhs
   239   show ?rhs
   240   proof (cases "a = b")
   241     case True with `?lhs` show ?thesis by simp
   242   next
   243     case False
   244     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   245     with False have "a \<in># N" by auto
   246     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   247     moreover note False
   248     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   249   qed
   250 qed
   251 
   252 lemma insert_noteq_member: 
   253   assumes BC: "B + {#b#} = C + {#c#}"
   254    and bnotc: "b \<noteq> c"
   255   shows "c \<in># B"
   256 proof -
   257   have "c \<in># C + {#c#}" by simp
   258   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   259   then have "c \<in># B + {#b#}" using BC by simp
   260   then show "c \<in># B" using nc by simp
   261 qed
   262 
   263 lemma add_eq_conv_ex:
   264   "(M + {#a#} = N + {#b#}) =
   265     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   266   by (auto simp add: add_eq_conv_diff)
   267 
   268 
   269 subsubsection {* Pointwise ordering induced by count *}
   270 
   271 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
   272 begin
   273 
   274 definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
   275   mset_le_def: "A \<le> B \<longleftrightarrow> (\<forall>a. count A a \<le> count B a)"
   276 
   277 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
   278   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
   279 
   280 instance proof
   281 qed (auto simp add: mset_le_def mset_less_def multiset_ext_iff intro: order_trans antisym)
   282 
   283 end
   284 
   285 lemma mset_less_eqI:
   286   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
   287   by (simp add: mset_le_def)
   288 
   289 lemma mset_le_exists_conv:
   290   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
   291 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
   292 apply (auto intro: multiset_ext_iff [THEN iffD2])
   293 done
   294 
   295 lemma mset_le_mono_add_right_cancel [simp]:
   296   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
   297   by (fact add_le_cancel_right)
   298 
   299 lemma mset_le_mono_add_left_cancel [simp]:
   300   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
   301   by (fact add_le_cancel_left)
   302 
   303 lemma mset_le_mono_add:
   304   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
   305   by (fact add_mono)
   306 
   307 lemma mset_le_add_left [simp]:
   308   "(A::'a multiset) \<le> A + B"
   309   unfolding mset_le_def by auto
   310 
   311 lemma mset_le_add_right [simp]:
   312   "B \<le> (A::'a multiset) + B"
   313   unfolding mset_le_def by auto
   314 
   315 lemma mset_le_single:
   316   "a :# B \<Longrightarrow> {#a#} \<le> B"
   317   by (simp add: mset_le_def)
   318 
   319 lemma multiset_diff_union_assoc:
   320   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
   321   by (simp add: multiset_ext_iff mset_le_def)
   322 
   323 lemma mset_le_multiset_union_diff_commute:
   324   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
   325 by (simp add: multiset_ext_iff mset_le_def)
   326 
   327 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   328 apply (clarsimp simp: mset_le_def mset_less_def)
   329 apply (erule_tac x=x in allE)
   330 apply auto
   331 done
   332 
   333 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   334 apply (clarsimp simp: mset_le_def mset_less_def)
   335 apply (erule_tac x = x in allE)
   336 apply auto
   337 done
   338   
   339 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
   340 apply (rule conjI)
   341  apply (simp add: mset_lessD)
   342 apply (clarsimp simp: mset_le_def mset_less_def)
   343 apply safe
   344  apply (erule_tac x = a in allE)
   345  apply (auto split: split_if_asm)
   346 done
   347 
   348 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
   349 apply (rule conjI)
   350  apply (simp add: mset_leD)
   351 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
   352 done
   353 
   354 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
   355   by (auto simp add: mset_less_def mset_le_def multiset_ext_iff)
   356 
   357 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
   358   by (auto simp: mset_le_def mset_less_def)
   359 
   360 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
   361   by simp
   362 
   363 lemma mset_less_add_bothsides:
   364   "T + {#x#} < S + {#x#} \<Longrightarrow> T < S"
   365   by (fact add_less_imp_less_right)
   366 
   367 lemma mset_less_empty_nonempty:
   368   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
   369   by (auto simp: mset_le_def mset_less_def)
   370 
   371 lemma mset_less_diff_self:
   372   "c \<in># B \<Longrightarrow> B - {#c#} < B"
   373   by (auto simp: mset_le_def mset_less_def multiset_ext_iff)
   374 
   375 
   376 subsubsection {* Intersection *}
   377 
   378 instantiation multiset :: (type) semilattice_inf
   379 begin
   380 
   381 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   382   multiset_inter_def: "inf_multiset A B = A - (A - B)"
   383 
   384 instance proof -
   385   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
   386   show "OFCLASS('a multiset, semilattice_inf_class)" proof
   387   qed (auto simp add: multiset_inter_def mset_le_def aux)
   388 qed
   389 
   390 end
   391 
   392 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   393   "multiset_inter \<equiv> inf"
   394 
   395 lemma multiset_inter_count:
   396   "count (A #\<inter> B) x = min (count A x) (count B x)"
   397   by (simp add: multiset_inter_def multiset_typedef)
   398 
   399 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   400   by (rule multiset_ext) (auto simp add: multiset_inter_count)
   401 
   402 lemma multiset_union_diff_commute:
   403   assumes "B #\<inter> C = {#}"
   404   shows "A + B - C = A - C + B"
   405 proof (rule multiset_ext)
   406   fix x
   407   from assms have "min (count B x) (count C x) = 0"
   408     by (auto simp add: multiset_inter_count multiset_ext_iff)
   409   then have "count B x = 0 \<or> count C x = 0"
   410     by auto
   411   then show "count (A + B - C) x = count (A - C + B) x"
   412     by auto
   413 qed
   414 
   415 
   416 subsubsection {* Comprehension (filter) *}
   417 
   418 lemma count_MCollect [simp]:
   419   "count {# x:#M. P x #} a = (if P a then count M a else 0)"
   420   by (simp add: MCollect_def in_multiset multiset_typedef)
   421 
   422 lemma MCollect_empty [simp]: "MCollect {#} P = {#}"
   423   by (rule multiset_ext) simp
   424 
   425 lemma MCollect_single [simp]:
   426   "MCollect {#x#} P = (if P x then {#x#} else {#})"
   427   by (rule multiset_ext) simp
   428 
   429 lemma MCollect_union [simp]:
   430   "MCollect (M + N) f = MCollect M f + MCollect N f"
   431   by (rule multiset_ext) simp
   432 
   433 
   434 subsubsection {* Set of elements *}
   435 
   436 definition set_of :: "'a multiset => 'a set" where
   437   "set_of M = {x. x :# M}"
   438 
   439 lemma set_of_empty [simp]: "set_of {#} = {}"
   440 by (simp add: set_of_def)
   441 
   442 lemma set_of_single [simp]: "set_of {#b#} = {b}"
   443 by (simp add: set_of_def)
   444 
   445 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
   446 by (auto simp add: set_of_def)
   447 
   448 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
   449 by (auto simp add: set_of_def multiset_ext_iff)
   450 
   451 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
   452 by (auto simp add: set_of_def)
   453 
   454 lemma set_of_MCollect [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
   455 by (auto simp add: set_of_def)
   456 
   457 lemma finite_set_of [iff]: "finite (set_of M)"
   458   using count [of M] by (simp add: multiset_def set_of_def)
   459 
   460 
   461 subsubsection {* Size *}
   462 
   463 instantiation multiset :: (type) size
   464 begin
   465 
   466 definition size_def:
   467   "size M = setsum (count M) (set_of M)"
   468 
   469 instance ..
   470 
   471 end
   472 
   473 lemma size_empty [simp]: "size {#} = 0"
   474 by (simp add: size_def)
   475 
   476 lemma size_single [simp]: "size {#b#} = 1"
   477 by (simp add: size_def)
   478 
   479 lemma setsum_count_Int:
   480   "finite A ==> setsum (count N) (A \<inter> set_of N) = setsum (count N) A"
   481 apply (induct rule: finite_induct)
   482  apply simp
   483 apply (simp add: Int_insert_left set_of_def)
   484 done
   485 
   486 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   487 apply (unfold size_def)
   488 apply (subgoal_tac "count (M + N) = (\<lambda>a. count M a + count N a)")
   489  prefer 2
   490  apply (rule ext, simp)
   491 apply (simp (no_asm_simp) add: setsum_Un_nat setsum_addf setsum_count_Int)
   492 apply (subst Int_commute)
   493 apply (simp (no_asm_simp) add: setsum_count_Int)
   494 done
   495 
   496 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   497 by (auto simp add: size_def multiset_ext_iff)
   498 
   499 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   500 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   501 
   502 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
   503 apply (unfold size_def)
   504 apply (drule setsum_SucD)
   505 apply auto
   506 done
   507 
   508 lemma size_eq_Suc_imp_eq_union:
   509   assumes "size M = Suc n"
   510   shows "\<exists>a N. M = N + {#a#}"
   511 proof -
   512   from assms obtain a where "a \<in># M"
   513     by (erule size_eq_Suc_imp_elem [THEN exE])
   514   then have "M = M - {#a#} + {#a#}" by simp
   515   then show ?thesis by blast
   516 qed
   517 
   518 
   519 subsection {* Induction and case splits *}
   520 
   521 lemma setsum_decr:
   522   "finite F ==> (0::nat) < f a ==>
   523     setsum (f (a := f a - 1)) F = (if a\<in>F then setsum f F - 1 else setsum f F)"
   524 apply (induct rule: finite_induct)
   525  apply auto
   526 apply (drule_tac a = a in mk_disjoint_insert, auto)
   527 done
   528 
   529 lemma rep_multiset_induct_aux:
   530 assumes 1: "P (\<lambda>a. (0::nat))"
   531   and 2: "!!f b. f \<in> multiset ==> P f ==> P (f (b := f b + 1))"
   532 shows "\<forall>f. f \<in> multiset --> setsum f {x. f x \<noteq> 0} = n --> P f"
   533 apply (unfold multiset_def)
   534 apply (induct_tac n, simp, clarify)
   535  apply (subgoal_tac "f = (\<lambda>a.0)")
   536   apply simp
   537   apply (rule 1)
   538  apply (rule ext, force, clarify)
   539 apply (frule setsum_SucD, clarify)
   540 apply (rename_tac a)
   541 apply (subgoal_tac "finite {x. (f (a := f a - 1)) x > 0}")
   542  prefer 2
   543  apply (rule finite_subset)
   544   prefer 2
   545   apply assumption
   546  apply simp
   547  apply blast
   548 apply (subgoal_tac "f = (f (a := f a - 1))(a := (f (a := f a - 1)) a + 1)")
   549  prefer 2
   550  apply (rule ext)
   551  apply (simp (no_asm_simp))
   552  apply (erule ssubst, rule 2 [unfolded multiset_def], blast)
   553 apply (erule allE, erule impE, erule_tac [2] mp, blast)
   554 apply (simp (no_asm_simp) add: setsum_decr del: fun_upd_apply One_nat_def)
   555 apply (subgoal_tac "{x. x \<noteq> a --> f x \<noteq> 0} = {x. f x \<noteq> 0}")
   556  prefer 2
   557  apply blast
   558 apply (subgoal_tac "{x. x \<noteq> a \<and> f x \<noteq> 0} = {x. f x \<noteq> 0} - {a}")
   559  prefer 2
   560  apply blast
   561 apply (simp add: le_imp_diff_is_add setsum_diff1_nat cong: conj_cong)
   562 done
   563 
   564 theorem rep_multiset_induct:
   565   "f \<in> multiset ==> P (\<lambda>a. 0) ==>
   566     (!!f b. f \<in> multiset ==> P f ==> P (f (b := f b + 1))) ==> P f"
   567 using rep_multiset_induct_aux by blast
   568 
   569 theorem multiset_induct [case_names empty add, induct type: multiset]:
   570 assumes empty: "P {#}"
   571   and add: "!!M x. P M ==> P (M + {#x#})"
   572 shows "P M"
   573 proof -
   574   note defns = union_def single_def Mempty_def
   575   note add' = add [unfolded defns, simplified]
   576   have aux: "\<And>a::'a. count (Abs_multiset (\<lambda>b. if b = a then 1 else 0)) =
   577     (\<lambda>b. if b = a then 1 else 0)" by (simp add: Abs_multiset_inverse in_multiset) 
   578   show ?thesis
   579     apply (rule count_inverse [THEN subst])
   580     apply (rule count [THEN rep_multiset_induct])
   581      apply (rule empty [unfolded defns])
   582     apply (subgoal_tac "f(b := f b + 1) = (\<lambda>a. f a + (if a=b then 1 else 0))")
   583      prefer 2
   584      apply (simp add: ext_iff)
   585     apply (erule ssubst)
   586     apply (erule Abs_multiset_inverse [THEN subst])
   587     apply (drule add')
   588     apply (simp add: aux)
   589     done
   590 qed
   591 
   592 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   593 by (induct M) auto
   594 
   595 lemma multiset_cases [cases type, case_names empty add]:
   596 assumes em:  "M = {#} \<Longrightarrow> P"
   597 assumes add: "\<And>N x. M = N + {#x#} \<Longrightarrow> P"
   598 shows "P"
   599 proof (cases "M = {#}")
   600   assume "M = {#}" then show ?thesis using em by simp
   601 next
   602   assume "M \<noteq> {#}"
   603   then obtain M' m where "M = M' + {#m#}" 
   604     by (blast dest: multi_nonempty_split)
   605   then show ?thesis using add by simp
   606 qed
   607 
   608 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   609 apply (cases M)
   610  apply simp
   611 apply (rule_tac x="M - {#x#}" in exI, simp)
   612 done
   613 
   614 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   615 by (cases "B = {#}") (auto dest: multi_member_split)
   616 
   617 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
   618 apply (subst multiset_ext_iff)
   619 apply auto
   620 done
   621 
   622 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
   623 proof (induct A arbitrary: B)
   624   case (empty M)
   625   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   626   then obtain M' x where "M = M' + {#x#}" 
   627     by (blast dest: multi_nonempty_split)
   628   then show ?case by simp
   629 next
   630   case (add S x T)
   631   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
   632   have SxsubT: "S + {#x#} < T" by fact
   633   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
   634   then obtain T' where T: "T = T' + {#x#}" 
   635     by (blast dest: multi_member_split)
   636   then have "S < T'" using SxsubT 
   637     by (blast intro: mset_less_add_bothsides)
   638   then have "size S < size T'" using IH by simp
   639   then show ?case using T by simp
   640 qed
   641 
   642 
   643 subsubsection {* Strong induction and subset induction for multisets *}
   644 
   645 text {* Well-foundedness of proper subset operator: *}
   646 
   647 text {* proper multiset subset *}
   648 
   649 definition
   650   mset_less_rel :: "('a multiset * 'a multiset) set" where
   651   "mset_less_rel = {(A,B). A < B}"
   652 
   653 lemma multiset_add_sub_el_shuffle: 
   654   assumes "c \<in># B" and "b \<noteq> c" 
   655   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   656 proof -
   657   from `c \<in># B` obtain A where B: "B = A + {#c#}" 
   658     by (blast dest: multi_member_split)
   659   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   660   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}" 
   661     by (simp add: add_ac)
   662   then show ?thesis using B by simp
   663 qed
   664 
   665 lemma wf_mset_less_rel: "wf mset_less_rel"
   666 apply (unfold mset_less_rel_def)
   667 apply (rule wf_measure [THEN wf_subset, where f1=size])
   668 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   669 done
   670 
   671 text {* The induction rules: *}
   672 
   673 lemma full_multiset_induct [case_names less]:
   674 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
   675 shows "P B"
   676 apply (rule wf_mset_less_rel [THEN wf_induct])
   677 apply (rule ih, auto simp: mset_less_rel_def)
   678 done
   679 
   680 lemma multi_subset_induct [consumes 2, case_names empty add]:
   681 assumes "F \<le> A"
   682   and empty: "P {#}"
   683   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   684 shows "P F"
   685 proof -
   686   from `F \<le> A`
   687   show ?thesis
   688   proof (induct F)
   689     show "P {#}" by fact
   690   next
   691     fix x F
   692     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
   693     show "P (F + {#x#})"
   694     proof (rule insert)
   695       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   696       from i have "F \<le> A" by (auto dest: mset_le_insertD)
   697       with P show "P F" .
   698     qed
   699   qed
   700 qed
   701 
   702 
   703 subsection {* Alternative representations *}
   704 
   705 subsubsection {* Lists *}
   706 
   707 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
   708   "multiset_of [] = {#}" |
   709   "multiset_of (a # x) = multiset_of x + {# a #}"
   710 
   711 lemma in_multiset_in_set:
   712   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
   713   by (induct xs) simp_all
   714 
   715 lemma count_multiset_of:
   716   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   717   by (induct xs) simp_all
   718 
   719 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
   720 by (induct x) auto
   721 
   722 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
   723 by (induct x) auto
   724 
   725 lemma set_of_multiset_of[simp]: "set_of(multiset_of x) = set x"
   726 by (induct x) auto
   727 
   728 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
   729 by (induct xs) auto
   730 
   731 lemma multiset_of_append [simp]:
   732   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
   733   by (induct xs arbitrary: ys) (auto simp: add_ac)
   734 
   735 lemma surj_multiset_of: "surj multiset_of"
   736 apply (unfold surj_def)
   737 apply (rule allI)
   738 apply (rule_tac M = y in multiset_induct)
   739  apply auto
   740 apply (rule_tac x = "x # xa" in exI)
   741 apply auto
   742 done
   743 
   744 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
   745 by (induct x) auto
   746 
   747 lemma distinct_count_atmost_1:
   748   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
   749 apply (induct x, simp, rule iffI, simp_all)
   750 apply (rule conjI)
   751 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
   752 apply (erule_tac x = a in allE, simp, clarify)
   753 apply (erule_tac x = aa in allE, simp)
   754 done
   755 
   756 lemma multiset_of_eq_setD:
   757   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
   758 by (rule) (auto simp add:multiset_ext_iff set_count_greater_0)
   759 
   760 lemma set_eq_iff_multiset_of_eq_distinct:
   761   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   762     (set x = set y) = (multiset_of x = multiset_of y)"
   763 by (auto simp: multiset_ext_iff distinct_count_atmost_1)
   764 
   765 lemma set_eq_iff_multiset_of_remdups_eq:
   766    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
   767 apply (rule iffI)
   768 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
   769 apply (drule distinct_remdups [THEN distinct_remdups
   770       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
   771 apply simp
   772 done
   773 
   774 lemma multiset_of_compl_union [simp]:
   775   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
   776   by (induct xs) (auto simp: add_ac)
   777 
   778 lemma count_filter:
   779   "count (multiset_of xs) x = length [y \<leftarrow> xs. y = x]"
   780 by (induct xs) auto
   781 
   782 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
   783 apply (induct ls arbitrary: i)
   784  apply simp
   785 apply (case_tac i)
   786  apply auto
   787 done
   788 
   789 lemma multiset_of_remove1[simp]:
   790   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
   791 by (induct xs) (auto simp add: multiset_ext_iff)
   792 
   793 lemma multiset_of_eq_length:
   794   assumes "multiset_of xs = multiset_of ys"
   795   shows "length xs = length ys"
   796 using assms proof (induct xs arbitrary: ys)
   797   case Nil then show ?case by simp
   798 next
   799   case (Cons x xs)
   800   then have "x \<in># multiset_of ys" by (simp add: union_single_eq_member)
   801   then have "x \<in> set ys" by (simp add: in_multiset_in_set)
   802   from Cons.prems [symmetric] have "multiset_of xs = multiset_of (remove1 x ys)"
   803     by simp
   804   with Cons.hyps have "length xs = length (remove1 x ys)" .
   805   with `x \<in> set ys` show ?case
   806     by (auto simp add: length_remove1 dest: length_pos_if_in_set)
   807 qed
   808 
   809 lemma (in linorder) multiset_of_insort [simp]:
   810   "multiset_of (insort x xs) = {#x#} + multiset_of xs"
   811   by (induct xs) (simp_all add: ac_simps)
   812 
   813 lemma (in linorder) multiset_of_sort [simp]:
   814   "multiset_of (sort xs) = multiset_of xs"
   815   by (induct xs) (simp_all add: ac_simps)
   816 
   817 text {*
   818   This lemma shows which properties suffice to show that a function
   819   @{text "f"} with @{text "f xs = ys"} behaves like sort.
   820 *}
   821 
   822 lemma (in linorder) properties_for_sort:
   823   "multiset_of ys = multiset_of xs \<Longrightarrow> sorted ys \<Longrightarrow> sort xs = ys"
   824 proof (induct xs arbitrary: ys)
   825   case Nil then show ?case by simp
   826 next
   827   case (Cons x xs)
   828   then have "x \<in> set ys"
   829     by (auto simp add:  mem_set_multiset_eq intro!: ccontr)
   830   with Cons.prems Cons.hyps [of "remove1 x ys"] show ?case
   831     by (simp add: sorted_remove1 multiset_of_remove1 insort_remove1)
   832 qed
   833 
   834 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
   835   by (induct xs) (auto intro: order_trans)
   836 
   837 lemma multiset_of_update:
   838   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
   839 proof (induct ls arbitrary: i)
   840   case Nil then show ?case by simp
   841 next
   842   case (Cons x xs)
   843   show ?case
   844   proof (cases i)
   845     case 0 then show ?thesis by simp
   846   next
   847     case (Suc i')
   848     with Cons show ?thesis
   849       apply simp
   850       apply (subst add_assoc)
   851       apply (subst add_commute [of "{#v#}" "{#x#}"])
   852       apply (subst add_assoc [symmetric])
   853       apply simp
   854       apply (rule mset_le_multiset_union_diff_commute)
   855       apply (simp add: mset_le_single nth_mem_multiset_of)
   856       done
   857   qed
   858 qed
   859 
   860 lemma multiset_of_swap:
   861   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
   862     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
   863   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
   864 
   865 
   866 subsubsection {* Association lists -- including rudimentary code generation *}
   867 
   868 definition count_of :: "('a \<times> nat) list \<Rightarrow> 'a \<Rightarrow> nat" where
   869   "count_of xs x = (case map_of xs x of None \<Rightarrow> 0 | Some n \<Rightarrow> n)"
   870 
   871 lemma count_of_multiset:
   872   "count_of xs \<in> multiset"
   873 proof -
   874   let ?A = "{x::'a. 0 < (case map_of xs x of None \<Rightarrow> 0\<Colon>nat | Some (n\<Colon>nat) \<Rightarrow> n)}"
   875   have "?A \<subseteq> dom (map_of xs)"
   876   proof
   877     fix x
   878     assume "x \<in> ?A"
   879     then have "0 < (case map_of xs x of None \<Rightarrow> 0\<Colon>nat | Some (n\<Colon>nat) \<Rightarrow> n)" by simp
   880     then have "map_of xs x \<noteq> None" by (cases "map_of xs x") auto
   881     then show "x \<in> dom (map_of xs)" by auto
   882   qed
   883   with finite_dom_map_of [of xs] have "finite ?A"
   884     by (auto intro: finite_subset)
   885   then show ?thesis
   886     by (simp add: count_of_def ext_iff multiset_def)
   887 qed
   888 
   889 lemma count_simps [simp]:
   890   "count_of [] = (\<lambda>_. 0)"
   891   "count_of ((x, n) # xs) = (\<lambda>y. if x = y then n else count_of xs y)"
   892   by (simp_all add: count_of_def ext_iff)
   893 
   894 lemma count_of_empty:
   895   "x \<notin> fst ` set xs \<Longrightarrow> count_of xs x = 0"
   896   by (induct xs) (simp_all add: count_of_def)
   897 
   898 lemma count_of_filter:
   899   "count_of (filter (P \<circ> fst) xs) x = (if P x then count_of xs x else 0)"
   900   by (induct xs) auto
   901 
   902 definition Bag :: "('a \<times> nat) list \<Rightarrow> 'a multiset" where
   903   "Bag xs = Abs_multiset (count_of xs)"
   904 
   905 code_datatype Bag
   906 
   907 lemma count_Bag [simp, code]:
   908   "count (Bag xs) = count_of xs"
   909   by (simp add: Bag_def count_of_multiset Abs_multiset_inverse)
   910 
   911 lemma Mempty_Bag [code]:
   912   "{#} = Bag []"
   913   by (simp add: multiset_ext_iff)
   914   
   915 lemma single_Bag [code]:
   916   "{#x#} = Bag [(x, 1)]"
   917   by (simp add: multiset_ext_iff)
   918 
   919 lemma MCollect_Bag [code]:
   920   "MCollect (Bag xs) P = Bag (filter (P \<circ> fst) xs)"
   921   by (simp add: multiset_ext_iff count_of_filter)
   922 
   923 lemma mset_less_eq_Bag [code]:
   924   "Bag xs \<le> A \<longleftrightarrow> (\<forall>(x, n) \<in> set xs. count_of xs x \<le> count A x)"
   925     (is "?lhs \<longleftrightarrow> ?rhs")
   926 proof
   927   assume ?lhs then show ?rhs
   928     by (auto simp add: mset_le_def count_Bag)
   929 next
   930   assume ?rhs
   931   show ?lhs
   932   proof (rule mset_less_eqI)
   933     fix x
   934     from `?rhs` have "count_of xs x \<le> count A x"
   935       by (cases "x \<in> fst ` set xs") (auto simp add: count_of_empty)
   936     then show "count (Bag xs) x \<le> count A x"
   937       by (simp add: mset_le_def count_Bag)
   938   qed
   939 qed
   940 
   941 instantiation multiset :: (equal) equal
   942 begin
   943 
   944 definition
   945   "HOL.equal A B \<longleftrightarrow> (A::'a multiset) \<le> B \<and> B \<le> A"
   946 
   947 instance proof
   948 qed (simp add: equal_multiset_def eq_iff)
   949 
   950 end
   951 
   952 lemma [code nbe]:
   953   "HOL.equal (A :: 'a::equal multiset) A \<longleftrightarrow> True"
   954   by (fact equal_refl)
   955 
   956 definition (in term_syntax)
   957   bagify :: "('a\<Colon>typerep \<times> nat) list \<times> (unit \<Rightarrow> Code_Evaluation.term)
   958     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
   959   [code_unfold]: "bagify xs = Code_Evaluation.valtermify Bag {\<cdot>} xs"
   960 
   961 notation fcomp (infixl "\<circ>>" 60)
   962 notation scomp (infixl "\<circ>\<rightarrow>" 60)
   963 
   964 instantiation multiset :: (random) random
   965 begin
   966 
   967 definition
   968   "Quickcheck.random i = Quickcheck.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (bagify xs))"
   969 
   970 instance ..
   971 
   972 end
   973 
   974 no_notation fcomp (infixl "\<circ>>" 60)
   975 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   976 
   977 hide_const (open) bagify
   978 
   979 
   980 subsection {* The multiset order *}
   981 
   982 subsubsection {* Well-foundedness *}
   983 
   984 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
   985   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
   986       (\<forall>b. b :# K --> (b, a) \<in> r)}"
   987 
   988 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
   989   "mult r = (mult1 r)\<^sup>+"
   990 
   991 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
   992 by (simp add: mult1_def)
   993 
   994 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
   995     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
   996     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
   997   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
   998 proof (unfold mult1_def)
   999   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
  1000   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1001   let ?case1 = "?case1 {(N, M). ?R N M}"
  1002 
  1003   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
  1004   then have "\<exists>a' M0' K.
  1005       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
  1006   then show "?case1 \<or> ?case2"
  1007   proof (elim exE conjE)
  1008     fix a' M0' K
  1009     assume N: "N = M0' + K" and r: "?r K a'"
  1010     assume "M0 + {#a#} = M0' + {#a'#}"
  1011     then have "M0 = M0' \<and> a = a' \<or>
  1012         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
  1013       by (simp only: add_eq_conv_ex)
  1014     then show ?thesis
  1015     proof (elim disjE conjE exE)
  1016       assume "M0 = M0'" "a = a'"
  1017       with N r have "?r K a \<and> N = M0 + K" by simp
  1018       then have ?case2 .. then show ?thesis ..
  1019     next
  1020       fix K'
  1021       assume "M0' = K' + {#a#}"
  1022       with N have n: "N = K' + K + {#a#}" by (simp add: add_ac)
  1023 
  1024       assume "M0 = K' + {#a'#}"
  1025       with r have "?R (K' + K) M0" by blast
  1026       with n have ?case1 by simp then show ?thesis ..
  1027     qed
  1028   qed
  1029 qed
  1030 
  1031 lemma all_accessible: "wf r ==> \<forall>M. M \<in> acc (mult1 r)"
  1032 proof
  1033   let ?R = "mult1 r"
  1034   let ?W = "acc ?R"
  1035   {
  1036     fix M M0 a
  1037     assume M0: "M0 \<in> ?W"
  1038       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1039       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
  1040     have "M0 + {#a#} \<in> ?W"
  1041     proof (rule accI [of "M0 + {#a#}"])
  1042       fix N
  1043       assume "(N, M0 + {#a#}) \<in> ?R"
  1044       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
  1045           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
  1046         by (rule less_add)
  1047       then show "N \<in> ?W"
  1048       proof (elim exE disjE conjE)
  1049         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
  1050         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
  1051         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
  1052         then show "N \<in> ?W" by (simp only: N)
  1053       next
  1054         fix K
  1055         assume N: "N = M0 + K"
  1056         assume "\<forall>b. b :# K --> (b, a) \<in> r"
  1057         then have "M0 + K \<in> ?W"
  1058         proof (induct K)
  1059           case empty
  1060           from M0 show "M0 + {#} \<in> ?W" by simp
  1061         next
  1062           case (add K x)
  1063           from add.prems have "(x, a) \<in> r" by simp
  1064           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1065           moreover from add have "M0 + K \<in> ?W" by simp
  1066           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1067           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add_assoc)
  1068         qed
  1069         then show "N \<in> ?W" by (simp only: N)
  1070       qed
  1071     qed
  1072   } note tedious_reasoning = this
  1073 
  1074   assume wf: "wf r"
  1075   fix M
  1076   show "M \<in> ?W"
  1077   proof (induct M)
  1078     show "{#} \<in> ?W"
  1079     proof (rule accI)
  1080       fix b assume "(b, {#}) \<in> ?R"
  1081       with not_less_empty show "b \<in> ?W" by contradiction
  1082     qed
  1083 
  1084     fix M a assume "M \<in> ?W"
  1085     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1086     proof induct
  1087       fix a
  1088       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1089       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1090       proof
  1091         fix M assume "M \<in> ?W"
  1092         then show "M + {#a#} \<in> ?W"
  1093           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1094       qed
  1095     qed
  1096     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
  1097   qed
  1098 qed
  1099 
  1100 theorem wf_mult1: "wf r ==> wf (mult1 r)"
  1101 by (rule acc_wfI) (rule all_accessible)
  1102 
  1103 theorem wf_mult: "wf r ==> wf (mult r)"
  1104 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1105 
  1106 
  1107 subsubsection {* Closure-free presentation *}
  1108 
  1109 text {* One direction. *}
  1110 
  1111 lemma mult_implies_one_step:
  1112   "trans r ==> (M, N) \<in> mult r ==>
  1113     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1114     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
  1115 apply (unfold mult_def mult1_def set_of_def)
  1116 apply (erule converse_trancl_induct, clarify)
  1117  apply (rule_tac x = M0 in exI, simp, clarify)
  1118 apply (case_tac "a :# K")
  1119  apply (rule_tac x = I in exI)
  1120  apply (simp (no_asm))
  1121  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1122  apply (simp (no_asm_simp) add: add_assoc [symmetric])
  1123  apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong)
  1124  apply (simp add: diff_union_single_conv)
  1125  apply (simp (no_asm_use) add: trans_def)
  1126  apply blast
  1127 apply (subgoal_tac "a :# I")
  1128  apply (rule_tac x = "I - {#a#}" in exI)
  1129  apply (rule_tac x = "J + {#a#}" in exI)
  1130  apply (rule_tac x = "K + Ka" in exI)
  1131  apply (rule conjI)
  1132   apply (simp add: multiset_ext_iff split: nat_diff_split)
  1133  apply (rule conjI)
  1134   apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong, simp)
  1135   apply (simp add: multiset_ext_iff split: nat_diff_split)
  1136  apply (simp (no_asm_use) add: trans_def)
  1137  apply blast
  1138 apply (subgoal_tac "a :# (M0 + {#a#})")
  1139  apply simp
  1140 apply (simp (no_asm))
  1141 done
  1142 
  1143 lemma one_step_implies_mult_aux:
  1144   "trans r ==>
  1145     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
  1146       --> (I + K, I + J) \<in> mult r"
  1147 apply (induct_tac n, auto)
  1148 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1149 apply (rename_tac "J'", simp)
  1150 apply (erule notE, auto)
  1151 apply (case_tac "J' = {#}")
  1152  apply (simp add: mult_def)
  1153  apply (rule r_into_trancl)
  1154  apply (simp add: mult1_def set_of_def, blast)
  1155 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
  1156 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1157 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
  1158 apply (erule ssubst)
  1159 apply (simp add: Ball_def, auto)
  1160 apply (subgoal_tac
  1161   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
  1162     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
  1163  prefer 2
  1164  apply force
  1165 apply (simp (no_asm_use) add: add_assoc [symmetric] mult_def)
  1166 apply (erule trancl_trans)
  1167 apply (rule r_into_trancl)
  1168 apply (simp add: mult1_def set_of_def)
  1169 apply (rule_tac x = a in exI)
  1170 apply (rule_tac x = "I + J'" in exI)
  1171 apply (simp add: add_ac)
  1172 done
  1173 
  1174 lemma one_step_implies_mult:
  1175   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
  1176     ==> (I + K, I + J) \<in> mult r"
  1177 using one_step_implies_mult_aux by blast
  1178 
  1179 
  1180 subsubsection {* Partial-order properties *}
  1181 
  1182 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
  1183   "M' <# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1184 
  1185 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
  1186   "M' <=# M \<longleftrightarrow> M' <# M \<or> M' = M"
  1187 
  1188 notation (xsymbols) less_multiset (infix "\<subset>#" 50)
  1189 notation (xsymbols) le_multiset (infix "\<subseteq>#" 50)
  1190 
  1191 interpretation multiset_order: order le_multiset less_multiset
  1192 proof -
  1193   have irrefl: "\<And>M :: 'a multiset. \<not> M \<subset># M"
  1194   proof
  1195     fix M :: "'a multiset"
  1196     assume "M \<subset># M"
  1197     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1198     have "trans {(x'::'a, x). x' < x}"
  1199       by (rule transI) simp
  1200     moreover note MM
  1201     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1202       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
  1203       by (rule mult_implies_one_step)
  1204     then obtain I J K where "M = I + J" and "M = I + K"
  1205       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
  1206     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
  1207     have "finite (set_of K)" by simp
  1208     moreover note aux2
  1209     ultimately have "set_of K = {}"
  1210       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1211     with aux1 show False by simp
  1212   qed
  1213   have trans: "\<And>K M N :: 'a multiset. K \<subset># M \<Longrightarrow> M \<subset># N \<Longrightarrow> K \<subset># N"
  1214     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1215   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset" proof
  1216   qed (auto simp add: le_multiset_def irrefl dest: trans)
  1217 qed
  1218 
  1219 lemma mult_less_irrefl [elim!]:
  1220   "M \<subset># (M::'a::order multiset) ==> R"
  1221   by (simp add: multiset_order.less_irrefl)
  1222 
  1223 
  1224 subsubsection {* Monotonicity of multiset union *}
  1225 
  1226 lemma mult1_union:
  1227   "(B, D) \<in> mult1 r ==> trans r ==> (C + B, C + D) \<in> mult1 r"
  1228 apply (unfold mult1_def)
  1229 apply auto
  1230 apply (rule_tac x = a in exI)
  1231 apply (rule_tac x = "C + M0" in exI)
  1232 apply (simp add: add_assoc)
  1233 done
  1234 
  1235 lemma union_less_mono2: "B \<subset># D ==> C + B \<subset># C + (D::'a::order multiset)"
  1236 apply (unfold less_multiset_def mult_def)
  1237 apply (erule trancl_induct)
  1238  apply (blast intro: mult1_union transI order_less_trans r_into_trancl)
  1239 apply (blast intro: mult1_union transI order_less_trans r_into_trancl trancl_trans)
  1240 done
  1241 
  1242 lemma union_less_mono1: "B \<subset># D ==> B + C \<subset># D + (C::'a::order multiset)"
  1243 apply (subst add_commute [of B C])
  1244 apply (subst add_commute [of D C])
  1245 apply (erule union_less_mono2)
  1246 done
  1247 
  1248 lemma union_less_mono:
  1249   "A \<subset># C ==> B \<subset># D ==> A + B \<subset># C + (D::'a::order multiset)"
  1250   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1251 
  1252 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1253 proof
  1254 qed (auto simp add: le_multiset_def intro: union_less_mono2)
  1255 
  1256 
  1257 subsection {* The fold combinator *}
  1258 
  1259 text {*
  1260   The intended behaviour is
  1261   @{text "fold_mset f z {#x\<^isub>1, ..., x\<^isub>n#} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
  1262   if @{text f} is associative-commutative. 
  1263 *}
  1264 
  1265 text {*
  1266   The graph of @{text "fold_mset"}, @{text "z"}: the start element,
  1267   @{text "f"}: folding function, @{text "A"}: the multiset, @{text
  1268   "y"}: the result.
  1269 *}
  1270 inductive 
  1271   fold_msetG :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b \<Rightarrow> bool" 
  1272   for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" 
  1273   and z :: 'b
  1274 where
  1275   emptyI [intro]:  "fold_msetG f z {#} z"
  1276 | insertI [intro]: "fold_msetG f z A y \<Longrightarrow> fold_msetG f z (A + {#x#}) (f x y)"
  1277 
  1278 inductive_cases empty_fold_msetGE [elim!]: "fold_msetG f z {#} x"
  1279 inductive_cases insert_fold_msetGE: "fold_msetG f z (A + {#}) y" 
  1280 
  1281 definition
  1282   fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b" where
  1283   "fold_mset f z A = (THE x. fold_msetG f z A x)"
  1284 
  1285 lemma Diff1_fold_msetG:
  1286   "fold_msetG f z (A - {#x#}) y \<Longrightarrow> x \<in># A \<Longrightarrow> fold_msetG f z A (f x y)"
  1287 apply (frule_tac x = x in fold_msetG.insertI)
  1288 apply auto
  1289 done
  1290 
  1291 lemma fold_msetG_nonempty: "\<exists>x. fold_msetG f z A x"
  1292 apply (induct A)
  1293  apply blast
  1294 apply clarsimp
  1295 apply (drule_tac x = x in fold_msetG.insertI)
  1296 apply auto
  1297 done
  1298 
  1299 lemma fold_mset_empty[simp]: "fold_mset f z {#} = z"
  1300 unfolding fold_mset_def by blast
  1301 
  1302 context fun_left_comm
  1303 begin
  1304 
  1305 lemma fold_msetG_determ:
  1306   "fold_msetG f z A x \<Longrightarrow> fold_msetG f z A y \<Longrightarrow> y = x"
  1307 proof (induct arbitrary: x y z rule: full_multiset_induct)
  1308   case (less M x\<^isub>1 x\<^isub>2 Z)
  1309   have IH: "\<forall>A. A < M \<longrightarrow> 
  1310     (\<forall>x x' x''. fold_msetG f x'' A x \<longrightarrow> fold_msetG f x'' A x'
  1311                \<longrightarrow> x' = x)" by fact
  1312   have Mfoldx\<^isub>1: "fold_msetG f Z M x\<^isub>1" and Mfoldx\<^isub>2: "fold_msetG f Z M x\<^isub>2" by fact+
  1313   show ?case
  1314   proof (rule fold_msetG.cases [OF Mfoldx\<^isub>1])
  1315     assume "M = {#}" and "x\<^isub>1 = Z"
  1316     then show ?case using Mfoldx\<^isub>2 by auto 
  1317   next
  1318     fix B b u
  1319     assume "M = B + {#b#}" and "x\<^isub>1 = f b u" and Bu: "fold_msetG f Z B u"
  1320     then have MBb: "M = B + {#b#}" and x\<^isub>1: "x\<^isub>1 = f b u" by auto
  1321     show ?case
  1322     proof (rule fold_msetG.cases [OF Mfoldx\<^isub>2])
  1323       assume "M = {#}" "x\<^isub>2 = Z"
  1324       then show ?case using Mfoldx\<^isub>1 by auto
  1325     next
  1326       fix C c v
  1327       assume "M = C + {#c#}" and "x\<^isub>2 = f c v" and Cv: "fold_msetG f Z C v"
  1328       then have MCc: "M = C + {#c#}" and x\<^isub>2: "x\<^isub>2 = f c v" by auto
  1329       then have CsubM: "C < M" by simp
  1330       from MBb have BsubM: "B < M" by simp
  1331       show ?case
  1332       proof cases
  1333         assume "b=c"
  1334         then moreover have "B = C" using MBb MCc by auto
  1335         ultimately show ?thesis using Bu Cv x\<^isub>1 x\<^isub>2 CsubM IH by auto
  1336       next
  1337         assume diff: "b \<noteq> c"
  1338         let ?D = "B - {#c#}"
  1339         have cinB: "c \<in># B" and binC: "b \<in># C" using MBb MCc diff
  1340           by (auto intro: insert_noteq_member dest: sym)
  1341         have "B - {#c#} < B" using cinB by (rule mset_less_diff_self)
  1342         then have DsubM: "?D < M" using BsubM by (blast intro: order_less_trans)
  1343         from MBb MCc have "B + {#b#} = C + {#c#}" by blast
  1344         then have [simp]: "B + {#b#} - {#c#} = C"
  1345           using MBb MCc binC cinB by auto
  1346         have B: "B = ?D + {#c#}" and C: "C = ?D + {#b#}"
  1347           using MBb MCc diff binC cinB
  1348           by (auto simp: multiset_add_sub_el_shuffle)
  1349         then obtain d where Dfoldd: "fold_msetG f Z ?D d"
  1350           using fold_msetG_nonempty by iprover
  1351         then have "fold_msetG f Z B (f c d)" using cinB
  1352           by (rule Diff1_fold_msetG)
  1353         then have "f c d = u" using IH BsubM Bu by blast
  1354         moreover 
  1355         have "fold_msetG f Z C (f b d)" using binC cinB diff Dfoldd
  1356           by (auto simp: multiset_add_sub_el_shuffle 
  1357             dest: fold_msetG.insertI [where x=b])
  1358         then have "f b d = v" using IH CsubM Cv by blast
  1359         ultimately show ?thesis using x\<^isub>1 x\<^isub>2
  1360           by (auto simp: fun_left_comm)
  1361       qed
  1362     qed
  1363   qed
  1364 qed
  1365         
  1366 lemma fold_mset_insert_aux:
  1367   "(fold_msetG f z (A + {#x#}) v) =
  1368     (\<exists>y. fold_msetG f z A y \<and> v = f x y)"
  1369 apply (rule iffI)
  1370  prefer 2
  1371  apply blast
  1372 apply (rule_tac A=A and f=f in fold_msetG_nonempty [THEN exE, standard])
  1373 apply (blast intro: fold_msetG_determ)
  1374 done
  1375 
  1376 lemma fold_mset_equality: "fold_msetG f z A y \<Longrightarrow> fold_mset f z A = y"
  1377 unfolding fold_mset_def by (blast intro: fold_msetG_determ)
  1378 
  1379 lemma fold_mset_insert:
  1380   "fold_mset f z (A + {#x#}) = f x (fold_mset f z A)"
  1381 apply (simp add: fold_mset_def fold_mset_insert_aux add_commute)  
  1382 apply (rule the_equality)
  1383  apply (auto cong add: conj_cong 
  1384      simp add: fold_mset_def [symmetric] fold_mset_equality fold_msetG_nonempty)
  1385 done
  1386 
  1387 lemma fold_mset_insert_idem:
  1388   "fold_mset f z (A + {#a#}) = f a (fold_mset f z A)"
  1389 apply (simp add: fold_mset_def fold_mset_insert_aux)
  1390 apply (rule the_equality)
  1391  apply (auto cong add: conj_cong 
  1392      simp add: fold_mset_def [symmetric] fold_mset_equality fold_msetG_nonempty)
  1393 done
  1394 
  1395 lemma fold_mset_commute: "f x (fold_mset f z A) = fold_mset f (f x z) A"
  1396 by (induct A) (auto simp: fold_mset_insert fun_left_comm [of x])
  1397 
  1398 lemma fold_mset_single [simp]: "fold_mset f z {#x#} = f x z"
  1399 using fold_mset_insert [of z "{#}"] by simp
  1400 
  1401 lemma fold_mset_union [simp]:
  1402   "fold_mset f z (A+B) = fold_mset f (fold_mset f z A) B"
  1403 proof (induct A)
  1404   case empty then show ?case by simp
  1405 next
  1406   case (add A x)
  1407   have "A + {#x#} + B = (A+B) + {#x#}" by (simp add: add_ac)
  1408   then have "fold_mset f z (A + {#x#} + B) = f x (fold_mset f z (A + B))" 
  1409     by (simp add: fold_mset_insert)
  1410   also have "\<dots> = fold_mset f (fold_mset f z (A + {#x#})) B"
  1411     by (simp add: fold_mset_commute[of x,symmetric] add fold_mset_insert)
  1412   finally show ?case .
  1413 qed
  1414 
  1415 lemma fold_mset_fusion:
  1416   assumes "fun_left_comm g"
  1417   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold_mset g w A) = fold_mset f (h w) A" (is "PROP ?P")
  1418 proof -
  1419   interpret fun_left_comm g by (fact assms)
  1420   show "PROP ?P" by (induct A) auto
  1421 qed
  1422 
  1423 lemma fold_mset_rec:
  1424   assumes "a \<in># A" 
  1425   shows "fold_mset f z A = f a (fold_mset f z (A - {#a#}))"
  1426 proof -
  1427   from assms obtain A' where "A = A' + {#a#}"
  1428     by (blast dest: multi_member_split)
  1429   then show ?thesis by simp
  1430 qed
  1431 
  1432 end
  1433 
  1434 text {*
  1435   A note on code generation: When defining some function containing a
  1436   subterm @{term"fold_mset F"}, code generation is not automatic. When
  1437   interpreting locale @{text left_commutative} with @{text F}, the
  1438   would be code thms for @{const fold_mset} become thms like
  1439   @{term"fold_mset F z {#} = z"} where @{text F} is not a pattern but
  1440   contains defined symbols, i.e.\ is not a code thm. Hence a separate
  1441   constant with its own code thms needs to be introduced for @{text
  1442   F}. See the image operator below.
  1443 *}
  1444 
  1445 
  1446 subsection {* Image *}
  1447 
  1448 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
  1449   "image_mset f = fold_mset (op + o single o f) {#}"
  1450 
  1451 interpretation image_left_comm: fun_left_comm "op + o single o f"
  1452 proof qed (simp add: add_ac)
  1453 
  1454 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
  1455 by (simp add: image_mset_def)
  1456 
  1457 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
  1458 by (simp add: image_mset_def)
  1459 
  1460 lemma image_mset_insert:
  1461   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
  1462 by (simp add: image_mset_def add_ac)
  1463 
  1464 lemma image_mset_union [simp]:
  1465   "image_mset f (M+N) = image_mset f M + image_mset f N"
  1466 apply (induct N)
  1467  apply simp
  1468 apply (simp add: add_assoc [symmetric] image_mset_insert)
  1469 done
  1470 
  1471 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
  1472 by (induct M) simp_all
  1473 
  1474 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
  1475 by (cases M) auto
  1476 
  1477 syntax
  1478   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
  1479       ("({#_/. _ :# _#})")
  1480 translations
  1481   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
  1482 
  1483 syntax
  1484   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
  1485       ("({#_/ | _ :# _./ _#})")
  1486 translations
  1487   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
  1488 
  1489 text {*
  1490   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
  1491   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
  1492   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
  1493   @{term "{#x+x|x:#M. x<c#}"}.
  1494 *}
  1495 
  1496 
  1497 subsection {* Termination proofs with multiset orders *}
  1498 
  1499 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1500   and multi_member_this: "x \<in># {# x #} + XS"
  1501   and multi_member_last: "x \<in># {# x #}"
  1502   by auto
  1503 
  1504 definition "ms_strict = mult pair_less"
  1505 definition "ms_weak = ms_strict \<union> Id"
  1506 
  1507 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1508 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1509 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1510 
  1511 lemma smsI:
  1512   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1513   unfolding ms_strict_def
  1514 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1515 
  1516 lemma wmsI:
  1517   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1518   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1519 unfolding ms_weak_def ms_strict_def
  1520 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1521 
  1522 inductive pw_leq
  1523 where
  1524   pw_leq_empty: "pw_leq {#} {#}"
  1525 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1526 
  1527 lemma pw_leq_lstep:
  1528   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1529 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1530 
  1531 lemma pw_leq_split:
  1532   assumes "pw_leq X Y"
  1533   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1534   using assms
  1535 proof (induct)
  1536   case pw_leq_empty thus ?case by auto
  1537 next
  1538   case (pw_leq_step x y X Y)
  1539   then obtain A B Z where
  1540     [simp]: "X = A + Z" "Y = B + Z" 
  1541       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})" 
  1542     by auto
  1543   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less" 
  1544     unfolding pair_leq_def by auto
  1545   thus ?case
  1546   proof
  1547     assume [simp]: "x = y"
  1548     have
  1549       "{#x#} + X = A + ({#y#}+Z) 
  1550       \<and> {#y#} + Y = B + ({#y#}+Z)
  1551       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1552       by (auto simp: add_ac)
  1553     thus ?case by (intro exI)
  1554   next
  1555     assume A: "(x, y) \<in> pair_less"
  1556     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1557     have "{#x#} + X = ?A' + Z"
  1558       "{#y#} + Y = ?B' + Z"
  1559       by (auto simp add: add_ac)
  1560     moreover have 
  1561       "(set_of ?A', set_of ?B') \<in> max_strict"
  1562       using 1 A unfolding max_strict_def 
  1563       by (auto elim!: max_ext.cases)
  1564     ultimately show ?thesis by blast
  1565   qed
  1566 qed
  1567 
  1568 lemma 
  1569   assumes pwleq: "pw_leq Z Z'"
  1570   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1571   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1572   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1573 proof -
  1574   from pw_leq_split[OF pwleq] 
  1575   obtain A' B' Z''
  1576     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1577     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1578     by blast
  1579   {
  1580     assume max: "(set_of A, set_of B) \<in> max_strict"
  1581     from mx_or_empty
  1582     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1583     proof
  1584       assume max': "(set_of A', set_of B') \<in> max_strict"
  1585       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
  1586         by (auto simp: max_strict_def intro: max_ext_additive)
  1587       thus ?thesis by (rule smsI) 
  1588     next
  1589       assume [simp]: "A' = {#} \<and> B' = {#}"
  1590       show ?thesis by (rule smsI) (auto intro: max)
  1591     qed
  1592     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:add_ac)
  1593     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1594   }
  1595   from mx_or_empty
  1596   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1597   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:add_ac)
  1598 qed
  1599 
  1600 lemma empty_idemp: "{#} + x = x" "x + {#} = x"
  1601 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1602 and nonempty_single: "{# x #} \<noteq> {#}"
  1603 by auto
  1604 
  1605 setup {*
  1606 let
  1607   fun msetT T = Type (@{type_name multiset}, [T]);
  1608 
  1609   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1610     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1611     | mk_mset T (x :: xs) =
  1612           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1613                 mk_mset T [x] $ mk_mset T xs
  1614 
  1615   fun mset_member_tac m i =
  1616       (if m <= 0 then
  1617            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
  1618        else
  1619            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
  1620 
  1621   val mset_nonempty_tac =
  1622       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
  1623 
  1624   val regroup_munion_conv =
  1625       Function_Lib.regroup_conv @{const_abbrev Mempty} @{const_name plus}
  1626         (map (fn t => t RS eq_reflection) (@{thms add_ac} @ @{thms empty_idemp}))
  1627 
  1628   fun unfold_pwleq_tac i =
  1629     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
  1630       ORELSE (rtac @{thm pw_leq_lstep} i)
  1631       ORELSE (rtac @{thm pw_leq_empty} i)
  1632 
  1633   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
  1634                       @{thm Un_insert_left}, @{thm Un_empty_left}]
  1635 in
  1636   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset 
  1637   {
  1638     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1639     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1640     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
  1641     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  1642     reduction_pair= @{thm ms_reduction_pair}
  1643   })
  1644 end
  1645 *}
  1646 
  1647 
  1648 subsection {* Legacy theorem bindings *}
  1649 
  1650 lemmas multi_count_eq = multiset_ext_iff [symmetric]
  1651 
  1652 lemma union_commute: "M + N = N + (M::'a multiset)"
  1653   by (fact add_commute)
  1654 
  1655 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  1656   by (fact add_assoc)
  1657 
  1658 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  1659   by (fact add_left_commute)
  1660 
  1661 lemmas union_ac = union_assoc union_commute union_lcomm
  1662 
  1663 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  1664   by (fact add_right_cancel)
  1665 
  1666 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  1667   by (fact add_left_cancel)
  1668 
  1669 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  1670   by (fact add_imp_eq)
  1671 
  1672 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
  1673   by (fact order_less_trans)
  1674 
  1675 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  1676   by (fact inf.commute)
  1677 
  1678 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  1679   by (fact inf.assoc [symmetric])
  1680 
  1681 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  1682   by (fact inf.left_commute)
  1683 
  1684 lemmas multiset_inter_ac =
  1685   multiset_inter_commute
  1686   multiset_inter_assoc
  1687   multiset_inter_left_commute
  1688 
  1689 lemma mult_less_not_refl:
  1690   "\<not> M \<subset># (M::'a::order multiset)"
  1691   by (fact multiset_order.less_irrefl)
  1692 
  1693 lemma mult_less_trans:
  1694   "K \<subset># M ==> M \<subset># N ==> K \<subset># (N::'a::order multiset)"
  1695   by (fact multiset_order.less_trans)
  1696     
  1697 lemma mult_less_not_sym:
  1698   "M \<subset># N ==> \<not> N \<subset># (M::'a::order multiset)"
  1699   by (fact multiset_order.less_not_sym)
  1700 
  1701 lemma mult_less_asym:
  1702   "M \<subset># N ==> (\<not> P ==> N \<subset># (M::'a::order multiset)) ==> P"
  1703   by (fact multiset_order.less_asym)
  1704 
  1705 ML {*
  1706 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
  1707                       (Const _ $ t') =
  1708     let
  1709       val (maybe_opt, ps) =
  1710         Nitpick_Model.dest_plain_fun t' ||> op ~~
  1711         ||> map (apsnd (snd o HOLogic.dest_number))
  1712       fun elems_for t =
  1713         case AList.lookup (op =) ps t of
  1714           SOME n => replicate n t
  1715         | NONE => [Const (maybe_name, elem_T --> elem_T) $ t]
  1716     in
  1717       case maps elems_for (all_values elem_T) @
  1718            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
  1719             else []) of
  1720         [] => Const (@{const_name zero_class.zero}, T)
  1721       | ts => foldl1 (fn (t1, t2) =>
  1722                          Const (@{const_name plus_class.plus}, T --> T --> T)
  1723                          $ t1 $ t2)
  1724                      (map (curry (op $) (Const (@{const_name single},
  1725                                                 elem_T --> T))) ts)
  1726     end
  1727   | multiset_postproc _ _ _ _ t = t
  1728 *}
  1729 
  1730 declaration {*
  1731 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
  1732     multiset_postproc
  1733 *}
  1734 
  1735 end