src/Tools/nbe.ML
author wenzelm
Wed Dec 31 18:53:17 2008 +0100 (2008-12-31)
changeset 29272 fb3ccf499df5
parent 28706 3fef773ae6b1
child 30022 1d8b8fa19074
permissions -rw-r--r--
use regular Term.add_XXX etc.;
     1 (*  Title:      Tools/nbe.ML
     2     Authors:    Klaus Aehlig, LMU Muenchen; Tobias Nipkow, Florian Haftmann, TU Muenchen
     3 
     4 Normalization by evaluation, based on generic code generator.
     5 *)
     6 
     7 signature NBE =
     8 sig
     9   val norm_conv: cterm -> thm
    10   val norm_term: theory -> term -> term
    11 
    12   datatype Univ =
    13       Const of int * Univ list               (*named (uninterpreted) constants*)
    14     | Free of string * Univ list             (*free (uninterpreted) variables*)
    15     | DFree of string * int                  (*free (uninterpreted) dictionary parameters*)
    16     | BVar of int * Univ list
    17     | Abs of (int * (Univ list -> Univ)) * Univ list
    18   val apps: Univ -> Univ list -> Univ        (*explicit applications*)
    19   val abss: int -> (Univ list -> Univ) -> Univ
    20                                              (*abstractions as closures*)
    21   val same: Univ -> Univ -> bool
    22 
    23   val univs_ref: (unit -> Univ list -> Univ list) option ref
    24   val trace: bool ref
    25 
    26   val setup: theory -> theory
    27 end;
    28 
    29 structure Nbe: NBE =
    30 struct
    31 
    32 (* generic non-sense *)
    33 
    34 val trace = ref false;
    35 fun tracing f x = if !trace then (Output.tracing (f x); x) else x;
    36 
    37 
    38 (** the semantical universe **)
    39 
    40 (*
    41    Functions are given by their semantical function value. To avoid
    42    trouble with the ML-type system, these functions have the most
    43    generic type, that is "Univ list -> Univ". The calling convention is
    44    that the arguments come as a list, the last argument first. In
    45    other words, a function call that usually would look like
    46 
    47    f x_1 x_2 ... x_n   or   f(x_1,x_2, ..., x_n)
    48 
    49    would be in our convention called as
    50 
    51               f [x_n,..,x_2,x_1]
    52 
    53    Moreover, to handle functions that are still waiting for some
    54    arguments we have additionally a list of arguments collected to far
    55    and the number of arguments we're still waiting for.
    56 *)
    57 
    58 datatype Univ =
    59     Const of int * Univ list           (*named (uninterpreted) constants*)
    60   | Free of string * Univ list         (*free variables*)
    61   | DFree of string * int              (*free (uninterpreted) dictionary parameters*)
    62   | BVar of int * Univ list            (*bound variables, named*)
    63   | Abs of (int * (Univ list -> Univ)) * Univ list
    64                                        (*abstractions as closures*);
    65 
    66 fun same (Const (k, xs)) (Const (l, ys)) = k = l andalso sames xs ys
    67   | same (Free (s, xs)) (Free (t, ys)) = s = t andalso sames xs ys
    68   | same (DFree (s, k)) (DFree (t, l)) = s = t andalso k = l
    69   | same (BVar (k, xs)) (BVar (l, ys)) = k = l andalso sames xs ys
    70   | same _ _ = false
    71 and sames xs ys = length xs = length ys andalso forall (uncurry same) (xs ~~ ys);
    72 
    73 (* constructor functions *)
    74 
    75 fun abss n f = Abs ((n, f), []);
    76 fun apps (Abs ((n, f), xs)) ys = let val k = n - length ys in
    77       case int_ord (k, 0)
    78        of EQUAL => f (ys @ xs)
    79         | LESS => let val (zs, ws) = chop (~ k) ys in apps (f (ws @ xs)) zs end
    80         | GREATER => Abs ((k, f), ys @ xs) (*note: reverse convention also for apps!*)
    81       end
    82   | apps (Const (name, xs)) ys = Const (name, ys @ xs)
    83   | apps (Free (name, xs)) ys = Free (name, ys @ xs)
    84   | apps (BVar (n, xs)) ys = BVar (n, ys @ xs);
    85 
    86 
    87 (** assembling and compiling ML code from terms **)
    88 
    89 (* abstract ML syntax *)
    90 
    91 infix 9 `$` `$$`;
    92 fun e1 `$` e2 = "(" ^ e1 ^ " " ^ e2 ^ ")";
    93 fun e `$$` [] = e
    94   | e `$$` es = "(" ^ e ^ " " ^ space_implode " " es ^ ")";
    95 fun ml_abs v e = "(fn " ^ v ^ " => " ^ e ^ ")";
    96 
    97 fun ml_cases t cs =
    98   "(case " ^ t ^ " of " ^ space_implode " | " (map (fn (p, t) => p ^ " => " ^ t) cs) ^ ")";
    99 fun ml_Let d e = "let\n" ^ d ^ " in " ^ e ^ " end";
   100 fun ml_as v t = "(" ^ v ^ " as " ^ t ^ ")";
   101 
   102 fun ml_and [] = "true"
   103   | ml_and [x] = x
   104   | ml_and xs = "(" ^ space_implode " andalso " xs ^ ")";
   105 fun ml_if b x y = "(if " ^ b ^ " then " ^ x ^ " else " ^ y ^ ")";
   106 
   107 fun ml_list es = "[" ^ commas es ^ "]";
   108 
   109 fun ml_fundefs ([(name, [([], e)])]) =
   110       "val " ^ name ^ " = " ^ e ^ "\n"
   111   | ml_fundefs (eqs :: eqss) =
   112       let
   113         fun fundef (name, eqs) =
   114           let
   115             fun eqn (es, e) = name ^ " " ^ space_implode " " es ^ " = " ^ e
   116           in space_implode "\n  | " (map eqn eqs) end;
   117       in
   118         (prefix "fun " o fundef) eqs :: map (prefix "and " o fundef) eqss
   119         |> cat_lines
   120         |> suffix "\n"
   121       end;
   122 
   123 (* nbe specific syntax and sandbox communication *)
   124 
   125 val univs_ref = ref (NONE : (unit -> Univ list -> Univ list) option);
   126 
   127 local
   128   val prefix =      "Nbe.";
   129   val name_ref =    prefix ^ "univs_ref";
   130   val name_const =  prefix ^ "Const";
   131   val name_abss =   prefix ^ "abss";
   132   val name_apps =   prefix ^ "apps";
   133   val name_same =   prefix ^ "same";
   134 in
   135 
   136 val univs_cookie = (name_ref, univs_ref);
   137 
   138 fun nbe_fun 0 "" = "nbe_value"
   139   | nbe_fun i c = "c_" ^ translate_string (fn "." => "_" | c => c) c ^ "_" ^ string_of_int i;
   140 fun nbe_dict v n = "d_" ^ v ^ "_" ^ string_of_int n;
   141 fun nbe_bound v = "v_" ^ v;
   142 fun nbe_default v = "w_" ^ v;
   143 
   144 (*note: these three are the "turning spots" where proper argument order is established!*)
   145 fun nbe_apps t [] = t
   146   | nbe_apps t ts = name_apps `$$` [t, ml_list (rev ts)];
   147 fun nbe_apps_local i c ts = nbe_fun i c `$` ml_list (rev ts);
   148 fun nbe_apps_constr idx_of c ts =
   149   let
   150     val c' = if !trace then string_of_int (idx_of c) ^ " (*" ^ c ^ "*)"
   151       else string_of_int (idx_of c);
   152   in name_const `$` ("(" ^ c' ^ ", " ^ ml_list (rev ts) ^ ")") end;
   153 
   154 fun nbe_abss 0 f = f `$` ml_list []
   155   | nbe_abss n f = name_abss `$$` [string_of_int n, f];
   156 
   157 fun nbe_same v1 v2 = "(" ^ name_same ^ " " ^ nbe_bound v1 ^ " " ^ nbe_bound v2 ^ ")";
   158 
   159 end;
   160 
   161 open Basic_Code_Thingol;
   162 
   163 (* code generation *)
   164 
   165 fun assemble_eqnss idx_of deps eqnss =
   166   let
   167     fun prep_eqns (c, (vs, eqns)) =
   168       let
   169         val dicts = maps (fn (v, sort) => map_index (nbe_dict v o fst) sort) vs;
   170         val num_args = length dicts + ((length o fst o hd) eqns);
   171       in (c, (num_args, (dicts, eqns))) end;
   172     val eqnss' = map prep_eqns eqnss;
   173 
   174     fun assemble_constapp c dss ts = 
   175       let
   176         val ts' = (maps o map) assemble_idict dss @ ts;
   177       in case AList.lookup (op =) eqnss' c
   178        of SOME (num_args, _) => if num_args <= length ts'
   179             then let val (ts1, ts2) = chop num_args ts'
   180             in nbe_apps (nbe_apps_local 0 c ts1) ts2
   181             end else nbe_apps (nbe_abss num_args (nbe_fun 0 c)) ts'
   182         | NONE => if member (op =) deps c
   183             then nbe_apps (nbe_fun 0 c) ts'
   184             else nbe_apps_constr idx_of c ts'
   185       end
   186     and assemble_idict (DictConst (inst, dss)) =
   187           assemble_constapp inst dss []
   188       | assemble_idict (DictVar (supers, (v, (n, _)))) =
   189           fold_rev (fn super => assemble_constapp super [] o single) supers (nbe_dict v n);
   190 
   191     fun assemble_iterm constapp =
   192       let
   193         fun of_iterm match_cont t =
   194           let
   195             val (t', ts) = Code_Thingol.unfold_app t
   196           in of_iapp match_cont t' (fold_rev (cons o of_iterm NONE) ts []) end
   197         and of_iapp match_cont (IConst (c, (dss, _))) ts = constapp c dss ts
   198           | of_iapp match_cont (IVar v) ts = nbe_apps (nbe_bound v) ts
   199           | of_iapp match_cont ((v, _) `|-> t) ts =
   200               nbe_apps (nbe_abss 1 (ml_abs (ml_list [nbe_bound v]) (of_iterm NONE t))) ts
   201           | of_iapp match_cont (ICase (((t, _), cs), t0)) ts =
   202               nbe_apps (ml_cases (of_iterm NONE t)
   203                 (map (fn (p, t) => (of_iterm NONE p, of_iterm match_cont t)) cs
   204                   @ [("_", case match_cont of SOME s => s | NONE => of_iterm NONE t0)])) ts
   205       in of_iterm end;
   206 
   207     fun subst_nonlin_vars args =
   208       let
   209         val vs = (fold o Code_Thingol.fold_varnames)
   210           (fn v => AList.map_default (op =) (v, 0) (curry (op +) 1)) args [];
   211         val names = Name.make_context (map fst vs);
   212         fun declare v k ctxt = let val vs = Name.invents ctxt v k
   213           in (vs, fold Name.declare vs ctxt) end;
   214         val (vs_renames, _) = fold_map (fn (v, k) => if k > 1
   215           then declare v (k - 1) #>> (fn vs => (v, vs))
   216           else pair (v, [])) vs names;
   217         val samepairs = maps (fn (v, vs) => map (pair v) vs) vs_renames;
   218         fun subst_vars (t as IConst _) samepairs = (t, samepairs)
   219           | subst_vars (t as IVar v) samepairs = (case AList.lookup (op =) samepairs v
   220              of SOME v' => (IVar v', AList.delete (op =) v samepairs)
   221               | NONE => (t, samepairs))
   222           | subst_vars (t1 `$ t2) samepairs = samepairs
   223               |> subst_vars t1
   224               ||>> subst_vars t2
   225               |>> (op `$)
   226           | subst_vars (ICase (_, t)) samepairs = subst_vars t samepairs;
   227         val (args', _) = fold_map subst_vars args samepairs;
   228       in (samepairs, args') end;
   229 
   230     fun assemble_eqn c dicts default_args (i, (args, rhs)) =
   231       let
   232         val is_eval = (c = "");
   233         val default_rhs = nbe_apps_local (i+1) c (dicts @ default_args);
   234         val match_cont = if is_eval then NONE else SOME default_rhs;
   235         val assemble_arg = assemble_iterm
   236           (fn c => fn _ => fn ts => nbe_apps_constr idx_of c ts) NONE;
   237         val assemble_rhs = assemble_iterm assemble_constapp match_cont ;
   238         val (samepairs, args') = subst_nonlin_vars args;
   239         val s_args = map assemble_arg args';
   240         val s_rhs = if null samepairs then assemble_rhs rhs
   241           else ml_if (ml_and (map (uncurry nbe_same) samepairs))
   242             (assemble_rhs rhs) default_rhs;
   243         val eqns = if is_eval then
   244             [([ml_list (rev (dicts @ s_args))], s_rhs)]
   245           else
   246             [([ml_list (rev (dicts @ map2 ml_as default_args s_args))], s_rhs),
   247               ([ml_list (rev (dicts @ default_args))], default_rhs)]
   248       in (nbe_fun i c, eqns) end;
   249 
   250     fun assemble_eqns (c, (num_args, (dicts, eqns))) =
   251       let
   252         val default_args = map nbe_default
   253           (Name.invent_list [] "a" (num_args - length dicts));
   254         val eqns' = map_index (assemble_eqn c dicts default_args) eqns
   255           @ (if c = "" then [] else [(nbe_fun (length eqns) c,
   256             [([ml_list (rev (dicts @ default_args))],
   257               nbe_apps_constr idx_of c (dicts @ default_args))])]);
   258       in (eqns', nbe_abss num_args (nbe_fun 0 c)) end;
   259 
   260     val (fun_vars, fun_vals) = map_split assemble_eqns eqnss';
   261     val deps_vars = ml_list (map (nbe_fun 0) deps);
   262   in ml_abs deps_vars (ml_Let (ml_fundefs (flat fun_vars)) (ml_list fun_vals)) end;
   263 
   264 (* code compilation *)
   265 
   266 fun compile_eqnss _ gr raw_deps [] = []
   267   | compile_eqnss ctxt gr raw_deps eqnss =
   268       let
   269         val (deps, deps_vals) = split_list (map_filter
   270           (fn dep => Option.map (fn univ => (dep, univ)) (fst ((Graph.get_node gr dep)))) raw_deps);
   271         val idx_of = raw_deps
   272           |> map (fn dep => (dep, snd (Graph.get_node gr dep)))
   273           |> AList.lookup (op =)
   274           |> (fn f => the o f);
   275         val s = assemble_eqnss idx_of deps eqnss;
   276         val cs = map fst eqnss;
   277       in
   278         s
   279         |> tracing (fn s => "\n--- code to be evaluated:\n" ^ s)
   280         |> ML_Context.evaluate ctxt
   281             (Output.tracing o enclose "\n---compiler echo:\n" "\n---\n",
   282             Output.tracing o enclose "\n--- compiler echo (with error):\n" "\n---\n")
   283             (!trace) univs_cookie
   284         |> (fn f => f deps_vals)
   285         |> (fn univs => cs ~~ univs)
   286       end;
   287 
   288 (* preparing function equations *)
   289 
   290 fun eqns_of_stmt (_, Code_Thingol.Fun (_, (_, []))) =
   291       []
   292   | eqns_of_stmt (const, Code_Thingol.Fun (_, ((vs, _), eqns))) =
   293       [(const, (vs, map fst eqns))]
   294   | eqns_of_stmt (_, Code_Thingol.Datatypecons _) =
   295       []
   296   | eqns_of_stmt (_, Code_Thingol.Datatype _) =
   297       []
   298   | eqns_of_stmt (class, Code_Thingol.Class (_, (v, (superclasses, classops)))) =
   299       let
   300         val names = map snd superclasses @ map fst classops;
   301         val params = Name.invent_list [] "d" (length names);
   302         fun mk (k, name) =
   303           (name, ([(v, [])],
   304             [([IConst (class, ([], [])) `$$ map IVar params], IVar (nth params k))]));
   305       in map_index mk names end
   306   | eqns_of_stmt (_, Code_Thingol.Classrel _) =
   307       []
   308   | eqns_of_stmt (_, Code_Thingol.Classparam _) =
   309       []
   310   | eqns_of_stmt (inst, Code_Thingol.Classinst ((class, (_, arities)), (superinsts, instops))) =
   311       [(inst, (arities, [([], IConst (class, ([], [])) `$$
   312         map (fn (_, (_, (inst, dicts))) => IConst (inst, (dicts, []))) superinsts
   313         @ map (IConst o snd o fst) instops)]))];
   314 
   315 fun compile_stmts ctxt stmts_deps =
   316   let
   317     val names = map (fst o fst) stmts_deps;
   318     val names_deps = map (fn ((name, _), deps) => (name, deps)) stmts_deps;
   319     val eqnss = maps (eqns_of_stmt o fst) stmts_deps;
   320     val refl_deps = names_deps
   321       |> maps snd
   322       |> distinct (op =)
   323       |> fold (insert (op =)) names;
   324     fun new_node name (gr, (maxidx, idx_tab)) = if can (Graph.get_node gr) name
   325       then (gr, (maxidx, idx_tab))
   326       else (Graph.new_node (name, (NONE, maxidx)) gr,
   327         (maxidx + 1, Inttab.update_new (maxidx, name) idx_tab));
   328     fun compile gr = eqnss
   329       |> compile_eqnss ctxt gr refl_deps
   330       |> rpair gr;
   331   in
   332     fold new_node refl_deps
   333     #> apfst (fold (fn (name, deps) => fold (curry Graph.add_edge name) deps) names_deps
   334       #> compile
   335       #-> fold (fn (name, univ) => (Graph.map_node name o apfst) (K (SOME univ))))
   336   end;
   337 
   338 fun ensure_stmts ctxt naming program =
   339   let
   340     fun add_stmts names (gr, (maxidx, idx_tab)) = if exists ((can o Graph.get_node) gr) names
   341       then (gr, (maxidx, idx_tab))
   342       else (gr, (maxidx, idx_tab))
   343         |> compile_stmts ctxt (map (fn name => ((name, Graph.get_node program name),
   344           Graph.imm_succs program name)) names);
   345   in
   346     fold_rev add_stmts (Graph.strong_conn program)
   347     #> pair naming
   348   end;
   349 
   350 
   351 (** evaluation **)
   352 
   353 (* term evaluation *)
   354 
   355 fun eval_term ctxt gr deps ((vs, ty) : typscheme, t) =
   356   let 
   357     val frees = Code_Thingol.fold_unbound_varnames (insert (op =)) t []
   358     val frees' = map (fn v => Free (v, [])) frees;
   359     val dict_frees = maps (fn (v, sort) => map_index (curry DFree v o fst) sort) vs;
   360   in
   361     ("", (vs, [(map IVar frees, t)]))
   362     |> singleton (compile_eqnss ctxt gr deps)
   363     |> snd
   364     |> (fn t => apps t (rev (dict_frees @ frees')))
   365   end;
   366 
   367 (* reification *)
   368 
   369 fun term_of_univ thy program idx_tab t =
   370   let
   371     fun take_until f [] = []
   372       | take_until f (x::xs) = if f x then [] else x :: take_until f xs;
   373     fun is_dict (Const (idx, _)) = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   374          of Code_Thingol.Class _ => true
   375           | Code_Thingol.Classrel _ => true
   376           | Code_Thingol.Classinst _ => true
   377           | _ => false)
   378       | is_dict (DFree _) = true
   379       | is_dict _ = false;
   380     fun const_of_idx idx = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   381          of Code_Thingol.Fun (c, _) => c
   382           | Code_Thingol.Datatypecons (c, _) => c
   383           | Code_Thingol.Classparam (c, _) => c);
   384     fun of_apps bounds (t, ts) =
   385       fold_map (of_univ bounds) ts
   386       #>> (fn ts' => list_comb (t, rev ts'))
   387     and of_univ bounds (Const (idx, ts)) typidx =
   388           let
   389             val ts' = take_until is_dict ts;
   390             val c = const_of_idx idx;
   391             val (_, T) = Code.default_typscheme thy c;
   392             val T' = map_type_tvar (fn ((v, i), S) => TypeInfer.param (typidx + i) (v, [])) T;
   393             val typidx' = typidx + maxidx_of_typ T' + 1;
   394           in of_apps bounds (Term.Const (c, T'), ts') typidx' end
   395       | of_univ bounds (Free (name, ts)) typidx =
   396           of_apps bounds (Term.Free (name, dummyT), ts) typidx
   397       | of_univ bounds (BVar (n, ts)) typidx =
   398           of_apps bounds (Bound (bounds - n - 1), ts) typidx
   399       | of_univ bounds (t as Abs _) typidx =
   400           typidx
   401           |> of_univ (bounds + 1) (apps t [BVar (bounds, [])])
   402           |-> (fn t' => pair (Term.Abs ("u", dummyT, t')))
   403   in of_univ 0 t 0 |> fst end;
   404 
   405 (* function store *)
   406 
   407 structure Nbe_Functions = CodeDataFun
   408 (
   409   type T = Code_Thingol.naming * ((Univ option * int) Graph.T * (int * string Inttab.table));
   410   val empty = (Code_Thingol.empty_naming, (Graph.empty, (0, Inttab.empty)));
   411   fun purge thy cs (naming, (gr, (maxidx, idx_tab))) =
   412     let
   413       val names_delete = cs
   414         |> map_filter (Code_Thingol.lookup_const naming)
   415         |> filter (can (Graph.get_node gr))
   416         |> Graph.all_preds gr;
   417       val gr' = Graph.del_nodes names_delete gr;
   418     in (naming, (gr', (maxidx, idx_tab))) end;
   419 );
   420 
   421 (* compilation, evaluation and reification *)
   422 
   423 fun compile_eval thy naming program vs_ty_t deps =
   424   let
   425     val ctxt = ProofContext.init thy;
   426     val (_, (gr, (_, idx_tab))) =
   427       Nbe_Functions.change thy (ensure_stmts ctxt naming program o snd);
   428   in
   429     vs_ty_t
   430     |> eval_term ctxt gr deps
   431     |> term_of_univ thy program idx_tab
   432   end;
   433 
   434 (* evaluation with type reconstruction *)
   435 
   436 fun eval thy t naming program vs_ty_t deps =
   437   let
   438     fun subst_const f = map_aterms (fn t as Term.Const (c, ty) => Term.Const (f c, ty)
   439       | t => t);
   440     val subst_triv_consts = subst_const (Code_Unit.resubst_alias thy);
   441     val ty = type_of t;
   442     val type_free = AList.lookup (op =)
   443       (map (fn (s, T) => (s, Term.Free (s, T))) (Term.add_frees t []));
   444     val type_frees = Term.map_aterms
   445       (fn (t as Term.Free (s, _)) => the_default t (type_free s) | t => t);
   446     fun type_infer t =
   447       singleton (TypeInfer.infer_types (Syntax.pp_global thy) (Sign.tsig_of thy) I
   448         (try (Type.strip_sorts o Sign.the_const_type thy)) (K NONE) Name.context 0)
   449       (TypeInfer.constrain ty t);
   450     fun check_tvars t = if null (Term.add_tvars t []) then t else
   451       error ("Illegal schematic type variables in normalized term: "
   452         ^ setmp show_types true (Syntax.string_of_term_global thy) t);
   453     val string_of_term = setmp show_types true (Syntax.string_of_term_global thy);
   454   in
   455     compile_eval thy naming program vs_ty_t deps
   456     |> tracing (fn t => "Normalized:\n" ^ string_of_term t)
   457     |> subst_triv_consts
   458     |> type_frees
   459     |> tracing (fn t => "Vars typed:\n" ^ string_of_term t)
   460     |> type_infer
   461     |> tracing (fn t => "Types inferred:\n" ^ string_of_term t)
   462     |> check_tvars
   463     |> tracing (fn t => "---\n")
   464   end;
   465 
   466 (* evaluation oracle *)
   467 
   468 val (_, norm_oracle) = Context.>>> (Context.map_theory_result
   469   (Thm.add_oracle ("norm", fn (thy, t, naming, program, vs_ty_t, deps) =>
   470     Thm.cterm_of thy (Logic.mk_equals (t, eval thy t naming program vs_ty_t deps)))));
   471 
   472 fun add_triv_classes thy =
   473   let
   474     val inters = curry (Sorts.inter_sort (Sign.classes_of thy))
   475       (Code_Unit.triv_classes thy);
   476     fun map_sorts f = (map_types o map_atyps)
   477       (fn TVar (v, sort) => TVar (v, f sort)
   478         | TFree (v, sort) => TFree (v, f sort));
   479   in map_sorts inters end;
   480 
   481 fun norm_conv ct =
   482   let
   483     val thy = Thm.theory_of_cterm ct;
   484     fun evaluator' t naming program vs_ty_t deps =
   485       norm_oracle (thy, t, naming, program, vs_ty_t, deps);
   486     fun evaluator t = (add_triv_classes thy t, evaluator' t);
   487   in Code_Thingol.eval_conv thy evaluator ct end;
   488 
   489 fun norm_term thy t =
   490   let
   491     fun evaluator' t naming program vs_ty_t deps = eval thy t naming program vs_ty_t deps;
   492     fun evaluator t = (add_triv_classes thy t, evaluator' t);
   493   in (Code.postprocess_term thy o Code_Thingol.eval_term thy evaluator) t end;
   494 
   495 (* evaluation command *)
   496 
   497 fun norm_print_term ctxt modes t =
   498   let
   499     val thy = ProofContext.theory_of ctxt;
   500     val t' = norm_term thy t;
   501     val ty' = Term.type_of t';
   502     val ctxt' = Variable.auto_fixes t ctxt;
   503     val p = PrintMode.with_modes modes (fn () =>
   504       Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t'), Pretty.fbrk,
   505         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' ty')]) ();
   506   in Pretty.writeln p end;
   507 
   508 
   509 (** Isar setup **)
   510 
   511 fun norm_print_term_cmd (modes, s) state =
   512   let val ctxt = Toplevel.context_of state
   513   in norm_print_term ctxt modes (Syntax.read_term ctxt s) end;
   514 
   515 val setup =
   516   Value.add_evaluator ("nbe", norm_term o ProofContext.theory_of);
   517 
   518 local structure P = OuterParse and K = OuterKeyword in
   519 
   520 val opt_modes = Scan.optional (P.$$$ "(" |-- P.!!! (Scan.repeat1 P.xname --| P.$$$ ")")) [];
   521 
   522 val _ =
   523   OuterSyntax.improper_command "normal_form" "normalize term by evaluation" K.diag
   524     (opt_modes -- P.term >> (Toplevel.keep o norm_print_term_cmd));
   525 
   526 end;
   527 
   528 end;
   529