src/HOL/Library/Product_Vector.thy
author wenzelm
Wed Sep 12 13:42:28 2012 +0200 (2012-09-12)
changeset 49322 fbb320d02420
parent 44749 5b1e1432c320
child 49962 a8cc904a6820
permissions -rw-r--r--
tuned headers;
     1 (*  Title:      HOL/Library/Product_Vector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Cartesian Products as Vector Spaces *}
     6 
     7 theory Product_Vector
     8 imports Inner_Product Product_plus
     9 begin
    10 
    11 subsection {* Product is a real vector space *}
    12 
    13 instantiation prod :: (real_vector, real_vector) real_vector
    14 begin
    15 
    16 definition scaleR_prod_def:
    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
    18 
    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
    20   unfolding scaleR_prod_def by simp
    21 
    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
    23   unfolding scaleR_prod_def by simp
    24 
    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
    26   unfolding scaleR_prod_def by simp
    27 
    28 instance proof
    29   fix a b :: real and x y :: "'a \<times> 'b"
    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
    31     by (simp add: prod_eq_iff scaleR_right_distrib)
    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
    33     by (simp add: prod_eq_iff scaleR_left_distrib)
    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
    35     by (simp add: prod_eq_iff)
    36   show "scaleR 1 x = x"
    37     by (simp add: prod_eq_iff)
    38 qed
    39 
    40 end
    41 
    42 subsection {* Product is a topological space *}
    43 
    44 instantiation prod :: (topological_space, topological_space) topological_space
    45 begin
    46 
    47 definition open_prod_def:
    48   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
    49     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
    50 
    51 lemma open_prod_elim:
    52   assumes "open S" and "x \<in> S"
    53   obtains A B where "open A" and "open B" and "x \<in> A \<times> B" and "A \<times> B \<subseteq> S"
    54 using assms unfolding open_prod_def by fast
    55 
    56 lemma open_prod_intro:
    57   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S"
    58   shows "open S"
    59 using assms unfolding open_prod_def by fast
    60 
    61 instance proof
    62   show "open (UNIV :: ('a \<times> 'b) set)"
    63     unfolding open_prod_def by auto
    64 next
    65   fix S T :: "('a \<times> 'b) set"
    66   assume "open S" "open T"
    67   show "open (S \<inter> T)"
    68   proof (rule open_prod_intro)
    69     fix x assume x: "x \<in> S \<inter> T"
    70     from x have "x \<in> S" by simp
    71     obtain Sa Sb where A: "open Sa" "open Sb" "x \<in> Sa \<times> Sb" "Sa \<times> Sb \<subseteq> S"
    72       using `open S` and `x \<in> S` by (rule open_prod_elim)
    73     from x have "x \<in> T" by simp
    74     obtain Ta Tb where B: "open Ta" "open Tb" "x \<in> Ta \<times> Tb" "Ta \<times> Tb \<subseteq> T"
    75       using `open T` and `x \<in> T` by (rule open_prod_elim)
    76     let ?A = "Sa \<inter> Ta" and ?B = "Sb \<inter> Tb"
    77     have "open ?A \<and> open ?B \<and> x \<in> ?A \<times> ?B \<and> ?A \<times> ?B \<subseteq> S \<inter> T"
    78       using A B by (auto simp add: open_Int)
    79     thus "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S \<inter> T"
    80       by fast
    81   qed
    82 next
    83   fix K :: "('a \<times> 'b) set set"
    84   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
    85     unfolding open_prod_def by fast
    86 qed
    87 
    88 end
    89 
    90 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
    91 unfolding open_prod_def by auto
    92 
    93 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
    94 by auto
    95 
    96 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
    97 by auto
    98 
    99 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
   100 by (simp add: fst_vimage_eq_Times open_Times)
   101 
   102 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
   103 by (simp add: snd_vimage_eq_Times open_Times)
   104 
   105 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
   106 unfolding closed_open vimage_Compl [symmetric]
   107 by (rule open_vimage_fst)
   108 
   109 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
   110 unfolding closed_open vimage_Compl [symmetric]
   111 by (rule open_vimage_snd)
   112 
   113 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
   114 proof -
   115   have "S \<times> T = (fst -` S) \<inter> (snd -` T)" by auto
   116   thus "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
   117     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
   118 qed
   119 
   120 lemma openI: (* TODO: move *)
   121   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
   122   shows "open S"
   123 proof -
   124   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
   125   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
   126   ultimately show "open S" by simp
   127 qed
   128 
   129 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
   130   unfolding image_def subset_eq by force
   131 
   132 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
   133   unfolding image_def subset_eq by force
   134 
   135 lemma open_image_fst: assumes "open S" shows "open (fst ` S)"
   136 proof (rule openI)
   137   fix x assume "x \<in> fst ` S"
   138   then obtain y where "(x, y) \<in> S" by auto
   139   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   140     using `open S` unfolding open_prod_def by auto
   141   from `A \<times> B \<subseteq> S` `y \<in> B` have "A \<subseteq> fst ` S" by (rule subset_fst_imageI)
   142   with `open A` `x \<in> A` have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S" by simp
   143   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" by - (rule exI)
   144 qed
   145 
   146 lemma open_image_snd: assumes "open S" shows "open (snd ` S)"
   147 proof (rule openI)
   148   fix y assume "y \<in> snd ` S"
   149   then obtain x where "(x, y) \<in> S" by auto
   150   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   151     using `open S` unfolding open_prod_def by auto
   152   from `A \<times> B \<subseteq> S` `x \<in> A` have "B \<subseteq> snd ` S" by (rule subset_snd_imageI)
   153   with `open B` `y \<in> B` have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S" by simp
   154   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" by - (rule exI)
   155 qed
   156 
   157 subsubsection {* Continuity of operations *}
   158 
   159 lemma tendsto_fst [tendsto_intros]:
   160   assumes "(f ---> a) F"
   161   shows "((\<lambda>x. fst (f x)) ---> fst a) F"
   162 proof (rule topological_tendstoI)
   163   fix S assume "open S" and "fst a \<in> S"
   164   then have "open (fst -` S)" and "a \<in> fst -` S"
   165     by (simp_all add: open_vimage_fst)
   166   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) F"
   167     by (rule topological_tendstoD)
   168   then show "eventually (\<lambda>x. fst (f x) \<in> S) F"
   169     by simp
   170 qed
   171 
   172 lemma tendsto_snd [tendsto_intros]:
   173   assumes "(f ---> a) F"
   174   shows "((\<lambda>x. snd (f x)) ---> snd a) F"
   175 proof (rule topological_tendstoI)
   176   fix S assume "open S" and "snd a \<in> S"
   177   then have "open (snd -` S)" and "a \<in> snd -` S"
   178     by (simp_all add: open_vimage_snd)
   179   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) F"
   180     by (rule topological_tendstoD)
   181   then show "eventually (\<lambda>x. snd (f x) \<in> S) F"
   182     by simp
   183 qed
   184 
   185 lemma tendsto_Pair [tendsto_intros]:
   186   assumes "(f ---> a) F" and "(g ---> b) F"
   187   shows "((\<lambda>x. (f x, g x)) ---> (a, b)) F"
   188 proof (rule topological_tendstoI)
   189   fix S assume "open S" and "(a, b) \<in> S"
   190   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
   191     unfolding open_prod_def by fast
   192   have "eventually (\<lambda>x. f x \<in> A) F"
   193     using `(f ---> a) F` `open A` `a \<in> A`
   194     by (rule topological_tendstoD)
   195   moreover
   196   have "eventually (\<lambda>x. g x \<in> B) F"
   197     using `(g ---> b) F` `open B` `b \<in> B`
   198     by (rule topological_tendstoD)
   199   ultimately
   200   show "eventually (\<lambda>x. (f x, g x) \<in> S) F"
   201     by (rule eventually_elim2)
   202        (simp add: subsetD [OF `A \<times> B \<subseteq> S`])
   203 qed
   204 
   205 lemma isCont_fst [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. fst (f x)) a"
   206   unfolding isCont_def by (rule tendsto_fst)
   207 
   208 lemma isCont_snd [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. snd (f x)) a"
   209   unfolding isCont_def by (rule tendsto_snd)
   210 
   211 lemma isCont_Pair [simp]:
   212   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) a"
   213   unfolding isCont_def by (rule tendsto_Pair)
   214 
   215 subsubsection {* Separation axioms *}
   216 
   217 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
   218   by (induct x) simp (* TODO: move elsewhere *)
   219 
   220 instance prod :: (t0_space, t0_space) t0_space
   221 proof
   222   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   223   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   224     by (simp add: prod_eq_iff)
   225   thus "\<exists>U. open U \<and> (x \<in> U) \<noteq> (y \<in> U)"
   226     apply (rule disjE)
   227     apply (drule t0_space, erule exE, rule_tac x="U \<times> UNIV" in exI)
   228     apply (simp add: open_Times mem_Times_iff)
   229     apply (drule t0_space, erule exE, rule_tac x="UNIV \<times> U" in exI)
   230     apply (simp add: open_Times mem_Times_iff)
   231     done
   232 qed
   233 
   234 instance prod :: (t1_space, t1_space) t1_space
   235 proof
   236   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   237   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   238     by (simp add: prod_eq_iff)
   239   thus "\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   240     apply (rule disjE)
   241     apply (drule t1_space, erule exE, rule_tac x="U \<times> UNIV" in exI)
   242     apply (simp add: open_Times mem_Times_iff)
   243     apply (drule t1_space, erule exE, rule_tac x="UNIV \<times> U" in exI)
   244     apply (simp add: open_Times mem_Times_iff)
   245     done
   246 qed
   247 
   248 instance prod :: (t2_space, t2_space) t2_space
   249 proof
   250   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   251   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   252     by (simp add: prod_eq_iff)
   253   thus "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   254     apply (rule disjE)
   255     apply (drule hausdorff, clarify)
   256     apply (rule_tac x="U \<times> UNIV" in exI, rule_tac x="V \<times> UNIV" in exI)
   257     apply (simp add: open_Times mem_Times_iff disjoint_iff_not_equal)
   258     apply (drule hausdorff, clarify)
   259     apply (rule_tac x="UNIV \<times> U" in exI, rule_tac x="UNIV \<times> V" in exI)
   260     apply (simp add: open_Times mem_Times_iff disjoint_iff_not_equal)
   261     done
   262 qed
   263 
   264 subsection {* Product is a metric space *}
   265 
   266 instantiation prod :: (metric_space, metric_space) metric_space
   267 begin
   268 
   269 definition dist_prod_def:
   270   "dist x y = sqrt ((dist (fst x) (fst y))\<twosuperior> + (dist (snd x) (snd y))\<twosuperior>)"
   271 
   272 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<twosuperior> + (dist b d)\<twosuperior>)"
   273   unfolding dist_prod_def by simp
   274 
   275 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
   276 unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge1)
   277 
   278 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
   279 unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge2)
   280 
   281 instance proof
   282   fix x y :: "'a \<times> 'b"
   283   show "dist x y = 0 \<longleftrightarrow> x = y"
   284     unfolding dist_prod_def prod_eq_iff by simp
   285 next
   286   fix x y z :: "'a \<times> 'b"
   287   show "dist x y \<le> dist x z + dist y z"
   288     unfolding dist_prod_def
   289     by (intro order_trans [OF _ real_sqrt_sum_squares_triangle_ineq]
   290         real_sqrt_le_mono add_mono power_mono dist_triangle2 zero_le_dist)
   291 next
   292   fix S :: "('a \<times> 'b) set"
   293   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   294   proof
   295     assume "open S" show "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   296     proof
   297       fix x assume "x \<in> S"
   298       obtain A B where "open A" "open B" "x \<in> A \<times> B" "A \<times> B \<subseteq> S"
   299         using `open S` and `x \<in> S` by (rule open_prod_elim)
   300       obtain r where r: "0 < r" "\<forall>y. dist y (fst x) < r \<longrightarrow> y \<in> A"
   301         using `open A` and `x \<in> A \<times> B` unfolding open_dist by auto
   302       obtain s where s: "0 < s" "\<forall>y. dist y (snd x) < s \<longrightarrow> y \<in> B"
   303         using `open B` and `x \<in> A \<times> B` unfolding open_dist by auto
   304       let ?e = "min r s"
   305       have "0 < ?e \<and> (\<forall>y. dist y x < ?e \<longrightarrow> y \<in> S)"
   306       proof (intro allI impI conjI)
   307         show "0 < min r s" by (simp add: r(1) s(1))
   308       next
   309         fix y assume "dist y x < min r s"
   310         hence "dist y x < r" and "dist y x < s"
   311           by simp_all
   312         hence "dist (fst y) (fst x) < r" and "dist (snd y) (snd x) < s"
   313           by (auto intro: le_less_trans dist_fst_le dist_snd_le)
   314         hence "fst y \<in> A" and "snd y \<in> B"
   315           by (simp_all add: r(2) s(2))
   316         hence "y \<in> A \<times> B" by (induct y, simp)
   317         with `A \<times> B \<subseteq> S` show "y \<in> S" ..
   318       qed
   319       thus "\<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" ..
   320     qed
   321   next
   322     assume *: "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" show "open S"
   323     proof (rule open_prod_intro)
   324       fix x assume "x \<in> S"
   325       then obtain e where "0 < e" and S: "\<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   326         using * by fast
   327       def r \<equiv> "e / sqrt 2" and s \<equiv> "e / sqrt 2"
   328       from `0 < e` have "0 < r" and "0 < s"
   329         unfolding r_def s_def by (simp_all add: divide_pos_pos)
   330       from `0 < e` have "e = sqrt (r\<twosuperior> + s\<twosuperior>)"
   331         unfolding r_def s_def by (simp add: power_divide)
   332       def A \<equiv> "{y. dist (fst x) y < r}" and B \<equiv> "{y. dist (snd x) y < s}"
   333       have "open A" and "open B"
   334         unfolding A_def B_def by (simp_all add: open_ball)
   335       moreover have "x \<in> A \<times> B"
   336         unfolding A_def B_def mem_Times_iff
   337         using `0 < r` and `0 < s` by simp
   338       moreover have "A \<times> B \<subseteq> S"
   339       proof (clarify)
   340         fix a b assume "a \<in> A" and "b \<in> B"
   341         hence "dist a (fst x) < r" and "dist b (snd x) < s"
   342           unfolding A_def B_def by (simp_all add: dist_commute)
   343         hence "dist (a, b) x < e"
   344           unfolding dist_prod_def `e = sqrt (r\<twosuperior> + s\<twosuperior>)`
   345           by (simp add: add_strict_mono power_strict_mono)
   346         thus "(a, b) \<in> S"
   347           by (simp add: S)
   348       qed
   349       ultimately show "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S" by fast
   350     qed
   351   qed
   352 qed
   353 
   354 end
   355 
   356 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
   357 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
   358 
   359 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
   360 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
   361 
   362 lemma Cauchy_Pair:
   363   assumes "Cauchy X" and "Cauchy Y"
   364   shows "Cauchy (\<lambda>n. (X n, Y n))"
   365 proof (rule metric_CauchyI)
   366   fix r :: real assume "0 < r"
   367   then have "0 < r / sqrt 2" (is "0 < ?s")
   368     by (simp add: divide_pos_pos)
   369   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
   370     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
   371   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
   372     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
   373   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
   374     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   375   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
   376 qed
   377 
   378 subsection {* Product is a complete metric space *}
   379 
   380 instance prod :: (complete_space, complete_space) complete_space
   381 proof
   382   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
   383   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
   384     using Cauchy_fst [OF `Cauchy X`]
   385     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   386   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
   387     using Cauchy_snd [OF `Cauchy X`]
   388     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   389   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
   390     using tendsto_Pair [OF 1 2] by simp
   391   then show "convergent X"
   392     by (rule convergentI)
   393 qed
   394 
   395 subsection {* Product is a normed vector space *}
   396 
   397 instantiation prod :: (real_normed_vector, real_normed_vector) real_normed_vector
   398 begin
   399 
   400 definition norm_prod_def:
   401   "norm x = sqrt ((norm (fst x))\<twosuperior> + (norm (snd x))\<twosuperior>)"
   402 
   403 definition sgn_prod_def:
   404   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
   405 
   406 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<twosuperior> + (norm b)\<twosuperior>)"
   407   unfolding norm_prod_def by simp
   408 
   409 instance proof
   410   fix r :: real and x y :: "'a \<times> 'b"
   411   show "0 \<le> norm x"
   412     unfolding norm_prod_def by simp
   413   show "norm x = 0 \<longleftrightarrow> x = 0"
   414     unfolding norm_prod_def
   415     by (simp add: prod_eq_iff)
   416   show "norm (x + y) \<le> norm x + norm y"
   417     unfolding norm_prod_def
   418     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
   419     apply (simp add: add_mono power_mono norm_triangle_ineq)
   420     done
   421   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   422     unfolding norm_prod_def
   423     apply (simp add: power_mult_distrib)
   424     apply (simp add: right_distrib [symmetric])
   425     apply (simp add: real_sqrt_mult_distrib)
   426     done
   427   show "sgn x = scaleR (inverse (norm x)) x"
   428     by (rule sgn_prod_def)
   429   show "dist x y = norm (x - y)"
   430     unfolding dist_prod_def norm_prod_def
   431     by (simp add: dist_norm)
   432 qed
   433 
   434 end
   435 
   436 instance prod :: (banach, banach) banach ..
   437 
   438 subsubsection {* Pair operations are linear *}
   439 
   440 lemma bounded_linear_fst: "bounded_linear fst"
   441   using fst_add fst_scaleR
   442   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
   443 
   444 lemma bounded_linear_snd: "bounded_linear snd"
   445   using snd_add snd_scaleR
   446   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
   447 
   448 text {* TODO: move to NthRoot *}
   449 lemma sqrt_add_le_add_sqrt:
   450   assumes x: "0 \<le> x" and y: "0 \<le> y"
   451   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   452 apply (rule power2_le_imp_le)
   453 apply (simp add: power2_sum x y)
   454 apply (simp add: mult_nonneg_nonneg x y)
   455 apply (simp add: x y)
   456 done
   457 
   458 lemma bounded_linear_Pair:
   459   assumes f: "bounded_linear f"
   460   assumes g: "bounded_linear g"
   461   shows "bounded_linear (\<lambda>x. (f x, g x))"
   462 proof
   463   interpret f: bounded_linear f by fact
   464   interpret g: bounded_linear g by fact
   465   fix x y and r :: real
   466   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
   467     by (simp add: f.add g.add)
   468   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
   469     by (simp add: f.scaleR g.scaleR)
   470   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
   471     using f.pos_bounded by fast
   472   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
   473     using g.pos_bounded by fast
   474   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
   475     apply (rule allI)
   476     apply (simp add: norm_Pair)
   477     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
   478     apply (simp add: right_distrib)
   479     apply (rule add_mono [OF norm_f norm_g])
   480     done
   481   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
   482 qed
   483 
   484 subsubsection {* Frechet derivatives involving pairs *}
   485 
   486 lemma FDERIV_Pair:
   487   assumes f: "FDERIV f x :> f'" and g: "FDERIV g x :> g'"
   488   shows "FDERIV (\<lambda>x. (f x, g x)) x :> (\<lambda>h. (f' h, g' h))"
   489 proof (rule FDERIV_I)
   490   show "bounded_linear (\<lambda>h. (f' h, g' h))"
   491     using f g by (intro bounded_linear_Pair FDERIV_bounded_linear)
   492   let ?Rf = "\<lambda>h. f (x + h) - f x - f' h"
   493   let ?Rg = "\<lambda>h. g (x + h) - g x - g' h"
   494   let ?R = "\<lambda>h. ((f (x + h), g (x + h)) - (f x, g x) - (f' h, g' h))"
   495   show "(\<lambda>h. norm (?R h) / norm h) -- 0 --> 0"
   496   proof (rule real_LIM_sandwich_zero)
   497     show "(\<lambda>h. norm (?Rf h) / norm h + norm (?Rg h) / norm h) -- 0 --> 0"
   498       using f g by (intro tendsto_add_zero FDERIV_D)
   499     fix h :: 'a assume "h \<noteq> 0"
   500     thus "0 \<le> norm (?R h) / norm h"
   501       by (simp add: divide_nonneg_pos)
   502     show "norm (?R h) / norm h \<le> norm (?Rf h) / norm h + norm (?Rg h) / norm h"
   503       unfolding add_divide_distrib [symmetric]
   504       by (simp add: norm_Pair divide_right_mono
   505         order_trans [OF sqrt_add_le_add_sqrt])
   506   qed
   507 qed
   508 
   509 subsection {* Product is an inner product space *}
   510 
   511 instantiation prod :: (real_inner, real_inner) real_inner
   512 begin
   513 
   514 definition inner_prod_def:
   515   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
   516 
   517 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
   518   unfolding inner_prod_def by simp
   519 
   520 instance proof
   521   fix r :: real
   522   fix x y z :: "'a::real_inner \<times> 'b::real_inner"
   523   show "inner x y = inner y x"
   524     unfolding inner_prod_def
   525     by (simp add: inner_commute)
   526   show "inner (x + y) z = inner x z + inner y z"
   527     unfolding inner_prod_def
   528     by (simp add: inner_add_left)
   529   show "inner (scaleR r x) y = r * inner x y"
   530     unfolding inner_prod_def
   531     by (simp add: right_distrib)
   532   show "0 \<le> inner x x"
   533     unfolding inner_prod_def
   534     by (intro add_nonneg_nonneg inner_ge_zero)
   535   show "inner x x = 0 \<longleftrightarrow> x = 0"
   536     unfolding inner_prod_def prod_eq_iff
   537     by (simp add: add_nonneg_eq_0_iff)
   538   show "norm x = sqrt (inner x x)"
   539     unfolding norm_prod_def inner_prod_def
   540     by (simp add: power2_norm_eq_inner)
   541 qed
   542 
   543 end
   544 
   545 end