src/HOL/Divides.thy
author huffman
Tue Mar 27 09:54:39 2012 +0200 (2012-03-27)
changeset 47135 fb67b596067f
parent 47134 28c1db43d4d0
child 47136 5b6c5641498a
permissions -rw-r--r--
rename lemmas {div,mod}_eq -> {div,mod}_nat_unique, for consistency with minus_unique, inverse_unique, etc.
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastforce simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + comm_ring_1
   380 begin
   381 
   382 subclass ring_1_no_zero_divisors ..
   383 
   384 text {* Negation respects modular equivalence. *}
   385 
   386 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   387 proof -
   388   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   389     by (simp only: mod_div_equality)
   390   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   391     by (simp only: minus_add_distrib minus_mult_left add_ac)
   392   also have "\<dots> = (- (a mod b)) mod b"
   393     by (rule mod_mult_self1)
   394   finally show ?thesis .
   395 qed
   396 
   397 lemma mod_minus_cong:
   398   assumes "a mod b = a' mod b"
   399   shows "(- a) mod b = (- a') mod b"
   400 proof -
   401   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   402     unfolding assms ..
   403   thus ?thesis
   404     by (simp only: mod_minus_eq [symmetric])
   405 qed
   406 
   407 text {* Subtraction respects modular equivalence. *}
   408 
   409 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   410   unfolding diff_minus
   411   by (intro mod_add_cong mod_minus_cong) simp_all
   412 
   413 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   414   unfolding diff_minus
   415   by (intro mod_add_cong mod_minus_cong) simp_all
   416 
   417 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   418   unfolding diff_minus
   419   by (intro mod_add_cong mod_minus_cong) simp_all
   420 
   421 lemma mod_diff_cong:
   422   assumes "a mod c = a' mod c"
   423   assumes "b mod c = b' mod c"
   424   shows "(a - b) mod c = (a' - b') mod c"
   425   unfolding diff_minus using assms
   426   by (intro mod_add_cong mod_minus_cong)
   427 
   428 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   429 apply (case_tac "y = 0") apply simp
   430 apply (auto simp add: dvd_def)
   431 apply (subgoal_tac "-(y * k) = y * - k")
   432  apply (erule ssubst)
   433  apply (erule div_mult_self1_is_id)
   434 apply simp
   435 done
   436 
   437 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   438 apply (case_tac "y = 0") apply simp
   439 apply (auto simp add: dvd_def)
   440 apply (subgoal_tac "y * k = -y * -k")
   441  apply (erule ssubst)
   442  apply (rule div_mult_self1_is_id)
   443  apply simp
   444 apply simp
   445 done
   446 
   447 end
   448 
   449 
   450 subsection {* Division on @{typ nat} *}
   451 
   452 text {*
   453   We define @{const div} and @{const mod} on @{typ nat} by means
   454   of a characteristic relation with two input arguments
   455   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   456   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   457 *}
   458 
   459 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   460   "divmod_nat_rel m n qr \<longleftrightarrow>
   461     m = fst qr * n + snd qr \<and>
   462       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   463 
   464 text {* @{const divmod_nat_rel} is total: *}
   465 
   466 lemma divmod_nat_rel_ex:
   467   obtains q r where "divmod_nat_rel m n (q, r)"
   468 proof (cases "n = 0")
   469   case True  with that show thesis
   470     by (auto simp add: divmod_nat_rel_def)
   471 next
   472   case False
   473   have "\<exists>q r. m = q * n + r \<and> r < n"
   474   proof (induct m)
   475     case 0 with `n \<noteq> 0`
   476     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   477     then show ?case by blast
   478   next
   479     case (Suc m) then obtain q' r'
   480       where m: "m = q' * n + r'" and n: "r' < n" by auto
   481     then show ?case proof (cases "Suc r' < n")
   482       case True
   483       from m n have "Suc m = q' * n + Suc r'" by simp
   484       with True show ?thesis by blast
   485     next
   486       case False then have "n \<le> Suc r'" by auto
   487       moreover from n have "Suc r' \<le> n" by auto
   488       ultimately have "n = Suc r'" by auto
   489       with m have "Suc m = Suc q' * n + 0" by simp
   490       with `n \<noteq> 0` show ?thesis by blast
   491     qed
   492   qed
   493   with that show thesis
   494     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   495 qed
   496 
   497 text {* @{const divmod_nat_rel} is injective: *}
   498 
   499 lemma divmod_nat_rel_unique:
   500   assumes "divmod_nat_rel m n qr"
   501     and "divmod_nat_rel m n qr'"
   502   shows "qr = qr'"
   503 proof (cases "n = 0")
   504   case True with assms show ?thesis
   505     by (cases qr, cases qr')
   506       (simp add: divmod_nat_rel_def)
   507 next
   508   case False
   509   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   510   apply (rule leI)
   511   apply (subst less_iff_Suc_add)
   512   apply (auto simp add: add_mult_distrib)
   513   done
   514   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   515     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   516   moreover from this assms have "snd qr = snd qr'"
   517     by (simp add: divmod_nat_rel_def)
   518   ultimately show ?thesis by (cases qr, cases qr') simp
   519 qed
   520 
   521 text {*
   522   We instantiate divisibility on the natural numbers by
   523   means of @{const divmod_nat_rel}:
   524 *}
   525 
   526 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   527   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   528 
   529 lemma divmod_nat_rel_divmod_nat:
   530   "divmod_nat_rel m n (divmod_nat m n)"
   531 proof -
   532   from divmod_nat_rel_ex
   533     obtain qr where rel: "divmod_nat_rel m n qr" .
   534   then show ?thesis
   535   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   536 qed
   537 
   538 lemma divmod_nat_unique:
   539   assumes "divmod_nat_rel m n qr" 
   540   shows "divmod_nat m n = qr"
   541   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   542 
   543 instantiation nat :: semiring_div
   544 begin
   545 
   546 definition div_nat where
   547   "m div n = fst (divmod_nat m n)"
   548 
   549 lemma fst_divmod_nat [simp]:
   550   "fst (divmod_nat m n) = m div n"
   551   by (simp add: div_nat_def)
   552 
   553 definition mod_nat where
   554   "m mod n = snd (divmod_nat m n)"
   555 
   556 lemma snd_divmod_nat [simp]:
   557   "snd (divmod_nat m n) = m mod n"
   558   by (simp add: mod_nat_def)
   559 
   560 lemma divmod_nat_div_mod:
   561   "divmod_nat m n = (m div n, m mod n)"
   562   by (simp add: prod_eq_iff)
   563 
   564 lemma div_nat_unique:
   565   assumes "divmod_nat_rel m n (q, r)" 
   566   shows "m div n = q"
   567   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   568 
   569 lemma mod_nat_unique:
   570   assumes "divmod_nat_rel m n (q, r)" 
   571   shows "m mod n = r"
   572   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   573 
   574 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   575   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   576 
   577 lemma divmod_nat_zero:
   578   "divmod_nat m 0 = (0, m)"
   579 proof (rule divmod_nat_unique)
   580   show "divmod_nat_rel m 0 (0, m)"
   581     unfolding divmod_nat_rel_def by simp
   582 qed
   583 
   584 lemma divmod_nat_base:
   585   assumes "m < n"
   586   shows "divmod_nat m n = (0, m)"
   587 proof (rule divmod_nat_unique)
   588   show "divmod_nat_rel m n (0, m)"
   589     unfolding divmod_nat_rel_def using assms by simp
   590 qed
   591 
   592 lemma divmod_nat_step:
   593   assumes "0 < n" and "n \<le> m"
   594   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   595 proof (rule divmod_nat_unique)
   596   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   597     by (rule divmod_nat_rel)
   598   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   599     unfolding divmod_nat_rel_def using assms by auto
   600 qed
   601 
   602 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   603 
   604 lemma div_less [simp]:
   605   fixes m n :: nat
   606   assumes "m < n"
   607   shows "m div n = 0"
   608   using assms divmod_nat_base by (simp add: prod_eq_iff)
   609 
   610 lemma le_div_geq:
   611   fixes m n :: nat
   612   assumes "0 < n" and "n \<le> m"
   613   shows "m div n = Suc ((m - n) div n)"
   614   using assms divmod_nat_step by (simp add: prod_eq_iff)
   615 
   616 lemma mod_less [simp]:
   617   fixes m n :: nat
   618   assumes "m < n"
   619   shows "m mod n = m"
   620   using assms divmod_nat_base by (simp add: prod_eq_iff)
   621 
   622 lemma le_mod_geq:
   623   fixes m n :: nat
   624   assumes "n \<le> m"
   625   shows "m mod n = (m - n) mod n"
   626   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   627 
   628 instance proof -
   629   have [simp]: "\<And>n::nat. n div 0 = 0"
   630     by (simp add: div_nat_def divmod_nat_zero)
   631   have [simp]: "\<And>n::nat. 0 div n = 0"
   632   proof -
   633     fix n :: nat
   634     show "0 div n = 0"
   635       by (cases "n = 0") simp_all
   636   qed
   637   show "OFCLASS(nat, semiring_div_class)" proof
   638     fix m n :: nat
   639     show "m div n * n + m mod n = m"
   640       using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   641   next
   642     fix m n q :: nat
   643     assume "n \<noteq> 0"
   644     then show "(q + m * n) div n = m + q div n"
   645       by (induct m) (simp_all add: le_div_geq)
   646   next
   647     fix m n q :: nat
   648     assume "m \<noteq> 0"
   649     then show "(m * n) div (m * q) = n div q"
   650     proof (cases "n \<noteq> 0 \<and> q \<noteq> 0")
   651       case False then show ?thesis by auto
   652     next
   653       case True with `m \<noteq> 0`
   654         have "m > 0" and "n > 0" and "q > 0" by auto
   655       then have "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   656         by (auto simp add: divmod_nat_rel_def) (simp_all add: algebra_simps)
   657       moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   658       ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   659       then show ?thesis by (simp add: div_nat_unique)
   660     qed
   661   qed simp_all
   662 qed
   663 
   664 end
   665 
   666 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   667   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   668   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   669 
   670 text {* Simproc for cancelling @{const div} and @{const mod} *}
   671 
   672 ML {*
   673 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   674 (
   675   val div_name = @{const_name div};
   676   val mod_name = @{const_name mod};
   677   val mk_binop = HOLogic.mk_binop;
   678   val mk_sum = Nat_Arith.mk_sum;
   679   val dest_sum = Nat_Arith.dest_sum;
   680 
   681   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   682 
   683   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   684     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   685 )
   686 *}
   687 
   688 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   689 
   690 
   691 subsubsection {* Quotient *}
   692 
   693 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   694 by (simp add: le_div_geq linorder_not_less)
   695 
   696 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   697 by (simp add: div_geq)
   698 
   699 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   700 by simp
   701 
   702 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   703 by simp
   704 
   705 
   706 subsubsection {* Remainder *}
   707 
   708 lemma mod_less_divisor [simp]:
   709   fixes m n :: nat
   710   assumes "n > 0"
   711   shows "m mod n < (n::nat)"
   712   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   713 
   714 lemma mod_less_eq_dividend [simp]:
   715   fixes m n :: nat
   716   shows "m mod n \<le> m"
   717 proof (rule add_leD2)
   718   from mod_div_equality have "m div n * n + m mod n = m" .
   719   then show "m div n * n + m mod n \<le> m" by auto
   720 qed
   721 
   722 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   723 by (simp add: le_mod_geq linorder_not_less)
   724 
   725 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   726 by (simp add: le_mod_geq)
   727 
   728 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   729 by (induct m) (simp_all add: mod_geq)
   730 
   731 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   732   apply (cases "n = 0", simp)
   733   apply (cases "k = 0", simp)
   734   apply (induct m rule: nat_less_induct)
   735   apply (subst mod_if, simp)
   736   apply (simp add: mod_geq diff_mult_distrib)
   737   done
   738 
   739 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   740 by (simp add: mult_commute [of k] mod_mult_distrib)
   741 
   742 (* a simple rearrangement of mod_div_equality: *)
   743 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   744 by (cut_tac a = m and b = n in mod_div_equality2, arith)
   745 
   746 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   747   apply (drule mod_less_divisor [where m = m])
   748   apply simp
   749   done
   750 
   751 subsubsection {* Quotient and Remainder *}
   752 
   753 lemma divmod_nat_rel_mult1_eq:
   754   "divmod_nat_rel b c (q, r)
   755    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   756 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   757 
   758 lemma div_mult1_eq:
   759   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   760 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   761 
   762 lemma divmod_nat_rel_add1_eq:
   763   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   764    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   765 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   766 
   767 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   768 lemma div_add1_eq:
   769   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   770 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   771 
   772 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   773   apply (cut_tac m = q and n = c in mod_less_divisor)
   774   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   775   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   776   apply (simp add: add_mult_distrib2)
   777   done
   778 
   779 lemma divmod_nat_rel_mult2_eq:
   780   "divmod_nat_rel a b (q, r)
   781    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   782 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   783 
   784 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   785 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   786 
   787 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   788 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   789 
   790 
   791 subsubsection {* Further Facts about Quotient and Remainder *}
   792 
   793 lemma div_1 [simp]: "m div Suc 0 = m"
   794 by (induct m) (simp_all add: div_geq)
   795 
   796 (* Monotonicity of div in first argument *)
   797 lemma div_le_mono [rule_format (no_asm)]:
   798     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   799 apply (case_tac "k=0", simp)
   800 apply (induct "n" rule: nat_less_induct, clarify)
   801 apply (case_tac "n<k")
   802 (* 1  case n<k *)
   803 apply simp
   804 (* 2  case n >= k *)
   805 apply (case_tac "m<k")
   806 (* 2.1  case m<k *)
   807 apply simp
   808 (* 2.2  case m>=k *)
   809 apply (simp add: div_geq diff_le_mono)
   810 done
   811 
   812 (* Antimonotonicity of div in second argument *)
   813 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   814 apply (subgoal_tac "0<n")
   815  prefer 2 apply simp
   816 apply (induct_tac k rule: nat_less_induct)
   817 apply (rename_tac "k")
   818 apply (case_tac "k<n", simp)
   819 apply (subgoal_tac "~ (k<m) ")
   820  prefer 2 apply simp
   821 apply (simp add: div_geq)
   822 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   823  prefer 2
   824  apply (blast intro: div_le_mono diff_le_mono2)
   825 apply (rule le_trans, simp)
   826 apply (simp)
   827 done
   828 
   829 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   830 apply (case_tac "n=0", simp)
   831 apply (subgoal_tac "m div n \<le> m div 1", simp)
   832 apply (rule div_le_mono2)
   833 apply (simp_all (no_asm_simp))
   834 done
   835 
   836 (* Similar for "less than" *)
   837 lemma div_less_dividend [rule_format]:
   838      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   839 apply (induct_tac m rule: nat_less_induct)
   840 apply (rename_tac "m")
   841 apply (case_tac "m<n", simp)
   842 apply (subgoal_tac "0<n")
   843  prefer 2 apply simp
   844 apply (simp add: div_geq)
   845 apply (case_tac "n<m")
   846  apply (subgoal_tac "(m-n) div n < (m-n) ")
   847   apply (rule impI less_trans_Suc)+
   848 apply assumption
   849   apply (simp_all)
   850 done
   851 
   852 declare div_less_dividend [simp]
   853 
   854 text{*A fact for the mutilated chess board*}
   855 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   856 apply (case_tac "n=0", simp)
   857 apply (induct "m" rule: nat_less_induct)
   858 apply (case_tac "Suc (na) <n")
   859 (* case Suc(na) < n *)
   860 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   861 (* case n \<le> Suc(na) *)
   862 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   863 apply (auto simp add: Suc_diff_le le_mod_geq)
   864 done
   865 
   866 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   867 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   868 
   869 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   870 
   871 (*Loses information, namely we also have r<d provided d is nonzero*)
   872 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   873   apply (cut_tac a = m in mod_div_equality)
   874   apply (simp only: add_ac)
   875   apply (blast intro: sym)
   876   done
   877 
   878 lemma split_div:
   879  "P(n div k :: nat) =
   880  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   881  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   882 proof
   883   assume P: ?P
   884   show ?Q
   885   proof (cases)
   886     assume "k = 0"
   887     with P show ?Q by simp
   888   next
   889     assume not0: "k \<noteq> 0"
   890     thus ?Q
   891     proof (simp, intro allI impI)
   892       fix i j
   893       assume n: "n = k*i + j" and j: "j < k"
   894       show "P i"
   895       proof (cases)
   896         assume "i = 0"
   897         with n j P show "P i" by simp
   898       next
   899         assume "i \<noteq> 0"
   900         with not0 n j P show "P i" by(simp add:add_ac)
   901       qed
   902     qed
   903   qed
   904 next
   905   assume Q: ?Q
   906   show ?P
   907   proof (cases)
   908     assume "k = 0"
   909     with Q show ?P by simp
   910   next
   911     assume not0: "k \<noteq> 0"
   912     with Q have R: ?R by simp
   913     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   914     show ?P by simp
   915   qed
   916 qed
   917 
   918 lemma split_div_lemma:
   919   assumes "0 < n"
   920   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   921 proof
   922   assume ?rhs
   923   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   924   then have A: "n * q \<le> m" by simp
   925   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   926   then have "m < m + (n - (m mod n))" by simp
   927   then have "m < n + (m - (m mod n))" by simp
   928   with nq have "m < n + n * q" by simp
   929   then have B: "m < n * Suc q" by simp
   930   from A B show ?lhs ..
   931 next
   932   assume P: ?lhs
   933   then have "divmod_nat_rel m n (q, m - n * q)"
   934     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   935   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   936   have "(q, m - n * q) = (m div n, m mod n)" by auto
   937   then show ?rhs by simp
   938 qed
   939 
   940 theorem split_div':
   941   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   942    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   943   apply (case_tac "0 < n")
   944   apply (simp only: add: split_div_lemma)
   945   apply simp_all
   946   done
   947 
   948 lemma split_mod:
   949  "P(n mod k :: nat) =
   950  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   951  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   952 proof
   953   assume P: ?P
   954   show ?Q
   955   proof (cases)
   956     assume "k = 0"
   957     with P show ?Q by simp
   958   next
   959     assume not0: "k \<noteq> 0"
   960     thus ?Q
   961     proof (simp, intro allI impI)
   962       fix i j
   963       assume "n = k*i + j" "j < k"
   964       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   965     qed
   966   qed
   967 next
   968   assume Q: ?Q
   969   show ?P
   970   proof (cases)
   971     assume "k = 0"
   972     with Q show ?P by simp
   973   next
   974     assume not0: "k \<noteq> 0"
   975     with Q have R: ?R by simp
   976     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   977     show ?P by simp
   978   qed
   979 qed
   980 
   981 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   982   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
   983     subst [OF mod_div_equality [of _ n]])
   984   apply arith
   985   done
   986 
   987 lemma div_mod_equality':
   988   fixes m n :: nat
   989   shows "m div n * n = m - m mod n"
   990 proof -
   991   have "m mod n \<le> m mod n" ..
   992   from div_mod_equality have 
   993     "m div n * n + m mod n - m mod n = m - m mod n" by simp
   994   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
   995     "m div n * n + (m mod n - m mod n) = m - m mod n"
   996     by simp
   997   then show ?thesis by simp
   998 qed
   999 
  1000 
  1001 subsubsection {* An ``induction'' law for modulus arithmetic. *}
  1002 
  1003 lemma mod_induct_0:
  1004   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1005   and base: "P i" and i: "i<p"
  1006   shows "P 0"
  1007 proof (rule ccontr)
  1008   assume contra: "\<not>(P 0)"
  1009   from i have p: "0<p" by simp
  1010   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1011   proof
  1012     fix k
  1013     show "?A k"
  1014     proof (induct k)
  1015       show "?A 0" by simp  -- "by contradiction"
  1016     next
  1017       fix n
  1018       assume ih: "?A n"
  1019       show "?A (Suc n)"
  1020       proof (clarsimp)
  1021         assume y: "P (p - Suc n)"
  1022         have n: "Suc n < p"
  1023         proof (rule ccontr)
  1024           assume "\<not>(Suc n < p)"
  1025           hence "p - Suc n = 0"
  1026             by simp
  1027           with y contra show "False"
  1028             by simp
  1029         qed
  1030         hence n2: "Suc (p - Suc n) = p-n" by arith
  1031         from p have "p - Suc n < p" by arith
  1032         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1033           by blast
  1034         show "False"
  1035         proof (cases "n=0")
  1036           case True
  1037           with z n2 contra show ?thesis by simp
  1038         next
  1039           case False
  1040           with p have "p-n < p" by arith
  1041           with z n2 False ih show ?thesis by simp
  1042         qed
  1043       qed
  1044     qed
  1045   qed
  1046   moreover
  1047   from i obtain k where "0<k \<and> i+k=p"
  1048     by (blast dest: less_imp_add_positive)
  1049   hence "0<k \<and> i=p-k" by auto
  1050   moreover
  1051   note base
  1052   ultimately
  1053   show "False" by blast
  1054 qed
  1055 
  1056 lemma mod_induct:
  1057   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1058   and base: "P i" and i: "i<p" and j: "j<p"
  1059   shows "P j"
  1060 proof -
  1061   have "\<forall>j<p. P j"
  1062   proof
  1063     fix j
  1064     show "j<p \<longrightarrow> P j" (is "?A j")
  1065     proof (induct j)
  1066       from step base i show "?A 0"
  1067         by (auto elim: mod_induct_0)
  1068     next
  1069       fix k
  1070       assume ih: "?A k"
  1071       show "?A (Suc k)"
  1072       proof
  1073         assume suc: "Suc k < p"
  1074         hence k: "k<p" by simp
  1075         with ih have "P k" ..
  1076         with step k have "P (Suc k mod p)"
  1077           by blast
  1078         moreover
  1079         from suc have "Suc k mod p = Suc k"
  1080           by simp
  1081         ultimately
  1082         show "P (Suc k)" by simp
  1083       qed
  1084     qed
  1085   qed
  1086   with j show ?thesis by blast
  1087 qed
  1088 
  1089 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1090 by (auto simp add: numeral_2_eq_2 le_div_geq)
  1091 
  1092 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1093 by (simp add: nat_mult_2 [symmetric])
  1094 
  1095 lemma mod2_Suc_Suc [simp]: "Suc(Suc(m)) mod 2 = m mod 2"
  1096 apply (subgoal_tac "m mod 2 < 2")
  1097 apply (erule less_2_cases [THEN disjE])
  1098 apply (simp_all (no_asm_simp) add: Let_def mod_Suc)
  1099 done
  1100 
  1101 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1102 proof -
  1103   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1104   moreover have "m mod 2 < 2" by simp
  1105   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1106   then show ?thesis by auto
  1107 qed
  1108 
  1109 text{*These lemmas collapse some needless occurrences of Suc:
  1110     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1111     We already have some rules to simplify operands smaller than 3.*}
  1112 
  1113 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1114 by (simp add: Suc3_eq_add_3)
  1115 
  1116 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1117 by (simp add: Suc3_eq_add_3)
  1118 
  1119 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1120 by (simp add: Suc3_eq_add_3)
  1121 
  1122 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1123 by (simp add: Suc3_eq_add_3)
  1124 
  1125 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1126 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1127 
  1128 
  1129 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1130 apply (induct "m")
  1131 apply (simp_all add: mod_Suc)
  1132 done
  1133 
  1134 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1135 
  1136 lemma [simp]: "n div k \<le> (Suc n) div k"
  1137 by (simp add: div_le_mono) 
  1138 
  1139 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1140 by (cases n) simp_all
  1141 
  1142 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1143 proof -
  1144   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1145   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1146 qed
  1147 
  1148   (* Potential use of algebra : Equality modulo n*)
  1149 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1150 by (simp add: mult_ac add_ac)
  1151 
  1152 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1153 proof -
  1154   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1155   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1156   finally show ?thesis .
  1157 qed
  1158 
  1159 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1160 apply (subst mod_Suc [of m]) 
  1161 apply (subst mod_Suc [of "m mod n"], simp) 
  1162 done
  1163 
  1164 lemma mod_2_not_eq_zero_eq_one_nat:
  1165   fixes n :: nat
  1166   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1167   by simp
  1168 
  1169 
  1170 subsection {* Division on @{typ int} *}
  1171 
  1172 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1173     --{*definition of quotient and remainder*}
  1174     "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1175                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
  1176 
  1177 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1178     --{*for the division algorithm*}
  1179     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1180                          else (2 * q, r))"
  1181 
  1182 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1183 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1184   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1185      else adjust b (posDivAlg a (2 * b)))"
  1186 by auto
  1187 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1188   (auto simp add: mult_2)
  1189 
  1190 text{*algorithm for the case @{text "a<0, b>0"}*}
  1191 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1192   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1193      else adjust b (negDivAlg a (2 * b)))"
  1194 by auto
  1195 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1196   (auto simp add: mult_2)
  1197 
  1198 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1199 
  1200 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1201     --{*The full division algorithm considers all possible signs for a, b
  1202        including the special case @{text "a=0, b<0"} because 
  1203        @{term negDivAlg} requires @{term "a<0"}.*}
  1204   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1205                   else if a = 0 then (0, 0)
  1206                        else apsnd uminus (negDivAlg (-a) (-b))
  1207                else 
  1208                   if 0 < b then negDivAlg a b
  1209                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1210 
  1211 instantiation int :: Divides.div
  1212 begin
  1213 
  1214 definition div_int where
  1215   "a div b = fst (divmod_int a b)"
  1216 
  1217 lemma fst_divmod_int [simp]:
  1218   "fst (divmod_int a b) = a div b"
  1219   by (simp add: div_int_def)
  1220 
  1221 definition mod_int where
  1222   "a mod b = snd (divmod_int a b)"
  1223 
  1224 lemma snd_divmod_int [simp]:
  1225   "snd (divmod_int a b) = a mod b"
  1226   by (simp add: mod_int_def)
  1227 
  1228 instance ..
  1229 
  1230 end
  1231 
  1232 lemma divmod_int_mod_div:
  1233   "divmod_int p q = (p div q, p mod q)"
  1234   by (simp add: prod_eq_iff)
  1235 
  1236 text{*
  1237 Here is the division algorithm in ML:
  1238 
  1239 \begin{verbatim}
  1240     fun posDivAlg (a,b) =
  1241       if a<b then (0,a)
  1242       else let val (q,r) = posDivAlg(a, 2*b)
  1243                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1244            end
  1245 
  1246     fun negDivAlg (a,b) =
  1247       if 0\<le>a+b then (~1,a+b)
  1248       else let val (q,r) = negDivAlg(a, 2*b)
  1249                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1250            end;
  1251 
  1252     fun negateSnd (q,r:int) = (q,~r);
  1253 
  1254     fun divmod (a,b) = if 0\<le>a then 
  1255                           if b>0 then posDivAlg (a,b) 
  1256                            else if a=0 then (0,0)
  1257                                 else negateSnd (negDivAlg (~a,~b))
  1258                        else 
  1259                           if 0<b then negDivAlg (a,b)
  1260                           else        negateSnd (posDivAlg (~a,~b));
  1261 \end{verbatim}
  1262 *}
  1263 
  1264 
  1265 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1266 
  1267 lemma unique_quotient_lemma:
  1268      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1269       ==> q' \<le> (q::int)"
  1270 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1271  prefer 2 apply (simp add: right_diff_distrib)
  1272 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1273 apply (erule_tac [2] order_le_less_trans)
  1274  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1275 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1276  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1277 apply (simp add: mult_less_cancel_left)
  1278 done
  1279 
  1280 lemma unique_quotient_lemma_neg:
  1281      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1282       ==> q \<le> (q'::int)"
  1283 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1284     auto)
  1285 
  1286 lemma unique_quotient:
  1287      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1288       ==> q = q'"
  1289 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1290 apply (blast intro: order_antisym
  1291              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1292              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1293 done
  1294 
  1295 
  1296 lemma unique_remainder:
  1297      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1298       ==> r = r'"
  1299 apply (subgoal_tac "q = q'")
  1300  apply (simp add: divmod_int_rel_def)
  1301 apply (blast intro: unique_quotient)
  1302 done
  1303 
  1304 
  1305 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1306 
  1307 text{*And positive divisors*}
  1308 
  1309 lemma adjust_eq [simp]:
  1310      "adjust b (q, r) = 
  1311       (let diff = r - b in  
  1312         if 0 \<le> diff then (2 * q + 1, diff)   
  1313                      else (2*q, r))"
  1314   by (simp add: Let_def adjust_def)
  1315 
  1316 declare posDivAlg.simps [simp del]
  1317 
  1318 text{*use with a simproc to avoid repeatedly proving the premise*}
  1319 lemma posDivAlg_eqn:
  1320      "0 < b ==>  
  1321       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1322 by (rule posDivAlg.simps [THEN trans], simp)
  1323 
  1324 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1325 theorem posDivAlg_correct:
  1326   assumes "0 \<le> a" and "0 < b"
  1327   shows "divmod_int_rel a b (posDivAlg a b)"
  1328   using assms
  1329   apply (induct a b rule: posDivAlg.induct)
  1330   apply auto
  1331   apply (simp add: divmod_int_rel_def)
  1332   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1333   apply (case_tac "a < b")
  1334   apply simp_all
  1335   apply (erule splitE)
  1336   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1337   done
  1338 
  1339 
  1340 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1341 
  1342 text{*And positive divisors*}
  1343 
  1344 declare negDivAlg.simps [simp del]
  1345 
  1346 text{*use with a simproc to avoid repeatedly proving the premise*}
  1347 lemma negDivAlg_eqn:
  1348      "0 < b ==>  
  1349       negDivAlg a b =       
  1350        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1351 by (rule negDivAlg.simps [THEN trans], simp)
  1352 
  1353 (*Correctness of negDivAlg: it computes quotients correctly
  1354   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1355 lemma negDivAlg_correct:
  1356   assumes "a < 0" and "b > 0"
  1357   shows "divmod_int_rel a b (negDivAlg a b)"
  1358   using assms
  1359   apply (induct a b rule: negDivAlg.induct)
  1360   apply (auto simp add: linorder_not_le)
  1361   apply (simp add: divmod_int_rel_def)
  1362   apply (subst negDivAlg_eqn, assumption)
  1363   apply (case_tac "a + b < (0\<Colon>int)")
  1364   apply simp_all
  1365   apply (erule splitE)
  1366   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1367   done
  1368 
  1369 
  1370 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1371 
  1372 (*the case a=0*)
  1373 lemma divmod_int_rel_0: "b \<noteq> 0 ==> divmod_int_rel 0 b (0, 0)"
  1374 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1375 
  1376 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1377 by (subst posDivAlg.simps, auto)
  1378 
  1379 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1380 by (subst negDivAlg.simps, auto)
  1381 
  1382 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1383 by (auto simp add: split_ifs divmod_int_rel_def)
  1384 
  1385 lemma divmod_int_correct: "b \<noteq> 0 ==> divmod_int_rel a b (divmod_int a b)"
  1386 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1387                     posDivAlg_correct negDivAlg_correct)
  1388 
  1389 text{*Arbitrary definitions for division by zero.  Useful to simplify 
  1390     certain equations.*}
  1391 
  1392 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
  1393 by (simp add: div_int_def mod_int_def divmod_int_def posDivAlg.simps)  
  1394 
  1395 
  1396 text{*Basic laws about division and remainder*}
  1397 
  1398 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1399 apply (case_tac "b = 0", simp)
  1400 apply (cut_tac a = a and b = b in divmod_int_correct)
  1401 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1402 done
  1403 
  1404 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1405 by(simp add: zmod_zdiv_equality[symmetric])
  1406 
  1407 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1408 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
  1409 
  1410 text {* Tool setup *}
  1411 
  1412 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1413 lemmas add_0s = add_0_left add_0_right
  1414 
  1415 ML {*
  1416 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1417 (
  1418   val div_name = @{const_name div};
  1419   val mod_name = @{const_name mod};
  1420   val mk_binop = HOLogic.mk_binop;
  1421   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1422   val dest_sum = Arith_Data.dest_sum;
  1423 
  1424   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1425 
  1426   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1427     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1428 )
  1429 *}
  1430 
  1431 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1432 
  1433 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
  1434 apply (cut_tac a = a and b = b in divmod_int_correct)
  1435 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1436 done
  1437 
  1438 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1439    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1440 
  1441 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
  1442 apply (cut_tac a = a and b = b in divmod_int_correct)
  1443 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1444 done
  1445 
  1446 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1447    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1448 
  1449 
  1450 subsubsection {* General Properties of div and mod *}
  1451 
  1452 lemma divmod_int_rel_div_mod: "b \<noteq> 0 ==> divmod_int_rel a b (a div b, a mod b)"
  1453 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1454 apply (force simp add: divmod_int_rel_def linorder_neq_iff)
  1455 done
  1456 
  1457 lemma divmod_int_rel_div: "[| divmod_int_rel a b (q, r) |] ==> a div b = q"
  1458 apply (cases "b = 0")
  1459 apply (simp add: divmod_int_rel_def)
  1460 by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1461 
  1462 lemma divmod_int_rel_mod: "[| divmod_int_rel a b (q, r) |] ==> a mod b = r"
  1463 apply (cases "b = 0")
  1464 apply (simp add: divmod_int_rel_def)
  1465 by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1466 
  1467 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1468 apply (rule divmod_int_rel_div)
  1469 apply (auto simp add: divmod_int_rel_def)
  1470 done
  1471 
  1472 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1473 apply (rule divmod_int_rel_div)
  1474 apply (auto simp add: divmod_int_rel_def)
  1475 done
  1476 
  1477 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1478 apply (rule divmod_int_rel_div)
  1479 apply (auto simp add: divmod_int_rel_def)
  1480 done
  1481 
  1482 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1483 
  1484 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1485 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1486 apply (auto simp add: divmod_int_rel_def)
  1487 done
  1488 
  1489 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1490 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1491 apply (auto simp add: divmod_int_rel_def)
  1492 done
  1493 
  1494 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1495 apply (rule_tac q = "-1" in divmod_int_rel_mod)
  1496 apply (auto simp add: divmod_int_rel_def)
  1497 done
  1498 
  1499 text{*There is no @{text mod_neg_pos_trivial}.*}
  1500 
  1501 
  1502 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1503 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1504 apply (case_tac "b = 0", simp)
  1505 apply (simp add: divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, 
  1506                                  THEN divmod_int_rel_div, THEN sym])
  1507 
  1508 done
  1509 
  1510 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1511 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1512 apply (case_tac "b = 0", simp)
  1513 apply (subst divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, THEN divmod_int_rel_mod],
  1514        auto)
  1515 done
  1516 
  1517 
  1518 subsubsection {* Laws for div and mod with Unary Minus *}
  1519 
  1520 lemma zminus1_lemma:
  1521      "divmod_int_rel a b (q, r)
  1522       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1523                           if r=0 then 0 else b-r)"
  1524 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1525 
  1526 
  1527 lemma zdiv_zminus1_eq_if:
  1528      "b \<noteq> (0::int)  
  1529       ==> (-a) div b =  
  1530           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1531 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_div])
  1532 
  1533 lemma zmod_zminus1_eq_if:
  1534      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1535 apply (case_tac "b = 0", simp)
  1536 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_mod])
  1537 done
  1538 
  1539 lemma zmod_zminus1_not_zero:
  1540   fixes k l :: int
  1541   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1542   unfolding zmod_zminus1_eq_if by auto
  1543 
  1544 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1545 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
  1546 
  1547 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1548 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
  1549 
  1550 lemma zdiv_zminus2_eq_if:
  1551      "b \<noteq> (0::int)  
  1552       ==> a div (-b) =  
  1553           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1554 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1555 
  1556 lemma zmod_zminus2_eq_if:
  1557      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1558 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1559 
  1560 lemma zmod_zminus2_not_zero:
  1561   fixes k l :: int
  1562   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1563   unfolding zmod_zminus2_eq_if by auto 
  1564 
  1565 
  1566 subsubsection {* Division of a Number by Itself *}
  1567 
  1568 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
  1569 apply (subgoal_tac "0 < a*q")
  1570  apply (simp add: zero_less_mult_iff, arith)
  1571 done
  1572 
  1573 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
  1574 apply (subgoal_tac "0 \<le> a* (1-q) ")
  1575  apply (simp add: zero_le_mult_iff)
  1576 apply (simp add: right_diff_distrib)
  1577 done
  1578 
  1579 lemma self_quotient: "[| divmod_int_rel a a (q, r) |] ==> q = 1"
  1580 apply (simp add: split_ifs divmod_int_rel_def linorder_neq_iff)
  1581 apply (rule order_antisym, safe, simp_all)
  1582 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
  1583 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
  1584 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
  1585 done
  1586 
  1587 lemma self_remainder: "[| divmod_int_rel a a (q, r) |] ==> r = 0"
  1588 apply (frule self_quotient)
  1589 apply (simp add: divmod_int_rel_def)
  1590 done
  1591 
  1592 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
  1593 by (simp add: divmod_int_rel_div_mod [THEN self_quotient])
  1594 
  1595 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
  1596 lemma zmod_self [simp]: "a mod a = (0::int)"
  1597 apply (case_tac "a = 0", simp)
  1598 apply (simp add: divmod_int_rel_div_mod [THEN self_remainder])
  1599 done
  1600 
  1601 
  1602 subsubsection {* Computation of Division and Remainder *}
  1603 
  1604 lemma zdiv_zero [simp]: "(0::int) div b = 0"
  1605 by (simp add: div_int_def divmod_int_def)
  1606 
  1607 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1608 by (simp add: div_int_def divmod_int_def)
  1609 
  1610 lemma zmod_zero [simp]: "(0::int) mod b = 0"
  1611 by (simp add: mod_int_def divmod_int_def)
  1612 
  1613 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1614 by (simp add: mod_int_def divmod_int_def)
  1615 
  1616 text{*a positive, b positive *}
  1617 
  1618 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1619 by (simp add: div_int_def divmod_int_def)
  1620 
  1621 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1622 by (simp add: mod_int_def divmod_int_def)
  1623 
  1624 text{*a negative, b positive *}
  1625 
  1626 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1627 by (simp add: div_int_def divmod_int_def)
  1628 
  1629 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1630 by (simp add: mod_int_def divmod_int_def)
  1631 
  1632 text{*a positive, b negative *}
  1633 
  1634 lemma div_pos_neg:
  1635      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1636 by (simp add: div_int_def divmod_int_def)
  1637 
  1638 lemma mod_pos_neg:
  1639      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1640 by (simp add: mod_int_def divmod_int_def)
  1641 
  1642 text{*a negative, b negative *}
  1643 
  1644 lemma div_neg_neg:
  1645      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1646 by (simp add: div_int_def divmod_int_def)
  1647 
  1648 lemma mod_neg_neg:
  1649      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1650 by (simp add: mod_int_def divmod_int_def)
  1651 
  1652 text {*Simplify expresions in which div and mod combine numerical constants*}
  1653 
  1654 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1655   by (rule divmod_int_rel_div [of a b q r]) (simp add: divmod_int_rel_def)
  1656 
  1657 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1658   by (rule divmod_int_rel_div [of a b q r],
  1659     simp add: divmod_int_rel_def)
  1660 
  1661 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1662   by (rule divmod_int_rel_mod [of a b q r],
  1663     simp add: divmod_int_rel_def)
  1664 
  1665 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1666   by (rule divmod_int_rel_mod [of a b q r],
  1667     simp add: divmod_int_rel_def)
  1668 
  1669 (* simprocs adapted from HOL/ex/Binary.thy *)
  1670 ML {*
  1671 local
  1672   val mk_number = HOLogic.mk_number HOLogic.intT
  1673   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1674   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1675   val zero = @{term "0 :: int"}
  1676   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1677   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1678   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1679     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1680   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1681     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1682   fun binary_proc proc ss ct =
  1683     (case Thm.term_of ct of
  1684       _ $ t $ u =>
  1685       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1686         SOME args => proc (Simplifier.the_context ss) args
  1687       | NONE => NONE)
  1688     | _ => NONE);
  1689 in
  1690   fun divmod_proc posrule negrule =
  1691     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1692       if b = 0 then NONE else let
  1693         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1694         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1695         val (goal2, goal3, rule) = if b > 0
  1696           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1697           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1698       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1699 end
  1700 *}
  1701 
  1702 simproc_setup binary_int_div
  1703   ("numeral m div numeral n :: int" |
  1704    "numeral m div neg_numeral n :: int" |
  1705    "neg_numeral m div numeral n :: int" |
  1706    "neg_numeral m div neg_numeral n :: int") =
  1707   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1708 
  1709 simproc_setup binary_int_mod
  1710   ("numeral m mod numeral n :: int" |
  1711    "numeral m mod neg_numeral n :: int" |
  1712    "neg_numeral m mod numeral n :: int" |
  1713    "neg_numeral m mod neg_numeral n :: int") =
  1714   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1715 
  1716 lemmas posDivAlg_eqn_numeral [simp] =
  1717     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1718 
  1719 lemmas negDivAlg_eqn_numeral [simp] =
  1720     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1721 
  1722 
  1723 text{*Special-case simplification *}
  1724 
  1725 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1726 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1727 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1728 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1729 done
  1730 
  1731 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1732 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1733 
  1734 (** The last remaining special cases for constant arithmetic:
  1735     1 div z and 1 mod z **)
  1736 
  1737 lemmas div_pos_pos_1_numeral [simp] =
  1738   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1739 
  1740 lemmas div_pos_neg_1_numeral [simp] =
  1741   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1742   OF neg_numeral_less_zero] for w
  1743 
  1744 lemmas mod_pos_pos_1_numeral [simp] =
  1745   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1746 
  1747 lemmas mod_pos_neg_1_numeral [simp] =
  1748   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1749   OF neg_numeral_less_zero] for w
  1750 
  1751 lemmas posDivAlg_eqn_1_numeral [simp] =
  1752     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1753 
  1754 lemmas negDivAlg_eqn_1_numeral [simp] =
  1755     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1756 
  1757 
  1758 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1759 
  1760 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1761 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1762 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1763 apply (rule unique_quotient_lemma)
  1764 apply (erule subst)
  1765 apply (erule subst, simp_all)
  1766 done
  1767 
  1768 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1769 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1770 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1771 apply (rule unique_quotient_lemma_neg)
  1772 apply (erule subst)
  1773 apply (erule subst, simp_all)
  1774 done
  1775 
  1776 
  1777 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1778 
  1779 lemma q_pos_lemma:
  1780      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1781 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1782  apply (simp add: zero_less_mult_iff)
  1783 apply (simp add: right_distrib)
  1784 done
  1785 
  1786 lemma zdiv_mono2_lemma:
  1787      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1788          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1789       ==> q \<le> (q'::int)"
  1790 apply (frule q_pos_lemma, assumption+) 
  1791 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1792  apply (simp add: mult_less_cancel_left)
  1793 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1794  prefer 2 apply simp
  1795 apply (simp (no_asm_simp) add: right_distrib)
  1796 apply (subst add_commute, rule add_less_le_mono, arith)
  1797 apply (rule mult_right_mono, auto)
  1798 done
  1799 
  1800 lemma zdiv_mono2:
  1801      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1802 apply (subgoal_tac "b \<noteq> 0")
  1803  prefer 2 apply arith
  1804 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1805 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1806 apply (rule zdiv_mono2_lemma)
  1807 apply (erule subst)
  1808 apply (erule subst, simp_all)
  1809 done
  1810 
  1811 lemma q_neg_lemma:
  1812      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1813 apply (subgoal_tac "b'*q' < 0")
  1814  apply (simp add: mult_less_0_iff, arith)
  1815 done
  1816 
  1817 lemma zdiv_mono2_neg_lemma:
  1818      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1819          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1820       ==> q' \<le> (q::int)"
  1821 apply (frule q_neg_lemma, assumption+) 
  1822 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1823  apply (simp add: mult_less_cancel_left)
  1824 apply (simp add: right_distrib)
  1825 apply (subgoal_tac "b*q' \<le> b'*q'")
  1826  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1827 done
  1828 
  1829 lemma zdiv_mono2_neg:
  1830      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1831 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1832 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1833 apply (rule zdiv_mono2_neg_lemma)
  1834 apply (erule subst)
  1835 apply (erule subst, simp_all)
  1836 done
  1837 
  1838 
  1839 subsubsection {* More Algebraic Laws for div and mod *}
  1840 
  1841 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1842 
  1843 lemma zmult1_lemma:
  1844      "[| divmod_int_rel b c (q, r) |]  
  1845       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1846 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1847 
  1848 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1849 apply (case_tac "c = 0", simp)
  1850 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_div])
  1851 done
  1852 
  1853 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1854 apply (case_tac "c = 0", simp)
  1855 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_mod])
  1856 done
  1857 
  1858 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
  1859 apply (case_tac "b = 0", simp)
  1860 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
  1861 done
  1862 
  1863 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1864 
  1865 lemma zadd1_lemma:
  1866      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1867       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1868 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1869 
  1870 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1871 lemma zdiv_zadd1_eq:
  1872      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1873 apply (case_tac "c = 0", simp)
  1874 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] divmod_int_rel_div)
  1875 done
  1876 
  1877 instance int :: ring_div
  1878 proof
  1879   fix a b c :: int
  1880   assume not0: "b \<noteq> 0"
  1881   show "(a + c * b) div b = c + a div b"
  1882     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
  1883       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial zdiv_zmult1_eq)
  1884 next
  1885   fix a b c :: int
  1886   assume "a \<noteq> 0"
  1887   then show "(a * b) div (a * c) = b div c"
  1888   proof (cases "b \<noteq> 0 \<and> c \<noteq> 0")
  1889     case False then show ?thesis by auto
  1890   next
  1891     case True then have "b \<noteq> 0" and "c \<noteq> 0" by auto
  1892     with `a \<noteq> 0`
  1893     have "\<And>q r. divmod_int_rel b c (q, r) \<Longrightarrow> divmod_int_rel (a * b) (a * c) (q, a * r)"
  1894       apply (auto simp add: divmod_int_rel_def) 
  1895       apply (auto simp add: algebra_simps)
  1896       apply (auto simp add: zero_less_mult_iff zero_le_mult_iff mult_le_0_iff mult_commute [of a] mult_less_cancel_right)
  1897       done
  1898     moreover with `c \<noteq> 0` divmod_int_rel_div_mod have "divmod_int_rel b c (b div c, b mod c)" by auto
  1899     ultimately have "divmod_int_rel (a * b) (a * c) (b div c, a * (b mod c))" .
  1900     from this show ?thesis by (rule divmod_int_rel_div)
  1901   qed
  1902 qed auto
  1903 
  1904 lemma posDivAlg_div_mod:
  1905   assumes "k \<ge> 0"
  1906   and "l \<ge> 0"
  1907   shows "posDivAlg k l = (k div l, k mod l)"
  1908 proof (cases "l = 0")
  1909   case True then show ?thesis by (simp add: posDivAlg.simps)
  1910 next
  1911   case False with assms posDivAlg_correct
  1912     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1913     by simp
  1914   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1915   show ?thesis by simp
  1916 qed
  1917 
  1918 lemma negDivAlg_div_mod:
  1919   assumes "k < 0"
  1920   and "l > 0"
  1921   shows "negDivAlg k l = (k div l, k mod l)"
  1922 proof -
  1923   from assms have "l \<noteq> 0" by simp
  1924   from assms negDivAlg_correct
  1925     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1926     by simp
  1927   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1928   show ?thesis by simp
  1929 qed
  1930 
  1931 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1932 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1933 
  1934 (* REVISIT: should this be generalized to all semiring_div types? *)
  1935 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1936 
  1937 lemma zmod_zdiv_equality':
  1938   "(m\<Colon>int) mod n = m - (m div n) * n"
  1939   by (rule_tac P="%x. m mod n = x - (m div n) * n" in subst [OF mod_div_equality [of _ n]])
  1940     arith
  1941 
  1942 
  1943 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1944 
  1945 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1946   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1947   to cause particular problems.*)
  1948 
  1949 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1950 
  1951 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1952 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1953  apply (simp add: algebra_simps)
  1954 apply (rule order_le_less_trans)
  1955  apply (erule_tac [2] mult_strict_right_mono)
  1956  apply (rule mult_left_mono_neg)
  1957   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1958  apply (simp)
  1959 apply (simp)
  1960 done
  1961 
  1962 lemma zmult2_lemma_aux2:
  1963      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1964 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1965  apply arith
  1966 apply (simp add: mult_le_0_iff)
  1967 done
  1968 
  1969 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1970 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1971 apply arith
  1972 apply (simp add: zero_le_mult_iff)
  1973 done
  1974 
  1975 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1976 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1977  apply (simp add: right_diff_distrib)
  1978 apply (rule order_less_le_trans)
  1979  apply (erule mult_strict_right_mono)
  1980  apply (rule_tac [2] mult_left_mono)
  1981   apply simp
  1982  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1983 apply simp
  1984 done
  1985 
  1986 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1987       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1988 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1989                    zero_less_mult_iff right_distrib [symmetric] 
  1990                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
  1991 
  1992 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1993 apply (case_tac "b = 0", simp)
  1994 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_div])
  1995 done
  1996 
  1997 lemma zmod_zmult2_eq:
  1998      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1999 apply (case_tac "b = 0", simp)
  2000 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_mod])
  2001 done
  2002 
  2003 lemma div_pos_geq:
  2004   fixes k l :: int
  2005   assumes "0 < l" and "l \<le> k"
  2006   shows "k div l = (k - l) div l + 1"
  2007 proof -
  2008   have "k = (k - l) + l" by simp
  2009   then obtain j where k: "k = j + l" ..
  2010   with assms show ?thesis by simp
  2011 qed
  2012 
  2013 lemma mod_pos_geq:
  2014   fixes k l :: int
  2015   assumes "0 < l" and "l \<le> k"
  2016   shows "k mod l = (k - l) mod l"
  2017 proof -
  2018   have "k = (k - l) + l" by simp
  2019   then obtain j where k: "k = j + l" ..
  2020   with assms show ?thesis by simp
  2021 qed
  2022 
  2023 
  2024 subsubsection {* Splitting Rules for div and mod *}
  2025 
  2026 text{*The proofs of the two lemmas below are essentially identical*}
  2027 
  2028 lemma split_pos_lemma:
  2029  "0<k ==> 
  2030     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  2031 apply (rule iffI, clarify)
  2032  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2033  apply (subst mod_add_eq) 
  2034  apply (subst zdiv_zadd1_eq) 
  2035  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  2036 txt{*converse direction*}
  2037 apply (drule_tac x = "n div k" in spec) 
  2038 apply (drule_tac x = "n mod k" in spec, simp)
  2039 done
  2040 
  2041 lemma split_neg_lemma:
  2042  "k<0 ==>
  2043     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  2044 apply (rule iffI, clarify)
  2045  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2046  apply (subst mod_add_eq) 
  2047  apply (subst zdiv_zadd1_eq) 
  2048  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  2049 txt{*converse direction*}
  2050 apply (drule_tac x = "n div k" in spec) 
  2051 apply (drule_tac x = "n mod k" in spec, simp)
  2052 done
  2053 
  2054 lemma split_zdiv:
  2055  "P(n div k :: int) =
  2056   ((k = 0 --> P 0) & 
  2057    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  2058    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  2059 apply (case_tac "k=0", simp)
  2060 apply (simp only: linorder_neq_iff)
  2061 apply (erule disjE) 
  2062  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  2063                       split_neg_lemma [of concl: "%x y. P x"])
  2064 done
  2065 
  2066 lemma split_zmod:
  2067  "P(n mod k :: int) =
  2068   ((k = 0 --> P n) & 
  2069    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  2070    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  2071 apply (case_tac "k=0", simp)
  2072 apply (simp only: linorder_neq_iff)
  2073 apply (erule disjE) 
  2074  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  2075                       split_neg_lemma [of concl: "%x y. P y"])
  2076 done
  2077 
  2078 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  2079   when these are applied to some constant that is of the form
  2080   @{term "numeral k"}: *}
  2081 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  2082 declare split_zmod [of _ _ "numeral k", arith_split] for k
  2083 
  2084 
  2085 subsubsection {* Speeding up the Division Algorithm with Shifting *}
  2086 
  2087 text{*computing div by shifting *}
  2088 
  2089 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2090 proof cases
  2091   assume "a=0"
  2092     thus ?thesis by simp
  2093 next
  2094   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2095   hence a_pos: "1 \<le> a" by arith
  2096   hence one_less_a2: "1 < 2 * a" by arith
  2097   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2098     unfolding mult_le_cancel_left
  2099     by (simp add: add1_zle_eq add_commute [of 1])
  2100   with a_pos have "0 \<le> b mod a" by simp
  2101   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2102     by (simp add: mod_pos_pos_trivial one_less_a2)
  2103   with  le_2a
  2104   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2105     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2106                   right_distrib) 
  2107   thus ?thesis
  2108     by (subst zdiv_zadd1_eq,
  2109         simp add: mod_mult_mult1 one_less_a2
  2110                   div_pos_pos_trivial)
  2111 qed
  2112 
  2113 lemma neg_zdiv_mult_2: 
  2114   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2115 proof -
  2116   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2117   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2118     by (rule pos_zdiv_mult_2, simp add: A)
  2119   thus ?thesis
  2120     by (simp only: R zdiv_zminus_zminus diff_minus
  2121       minus_add_distrib [symmetric] mult_minus_right)
  2122 qed
  2123 
  2124 (* FIXME: add rules for negative numerals *)
  2125 lemma zdiv_numeral_Bit0 [simp]:
  2126   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2127     numeral v div (numeral w :: int)"
  2128   unfolding numeral.simps unfolding mult_2 [symmetric]
  2129   by (rule div_mult_mult1, simp)
  2130 
  2131 lemma zdiv_numeral_Bit1 [simp]:
  2132   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2133     (numeral v div (numeral w :: int))"
  2134   unfolding numeral.simps
  2135   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2136   by (rule pos_zdiv_mult_2, simp)
  2137 
  2138 
  2139 subsubsection {* Computing mod by Shifting (proofs resemble those for div) *}
  2140 
  2141 lemma pos_zmod_mult_2:
  2142   fixes a b :: int
  2143   assumes "0 \<le> a"
  2144   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2145 proof (cases "0 < a")
  2146   case False with assms show ?thesis by simp
  2147 next
  2148   case True
  2149   then have "b mod a < a" by (rule pos_mod_bound)
  2150   then have "1 + b mod a \<le> a" by simp
  2151   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2152   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2153   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2154   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2155     using `0 < a` and A
  2156     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2157   then show ?thesis by (subst mod_add_eq)
  2158 qed
  2159 
  2160 lemma neg_zmod_mult_2:
  2161   fixes a b :: int
  2162   assumes "a \<le> 0"
  2163   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2164 proof -
  2165   from assms have "0 \<le> - a" by auto
  2166   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2167     by (rule pos_zmod_mult_2)
  2168   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2169      (simp add: diff_minus add_ac)
  2170 qed
  2171 
  2172 (* FIXME: add rules for negative numerals *)
  2173 lemma zmod_numeral_Bit0 [simp]:
  2174   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2175     (2::int) * (numeral v mod numeral w)"
  2176   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2177   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2178 
  2179 lemma zmod_numeral_Bit1 [simp]:
  2180   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2181     2 * (numeral v mod numeral w) + (1::int)"
  2182   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2183   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2184   by (rule pos_zmod_mult_2, simp)
  2185 
  2186 lemma zdiv_eq_0_iff:
  2187  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2188 proof
  2189   assume ?L
  2190   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2191   with `?L` show ?R by blast
  2192 next
  2193   assume ?R thus ?L
  2194     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2195 qed
  2196 
  2197 
  2198 subsubsection {* Quotients of Signs *}
  2199 
  2200 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2201 apply (subgoal_tac "a div b \<le> -1", force)
  2202 apply (rule order_trans)
  2203 apply (rule_tac a' = "-1" in zdiv_mono1)
  2204 apply (auto simp add: div_eq_minus1)
  2205 done
  2206 
  2207 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2208 by (drule zdiv_mono1_neg, auto)
  2209 
  2210 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2211 by (drule zdiv_mono1, auto)
  2212 
  2213 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2214 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2215 They should all be simp rules unless that causes too much search. *}
  2216 
  2217 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2218 apply auto
  2219 apply (drule_tac [2] zdiv_mono1)
  2220 apply (auto simp add: linorder_neq_iff)
  2221 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2222 apply (blast intro: div_neg_pos_less0)
  2223 done
  2224 
  2225 lemma neg_imp_zdiv_nonneg_iff:
  2226   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2227 apply (subst zdiv_zminus_zminus [symmetric])
  2228 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2229 done
  2230 
  2231 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2232 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2233 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2234 
  2235 lemma pos_imp_zdiv_pos_iff:
  2236   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2237 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2238 by arith
  2239 
  2240 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2241 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2242 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2243 
  2244 lemma nonneg1_imp_zdiv_pos_iff:
  2245   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2246 apply rule
  2247  apply rule
  2248   using div_pos_pos_trivial[of a b]apply arith
  2249  apply(cases "b=0")apply simp
  2250  using div_nonneg_neg_le0[of a b]apply arith
  2251 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2252 done
  2253 
  2254 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2255 apply (rule split_zmod[THEN iffD2])
  2256 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2257 done
  2258 
  2259 
  2260 subsubsection {* The Divides Relation *}
  2261 
  2262 lemmas zdvd_iff_zmod_eq_0_numeral [simp] =
  2263   dvd_eq_mod_eq_0 [of "numeral x::int" "numeral y::int"]
  2264   dvd_eq_mod_eq_0 [of "numeral x::int" "neg_numeral y::int"]
  2265   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "numeral y::int"]
  2266   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "neg_numeral y::int"] for x y
  2267 
  2268 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2269   by (rule dvd_mod) (* TODO: remove *)
  2270 
  2271 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2272   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2273 
  2274 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2275   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2276 
  2277 
  2278 subsubsection {* Further properties *}
  2279 
  2280 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2281   using zmod_zdiv_equality[where a="m" and b="n"]
  2282   by (simp add: algebra_simps)
  2283 
  2284 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2285 apply (induct "y", auto)
  2286 apply (rule zmod_zmult1_eq [THEN trans])
  2287 apply (simp (no_asm_simp))
  2288 apply (rule mod_mult_eq [symmetric])
  2289 done
  2290 
  2291 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2292 apply (subst split_div, auto)
  2293 apply (subst split_zdiv, auto)
  2294 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2295 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2296 done
  2297 
  2298 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2299 apply (subst split_mod, auto)
  2300 apply (subst split_zmod, auto)
  2301 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2302        in unique_remainder)
  2303 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2304 done
  2305 
  2306 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2307 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2308 
  2309 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2310 apply (subgoal_tac "m mod n = 0")
  2311  apply (simp add: zmult_div_cancel)
  2312 apply (simp only: dvd_eq_mod_eq_0)
  2313 done
  2314 
  2315 text{*Suggested by Matthias Daum*}
  2316 lemma int_power_div_base:
  2317      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2318 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2319  apply (erule ssubst)
  2320  apply (simp only: power_add)
  2321  apply simp_all
  2322 done
  2323 
  2324 text {* by Brian Huffman *}
  2325 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2326 by (rule mod_minus_eq [symmetric])
  2327 
  2328 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2329 by (rule mod_diff_left_eq [symmetric])
  2330 
  2331 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2332 by (rule mod_diff_right_eq [symmetric])
  2333 
  2334 lemmas zmod_simps =
  2335   mod_add_left_eq  [symmetric]
  2336   mod_add_right_eq [symmetric]
  2337   zmod_zmult1_eq   [symmetric]
  2338   mod_mult_left_eq [symmetric]
  2339   zpower_zmod
  2340   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2341 
  2342 text {* Distributive laws for function @{text nat}. *}
  2343 
  2344 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2345 apply (rule linorder_cases [of y 0])
  2346 apply (simp add: div_nonneg_neg_le0)
  2347 apply simp
  2348 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2349 done
  2350 
  2351 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2352 lemma nat_mod_distrib:
  2353   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2354 apply (case_tac "y = 0", simp)
  2355 apply (simp add: nat_eq_iff zmod_int)
  2356 done
  2357 
  2358 text  {* transfer setup *}
  2359 
  2360 lemma transfer_nat_int_functions:
  2361     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2362     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2363   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2364 
  2365 lemma transfer_nat_int_function_closures:
  2366     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2367     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2368   apply (cases "y = 0")
  2369   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2370   apply (cases "y = 0")
  2371   apply auto
  2372 done
  2373 
  2374 declare transfer_morphism_nat_int [transfer add return:
  2375   transfer_nat_int_functions
  2376   transfer_nat_int_function_closures
  2377 ]
  2378 
  2379 lemma transfer_int_nat_functions:
  2380     "(int x) div (int y) = int (x div y)"
  2381     "(int x) mod (int y) = int (x mod y)"
  2382   by (auto simp add: zdiv_int zmod_int)
  2383 
  2384 lemma transfer_int_nat_function_closures:
  2385     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2386     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2387   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2388 
  2389 declare transfer_morphism_int_nat [transfer add return:
  2390   transfer_int_nat_functions
  2391   transfer_int_nat_function_closures
  2392 ]
  2393 
  2394 text{*Suggested by Matthias Daum*}
  2395 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2396 apply (subgoal_tac "nat x div nat k < nat x")
  2397  apply (simp add: nat_div_distrib [symmetric])
  2398 apply (rule Divides.div_less_dividend, simp_all)
  2399 done
  2400 
  2401 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2402 proof
  2403   assume H: "x mod n = y mod n"
  2404   hence "x mod n - y mod n = 0" by simp
  2405   hence "(x mod n - y mod n) mod n = 0" by simp 
  2406   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2407   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2408 next
  2409   assume H: "n dvd x - y"
  2410   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2411   hence "x = n*k + y" by simp
  2412   hence "x mod n = (n*k + y) mod n" by simp
  2413   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2414 qed
  2415 
  2416 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2417   shows "\<exists>q. x = y + n * q"
  2418 proof-
  2419   from xy have th: "int x - int y = int (x - y)" by simp 
  2420   from xyn have "int x mod int n = int y mod int n" 
  2421     by (simp add: zmod_int [symmetric])
  2422   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2423   hence "n dvd x - y" by (simp add: th zdvd_int)
  2424   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2425 qed
  2426 
  2427 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2428   (is "?lhs = ?rhs")
  2429 proof
  2430   assume H: "x mod n = y mod n"
  2431   {assume xy: "x \<le> y"
  2432     from H have th: "y mod n = x mod n" by simp
  2433     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2434       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2435   moreover
  2436   {assume xy: "y \<le> x"
  2437     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2438       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2439   ultimately  show ?rhs using linear[of x y] by blast  
  2440 next
  2441   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2442   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2443   thus  ?lhs by simp
  2444 qed
  2445 
  2446 lemma div_nat_numeral [simp]:
  2447   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2448   by (simp add: nat_div_distrib)
  2449 
  2450 lemma one_div_nat_numeral [simp]:
  2451   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2452   by (subst nat_div_distrib, simp_all)
  2453 
  2454 lemma mod_nat_numeral [simp]:
  2455   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2456   by (simp add: nat_mod_distrib)
  2457 
  2458 lemma one_mod_nat_numeral [simp]:
  2459   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2460   by (subst nat_mod_distrib) simp_all
  2461 
  2462 lemma mod_2_not_eq_zero_eq_one_int:
  2463   fixes k :: int
  2464   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2465   by auto
  2466 
  2467 
  2468 subsubsection {* Tools setup *}
  2469 
  2470 text {* Nitpick *}
  2471 
  2472 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2473 
  2474 
  2475 subsubsection {* Code generation *}
  2476 
  2477 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2478   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2479 
  2480 lemma pdivmod_posDivAlg [code]:
  2481   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2482 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2483 
  2484 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2485   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2486     then pdivmod k l
  2487     else (let (r, s) = pdivmod k l in
  2488        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2489 proof -
  2490   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2491   show ?thesis
  2492     by (simp add: divmod_int_mod_div pdivmod_def)
  2493       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2494       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2495 qed
  2496 
  2497 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2498   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2499     then pdivmod k l
  2500     else (let (r, s) = pdivmod k l in
  2501       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2502 proof -
  2503   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2504     by (auto simp add: not_less sgn_if)
  2505   then show ?thesis by (simp add: divmod_int_pdivmod)
  2506 qed
  2507 
  2508 code_modulename SML
  2509   Divides Arith
  2510 
  2511 code_modulename OCaml
  2512   Divides Arith
  2513 
  2514 code_modulename Haskell
  2515   Divides Arith
  2516 
  2517 end