src/HOL/Inductive.thy
author Andreas Lochbihler
Fri Jul 29 09:49:23 2016 +0200 (2016-07-29)
changeset 63561 fba08009ff3e
parent 63540 f8652d0534fa
child 63588 d0e2bad67bd4
permissions -rw-r--r--
add lemmas contributed by Peter Gammie
     1 (*  Title:      HOL/Inductive.thy
     2     Author:     Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 section \<open>Knaster-Tarski Fixpoint Theorem and inductive definitions\<close>
     6 
     7 theory Inductive
     8 imports Complete_Lattices Ctr_Sugar
     9 keywords
    10   "inductive" "coinductive" "inductive_cases" "inductive_simps" :: thy_decl and
    11   "monos" and
    12   "print_inductives" :: diag and
    13   "old_rep_datatype" :: thy_goal and
    14   "primrec" :: thy_decl
    15 begin
    16 
    17 subsection \<open>Least and greatest fixed points\<close>
    18 
    19 context complete_lattice
    20 begin
    21 
    22 definition lfp :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a"  \<comment> \<open>least fixed point\<close>
    23   where "lfp f = Inf {u. f u \<le> u}"
    24 
    25 definition gfp :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a"  \<comment> \<open>greatest fixed point\<close>
    26   where "gfp f = Sup {u. u \<le> f u}"
    27 
    28 
    29 subsection \<open>Proof of Knaster-Tarski Theorem using @{term lfp}\<close>
    30 
    31 text \<open>@{term "lfp f"} is the least upper bound of the set @{term "{u. f u \<le> u}"}\<close>
    32 
    33 lemma lfp_lowerbound: "f A \<le> A \<Longrightarrow> lfp f \<le> A"
    34   by (auto simp add: lfp_def intro: Inf_lower)
    35 
    36 lemma lfp_greatest: "(\<And>u. f u \<le> u \<Longrightarrow> A \<le> u) \<Longrightarrow> A \<le> lfp f"
    37   by (auto simp add: lfp_def intro: Inf_greatest)
    38 
    39 end
    40 
    41 lemma lfp_lemma2: "mono f \<Longrightarrow> f (lfp f) \<le> lfp f"
    42   by (iprover intro: lfp_greatest order_trans monoD lfp_lowerbound)
    43 
    44 lemma lfp_lemma3: "mono f \<Longrightarrow> lfp f \<le> f (lfp f)"
    45   by (iprover intro: lfp_lemma2 monoD lfp_lowerbound)
    46 
    47 lemma lfp_unfold: "mono f \<Longrightarrow> lfp f = f (lfp f)"
    48   by (iprover intro: order_antisym lfp_lemma2 lfp_lemma3)
    49 
    50 lemma lfp_const: "lfp (\<lambda>x. t) = t"
    51   by (rule lfp_unfold) (simp add: mono_def)
    52 
    53 lemma lfp_eqI: "\<lbrakk> mono F; F x = x; \<And>z. F z = z \<Longrightarrow> x \<le> z \<rbrakk> \<Longrightarrow> lfp F = x"
    54 by (rule antisym) (simp_all add: lfp_lowerbound lfp_unfold[symmetric])
    55 
    56 
    57 subsection \<open>General induction rules for least fixed points\<close>
    58 
    59 lemma lfp_ordinal_induct [case_names mono step union]:
    60   fixes f :: "'a::complete_lattice \<Rightarrow> 'a"
    61   assumes mono: "mono f"
    62     and P_f: "\<And>S. P S \<Longrightarrow> S \<le> lfp f \<Longrightarrow> P (f S)"
    63     and P_Union: "\<And>M. \<forall>S\<in>M. P S \<Longrightarrow> P (Sup M)"
    64   shows "P (lfp f)"
    65 proof -
    66   let ?M = "{S. S \<le> lfp f \<and> P S}"
    67   have "P (Sup ?M)" using P_Union by simp
    68   also have "Sup ?M = lfp f"
    69   proof (rule antisym)
    70     show "Sup ?M \<le> lfp f" by (blast intro: Sup_least)
    71     then have "f (Sup ?M) \<le> f (lfp f)"
    72       by (rule mono [THEN monoD])
    73     then have "f (Sup ?M) \<le> lfp f"
    74       using mono [THEN lfp_unfold] by simp
    75     then have "f (Sup ?M) \<in> ?M"
    76       using P_Union by simp (intro P_f Sup_least, auto)
    77     then have "f (Sup ?M) \<le> Sup ?M"
    78       by (rule Sup_upper)
    79     then show "lfp f \<le> Sup ?M"
    80       by (rule lfp_lowerbound)
    81   qed
    82   finally show ?thesis .
    83 qed
    84 
    85 theorem lfp_induct:
    86   assumes mono: "mono f"
    87     and ind: "f (inf (lfp f) P) \<le> P"
    88   shows "lfp f \<le> P"
    89 proof (induction rule: lfp_ordinal_induct)
    90   case (step S)
    91   then show ?case
    92     by (intro order_trans[OF _ ind] monoD[OF mono]) auto
    93 qed (auto intro: mono Sup_least)
    94 
    95 lemma lfp_induct_set:
    96   assumes lfp: "a \<in> lfp f"
    97     and mono: "mono f"
    98     and hyp: "\<And>x. x \<in> f (lfp f \<inter> {x. P x}) \<Longrightarrow> P x"
    99   shows "P a"
   100   by (rule lfp_induct [THEN subsetD, THEN CollectD, OF mono _ lfp]) (auto intro: hyp)
   101 
   102 lemma lfp_ordinal_induct_set:
   103   assumes mono: "mono f"
   104     and P_f: "\<And>S. P S \<Longrightarrow> P (f S)"
   105     and P_Union: "\<And>M. \<forall>S\<in>M. P S \<Longrightarrow> P (\<Union>M)"
   106   shows "P (lfp f)"
   107   using assms by (rule lfp_ordinal_induct)
   108 
   109 
   110 text \<open>Definition forms of \<open>lfp_unfold\<close> and \<open>lfp_induct\<close>, to control unfolding.\<close>
   111 
   112 lemma def_lfp_unfold: "h \<equiv> lfp f \<Longrightarrow> mono f \<Longrightarrow> h = f h"
   113   by (auto intro!: lfp_unfold)
   114 
   115 lemma def_lfp_induct: "A \<equiv> lfp f \<Longrightarrow> mono f \<Longrightarrow> f (inf A P) \<le> P \<Longrightarrow> A \<le> P"
   116   by (blast intro: lfp_induct)
   117 
   118 lemma def_lfp_induct_set:
   119   "A \<equiv> lfp f \<Longrightarrow> mono f \<Longrightarrow> a \<in> A \<Longrightarrow> (\<And>x. x \<in> f (A \<inter> {x. P x}) \<Longrightarrow> P x) \<Longrightarrow> P a"
   120   by (blast intro: lfp_induct_set)
   121 
   122 text \<open>Monotonicity of \<open>lfp\<close>!\<close>
   123 lemma lfp_mono: "(\<And>Z. f Z \<le> g Z) \<Longrightarrow> lfp f \<le> lfp g"
   124   by (rule lfp_lowerbound [THEN lfp_greatest]) (blast intro: order_trans)
   125 
   126 
   127 subsection \<open>Proof of Knaster-Tarski Theorem using \<open>gfp\<close>\<close>
   128 
   129 text \<open>@{term "gfp f"} is the greatest lower bound of the set @{term "{u. u \<le> f u}"}\<close>
   130 
   131 lemma gfp_upperbound: "X \<le> f X \<Longrightarrow> X \<le> gfp f"
   132   by (auto simp add: gfp_def intro: Sup_upper)
   133 
   134 lemma gfp_least: "(\<And>u. u \<le> f u \<Longrightarrow> u \<le> X) \<Longrightarrow> gfp f \<le> X"
   135   by (auto simp add: gfp_def intro: Sup_least)
   136 
   137 lemma gfp_lemma2: "mono f \<Longrightarrow> gfp f \<le> f (gfp f)"
   138   by (iprover intro: gfp_least order_trans monoD gfp_upperbound)
   139 
   140 lemma gfp_lemma3: "mono f \<Longrightarrow> f (gfp f) \<le> gfp f"
   141   by (iprover intro: gfp_lemma2 monoD gfp_upperbound)
   142 
   143 lemma gfp_unfold: "mono f \<Longrightarrow> gfp f = f (gfp f)"
   144   by (iprover intro: order_antisym gfp_lemma2 gfp_lemma3)
   145 
   146 lemma gfp_const: "gfp (\<lambda>x. t) = t"
   147 by (rule gfp_unfold) (simp add: mono_def)
   148 
   149 lemma gfp_eqI: "\<lbrakk> mono F; F x = x; \<And>z. F z = z \<Longrightarrow> z \<le> x \<rbrakk> \<Longrightarrow> gfp F = x"
   150 by (rule antisym) (simp_all add: gfp_upperbound gfp_unfold[symmetric])
   151 
   152 
   153 subsection \<open>Coinduction rules for greatest fixed points\<close>
   154 
   155 text \<open>Weak version.\<close>
   156 lemma weak_coinduct: "a \<in> X \<Longrightarrow> X \<subseteq> f X \<Longrightarrow> a \<in> gfp f"
   157   by (rule gfp_upperbound [THEN subsetD]) auto
   158 
   159 lemma weak_coinduct_image: "a \<in> X \<Longrightarrow> g`X \<subseteq> f (g`X) \<Longrightarrow> g a \<in> gfp f"
   160   apply (erule gfp_upperbound [THEN subsetD])
   161   apply (erule imageI)
   162   done
   163 
   164 lemma coinduct_lemma: "X \<le> f (sup X (gfp f)) \<Longrightarrow> mono f \<Longrightarrow> sup X (gfp f) \<le> f (sup X (gfp f))"
   165   apply (frule gfp_lemma2)
   166   apply (drule mono_sup)
   167   apply (rule le_supI)
   168   apply assumption
   169   apply (rule order_trans)
   170   apply (rule order_trans)
   171   apply assumption
   172   apply (rule sup_ge2)
   173   apply assumption
   174   done
   175 
   176 text \<open>Strong version, thanks to Coen and Frost.\<close>
   177 lemma coinduct_set: "mono f \<Longrightarrow> a \<in> X \<Longrightarrow> X \<subseteq> f (X \<union> gfp f) \<Longrightarrow> a \<in> gfp f"
   178   by (rule weak_coinduct[rotated], rule coinduct_lemma) blast+
   179 
   180 lemma gfp_fun_UnI2: "mono f \<Longrightarrow> a \<in> gfp f \<Longrightarrow> a \<in> f (X \<union> gfp f)"
   181   by (blast dest: gfp_lemma2 mono_Un)
   182 
   183 lemma gfp_ordinal_induct[case_names mono step union]:
   184   fixes f :: "'a::complete_lattice \<Rightarrow> 'a"
   185   assumes mono: "mono f"
   186     and P_f: "\<And>S. P S \<Longrightarrow> gfp f \<le> S \<Longrightarrow> P (f S)"
   187     and P_Union: "\<And>M. \<forall>S\<in>M. P S \<Longrightarrow> P (Inf M)"
   188   shows "P (gfp f)"
   189 proof -
   190   let ?M = "{S. gfp f \<le> S \<and> P S}"
   191   have "P (Inf ?M)" using P_Union by simp
   192   also have "Inf ?M = gfp f"
   193   proof (rule antisym)
   194     show "gfp f \<le> Inf ?M"
   195       by (blast intro: Inf_greatest)
   196     then have "f (gfp f) \<le> f (Inf ?M)"
   197       by (rule mono [THEN monoD])
   198     then have "gfp f \<le> f (Inf ?M)"
   199       using mono [THEN gfp_unfold] by simp
   200     then have "f (Inf ?M) \<in> ?M"
   201       using P_Union by simp (intro P_f Inf_greatest, auto)
   202     then have "Inf ?M \<le> f (Inf ?M)"
   203       by (rule Inf_lower)
   204     then show "Inf ?M \<le> gfp f"
   205       by (rule gfp_upperbound)
   206   qed
   207   finally show ?thesis .
   208 qed
   209 
   210 lemma coinduct:
   211   assumes mono: "mono f"
   212     and ind: "X \<le> f (sup X (gfp f))"
   213   shows "X \<le> gfp f"
   214 proof (induction rule: gfp_ordinal_induct)
   215   case (step S) then show ?case
   216     by (intro order_trans[OF ind _] monoD[OF mono]) auto
   217 qed (auto intro: mono Inf_greatest)
   218 
   219 
   220 subsection \<open>Even Stronger Coinduction Rule, by Martin Coen\<close>
   221 
   222 text \<open>Weakens the condition @{term "X \<subseteq> f X"} to one expressed using both
   223   @{term lfp} and @{term gfp}\<close>
   224 lemma coinduct3_mono_lemma: "mono f \<Longrightarrow> mono (\<lambda>x. f x \<union> X \<union> B)"
   225   by (iprover intro: subset_refl monoI Un_mono monoD)
   226 
   227 lemma coinduct3_lemma:
   228   "X \<subseteq> f (lfp (\<lambda>x. f x \<union> X \<union> gfp f)) \<Longrightarrow> mono f \<Longrightarrow>
   229     lfp (\<lambda>x. f x \<union> X \<union> gfp f) \<subseteq> f (lfp (\<lambda>x. f x \<union> X \<union> gfp f))"
   230   apply (rule subset_trans)
   231   apply (erule coinduct3_mono_lemma [THEN lfp_lemma3])
   232   apply (rule Un_least [THEN Un_least])
   233   apply (rule subset_refl, assumption)
   234   apply (rule gfp_unfold [THEN equalityD1, THEN subset_trans], assumption)
   235   apply (rule monoD, assumption)
   236   apply (subst coinduct3_mono_lemma [THEN lfp_unfold], auto)
   237   done
   238 
   239 lemma coinduct3: "mono f \<Longrightarrow> a \<in> X \<Longrightarrow> X \<subseteq> f (lfp (\<lambda>x. f x \<union> X \<union> gfp f)) \<Longrightarrow> a \<in> gfp f"
   240   apply (rule coinduct3_lemma [THEN [2] weak_coinduct])
   241   apply (rule coinduct3_mono_lemma [THEN lfp_unfold, THEN ssubst])
   242   apply simp_all
   243   done
   244 
   245 text  \<open>Definition forms of \<open>gfp_unfold\<close> and \<open>coinduct\<close>, to control unfolding.\<close>
   246 
   247 lemma def_gfp_unfold: "A \<equiv> gfp f \<Longrightarrow> mono f \<Longrightarrow> A = f A"
   248   by (auto intro!: gfp_unfold)
   249 
   250 lemma def_coinduct: "A \<equiv> gfp f \<Longrightarrow> mono f \<Longrightarrow> X \<le> f (sup X A) \<Longrightarrow> X \<le> A"
   251   by (iprover intro!: coinduct)
   252 
   253 lemma def_coinduct_set: "A \<equiv> gfp f \<Longrightarrow> mono f \<Longrightarrow> a \<in> X \<Longrightarrow> X \<subseteq> f (X \<union> A) \<Longrightarrow> a \<in> A"
   254   by (auto intro!: coinduct_set)
   255 
   256 lemma def_Collect_coinduct:
   257   "A \<equiv> gfp (\<lambda>w. Collect (P w)) \<Longrightarrow> mono (\<lambda>w. Collect (P w)) \<Longrightarrow> a \<in> X \<Longrightarrow>
   258     (\<And>z. z \<in> X \<Longrightarrow> P (X \<union> A) z) \<Longrightarrow> a \<in> A"
   259   by (erule def_coinduct_set) auto
   260 
   261 lemma def_coinduct3: "A \<equiv> gfp f \<Longrightarrow> mono f \<Longrightarrow> a \<in> X \<Longrightarrow> X \<subseteq> f (lfp (\<lambda>x. f x \<union> X \<union> A)) \<Longrightarrow> a \<in> A"
   262   by (auto intro!: coinduct3)
   263 
   264 text \<open>Monotonicity of @{term gfp}!\<close>
   265 lemma gfp_mono: "(\<And>Z. f Z \<le> g Z) \<Longrightarrow> gfp f \<le> gfp g"
   266   by (rule gfp_upperbound [THEN gfp_least]) (blast intro: order_trans)
   267 
   268 
   269 subsection \<open>Rules for fixed point calculus\<close>
   270 
   271 lemma lfp_rolling:
   272   assumes "mono g" "mono f"
   273   shows "g (lfp (\<lambda>x. f (g x))) = lfp (\<lambda>x. g (f x))"
   274 proof (rule antisym)
   275   have *: "mono (\<lambda>x. f (g x))"
   276     using assms by (auto simp: mono_def)
   277   show "lfp (\<lambda>x. g (f x)) \<le> g (lfp (\<lambda>x. f (g x)))"
   278     by (rule lfp_lowerbound) (simp add: lfp_unfold[OF *, symmetric])
   279   show "g (lfp (\<lambda>x. f (g x))) \<le> lfp (\<lambda>x. g (f x))"
   280   proof (rule lfp_greatest)
   281     fix u
   282     assume u: "g (f u) \<le> u"
   283     then have "g (lfp (\<lambda>x. f (g x))) \<le> g (f u)"
   284       by (intro assms[THEN monoD] lfp_lowerbound)
   285     with u show "g (lfp (\<lambda>x. f (g x))) \<le> u"
   286       by auto
   287   qed
   288 qed
   289 
   290 lemma lfp_lfp:
   291   assumes f: "\<And>x y w z. x \<le> y \<Longrightarrow> w \<le> z \<Longrightarrow> f x w \<le> f y z"
   292   shows "lfp (\<lambda>x. lfp (f x)) = lfp (\<lambda>x. f x x)"
   293 proof (rule antisym)
   294   have *: "mono (\<lambda>x. f x x)"
   295     by (blast intro: monoI f)
   296   show "lfp (\<lambda>x. lfp (f x)) \<le> lfp (\<lambda>x. f x x)"
   297     by (intro lfp_lowerbound) (simp add: lfp_unfold[OF *, symmetric])
   298   show "lfp (\<lambda>x. lfp (f x)) \<ge> lfp (\<lambda>x. f x x)" (is "?F \<ge> _")
   299   proof (intro lfp_lowerbound)
   300     have *: "?F = lfp (f ?F)"
   301       by (rule lfp_unfold) (blast intro: monoI lfp_mono f)
   302     also have "\<dots> = f ?F (lfp (f ?F))"
   303       by (rule lfp_unfold) (blast intro: monoI lfp_mono f)
   304     finally show "f ?F ?F \<le> ?F"
   305       by (simp add: *[symmetric])
   306   qed
   307 qed
   308 
   309 lemma gfp_rolling:
   310   assumes "mono g" "mono f"
   311   shows "g (gfp (\<lambda>x. f (g x))) = gfp (\<lambda>x. g (f x))"
   312 proof (rule antisym)
   313   have *: "mono (\<lambda>x. f (g x))"
   314     using assms by (auto simp: mono_def)
   315   show "g (gfp (\<lambda>x. f (g x))) \<le> gfp (\<lambda>x. g (f x))"
   316     by (rule gfp_upperbound) (simp add: gfp_unfold[OF *, symmetric])
   317   show "gfp (\<lambda>x. g (f x)) \<le> g (gfp (\<lambda>x. f (g x)))"
   318   proof (rule gfp_least)
   319     fix u
   320     assume u: "u \<le> g (f u)"
   321     then have "g (f u) \<le> g (gfp (\<lambda>x. f (g x)))"
   322       by (intro assms[THEN monoD] gfp_upperbound)
   323     with u show "u \<le> g (gfp (\<lambda>x. f (g x)))"
   324       by auto
   325   qed
   326 qed
   327 
   328 lemma gfp_gfp:
   329   assumes f: "\<And>x y w z. x \<le> y \<Longrightarrow> w \<le> z \<Longrightarrow> f x w \<le> f y z"
   330   shows "gfp (\<lambda>x. gfp (f x)) = gfp (\<lambda>x. f x x)"
   331 proof (rule antisym)
   332   have *: "mono (\<lambda>x. f x x)"
   333     by (blast intro: monoI f)
   334   show "gfp (\<lambda>x. f x x) \<le> gfp (\<lambda>x. gfp (f x))"
   335     by (intro gfp_upperbound) (simp add: gfp_unfold[OF *, symmetric])
   336   show "gfp (\<lambda>x. gfp (f x)) \<le> gfp (\<lambda>x. f x x)" (is "?F \<le> _")
   337   proof (intro gfp_upperbound)
   338     have *: "?F = gfp (f ?F)"
   339       by (rule gfp_unfold) (blast intro: monoI gfp_mono f)
   340     also have "\<dots> = f ?F (gfp (f ?F))"
   341       by (rule gfp_unfold) (blast intro: monoI gfp_mono f)
   342     finally show "?F \<le> f ?F ?F"
   343       by (simp add: *[symmetric])
   344   qed
   345 qed
   346 
   347 
   348 subsection \<open>Inductive predicates and sets\<close>
   349 
   350 text \<open>Package setup.\<close>
   351 
   352 lemmas basic_monos =
   353   subset_refl imp_refl disj_mono conj_mono ex_mono all_mono if_bool_eq_conj
   354   Collect_mono in_mono vimage_mono
   355 
   356 ML_file "Tools/inductive.ML"
   357 
   358 lemmas [mono] =
   359   imp_refl disj_mono conj_mono ex_mono all_mono if_bool_eq_conj
   360   imp_mono not_mono
   361   Ball_def Bex_def
   362   induct_rulify_fallback
   363 
   364 
   365 subsection \<open>Inductive datatypes and primitive recursion\<close>
   366 
   367 text \<open>Package setup.\<close>
   368 
   369 ML_file "Tools/Old_Datatype/old_datatype_aux.ML"
   370 ML_file "Tools/Old_Datatype/old_datatype_prop.ML"
   371 ML_file "Tools/Old_Datatype/old_datatype_data.ML"
   372 ML_file "Tools/Old_Datatype/old_rep_datatype.ML"
   373 ML_file "Tools/Old_Datatype/old_datatype_codegen.ML"
   374 ML_file "Tools/Old_Datatype/old_primrec.ML"
   375 
   376 ML_file "Tools/BNF/bnf_fp_rec_sugar_util.ML"
   377 ML_file "Tools/BNF/bnf_lfp_rec_sugar.ML"
   378 
   379 text \<open>Lambda-abstractions with pattern matching:\<close>
   380 syntax (ASCII)
   381   "_lam_pats_syntax" :: "cases_syn \<Rightarrow> 'a \<Rightarrow> 'b"  ("(%_)" 10)
   382 syntax
   383   "_lam_pats_syntax" :: "cases_syn \<Rightarrow> 'a \<Rightarrow> 'b"  ("(\<lambda>_)" 10)
   384 parse_translation \<open>
   385   let
   386     fun fun_tr ctxt [cs] =
   387       let
   388         val x = Syntax.free (fst (Name.variant "x" (Term.declare_term_frees cs Name.context)));
   389         val ft = Case_Translation.case_tr true ctxt [x, cs];
   390       in lambda x ft end
   391   in [(@{syntax_const "_lam_pats_syntax"}, fun_tr)] end
   392 \<close>
   393 
   394 end