src/HOL/Tools/Datatype/datatype.ML
author bulwahn
Wed Sep 23 16:20:12 2009 +0200 (2009-09-23)
changeset 32671 fbd224850767
parent 32374 62617ef2c0d0
child 32712 ec5976f4d3d8
permissions -rw-r--r--
adapted configuration for DatatypeCase.make_case
     1 (*  Title:      HOL/Tools/datatype.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Datatype package for Isabelle/HOL.
     5 *)
     6 
     7 signature DATATYPE =
     8 sig
     9   include DATATYPE_COMMON
    10   val add_datatype : config -> string list -> (string list * binding * mixfix *
    11     (binding * typ list * mixfix) list) list -> theory -> string list * theory
    12   val datatype_cmd : string list -> (string list * binding * mixfix *
    13     (binding * string list * mixfix) list) list -> theory -> theory
    14   val rep_datatype : config -> (string list -> Proof.context -> Proof.context)
    15     -> string list option -> term list -> theory -> Proof.state
    16   val rep_datatype_cmd : string list option -> string list -> theory -> Proof.state
    17   val get_info : theory -> string -> info option
    18   val the_info : theory -> string -> info
    19   val the_descr : theory -> string list
    20     -> descr * (string * sort) list * string list
    21       * string * (string list * string list) * (typ list * typ list)
    22   val the_spec : theory -> string -> (string * sort) list * (string * typ list) list
    23   val get_constrs : theory -> string -> (string * typ) list option
    24   val get_all : theory -> info Symtab.table
    25   val info_of_constr : theory -> string -> info option
    26   val info_of_case : theory -> string -> info option
    27   val interpretation : (config -> string list -> theory -> theory) -> theory -> theory
    28   val distinct_simproc : simproc
    29   val make_case :  Proof.context -> DatatypeCase.config -> string list -> term ->
    30     (term * term) list -> term * (term * (int * bool)) list
    31   val strip_case : Proof.context -> bool -> term -> (term * (term * term) list) option
    32   val read_typ: theory ->
    33     (typ list * (string * sort) list) * string -> typ list * (string * sort) list
    34   val setup: theory -> theory
    35 end;
    36 
    37 structure Datatype : DATATYPE =
    38 struct
    39 
    40 open DatatypeAux;
    41 
    42 
    43 (* theory data *)
    44 
    45 structure DatatypesData = TheoryDataFun
    46 (
    47   type T =
    48     {types: info Symtab.table,
    49      constrs: info Symtab.table,
    50      cases: info Symtab.table};
    51 
    52   val empty =
    53     {types = Symtab.empty, constrs = Symtab.empty, cases = Symtab.empty};
    54   val copy = I;
    55   val extend = I;
    56   fun merge _
    57     ({types = types1, constrs = constrs1, cases = cases1},
    58      {types = types2, constrs = constrs2, cases = cases2}) =
    59     {types = Symtab.merge (K true) (types1, types2),
    60      constrs = Symtab.merge (K true) (constrs1, constrs2),
    61      cases = Symtab.merge (K true) (cases1, cases2)};
    62 );
    63 
    64 val get_all = #types o DatatypesData.get;
    65 val map_datatypes = DatatypesData.map;
    66 
    67 
    68 (** theory information about datatypes **)
    69 
    70 fun put_dt_infos (dt_infos : (string * info) list) =
    71   map_datatypes (fn {types, constrs, cases} =>
    72     {types = fold Symtab.update dt_infos types,
    73      constrs = fold Symtab.default (*conservative wrt. overloaded constructors*)
    74        (maps (fn (_, info as {descr, index, ...}) => map (rpair info o fst)
    75           (#3 (the (AList.lookup op = descr index)))) dt_infos) constrs,
    76      cases = fold Symtab.update
    77        (map (fn (_, info as {case_name, ...}) => (case_name, info)) dt_infos)
    78        cases});
    79 
    80 val get_info = Symtab.lookup o get_all;
    81 
    82 fun the_info thy name = (case get_info thy name of
    83       SOME info => info
    84     | NONE => error ("Unknown datatype " ^ quote name));
    85 
    86 val info_of_constr = Symtab.lookup o #constrs o DatatypesData.get;
    87 val info_of_case = Symtab.lookup o #cases o DatatypesData.get;
    88 
    89 fun get_info_descr thy dtco =
    90   get_info thy dtco
    91   |> Option.map (fn info as { descr, index, ... } =>
    92        (info, (((fn SOME (_, dtys, cos) => (dtys, cos)) o AList.lookup (op =) descr) index)));
    93 
    94 fun the_spec thy dtco =
    95   let
    96     val info as { descr, index, sorts = raw_sorts, ... } = the_info thy dtco;
    97     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr index;
    98     val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
    99       o DatatypeAux.dest_DtTFree) dtys;
   100     val cos = map
   101       (fn (co, tys) => (co, map (DatatypeAux.typ_of_dtyp descr sorts) tys)) raw_cos;
   102   in (sorts, cos) end;
   103 
   104 fun the_descr thy (raw_tycos as raw_tyco :: _) =
   105   let
   106     val info = the_info thy raw_tyco;
   107     val descr = #descr info;
   108 
   109     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr (#index info);
   110     val vs = map ((fn v => (v, (the o AList.lookup (op =) (#sorts info)) v))
   111       o dest_DtTFree) dtys;
   112 
   113     fun is_DtTFree (DtTFree _) = true
   114       | is_DtTFree _ = false
   115     val k = find_index (fn (_, (_, dTs, _)) => not (forall is_DtTFree dTs)) descr;
   116     val protoTs as (dataTs, _) = chop k descr
   117       |> (pairself o map) (fn (_, (tyco, dTs, _)) => (tyco, map (typ_of_dtyp descr vs) dTs));
   118     
   119     val tycos = map fst dataTs;
   120     val _ = if gen_eq_set (op =) (tycos, raw_tycos) then ()
   121       else error ("Type constructors " ^ commas (map quote raw_tycos)
   122         ^ " do not belong exhaustively to one mutual recursive datatype");
   123 
   124     val (Ts, Us) = (pairself o map) Type protoTs;
   125 
   126     val names = map Long_Name.base_name (the_default tycos (#alt_names info));
   127     val (auxnames, _) = Name.make_context names
   128       |> fold_map (yield_singleton Name.variants o name_of_typ) Us;
   129     val prefix = space_implode "_" names;
   130 
   131   in (descr, vs, tycos, prefix, (names, auxnames), (Ts, Us)) end;
   132 
   133 fun get_constrs thy dtco =
   134   case try (the_spec thy) dtco
   135    of SOME (sorts, cos) =>
   136         let
   137           fun subst (v, sort) = TVar ((v, 0), sort);
   138           fun subst_ty (TFree v) = subst v
   139             | subst_ty ty = ty;
   140           val dty = Type (dtco, map subst sorts);
   141           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   142         in SOME (map mk_co cos) end
   143     | NONE => NONE;
   144 
   145 
   146 (** induct method setup **)
   147 
   148 (* case names *)
   149 
   150 local
   151 
   152 fun dt_recs (DtTFree _) = []
   153   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   154   | dt_recs (DtRec i) = [i];
   155 
   156 fun dt_cases (descr: descr) (_, args, constrs) =
   157   let
   158     fun the_bname i = Long_Name.base_name (#1 (the (AList.lookup (op =) descr i)));
   159     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   160   in map (fn (c, _) => space_implode "_" (Long_Name.base_name c :: bnames)) constrs end;
   161 
   162 
   163 fun induct_cases descr =
   164   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   165 
   166 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   167 
   168 in
   169 
   170 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   171 
   172 fun mk_case_names_exhausts descr new =
   173   map (RuleCases.case_names o exhaust_cases descr o #1)
   174     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   175 
   176 end;
   177 
   178 fun add_rules simps case_thms rec_thms inject distinct
   179                   weak_case_congs cong_att =
   180   PureThy.add_thmss [((Binding.name "simps", simps), []),
   181     ((Binding.empty, flat case_thms @
   182           flat distinct @ rec_thms), [Simplifier.simp_add]),
   183     ((Binding.empty, rec_thms), [Code.add_default_eqn_attribute]),
   184     ((Binding.empty, flat inject), [iff_add]),
   185     ((Binding.empty, map (fn th => th RS notE) (flat distinct)), [Classical.safe_elim NONE]),
   186     ((Binding.empty, weak_case_congs), [cong_att])]
   187   #> snd;
   188 
   189 
   190 (* add_cases_induct *)
   191 
   192 fun add_cases_induct infos induction thy =
   193   let
   194     val inducts = Project_Rule.projections (ProofContext.init thy) induction;
   195 
   196     fun named_rules (name, {index, exhaustion, ...}: info) =
   197       [((Binding.empty, nth inducts index), [Induct.induct_type name]),
   198        ((Binding.empty, exhaustion), [Induct.cases_type name])];
   199     fun unnamed_rule i =
   200       ((Binding.empty, nth inducts i), [Thm.kind_internal, Induct.induct_type ""]);
   201   in
   202     thy |> PureThy.add_thms
   203       (maps named_rules infos @
   204         map unnamed_rule (length infos upto length inducts - 1)) |> snd
   205     |> PureThy.add_thmss [((Binding.name "inducts", inducts), [])] |> snd
   206   end;
   207 
   208 
   209 
   210 (**** simplification procedure for showing distinctness of constructors ****)
   211 
   212 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   213   | stripT p = p;
   214 
   215 fun stripC (i, f $ x) = stripC (i + 1, f)
   216   | stripC p = p;
   217 
   218 val distinctN = "constr_distinct";
   219 
   220 fun distinct_rule thy ss tname eq_t = case #distinct (the_info thy tname) of
   221     FewConstrs thms => Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   222       (EVERY [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   223         atac 2, resolve_tac thms 1, etac FalseE 1]))
   224   | ManyConstrs (thm, simpset) =>
   225       let
   226         val [In0_inject, In1_inject, In0_not_In1, In1_not_In0] =
   227           map (PureThy.get_thm (ThyInfo.the_theory "Datatype" thy))
   228             ["In0_inject", "In1_inject", "In0_not_In1", "In1_not_In0"];
   229       in
   230         Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   231         (EVERY [rtac eq_reflection 1, rtac iffI 1, dtac thm 1,
   232           full_simp_tac (Simplifier.inherit_context ss simpset) 1,
   233           REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   234           eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1,
   235           etac FalseE 1]))
   236       end;
   237 
   238 fun distinct_proc thy ss (t as Const ("op =", _) $ t1 $ t2) =
   239   (case (stripC (0, t1), stripC (0, t2)) of
   240      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   241          (case (stripT (0, T1), stripT (0, T2)) of
   242             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   243                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   244                    (case (get_info_descr thy) tname1 of
   245                       SOME (_, (_, constrs)) => let val cnames = map fst constrs
   246                         in if cname1 mem cnames andalso cname2 mem cnames then
   247                              SOME (distinct_rule thy ss tname1
   248                                (Logic.mk_equals (t, Const ("False", HOLogic.boolT))))
   249                            else NONE
   250                         end
   251                     | NONE => NONE)
   252                 else NONE
   253           | _ => NONE)
   254    | _ => NONE)
   255   | distinct_proc _ _ _ = NONE;
   256 
   257 val distinct_simproc =
   258   Simplifier.simproc @{theory HOL} distinctN ["s = t"] distinct_proc;
   259 
   260 val dist_ss = HOL_ss addsimprocs [distinct_simproc];
   261 
   262 val simproc_setup =
   263   Simplifier.map_simpset (fn ss => ss addsimprocs [distinct_simproc]);
   264 
   265 
   266 (**** translation rules for case ****)
   267 
   268 fun make_case ctxt = DatatypeCase.make_case
   269   (info_of_constr (ProofContext.theory_of ctxt)) ctxt;
   270 
   271 fun strip_case ctxt = DatatypeCase.strip_case
   272   (info_of_case (ProofContext.theory_of ctxt));
   273 
   274 fun add_case_tr' case_names thy =
   275   Sign.add_advanced_trfuns ([], [],
   276     map (fn case_name =>
   277       let val case_name' = Sign.const_syntax_name thy case_name
   278       in (case_name', DatatypeCase.case_tr' info_of_case case_name')
   279       end) case_names, []) thy;
   280 
   281 val trfun_setup =
   282   Sign.add_advanced_trfuns ([],
   283     [("_case_syntax", DatatypeCase.case_tr true info_of_constr)],
   284     [], []);
   285 
   286 
   287 (* prepare types *)
   288 
   289 fun read_typ thy ((Ts, sorts), str) =
   290   let
   291     val ctxt = ProofContext.init thy
   292       |> fold (Variable.declare_typ o TFree) sorts;
   293     val T = Syntax.read_typ ctxt str;
   294   in (Ts @ [T], Term.add_tfreesT T sorts) end;
   295 
   296 fun cert_typ sign ((Ts, sorts), raw_T) =
   297   let
   298     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   299       TYPE (msg, _, _) => error msg;
   300     val sorts' = Term.add_tfreesT T sorts;
   301   in (Ts @ [T],
   302       case duplicates (op =) (map fst sorts') of
   303          [] => sorts'
   304        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   305   end;
   306 
   307 
   308 (**** make datatype info ****)
   309 
   310 fun make_dt_info alt_names descr sorts induct reccomb_names rec_thms
   311     (((((((((i, (_, (tname, _, _))), case_name), case_thms),
   312       exhaustion_thm), distinct_thm), inject), nchotomy), case_cong), weak_case_cong) =
   313   (tname,
   314    {index = i,
   315     alt_names = alt_names,
   316     descr = descr,
   317     sorts = sorts,
   318     rec_names = reccomb_names,
   319     rec_rewrites = rec_thms,
   320     case_name = case_name,
   321     case_rewrites = case_thms,
   322     induction = induct,
   323     exhaustion = exhaustion_thm,
   324     distinct = distinct_thm,
   325     inject = inject,
   326     nchotomy = nchotomy,
   327     case_cong = case_cong,
   328     weak_case_cong = weak_case_cong});
   329 
   330 structure DatatypeInterpretation = InterpretationFun
   331   (type T = config * string list val eq: T * T -> bool = eq_snd op =);
   332 fun interpretation f = DatatypeInterpretation.interpretation (uncurry f);
   333 
   334 
   335 (******************* definitional introduction of datatypes *******************)
   336 
   337 fun add_datatype_def (config : config) new_type_names descr sorts types_syntax constr_syntax dt_info
   338     case_names_induct case_names_exhausts thy =
   339   let
   340     val _ = message config ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   341 
   342     val ((inject, distinct, dist_rewrites, simproc_dists, induct), thy2) = thy |>
   343       DatatypeRepProofs.representation_proofs config dt_info new_type_names descr sorts
   344         types_syntax constr_syntax case_names_induct;
   345 
   346     val (casedist_thms, thy3) = DatatypeAbsProofs.prove_casedist_thms config new_type_names descr
   347       sorts induct case_names_exhausts thy2;
   348     val ((reccomb_names, rec_thms), thy4) = DatatypeAbsProofs.prove_primrec_thms
   349       config new_type_names descr sorts dt_info inject dist_rewrites
   350       (Simplifier.theory_context thy3 dist_ss) induct thy3;
   351     val ((case_thms, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   352       config new_type_names descr sorts reccomb_names rec_thms thy4;
   353     val (split_thms, thy7) = DatatypeAbsProofs.prove_split_thms config new_type_names
   354       descr sorts inject dist_rewrites casedist_thms case_thms thy6;
   355     val (nchotomys, thy8) = DatatypeAbsProofs.prove_nchotomys config new_type_names
   356       descr sorts casedist_thms thy7;
   357     val (case_congs, thy9) = DatatypeAbsProofs.prove_case_congs new_type_names
   358       descr sorts nchotomys case_thms thy8;
   359     val (weak_case_congs, thy10) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   360       descr sorts thy9;
   361 
   362     val dt_infos = map
   363       (make_dt_info (SOME new_type_names) (flat descr) sorts induct reccomb_names rec_thms)
   364       ((0 upto length (hd descr) - 1) ~~ hd descr ~~ case_names ~~ case_thms ~~
   365         casedist_thms ~~ simproc_dists ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   366 
   367     val simps = flat (distinct @ inject @ case_thms) @ rec_thms;
   368     val dt_names = map fst dt_infos;
   369 
   370     val thy12 =
   371       thy10
   372       |> add_case_tr' case_names
   373       |> Sign.add_path (space_implode "_" new_type_names)
   374       |> add_rules simps case_thms rec_thms inject distinct
   375           weak_case_congs (Simplifier.attrib (op addcongs))
   376       |> put_dt_infos dt_infos
   377       |> add_cases_induct dt_infos induct
   378       |> Sign.parent_path
   379       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms) |> snd
   380       |> DatatypeInterpretation.data (config, map fst dt_infos);
   381   in (dt_names, thy12) end;
   382 
   383 
   384 (*********************** declare existing type as datatype *********************)
   385 
   386 fun prove_rep_datatype (config : config) alt_names new_type_names descr sorts induct inject half_distinct thy =
   387   let
   388     val ((_, [induct']), _) =
   389       Variable.importT [induct] (Variable.thm_context induct);
   390 
   391     fun err t = error ("Ill-formed predicate in induction rule: " ^
   392       Syntax.string_of_term_global thy t);
   393 
   394     fun get_typ (t as _ $ Var (_, Type (tname, Ts))) =
   395           ((tname, map (fst o dest_TFree) Ts) handle TERM _ => err t)
   396       | get_typ t = err t;
   397     val dtnames = map get_typ (HOLogic.dest_conj (HOLogic.dest_Trueprop (Thm.concl_of induct')));
   398 
   399     val dt_info = get_all thy;
   400 
   401     val distinct = (map o maps) (fn thm => [thm, thm RS not_sym]) half_distinct;
   402     val (case_names_induct, case_names_exhausts) =
   403       (mk_case_names_induct descr, mk_case_names_exhausts descr (map #1 dtnames));
   404 
   405     val _ = message config ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   406 
   407     val (casedist_thms, thy2) = thy |>
   408       DatatypeAbsProofs.prove_casedist_thms config new_type_names [descr] sorts induct
   409         case_names_exhausts;
   410     val ((reccomb_names, rec_thms), thy3) = DatatypeAbsProofs.prove_primrec_thms
   411       config new_type_names [descr] sorts dt_info inject distinct
   412       (Simplifier.theory_context thy2 dist_ss) induct thy2;
   413     val ((case_thms, case_names), thy4) = DatatypeAbsProofs.prove_case_thms
   414       config new_type_names [descr] sorts reccomb_names rec_thms thy3;
   415     val (split_thms, thy5) = DatatypeAbsProofs.prove_split_thms
   416       config new_type_names [descr] sorts inject distinct casedist_thms case_thms thy4;
   417     val (nchotomys, thy6) = DatatypeAbsProofs.prove_nchotomys config new_type_names
   418       [descr] sorts casedist_thms thy5;
   419     val (case_congs, thy7) = DatatypeAbsProofs.prove_case_congs new_type_names
   420       [descr] sorts nchotomys case_thms thy6;
   421     val (weak_case_congs, thy8) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   422       [descr] sorts thy7;
   423 
   424     val ((_, [induct']), thy10) =
   425       thy8
   426       |> store_thmss "inject" new_type_names inject
   427       ||>> store_thmss "distinct" new_type_names distinct
   428       ||> Sign.add_path (space_implode "_" new_type_names)
   429       ||>> PureThy.add_thms [((Binding.name "induct", induct), [case_names_induct])];
   430 
   431     val dt_infos = map (make_dt_info alt_names descr sorts induct' reccomb_names rec_thms)
   432       ((0 upto length descr - 1) ~~ descr ~~ case_names ~~ case_thms ~~ casedist_thms ~~
   433         map FewConstrs distinct ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   434 
   435     val simps = flat (distinct @ inject @ case_thms) @ rec_thms;
   436     val dt_names = map fst dt_infos;
   437 
   438     val thy11 =
   439       thy10
   440       |> add_case_tr' case_names
   441       |> add_rules simps case_thms rec_thms inject distinct
   442            weak_case_congs (Simplifier.attrib (op addcongs))
   443       |> put_dt_infos dt_infos
   444       |> add_cases_induct dt_infos induct'
   445       |> Sign.parent_path
   446       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms)
   447       |> snd
   448       |> DatatypeInterpretation.data (config, dt_names);
   449   in (dt_names, thy11) end;
   450 
   451 fun gen_rep_datatype prep_term (config : config) after_qed alt_names raw_ts thy =
   452   let
   453     fun constr_of_term (Const (c, T)) = (c, T)
   454       | constr_of_term t =
   455           error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
   456     fun no_constr (c, T) = error ("Bad constructor: "
   457       ^ Sign.extern_const thy c ^ "::"
   458       ^ Syntax.string_of_typ_global thy T);
   459     fun type_of_constr (cT as (_, T)) =
   460       let
   461         val frees = OldTerm.typ_tfrees T;
   462         val (tyco, vs) = ((apsnd o map) (dest_TFree) o dest_Type o snd o strip_type) T
   463           handle TYPE _ => no_constr cT
   464         val _ = if has_duplicates (eq_fst (op =)) vs then no_constr cT else ();
   465         val _ = if length frees <> length vs then no_constr cT else ();
   466       in (tyco, (vs, cT)) end;
   467 
   468     val raw_cs = AList.group (op =) (map (type_of_constr o constr_of_term o prep_term thy) raw_ts);
   469     val _ = case map_filter (fn (tyco, _) =>
   470         if Symtab.defined (get_all thy) tyco then SOME tyco else NONE) raw_cs
   471      of [] => ()
   472       | tycos => error ("Type(s) " ^ commas (map quote tycos)
   473           ^ " already represented inductivly");
   474     val raw_vss = maps (map (map snd o fst) o snd) raw_cs;
   475     val ms = case distinct (op =) (map length raw_vss)
   476      of [n] => 0 upto n - 1
   477       | _ => error ("Different types in given constructors");
   478     fun inter_sort m = map (fn xs => nth xs m) raw_vss
   479       |> Library.foldr1 (Sorts.inter_sort (Sign.classes_of thy))
   480     val sorts = map inter_sort ms;
   481     val vs = Name.names Name.context Name.aT sorts;
   482 
   483     fun norm_constr (raw_vs, (c, T)) = (c, map_atyps
   484       (TFree o (the o AList.lookup (op =) (map fst raw_vs ~~ vs)) o fst o dest_TFree) T);
   485 
   486     val cs = map (apsnd (map norm_constr)) raw_cs;
   487     val dtyps_of_typ = map (dtyp_of_typ (map (rpair (map fst vs) o fst) cs))
   488       o fst o strip_type;
   489     val new_type_names = map Long_Name.base_name (the_default (map fst cs) alt_names);
   490 
   491     fun mk_spec (i, (tyco, constr)) = (i, (tyco,
   492       map (DtTFree o fst) vs,
   493       (map o apsnd) dtyps_of_typ constr))
   494     val descr = map_index mk_spec cs;
   495     val injs = DatatypeProp.make_injs [descr] vs;
   496     val half_distincts = map snd (DatatypeProp.make_distincts [descr] vs);
   497     val ind = DatatypeProp.make_ind [descr] vs;
   498     val rules = (map o map o map) Logic.close_form [[[ind]], injs, half_distincts];
   499 
   500     fun after_qed' raw_thms =
   501       let
   502         val [[[induct]], injs, half_distincts] =
   503           unflat rules (map Drule.zero_var_indexes_list raw_thms);
   504             (*FIXME somehow dubious*)
   505       in
   506         ProofContext.theory_result
   507           (prove_rep_datatype config alt_names new_type_names descr vs induct injs half_distincts)
   508         #-> after_qed
   509       end;
   510   in
   511     thy
   512     |> ProofContext.init
   513     |> Proof.theorem_i NONE after_qed' ((map o map) (rpair []) (flat rules))
   514   end;
   515 
   516 val rep_datatype = gen_rep_datatype Sign.cert_term;
   517 val rep_datatype_cmd = gen_rep_datatype Syntax.read_term_global default_config (K I);
   518 
   519 
   520 
   521 (******************************** add datatype ********************************)
   522 
   523 fun gen_add_datatype prep_typ (config : config) new_type_names dts thy =
   524   let
   525     val _ = Theory.requires thy "Datatype" "datatype definitions";
   526 
   527     (* this theory is used just for parsing *)
   528 
   529     val tmp_thy = thy |>
   530       Theory.copy |>
   531       Sign.add_types (map (fn (tvs, tname, mx, _) =>
   532         (tname, length tvs, mx)) dts);
   533 
   534     val (tyvars, _, _, _)::_ = dts;
   535     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   536       let val full_tname = Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname)
   537       in (case duplicates (op =) tvs of
   538             [] => if eq_set (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   539                   else error ("Mutually recursive datatypes must have same type parameters")
   540           | dups => error ("Duplicate parameter(s) for datatype " ^ quote (Binding.str_of tname) ^
   541               " : " ^ commas dups))
   542       end) dts);
   543 
   544     val _ = (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   545       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   546 
   547     fun prep_dt_spec ((tvs, tname, mx, constrs), tname') (dts', constr_syntax, sorts, i) =
   548       let
   549         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   550           let
   551             val (cargs', sorts'') = Library.foldl (prep_typ tmp_thy) (([], sorts'), cargs);
   552             val _ = (case fold (curry OldTerm.add_typ_tfree_names) cargs' [] \\ tvs of
   553                 [] => ()
   554               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   555           in (constrs @ [(Sign.full_name_path tmp_thy tname'
   556                   (Binding.map_name (Syntax.const_name mx') cname),
   557                    map (dtyp_of_typ new_dts) cargs')],
   558               constr_syntax' @ [(cname, mx')], sorts'')
   559           end handle ERROR msg => cat_error msg
   560            ("The error above occured in constructor " ^ quote (Binding.str_of cname) ^
   561             " of datatype " ^ quote (Binding.str_of tname));
   562 
   563         val (constrs', constr_syntax', sorts') =
   564           fold prep_constr constrs ([], [], sorts)
   565 
   566       in
   567         case duplicates (op =) (map fst constrs') of
   568            [] =>
   569              (dts' @ [(i, (Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname),
   570                 map DtTFree tvs, constrs'))],
   571               constr_syntax @ [constr_syntax'], sorts', i + 1)
   572          | dups => error ("Duplicate constructors " ^ commas dups ^
   573              " in datatype " ^ quote (Binding.str_of tname))
   574       end;
   575 
   576     val (dts', constr_syntax, sorts', i) =
   577       fold prep_dt_spec (dts ~~ new_type_names) ([], [], [], 0);
   578     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (tyvars \\ map fst sorts'));
   579     val dt_info = get_all thy;
   580     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   581     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   582       if #strict config then error ("Nonemptiness check failed for datatype " ^ s)
   583       else raise exn;
   584 
   585     val descr' = flat descr;
   586     val case_names_induct = mk_case_names_induct descr';
   587     val case_names_exhausts = mk_case_names_exhausts descr' (map #1 new_dts);
   588   in
   589     add_datatype_def
   590       (config : config) new_type_names descr sorts types_syntax constr_syntax dt_info
   591       case_names_induct case_names_exhausts thy
   592   end;
   593 
   594 val add_datatype = gen_add_datatype cert_typ;
   595 val datatype_cmd = snd ooo gen_add_datatype read_typ default_config;
   596 
   597 
   598 
   599 (** package setup **)
   600 
   601 (* setup theory *)
   602 
   603 val setup =
   604   DatatypeRepProofs.distinctness_limit_setup #>
   605   simproc_setup #>
   606   trfun_setup #>
   607   DatatypeInterpretation.init;
   608 
   609 
   610 (* outer syntax *)
   611 
   612 local
   613 
   614 structure P = OuterParse and K = OuterKeyword
   615 
   616 fun prep_datatype_decls args =
   617   let
   618     val names = map
   619       (fn ((((NONE, _), t), _), _) => Binding.name_of t | ((((SOME t, _), _), _), _) => t) args;
   620     val specs = map (fn ((((_, vs), t), mx), cons) =>
   621       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   622   in (names, specs) end;
   623 
   624 val parse_datatype_decl =
   625   (Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.binding -- P.opt_infix --
   626     (P.$$$ "=" |-- P.enum1 "|" (P.binding -- Scan.repeat P.typ -- P.opt_mixfix)));
   627 
   628 val parse_datatype_decls = P.and_list1 parse_datatype_decl >> prep_datatype_decls;
   629 
   630 in
   631 
   632 val _ =
   633   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   634     (parse_datatype_decls >> (fn (names, specs) => Toplevel.theory (datatype_cmd names specs)));
   635 
   636 val _ =
   637   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_goal
   638     (Scan.option (P.$$$ "(" |-- Scan.repeat1 P.name --| P.$$$ ")") -- Scan.repeat1 P.term
   639       >> (fn (alt_names, ts) => Toplevel.print
   640            o Toplevel.theory_to_proof (rep_datatype_cmd alt_names ts)));
   641 
   642 end;
   643 
   644 
   645 (* document antiquotation *)
   646 
   647 val _ = ThyOutput.antiquotation "datatype" Args.tyname
   648   (fn {source = src, context = ctxt, ...} => fn dtco =>
   649     let
   650       val thy = ProofContext.theory_of ctxt;
   651       val (vs, cos) = the_spec thy dtco;
   652       val ty = Type (dtco, map TFree vs);
   653       fun pretty_typ_bracket (ty as Type (_, _ :: _)) =
   654             Pretty.enclose "(" ")" [Syntax.pretty_typ ctxt ty]
   655         | pretty_typ_bracket ty =
   656             Syntax.pretty_typ ctxt ty;
   657       fun pretty_constr (co, tys) =
   658         (Pretty.block o Pretty.breaks)
   659           (Syntax.pretty_term ctxt (Const (co, tys ---> ty)) ::
   660             map pretty_typ_bracket tys);
   661       val pretty_datatype =
   662         Pretty.block
   663           (Pretty.command "datatype" :: Pretty.brk 1 ::
   664            Syntax.pretty_typ ctxt ty ::
   665            Pretty.str " =" :: Pretty.brk 1 ::
   666            flat (separate [Pretty.brk 1, Pretty.str "| "]
   667              (map (single o pretty_constr) cos)));
   668     in ThyOutput.output (ThyOutput.maybe_pretty_source (K pretty_datatype) src [()]) end);
   669 
   670 end;
   671