src/HOL/Algebra/UnivPoly.thy
author paulson
Tue Feb 01 18:01:57 2005 +0100 (2005-02-01)
changeset 15481 fc075ae929e4
parent 15095 63f5f4c265dd
child 15596 8665d08085df
permissions -rw-r--r--
the new subst tactic, by Lucas Dixon
     1 (*
     2   Title:     HOL/Algebra/UnivPoly.thy
     3   Id:        $Id$
     4   Author:    Clemens Ballarin, started 9 December 1996
     5   Copyright: Clemens Ballarin
     6 *)
     7 
     8 header {* Univariate Polynomials *}
     9 
    10 theory UnivPoly = Module:
    11 
    12 text {*
    13   Polynomials are formalised as modules with additional operations for
    14   extracting coefficients from polynomials and for obtaining monomials
    15   from coefficients and exponents (record @{text "up_ring"}).  The
    16   carrier set is a set of bounded functions from Nat to the
    17   coefficient domain.  Bounded means that these functions return zero
    18   above a certain bound (the degree).  There is a chapter on the
    19   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},
    20   which was implemented with axiomatic type classes.  This was later
    21   ported to Locales.
    22 *}
    23 
    24 
    25 subsection {* The Constructor for Univariate Polynomials *}
    26 
    27 text {*
    28   Functions with finite support.
    29 *}
    30 
    31 locale bound =
    32   fixes z :: 'a
    33     and n :: nat
    34     and f :: "nat => 'a"
    35   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    36 
    37 declare bound.intro [intro!]
    38   and bound.bound [dest]
    39 
    40 lemma bound_below:
    41   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    42 proof (rule classical)
    43   assume "~ ?thesis"
    44   then have "m < n" by arith
    45   with bound have "f n = z" ..
    46   with nonzero show ?thesis by contradiction
    47 qed
    48 
    49 record ('a, 'p) up_ring = "('a, 'p) module" +
    50   monom :: "['a, nat] => 'p"
    51   coeff :: "['p, nat] => 'a"
    52 
    53 constdefs (structure R)
    54   up :: "('a, 'm) ring_scheme => (nat => 'a) set"
    55   "up R == {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero> n f)}"
    56   UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"
    57   "UP R == (|
    58     carrier = up R,
    59     mult = (%p:up R. %q:up R. %n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)),
    60     one = (%i. if i=0 then \<one> else \<zero>),
    61     zero = (%i. \<zero>),
    62     add = (%p:up R. %q:up R. %i. p i \<oplus> q i),
    63     smult = (%a:carrier R. %p:up R. %i. a \<otimes> p i),
    64     monom = (%a:carrier R. %n i. if i=n then a else \<zero>),
    65     coeff = (%p:up R. %n. p n) |)"
    66 
    67 text {*
    68   Properties of the set of polynomials @{term up}.
    69 *}
    70 
    71 lemma mem_upI [intro]:
    72   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"
    73   by (simp add: up_def Pi_def)
    74 
    75 lemma mem_upD [dest]:
    76   "f \<in> up R ==> f n \<in> carrier R"
    77   by (simp add: up_def Pi_def)
    78 
    79 lemma (in cring) bound_upD [dest]:
    80   "f \<in> up R ==> EX n. bound \<zero> n f"
    81   by (simp add: up_def)
    82 
    83 lemma (in cring) up_one_closed:
    84    "(%n. if n = 0 then \<one> else \<zero>) \<in> up R"
    85   using up_def by force
    86 
    87 lemma (in cring) up_smult_closed:
    88   "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R"
    89   by force
    90 
    91 lemma (in cring) up_add_closed:
    92   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"
    93 proof
    94   fix n
    95   assume "p \<in> up R" and "q \<in> up R"
    96   then show "p n \<oplus> q n \<in> carrier R"
    97     by auto
    98 next
    99   assume UP: "p \<in> up R" "q \<in> up R"
   100   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"
   101   proof -
   102     from UP obtain n where boundn: "bound \<zero> n p" by fast
   103     from UP obtain m where boundm: "bound \<zero> m q" by fast
   104     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"
   105     proof
   106       fix i
   107       assume "max n m < i"
   108       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp
   109     qed
   110     then show ?thesis ..
   111   qed
   112 qed
   113 
   114 lemma (in cring) up_a_inv_closed:
   115   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"
   116 proof
   117   assume R: "p \<in> up R"
   118   then obtain n where "bound \<zero> n p" by auto
   119   then have "bound \<zero> n (%i. \<ominus> p i)" by auto
   120   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto
   121 qed auto
   122 
   123 lemma (in cring) up_mult_closed:
   124   "[| p \<in> up R; q \<in> up R |] ==>
   125   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   126 proof
   127   fix n
   128   assume "p \<in> up R" "q \<in> up R"
   129   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   130     by (simp add: mem_upD  funcsetI)
   131 next
   132   assume UP: "p \<in> up R" "q \<in> up R"
   133   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   134   proof -
   135     from UP obtain n where boundn: "bound \<zero> n p" by fast
   136     from UP obtain m where boundm: "bound \<zero> m q" by fast
   137     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   138     proof
   139       fix k assume bound: "n + m < k"
   140       {
   141         fix i
   142         have "p i \<otimes> q (k-i) = \<zero>"
   143         proof (cases "n < i")
   144           case True
   145           with boundn have "p i = \<zero>" by auto
   146           moreover from UP have "q (k-i) \<in> carrier R" by auto
   147           ultimately show ?thesis by simp
   148         next
   149           case False
   150           with bound have "m < k-i" by arith
   151           with boundm have "q (k-i) = \<zero>" by auto
   152           moreover from UP have "p i \<in> carrier R" by auto
   153           ultimately show ?thesis by simp
   154         qed
   155       }
   156       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   157         by (simp add: Pi_def)
   158     qed
   159     then show ?thesis by fast
   160   qed
   161 qed
   162 
   163 
   164 subsection {* Effect of operations on coefficients *}
   165 
   166 locale UP = struct R + struct P +
   167   defines P_def: "P == UP R"
   168 
   169 locale UP_cring = UP + cring R
   170 
   171 locale UP_domain = UP_cring + "domain" R
   172 
   173 text {*
   174   Temporarily declare @{thm [locale=UP] P_def} as simp rule.
   175 *}
   176 
   177 declare (in UP) P_def [simp]
   178 
   179 lemma (in UP_cring) coeff_monom [simp]:
   180   "a \<in> carrier R ==>
   181   coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   182 proof -
   183   assume R: "a \<in> carrier R"
   184   then have "(%n. if n = m then a else \<zero>) \<in> up R"
   185     using up_def by force
   186   with R show ?thesis by (simp add: UP_def)
   187 qed
   188 
   189 lemma (in UP_cring) coeff_zero [simp]:
   190   "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>"
   191   by (auto simp add: UP_def)
   192 
   193 lemma (in UP_cring) coeff_one [simp]:
   194   "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"
   195   using up_one_closed by (simp add: UP_def)
   196 
   197 lemma (in UP_cring) coeff_smult [simp]:
   198   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   199   coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"
   200   by (simp add: UP_def up_smult_closed)
   201 
   202 lemma (in UP_cring) coeff_add [simp]:
   203   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   204   coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"
   205   by (simp add: UP_def up_add_closed)
   206 
   207 lemma (in UP_cring) coeff_mult [simp]:
   208   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   209   coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   210   by (simp add: UP_def up_mult_closed)
   211 
   212 lemma (in UP) up_eqI:
   213   assumes prem: "!!n. coeff P p n = coeff P q n"
   214     and R: "p \<in> carrier P" "q \<in> carrier P"
   215   shows "p = q"
   216 proof
   217   fix x
   218   from prem and R show "p x = q x" by (simp add: UP_def)
   219 qed
   220 
   221 subsection {* Polynomials form a commutative ring. *}
   222 
   223 text {* Operations are closed over @{term P}. *}
   224 
   225 lemma (in UP_cring) UP_mult_closed [simp]:
   226   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P"
   227   by (simp add: UP_def up_mult_closed)
   228 
   229 lemma (in UP_cring) UP_one_closed [simp]:
   230   "\<one>\<^bsub>P\<^esub> \<in> carrier P"
   231   by (simp add: UP_def up_one_closed)
   232 
   233 lemma (in UP_cring) UP_zero_closed [intro, simp]:
   234   "\<zero>\<^bsub>P\<^esub> \<in> carrier P"
   235   by (auto simp add: UP_def)
   236 
   237 lemma (in UP_cring) UP_a_closed [intro, simp]:
   238   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P"
   239   by (simp add: UP_def up_add_closed)
   240 
   241 lemma (in UP_cring) monom_closed [simp]:
   242   "a \<in> carrier R ==> monom P a n \<in> carrier P"
   243   by (auto simp add: UP_def up_def Pi_def)
   244 
   245 lemma (in UP_cring) UP_smult_closed [simp]:
   246   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P"
   247   by (simp add: UP_def up_smult_closed)
   248 
   249 lemma (in UP) coeff_closed [simp]:
   250   "p \<in> carrier P ==> coeff P p n \<in> carrier R"
   251   by (auto simp add: UP_def)
   252 
   253 declare (in UP) P_def [simp del]
   254 
   255 text {* Algebraic ring properties *}
   256 
   257 lemma (in UP_cring) UP_a_assoc:
   258   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   259   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)"
   260   by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   261 
   262 lemma (in UP_cring) UP_l_zero [simp]:
   263   assumes R: "p \<in> carrier P"
   264   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p"
   265   by (rule up_eqI, simp_all add: R)
   266 
   267 lemma (in UP_cring) UP_l_neg_ex:
   268   assumes R: "p \<in> carrier P"
   269   shows "EX q : carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   270 proof -
   271   let ?q = "%i. \<ominus> (p i)"
   272   from R have closed: "?q \<in> carrier P"
   273     by (simp add: UP_def P_def up_a_inv_closed)
   274   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   275     by (simp add: UP_def P_def up_a_inv_closed)
   276   show ?thesis
   277   proof
   278     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   279       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   280   qed (rule closed)
   281 qed
   282 
   283 lemma (in UP_cring) UP_a_comm:
   284   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   285   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p"
   286   by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   287 
   288 ML_setup {*
   289   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   290 *}
   291 
   292 lemma (in UP_cring) UP_m_assoc:
   293   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   294   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   295 proof (rule up_eqI)
   296   fix n
   297   {
   298     fix k and a b c :: "nat=>'a"
   299     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   300       "c \<in> UNIV -> carrier R"
   301     then have "k <= n ==>
   302       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   303       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   304       (concl is "?eq k")
   305     proof (induct k)
   306       case 0 then show ?case by (simp add: Pi_def m_assoc)
   307     next
   308       case (Suc k)
   309       then have "k <= n" by arith
   310       then have "?eq k" by (rule Suc)
   311       with R show ?case
   312         by (simp cong: finsum_cong
   313              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   314           (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   315     qed
   316   }
   317   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"
   318     by (simp add: Pi_def)
   319 qed (simp_all add: R)
   320 
   321 ML_setup {*
   322   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
   323 *}
   324 
   325 lemma (in UP_cring) UP_l_one [simp]:
   326   assumes R: "p \<in> carrier P"
   327   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"
   328 proof (rule up_eqI)
   329   fix n
   330   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"
   331   proof (cases n)
   332     case 0 with R show ?thesis by simp
   333   next
   334     case Suc with R show ?thesis
   335       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   336   qed
   337 qed (simp_all add: R)
   338 
   339 lemma (in UP_cring) UP_l_distr:
   340   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   341   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   342   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   343 
   344 lemma (in UP_cring) UP_m_comm:
   345   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   346   shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"
   347 proof (rule up_eqI)
   348   fix n
   349   {
   350     fix k and a b :: "nat=>'a"
   351     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   352     then have "k <= n ==>
   353       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) =
   354       (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   355       (concl is "?eq k")
   356     proof (induct k)
   357       case 0 then show ?case by (simp add: Pi_def)
   358     next
   359       case (Suc k) then show ?case
   360         by (simplesubst finsum_Suc2) (simp add: Pi_def a_comm)+
   361     qed
   362   }
   363   note l = this
   364   from R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"
   365     apply (simp add: Pi_def)
   366     apply (subst l)
   367     apply (auto simp add: Pi_def)
   368     apply (simp add: m_comm)
   369     done
   370 qed (simp_all add: R)
   371 
   372 theorem (in UP_cring) UP_cring:
   373   "cring P"
   374   by (auto intro!: cringI abelian_groupI comm_monoidI UP_a_assoc UP_l_zero
   375     UP_l_neg_ex UP_a_comm UP_m_assoc UP_l_one UP_m_comm UP_l_distr)
   376 
   377 lemma (in UP_cring) UP_ring:  (* preliminary *)
   378   "ring P"
   379   by (auto intro: ring.intro cring.axioms UP_cring)
   380 
   381 lemma (in UP_cring) UP_a_inv_closed [intro, simp]:
   382   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"
   383   by (rule abelian_group.a_inv_closed
   384     [OF ring.is_abelian_group [OF UP_ring]])
   385 
   386 lemma (in UP_cring) coeff_a_inv [simp]:
   387   assumes R: "p \<in> carrier P"
   388   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"
   389 proof -
   390   from R coeff_closed UP_a_inv_closed have
   391     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"
   392     by algebra
   393   also from R have "... =  \<ominus> (coeff P p n)"
   394     by (simp del: coeff_add add: coeff_add [THEN sym]
   395       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   396   finally show ?thesis .
   397 qed
   398 
   399 text {*
   400   Instantiation of lemmas from @{term cring}.
   401 *}
   402 
   403 (* TODO: this should be automated with an instantiation command. *)
   404 
   405 lemma (in UP_cring) UP_monoid:
   406   "monoid P"
   407   by (fast intro!: cring.is_comm_monoid comm_monoid.axioms monoid.intro
   408     UP_cring)
   409 (* TODO: provide cring.is_monoid *)
   410 
   411 lemma (in UP_cring) UP_comm_monoid:
   412   "comm_monoid P"
   413   by (fast intro!: cring.is_comm_monoid UP_cring)
   414 
   415 lemma (in UP_cring) UP_abelian_monoid:
   416   "abelian_monoid P"
   417   by (fast intro!: abelian_group.axioms ring.is_abelian_group UP_ring)
   418 
   419 lemma (in UP_cring) UP_abelian_group:
   420   "abelian_group P"
   421   by (fast intro!: ring.is_abelian_group UP_ring)
   422 
   423 lemmas (in UP_cring) UP_r_one [simp] =
   424   monoid.r_one [OF UP_monoid]
   425 
   426 lemmas (in UP_cring) UP_nat_pow_closed [intro, simp] =
   427   monoid.nat_pow_closed [OF UP_monoid]
   428 
   429 lemmas (in UP_cring) UP_nat_pow_0 [simp] =
   430   monoid.nat_pow_0 [OF UP_monoid]
   431 
   432 lemmas (in UP_cring) UP_nat_pow_Suc [simp] =
   433   monoid.nat_pow_Suc [OF UP_monoid]
   434 
   435 lemmas (in UP_cring) UP_nat_pow_one [simp] =
   436   monoid.nat_pow_one [OF UP_monoid]
   437 
   438 lemmas (in UP_cring) UP_nat_pow_mult =
   439   monoid.nat_pow_mult [OF UP_monoid]
   440 
   441 lemmas (in UP_cring) UP_nat_pow_pow =
   442   monoid.nat_pow_pow [OF UP_monoid]
   443 
   444 lemmas (in UP_cring) UP_m_lcomm =
   445   comm_monoid.m_lcomm [OF UP_comm_monoid]
   446 
   447 lemmas (in UP_cring) UP_m_ac = UP_m_assoc UP_m_comm UP_m_lcomm
   448 
   449 lemmas (in UP_cring) UP_nat_pow_distr =
   450   comm_monoid.nat_pow_distr [OF UP_comm_monoid]
   451 
   452 lemmas (in UP_cring) UP_a_lcomm = abelian_monoid.a_lcomm [OF UP_abelian_monoid]
   453 
   454 lemmas (in UP_cring) UP_r_zero [simp] =
   455   abelian_monoid.r_zero [OF UP_abelian_monoid]
   456 
   457 lemmas (in UP_cring) UP_a_ac = UP_a_assoc UP_a_comm UP_a_lcomm
   458 
   459 lemmas (in UP_cring) UP_finsum_empty [simp] =
   460   abelian_monoid.finsum_empty [OF UP_abelian_monoid]
   461 
   462 lemmas (in UP_cring) UP_finsum_insert [simp] =
   463   abelian_monoid.finsum_insert [OF UP_abelian_monoid]
   464 
   465 lemmas (in UP_cring) UP_finsum_zero [simp] =
   466   abelian_monoid.finsum_zero [OF UP_abelian_monoid]
   467 
   468 lemmas (in UP_cring) UP_finsum_closed [simp] =
   469   abelian_monoid.finsum_closed [OF UP_abelian_monoid]
   470 
   471 lemmas (in UP_cring) UP_finsum_Un_Int =
   472   abelian_monoid.finsum_Un_Int [OF UP_abelian_monoid]
   473 
   474 lemmas (in UP_cring) UP_finsum_Un_disjoint =
   475   abelian_monoid.finsum_Un_disjoint [OF UP_abelian_monoid]
   476 
   477 lemmas (in UP_cring) UP_finsum_addf =
   478   abelian_monoid.finsum_addf [OF UP_abelian_monoid]
   479 
   480 lemmas (in UP_cring) UP_finsum_cong' =
   481   abelian_monoid.finsum_cong' [OF UP_abelian_monoid]
   482 
   483 lemmas (in UP_cring) UP_finsum_0 [simp] =
   484   abelian_monoid.finsum_0 [OF UP_abelian_monoid]
   485 
   486 lemmas (in UP_cring) UP_finsum_Suc [simp] =
   487   abelian_monoid.finsum_Suc [OF UP_abelian_monoid]
   488 
   489 lemmas (in UP_cring) UP_finsum_Suc2 =
   490   abelian_monoid.finsum_Suc2 [OF UP_abelian_monoid]
   491 
   492 lemmas (in UP_cring) UP_finsum_add [simp] =
   493   abelian_monoid.finsum_add [OF UP_abelian_monoid]
   494 
   495 lemmas (in UP_cring) UP_finsum_cong =
   496   abelian_monoid.finsum_cong [OF UP_abelian_monoid]
   497 
   498 lemmas (in UP_cring) UP_minus_closed [intro, simp] =
   499   abelian_group.minus_closed [OF UP_abelian_group]
   500 
   501 lemmas (in UP_cring) UP_a_l_cancel [simp] =
   502   abelian_group.a_l_cancel [OF UP_abelian_group]
   503 
   504 lemmas (in UP_cring) UP_a_r_cancel [simp] =
   505   abelian_group.a_r_cancel [OF UP_abelian_group]
   506 
   507 lemmas (in UP_cring) UP_l_neg =
   508   abelian_group.l_neg [OF UP_abelian_group]
   509 
   510 lemmas (in UP_cring) UP_r_neg =
   511   abelian_group.r_neg [OF UP_abelian_group]
   512 
   513 lemmas (in UP_cring) UP_minus_zero [simp] =
   514   abelian_group.minus_zero [OF UP_abelian_group]
   515 
   516 lemmas (in UP_cring) UP_minus_minus [simp] =
   517   abelian_group.minus_minus [OF UP_abelian_group]
   518 
   519 lemmas (in UP_cring) UP_minus_add =
   520   abelian_group.minus_add [OF UP_abelian_group]
   521 
   522 lemmas (in UP_cring) UP_r_neg2 =
   523   abelian_group.r_neg2 [OF UP_abelian_group]
   524 
   525 lemmas (in UP_cring) UP_r_neg1 =
   526   abelian_group.r_neg1 [OF UP_abelian_group]
   527 
   528 lemmas (in UP_cring) UP_r_distr =
   529   ring.r_distr [OF UP_ring]
   530 
   531 lemmas (in UP_cring) UP_l_null [simp] =
   532   ring.l_null [OF UP_ring]
   533 
   534 lemmas (in UP_cring) UP_r_null [simp] =
   535   ring.r_null [OF UP_ring]
   536 
   537 lemmas (in UP_cring) UP_l_minus =
   538   ring.l_minus [OF UP_ring]
   539 
   540 lemmas (in UP_cring) UP_r_minus =
   541   ring.r_minus [OF UP_ring]
   542 
   543 lemmas (in UP_cring) UP_finsum_ldistr =
   544   cring.finsum_ldistr [OF UP_cring]
   545 
   546 lemmas (in UP_cring) UP_finsum_rdistr =
   547   cring.finsum_rdistr [OF UP_cring]
   548 
   549 
   550 subsection {* Polynomials form an Algebra *}
   551 
   552 lemma (in UP_cring) UP_smult_l_distr:
   553   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   554   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"
   555   by (rule up_eqI) (simp_all add: R.l_distr)
   556 
   557 lemma (in UP_cring) UP_smult_r_distr:
   558   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   559   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"
   560   by (rule up_eqI) (simp_all add: R.r_distr)
   561 
   562 lemma (in UP_cring) UP_smult_assoc1:
   563       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   564       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"
   565   by (rule up_eqI) (simp_all add: R.m_assoc)
   566 
   567 lemma (in UP_cring) UP_smult_one [simp]:
   568       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"
   569   by (rule up_eqI) simp_all
   570 
   571 lemma (in UP_cring) UP_smult_assoc2:
   572   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   573   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"
   574   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   575 
   576 text {*
   577   Instantiation of lemmas from @{term algebra}.
   578 *}
   579 
   580 (* TODO: this should be automated with an instantiation command. *)
   581 
   582 (* TODO: move to CRing.thy, really a fact missing from the locales package *)
   583 lemma (in cring) cring:
   584   "cring R"
   585   by (fast intro: cring.intro prems)
   586 
   587 lemma (in UP_cring) UP_algebra:
   588   "algebra R P"
   589   by (auto intro: algebraI cring UP_cring UP_smult_l_distr UP_smult_r_distr
   590     UP_smult_assoc1 UP_smult_assoc2)
   591 
   592 lemmas (in UP_cring) UP_smult_l_null [simp] =
   593   algebra.smult_l_null [OF UP_algebra]
   594 
   595 lemmas (in UP_cring) UP_smult_r_null [simp] =
   596   algebra.smult_r_null [OF UP_algebra]
   597 
   598 lemmas (in UP_cring) UP_smult_l_minus =
   599   algebra.smult_l_minus [OF UP_algebra]
   600 
   601 lemmas (in UP_cring) UP_smult_r_minus =
   602   algebra.smult_r_minus [OF UP_algebra]
   603 
   604 subsection {* Further lemmas involving monomials *}
   605 
   606 lemma (in UP_cring) monom_zero [simp]:
   607   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>"
   608   by (simp add: UP_def P_def)
   609 
   610 ML_setup {*
   611   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   612 *}
   613 
   614 lemma (in UP_cring) monom_mult_is_smult:
   615   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   616   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"
   617 proof (rule up_eqI)
   618   fix n
   619   have "coeff P (p \<otimes>\<^bsub>P\<^esub> monom P a 0) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   620   proof (cases n)
   621     case 0 with R show ?thesis by (simp add: R.m_comm)
   622   next
   623     case Suc with R show ?thesis
   624       by (simp cong: finsum_cong add: R.r_null Pi_def)
   625         (simp add: m_comm)
   626   qed
   627   with R show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   628     by (simp add: UP_m_comm)
   629 qed (simp_all add: R)
   630 
   631 ML_setup {*
   632   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
   633 *}
   634 
   635 lemma (in UP_cring) monom_add [simp]:
   636   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   637   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"
   638   by (rule up_eqI) simp_all
   639 
   640 ML_setup {*
   641   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   642 *}
   643 
   644 lemma (in UP_cring) monom_one_Suc:
   645   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   646 proof (rule up_eqI)
   647   fix k
   648   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   649   proof (cases "k = Suc n")
   650     case True show ?thesis
   651     proof -
   652       from True have less_add_diff:
   653         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   654       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   655       also from True
   656       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   657         coeff P (monom P \<one> 1) (k - i))"
   658         by (simp cong: finsum_cong add: finsum_Un_disjoint Pi_def)
   659       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   660         coeff P (monom P \<one> 1) (k - i))"
   661         by (simp only: ivl_disj_un_singleton)
   662       also from True
   663       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   664         coeff P (monom P \<one> 1) (k - i))"
   665         by (simp cong: finsum_cong add: finsum_Un_disjoint ivl_disj_int_one
   666           order_less_imp_not_eq Pi_def)
   667       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   668         by (simp add: ivl_disj_un_one)
   669       finally show ?thesis .
   670     qed
   671   next
   672     case False
   673     note neq = False
   674     let ?s =
   675       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   676     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   677     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   678     proof -
   679       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"
   680         by (simp cong: finsum_cong add: Pi_def)
   681       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   682         by (simp cong: finsum_cong add: Pi_def) arith
   683       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   684         by (simp cong: finsum_cong add: order_less_imp_not_eq Pi_def)
   685       show ?thesis
   686       proof (cases "k < n")
   687         case True then show ?thesis by (simp cong: finsum_cong add: Pi_def)
   688       next
   689         case False then have n_le_k: "n <= k" by arith
   690         show ?thesis
   691         proof (cases "n = k")
   692           case True
   693           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   694             by (simp cong: finsum_cong add: finsum_Un_disjoint
   695               ivl_disj_int_singleton Pi_def)
   696           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   697             by (simp only: ivl_disj_un_singleton)
   698           finally show ?thesis .
   699         next
   700           case False with n_le_k have n_less_k: "n < k" by arith
   701           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   702             by (simp add: finsum_Un_disjoint f1 f2
   703               ivl_disj_int_singleton Pi_def del: Un_insert_right)
   704           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   705             by (simp only: ivl_disj_un_singleton)
   706           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   707             by (simp add: finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   708           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   709             by (simp only: ivl_disj_un_one)
   710           finally show ?thesis .
   711         qed
   712       qed
   713     qed
   714     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp
   715     finally show ?thesis .
   716   qed
   717 qed (simp_all)
   718 
   719 ML_setup {*
   720   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
   721 *}
   722 
   723 lemma (in UP_cring) monom_mult_smult:
   724   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"
   725   by (rule up_eqI) simp_all
   726 
   727 lemma (in UP_cring) monom_one [simp]:
   728   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"
   729   by (rule up_eqI) simp_all
   730 
   731 lemma (in UP_cring) monom_one_mult:
   732   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"
   733 proof (induct n)
   734   case 0 show ?case by simp
   735 next
   736   case Suc then show ?case
   737     by (simp only: add_Suc monom_one_Suc) (simp add: UP_m_ac)
   738 qed
   739 
   740 lemma (in UP_cring) monom_mult [simp]:
   741   assumes R: "a \<in> carrier R" "b \<in> carrier R"
   742   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"
   743 proof -
   744   from R have "monom P (a \<otimes> b) (n + m) = monom P (a \<otimes> b \<otimes> \<one>) (n + m)" by simp
   745   also from R have "... = a \<otimes> b \<odot>\<^bsub>P\<^esub> monom P \<one> (n + m)"
   746     by (simp add: monom_mult_smult del: r_one)
   747   also have "... = a \<otimes> b \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m)"
   748     by (simp only: monom_one_mult)
   749   also from R have "... = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m))"
   750     by (simp add: UP_smult_assoc1)
   751   also from R have "... = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> (monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n))"
   752     by (simp add: UP_m_comm)
   753   also from R have "... = a \<odot>\<^bsub>P\<^esub> ((b \<odot>\<^bsub>P\<^esub> monom P \<one> m) \<otimes>\<^bsub>P\<^esub> monom P \<one> n)"
   754     by (simp add: UP_smult_assoc2)
   755   also from R have "... = a \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> monom P \<one> m))"
   756     by (simp add: UP_m_comm)
   757   also from R have "... = (a \<odot>\<^bsub>P\<^esub> monom P \<one> n) \<otimes>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> monom P \<one> m)"
   758     by (simp add: UP_smult_assoc2)
   759   also from R have "... = monom P (a \<otimes> \<one>) n \<otimes>\<^bsub>P\<^esub> monom P (b \<otimes> \<one>) m"
   760     by (simp add: monom_mult_smult del: r_one)
   761   also from R have "... = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m" by simp
   762   finally show ?thesis .
   763 qed
   764 
   765 lemma (in UP_cring) monom_a_inv [simp]:
   766   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"
   767   by (rule up_eqI) simp_all
   768 
   769 lemma (in UP_cring) monom_inj:
   770   "inj_on (%a. monom P a n) (carrier R)"
   771 proof (rule inj_onI)
   772   fix x y
   773   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   774   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   775   with R show "x = y" by simp
   776 qed
   777 
   778 subsection {* The degree function *}
   779 
   780 constdefs (structure R)
   781   deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"
   782   "deg R p == LEAST n. bound \<zero> n (coeff (UP R) p)"
   783 
   784 lemma (in UP_cring) deg_aboveI:
   785   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   786   by (unfold deg_def P_def) (fast intro: Least_le)
   787 
   788 (*
   789 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   790 proof -
   791   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   792   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   793   then show ?thesis ..
   794 qed
   795 
   796 lemma bound_coeff_obtain:
   797   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   798 proof -
   799   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   800   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   801   with prem show P .
   802 qed
   803 *)
   804 
   805 lemma (in UP_cring) deg_aboveD:
   806   "[| deg R p < m; p \<in> carrier P |] ==> coeff P p m = \<zero>"
   807 proof -
   808   assume R: "p \<in> carrier P" and "deg R p < m"
   809   from R obtain n where "bound \<zero> n (coeff P p)"
   810     by (auto simp add: UP_def P_def)
   811   then have "bound \<zero> (deg R p) (coeff P p)"
   812     by (auto simp: deg_def P_def dest: LeastI)
   813   then show ?thesis ..
   814 qed
   815 
   816 lemma (in UP_cring) deg_belowI:
   817   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"
   818     and R: "p \<in> carrier P"
   819   shows "n <= deg R p"
   820 -- {* Logically, this is a slightly stronger version of
   821    @{thm [source] deg_aboveD} *}
   822 proof (cases "n=0")
   823   case True then show ?thesis by simp
   824 next
   825   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)
   826   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)
   827   then show ?thesis by arith
   828 qed
   829 
   830 lemma (in UP_cring) lcoeff_nonzero_deg:
   831   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"
   832   shows "coeff P p (deg R p) ~= \<zero>"
   833 proof -
   834   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"
   835   proof -
   836     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"
   837       by arith
   838 (* TODO: why does simplification below not work with "1" *)
   839     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   840       by (unfold deg_def P_def) arith
   841     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   842     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"
   843       by (unfold bound_def) fast
   844     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)
   845     then show ?thesis by auto
   846   qed
   847   with deg_belowI R have "deg R p = m" by fastsimp
   848   with m_coeff show ?thesis by simp
   849 qed
   850 
   851 lemma (in UP_cring) lcoeff_nonzero_nonzero:
   852   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   853   shows "coeff P p 0 ~= \<zero>"
   854 proof -
   855   have "EX m. coeff P p m ~= \<zero>"
   856   proof (rule classical)
   857     assume "~ ?thesis"
   858     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)
   859     with nonzero show ?thesis by contradiction
   860   qed
   861   then obtain m where coeff: "coeff P p m ~= \<zero>" ..
   862   then have "m <= deg R p" by (rule deg_belowI)
   863   then have "m = 0" by (simp add: deg)
   864   with coeff show ?thesis by simp
   865 qed
   866 
   867 lemma (in UP_cring) lcoeff_nonzero:
   868   assumes neq: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   869   shows "coeff P p (deg R p) ~= \<zero>"
   870 proof (cases "deg R p = 0")
   871   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   872 next
   873   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   874 qed
   875 
   876 lemma (in UP_cring) deg_eqI:
   877   "[| !!m. n < m ==> coeff P p m = \<zero>;
   878       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"
   879 by (fast intro: le_anti_sym deg_aboveI deg_belowI)
   880 
   881 (* Degree and polynomial operations *)
   882 
   883 lemma (in UP_cring) deg_add [simp]:
   884   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   885   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) <= max (deg R p) (deg R q)"
   886 proof (cases "deg R p <= deg R q")
   887   case True show ?thesis
   888     by (rule deg_aboveI) (simp_all add: True R deg_aboveD)
   889 next
   890   case False show ?thesis
   891     by (rule deg_aboveI) (simp_all add: False R deg_aboveD)
   892 qed
   893 
   894 lemma (in UP_cring) deg_monom_le:
   895   "a \<in> carrier R ==> deg R (monom P a n) <= n"
   896   by (intro deg_aboveI) simp_all
   897 
   898 lemma (in UP_cring) deg_monom [simp]:
   899   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   900   by (fastsimp intro: le_anti_sym deg_aboveI deg_belowI)
   901 
   902 lemma (in UP_cring) deg_const [simp]:
   903   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   904 proof (rule le_anti_sym)
   905   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)
   906 next
   907   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   908 qed
   909 
   910 lemma (in UP_cring) deg_zero [simp]:
   911   "deg R \<zero>\<^bsub>P\<^esub> = 0"
   912 proof (rule le_anti_sym)
   913   show "deg R \<zero>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   914 next
   915   show "0 <= deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   916 qed
   917 
   918 lemma (in UP_cring) deg_one [simp]:
   919   "deg R \<one>\<^bsub>P\<^esub> = 0"
   920 proof (rule le_anti_sym)
   921   show "deg R \<one>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   922 next
   923   show "0 <= deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   924 qed
   925 
   926 lemma (in UP_cring) deg_uminus [simp]:
   927   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"
   928 proof (rule le_anti_sym)
   929   show "deg R (\<ominus>\<^bsub>P\<^esub> p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)
   930 next
   931   show "deg R p <= deg R (\<ominus>\<^bsub>P\<^esub> p)"
   932     by (simp add: deg_belowI lcoeff_nonzero_deg
   933       inj_on_iff [OF a_inv_inj, of _ "\<zero>", simplified] R)
   934 qed
   935 
   936 lemma (in UP_domain) deg_smult_ring:
   937   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   938   deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   939   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   940 
   941 lemma (in UP_domain) deg_smult [simp]:
   942   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   943   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"
   944 proof (rule le_anti_sym)
   945   show "deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   946     by (rule deg_smult_ring)
   947 next
   948   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^bsub>P\<^esub> p)"
   949   proof (cases "a = \<zero>")
   950   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   951 qed
   952 
   953 lemma (in UP_cring) deg_mult_cring:
   954   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   955   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q"
   956 proof (rule deg_aboveI)
   957   fix m
   958   assume boundm: "deg R p + deg R q < m"
   959   {
   960     fix k i
   961     assume boundk: "deg R p + deg R q < k"
   962     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   963     proof (cases "deg R p < i")
   964       case True then show ?thesis by (simp add: deg_aboveD R)
   965     next
   966       case False with boundk have "deg R q < k - i" by arith
   967       then show ?thesis by (simp add: deg_aboveD R)
   968     qed
   969   }
   970   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp
   971 qed (simp add: R)
   972 
   973 ML_setup {*
   974   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   975 *}
   976 
   977 lemma (in UP_domain) deg_mult [simp]:
   978   "[| p ~= \<zero>\<^bsub>P\<^esub>; q ~= \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>
   979   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"
   980 proof (rule le_anti_sym)
   981   assume "p \<in> carrier P" " q \<in> carrier P"
   982   show "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q" by (rule deg_mult_cring)
   983 next
   984   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   985   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^bsub>P\<^esub>" "q ~= \<zero>\<^bsub>P\<^esub>"
   986   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   987   show "deg R p + deg R q <= deg R (p \<otimes>\<^bsub>P\<^esub> q)"
   988   proof (rule deg_belowI, simp add: R)
   989     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   990       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"
   991       by (simp only: ivl_disj_un_one)
   992     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"
   993       by (simp cong: finsum_cong add: finsum_Un_disjoint ivl_disj_int_one
   994         deg_aboveD less_add_diff R Pi_def)
   995     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"
   996       by (simp only: ivl_disj_un_singleton)
   997     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   998       by (simp cong: finsum_cong add: finsum_Un_disjoint
   999         ivl_disj_int_singleton deg_aboveD R Pi_def)
  1000     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
  1001       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
  1002     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) ~= \<zero>"
  1003       by (simp add: integral_iff lcoeff_nonzero R)
  1004     qed (simp add: R)
  1005   qed
  1006 
  1007 lemma (in UP_cring) coeff_finsum:
  1008   assumes fin: "finite A"
  1009   shows "p \<in> A -> carrier P ==>
  1010     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"
  1011   using fin by induct (auto simp: Pi_def)
  1012 
  1013 ML_setup {*
  1014   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
  1015 *}
  1016 
  1017 lemma (in UP_cring) up_repr:
  1018   assumes R: "p \<in> carrier P"
  1019   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
  1020 proof (rule up_eqI)
  1021   let ?s = "(%i. monom P (coeff P p i) i)"
  1022   fix k
  1023   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
  1024     by simp
  1025   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"
  1026   proof (cases "k <= deg R p")
  1027     case True
  1028     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
  1029           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"
  1030       by (simp only: ivl_disj_un_one)
  1031     also from True
  1032     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"
  1033       by (simp cong: finsum_cong add: finsum_Un_disjoint
  1034         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
  1035     also
  1036     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"
  1037       by (simp only: ivl_disj_un_singleton)
  1038     also have "... = coeff P p k"
  1039       by (simp cong: finsum_cong add: setsum_Un_disjoint
  1040         ivl_disj_int_singleton coeff_finsum deg_aboveD R RR Pi_def)
  1041     finally show ?thesis .
  1042   next
  1043     case False
  1044     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
  1045           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"
  1046       by (simp only: ivl_disj_un_singleton)
  1047     also from False have "... = coeff P p k"
  1048       by (simp cong: finsum_cong add: setsum_Un_disjoint ivl_disj_int_singleton
  1049         coeff_finsum deg_aboveD R Pi_def)
  1050     finally show ?thesis .
  1051   qed
  1052 qed (simp_all add: R Pi_def)
  1053 
  1054 lemma (in UP_cring) up_repr_le:
  1055   "[| deg R p <= n; p \<in> carrier P |] ==>
  1056   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"
  1057 proof -
  1058   let ?s = "(%i. monom P (coeff P p i) i)"
  1059   assume R: "p \<in> carrier P" and "deg R p <= n"
  1060   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"
  1061     by (simp only: ivl_disj_un_one)
  1062   also have "... = finsum P ?s {..deg R p}"
  1063     by (simp cong: UP_finsum_cong add: UP_finsum_Un_disjoint ivl_disj_int_one
  1064       deg_aboveD R Pi_def)
  1065   also have "... = p" by (rule up_repr)
  1066   finally show ?thesis .
  1067 qed
  1068 
  1069 ML_setup {*
  1070   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
  1071 *}
  1072 
  1073 subsection {* Polynomials over an integral domain form an integral domain *}
  1074 
  1075 lemma domainI:
  1076   assumes cring: "cring R"
  1077     and one_not_zero: "one R ~= zero R"
  1078     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;
  1079       b \<in> carrier R |] ==> a = zero R | b = zero R"
  1080   shows "domain R"
  1081   by (auto intro!: domain.intro domain_axioms.intro cring.axioms prems
  1082     del: disjCI)
  1083 
  1084 lemma (in UP_domain) UP_one_not_zero:
  1085   "\<one>\<^bsub>P\<^esub> ~= \<zero>\<^bsub>P\<^esub>"
  1086 proof
  1087   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"
  1088   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp
  1089   hence "\<one> = \<zero>" by simp
  1090   with one_not_zero show "False" by contradiction
  1091 qed
  1092 
  1093 lemma (in UP_domain) UP_integral:
  1094   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1095 proof -
  1096   fix p q
  1097   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"
  1098   show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1099   proof (rule classical)
  1100     assume c: "~ (p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>)"
  1101     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp
  1102     also from pq have "... = 0" by simp
  1103     finally have "deg R p + deg R q = 0" .
  1104     then have f1: "deg R p = 0 & deg R q = 0" by simp
  1105     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"
  1106       by (simp only: up_repr_le)
  1107     also from R have "... = monom P (coeff P p 0) 0" by simp
  1108     finally have p: "p = monom P (coeff P p 0) 0" .
  1109     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"
  1110       by (simp only: up_repr_le)
  1111     also from R have "... = monom P (coeff P q 0) 0" by simp
  1112     finally have q: "q = monom P (coeff P q 0) 0" .
  1113     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp
  1114     also from pq have "... = \<zero>" by simp
  1115     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
  1116     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"
  1117       by (simp add: R.integral_iff)
  1118     with p q show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>" by fastsimp
  1119   qed
  1120 qed
  1121 
  1122 theorem (in UP_domain) UP_domain:
  1123   "domain P"
  1124   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
  1125 
  1126 text {*
  1127   Instantiation of theorems from @{term domain}.
  1128 *}
  1129 
  1130 (* TODO: this should be automated with an instantiation command. *)
  1131 
  1132 lemmas (in UP_domain) UP_zero_not_one [simp] =
  1133   domain.zero_not_one [OF UP_domain]
  1134 
  1135 lemmas (in UP_domain) UP_integral_iff =
  1136   domain.integral_iff [OF UP_domain]
  1137 
  1138 lemmas (in UP_domain) UP_m_lcancel =
  1139   domain.m_lcancel [OF UP_domain]
  1140 
  1141 lemmas (in UP_domain) UP_m_rcancel =
  1142   domain.m_rcancel [OF UP_domain]
  1143 
  1144 lemma (in UP_domain) smult_integral:
  1145   "[| a \<odot>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>; a \<in> carrier R; p \<in> carrier P |] ==> a = \<zero> | p = \<zero>\<^bsub>P\<^esub>"
  1146   by (simp add: monom_mult_is_smult [THEN sym] UP_integral_iff
  1147     inj_on_iff [OF monom_inj, of _ "\<zero>", simplified])
  1148 
  1149 
  1150 subsection {* Evaluation Homomorphism and Universal Property*}
  1151 
  1152 (* alternative congruence rule (possibly more efficient)
  1153 lemma (in abelian_monoid) finsum_cong2:
  1154   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
  1155   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
  1156   sorry*)
  1157 
  1158 ML_setup {*
  1159   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
  1160 *}
  1161 
  1162 theorem (in cring) diagonal_sum:
  1163   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>
  1164   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1165   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1166 proof -
  1167   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"
  1168   {
  1169     fix j
  1170     have "j <= n + m ==>
  1171       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1172       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
  1173     proof (induct j)
  1174       case 0 from Rf Rg show ?case by (simp add: Pi_def)
  1175     next
  1176       case (Suc j)
  1177       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1178         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1179       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
  1180         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1181       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
  1182         using Suc by (auto intro!: funcset_mem [OF Rf])
  1183       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1184         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1185       have R11: "g 0 \<in> carrier R"
  1186         using Suc by (auto intro!: funcset_mem [OF Rg])
  1187       from Suc show ?case
  1188         by (simp cong: finsum_cong add: Suc_diff_le a_ac
  1189           Pi_def R6 R8 R9 R10 R11)
  1190     qed
  1191   }
  1192   then show ?thesis by fast
  1193 qed
  1194 
  1195 lemma (in abelian_monoid) boundD_carrier:
  1196   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
  1197   by auto
  1198 
  1199 theorem (in cring) cauchy_product:
  1200   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
  1201     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"
  1202   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1203     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"       (* State revese direction? *)
  1204 proof -
  1205   have f: "!!x. f x \<in> carrier R"
  1206   proof -
  1207     fix x
  1208     show "f x \<in> carrier R"
  1209       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1210   qed
  1211   have g: "!!x. g x \<in> carrier R"
  1212   proof -
  1213     fix x
  1214     show "g x \<in> carrier R"
  1215       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1216   qed
  1217   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1218       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1219     by (simp add: diagonal_sum Pi_def)
  1220   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1221     by (simp only: ivl_disj_un_one)
  1222   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1223     by (simp cong: finsum_cong
  1224       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1225   also from f g
  1226   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1227     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1228   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1229     by (simp cong: finsum_cong
  1230       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1231   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1232     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1233       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1234   finally show ?thesis .
  1235 qed
  1236 
  1237 lemma (in UP_cring) const_ring_hom:
  1238   "(%a. monom P a 0) \<in> ring_hom R P"
  1239   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1240 
  1241 constdefs (structure S)
  1242   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,
  1243            'a => 'b, 'b, nat => 'a] => 'b"
  1244   "eval R S phi s == \<lambda>p \<in> carrier (UP R).
  1245     \<Oplus>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes> s (^) i"
  1246 
  1247 locale UP_univ_prop = ring_hom_cring R S + UP_cring R
  1248 
  1249 lemma (in UP) eval_on_carrier:
  1250   includes struct S
  1251   shows  "p \<in> carrier P ==>
  1252     eval R S phi s p =
  1253     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1254   by (unfold eval_def, fold P_def) simp
  1255 
  1256 lemma (in UP) eval_extensional:
  1257   "eval R S phi s \<in> extensional (carrier P)"
  1258   by (unfold eval_def, fold P_def) simp
  1259 
  1260 theorem (in UP_univ_prop) eval_ring_hom:
  1261   "s \<in> carrier S ==> eval R S h s \<in> ring_hom P S"
  1262 proof (rule ring_hom_memI)
  1263   fix p
  1264   assume RS: "p \<in> carrier P" "s \<in> carrier S"
  1265   then show "eval R S h s p \<in> carrier S"
  1266     by (simp only: eval_on_carrier) (simp add: Pi_def)
  1267 next
  1268   fix p q
  1269   assume RS: "p \<in> carrier P" "q \<in> carrier P" "s \<in> carrier S"
  1270   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1271   proof (simp only: eval_on_carrier UP_mult_closed)
  1272     from RS have
  1273       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1274       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.
  1275         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1276       by (simp cong: finsum_cong
  1277         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def
  1278         del: coeff_mult)
  1279     also from RS have "... =
  1280       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1281       by (simp only: ivl_disj_un_one deg_mult_cring)
  1282     also from RS have "... =
  1283       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.
  1284          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.
  1285            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>
  1286            (s (^)\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> (i - k)))"
  1287       by (simp cong: finsum_cong add: nat_pow_mult Pi_def
  1288         S.m_ac S.finsum_rdistr)
  1289     also from RS have "... =
  1290       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1291       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1292       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1293         Pi_def)
  1294     finally show
  1295       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1296       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1297       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1298   qed
  1299 next
  1300   fix p q
  1301   assume RS: "p \<in> carrier P" "q \<in> carrier P" "s \<in> carrier S"
  1302   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1303   proof (simp only: eval_on_carrier UP_a_closed)
  1304     from RS have
  1305       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1306       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.
  1307         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1308       by (simp cong: finsum_cong
  1309         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def
  1310         del: coeff_add)
  1311     also from RS have "... =
  1312         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.
  1313           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1314       by (simp add: ivl_disj_un_one)
  1315     also from RS have "... =
  1316       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1317       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1318       by (simp cong: finsum_cong
  1319         add: l_distr deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1320     also have "... =
  1321         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1322           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1323         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1324           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1325       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)
  1326     also from RS have "... =
  1327       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1328       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1329       by (simp cong: finsum_cong
  1330         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1331     finally show
  1332       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1333       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1334       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1335   qed
  1336 next
  1337   assume S: "s \<in> carrier S"
  1338   then show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1339     by (simp only: eval_on_carrier UP_one_closed) simp
  1340 qed
  1341 
  1342 text {* Instantiation of ring homomorphism lemmas. *}
  1343 
  1344 (* TODO: again, automate with instantiation command *)
  1345 
  1346 lemma (in UP_univ_prop) ring_hom_cring_P_S:
  1347   "s \<in> carrier S ==> ring_hom_cring P S (eval R S h s)"
  1348   by (fast intro!: ring_hom_cring.intro UP_cring cring.axioms prems
  1349     intro: ring_hom_cring_axioms.intro eval_ring_hom)
  1350 
  1351 (*
  1352 lemma (in UP_univ_prop) UP_hom_closed [intro, simp]:
  1353   "[| s \<in> carrier S; p \<in> carrier P |] ==> eval R S h s p \<in> carrier S"
  1354   by (rule ring_hom_cring.hom_closed [OF ring_hom_cring_P_S])
  1355 
  1356 lemma (in UP_univ_prop) UP_hom_mult [simp]:
  1357   "[| s \<in> carrier S; p \<in> carrier P; q \<in> carrier P |] ==>
  1358   eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1359   by (rule ring_hom_cring.hom_mult [OF ring_hom_cring_P_S])
  1360 
  1361 lemma (in UP_univ_prop) UP_hom_add [simp]:
  1362   "[| s \<in> carrier S; p \<in> carrier P; q \<in> carrier P |] ==>
  1363   eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1364   by (rule ring_hom_cring.hom_add [OF ring_hom_cring_P_S])
  1365 
  1366 lemma (in UP_univ_prop) UP_hom_one [simp]:
  1367   "s \<in> carrier S ==> eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1368   by (rule ring_hom_cring.hom_one [OF ring_hom_cring_P_S])
  1369 
  1370 lemma (in UP_univ_prop) UP_hom_zero [simp]:
  1371   "s \<in> carrier S ==> eval R S h s \<zero>\<^bsub>P\<^esub> = \<zero>\<^bsub>S\<^esub>"
  1372   by (rule ring_hom_cring.hom_zero [OF ring_hom_cring_P_S])
  1373 
  1374 lemma (in UP_univ_prop) UP_hom_a_inv [simp]:
  1375   "[| s \<in> carrier S; p \<in> carrier P |] ==>
  1376   (eval R S h s) (\<ominus>\<^bsub>P\<^esub> p) = \<ominus>\<^bsub>S\<^esub> (eval R S h s) p"
  1377   by (rule ring_hom_cring.hom_a_inv [OF ring_hom_cring_P_S])
  1378 
  1379 lemma (in UP_univ_prop) UP_hom_finsum [simp]:
  1380   "[| s \<in> carrier S; finite A; f \<in> A -> carrier P |] ==>
  1381   (eval R S h s) (finsum P f A) = finsum S (eval R S h s o f) A"
  1382   by (rule ring_hom_cring.hom_finsum [OF ring_hom_cring_P_S])
  1383 
  1384 lemma (in UP_univ_prop) UP_hom_finprod [simp]:
  1385   "[| s \<in> carrier S; finite A; f \<in> A -> carrier P |] ==>
  1386   (eval R S h s) (finprod P f A) = finprod S (eval R S h s o f) A"
  1387   by (rule ring_hom_cring.hom_finprod [OF ring_hom_cring_P_S])
  1388 *)
  1389 
  1390 text {* Further properties of the evaluation homomorphism. *}
  1391 
  1392 (* The following lemma could be proved in UP\_cring with the additional
  1393    assumption that h is closed. *)
  1394 
  1395 lemma (in UP_univ_prop) eval_const:
  1396   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1397   by (simp only: eval_on_carrier monom_closed) simp
  1398 
  1399 text {* The following proof is complicated by the fact that in arbitrary
  1400   rings one might have @{term "one R = zero R"}. *}
  1401 
  1402 (* TODO: simplify by cases "one R = zero R" *)
  1403 
  1404 lemma (in UP_univ_prop) eval_monom1:
  1405   "s \<in> carrier S ==> eval R S h s (monom P \<one> 1) = s"
  1406 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1407   assume S: "s \<in> carrier S"
  1408   then have
  1409     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1410     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1411       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1412     by (simp cong: finsum_cong del: coeff_monom
  1413       add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1414   also have "... =
  1415     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1416     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1417   also have "... = s"
  1418   proof (cases "s = \<zero>\<^bsub>S\<^esub>")
  1419     case True then show ?thesis by (simp add: Pi_def)
  1420   next
  1421     case False with S show ?thesis by (simp add: Pi_def)
  1422   qed
  1423   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.
  1424     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) = s" .
  1425 qed
  1426 
  1427 lemma (in UP_cring) monom_pow:
  1428   assumes R: "a \<in> carrier R"
  1429   shows "(monom P a n) (^)\<^bsub>P\<^esub> m = monom P (a (^) m) (n * m)"
  1430 proof (induct m)
  1431   case 0 from R show ?case by simp
  1432 next
  1433   case Suc with R show ?case
  1434     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)
  1435 qed
  1436 
  1437 lemma (in ring_hom_cring) hom_pow [simp]:
  1438   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^bsub>S\<^esub> (n::nat)"
  1439   by (induct n) simp_all
  1440 
  1441 lemma (in UP_univ_prop) eval_monom:
  1442   "[| s \<in> carrier S; r \<in> carrier R |] ==>
  1443   eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1444 proof -
  1445   assume S: "s \<in> carrier S" and R: "r \<in> carrier R"
  1446   from R S have "eval R S h s (monom P r n) =
  1447     eval R S h s (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) (^)\<^bsub>P\<^esub> n)"
  1448     by (simp del: monom_mult (* eval.hom_mult eval.hom_pow, delayed inst! *)
  1449       add: monom_mult [THEN sym] monom_pow)
  1450   also
  1451   from ring_hom_cring_P_S [OF S] instantiate eval: ring_hom_cring
  1452   from R S eval_monom1 have "... = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1453     by (simp add: eval_const)
  1454   finally show ?thesis .
  1455 qed
  1456 
  1457 lemma (in UP_univ_prop) eval_smult:
  1458   "[| s \<in> carrier S; r \<in> carrier R; p \<in> carrier P |] ==>
  1459   eval R S h s (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> eval R S h s p"
  1460 proof -
  1461   assume S: "s \<in> carrier S" and R: "r \<in> carrier R" and P: "p \<in> carrier P"
  1462   from ring_hom_cring_P_S [OF S] instantiate eval: ring_hom_cring
  1463   from S R P show ?thesis
  1464     by (simp add: monom_mult_is_smult [THEN sym] eval_const)
  1465 qed
  1466 
  1467 lemma ring_hom_cringI:
  1468   assumes "cring R"
  1469     and "cring S"
  1470     and "h \<in> ring_hom R S"
  1471   shows "ring_hom_cring R S h"
  1472   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1473     cring.axioms prems)
  1474 
  1475 lemma (in UP_univ_prop) UP_hom_unique:
  1476   assumes Phi: "Phi \<in> ring_hom P S" "Phi (monom P \<one> (Suc 0)) = s"
  1477       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1478     and Psi: "Psi \<in> ring_hom P S" "Psi (monom P \<one> (Suc 0)) = s"
  1479       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1480     and S: "s \<in> carrier S" and P: "p \<in> carrier P"
  1481   shows "Phi p = Psi p"
  1482 proof -
  1483   have Phi_hom: "ring_hom_cring P S Phi"
  1484     by (auto intro: ring_hom_cringI UP_cring S.cring Phi)
  1485   have Psi_hom: "ring_hom_cring P S Psi"
  1486     by (auto intro: ring_hom_cringI UP_cring S.cring Psi)
  1487   have "Phi p =
  1488       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1489     by (simp add: up_repr P S monom_mult [THEN sym] monom_pow del: monom_mult)
  1490   also 
  1491     from Phi_hom instantiate Phi: ring_hom_cring
  1492     from Psi_hom instantiate Psi: ring_hom_cring
  1493     have "... =
  1494       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1495     by (simp add: Phi Psi P S Pi_def comp_def)
  1496 (* Without instantiate, the following command would have been necessary.
  1497     by (simp add: ring_hom_cring.hom_finsum [OF Phi_hom]
  1498       ring_hom_cring.hom_mult [OF Phi_hom]
  1499       ring_hom_cring.hom_pow [OF Phi_hom] Phi
  1500       ring_hom_cring.hom_finsum [OF Psi_hom]
  1501       ring_hom_cring.hom_mult [OF Psi_hom]
  1502       ring_hom_cring.hom_pow [OF Psi_hom] Psi RS Pi_def comp_def)
  1503 *)
  1504   also have "... = Psi p"
  1505     by (simp add: up_repr P S monom_mult [THEN sym] monom_pow del: monom_mult)
  1506   finally show ?thesis .
  1507 qed
  1508 
  1509 theorem (in UP_univ_prop) UP_universal_property:
  1510   "s \<in> carrier S ==>
  1511   EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &
  1512     Phi (monom P \<one> 1) = s &
  1513     (ALL r : carrier R. Phi (monom P r 0) = h r)"
  1514   using eval_monom1
  1515   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1516   apply (rule extensionalityI)
  1517   apply (auto intro: UP_hom_unique)
  1518   done
  1519 
  1520 subsection {* Sample application of evaluation homomorphism *}
  1521 
  1522 lemma UP_univ_propI:
  1523   assumes "cring R"
  1524     and "cring S"
  1525     and "h \<in> ring_hom R S"
  1526   shows "UP_univ_prop R S h"
  1527   by (fast intro: UP_univ_prop.intro ring_hom_cring_axioms.intro
  1528     cring.axioms prems)
  1529 
  1530 constdefs
  1531   INTEG :: "int ring"
  1532   "INTEG == (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"
  1533 
  1534 lemma INTEG_cring:
  1535   "cring INTEG"
  1536   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1537     zadd_zminus_inverse2 zadd_zmult_distrib)
  1538 
  1539 lemma INTEG_id_eval:
  1540   "UP_univ_prop INTEG INTEG id"
  1541   by (fast intro: UP_univ_propI INTEG_cring id_ring_hom)
  1542 
  1543 text {*
  1544   An instantiation mechanism would now import all theorems and lemmas
  1545   valid in the context of homomorphisms between @{term INTEG} and @{term
  1546   "UP INTEG"} globally.
  1547 *}
  1548 
  1549 lemma INTEG_closed [intro, simp]:
  1550   "z \<in> carrier INTEG"
  1551   by (unfold INTEG_def) simp
  1552 
  1553 lemma INTEG_mult [simp]:
  1554   "mult INTEG z w = z * w"
  1555   by (unfold INTEG_def) simp
  1556 
  1557 lemma INTEG_pow [simp]:
  1558   "pow INTEG z n = z ^ n"
  1559   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1560 
  1561 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1562   by (simp add: UP_univ_prop.eval_monom [OF INTEG_id_eval])
  1563 
  1564 end