src/HOL/Relation.thy
author haftmann
Tue Jul 10 17:30:50 2007 +0200 (2007-07-10)
changeset 23709 fd31da8f752a
parent 23185 1fa87978cf27
child 24286 7619080e49f0
permissions -rw-r--r--
moved lfp_induct2 here
     1 (*  Title:      HOL/Relation.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 *)
     6 
     7 header {* Relations *}
     8 
     9 theory Relation
    10 imports Product_Type FixedPoint
    11 begin
    12 
    13 subsection {* Definitions *}
    14 
    15 definition
    16   converse :: "('a * 'b) set => ('b * 'a) set"
    17     ("(_^-1)" [1000] 999) where
    18   "r^-1 == {(y, x). (x, y) : r}"
    19 
    20 notation (xsymbols)
    21   converse  ("(_\<inverse>)" [1000] 999)
    22 
    23 definition
    24   rel_comp  :: "[('b * 'c) set, ('a * 'b) set] => ('a * 'c) set"
    25     (infixr "O" 75) where
    26   "r O s == {(x,z). EX y. (x, y) : s & (y, z) : r}"
    27 
    28 definition
    29   Image :: "[('a * 'b) set, 'a set] => 'b set"
    30     (infixl "``" 90) where
    31   "r `` s == {y. EX x:s. (x,y):r}"
    32 
    33 definition
    34   Id :: "('a * 'a) set" where -- {* the identity relation *}
    35   "Id == {p. EX x. p = (x,x)}"
    36 
    37 definition
    38   diag  :: "'a set => ('a * 'a) set" where -- {* diagonal: identity over a set *}
    39   "diag A == \<Union>x\<in>A. {(x,x)}"
    40 
    41 definition
    42   Domain :: "('a * 'b) set => 'a set" where
    43   "Domain r == {x. EX y. (x,y):r}"
    44 
    45 definition
    46   Range  :: "('a * 'b) set => 'b set" where
    47   "Range r == Domain(r^-1)"
    48 
    49 definition
    50   Field :: "('a * 'a) set => 'a set" where
    51   "Field r == Domain r \<union> Range r"
    52 
    53 definition
    54   refl :: "['a set, ('a * 'a) set] => bool" where -- {* reflexivity over a set *}
    55   "refl A r == r \<subseteq> A \<times> A & (ALL x: A. (x,x) : r)"
    56 
    57 definition
    58   sym :: "('a * 'a) set => bool" where -- {* symmetry predicate *}
    59   "sym r == ALL x y. (x,y): r --> (y,x): r"
    60 
    61 definition
    62   antisym :: "('a * 'a) set => bool" where -- {* antisymmetry predicate *}
    63   "antisym r == ALL x y. (x,y):r --> (y,x):r --> x=y"
    64 
    65 definition
    66   trans :: "('a * 'a) set => bool" where -- {* transitivity predicate *}
    67   "trans r == (ALL x y z. (x,y):r --> (y,z):r --> (x,z):r)"
    68 
    69 definition
    70   single_valued :: "('a * 'b) set => bool" where
    71   "single_valued r == ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z)"
    72 
    73 definition
    74   inv_image :: "('b * 'b) set => ('a => 'b) => ('a * 'a) set" where
    75   "inv_image r f == {(x, y). (f x, f y) : r}"
    76 
    77 abbreviation
    78   reflexive :: "('a * 'a) set => bool" where -- {* reflexivity over a type *}
    79   "reflexive == refl UNIV"
    80 
    81 
    82 subsection {* The identity relation *}
    83 
    84 lemma IdI [intro]: "(a, a) : Id"
    85   by (simp add: Id_def)
    86 
    87 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
    88   by (unfold Id_def) (iprover elim: CollectE)
    89 
    90 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
    91   by (unfold Id_def) blast
    92 
    93 lemma reflexive_Id: "reflexive Id"
    94   by (simp add: refl_def)
    95 
    96 lemma antisym_Id: "antisym Id"
    97   -- {* A strange result, since @{text Id} is also symmetric. *}
    98   by (simp add: antisym_def)
    99 
   100 lemma sym_Id: "sym Id"
   101   by (simp add: sym_def)
   102 
   103 lemma trans_Id: "trans Id"
   104   by (simp add: trans_def)
   105 
   106 
   107 subsection {* Diagonal: identity over a set *}
   108 
   109 lemma diag_empty [simp]: "diag {} = {}"
   110   by (simp add: diag_def) 
   111 
   112 lemma diag_eqI: "a = b ==> a : A ==> (a, b) : diag A"
   113   by (simp add: diag_def)
   114 
   115 lemma diagI [intro!]: "a : A ==> (a, a) : diag A"
   116   by (rule diag_eqI) (rule refl)
   117 
   118 lemma diagE [elim!]:
   119   "c : diag A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   120   -- {* The general elimination rule. *}
   121   by (unfold diag_def) (iprover elim!: UN_E singletonE)
   122 
   123 lemma diag_iff: "((x, y) : diag A) = (x = y & x : A)"
   124   by blast
   125 
   126 lemma diag_subset_Times: "diag A \<subseteq> A \<times> A"
   127   by blast
   128 
   129 
   130 subsection {* Composition of two relations *}
   131 
   132 lemma rel_compI [intro]:
   133   "(a, b) : s ==> (b, c) : r ==> (a, c) : r O s"
   134   by (unfold rel_comp_def) blast
   135 
   136 lemma rel_compE [elim!]: "xz : r O s ==>
   137   (!!x y z. xz = (x, z) ==> (x, y) : s ==> (y, z) : r  ==> P) ==> P"
   138   by (unfold rel_comp_def) (iprover elim!: CollectE splitE exE conjE)
   139 
   140 lemma rel_compEpair:
   141   "(a, c) : r O s ==> (!!y. (a, y) : s ==> (y, c) : r ==> P) ==> P"
   142   by (iprover elim: rel_compE Pair_inject ssubst)
   143 
   144 lemma R_O_Id [simp]: "R O Id = R"
   145   by fast
   146 
   147 lemma Id_O_R [simp]: "Id O R = R"
   148   by fast
   149 
   150 lemma rel_comp_empty1[simp]: "{} O R = {}"
   151   by blast
   152 
   153 lemma rel_comp_empty2[simp]: "R O {} = {}"
   154   by blast
   155 
   156 lemma O_assoc: "(R O S) O T = R O (S O T)"
   157   by blast
   158 
   159 lemma trans_O_subset: "trans r ==> r O r \<subseteq> r"
   160   by (unfold trans_def) blast
   161 
   162 lemma rel_comp_mono: "r' \<subseteq> r ==> s' \<subseteq> s ==> (r' O s') \<subseteq> (r O s)"
   163   by blast
   164 
   165 lemma rel_comp_subset_Sigma:
   166     "s \<subseteq> A \<times> B ==> r \<subseteq> B \<times> C ==> (r O s) \<subseteq> A \<times> C"
   167   by blast
   168 
   169 
   170 subsection {* Reflexivity *}
   171 
   172 lemma reflI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl A r"
   173   by (unfold refl_def) (iprover intro!: ballI)
   174 
   175 lemma reflD: "refl A r ==> a : A ==> (a, a) : r"
   176   by (unfold refl_def) blast
   177 
   178 lemma reflD1: "refl A r ==> (x, y) : r ==> x : A"
   179   by (unfold refl_def) blast
   180 
   181 lemma reflD2: "refl A r ==> (x, y) : r ==> y : A"
   182   by (unfold refl_def) blast
   183 
   184 lemma refl_Int: "refl A r ==> refl B s ==> refl (A \<inter> B) (r \<inter> s)"
   185   by (unfold refl_def) blast
   186 
   187 lemma refl_Un: "refl A r ==> refl B s ==> refl (A \<union> B) (r \<union> s)"
   188   by (unfold refl_def) blast
   189 
   190 lemma refl_INTER:
   191   "ALL x:S. refl (A x) (r x) ==> refl (INTER S A) (INTER S r)"
   192   by (unfold refl_def) fast
   193 
   194 lemma refl_UNION:
   195   "ALL x:S. refl (A x) (r x) \<Longrightarrow> refl (UNION S A) (UNION S r)"
   196   by (unfold refl_def) blast
   197 
   198 lemma refl_diag: "refl A (diag A)"
   199   by (rule reflI [OF diag_subset_Times diagI])
   200 
   201 
   202 subsection {* Antisymmetry *}
   203 
   204 lemma antisymI:
   205   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   206   by (unfold antisym_def) iprover
   207 
   208 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   209   by (unfold antisym_def) iprover
   210 
   211 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   212   by (unfold antisym_def) blast
   213 
   214 lemma antisym_empty [simp]: "antisym {}"
   215   by (unfold antisym_def) blast
   216 
   217 lemma antisym_diag [simp]: "antisym (diag A)"
   218   by (unfold antisym_def) blast
   219 
   220 
   221 subsection {* Symmetry *}
   222 
   223 lemma symI: "(!!a b. (a, b) : r ==> (b, a) : r) ==> sym r"
   224   by (unfold sym_def) iprover
   225 
   226 lemma symD: "sym r ==> (a, b) : r ==> (b, a) : r"
   227   by (unfold sym_def, blast)
   228 
   229 lemma sym_Int: "sym r ==> sym s ==> sym (r \<inter> s)"
   230   by (fast intro: symI dest: symD)
   231 
   232 lemma sym_Un: "sym r ==> sym s ==> sym (r \<union> s)"
   233   by (fast intro: symI dest: symD)
   234 
   235 lemma sym_INTER: "ALL x:S. sym (r x) ==> sym (INTER S r)"
   236   by (fast intro: symI dest: symD)
   237 
   238 lemma sym_UNION: "ALL x:S. sym (r x) ==> sym (UNION S r)"
   239   by (fast intro: symI dest: symD)
   240 
   241 lemma sym_diag [simp]: "sym (diag A)"
   242   by (rule symI) clarify
   243 
   244 
   245 subsection {* Transitivity *}
   246 
   247 lemma transI:
   248   "(!!x y z. (x, y) : r ==> (y, z) : r ==> (x, z) : r) ==> trans r"
   249   by (unfold trans_def) iprover
   250 
   251 lemma transD: "trans r ==> (a, b) : r ==> (b, c) : r ==> (a, c) : r"
   252   by (unfold trans_def) iprover
   253 
   254 lemma trans_Int: "trans r ==> trans s ==> trans (r \<inter> s)"
   255   by (fast intro: transI elim: transD)
   256 
   257 lemma trans_INTER: "ALL x:S. trans (r x) ==> trans (INTER S r)"
   258   by (fast intro: transI elim: transD)
   259 
   260 lemma trans_diag [simp]: "trans (diag A)"
   261   by (fast intro: transI elim: transD)
   262 
   263 
   264 subsection {* Converse *}
   265 
   266 lemma converse_iff [iff]: "((a,b): r^-1) = ((b,a) : r)"
   267   by (simp add: converse_def)
   268 
   269 lemma converseI[sym]: "(a, b) : r ==> (b, a) : r^-1"
   270   by (simp add: converse_def)
   271 
   272 lemma converseD[sym]: "(a,b) : r^-1 ==> (b, a) : r"
   273   by (simp add: converse_def)
   274 
   275 lemma converseE [elim!]:
   276   "yx : r^-1 ==> (!!x y. yx = (y, x) ==> (x, y) : r ==> P) ==> P"
   277     -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   278   by (unfold converse_def) (iprover elim!: CollectE splitE bexE)
   279 
   280 lemma converse_converse [simp]: "(r^-1)^-1 = r"
   281   by (unfold converse_def) blast
   282 
   283 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   284   by blast
   285 
   286 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   287   by blast
   288 
   289 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   290   by blast
   291 
   292 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   293   by fast
   294 
   295 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   296   by blast
   297 
   298 lemma converse_Id [simp]: "Id^-1 = Id"
   299   by blast
   300 
   301 lemma converse_diag [simp]: "(diag A)^-1 = diag A"
   302   by blast
   303 
   304 lemma refl_converse [simp]: "refl A (converse r) = refl A r"
   305   by (unfold refl_def) auto
   306 
   307 lemma sym_converse [simp]: "sym (converse r) = sym r"
   308   by (unfold sym_def) blast
   309 
   310 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   311   by (unfold antisym_def) blast
   312 
   313 lemma trans_converse [simp]: "trans (converse r) = trans r"
   314   by (unfold trans_def) blast
   315 
   316 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   317   by (unfold sym_def) fast
   318 
   319 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   320   by (unfold sym_def) blast
   321 
   322 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   323   by (unfold sym_def) blast
   324 
   325 
   326 subsection {* Domain *}
   327 
   328 lemma Domain_iff: "(a : Domain r) = (EX y. (a, y) : r)"
   329   by (unfold Domain_def) blast
   330 
   331 lemma DomainI [intro]: "(a, b) : r ==> a : Domain r"
   332   by (iprover intro!: iffD2 [OF Domain_iff])
   333 
   334 lemma DomainE [elim!]:
   335   "a : Domain r ==> (!!y. (a, y) : r ==> P) ==> P"
   336   by (iprover dest!: iffD1 [OF Domain_iff])
   337 
   338 lemma Domain_empty [simp]: "Domain {} = {}"
   339   by blast
   340 
   341 lemma Domain_insert: "Domain (insert (a, b) r) = insert a (Domain r)"
   342   by blast
   343 
   344 lemma Domain_Id [simp]: "Domain Id = UNIV"
   345   by blast
   346 
   347 lemma Domain_diag [simp]: "Domain (diag A) = A"
   348   by blast
   349 
   350 lemma Domain_Un_eq: "Domain(A \<union> B) = Domain(A) \<union> Domain(B)"
   351   by blast
   352 
   353 lemma Domain_Int_subset: "Domain(A \<inter> B) \<subseteq> Domain(A) \<inter> Domain(B)"
   354   by blast
   355 
   356 lemma Domain_Diff_subset: "Domain(A) - Domain(B) \<subseteq> Domain(A - B)"
   357   by blast
   358 
   359 lemma Domain_Union: "Domain (Union S) = (\<Union>A\<in>S. Domain A)"
   360   by blast
   361 
   362 lemma Domain_mono: "r \<subseteq> s ==> Domain r \<subseteq> Domain s"
   363   by blast
   364 
   365 lemma fst_eq_Domain: "fst ` R = Domain R";
   366   apply auto
   367   apply (rule image_eqI, auto) 
   368   done
   369 
   370 
   371 subsection {* Range *}
   372 
   373 lemma Range_iff: "(a : Range r) = (EX y. (y, a) : r)"
   374   by (simp add: Domain_def Range_def)
   375 
   376 lemma RangeI [intro]: "(a, b) : r ==> b : Range r"
   377   by (unfold Range_def) (iprover intro!: converseI DomainI)
   378 
   379 lemma RangeE [elim!]: "b : Range r ==> (!!x. (x, b) : r ==> P) ==> P"
   380   by (unfold Range_def) (iprover elim!: DomainE dest!: converseD)
   381 
   382 lemma Range_empty [simp]: "Range {} = {}"
   383   by blast
   384 
   385 lemma Range_insert: "Range (insert (a, b) r) = insert b (Range r)"
   386   by blast
   387 
   388 lemma Range_Id [simp]: "Range Id = UNIV"
   389   by blast
   390 
   391 lemma Range_diag [simp]: "Range (diag A) = A"
   392   by auto
   393 
   394 lemma Range_Un_eq: "Range(A \<union> B) = Range(A) \<union> Range(B)"
   395   by blast
   396 
   397 lemma Range_Int_subset: "Range(A \<inter> B) \<subseteq> Range(A) \<inter> Range(B)"
   398   by blast
   399 
   400 lemma Range_Diff_subset: "Range(A) - Range(B) \<subseteq> Range(A - B)"
   401   by blast
   402 
   403 lemma Range_Union: "Range (Union S) = (\<Union>A\<in>S. Range A)"
   404   by blast
   405 
   406 lemma snd_eq_Range: "snd ` R = Range R";
   407   apply auto
   408   apply (rule image_eqI, auto) 
   409   done
   410 
   411 
   412 subsection {* Image of a set under a relation *}
   413 
   414 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   415   by (simp add: Image_def)
   416 
   417 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   418   by (simp add: Image_def)
   419 
   420 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   421   by (rule Image_iff [THEN trans]) simp
   422 
   423 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
   424   by (unfold Image_def) blast
   425 
   426 lemma ImageE [elim!]:
   427     "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   428   by (unfold Image_def) (iprover elim!: CollectE bexE)
   429 
   430 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   431   -- {* This version's more effective when we already have the required @{text a} *}
   432   by blast
   433 
   434 lemma Image_empty [simp]: "R``{} = {}"
   435   by blast
   436 
   437 lemma Image_Id [simp]: "Id `` A = A"
   438   by blast
   439 
   440 lemma Image_diag [simp]: "diag A `` B = A \<inter> B"
   441   by blast
   442 
   443 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   444   by blast
   445 
   446 lemma Image_Int_eq:
   447      "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   448   by (simp add: single_valued_def, blast) 
   449 
   450 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   451   by blast
   452 
   453 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   454   by blast
   455 
   456 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   457   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   458 
   459 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   460   -- {* NOT suitable for rewriting *}
   461   by blast
   462 
   463 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   464   by blast
   465 
   466 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   467   by blast
   468 
   469 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   470   by blast
   471 
   472 text{*Converse inclusion requires some assumptions*}
   473 lemma Image_INT_eq:
   474      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   475 apply (rule equalityI)
   476  apply (rule Image_INT_subset) 
   477 apply  (simp add: single_valued_def, blast)
   478 done
   479 
   480 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   481   by blast
   482 
   483 
   484 subsection {* Single valued relations *}
   485 
   486 lemma single_valuedI:
   487   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   488   by (unfold single_valued_def)
   489 
   490 lemma single_valuedD:
   491   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   492   by (simp add: single_valued_def)
   493 
   494 lemma single_valued_rel_comp:
   495   "single_valued r ==> single_valued s ==> single_valued (r O s)"
   496   by (unfold single_valued_def) blast
   497 
   498 lemma single_valued_subset:
   499   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   500   by (unfold single_valued_def) blast
   501 
   502 lemma single_valued_Id [simp]: "single_valued Id"
   503   by (unfold single_valued_def) blast
   504 
   505 lemma single_valued_diag [simp]: "single_valued (diag A)"
   506   by (unfold single_valued_def) blast
   507 
   508 
   509 subsection {* Graphs given by @{text Collect} *}
   510 
   511 lemma Domain_Collect_split [simp]: "Domain{(x,y). P x y} = {x. EX y. P x y}"
   512   by auto
   513 
   514 lemma Range_Collect_split [simp]: "Range{(x,y). P x y} = {y. EX x. P x y}"
   515   by auto
   516 
   517 lemma Image_Collect_split [simp]: "{(x,y). P x y} `` A = {y. EX x:A. P x y}"
   518   by auto
   519 
   520 
   521 subsection {* Inverse image *}
   522 
   523 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
   524   by (unfold sym_def inv_image_def) blast
   525 
   526 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
   527   apply (unfold trans_def inv_image_def)
   528   apply (simp (no_asm))
   529   apply blast
   530   done
   531 
   532 
   533 subsection {* Version of @{text lfp_induct} for binary relations *}
   534 
   535 lemmas lfp_induct2 = 
   536   lfp_induct_set [of "(a, b)", split_format (complete)]
   537 
   538 end