src/HOL/Hyperreal/Filter.thy
author ballarin
Tue Jun 20 15:53:44 2006 +0200 (2006-06-20)
changeset 19931 fb32b43e7f80
parent 17332 4910cf8c0cd2
child 19984 29bb4659f80a
permissions -rw-r--r--
Restructured locales with predicates: import is now an interpretation.
New method intro_locales.
     1 (*  Title       : Filter.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     Conversion to locales by Brian Huffman, 2005
     7 *) 
     8 
     9 header {* Filters and Ultrafilters *}
    10 
    11 theory Filter
    12 imports Zorn
    13 begin
    14 
    15 subsection {* Definitions and basic properties *}
    16 
    17 subsubsection {* Filters *}
    18 
    19 locale filter =
    20   fixes F :: "'a set set"
    21   assumes UNIV [iff]:  "UNIV \<in> F"
    22   assumes empty [iff]: "{} \<notin> F"
    23   assumes Int:         "\<lbrakk>u \<in> F; v \<in> F\<rbrakk> \<Longrightarrow> u \<inter> v \<in> F"
    24   assumes subset:      "\<lbrakk>u \<in> F; u \<subseteq> v\<rbrakk> \<Longrightarrow> v \<in> F"
    25 
    26 lemma (in filter) memD: "A \<in> F \<Longrightarrow> - A \<notin> F"
    27 proof
    28   assume "A \<in> F" and "- A \<in> F"
    29   hence "A \<inter> (- A) \<in> F" by (rule Int)
    30   thus "False" by simp
    31 qed
    32 
    33 lemma (in filter) not_memI: "- A \<in> F \<Longrightarrow> A \<notin> F"
    34 by (drule memD, simp)
    35 
    36 lemma (in filter) Int_iff: "(x \<inter> y \<in> F) = (x \<in> F \<and> y \<in> F)"
    37 by (auto elim: subset intro: Int)
    38 
    39 subsubsection {* Ultrafilters *}
    40 
    41 locale ultrafilter = filter +
    42   assumes ultra: "A \<in> F \<or> - A \<in> F"
    43 
    44 lemma (in ultrafilter) memI: "- A \<notin> F \<Longrightarrow> A \<in> F"
    45 by (cut_tac ultra [of A], simp)
    46 
    47 lemma (in ultrafilter) not_memD: "A \<notin> F \<Longrightarrow> - A \<in> F"
    48 by (rule memI, simp)
    49 
    50 lemma (in ultrafilter) not_mem_iff: "(A \<notin> F) = (- A \<in> F)"
    51 by (rule iffI [OF not_memD not_memI])
    52 
    53 lemma (in ultrafilter) Compl_iff: "(- A \<in> F) = (A \<notin> F)"
    54 by (rule iffI [OF not_memI not_memD])
    55 
    56 lemma (in ultrafilter) Un_iff: "(x \<union> y \<in> F) = (x \<in> F \<or> y \<in> F)"
    57  apply (rule iffI)
    58   apply (erule contrapos_pp)
    59   apply (simp add: Int_iff not_mem_iff)
    60  apply (auto elim: subset)
    61 done
    62 
    63 subsubsection {* Free Ultrafilters *}
    64 
    65 locale freeultrafilter = ultrafilter +
    66   assumes infinite: "A \<in> F \<Longrightarrow> infinite A"
    67 
    68 lemma (in freeultrafilter) finite: "finite A \<Longrightarrow> A \<notin> F"
    69 by (erule contrapos_pn, erule infinite)
    70 
    71 lemma (in freeultrafilter) filter: "filter F" by intro_locales
    72 
    73 lemma (in freeultrafilter) ultrafilter: "ultrafilter F"
    74   by intro_locales
    75 
    76 
    77 subsection {* Collect properties *}
    78 
    79 lemma (in filter) Collect_ex:
    80   "({n. \<exists>x. P n x} \<in> F) = (\<exists>X. {n. P n (X n)} \<in> F)"
    81 proof
    82   assume "{n. \<exists>x. P n x} \<in> F"
    83   hence "{n. P n (SOME x. P n x)} \<in> F"
    84     by (auto elim: someI subset)
    85   thus "\<exists>X. {n. P n (X n)} \<in> F" by fast
    86 next
    87   show "\<exists>X. {n. P n (X n)} \<in> F \<Longrightarrow> {n. \<exists>x. P n x} \<in> F"
    88     by (auto elim: subset)
    89 qed
    90 
    91 lemma (in filter) Collect_conj:
    92   "({n. P n \<and> Q n} \<in> F) = ({n. P n} \<in> F \<and> {n. Q n} \<in> F)"
    93 by (subst Collect_conj_eq, rule Int_iff)
    94 
    95 lemma (in ultrafilter) Collect_not:
    96   "({n. \<not> P n} \<in> F) = ({n. P n} \<notin> F)"
    97 by (subst Collect_neg_eq, rule Compl_iff)
    98 
    99 lemma (in ultrafilter) Collect_disj:
   100   "({n. P n \<or> Q n} \<in> F) = ({n. P n} \<in> F \<or> {n. Q n} \<in> F)"
   101 by (subst Collect_disj_eq, rule Un_iff)
   102 
   103 lemma (in ultrafilter) Collect_all:
   104   "({n. \<forall>x. P n x} \<in> F) = (\<forall>X. {n. P n (X n)} \<in> F)"
   105 apply (rule Not_eq_iff [THEN iffD1])
   106 apply (simp add: Collect_not [symmetric])
   107 apply (rule Collect_ex)
   108 done
   109 
   110 subsection {* Maximal filter = Ultrafilter *}
   111 
   112 text {*
   113    A filter F is an ultrafilter iff it is a maximal filter,
   114    i.e. whenever G is a filter and @{term "F \<subseteq> G"} then @{term "F = G"}
   115 *}
   116 text {*
   117   Lemmas that shows existence of an extension to what was assumed to
   118   be a maximal filter. Will be used to derive contradiction in proof of
   119   property of ultrafilter.
   120 *}
   121 
   122 lemma extend_lemma1: "UNIV \<in> F \<Longrightarrow> A \<in> {X. \<exists>f\<in>F. A \<inter> f \<subseteq> X}"
   123 by blast
   124 
   125 lemma extend_lemma2: "F \<subseteq> {X. \<exists>f\<in>F. A \<inter> f \<subseteq> X}"
   126 by blast
   127 
   128 lemma (in filter) extend_filter:
   129 assumes A: "- A \<notin> F"
   130 shows "filter {X. \<exists>f\<in>F. A \<inter> f \<subseteq> X}" (is "filter ?X")
   131 proof (rule filter.intro)
   132   show "UNIV \<in> ?X" by blast
   133 next
   134   show "{} \<notin> ?X"
   135   proof (clarify)
   136     fix f assume f: "f \<in> F" and Af: "A \<inter> f \<subseteq> {}"
   137     from Af have fA: "f \<subseteq> - A" by blast
   138     from f fA have "- A \<in> F" by (rule subset)
   139     with A show "False" by simp
   140   qed
   141 next
   142   fix u and v
   143   assume u: "u \<in> ?X" and v: "v \<in> ?X"
   144   from u obtain f where f: "f \<in> F" and Af: "A \<inter> f \<subseteq> u" by blast
   145   from v obtain g where g: "g \<in> F" and Ag: "A \<inter> g \<subseteq> v" by blast
   146   from f g have fg: "f \<inter> g \<in> F" by (rule Int)
   147   from Af Ag have Afg: "A \<inter> (f \<inter> g) \<subseteq> u \<inter> v" by blast
   148   from fg Afg show "u \<inter> v \<in> ?X" by blast
   149 next
   150   fix u and v
   151   assume uv: "u \<subseteq> v" and u: "u \<in> ?X"
   152   from u obtain f where f: "f \<in> F" and Afu: "A \<inter> f \<subseteq> u" by blast
   153   from Afu uv have Afv: "A \<inter> f \<subseteq> v" by blast
   154   from f Afv have "\<exists>f\<in>F. A \<inter> f \<subseteq> v" by blast
   155   thus "v \<in> ?X" by simp
   156 qed
   157 
   158 lemma (in filter) max_filter_ultrafilter:
   159 assumes max: "\<And>G. \<lbrakk>filter G; F \<subseteq> G\<rbrakk> \<Longrightarrow> F = G"
   160 shows "ultrafilter_axioms F"
   161 proof (rule ultrafilter_axioms.intro)
   162   fix A show "A \<in> F \<or> - A \<in> F"
   163   proof (rule disjCI)
   164     let ?X = "{X. \<exists>f\<in>F. A \<inter> f \<subseteq> X}"
   165     assume AF: "- A \<notin> F"
   166     from AF have X: "filter ?X" by (rule extend_filter)
   167     from UNIV have AX: "A \<in> ?X" by (rule extend_lemma1)
   168     have FX: "F \<subseteq> ?X" by (rule extend_lemma2)
   169     from X FX have "F = ?X" by (rule max)
   170     with AX show "A \<in> F" by simp
   171   qed
   172 qed
   173 
   174 lemma (in ultrafilter) max_filter:
   175 assumes G: "filter G" and sub: "F \<subseteq> G" shows "F = G"
   176 proof
   177   show "F \<subseteq> G" .
   178   show "G \<subseteq> F"
   179   proof
   180     fix A assume A: "A \<in> G"
   181     from G A have "- A \<notin> G" by (rule filter.memD)
   182     with sub have B: "- A \<notin> F" by blast
   183     thus "A \<in> F" by (rule memI)
   184   qed
   185 qed
   186 
   187 subsection {* Ultrafilter Theorem *}
   188 
   189 text "A locale makes proof of ultrafilter Theorem more modular"
   190 locale (open) UFT =
   191   fixes   frechet :: "'a set set"
   192   and     superfrechet :: "'a set set set"
   193 
   194   assumes infinite_UNIV: "infinite (UNIV :: 'a set)"
   195 
   196   defines frechet_def: "frechet \<equiv> {A. finite (- A)}"
   197   and     superfrechet_def: "superfrechet \<equiv> {G. filter G \<and> frechet \<subseteq> G}"
   198 
   199 lemma (in UFT) superfrechetI:
   200   "\<lbrakk>filter G; frechet \<subseteq> G\<rbrakk> \<Longrightarrow> G \<in> superfrechet"
   201 by (simp add: superfrechet_def)
   202 
   203 lemma (in UFT) superfrechetD1:
   204   "G \<in> superfrechet \<Longrightarrow> filter G"
   205 by (simp add: superfrechet_def)
   206 
   207 lemma (in UFT) superfrechetD2:
   208   "G \<in> superfrechet \<Longrightarrow> frechet \<subseteq> G"
   209 by (simp add: superfrechet_def)
   210 
   211 text {* A few properties of free filters *}
   212 
   213 lemma filter_cofinite:
   214 assumes inf: "infinite (UNIV :: 'a set)"
   215 shows "filter {A:: 'a set. finite (- A)}" (is "filter ?F")
   216 proof (rule filter.intro)
   217   show "UNIV \<in> ?F" by simp
   218 next
   219   show "{} \<notin> ?F" by simp
   220 next
   221   fix u v assume "u \<in> ?F" and "v \<in> ?F"
   222   thus "u \<inter> v \<in> ?F" by simp
   223 next
   224   fix u v assume uv: "u \<subseteq> v" and u: "u \<in> ?F"
   225   from uv have vu: "- v \<subseteq> - u" by simp
   226   from u show "v \<in> ?F"
   227     by (simp add: finite_subset [OF vu])
   228 qed
   229 
   230 text {*
   231    We prove: 1. Existence of maximal filter i.e. ultrafilter;
   232              2. Freeness property i.e ultrafilter is free.
   233              Use a locale to prove various lemmas and then 
   234              export main result: The ultrafilter Theorem
   235 *}
   236 
   237 lemma (in UFT) filter_frechet: "filter frechet"
   238 by (unfold frechet_def, rule filter_cofinite [OF infinite_UNIV])
   239 
   240 lemma (in UFT) frechet_in_superfrechet: "frechet \<in> superfrechet"
   241 by (rule superfrechetI [OF filter_frechet subset_refl])
   242 
   243 lemma (in UFT) lemma_mem_chain_filter:
   244   "\<lbrakk>c \<in> chain superfrechet; x \<in> c\<rbrakk> \<Longrightarrow> filter x"
   245 by (unfold chain_def superfrechet_def, blast)
   246 
   247 
   248 subsubsection {* Unions of chains of superfrechets *}
   249 
   250 text "In this section we prove that superfrechet is closed
   251 with respect to unions of non-empty chains. We must show
   252   1) Union of a chain is a filter,
   253   2) Union of a chain contains frechet.
   254 
   255 Number 2 is trivial, but 1 requires us to prove all the filter rules."
   256 
   257 lemma (in UFT) Union_chain_UNIV:
   258 "\<lbrakk>c \<in> chain superfrechet; c \<noteq> {}\<rbrakk> \<Longrightarrow> UNIV \<in> \<Union>c"
   259 proof -
   260   assume 1: "c \<in> chain superfrechet" and 2: "c \<noteq> {}"
   261   from 2 obtain x where 3: "x \<in> c" by blast
   262   from 1 3 have "filter x" by (rule lemma_mem_chain_filter)
   263   hence "UNIV \<in> x" by (rule filter.UNIV)
   264   with 3 show "UNIV \<in> \<Union>c" by blast
   265 qed
   266 
   267 lemma (in UFT) Union_chain_empty:
   268 "c \<in> chain superfrechet \<Longrightarrow> {} \<notin> \<Union>c"
   269 proof
   270   assume 1: "c \<in> chain superfrechet" and 2: "{} \<in> \<Union>c"
   271   from 2 obtain x where 3: "x \<in> c" and 4: "{} \<in> x" ..
   272   from 1 3 have "filter x" by (rule lemma_mem_chain_filter)
   273   hence "{} \<notin> x" by (rule filter.empty)
   274   with 4 show "False" by simp
   275 qed
   276 
   277 lemma (in UFT) Union_chain_Int:
   278 "\<lbrakk>c \<in> chain superfrechet; u \<in> \<Union>c; v \<in> \<Union>c\<rbrakk> \<Longrightarrow> u \<inter> v \<in> \<Union>c"
   279 proof -
   280   assume c: "c \<in> chain superfrechet"
   281   assume "u \<in> \<Union>c"
   282     then obtain x where ux: "u \<in> x" and xc: "x \<in> c" ..
   283   assume "v \<in> \<Union>c"
   284     then obtain y where vy: "v \<in> y" and yc: "y \<in> c" ..
   285   from c xc yc have "x \<subseteq> y \<or> y \<subseteq> x" by (rule chainD)
   286   with xc yc have xyc: "x \<union> y \<in> c"
   287     by (auto simp add: Un_absorb1 Un_absorb2)
   288   with c have fxy: "filter (x \<union> y)" by (rule lemma_mem_chain_filter)
   289   from ux have uxy: "u \<in> x \<union> y" by simp
   290   from vy have vxy: "v \<in> x \<union> y" by simp
   291   from fxy uxy vxy have "u \<inter> v \<in> x \<union> y" by (rule filter.Int)
   292   with xyc show "u \<inter> v \<in> \<Union>c" ..
   293 qed
   294 
   295 lemma (in UFT) Union_chain_subset:
   296 "\<lbrakk>c \<in> chain superfrechet; u \<in> \<Union>c; u \<subseteq> v\<rbrakk> \<Longrightarrow> v \<in> \<Union>c"
   297 proof -
   298   assume c: "c \<in> chain superfrechet"
   299      and u: "u \<in> \<Union>c" and uv: "u \<subseteq> v"
   300   from u obtain x where ux: "u \<in> x" and xc: "x \<in> c" ..
   301   from c xc have fx: "filter x" by (rule lemma_mem_chain_filter)
   302   from fx ux uv have vx: "v \<in> x" by (rule filter.subset)
   303   with xc show "v \<in> \<Union>c" ..
   304 qed
   305 
   306 lemma (in UFT) Union_chain_filter:
   307 assumes "c \<in> chain superfrechet" and "c \<noteq> {}"
   308 shows "filter (\<Union>c)"
   309 proof (rule filter.intro)
   310   show "UNIV \<in> \<Union>c" by (rule Union_chain_UNIV)
   311 next
   312   show "{} \<notin> \<Union>c" by (rule Union_chain_empty)
   313 next
   314   fix u v assume "u \<in> \<Union>c" and "v \<in> \<Union>c"
   315   show "u \<inter> v \<in> \<Union>c" by (rule Union_chain_Int)
   316 next
   317   fix u v assume "u \<in> \<Union>c" and "u \<subseteq> v"
   318   show "v \<in> \<Union>c" by (rule Union_chain_subset)
   319 qed
   320 
   321 lemma (in UFT) lemma_mem_chain_frechet_subset:
   322   "\<lbrakk>c \<in> chain superfrechet; x \<in> c\<rbrakk> \<Longrightarrow> frechet \<subseteq> x"
   323 by (unfold superfrechet_def chain_def, blast)
   324 
   325 lemma (in UFT) Union_chain_superfrechet:
   326   "\<lbrakk>c \<noteq> {}; c \<in> chain superfrechet\<rbrakk> \<Longrightarrow> \<Union>c \<in> superfrechet"
   327 proof (rule superfrechetI)
   328   assume 1: "c \<in> chain superfrechet" and 2: "c \<noteq> {}"
   329   thus "filter (\<Union>c)" by (rule Union_chain_filter)
   330   from 2 obtain x where 3: "x \<in> c" by blast
   331   from 1 3 have "frechet \<subseteq> x" by (rule lemma_mem_chain_frechet_subset)
   332   also from 3 have "x \<subseteq> \<Union>c" by blast
   333   finally show "frechet \<subseteq> \<Union>c" .
   334 qed
   335 
   336 subsubsection {* Existence of free ultrafilter *}
   337 
   338 lemma (in UFT) max_cofinite_filter_Ex:
   339   "\<exists>U\<in>superfrechet. \<forall>G\<in>superfrechet. U \<subseteq> G \<longrightarrow> U = G"
   340 proof (rule Zorn_Lemma2 [rule_format])
   341   fix c assume c: "c \<in> chain superfrechet"
   342   show "\<exists>U\<in>superfrechet. \<forall>G\<in>c. G \<subseteq> U" (is "?U")
   343   proof (cases)
   344     assume "c = {}"
   345     with frechet_in_superfrechet show "?U" by blast
   346   next
   347     assume A: "c \<noteq> {}"
   348     from A c have "\<Union>c \<in> superfrechet"
   349       by (rule Union_chain_superfrechet)
   350     thus "?U" by blast
   351   qed
   352 qed
   353 
   354 lemma (in UFT) mem_superfrechet_all_infinite:
   355   "\<lbrakk>U \<in> superfrechet; A \<in> U\<rbrakk> \<Longrightarrow> infinite A"
   356 proof
   357   assume U: "U \<in> superfrechet" and A: "A \<in> U" and fin: "finite A"
   358   from U have fil: "filter U" and fre: "frechet \<subseteq> U"
   359     by (simp_all add: superfrechet_def)
   360   from fin have "- A \<in> frechet" by (simp add: frechet_def)
   361   with fre have cA: "- A \<in> U" by (rule subsetD)
   362   from fil A cA have "A \<inter> - A \<in> U" by (rule filter.Int)
   363   with fil show "False" by (simp add: filter.empty)
   364 qed
   365 
   366 text {* There exists a free ultrafilter on any infinite set *}
   367 
   368 lemma (in UFT) freeultrafilter_ex:
   369   "\<exists>U::'a set set. freeultrafilter U"
   370 proof -
   371   from max_cofinite_filter_Ex obtain U
   372     where U: "U \<in> superfrechet"
   373       and max [rule_format]: "\<forall>G\<in>superfrechet. U \<subseteq> G \<longrightarrow> U = G" ..
   374   from U have fil: "filter U" by (rule superfrechetD1)
   375   from U have fre: "frechet \<subseteq> U" by (rule superfrechetD2)
   376   have ultra: "ultrafilter_axioms U"
   377   proof (rule filter.max_filter_ultrafilter [OF fil])
   378     fix G assume G: "filter G" and UG: "U \<subseteq> G"
   379     from fre UG have "frechet \<subseteq> G" by simp
   380     with G have "G \<in> superfrechet" by (rule superfrechetI)
   381     from this UG show "U = G" by (rule max)
   382   qed
   383   have free: "freeultrafilter_axioms U"
   384   proof (rule freeultrafilter_axioms.intro)
   385     fix A assume "A \<in> U"
   386     with U show "infinite A" by (rule mem_superfrechet_all_infinite)
   387   qed
   388   from fil ultra free have "freeultrafilter U"
   389     by (rule freeultrafilter.intro [OF ultrafilter.intro])
   390     (* FIXME: intro_locales should use chained facts *)
   391   thus ?thesis ..
   392 qed
   393 
   394 lemmas freeultrafilter_Ex = UFT.freeultrafilter_ex
   395 
   396 end