src/HOL/Algebra/Group.thy
author ballarin
Tue Jun 20 15:53:44 2006 +0200 (2006-06-20)
changeset 19931 fb32b43e7f80
parent 19783 82f365a14960
child 19981 c0f124a0d385
permissions -rw-r--r--
Restructured locales with predicates: import is now an interpretation.
New method intro_locales.
     1 (*
     2   Title:  HOL/Algebra/Group.thy
     3   Id:     $Id$
     4   Author: Clemens Ballarin, started 4 February 2003
     5 
     6 Based on work by Florian Kammueller, L C Paulson and Markus Wenzel.
     7 *)
     8 
     9 header {* Groups *}
    10 
    11 theory Group imports FuncSet Lattice begin
    12 
    13 
    14 section {* Monoids and Groups *}
    15 
    16 text {*
    17   Definitions follow \cite{Jacobson:1985}.
    18 *}
    19 
    20 subsection {* Definitions *}
    21 
    22 record 'a monoid =  "'a partial_object" +
    23   mult    :: "['a, 'a] \<Rightarrow> 'a" (infixl "\<otimes>\<index>" 70)
    24   one     :: 'a ("\<one>\<index>")
    25 
    26 constdefs (structure G)
    27   m_inv :: "('a, 'b) monoid_scheme => 'a => 'a" ("inv\<index> _" [81] 80)
    28   "inv x == (THE y. y \<in> carrier G & x \<otimes> y = \<one> & y \<otimes> x = \<one>)"
    29 
    30   Units :: "_ => 'a set"
    31   --{*The set of invertible elements*}
    32   "Units G == {y. y \<in> carrier G & (\<exists>x \<in> carrier G. x \<otimes> y = \<one> & y \<otimes> x = \<one>)}"
    33 
    34 consts
    35   pow :: "[('a, 'm) monoid_scheme, 'a, 'b::number] => 'a" (infixr "'(^')\<index>" 75)
    36 
    37 defs (overloaded)
    38   nat_pow_def: "pow G a n == nat_rec \<one>\<^bsub>G\<^esub> (%u b. b \<otimes>\<^bsub>G\<^esub> a) n"
    39   int_pow_def: "pow G a z ==
    40     let p = nat_rec \<one>\<^bsub>G\<^esub> (%u b. b \<otimes>\<^bsub>G\<^esub> a)
    41     in if neg z then inv\<^bsub>G\<^esub> (p (nat (-z))) else p (nat z)"
    42 
    43 locale monoid =
    44   fixes G (structure)
    45   assumes m_closed [intro, simp]:
    46          "\<lbrakk>x \<in> carrier G; y \<in> carrier G\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> carrier G"
    47       and m_assoc:
    48          "\<lbrakk>x \<in> carrier G; y \<in> carrier G; z \<in> carrier G\<rbrakk> 
    49           \<Longrightarrow> (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
    50       and one_closed [intro, simp]: "\<one> \<in> carrier G"
    51       and l_one [simp]: "x \<in> carrier G \<Longrightarrow> \<one> \<otimes> x = x"
    52       and r_one [simp]: "x \<in> carrier G \<Longrightarrow> x \<otimes> \<one> = x"
    53 
    54 lemma monoidI:
    55   fixes G (structure)
    56   assumes m_closed:
    57       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
    58     and one_closed: "\<one> \<in> carrier G"
    59     and m_assoc:
    60       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
    61       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
    62     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
    63     and r_one: "!!x. x \<in> carrier G ==> x \<otimes> \<one> = x"
    64   shows "monoid G"
    65   by (fast intro!: monoid.intro intro: prems)
    66 
    67 lemma (in monoid) Units_closed [dest]:
    68   "x \<in> Units G ==> x \<in> carrier G"
    69   by (unfold Units_def) fast
    70 
    71 lemma (in monoid) inv_unique:
    72   assumes eq: "y \<otimes> x = \<one>"  "x \<otimes> y' = \<one>"
    73     and G: "x \<in> carrier G"  "y \<in> carrier G"  "y' \<in> carrier G"
    74   shows "y = y'"
    75 proof -
    76   from G eq have "y = y \<otimes> (x \<otimes> y')" by simp
    77   also from G have "... = (y \<otimes> x) \<otimes> y'" by (simp add: m_assoc)
    78   also from G eq have "... = y'" by simp
    79   finally show ?thesis .
    80 qed
    81 
    82 lemma (in monoid) Units_one_closed [intro, simp]:
    83   "\<one> \<in> Units G"
    84   by (unfold Units_def) auto
    85 
    86 lemma (in monoid) Units_inv_closed [intro, simp]:
    87   "x \<in> Units G ==> inv x \<in> carrier G"
    88   apply (unfold Units_def m_inv_def, auto)
    89   apply (rule theI2, fast)
    90    apply (fast intro: inv_unique, fast)
    91   done
    92 
    93 lemma (in monoid) Units_l_inv:
    94   "x \<in> Units G ==> inv x \<otimes> x = \<one>"
    95   apply (unfold Units_def m_inv_def, auto)
    96   apply (rule theI2, fast)
    97    apply (fast intro: inv_unique, fast)
    98   done
    99 
   100 lemma (in monoid) Units_r_inv:
   101   "x \<in> Units G ==> x \<otimes> inv x = \<one>"
   102   apply (unfold Units_def m_inv_def, auto)
   103   apply (rule theI2, fast)
   104    apply (fast intro: inv_unique, fast)
   105   done
   106 
   107 lemma (in monoid) Units_inv_Units [intro, simp]:
   108   "x \<in> Units G ==> inv x \<in> Units G"
   109 proof -
   110   assume x: "x \<in> Units G"
   111   show "inv x \<in> Units G"
   112     by (auto simp add: Units_def
   113       intro: Units_l_inv Units_r_inv x Units_closed [OF x])
   114 qed
   115 
   116 lemma (in monoid) Units_l_cancel [simp]:
   117   "[| x \<in> Units G; y \<in> carrier G; z \<in> carrier G |] ==>
   118    (x \<otimes> y = x \<otimes> z) = (y = z)"
   119 proof
   120   assume eq: "x \<otimes> y = x \<otimes> z"
   121     and G: "x \<in> Units G"  "y \<in> carrier G"  "z \<in> carrier G"
   122   then have "(inv x \<otimes> x) \<otimes> y = (inv x \<otimes> x) \<otimes> z"
   123     by (simp add: m_assoc Units_closed)
   124   with G show "y = z" by (simp add: Units_l_inv)
   125 next
   126   assume eq: "y = z"
   127     and G: "x \<in> Units G"  "y \<in> carrier G"  "z \<in> carrier G"
   128   then show "x \<otimes> y = x \<otimes> z" by simp
   129 qed
   130 
   131 lemma (in monoid) Units_inv_inv [simp]:
   132   "x \<in> Units G ==> inv (inv x) = x"
   133 proof -
   134   assume x: "x \<in> Units G"
   135   then have "inv x \<otimes> inv (inv x) = inv x \<otimes> x"
   136     by (simp add: Units_l_inv Units_r_inv)
   137   with x show ?thesis by (simp add: Units_closed)
   138 qed
   139 
   140 lemma (in monoid) inv_inj_on_Units:
   141   "inj_on (m_inv G) (Units G)"
   142 proof (rule inj_onI)
   143   fix x y
   144   assume G: "x \<in> Units G"  "y \<in> Units G" and eq: "inv x = inv y"
   145   then have "inv (inv x) = inv (inv y)" by simp
   146   with G show "x = y" by simp
   147 qed
   148 
   149 lemma (in monoid) Units_inv_comm:
   150   assumes inv: "x \<otimes> y = \<one>"
   151     and G: "x \<in> Units G"  "y \<in> Units G"
   152   shows "y \<otimes> x = \<one>"
   153 proof -
   154   from G have "x \<otimes> y \<otimes> x = x \<otimes> \<one>" by (auto simp add: inv Units_closed)
   155   with G show ?thesis by (simp del: r_one add: m_assoc Units_closed)
   156 qed
   157 
   158 text {* Power *}
   159 
   160 lemma (in monoid) nat_pow_closed [intro, simp]:
   161   "x \<in> carrier G ==> x (^) (n::nat) \<in> carrier G"
   162   by (induct n) (simp_all add: nat_pow_def)
   163 
   164 lemma (in monoid) nat_pow_0 [simp]:
   165   "x (^) (0::nat) = \<one>"
   166   by (simp add: nat_pow_def)
   167 
   168 lemma (in monoid) nat_pow_Suc [simp]:
   169   "x (^) (Suc n) = x (^) n \<otimes> x"
   170   by (simp add: nat_pow_def)
   171 
   172 lemma (in monoid) nat_pow_one [simp]:
   173   "\<one> (^) (n::nat) = \<one>"
   174   by (induct n) simp_all
   175 
   176 lemma (in monoid) nat_pow_mult:
   177   "x \<in> carrier G ==> x (^) (n::nat) \<otimes> x (^) m = x (^) (n + m)"
   178   by (induct m) (simp_all add: m_assoc [THEN sym])
   179 
   180 lemma (in monoid) nat_pow_pow:
   181   "x \<in> carrier G ==> (x (^) n) (^) m = x (^) (n * m::nat)"
   182   by (induct m) (simp, simp add: nat_pow_mult add_commute)
   183 
   184 text {*
   185   A group is a monoid all of whose elements are invertible.
   186 *}
   187 
   188 locale group = monoid +
   189   assumes Units: "carrier G <= Units G"
   190 
   191 
   192 lemma (in group) is_group: "group G" .
   193 
   194 theorem groupI:
   195   fixes G (structure)
   196   assumes m_closed [simp]:
   197       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
   198     and one_closed [simp]: "\<one> \<in> carrier G"
   199     and m_assoc:
   200       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   201       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
   202     and l_one [simp]: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
   203     and l_inv_ex: "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   204   shows "group G"
   205 proof -
   206   have l_cancel [simp]:
   207     "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   208     (x \<otimes> y = x \<otimes> z) = (y = z)"
   209   proof
   210     fix x y z
   211     assume eq: "x \<otimes> y = x \<otimes> z"
   212       and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   213     with l_inv_ex obtain x_inv where xG: "x_inv \<in> carrier G"
   214       and l_inv: "x_inv \<otimes> x = \<one>" by fast
   215     from G eq xG have "(x_inv \<otimes> x) \<otimes> y = (x_inv \<otimes> x) \<otimes> z"
   216       by (simp add: m_assoc)
   217     with G show "y = z" by (simp add: l_inv)
   218   next
   219     fix x y z
   220     assume eq: "y = z"
   221       and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   222     then show "x \<otimes> y = x \<otimes> z" by simp
   223   qed
   224   have r_one:
   225     "!!x. x \<in> carrier G ==> x \<otimes> \<one> = x"
   226   proof -
   227     fix x
   228     assume x: "x \<in> carrier G"
   229     with l_inv_ex obtain x_inv where xG: "x_inv \<in> carrier G"
   230       and l_inv: "x_inv \<otimes> x = \<one>" by fast
   231     from x xG have "x_inv \<otimes> (x \<otimes> \<one>) = x_inv \<otimes> x"
   232       by (simp add: m_assoc [symmetric] l_inv)
   233     with x xG show "x \<otimes> \<one> = x" by simp
   234   qed
   235   have inv_ex:
   236     "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one> & x \<otimes> y = \<one>"
   237   proof -
   238     fix x
   239     assume x: "x \<in> carrier G"
   240     with l_inv_ex obtain y where y: "y \<in> carrier G"
   241       and l_inv: "y \<otimes> x = \<one>" by fast
   242     from x y have "y \<otimes> (x \<otimes> y) = y \<otimes> \<one>"
   243       by (simp add: m_assoc [symmetric] l_inv r_one)
   244     with x y have r_inv: "x \<otimes> y = \<one>"
   245       by simp
   246     from x y show "\<exists>y \<in> carrier G. y \<otimes> x = \<one> & x \<otimes> y = \<one>"
   247       by (fast intro: l_inv r_inv)
   248   qed
   249   then have carrier_subset_Units: "carrier G <= Units G"
   250     by (unfold Units_def) fast
   251   show ?thesis
   252     by (fast intro!: group.intro monoid.intro group_axioms.intro
   253       carrier_subset_Units intro: prems r_one)
   254 qed
   255 
   256 lemma (in monoid) monoid_groupI:
   257   assumes l_inv_ex:
   258     "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   259   shows "group G"
   260   by (rule groupI) (auto intro: m_assoc l_inv_ex)
   261 
   262 lemma (in group) Units_eq [simp]:
   263   "Units G = carrier G"
   264 proof
   265   show "Units G <= carrier G" by fast
   266 next
   267   show "carrier G <= Units G" by (rule Units)
   268 qed
   269 
   270 lemma (in group) inv_closed [intro, simp]:
   271   "x \<in> carrier G ==> inv x \<in> carrier G"
   272   using Units_inv_closed by simp
   273 
   274 lemma (in group) l_inv [simp]:
   275   "x \<in> carrier G ==> inv x \<otimes> x = \<one>"
   276   using Units_l_inv by simp
   277 
   278 subsection {* Cancellation Laws and Basic Properties *}
   279 
   280 lemma (in group) l_cancel [simp]:
   281   "[| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   282    (x \<otimes> y = x \<otimes> z) = (y = z)"
   283   using Units_l_inv by simp
   284 
   285 lemma (in group) r_inv [simp]:
   286   "x \<in> carrier G ==> x \<otimes> inv x = \<one>"
   287 proof -
   288   assume x: "x \<in> carrier G"
   289   then have "inv x \<otimes> (x \<otimes> inv x) = inv x \<otimes> \<one>"
   290     by (simp add: m_assoc [symmetric] l_inv)
   291   with x show ?thesis by (simp del: r_one)
   292 qed
   293 
   294 lemma (in group) r_cancel [simp]:
   295   "[| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   296    (y \<otimes> x = z \<otimes> x) = (y = z)"
   297 proof
   298   assume eq: "y \<otimes> x = z \<otimes> x"
   299     and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   300   then have "y \<otimes> (x \<otimes> inv x) = z \<otimes> (x \<otimes> inv x)"
   301     by (simp add: m_assoc [symmetric] del: r_inv)
   302   with G show "y = z" by simp
   303 next
   304   assume eq: "y = z"
   305     and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   306   then show "y \<otimes> x = z \<otimes> x" by simp
   307 qed
   308 
   309 lemma (in group) inv_one [simp]:
   310   "inv \<one> = \<one>"
   311 proof -
   312   have "inv \<one> = \<one> \<otimes> (inv \<one>)" by (simp del: r_inv)
   313   moreover have "... = \<one>" by simp
   314   finally show ?thesis .
   315 qed
   316 
   317 lemma (in group) inv_inv [simp]:
   318   "x \<in> carrier G ==> inv (inv x) = x"
   319   using Units_inv_inv by simp
   320 
   321 lemma (in group) inv_inj:
   322   "inj_on (m_inv G) (carrier G)"
   323   using inv_inj_on_Units by simp
   324 
   325 lemma (in group) inv_mult_group:
   326   "[| x \<in> carrier G; y \<in> carrier G |] ==> inv (x \<otimes> y) = inv y \<otimes> inv x"
   327 proof -
   328   assume G: "x \<in> carrier G"  "y \<in> carrier G"
   329   then have "inv (x \<otimes> y) \<otimes> (x \<otimes> y) = (inv y \<otimes> inv x) \<otimes> (x \<otimes> y)"
   330     by (simp add: m_assoc l_inv) (simp add: m_assoc [symmetric])
   331   with G show ?thesis by (simp del: l_inv)
   332 qed
   333 
   334 lemma (in group) inv_comm:
   335   "[| x \<otimes> y = \<one>; x \<in> carrier G; y \<in> carrier G |] ==> y \<otimes> x = \<one>"
   336   by (rule Units_inv_comm) auto
   337 
   338 lemma (in group) inv_equality:
   339      "[|y \<otimes> x = \<one>; x \<in> carrier G; y \<in> carrier G|] ==> inv x = y"
   340 apply (simp add: m_inv_def)
   341 apply (rule the_equality)
   342  apply (simp add: inv_comm [of y x])
   343 apply (rule r_cancel [THEN iffD1], auto)
   344 done
   345 
   346 text {* Power *}
   347 
   348 lemma (in group) int_pow_def2:
   349   "a (^) (z::int) = (if neg z then inv (a (^) (nat (-z))) else a (^) (nat z))"
   350   by (simp add: int_pow_def nat_pow_def Let_def)
   351 
   352 lemma (in group) int_pow_0 [simp]:
   353   "x (^) (0::int) = \<one>"
   354   by (simp add: int_pow_def2)
   355 
   356 lemma (in group) int_pow_one [simp]:
   357   "\<one> (^) (z::int) = \<one>"
   358   by (simp add: int_pow_def2)
   359 
   360 subsection {* Subgroups *}
   361 
   362 locale subgroup =
   363   fixes H and G (structure)
   364   assumes subset: "H \<subseteq> carrier G"
   365     and m_closed [intro, simp]: "\<lbrakk>x \<in> H; y \<in> H\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> H"
   366     and  one_closed [simp]: "\<one> \<in> H"
   367     and m_inv_closed [intro,simp]: "x \<in> H \<Longrightarrow> inv x \<in> H"
   368 
   369 declare (in subgroup) group.intro [intro]
   370 
   371 lemma (in subgroup) mem_carrier [simp]:
   372   "x \<in> H \<Longrightarrow> x \<in> carrier G"
   373   using subset by blast
   374 
   375 lemma subgroup_imp_subset:
   376   "subgroup H G \<Longrightarrow> H \<subseteq> carrier G"
   377   by (rule subgroup.subset)
   378 
   379 lemma (in subgroup) subgroup_is_group [intro]:
   380   includes group G
   381   shows "group (G\<lparr>carrier := H\<rparr>)" 
   382   by (rule groupI) (auto intro: m_assoc l_inv mem_carrier)
   383 
   384 text {*
   385   Since @{term H} is nonempty, it contains some element @{term x}.  Since
   386   it is closed under inverse, it contains @{text "inv x"}.  Since
   387   it is closed under product, it contains @{text "x \<otimes> inv x = \<one>"}.
   388 *}
   389 
   390 lemma (in group) one_in_subset:
   391   "[| H \<subseteq> carrier G; H \<noteq> {}; \<forall>a \<in> H. inv a \<in> H; \<forall>a\<in>H. \<forall>b\<in>H. a \<otimes> b \<in> H |]
   392    ==> \<one> \<in> H"
   393 by (force simp add: l_inv)
   394 
   395 text {* A characterization of subgroups: closed, non-empty subset. *}
   396 
   397 lemma (in group) subgroupI:
   398   assumes subset: "H \<subseteq> carrier G" and non_empty: "H \<noteq> {}"
   399     and inv: "!!a. a \<in> H \<Longrightarrow> inv a \<in> H"
   400     and mult: "!!a b. \<lbrakk>a \<in> H; b \<in> H\<rbrakk> \<Longrightarrow> a \<otimes> b \<in> H"
   401   shows "subgroup H G"
   402 proof (simp add: subgroup_def prems)
   403   show "\<one> \<in> H" by (rule one_in_subset) (auto simp only: prems)
   404 qed
   405 
   406 declare monoid.one_closed [iff] group.inv_closed [simp]
   407   monoid.l_one [simp] monoid.r_one [simp] group.inv_inv [simp]
   408 
   409 lemma subgroup_nonempty:
   410   "~ subgroup {} G"
   411   by (blast dest: subgroup.one_closed)
   412 
   413 lemma (in subgroup) finite_imp_card_positive:
   414   "finite (carrier G) ==> 0 < card H"
   415 proof (rule classical)
   416   assume "finite (carrier G)" "~ 0 < card H"
   417   then have "finite H" by (blast intro: finite_subset [OF subset])
   418   with prems have "subgroup {} G" by simp
   419   with subgroup_nonempty show ?thesis by contradiction
   420 qed
   421 
   422 (*
   423 lemma (in monoid) Units_subgroup:
   424   "subgroup (Units G) G"
   425 *)
   426 
   427 subsection {* Direct Products *}
   428 
   429 constdefs
   430   DirProd :: "_ \<Rightarrow> _ \<Rightarrow> ('a \<times> 'b) monoid"  (infixr "\<times>\<times>" 80)
   431   "G \<times>\<times> H \<equiv> \<lparr>carrier = carrier G \<times> carrier H,
   432                 mult = (\<lambda>(g, h) (g', h'). (g \<otimes>\<^bsub>G\<^esub> g', h \<otimes>\<^bsub>H\<^esub> h')),
   433                 one = (\<one>\<^bsub>G\<^esub>, \<one>\<^bsub>H\<^esub>)\<rparr>"
   434 
   435 lemma DirProd_monoid:
   436   includes monoid G + monoid H
   437   shows "monoid (G \<times>\<times> H)"
   438 proof -
   439   from prems
   440   show ?thesis by (unfold monoid_def DirProd_def, auto) 
   441 qed
   442 
   443 
   444 text{*Does not use the previous result because it's easier just to use auto.*}
   445 lemma DirProd_group:
   446   includes group G + group H
   447   shows "group (G \<times>\<times> H)"
   448   by (rule groupI)
   449      (auto intro: G.m_assoc H.m_assoc G.l_inv H.l_inv
   450            simp add: DirProd_def)
   451 
   452 lemma carrier_DirProd [simp]:
   453      "carrier (G \<times>\<times> H) = carrier G \<times> carrier H"
   454   by (simp add: DirProd_def)
   455 
   456 lemma one_DirProd [simp]:
   457      "\<one>\<^bsub>G \<times>\<times> H\<^esub> = (\<one>\<^bsub>G\<^esub>, \<one>\<^bsub>H\<^esub>)"
   458   by (simp add: DirProd_def)
   459 
   460 lemma mult_DirProd [simp]:
   461      "(g, h) \<otimes>\<^bsub>(G \<times>\<times> H)\<^esub> (g', h') = (g \<otimes>\<^bsub>G\<^esub> g', h \<otimes>\<^bsub>H\<^esub> h')"
   462   by (simp add: DirProd_def)
   463 
   464 lemma inv_DirProd [simp]:
   465   includes group G + group H
   466   assumes g: "g \<in> carrier G"
   467       and h: "h \<in> carrier H"
   468   shows "m_inv (G \<times>\<times> H) (g, h) = (inv\<^bsub>G\<^esub> g, inv\<^bsub>H\<^esub> h)"
   469   apply (rule group.inv_equality [OF DirProd_group])
   470   apply (simp_all add: prems group.l_inv)
   471   done
   472 
   473 text{*This alternative proof of the previous result demonstrates interpret.
   474    It uses @{text Prod.inv_equality} (available after @{text interpret})
   475    instead of @{text "group.inv_equality [OF DirProd_group]"}. *}
   476 lemma
   477   includes group G + group H
   478   assumes g: "g \<in> carrier G"
   479       and h: "h \<in> carrier H"
   480   shows "m_inv (G \<times>\<times> H) (g, h) = (inv\<^bsub>G\<^esub> g, inv\<^bsub>H\<^esub> h)"
   481 proof -
   482   interpret Prod: group ["G \<times>\<times> H"]
   483     by (auto intro: DirProd_group group.intro group.axioms prems)
   484   show ?thesis by (simp add: Prod.inv_equality g h)
   485 qed
   486   
   487 
   488 subsection {* Homomorphisms and Isomorphisms *}
   489 
   490 constdefs (structure G and H)
   491   hom :: "_ => _ => ('a => 'b) set"
   492   "hom G H ==
   493     {h. h \<in> carrier G -> carrier H &
   494       (\<forall>x \<in> carrier G. \<forall>y \<in> carrier G. h (x \<otimes>\<^bsub>G\<^esub> y) = h x \<otimes>\<^bsub>H\<^esub> h y)}"
   495 
   496 lemma hom_mult:
   497   "[| h \<in> hom G H; x \<in> carrier G; y \<in> carrier G |]
   498    ==> h (x \<otimes>\<^bsub>G\<^esub> y) = h x \<otimes>\<^bsub>H\<^esub> h y"
   499   by (simp add: hom_def)
   500 
   501 lemma hom_closed:
   502   "[| h \<in> hom G H; x \<in> carrier G |] ==> h x \<in> carrier H"
   503   by (auto simp add: hom_def funcset_mem)
   504 
   505 lemma (in group) hom_compose:
   506      "[|h \<in> hom G H; i \<in> hom H I|] ==> compose (carrier G) i h \<in> hom G I"
   507 apply (auto simp add: hom_def funcset_compose) 
   508 apply (simp add: compose_def funcset_mem)
   509 done
   510 
   511 
   512 subsection {* Isomorphisms *}
   513 
   514 constdefs
   515   iso :: "_ => _ => ('a => 'b) set"  (infixr "\<cong>" 60)
   516   "G \<cong> H == {h. h \<in> hom G H & bij_betw h (carrier G) (carrier H)}"
   517 
   518 lemma iso_refl: "(%x. x) \<in> G \<cong> G"
   519 by (simp add: iso_def hom_def inj_on_def bij_betw_def Pi_def) 
   520 
   521 lemma (in group) iso_sym:
   522      "h \<in> G \<cong> H \<Longrightarrow> Inv (carrier G) h \<in> H \<cong> G"
   523 apply (simp add: iso_def bij_betw_Inv) 
   524 apply (subgoal_tac "Inv (carrier G) h \<in> carrier H \<rightarrow> carrier G") 
   525  prefer 2 apply (simp add: bij_betw_imp_funcset [OF bij_betw_Inv]) 
   526 apply (simp add: hom_def bij_betw_def Inv_f_eq funcset_mem f_Inv_f) 
   527 done
   528 
   529 lemma (in group) iso_trans: 
   530      "[|h \<in> G \<cong> H; i \<in> H \<cong> I|] ==> (compose (carrier G) i h) \<in> G \<cong> I"
   531 by (auto simp add: iso_def hom_compose bij_betw_compose)
   532 
   533 lemma DirProd_commute_iso:
   534   shows "(\<lambda>(x,y). (y,x)) \<in> (G \<times>\<times> H) \<cong> (H \<times>\<times> G)"
   535 by (auto simp add: iso_def hom_def inj_on_def bij_betw_def Pi_def) 
   536 
   537 lemma DirProd_assoc_iso:
   538   shows "(\<lambda>(x,y,z). (x,(y,z))) \<in> (G \<times>\<times> H \<times>\<times> I) \<cong> (G \<times>\<times> (H \<times>\<times> I))"
   539 by (auto simp add: iso_def hom_def inj_on_def bij_betw_def Pi_def) 
   540 
   541 
   542 text{*Basis for homomorphism proofs: we assume two groups @{term G} and
   543   @{term H}, with a homomorphism @{term h} between them*}
   544 locale group_hom = group G + group H + var h +
   545   assumes homh: "h \<in> hom G H"
   546   notes hom_mult [simp] = hom_mult [OF homh]
   547     and hom_closed [simp] = hom_closed [OF homh]
   548 
   549 lemma (in group_hom) one_closed [simp]:
   550   "h \<one> \<in> carrier H"
   551   by simp
   552 
   553 lemma (in group_hom) hom_one [simp]:
   554   "h \<one> = \<one>\<^bsub>H\<^esub>"
   555 proof -
   556   have "h \<one> \<otimes>\<^bsub>H\<^esub> \<one>\<^bsub>H\<^esub> = h \<one> \<otimes>\<^bsub>H\<^esub> h \<one>"
   557     by (simp add: hom_mult [symmetric] del: hom_mult)
   558   then show ?thesis by (simp del: r_one)
   559 qed
   560 
   561 lemma (in group_hom) inv_closed [simp]:
   562   "x \<in> carrier G ==> h (inv x) \<in> carrier H"
   563   by simp
   564 
   565 lemma (in group_hom) hom_inv [simp]:
   566   "x \<in> carrier G ==> h (inv x) = inv\<^bsub>H\<^esub> (h x)"
   567 proof -
   568   assume x: "x \<in> carrier G"
   569   then have "h x \<otimes>\<^bsub>H\<^esub> h (inv x) = \<one>\<^bsub>H\<^esub>"
   570     by (simp add: hom_mult [symmetric] del: hom_mult)
   571   also from x have "... = h x \<otimes>\<^bsub>H\<^esub> inv\<^bsub>H\<^esub> (h x)"
   572     by (simp add: hom_mult [symmetric] del: hom_mult)
   573   finally have "h x \<otimes>\<^bsub>H\<^esub> h (inv x) = h x \<otimes>\<^bsub>H\<^esub> inv\<^bsub>H\<^esub> (h x)" .
   574   with x show ?thesis by (simp del: H.r_inv)
   575 qed
   576 
   577 subsection {* Commutative Structures *}
   578 
   579 text {*
   580   Naming convention: multiplicative structures that are commutative
   581   are called \emph{commutative}, additive structures are called
   582   \emph{Abelian}.
   583 *}
   584 
   585 subsection {* Definition *}
   586 
   587 locale comm_monoid = monoid +
   588   assumes m_comm: "\<lbrakk>x \<in> carrier G; y \<in> carrier G\<rbrakk> \<Longrightarrow> x \<otimes> y = y \<otimes> x"
   589 
   590 lemma (in comm_monoid) m_lcomm:
   591   "\<lbrakk>x \<in> carrier G; y \<in> carrier G; z \<in> carrier G\<rbrakk> \<Longrightarrow>
   592    x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
   593 proof -
   594   assume xyz: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   595   from xyz have "x \<otimes> (y \<otimes> z) = (x \<otimes> y) \<otimes> z" by (simp add: m_assoc)
   596   also from xyz have "... = (y \<otimes> x) \<otimes> z" by (simp add: m_comm)
   597   also from xyz have "... = y \<otimes> (x \<otimes> z)" by (simp add: m_assoc)
   598   finally show ?thesis .
   599 qed
   600 
   601 lemmas (in comm_monoid) m_ac = m_assoc m_comm m_lcomm
   602 
   603 lemma comm_monoidI:
   604   fixes G (structure)
   605   assumes m_closed:
   606       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
   607     and one_closed: "\<one> \<in> carrier G"
   608     and m_assoc:
   609       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   610       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
   611     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
   612     and m_comm:
   613       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
   614   shows "comm_monoid G"
   615   using l_one
   616     by (auto intro!: comm_monoid.intro comm_monoid_axioms.intro monoid.intro 
   617              intro: prems simp: m_closed one_closed m_comm)
   618 
   619 lemma (in monoid) monoid_comm_monoidI:
   620   assumes m_comm:
   621       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
   622   shows "comm_monoid G"
   623   by (rule comm_monoidI) (auto intro: m_assoc m_comm)
   624 
   625 (*lemma (in comm_monoid) r_one [simp]:
   626   "x \<in> carrier G ==> x \<otimes> \<one> = x"
   627 proof -
   628   assume G: "x \<in> carrier G"
   629   then have "x \<otimes> \<one> = \<one> \<otimes> x" by (simp add: m_comm)
   630   also from G have "... = x" by simp
   631   finally show ?thesis .
   632 qed*)
   633 
   634 lemma (in comm_monoid) nat_pow_distr:
   635   "[| x \<in> carrier G; y \<in> carrier G |] ==>
   636   (x \<otimes> y) (^) (n::nat) = x (^) n \<otimes> y (^) n"
   637   by (induct n) (simp, simp add: m_ac)
   638 
   639 locale comm_group = comm_monoid + group
   640 
   641 lemma (in group) group_comm_groupI:
   642   assumes m_comm: "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==>
   643       x \<otimes> y = y \<otimes> x"
   644   shows "comm_group G"
   645   by intro_locales (simp_all add: m_comm)
   646 
   647 lemma comm_groupI:
   648   fixes G (structure)
   649   assumes m_closed:
   650       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
   651     and one_closed: "\<one> \<in> carrier G"
   652     and m_assoc:
   653       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   654       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
   655     and m_comm:
   656       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
   657     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
   658     and l_inv_ex: "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   659   shows "comm_group G"
   660   by (fast intro: group.group_comm_groupI groupI prems)
   661 
   662 lemma (in comm_group) inv_mult:
   663   "[| x \<in> carrier G; y \<in> carrier G |] ==> inv (x \<otimes> y) = inv x \<otimes> inv y"
   664   by (simp add: m_ac inv_mult_group)
   665 
   666 subsection {* Lattice of subgroups of a group *}
   667 
   668 text_raw {* \label{sec:subgroup-lattice} *}
   669 
   670 theorem (in group) subgroups_partial_order:
   671   "partial_order (| carrier = {H. subgroup H G}, le = op \<subseteq> |)"
   672   by (rule partial_order.intro) simp_all
   673 
   674 lemma (in group) subgroup_self:
   675   "subgroup (carrier G) G"
   676   by (rule subgroupI) auto
   677 
   678 lemma (in group) subgroup_imp_group:
   679   "subgroup H G ==> group (G(| carrier := H |))"
   680   by (rule subgroup.subgroup_is_group)
   681 
   682 lemma (in group) is_monoid [intro, simp]:
   683   "monoid G"
   684   by (auto intro: monoid.intro m_assoc) 
   685 
   686 lemma (in group) subgroup_inv_equality:
   687   "[| subgroup H G; x \<in> H |] ==> m_inv (G (| carrier := H |)) x = inv x"
   688 apply (rule_tac inv_equality [THEN sym])
   689   apply (rule group.l_inv [OF subgroup_imp_group, simplified], assumption+)
   690  apply (rule subsetD [OF subgroup.subset], assumption+)
   691 apply (rule subsetD [OF subgroup.subset], assumption)
   692 apply (rule_tac group.inv_closed [OF subgroup_imp_group, simplified], assumption+)
   693 done
   694 
   695 theorem (in group) subgroups_Inter:
   696   assumes subgr: "(!!H. H \<in> A ==> subgroup H G)"
   697     and not_empty: "A ~= {}"
   698   shows "subgroup (\<Inter>A) G"
   699 proof (rule subgroupI)
   700   from subgr [THEN subgroup.subset] and not_empty
   701   show "\<Inter>A \<subseteq> carrier G" by blast
   702 next
   703   from subgr [THEN subgroup.one_closed]
   704   show "\<Inter>A ~= {}" by blast
   705 next
   706   fix x assume "x \<in> \<Inter>A"
   707   with subgr [THEN subgroup.m_inv_closed]
   708   show "inv x \<in> \<Inter>A" by blast
   709 next
   710   fix x y assume "x \<in> \<Inter>A" "y \<in> \<Inter>A"
   711   with subgr [THEN subgroup.m_closed]
   712   show "x \<otimes> y \<in> \<Inter>A" by blast
   713 qed
   714 
   715 theorem (in group) subgroups_complete_lattice:
   716   "complete_lattice (| carrier = {H. subgroup H G}, le = op \<subseteq> |)"
   717     (is "complete_lattice ?L")
   718 proof (rule partial_order.complete_lattice_criterion1)
   719   show "partial_order ?L" by (rule subgroups_partial_order)
   720 next
   721   have "greatest ?L (carrier G) (carrier ?L)"
   722     by (unfold greatest_def) (simp add: subgroup.subset subgroup_self)
   723   then show "\<exists>G. greatest ?L G (carrier ?L)" ..
   724 next
   725   fix A
   726   assume L: "A \<subseteq> carrier ?L" and non_empty: "A ~= {}"
   727   then have Int_subgroup: "subgroup (\<Inter>A) G"
   728     by (fastsimp intro: subgroups_Inter)
   729   have "greatest ?L (\<Inter>A) (Lower ?L A)"
   730     (is "greatest ?L ?Int _")
   731   proof (rule greatest_LowerI)
   732     fix H
   733     assume H: "H \<in> A"
   734     with L have subgroupH: "subgroup H G" by auto
   735     from subgroupH have groupH: "group (G (| carrier := H |))" (is "group ?H")
   736       by (rule subgroup_imp_group)
   737     from groupH have monoidH: "monoid ?H"
   738       by (rule group.is_monoid)
   739     from H have Int_subset: "?Int \<subseteq> H" by fastsimp
   740     then show "le ?L ?Int H" by simp
   741   next
   742     fix H
   743     assume H: "H \<in> Lower ?L A"
   744     with L Int_subgroup show "le ?L H ?Int" by (fastsimp intro: Inter_greatest)
   745   next
   746     show "A \<subseteq> carrier ?L" by (rule L)
   747   next
   748     show "?Int \<in> carrier ?L" by simp (rule Int_subgroup)
   749   qed
   750   then show "\<exists>I. greatest ?L I (Lower ?L A)" ..
   751 qed
   752 
   753 end