src/HOL/Tools/record_package.ML
author wenzelm
Mon Jul 27 11:29:33 1998 +0200 (1998-07-27)
changeset 5201 fac6fea3b782
parent 5197 69c77ed95ba3
child 5210 54aaa779b6b4
permissions -rw-r--r--
tuned;
     1 (*  Title:      HOL/Tools/record_package.ML
     2     ID:         $Id$
     3     Author:     Wolfgang Naraschewski and Markus Wenzel, TU Muenchen
     4 
     5 Extensible records with structural subtyping in HOL.
     6 
     7 TODO:
     8   - field types: typedef;
     9   - operations and theorems: split, split_all/ex, ...;
    10   - field constructor: more specific type for snd component (x_more etc. classes);
    11 *)
    12 
    13 signature RECORD_PACKAGE =
    14 sig
    15   val moreS: sort
    16   val mk_fieldT: (string * typ) * typ -> typ
    17   val dest_fieldT: typ -> (string * typ) * typ
    18   val mk_field: (string * term) * term -> term
    19   val mk_fst: term -> term
    20   val mk_snd: term -> term
    21   val mk_recordT: (string * typ) list * typ -> typ
    22   val dest_recordT: typ -> (string * typ) list * typ
    23   val mk_record: (string * term) list * term -> term
    24   val mk_sel: term -> string -> term
    25   val mk_update: term -> string * term -> term
    26   val print_records: theory -> unit
    27   val add_record: (string list * bstring) -> string option
    28     -> (bstring * string) list -> theory -> theory
    29   val add_record_i: (string list * bstring) -> (typ list * string) option
    30     -> (bstring * typ) list -> theory -> theory
    31   val setup: (theory -> theory) list
    32 end;
    33 
    34 structure RecordPackage: RECORD_PACKAGE =
    35 struct
    36 
    37 
    38 (*** utilities ***)
    39 
    40 (* string suffixes *)
    41 
    42 fun suffix sfx s = s ^ sfx;
    43 
    44 fun unsuffix sfx s =
    45   let
    46     val cs = explode s;
    47     val prfx_len = size s - size sfx;
    48   in
    49     if prfx_len >= 0 andalso implode (drop (prfx_len, cs)) = sfx then
    50       implode (take (prfx_len, cs))
    51     else raise LIST "unsuffix"
    52   end;
    53 
    54 
    55 (* definitions and equations *)
    56 
    57 infix 0 :== === ;
    58 
    59 val (op :==) = Logic.mk_defpair;
    60 val (op ===) = HOLogic.mk_Trueprop o HOLogic.mk_eq;
    61 
    62 fun get_defs thy specs = map (PureThy.get_tthm thy o fst) specs;
    63 
    64 
    65 (* proof by simplification *)
    66 
    67 fun prove_simp thy simps =
    68   let
    69     val sign = Theory.sign_of thy;
    70     val ss = Simplifier.addsimps (HOL_basic_ss, map Attribute.thm_of simps);
    71 
    72     fun prove goal =
    73       Attribute.tthm_of
    74         (Goals.prove_goalw_cterm [] (Thm.cterm_of sign goal)
    75           (K [ALLGOALS (Simplifier.simp_tac ss)])
    76         handle ERROR => error ("The error(s) above occurred while trying to prove "
    77           ^ quote (Sign.string_of_term sign goal)));
    78   in prove end;
    79 
    80 
    81 
    82 (*** syntax operations ***)
    83 
    84 (** name components **)
    85 
    86 val moreN = "more";
    87 val schemeN = "_scheme";
    88 val fieldN = "_field";
    89 val field_typeN = "_field_type";
    90 val fstN = "_fst";
    91 val sndN = "_snd";
    92 val updateN = "_update";
    93 val makeN = "make";
    94 val make_schemeN = "make_scheme";
    95 
    96 
    97 
    98 (** tuple operations **)
    99 
   100 (* more type class *)
   101 
   102 val moreS = ["more"];
   103 
   104 
   105 (* types *)
   106 
   107 fun mk_fieldT ((c, T), U) = Type (suffix field_typeN c, [T, U]);
   108 
   109 fun dest_fieldT (typ as Type (c_field_type, [T, U])) =
   110       (case try (unsuffix field_typeN) c_field_type of
   111         None => raise TYPE ("dest_fieldT", [typ], [])
   112       | Some c => ((c, T), U))
   113   | dest_fieldT typ = raise TYPE ("dest_fieldT", [typ], []);
   114 
   115 
   116 (* constructors *)
   117 
   118 fun mk_fieldC U (c, T) = (suffix fieldN c, T --> U --> mk_fieldT ((c, T), U));
   119 
   120 fun mk_field ((c, t), u) =
   121   let val T = fastype_of t and U = fastype_of u
   122   in Const (suffix fieldN c, [T, U] ---> mk_fieldT ((c, T), U)) $ t $ u end;
   123 
   124 
   125 (* destructors *)
   126 
   127 fun mk_fstC U (c, T) = (suffix fstN c, mk_fieldT ((c, T), U) --> T);
   128 fun mk_sndC U (c, T) = (suffix sndN c, mk_fieldT ((c, T), U) --> U);
   129 
   130 fun dest_field fst_or_snd p =
   131   let
   132     val pT = fastype_of p;
   133     val ((c, T), U) = dest_fieldT pT;
   134     val (destN, destT) = if fst_or_snd then (fstN, T) else (sndN, U);
   135   in Const (suffix destN c, pT --> destT) $ p end;
   136 
   137 val mk_fst = dest_field true;
   138 val mk_snd = dest_field false;
   139 
   140 
   141 
   142 (** record operations **)
   143 
   144 (* types *)
   145 
   146 val mk_recordT = foldr mk_fieldT;
   147 
   148 fun dest_recordT T =
   149   (case try dest_fieldT T of
   150     None => ([], T)
   151   | Some (c_T, U) => apfst (cons c_T) (dest_recordT U));
   152 
   153 fun find_fieldT c rT =
   154   (case assoc (fst (dest_recordT rT), c) of
   155     None => raise TYPE ("find_field: " ^ c, [rT], [])
   156   | Some T => T);
   157 
   158 
   159 (* constructors *)
   160 
   161 val mk_record = foldr mk_field;
   162 
   163 
   164 (* selectors *)
   165 
   166 fun mk_selC rT (c, T) = (c, rT --> T);
   167 
   168 fun mk_sel r c =
   169   let val rT = fastype_of r
   170   in Const (mk_selC rT (c, find_fieldT c rT)) $ r end;
   171 
   172 val mk_moreC = mk_selC;
   173 
   174 fun mk_more r c =
   175   let val rT = fastype_of r
   176   in Const (mk_moreC rT (c, snd (dest_recordT rT))) $ r end;
   177 
   178 
   179 (* updates *)
   180 
   181 fun mk_updateC rT (c, T) = (suffix updateN c, T --> rT --> rT);
   182 
   183 fun mk_update r (c, x) =
   184   let val rT = fastype_of r
   185   in Const (mk_updateC rT (c, find_fieldT c rT)) $ x $ r end;
   186 
   187 val mk_more_updateC = mk_updateC;
   188 
   189 fun mk_more_update r (c, x) =
   190   let val rT = fastype_of r
   191   in Const (mk_more_updateC rT (c, snd (dest_recordT rT))) $ x $ r end;
   192 
   193 
   194 (* make *)
   195 
   196 fun mk_makeC rT (c, Ts) = (c, Ts ---> rT);
   197 
   198 
   199 
   200 (** concrete syntax for records **)
   201 
   202 (* parse translations *)
   203 
   204 fun gen_field_tr mark sfx (t as Const (c, _) $ Free (name, _) $ arg) =
   205       if c = mark then Syntax.const (suffix sfx name) $ arg
   206       else raise TERM ("gen_field_tr: " ^ mark, [t])
   207   | gen_field_tr mark _ t = raise TERM ("gen_field_tr: " ^ mark, [t]);
   208 
   209 fun gen_fields_tr sep mark sfx (tm as Const (c, _) $ t $ u) =
   210       if c = sep then gen_field_tr mark sfx t :: gen_fields_tr sep mark sfx u
   211       else [gen_field_tr mark sfx tm]
   212   | gen_fields_tr _ mark sfx tm = [gen_field_tr mark sfx tm];
   213 
   214 fun gen_record_tr sep mark sfx unit [t] = foldr (op $) (gen_fields_tr sep mark sfx t, unit)
   215   | gen_record_tr _ _ _ _ ts = raise TERM ("gen_record_tr", ts);
   216 
   217 fun gen_record_scheme_tr sep mark sfx [t, more] = foldr (op $) (gen_fields_tr sep mark sfx t, more)
   218   | gen_record_scheme_tr _ _ _ ts = raise TERM ("gen_record_scheme_tr", ts);
   219 
   220 
   221 val record_type_tr = gen_record_tr "_field_types" "_field_type" field_typeN (Syntax.const "unit");
   222 val record_type_scheme_tr = gen_record_scheme_tr "_field_types" "_field_type" field_typeN;
   223 
   224 val record_tr = gen_record_tr "_fields" "_field" fieldN HOLogic.unit;
   225 val record_scheme_tr = gen_record_scheme_tr "_fields" "_field" fieldN;
   226 
   227 fun record_update_tr [t, u] =
   228       foldr (op $) (rev (gen_fields_tr "_updates" "_update" updateN u), t)
   229   | record_update_tr ts = raise TERM ("record_update_tr", ts);
   230 
   231 
   232 val parse_translation =
   233  [("_record_type", record_type_tr),
   234   ("_record_type_scheme", record_type_scheme_tr),
   235   ("_record", record_tr),
   236   ("_record_scheme", record_scheme_tr),
   237   ("_record_update", record_update_tr)];
   238 
   239 
   240 (* print translations *)
   241 
   242 fun gen_fields_tr' mark sfx (tm as Const (name_field, _) $ t $ u) =
   243       (case try (unsuffix sfx) name_field of
   244         Some name =>
   245           apfst (cons (Syntax.const mark $ Syntax.free name $ t)) (gen_fields_tr' mark sfx u)
   246       | None => ([], tm))
   247   | gen_fields_tr' _ _ tm = ([], tm);
   248 
   249 fun gen_record_tr' sep mark sfx is_unit record record_scheme tm =
   250   let
   251     val (ts, u) = gen_fields_tr' mark sfx tm;
   252     val t' = foldr1 (fn (v, w) => Syntax.const sep $ v $ w) ts;
   253   in
   254     if is_unit u then Syntax.const record $ t'
   255     else Syntax.const record_scheme $ t' $ u
   256   end;
   257 
   258 
   259 val record_type_tr' =
   260   gen_record_tr' "_field_types" "_field_type" field_typeN
   261     (fn Const ("unit", _) => true | _ => false) "_record_type" "_record_type_scheme";
   262 
   263 val record_tr' =
   264   gen_record_tr' "_fields" "_field" fieldN HOLogic.is_unit "_record" "_record_scheme";
   265 
   266 fun record_update_tr' tm =
   267   let val (ts, u) = gen_fields_tr' "_update" updateN tm in
   268     Syntax.const "_record_update" $ u $
   269       foldr1 (fn (v, w) => Syntax.const "_updates" $ v $ w) (rev ts)
   270   end;
   271 
   272 
   273 fun gen_field_tr' sfx tr' name =
   274   let val name_sfx = suffix sfx name
   275   in (name_sfx, fn [t, u] => tr' (Syntax.const name_sfx $ t $ u) | _ => raise Match) end;
   276 
   277 fun print_translation names =
   278   map (gen_field_tr' field_typeN record_type_tr') names @
   279   map (gen_field_tr' fieldN record_tr') names @
   280   map (gen_field_tr' updateN record_update_tr') names;
   281 
   282 
   283 
   284 (*** extend theory by record definition ***)
   285 
   286 (** record info **)
   287 
   288 (* type record_info and parent_info *)
   289 
   290 type record_info =
   291  {args: (string * sort) list,
   292   parent: (typ list * string) option,
   293   fields: (string * typ) list,
   294   simps: tthm list};
   295 
   296 type parent_info =
   297  {name: string,
   298   fields: (string * typ) list,
   299   simps: tthm list};
   300 
   301 
   302 (* data kind 'HOL/records' *)
   303 
   304 structure RecordsArgs =
   305 struct
   306   val name = "HOL/records";
   307   type T = record_info Symtab.table;
   308 
   309   val empty = Symtab.empty;
   310   val prep_ext = I;
   311   val merge: T * T -> T = Symtab.merge (K true);
   312 
   313   fun print sg tab =
   314     let
   315       val prt_typ = Sign.pretty_typ sg;
   316       val ext_const = Sign.cond_extern sg Sign.constK;
   317 
   318       fun pretty_parent None = []
   319         | pretty_parent (Some (Ts, name)) =
   320             [Pretty.block [prt_typ (Type (name, Ts)), Pretty.str " +"]];
   321 
   322       fun pretty_field (c, T) = Pretty.block
   323         [Pretty.str (ext_const c), Pretty.str " ::", Pretty.brk 1, Pretty.quote (prt_typ T)];
   324 
   325       fun pretty_record (name, {args, parent, fields, simps = _}) = Pretty.block (Pretty.fbreaks
   326         (Pretty.block [prt_typ (Type (name, map TFree args)), Pretty.str " = "] ::
   327           pretty_parent parent @ map pretty_field fields));
   328     in
   329       seq (Pretty.writeln o pretty_record) (Symtab.dest tab)
   330     end;
   331 end;
   332 
   333 structure RecordsData = TheoryDataFun(RecordsArgs);
   334 val print_records = RecordsData.print;
   335 
   336 
   337 (* get and put records *)
   338 
   339 fun get_record thy name = Symtab.lookup (RecordsData.get thy, name);
   340 
   341 fun put_record name info thy =
   342   RecordsData.put (Symtab.update ((name, info), RecordsData.get thy)) thy;
   343 
   344 
   345 (* parent records *)
   346 
   347 fun inst_record thy (types, name) =
   348   let
   349     val sign = Theory.sign_of thy;
   350     fun err msg = error (msg ^ " parent record " ^ quote name);
   351 
   352     val {args, parent, fields, simps} =
   353       (case get_record thy name of Some info => info | None => err "Unknown");
   354     val _ = if length types <> length args then err "Bad number of arguments for" else ();
   355 
   356     fun bad_inst ((x, S), T) =
   357       if Sign.of_sort sign (T, S) then None else Some x
   358     val bads = mapfilter bad_inst (args ~~ types);
   359 
   360     val inst = map fst args ~~ types;
   361     val subst = Term.map_type_tfree (fn (x, _) => the (assoc (inst, x)));
   362   in
   363     if not (null bads) then
   364       err ("Ill-sorted instantiation of " ^ commas bads ^ " in")
   365     else (apsome (apfst (map subst)) parent, map (apsnd subst) fields, simps)
   366   end;
   367 
   368 fun add_parents thy (None, parents) = parents
   369   | add_parents thy (Some (types, name), parents) =
   370       let val (pparent, pfields, psimps) = inst_record thy (types, name)
   371       in add_parents thy (pparent, {name = name, fields = pfields, simps = psimps} :: parents) end;
   372 
   373 
   374 
   375 (** internal theory extenders **)
   376 
   377 (* field_definitions *)
   378 
   379 (*theorems from Prod.thy*)
   380 val prod_convs = map Attribute.tthm_of [fst_conv, snd_conv];
   381 
   382 
   383 fun field_definitions fields names zeta moreT more vars named_vars thy =
   384   let
   385     val base = Sign.base_name;
   386 
   387 
   388     (* prepare declarations and definitions *)
   389 
   390     (*field types*)
   391     fun mk_fieldT_spec c =
   392       (suffix field_typeN c, ["'a", zeta],
   393         HOLogic.mk_prodT (TFree ("'a", HOLogic.termS), moreT), Syntax.NoSyn);
   394     val fieldT_specs = map (mk_fieldT_spec o base) names;
   395 
   396     (*field declarations*)
   397     val field_decls = map (mk_fieldC moreT) fields;
   398     val dest_decls = map (mk_fstC moreT) fields @ map (mk_sndC moreT) fields;
   399 
   400     (*field constructors*)
   401     fun mk_field_spec (c, v) =
   402       mk_field ((c, v), more) :== HOLogic.mk_prod (v, more);
   403     val field_specs = map mk_field_spec named_vars;
   404 
   405     (*field destructors*)
   406     fun mk_dest_spec dest dest' (c, T) =
   407       let
   408         val p = Free ("p", mk_fieldT ((c, T), moreT));
   409         val p' = Free ("p", HOLogic.mk_prodT (T, moreT));
   410           (*note: field types are just abbreviations*)
   411       in dest p :== dest' p' end;
   412     val dest_specs =
   413       map (mk_dest_spec mk_fst HOLogic.mk_fst) fields @
   414       map (mk_dest_spec mk_snd HOLogic.mk_snd) fields;
   415 
   416 
   417     (* prepare theorems *)
   418 
   419     fun mk_dest_prop dest dest' (c, v) =
   420       dest (mk_field ((c, v), more)) === dest' (v, more);
   421     val dest_props =
   422       map (mk_dest_prop mk_fst fst) named_vars @
   423       map (mk_dest_prop mk_snd snd) named_vars;
   424 
   425 
   426     (* 1st stage: defs_thy *)
   427 
   428     val defs_thy =
   429       thy
   430       |> Theory.add_tyabbrs_i fieldT_specs
   431       |> (Theory.add_consts_i o map (Syntax.no_syn o apfst base))
   432         (field_decls @ dest_decls)
   433       |> (PureThy.add_defs_i o map (fn x => (x, [Attribute.tag_internal])))
   434         (field_specs @ dest_specs);
   435 
   436     val field_defs = get_defs defs_thy field_specs;
   437     val dest_defs = get_defs defs_thy dest_specs;
   438 
   439 
   440     (* 2nd stage: thms_thy *)
   441 
   442     val dest_convs =
   443       map (prove_simp defs_thy (field_defs @ dest_defs @ prod_convs)) dest_props;
   444 
   445     val thms_thy =
   446       defs_thy
   447       |> (PureThy.add_tthmss o map Attribute.none)
   448         [("field_defs", field_defs),
   449           ("dest_defs", dest_defs),
   450           ("dest_convs", dest_convs)];
   451 
   452   in (thms_thy, dest_convs) end;
   453 
   454 
   455 (* record_definition *)
   456 
   457 fun record_definition (args, bname) parent (parents: parent_info list) bfields thy =
   458   let
   459     val sign = Theory.sign_of thy;
   460     val full = Sign.full_name_path sign bname;
   461     val base = Sign.base_name;
   462 
   463 
   464     (* basic components *)
   465 
   466     val alphas = map fst args;
   467     val name = Sign.full_name sign bname;       (*not made part of record name space!*)
   468 
   469     val parent_fields = flat (map #fields parents);
   470     val parent_names = map fst parent_fields;
   471     val parent_types = map snd parent_fields;
   472     val parent_len = length parent_fields;
   473     val parent_xs = variantlist (map (base o fst) parent_fields, [moreN]);
   474     val parent_vars = ListPair.map Free (parent_xs, parent_types);
   475     val parent_named_vars = parent_names ~~ parent_vars;
   476 
   477     val fields = map (apfst full) bfields;
   478     val names = map fst fields;
   479     val types = map snd fields;
   480     val len = length fields;
   481     val xs = variantlist (map fst bfields, moreN :: parent_xs);
   482     val vars = ListPair.map Free (xs, types);
   483     val named_vars = names ~~ vars;
   484 
   485     val all_fields = parent_fields @ fields;
   486     val all_names = parent_names @ names;
   487     val all_types = parent_types @ types;
   488     val all_len = parent_len + len;
   489     val all_xs = parent_xs @ xs;
   490     val all_vars = parent_vars @ vars;
   491     val all_named_vars = parent_named_vars @ named_vars;
   492 
   493     val zeta = variant alphas "'z";
   494     val moreT = TFree (zeta, moreS);
   495     val more = Free (moreN, moreT);
   496     val full_moreN = full moreN;
   497     fun more_part t = mk_more t full_moreN;
   498     fun more_part_update t x = mk_more_update t (full_moreN, x);
   499 
   500     val parent_more = funpow parent_len mk_snd;
   501     val idxs = 0 upto (len - 1);
   502 
   503     val rec_schemeT = mk_recordT (all_fields, moreT);
   504     val rec_scheme = mk_record (all_named_vars, more);
   505     val r = Free ("r", rec_schemeT);
   506     val recT = mk_recordT (all_fields, HOLogic.unitT);
   507 
   508 
   509     (* prepare print translation functions *)
   510 
   511     val accesses = distinct (flat (map NameSpace.accesses (full_moreN :: names)));
   512     val (_, _, tr'_names, _) = Syntax.trfun_names (Theory.syn_of thy);
   513     val field_tr's = filter_out (fn (c, _) => c mem tr'_names) (print_translation accesses);
   514 
   515 
   516     (* prepare declarations *)
   517 
   518     val sel_decls = map (mk_selC rec_schemeT) bfields @
   519       [mk_moreC rec_schemeT (moreN, moreT)];
   520     val update_decls = map (mk_updateC rec_schemeT) bfields @
   521       [mk_more_updateC rec_schemeT (moreN, moreT)];
   522     val make_decls =
   523       [(mk_makeC rec_schemeT (make_schemeN, all_types @ [moreT])),
   524        (mk_makeC recT (makeN, all_types))];
   525 
   526 
   527     (* prepare definitions *)
   528 
   529     (*record (scheme) type abbreviation*)
   530     val recordT_specs =
   531       [(suffix schemeN bname, alphas @ [zeta], rec_schemeT, Syntax.NoSyn),
   532         (bname, alphas, recT, Syntax.NoSyn)];
   533 
   534     (*selectors*)
   535     fun mk_sel_spec (i, c) =
   536       mk_sel r c :== mk_fst (funpow i mk_snd (parent_more r));
   537     val sel_specs =
   538       ListPair.map mk_sel_spec (idxs, names) @
   539         [more_part r :== funpow len mk_snd (parent_more r)];
   540 
   541     (*updates*)
   542     val all_sels = all_names ~~ map (mk_sel r) all_names;
   543     fun mk_upd_spec (i, (c, x)) =
   544       mk_update r (c, x) :==
   545         mk_record (nth_update (c, x) (parent_len + i, all_sels), more_part r)
   546     val update_specs =
   547       ListPair.map mk_upd_spec (idxs, named_vars) @
   548         [more_part_update r more :== mk_record (all_sels, more)];
   549 
   550     (*makes*)
   551     val make_scheme = Const (mk_makeC rec_schemeT (full make_schemeN, all_types @ [moreT]));
   552     val make = Const (mk_makeC recT (full makeN, all_types));
   553     val make_specs =
   554       [list_comb (make_scheme, all_vars) $ more :== rec_scheme,
   555         list_comb (make, all_vars) :== mk_record (all_named_vars, HOLogic.unit)];
   556 
   557 
   558     (* prepare propositions *)
   559 
   560     (*selectors*)
   561     val sel_props =
   562       map (fn (c, x) => mk_sel rec_scheme c === x) named_vars @
   563         [more_part rec_scheme === more];
   564 
   565     (*updates*)
   566     fun mk_upd_prop (i, (c, T)) =
   567       let val x' = Free (variant all_xs (base c ^ "'"), T) in
   568         mk_update rec_scheme (c, x') ===
   569           mk_record (nth_update (c, x') (parent_len + i, all_named_vars), more)
   570       end;
   571     val update_props =
   572       ListPair.map mk_upd_prop (idxs, fields) @
   573         let val more' = Free (variant all_xs (moreN ^ "'"), moreT)
   574         in [more_part_update rec_scheme more' === mk_record (all_named_vars, more')] end;
   575 
   576 
   577     (* 1st stage: fields_thy *)
   578 
   579     val (fields_thy, field_simps) =
   580       thy
   581       |> Theory.add_path bname
   582       |> field_definitions fields names zeta moreT more vars named_vars;
   583 
   584 
   585     (* 2nd stage: defs_thy *)
   586 
   587     val defs_thy =
   588       fields_thy
   589       |> Theory.parent_path
   590       |> Theory.add_tyabbrs_i recordT_specs     (*not made part of record name space!*)
   591       |> Theory.add_path bname
   592       |> Theory.add_trfuns ([], [], field_tr's, [])
   593       |> (Theory.add_consts_i o map Syntax.no_syn)
   594         (sel_decls @ update_decls @ make_decls)
   595       |> (PureThy.add_defs_i o map (fn x => (x, [Attribute.tag_internal])))
   596         (sel_specs @ update_specs @ make_specs);
   597 
   598     val sel_defs = get_defs defs_thy sel_specs;
   599     val update_defs = get_defs defs_thy update_specs;
   600     val make_defs = get_defs defs_thy make_specs;
   601 
   602 
   603     (* 3rd stage: thms_thy *)
   604 
   605     val parent_simps = flat (map #simps parents);
   606     val prove = prove_simp defs_thy;
   607 
   608     val sel_convs = map (prove (parent_simps @ sel_defs @ field_simps)) sel_props;
   609     val update_convs = map (prove (parent_simps @ update_defs @ sel_convs)) update_props;
   610 
   611     val simps = field_simps @ sel_convs @ update_convs @ make_defs;
   612 
   613     val thms_thy =
   614       defs_thy
   615       |> (PureThy.add_tthmss o map Attribute.none)
   616         [("select_defs", sel_defs),
   617           ("update_defs", update_defs),
   618           ("make_defs", make_defs),
   619           ("select_convs", sel_convs),
   620           ("update_convs", update_convs)]
   621       |> PureThy.add_tthmss [(("simps", simps), [Simplifier.simp_add_global])];
   622 
   623 
   624     (* 4th stage: final_thy *)
   625 
   626     val final_thy =
   627       thms_thy
   628       |> put_record name {args = args, parent = parent, fields = fields, simps = simps}
   629       |> Theory.parent_path;
   630 
   631   in final_thy end;
   632 
   633 
   634 
   635 (** theory extender interface **)
   636 
   637 (* prepare arguments *)
   638 
   639 (*note: read_raw_typ avoids expanding type abbreviations*)
   640 fun read_raw_parent sign s =
   641   (case Sign.read_raw_typ (sign, K None) s handle TYPE (msg, _, _) => error msg of
   642     Type (name, Ts) => (Ts, name)
   643   | _ => error ("Bad parent record specification: " ^ quote s));
   644 
   645 fun read_typ sign (env, s) =
   646   let
   647     fun def_sort (x, ~1) = assoc (env, x)
   648       | def_sort _ = None;
   649     val T = Type.no_tvars (Sign.read_typ (sign, def_sort) s) handle TYPE (msg, _, _) => error msg;
   650   in (Term.add_typ_tfrees (T, env), T) end;
   651 
   652 fun cert_typ sign (env, raw_T) =
   653   let val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle TYPE (msg, _, _) => error msg
   654   in (Term.add_typ_tfrees (T, env), T) end;
   655 
   656 
   657 (* add_record *)
   658 
   659 (*we do all preparations and error checks here, deferring the real
   660   work to record_definition*)
   661 
   662 fun gen_add_record prep_typ prep_raw_parent (params, bname) raw_parent raw_fields thy =
   663   let
   664     val _ = Theory.requires thy "Record" "record definitions";
   665     val sign = Theory.sign_of thy;
   666     val _ = writeln ("Defining record " ^ quote bname ^ " ...");
   667 
   668 
   669     (* parents *)
   670 
   671     fun prep_inst T = snd (cert_typ sign ([], T));
   672 
   673     val parent = apsome (apfst (map prep_inst) o prep_raw_parent sign) raw_parent
   674       handle ERROR => error ("The error(s) above in parent record specification");
   675     val parents = add_parents thy (parent, []);
   676 
   677     val init_env =
   678       (case parent of
   679         None => []
   680       | Some (types, _) => foldr Term.add_typ_tfrees (types, []));
   681 
   682 
   683     (* fields *)
   684 
   685     fun prep_field (env, (c, raw_T)) =
   686       let val (env', T) = prep_typ sign (env, raw_T) handle ERROR =>
   687         error ("The error(s) above occured in field " ^ quote c)
   688       in (env', (c, T)) end;
   689 
   690     val (envir, bfields) = foldl_map prep_field (init_env, raw_fields);
   691     val envir_names = map fst envir;
   692 
   693 
   694     (* args *)
   695 
   696     val defaultS = Sign.defaultS sign;
   697     val args = map (fn x => (x, if_none (assoc (envir, x)) defaultS)) params;
   698 
   699 
   700     (* errors *)
   701 
   702     val name = Sign.full_name sign bname;
   703     val err_dup_record =
   704       if is_none (get_record thy name) then []
   705       else ["Duplicate definition of record " ^ quote name];
   706 
   707     val err_dup_parms =
   708       (case duplicates params of
   709         [] => []
   710       | dups => ["Duplicate parameter(s) " ^ commas dups]);
   711 
   712     val err_extra_frees =
   713       (case gen_rems (op =) (envir_names, params) of
   714         [] => []
   715       | extras => ["Extra free type variable(s) " ^ commas extras]);
   716 
   717     val err_no_fields = if null bfields then ["No fields present"] else [];
   718 
   719     val err_dup_fields =
   720       (case duplicates (map fst bfields) of
   721         [] => []
   722       | dups => ["Duplicate field(s) " ^ commas_quote dups]);
   723 
   724     val err_bad_fields =
   725       if forall (not_equal moreN o fst) bfields then []
   726       else ["Illegal field name " ^ quote moreN];
   727 
   728     val err_dup_sorts =
   729       (case duplicates envir_names of
   730         [] => []
   731       | dups => ["Inconsistent sort constraints for " ^ commas dups]);
   732 
   733     val errs =
   734       err_dup_record @ err_dup_parms @ err_extra_frees @ err_no_fields @
   735       err_dup_fields @ err_bad_fields @ err_dup_sorts;
   736   in
   737     if null errs then () else error (cat_lines errs);
   738     thy |> record_definition (args, bname) parent parents bfields
   739   end
   740   handle ERROR => error ("Failed to define record " ^ quote bname);
   741 
   742 val add_record = gen_add_record read_typ read_raw_parent;
   743 val add_record_i = gen_add_record cert_typ (K I);
   744 
   745 
   746 
   747 (** setup theory **)
   748 
   749 val setup =
   750  [RecordsData.init,
   751   Theory.add_trfuns ([], parse_translation, [], [])];
   752 
   753 
   754 end;