src/HOL/Complete_Lattice.thy
author haftmann
Sun Jul 10 15:45:35 2011 +0200 (2011-07-10)
changeset 43741 fac11b64713c
parent 43740 3316e6831801
child 43753 fe5e846c0839
permissions -rw-r--r--
tuned proofs and notation
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty [simp]:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty [simp]:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_UNIV [simp]:
    56   "\<Sqinter>UNIV = \<bottom>"
    57   by (simp add: Sup_Inf Sup_empty [symmetric])
    58 
    59 lemma Sup_UNIV [simp]:
    60   "\<Squnion>UNIV = \<top>"
    61   by (simp add: Inf_Sup Inf_empty [symmetric])
    62 
    63 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    64   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    65 
    66 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    67   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    68 
    69 lemma Inf_singleton [simp]:
    70   "\<Sqinter>{a} = a"
    71   by (auto intro: antisym Inf_lower Inf_greatest)
    72 
    73 lemma Sup_singleton [simp]:
    74   "\<Squnion>{a} = a"
    75   by (auto intro: antisym Sup_upper Sup_least)
    76 
    77 lemma Inf_binary:
    78   "\<Sqinter>{a, b} = a \<sqinter> b"
    79   by (simp add: Inf_empty Inf_insert)
    80 
    81 lemma Sup_binary:
    82   "\<Squnion>{a, b} = a \<squnion> b"
    83   by (simp add: Sup_empty Sup_insert)
    84 
    85 lemma le_Inf_iff: "b \<sqsubseteq> Inf A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    86   by (auto intro: Inf_greatest dest: Inf_lower)
    87 
    88 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    89   by (auto intro: Sup_least dest: Sup_upper)
    90 
    91 lemma Inf_mono:
    92   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
    93   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
    94 proof (rule Inf_greatest)
    95   fix b assume "b \<in> B"
    96   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
    97   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
    98   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
    99 qed
   100 
   101 lemma Sup_mono:
   102   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   103   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   104 proof (rule Sup_least)
   105   fix a assume "a \<in> A"
   106   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   107   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   108   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   109 qed
   110 
   111 lemma top_le:
   112   "\<top> \<sqsubseteq> x \<Longrightarrow> x = \<top>"
   113   by (rule antisym) auto
   114 
   115 lemma le_bot:
   116   "x \<sqsubseteq> \<bottom> \<Longrightarrow> x = \<bottom>"
   117   by (rule antisym) auto
   118 
   119 lemma not_less_bot[simp]: "\<not> (x \<sqsubset> \<bottom>)"
   120   using bot_least[of x] by (auto simp: le_less)
   121 
   122 lemma not_top_less[simp]: "\<not> (\<top> \<sqsubset> x)"
   123   using top_greatest[of x] by (auto simp: le_less)
   124 
   125 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   126   using Sup_upper[of u A] by auto
   127 
   128 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   129   using Inf_lower[of u A] by auto
   130 
   131 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   132   "INFI A f = \<Sqinter> (f ` A)"
   133 
   134 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   135   "SUPR A f = \<Squnion> (f ` A)"
   136 
   137 end
   138 
   139 syntax
   140   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
   141   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   142   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
   143   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   144 
   145 syntax (xsymbols)
   146   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   147   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   148   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   149   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   150 
   151 translations
   152   "INF x y. B"   == "INF x. INF y. B"
   153   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   154   "INF x. B"     == "INF x:CONST UNIV. B"
   155   "INF x:A. B"   == "CONST INFI A (%x. B)"
   156   "SUP x y. B"   == "SUP x. SUP y. B"
   157   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   158   "SUP x. B"     == "SUP x:CONST UNIV. B"
   159   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   160 
   161 print_translation {*
   162   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   163     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   164 *} -- {* to avoid eta-contraction of body *}
   165 
   166 context complete_lattice
   167 begin
   168 
   169 lemma SUP_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> SUPR A f = SUPR A g"
   170   by (simp add: SUPR_def cong: image_cong)
   171 
   172 lemma INF_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> INFI A f = INFI A g"
   173   by (simp add: INFI_def cong: image_cong)
   174 
   175 lemma le_SUPI: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   176   by (auto simp add: SUPR_def intro: Sup_upper)
   177 
   178 lemma le_SUPI2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> M i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   179   using le_SUPI[of i A M] by auto
   180 
   181 lemma SUP_leI: "(\<And>i. i \<in> A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. M i) \<sqsubseteq> u"
   182   by (auto simp add: SUPR_def intro: Sup_least)
   183 
   184 lemma INF_leI: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> M i"
   185   by (auto simp add: INFI_def intro: Inf_lower)
   186 
   187 lemma INF_leI2: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> u"
   188   using INF_leI[of i A M] by auto
   189 
   190 lemma le_INFI: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. M i)"
   191   by (auto simp add: INFI_def intro: Inf_greatest)
   192 
   193 lemma SUP_le_iff: "(SUP i:A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   194   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   195 
   196 lemma le_INF_iff: "u \<sqsubseteq> (INF i:A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   197   unfolding INFI_def by (auto simp add: le_Inf_iff)
   198 
   199 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
   200   by (auto intro: antisym INF_leI le_INFI)
   201 
   202 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
   203   by (auto intro: antisym SUP_leI le_SUPI)
   204 
   205 lemma INF_mono:
   206   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<le> g m) \<Longrightarrow> (INF n:A. f n) \<le> (INF n:B. g n)"
   207   by (force intro!: Inf_mono simp: INFI_def)
   208 
   209 lemma SUP_mono:
   210   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<le> g m) \<Longrightarrow> (SUP n:A. f n) \<le> (SUP n:B. g n)"
   211   by (force intro!: Sup_mono simp: SUPR_def)
   212 
   213 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<le> INFI A f"
   214   by (intro INF_mono) auto
   215 
   216 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<le> SUPR B f"
   217   by (intro SUP_mono) auto
   218 
   219 lemma INF_commute: "(INF i:A. INF j:B. f i j) = (INF j:B. INF i:A. f i j)"
   220   by (iprover intro: INF_leI le_INFI order_trans antisym)
   221 
   222 lemma SUP_commute: "(SUP i:A. SUP j:B. f i j) = (SUP j:B. SUP i:A. f i j)"
   223   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   224 
   225 end
   226 
   227 lemma Inf_less_iff:
   228   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   229   shows "Inf S < a \<longleftrightarrow> (\<exists>x\<in>S. x < a)"
   230   unfolding not_le[symmetric] le_Inf_iff by auto
   231 
   232 lemma less_Sup_iff:
   233   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   234   shows "a < Sup S \<longleftrightarrow> (\<exists>x\<in>S. a < x)"
   235   unfolding not_le[symmetric] Sup_le_iff by auto
   236 
   237 lemma INF_less_iff:
   238   fixes a :: "'a::{complete_lattice,linorder}"
   239   shows "(INF i:A. f i) < a \<longleftrightarrow> (\<exists>x\<in>A. f x < a)"
   240   unfolding INFI_def Inf_less_iff by auto
   241 
   242 lemma less_SUP_iff:
   243   fixes a :: "'a::{complete_lattice,linorder}"
   244   shows "a < (SUP i:A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a < f x)"
   245   unfolding SUPR_def less_Sup_iff by auto
   246 
   247 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   248 
   249 instantiation bool :: complete_lattice
   250 begin
   251 
   252 definition
   253   "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   254 
   255 definition
   256   "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   257 
   258 instance proof
   259 qed (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   260 
   261 end
   262 
   263 lemma INFI_bool_eq [simp]:
   264   "INFI = Ball"
   265 proof (rule ext)+
   266   fix A :: "'a set"
   267   fix P :: "'a \<Rightarrow> bool"
   268   show "(INF x:A. P x) \<longleftrightarrow> (\<forall>x \<in> A. P x)"
   269     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   270 qed
   271 
   272 lemma SUPR_bool_eq [simp]:
   273   "SUPR = Bex"
   274 proof (rule ext)+
   275   fix A :: "'a set"
   276   fix P :: "'a \<Rightarrow> bool"
   277   show "(SUP x:A. P x) \<longleftrightarrow> (\<exists>x \<in> A. P x)"
   278     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   279 qed
   280 
   281 instantiation "fun" :: (type, complete_lattice) complete_lattice
   282 begin
   283 
   284 definition
   285   "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   286 
   287 lemma Inf_apply:
   288   "(\<Sqinter>A) x = \<Sqinter>{y. \<exists>f\<in>A. y = f x}"
   289   by (simp add: Inf_fun_def)
   290 
   291 definition
   292   "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   293 
   294 lemma Sup_apply:
   295   "(\<Squnion>A) x = \<Squnion>{y. \<exists>f\<in>A. y = f x}"
   296   by (simp add: Sup_fun_def)
   297 
   298 instance proof
   299 qed (auto simp add: le_fun_def Inf_apply Sup_apply
   300   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   301 
   302 end
   303 
   304 lemma INFI_apply:
   305   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   306   by (auto intro: arg_cong [of _ _ Inf] simp add: INFI_def Inf_apply)
   307 
   308 lemma SUPR_apply:
   309   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   310   by (auto intro: arg_cong [of _ _ Sup] simp add: SUPR_def Sup_apply)
   311 
   312 
   313 subsection {* Inter *}
   314 
   315 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   316   "Inter S \<equiv> \<Sqinter>S"
   317   
   318 notation (xsymbols)
   319   Inter  ("\<Inter>_" [90] 90)
   320 
   321 lemma Inter_eq:
   322   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   323 proof (rule set_eqI)
   324   fix x
   325   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   326     by auto
   327   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   328     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   329 qed
   330 
   331 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   332   by (unfold Inter_eq) blast
   333 
   334 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   335   by (simp add: Inter_eq)
   336 
   337 text {*
   338   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   339   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   340   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   341 *}
   342 
   343 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   344   by auto
   345 
   346 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   347   -- {* ``Classical'' elimination rule -- does not require proving
   348     @{prop "X \<in> C"}. *}
   349   by (unfold Inter_eq) blast
   350 
   351 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   352   by (fact Inf_lower)
   353 
   354 lemma (in complete_lattice) Inf_less_eq:
   355   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   356     and "A \<noteq> {}"
   357   shows "\<Sqinter>A \<le> u"
   358 proof -
   359   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   360   moreover with assms have "v \<sqsubseteq> u" by blast
   361   ultimately show ?thesis by (rule Inf_lower2)
   362 qed
   363 
   364 lemma Inter_subset:
   365   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
   366   by (fact Inf_less_eq)
   367 
   368 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   369   by (fact Inf_greatest)
   370 
   371 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   372   by (fact Inf_binary [symmetric])
   373 
   374 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   375   by (fact Inf_empty)
   376 
   377 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   378   by (fact Inf_UNIV)
   379 
   380 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   381   by (fact Inf_insert)
   382 
   383 lemma (in complete_lattice) Inf_inter_less: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   384   by (auto intro: Inf_greatest Inf_lower)
   385 
   386 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   387   by (fact Inf_inter_less)
   388 
   389 (*lemma (in complete_lattice) Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"*)
   390 
   391 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   392   by blast
   393 
   394 lemma Inter_UNIV_conv [simp,no_atp]:
   395   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   396   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   397   by blast+
   398 
   399 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   400   by blast
   401 
   402 
   403 subsection {* Intersections of families *}
   404 
   405 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   406   "INTER \<equiv> INFI"
   407 
   408 syntax
   409   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   410   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   411 
   412 syntax (xsymbols)
   413   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   414   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   415 
   416 syntax (latex output)
   417   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   418   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   419 
   420 translations
   421   "INT x y. B"  == "INT x. INT y. B"
   422   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   423   "INT x. B"    == "INT x:CONST UNIV. B"
   424   "INT x:A. B"  == "CONST INTER A (%x. B)"
   425 
   426 print_translation {*
   427   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   428 *} -- {* to avoid eta-contraction of body *}
   429 
   430 lemma INTER_eq_Inter_image:
   431   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   432   by (fact INFI_def)
   433   
   434 lemma Inter_def:
   435   "\<Inter>S = (\<Inter>x\<in>S. x)"
   436   by (simp add: INTER_eq_Inter_image image_def)
   437 
   438 lemma INTER_def:
   439   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   440   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   441 
   442 lemma Inter_image_eq [simp]:
   443   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   444   by (rule sym) (fact INTER_eq_Inter_image)
   445 
   446 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   447   by (unfold INTER_def) blast
   448 
   449 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   450   by (unfold INTER_def) blast
   451 
   452 lemma INT_D [elim, Pure.elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   453   by auto
   454 
   455 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   456   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   457   by (unfold INTER_def) blast
   458 
   459 lemma INT_cong [cong]:
   460     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   461   by (simp add: INTER_def)
   462 
   463 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   464   by blast
   465 
   466 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   467   by blast
   468 
   469 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   470   by (fact INF_leI)
   471 
   472 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   473   by (fact le_INFI)
   474 
   475 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   476   by blast
   477 
   478 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   479   by blast
   480 
   481 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
   482   by (fact le_INF_iff)
   483 
   484 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   485   by blast
   486 
   487 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   488   by blast
   489 
   490 lemma INT_insert_distrib:
   491     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   492   by blast
   493 
   494 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   495   by auto
   496 
   497 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   498   -- {* Look: it has an \emph{existential} quantifier *}
   499   by blast
   500 
   501 lemma INTER_UNIV_conv[simp]:
   502  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   503  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   504 by blast+
   505 
   506 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
   507   by (auto intro: bool_induct)
   508 
   509 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   510   by blast
   511 
   512 lemma INT_anti_mono:
   513   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   514     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   515   -- {* The last inclusion is POSITIVE! *}
   516   by (blast dest: subsetD)
   517 
   518 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
   519   by blast
   520 
   521 
   522 subsection {* Union *}
   523 
   524 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   525   "Union S \<equiv> \<Squnion>S"
   526 
   527 notation (xsymbols)
   528   Union  ("\<Union>_" [90] 90)
   529 
   530 lemma Union_eq:
   531   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   532 proof (rule set_eqI)
   533   fix x
   534   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   535     by auto
   536   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   537     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   538 qed
   539 
   540 lemma Union_iff [simp, no_atp]:
   541   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   542   by (unfold Union_eq) blast
   543 
   544 lemma UnionI [intro]:
   545   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   546   -- {* The order of the premises presupposes that @{term C} is rigid;
   547     @{term A} may be flexible. *}
   548   by auto
   549 
   550 lemma UnionE [elim!]:
   551   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A\<in>X \<Longrightarrow> X\<in>C \<Longrightarrow> R) \<Longrightarrow> R"
   552   by auto
   553 
   554 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   555   by (iprover intro: subsetI UnionI)
   556 
   557 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   558   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   559 
   560 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   561   by blast
   562 
   563 lemma Union_empty [simp]: "Union({}) = {}"
   564   by blast
   565 
   566 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
   567   by blast
   568 
   569 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
   570   by blast
   571 
   572 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
   573   by blast
   574 
   575 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   576   by blast
   577 
   578 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
   579   by blast
   580 
   581 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
   582   by blast
   583 
   584 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
   585   by blast
   586 
   587 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   588   by blast
   589 
   590 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   591   by blast
   592 
   593 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
   594   by blast
   595 
   596 
   597 subsection {* Unions of families *}
   598 
   599 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   600   "UNION \<equiv> SUPR"
   601 
   602 syntax
   603   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   604   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   605 
   606 syntax (xsymbols)
   607   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   608   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   609 
   610 syntax (latex output)
   611   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   612   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   613 
   614 translations
   615   "UN x y. B"   == "UN x. UN y. B"
   616   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   617   "UN x. B"     == "UN x:CONST UNIV. B"
   618   "UN x:A. B"   == "CONST UNION A (%x. B)"
   619 
   620 text {*
   621   Note the difference between ordinary xsymbol syntax of indexed
   622   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   623   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   624   former does not make the index expression a subscript of the
   625   union/intersection symbol because this leads to problems with nested
   626   subscripts in Proof General.
   627 *}
   628 
   629 print_translation {*
   630   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   631 *} -- {* to avoid eta-contraction of body *}
   632 
   633 lemma UNION_eq_Union_image:
   634   "(\<Union>x\<in>A. B x) = \<Union>(B`A)"
   635   by (fact SUPR_def)
   636 
   637 lemma Union_def:
   638   "\<Union>S = (\<Union>x\<in>S. x)"
   639   by (simp add: UNION_eq_Union_image image_def)
   640 
   641 lemma UNION_def [no_atp]:
   642   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   643   by (auto simp add: UNION_eq_Union_image Union_eq)
   644   
   645 lemma Union_image_eq [simp]:
   646   "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
   647   by (rule sym) (fact UNION_eq_Union_image)
   648   
   649 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   650   by (unfold UNION_def) blast
   651 
   652 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   653   -- {* The order of the premises presupposes that @{term A} is rigid;
   654     @{term b} may be flexible. *}
   655   by auto
   656 
   657 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   658   by (unfold UNION_def) blast
   659 
   660 lemma UN_cong [cong]:
   661     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   662   by (simp add: UNION_def)
   663 
   664 lemma strong_UN_cong:
   665     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   666   by (simp add: UNION_def simp_implies_def)
   667 
   668 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
   669   by blast
   670 
   671 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   672   by (fact le_SUPI)
   673 
   674 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   675   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   676 
   677 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   678   by blast
   679 
   680 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   681   by blast
   682 
   683 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   684   by blast
   685 
   686 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   687   by blast
   688 
   689 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   690   by blast
   691 
   692 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   693   by auto
   694 
   695 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   696   by blast
   697 
   698 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   699   by blast
   700 
   701 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   702   by blast
   703 
   704 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   705   by (fact SUP_le_iff)
   706 
   707 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   708   by blast
   709 
   710 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   711   by auto
   712 
   713 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   714   by blast
   715 
   716 lemma UNION_empty_conv[simp]:
   717   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
   718   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
   719 by blast+
   720 
   721 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   722   by blast
   723 
   724 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   725   by blast
   726 
   727 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   728   by blast
   729 
   730 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   731   by (auto simp add: split_if_mem2)
   732 
   733 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
   734   by (auto intro: bool_contrapos)
   735 
   736 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   737   by blast
   738 
   739 lemma UN_mono:
   740   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   741     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   742   by (blast dest: subsetD)
   743 
   744 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
   745   by blast
   746 
   747 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
   748   by blast
   749 
   750 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
   751   -- {* NOT suitable for rewriting *}
   752   by blast
   753 
   754 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
   755 by blast
   756 
   757 
   758 subsection {* Distributive laws *}
   759 
   760 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   761   by blast
   762 
   763 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   764   by blast
   765 
   766 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
   767   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   768   -- {* Union of a family of unions *}
   769   by blast
   770 
   771 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   772   -- {* Equivalent version *}
   773   by blast
   774 
   775 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   776   by blast
   777 
   778 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
   779   by blast
   780 
   781 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   782   -- {* Equivalent version *}
   783   by blast
   784 
   785 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   786   -- {* Halmos, Naive Set Theory, page 35. *}
   787   by blast
   788 
   789 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   790   by blast
   791 
   792 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   793   by blast
   794 
   795 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   796   by blast
   797 
   798 
   799 subsection {* Complement *}
   800 
   801 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   802   by blast
   803 
   804 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   805   by blast
   806 
   807 
   808 subsection {* Miniscoping and maxiscoping *}
   809 
   810 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   811            and Intersections. *}
   812 
   813 lemma UN_simps [simp]:
   814   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
   815   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
   816   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
   817   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
   818   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
   819   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
   820   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
   821   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
   822   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
   823   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
   824   by auto
   825 
   826 lemma INT_simps [simp]:
   827   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
   828   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
   829   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
   830   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
   831   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
   832   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
   833   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
   834   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
   835   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
   836   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
   837   by auto
   838 
   839 lemma ball_simps [simp,no_atp]:
   840   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
   841   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
   842   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
   843   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
   844   "!!P. (ALL x:{}. P x) = True"
   845   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
   846   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
   847   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
   848   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
   849   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
   850   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
   851   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
   852   by auto
   853 
   854 lemma bex_simps [simp,no_atp]:
   855   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
   856   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
   857   "!!P. (EX x:{}. P x) = False"
   858   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
   859   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
   860   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
   861   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
   862   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
   863   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
   864   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
   865   by auto
   866 
   867 lemma ball_conj_distrib:
   868   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
   869   by blast
   870 
   871 lemma bex_disj_distrib:
   872   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
   873   by blast
   874 
   875 
   876 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   877 
   878 lemma UN_extend_simps:
   879   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
   880   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
   881   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
   882   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
   883   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
   884   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
   885   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
   886   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
   887   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
   888   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
   889   by auto
   890 
   891 lemma INT_extend_simps:
   892   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
   893   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
   894   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
   895   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
   896   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
   897   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
   898   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
   899   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
   900   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
   901   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
   902   by auto
   903 
   904 
   905 no_notation
   906   less_eq  (infix "\<sqsubseteq>" 50) and
   907   less (infix "\<sqsubset>" 50) and
   908   bot ("\<bottom>") and
   909   top ("\<top>") and
   910   inf  (infixl "\<sqinter>" 70) and
   911   sup  (infixl "\<squnion>" 65) and
   912   Inf  ("\<Sqinter>_" [900] 900) and
   913   Sup  ("\<Squnion>_" [900] 900)
   914 
   915 no_syntax (xsymbols)
   916   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   917   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   918   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   919   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   920 
   921 lemmas mem_simps =
   922   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   923   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   924   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   925 
   926 end