src/HOL/Map.thy
author nipkow
Tue Sep 07 10:05:19 2010 +0200 (2010-09-07)
changeset 39198 f967a16dfcdd
parent 35619 b5f6481772f3
child 39302 d7728f65b353
permissions -rw-r--r--
expand_fun_eq -> ext_iff
expand_set_eq -> set_ext_iff
Naming in line now with multisets
     1 (*  Title:      HOL/Map.thy
     2     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     3     Copyright   1997-2003 TU Muenchen
     4 
     5 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     6 *)
     7 
     8 header {* Maps *}
     9 
    10 theory Map
    11 imports List
    12 begin
    13 
    14 types ('a,'b) "map" = "'a => 'b option" (infixr "~=>" 0)
    15 translations (type) "'a ~=> 'b" <= (type) "'a => 'b option"
    16 
    17 type_notation (xsymbols)
    18   "map" (infixr "\<rightharpoonup>" 0)
    19 
    20 abbreviation
    21   empty :: "'a ~=> 'b" where
    22   "empty == %x. None"
    23 
    24 definition
    25   map_comp :: "('b ~=> 'c) => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    26   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    27 
    28 notation (xsymbols)
    29   map_comp  (infixl "\<circ>\<^sub>m" 55)
    30 
    31 definition
    32   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    33   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    34 
    35 definition
    36   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    37   "m|`A = (\<lambda>x. if x : A then m x else None)"
    38 
    39 notation (latex output)
    40   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    41 
    42 definition
    43   dom :: "('a ~=> 'b) => 'a set" where
    44   "dom m = {a. m a ~= None}"
    45 
    46 definition
    47   ran :: "('a ~=> 'b) => 'b set" where
    48   "ran m = {b. EX a. m a = Some b}"
    49 
    50 definition
    51   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    52   "(m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2) = (\<forall>a \<in> dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a)"
    53 
    54 nonterminals
    55   maplets maplet
    56 
    57 syntax
    58   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    59   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    60   ""         :: "maplet => maplets"             ("_")
    61   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    62   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    63   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    64 
    65 syntax (xsymbols)
    66   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    67   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    68 
    69 translations
    70   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    71   "_MapUpd m (_maplet  x y)"    == "m(x := CONST Some y)"
    72   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    73   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    74   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    75 
    76 primrec
    77   map_of :: "('a \<times> 'b) list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    78     "map_of [] = empty"
    79   | "map_of (p # ps) = (map_of ps)(fst p \<mapsto> snd p)"
    80 
    81 definition
    82   map_upds :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    83   "map_upds m xs ys = m ++ map_of (rev (zip xs ys))"
    84 
    85 translations
    86   "_MapUpd m (_maplets x y)"    == "CONST map_upds m x y"
    87 
    88 lemma map_of_Cons_code [code]: 
    89   "map_of [] k = None"
    90   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    91   by simp_all
    92 
    93 
    94 subsection {* @{term [source] empty} *}
    95 
    96 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    97 by (rule ext) simp
    98 
    99 
   100 subsection {* @{term [source] map_upd} *}
   101 
   102 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   103 by (rule ext) simp
   104 
   105 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   106 proof
   107   assume "t(k \<mapsto> x) = empty"
   108   then have "(t(k \<mapsto> x)) k = None" by simp
   109   then show False by simp
   110 qed
   111 
   112 lemma map_upd_eqD1:
   113   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   114   shows "x = y"
   115 proof -
   116   from prems have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   117   then show ?thesis by simp
   118 qed
   119 
   120 lemma map_upd_Some_unfold:
   121   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   122 by auto
   123 
   124 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   125 by auto
   126 
   127 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   128 unfolding image_def
   129 apply (simp (no_asm_use) add:full_SetCompr_eq)
   130 apply (rule finite_subset)
   131  prefer 2 apply assumption
   132 apply (auto)
   133 done
   134 
   135 
   136 subsection {* @{term [source] map_of} *}
   137 
   138 lemma map_of_eq_None_iff:
   139   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   140 by (induct xys) simp_all
   141 
   142 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   143 apply (induct xys)
   144  apply simp
   145 apply (clarsimp split: if_splits)
   146 done
   147 
   148 lemma map_of_eq_Some_iff [simp]:
   149   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   150 apply (induct xys)
   151  apply simp
   152 apply (auto simp: map_of_eq_None_iff [symmetric])
   153 done
   154 
   155 lemma Some_eq_map_of_iff [simp]:
   156   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   157 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   158 
   159 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   160     \<Longrightarrow> map_of xys x = Some y"
   161 apply (induct xys)
   162  apply simp
   163 apply force
   164 done
   165 
   166 lemma map_of_zip_is_None [simp]:
   167   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   168 by (induct rule: list_induct2) simp_all
   169 
   170 lemma map_of_zip_is_Some:
   171   assumes "length xs = length ys"
   172   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   173 using assms by (induct rule: list_induct2) simp_all
   174 
   175 lemma map_of_zip_upd:
   176   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   177   assumes "length ys = length xs"
   178     and "length zs = length xs"
   179     and "x \<notin> set xs"
   180     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   181   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   182 proof
   183   fix x' :: 'a
   184   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   185   proof (cases "x = x'")
   186     case True
   187     from assms True map_of_zip_is_None [of xs ys x']
   188       have "map_of (zip xs ys) x' = None" by simp
   189     moreover from assms True map_of_zip_is_None [of xs zs x']
   190       have "map_of (zip xs zs) x' = None" by simp
   191     ultimately show ?thesis by simp
   192   next
   193     case False from assms
   194       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   195     with False show ?thesis by simp
   196   qed
   197 qed
   198 
   199 lemma map_of_zip_inject:
   200   assumes "length ys = length xs"
   201     and "length zs = length xs"
   202     and dist: "distinct xs"
   203     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   204   shows "ys = zs"
   205 using assms(1) assms(2)[symmetric] using dist map_of proof (induct ys xs zs rule: list_induct3)
   206   case Nil show ?case by simp
   207 next
   208   case (Cons y ys x xs z zs)
   209   from `map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))`
   210     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   211   from Cons have "length ys = length xs" and "length zs = length xs"
   212     and "x \<notin> set xs" by simp_all
   213   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   214   with Cons.hyps `distinct (x # xs)` have "ys = zs" by simp
   215   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   216   ultimately show ?case by simp
   217 qed
   218 
   219 lemma map_of_zip_map:
   220   "map_of (zip xs (map f xs)) = (\<lambda>x. if x \<in> set xs then Some (f x) else None)"
   221   by (induct xs) (simp_all add: ext_iff)
   222 
   223 lemma finite_range_map_of: "finite (range (map_of xys))"
   224 apply (induct xys)
   225  apply (simp_all add: image_constant)
   226 apply (rule finite_subset)
   227  prefer 2 apply assumption
   228 apply auto
   229 done
   230 
   231 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   232 by (induct xs) (simp, atomize (full), auto)
   233 
   234 lemma map_of_mapk_SomeI:
   235   "inj f ==> map_of t k = Some x ==>
   236    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   237 by (induct t) (auto simp add: inj_eq)
   238 
   239 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   240 by (induct l) auto
   241 
   242 lemma map_of_filter_in:
   243   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   244 by (induct xs) auto
   245 
   246 lemma map_of_map:
   247   "map_of (map (\<lambda>(k, v). (k, f v)) xs) = Option.map f \<circ> map_of xs"
   248   by (induct xs) (auto simp add: ext_iff)
   249 
   250 lemma dom_option_map:
   251   "dom (\<lambda>k. Option.map (f k) (m k)) = dom m"
   252   by (simp add: dom_def)
   253 
   254 
   255 subsection {* @{const Option.map} related *}
   256 
   257 lemma option_map_o_empty [simp]: "Option.map f o empty = empty"
   258 by (rule ext) simp
   259 
   260 lemma option_map_o_map_upd [simp]:
   261   "Option.map f o m(a|->b) = (Option.map f o m)(a|->f b)"
   262 by (rule ext) simp
   263 
   264 
   265 subsection {* @{term [source] map_comp} related *}
   266 
   267 lemma map_comp_empty [simp]:
   268   "m \<circ>\<^sub>m empty = empty"
   269   "empty \<circ>\<^sub>m m = empty"
   270 by (auto simp add: map_comp_def intro: ext split: option.splits)
   271 
   272 lemma map_comp_simps [simp]:
   273   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   274   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   275 by (auto simp add: map_comp_def)
   276 
   277 lemma map_comp_Some_iff:
   278   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   279 by (auto simp add: map_comp_def split: option.splits)
   280 
   281 lemma map_comp_None_iff:
   282   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   283 by (auto simp add: map_comp_def split: option.splits)
   284 
   285 
   286 subsection {* @{text "++"} *}
   287 
   288 lemma map_add_empty[simp]: "m ++ empty = m"
   289 by(simp add: map_add_def)
   290 
   291 lemma empty_map_add[simp]: "empty ++ m = m"
   292 by (rule ext) (simp add: map_add_def split: option.split)
   293 
   294 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   295 by (rule ext) (simp add: map_add_def split: option.split)
   296 
   297 lemma map_add_Some_iff:
   298   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   299 by (simp add: map_add_def split: option.split)
   300 
   301 lemma map_add_SomeD [dest!]:
   302   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   303 by (rule map_add_Some_iff [THEN iffD1])
   304 
   305 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   306 by (subst map_add_Some_iff) fast
   307 
   308 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   309 by (simp add: map_add_def split: option.split)
   310 
   311 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   312 by (rule ext) (simp add: map_add_def)
   313 
   314 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   315 by (simp add: map_upds_def)
   316 
   317 lemma map_add_upd_left: "m\<notin>dom e2 \<Longrightarrow> e1(m \<mapsto> u1) ++ e2 = (e1 ++ e2)(m \<mapsto> u1)"
   318 by (rule ext) (auto simp: map_add_def dom_def split: option.split)
   319 
   320 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   321 unfolding map_add_def
   322 apply (induct xs)
   323  apply simp
   324 apply (rule ext)
   325 apply (simp split add: option.split)
   326 done
   327 
   328 lemma finite_range_map_of_map_add:
   329   "finite (range f) ==> finite (range (f ++ map_of l))"
   330 apply (induct l)
   331  apply (auto simp del: fun_upd_apply)
   332 apply (erule finite_range_updI)
   333 done
   334 
   335 lemma inj_on_map_add_dom [iff]:
   336   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   337 by (fastsimp simp: map_add_def dom_def inj_on_def split: option.splits)
   338 
   339 lemma map_upds_fold_map_upd:
   340   "m(ks[\<mapsto>]vs) = foldl (\<lambda>m (k, v). m(k \<mapsto> v)) m (zip ks vs)"
   341 unfolding map_upds_def proof (rule sym, rule zip_obtain_same_length)
   342   fix ks :: "'a list" and vs :: "'b list"
   343   assume "length ks = length vs"
   344   then show "foldl (\<lambda>m (k, v). m(k\<mapsto>v)) m (zip ks vs) = m ++ map_of (rev (zip ks vs))"
   345     by(induct arbitrary: m rule: list_induct2) simp_all
   346 qed
   347 
   348 lemma map_add_map_of_foldr:
   349   "m ++ map_of ps = foldr (\<lambda>(k, v) m. m(k \<mapsto> v)) ps m"
   350   by (induct ps) (auto simp add: ext_iff map_add_def)
   351 
   352 
   353 subsection {* @{term [source] restrict_map} *}
   354 
   355 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   356 by (simp add: restrict_map_def)
   357 
   358 lemma restrict_map_insert: "f |` (insert a A) = (f |` A)(a := f a)"
   359 by (auto simp add: restrict_map_def intro: ext)
   360 
   361 lemma restrict_map_empty [simp]: "empty|`D = empty"
   362 by (simp add: restrict_map_def)
   363 
   364 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   365 by (simp add: restrict_map_def)
   366 
   367 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   368 by (simp add: restrict_map_def)
   369 
   370 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   371 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   372 
   373 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   374 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   375 
   376 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   377 by (rule ext) (auto simp: restrict_map_def)
   378 
   379 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   380 by (rule ext) (auto simp: restrict_map_def)
   381 
   382 lemma restrict_fun_upd [simp]:
   383   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   384 by (simp add: restrict_map_def ext_iff)
   385 
   386 lemma fun_upd_None_restrict [simp]:
   387   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   388 by (simp add: restrict_map_def ext_iff)
   389 
   390 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   391 by (simp add: restrict_map_def ext_iff)
   392 
   393 lemma fun_upd_restrict_conv [simp]:
   394   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   395 by (simp add: restrict_map_def ext_iff)
   396 
   397 lemma map_of_map_restrict:
   398   "map_of (map (\<lambda>k. (k, f k)) ks) = (Some \<circ> f) |` set ks"
   399   by (induct ks) (simp_all add: ext_iff restrict_map_insert)
   400 
   401 lemma restrict_complement_singleton_eq:
   402   "f |` (- {x}) = f(x := None)"
   403   by (simp add: restrict_map_def ext_iff)
   404 
   405 
   406 subsection {* @{term [source] map_upds} *}
   407 
   408 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   409 by (simp add: map_upds_def)
   410 
   411 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   412 by (simp add:map_upds_def)
   413 
   414 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   415 by (simp add:map_upds_def)
   416 
   417 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   418   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   419 apply(induct xs)
   420  apply (clarsimp simp add: neq_Nil_conv)
   421 apply (case_tac ys)
   422  apply simp
   423 apply simp
   424 done
   425 
   426 lemma map_upds_list_update2_drop [simp]:
   427   "\<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   428     \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   429 apply (induct xs arbitrary: m ys i)
   430  apply simp
   431 apply (case_tac ys)
   432  apply simp
   433 apply (simp split: nat.split)
   434 done
   435 
   436 lemma map_upd_upds_conv_if:
   437   "(f(x|->y))(xs [|->] ys) =
   438    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   439                                     else (f(xs [|->] ys))(x|->y))"
   440 apply (induct xs arbitrary: x y ys f)
   441  apply simp
   442 apply (case_tac ys)
   443  apply (auto split: split_if simp: fun_upd_twist)
   444 done
   445 
   446 lemma map_upds_twist [simp]:
   447   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   448 using set_take_subset by (fastsimp simp add: map_upd_upds_conv_if)
   449 
   450 lemma map_upds_apply_nontin [simp]:
   451   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   452 apply (induct xs arbitrary: ys)
   453  apply simp
   454 apply (case_tac ys)
   455  apply (auto simp: map_upd_upds_conv_if)
   456 done
   457 
   458 lemma fun_upds_append_drop [simp]:
   459   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   460 apply (induct xs arbitrary: m ys)
   461  apply simp
   462 apply (case_tac ys)
   463  apply simp_all
   464 done
   465 
   466 lemma fun_upds_append2_drop [simp]:
   467   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   468 apply (induct xs arbitrary: m ys)
   469  apply simp
   470 apply (case_tac ys)
   471  apply simp_all
   472 done
   473 
   474 
   475 lemma restrict_map_upds[simp]:
   476   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   477     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   478 apply (induct xs arbitrary: m ys)
   479  apply simp
   480 apply (case_tac ys)
   481  apply simp
   482 apply (simp add: Diff_insert [symmetric] insert_absorb)
   483 apply (simp add: map_upd_upds_conv_if)
   484 done
   485 
   486 
   487 subsection {* @{term [source] dom} *}
   488 
   489 lemma dom_eq_empty_conv [simp]: "dom f = {} \<longleftrightarrow> f = empty"
   490 by(auto intro!:ext simp: dom_def)
   491 
   492 lemma domI: "m a = Some b ==> a : dom m"
   493 by(simp add:dom_def)
   494 (* declare domI [intro]? *)
   495 
   496 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   497 by (cases "m a") (auto simp add: dom_def)
   498 
   499 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   500 by(simp add:dom_def)
   501 
   502 lemma dom_empty [simp]: "dom empty = {}"
   503 by(simp add:dom_def)
   504 
   505 lemma dom_fun_upd [simp]:
   506   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   507 by(auto simp add:dom_def)
   508 
   509 lemma dom_if:
   510   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   511   by (auto split: if_splits)
   512 
   513 lemma dom_map_of_conv_image_fst:
   514   "dom (map_of xys) = fst ` set xys"
   515   by (induct xys) (auto simp add: dom_if)
   516 
   517 lemma dom_map_of_zip [simp]: "[| length xs = length ys; distinct xs |] ==>
   518   dom(map_of(zip xs ys)) = set xs"
   519 by (induct rule: list_induct2) simp_all
   520 
   521 lemma finite_dom_map_of: "finite (dom (map_of l))"
   522 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   523 
   524 lemma dom_map_upds [simp]:
   525   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   526 apply (induct xs arbitrary: m ys)
   527  apply simp
   528 apply (case_tac ys)
   529  apply auto
   530 done
   531 
   532 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   533 by(auto simp:dom_def)
   534 
   535 lemma dom_override_on [simp]:
   536   "dom(override_on f g A) =
   537     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   538 by(auto simp: dom_def override_on_def)
   539 
   540 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   541 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   542 
   543 lemma map_add_dom_app_simps:
   544   "\<lbrakk> m\<in>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   545   "\<lbrakk> m\<notin>dom l1 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   546   "\<lbrakk> m\<notin>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l1 m"
   547 by (auto simp add: map_add_def split: option.split_asm)
   548 
   549 lemma dom_const [simp]:
   550   "dom (\<lambda>x. Some (f x)) = UNIV"
   551   by auto
   552 
   553 (* Due to John Matthews - could be rephrased with dom *)
   554 lemma finite_map_freshness:
   555   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   556    \<exists>x. f x = None"
   557 by(bestsimp dest:ex_new_if_finite)
   558 
   559 lemma dom_minus:
   560   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   561   unfolding dom_def by simp
   562 
   563 lemma insert_dom:
   564   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   565   unfolding dom_def by auto
   566 
   567 lemma map_of_map_keys:
   568   "set xs = dom m \<Longrightarrow> map_of (map (\<lambda>k. (k, the (m k))) xs) = m"
   569   by (rule ext) (auto simp add: map_of_map_restrict restrict_map_def)
   570 
   571 
   572 subsection {* @{term [source] ran} *}
   573 
   574 lemma ranI: "m a = Some b ==> b : ran m"
   575 by(auto simp: ran_def)
   576 (* declare ranI [intro]? *)
   577 
   578 lemma ran_empty [simp]: "ran empty = {}"
   579 by(auto simp: ran_def)
   580 
   581 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   582 unfolding ran_def
   583 apply auto
   584 apply (subgoal_tac "aa ~= a")
   585  apply auto
   586 done
   587 
   588 lemma ran_distinct: 
   589   assumes dist: "distinct (map fst al)" 
   590   shows "ran (map_of al) = snd ` set al"
   591 using assms proof (induct al)
   592   case Nil then show ?case by simp
   593 next
   594   case (Cons kv al)
   595   then have "ran (map_of al) = snd ` set al" by simp
   596   moreover from Cons.prems have "map_of al (fst kv) = None"
   597     by (simp add: map_of_eq_None_iff)
   598   ultimately show ?case by (simp only: map_of.simps ran_map_upd) simp
   599 qed
   600 
   601 
   602 subsection {* @{text "map_le"} *}
   603 
   604 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   605 by (simp add: map_le_def)
   606 
   607 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   608 by (force simp add: map_le_def)
   609 
   610 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   611 by (fastsimp simp add: map_le_def)
   612 
   613 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   614 by (force simp add: map_le_def)
   615 
   616 lemma map_le_upds [simp]:
   617   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   618 apply (induct as arbitrary: f g bs)
   619  apply simp
   620 apply (case_tac bs)
   621  apply auto
   622 done
   623 
   624 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   625 by (fastsimp simp add: map_le_def dom_def)
   626 
   627 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   628 by (simp add: map_le_def)
   629 
   630 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   631 by (auto simp add: map_le_def dom_def)
   632 
   633 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   634 unfolding map_le_def
   635 apply (rule ext)
   636 apply (case_tac "x \<in> dom f", simp)
   637 apply (case_tac "x \<in> dom g", simp, fastsimp)
   638 done
   639 
   640 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   641 by (fastsimp simp add: map_le_def)
   642 
   643 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   644 by(fastsimp simp: map_add_def map_le_def ext_iff split: option.splits)
   645 
   646 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   647 by (fastsimp simp add: map_le_def map_add_def dom_def)
   648 
   649 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   650 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   651 
   652 lemma dom_eq_singleton_conv: "dom f = {x} \<longleftrightarrow> (\<exists>v. f = [x \<mapsto> v])"
   653 proof(rule iffI)
   654   assume "\<exists>v. f = [x \<mapsto> v]"
   655   thus "dom f = {x}" by(auto split: split_if_asm)
   656 next
   657   assume "dom f = {x}"
   658   then obtain v where "f x = Some v" by auto
   659   hence "[x \<mapsto> v] \<subseteq>\<^sub>m f" by(auto simp add: map_le_def)
   660   moreover have "f \<subseteq>\<^sub>m [x \<mapsto> v]" using `dom f = {x}` `f x = Some v`
   661     by(auto simp add: map_le_def)
   662   ultimately have "f = [x \<mapsto> v]" by-(rule map_le_antisym)
   663   thus "\<exists>v. f = [x \<mapsto> v]" by blast
   664 qed
   665 
   666 
   667 subsection {* Various *}
   668 
   669 lemma set_map_of_compr:
   670   assumes distinct: "distinct (map fst xs)"
   671   shows "set xs = {(k, v). map_of xs k = Some v}"
   672 using assms proof (induct xs)
   673   case Nil then show ?case by simp
   674 next
   675   case (Cons x xs)
   676   obtain k v where "x = (k, v)" by (cases x) blast
   677   with Cons.prems have "k \<notin> dom (map_of xs)"
   678     by (simp add: dom_map_of_conv_image_fst)
   679   then have *: "insert (k, v) {(k, v). map_of xs k = Some v} =
   680     {(k', v'). (map_of xs(k \<mapsto> v)) k' = Some v'}"
   681     by (auto split: if_splits)
   682   from Cons have "set xs = {(k, v). map_of xs k = Some v}" by simp
   683   with * `x = (k, v)` show ?case by simp
   684 qed
   685 
   686 lemma map_of_inject_set:
   687   assumes distinct: "distinct (map fst xs)" "distinct (map fst ys)"
   688   shows "map_of xs = map_of ys \<longleftrightarrow> set xs = set ys" (is "?lhs \<longleftrightarrow> ?rhs")
   689 proof
   690   assume ?lhs
   691   moreover from `distinct (map fst xs)` have "set xs = {(k, v). map_of xs k = Some v}"
   692     by (rule set_map_of_compr)
   693   moreover from `distinct (map fst ys)` have "set ys = {(k, v). map_of ys k = Some v}"
   694     by (rule set_map_of_compr)
   695   ultimately show ?rhs by simp
   696 next
   697   assume ?rhs show ?lhs proof
   698     fix k
   699     show "map_of xs k = map_of ys k" proof (cases "map_of xs k")
   700       case None
   701       moreover with `?rhs` have "map_of ys k = None"
   702         by (simp add: map_of_eq_None_iff)
   703       ultimately show ?thesis by simp
   704     next
   705       case (Some v)
   706       moreover with distinct `?rhs` have "map_of ys k = Some v"
   707         by simp
   708       ultimately show ?thesis by simp
   709     qed
   710   qed
   711 qed
   712 
   713 end