src/Pure/sign.ML
author wenzelm
Fri May 23 21:20:26 2008 +0200 (2008-05-23)
changeset 26978 fd4b4ecf935e
parent 26939 1035c89b4c02
child 27195 bbf4cbc69243
permissions -rw-r--r--
add constants: set Markup.theory_nameN in tags;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN =
    10 sig
    11   val rep_sg: theory ->
    12    {naming: NameSpace.naming,
    13     syn: Syntax.syntax,
    14     tsig: Type.tsig,
    15     consts: Consts.T}
    16   val naming_of: theory -> NameSpace.naming
    17   val base_name: string -> bstring
    18   val full_name: theory -> bstring -> string
    19   val full_name_path: theory -> string -> bstring -> string
    20   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val defaultS: theory -> sort
    29   val subsort: theory -> sort * sort -> bool
    30   val of_sort: theory -> typ * sort -> bool
    31   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    32   val is_logtype: theory -> string -> bool
    33   val typ_instance: theory -> typ * typ -> bool
    34   val typ_equiv: theory -> typ * typ -> bool
    35   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    36   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    37   val consts_of: theory -> Consts.T
    38   val the_const_constraint: theory -> string -> typ
    39   val const_type: theory -> string -> typ option
    40   val the_const_type: theory -> string -> typ
    41   val declared_tyname: theory -> string -> bool
    42   val declared_const: theory -> string -> bool
    43   val const_monomorphic: theory -> string -> bool
    44   val const_syntax_name: theory -> string -> string
    45   val const_typargs: theory -> string * typ -> typ list
    46   val const_instance: theory -> string * typ list -> typ
    47   val mk_const: theory -> string * typ list -> term
    48   val class_space: theory -> NameSpace.T
    49   val type_space: theory -> NameSpace.T
    50   val const_space: theory -> NameSpace.T
    51   val intern_class: theory -> xstring -> string
    52   val extern_class: theory -> string -> xstring
    53   val intern_type: theory -> xstring -> string
    54   val extern_type: theory -> string -> xstring
    55   val intern_const: theory -> xstring -> string
    56   val extern_const: theory -> string -> xstring
    57   val intern_sort: theory -> sort -> sort
    58   val extern_sort: theory -> sort -> sort
    59   val intern_typ: theory -> typ -> typ
    60   val extern_typ: theory -> typ -> typ
    61   val intern_term: theory -> term -> term
    62   val extern_term: (string -> xstring) -> theory -> term -> term
    63   val intern_tycons: theory -> typ -> typ
    64   val arity_number: theory -> string -> int
    65   val arity_sorts: theory -> string -> sort -> sort list
    66   val certify_class: theory -> class -> class
    67   val certify_sort: theory -> sort -> sort
    68   val certify_typ: theory -> typ -> typ
    69   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    70   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    71   val certify_term: theory -> term -> term * typ * int
    72   val certify_prop: theory -> term -> term * typ * int
    73   val cert_term: theory -> term -> term
    74   val cert_prop: theory -> term -> term
    75   val no_frees: Pretty.pp -> term -> term
    76   val no_vars: Pretty.pp -> term -> term
    77   val cert_def: Proof.context -> term -> (string * typ) * term
    78   val read_class: theory -> xstring -> class
    79   val read_arity: theory -> xstring * string list * string -> arity
    80   val cert_arity: theory -> arity -> arity
    81   val get_sort: theory ->
    82     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
    83   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
    84   val read_typ: theory -> string -> typ
    85   val read_typ_syntax: theory -> string -> typ
    86   val read_typ_abbrev: theory -> string -> typ
    87   val read_def_terms:
    88     theory * (indexname -> typ option) * (indexname -> sort option) ->
    89     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
    90   val simple_read_term: theory -> typ -> string -> term
    91   val read_term: theory -> string -> term
    92   val read_prop: theory -> string -> term
    93   val add_defsort: string -> theory -> theory
    94   val add_defsort_i: sort -> theory -> theory
    95   val add_types: (bstring * int * mixfix) list -> theory -> theory
    96   val add_nonterminals: bstring list -> theory -> theory
    97   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    98   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    99   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
   100   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
   101   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
   102   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
   103   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
   104   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
   105   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
   106   val add_consts: (bstring * string * mixfix) list -> theory -> theory
   107   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
   108   val declare_const: Markup.property list -> bstring * typ * mixfix -> theory -> term * theory
   109   val add_abbrev: string -> Markup.property list ->
   110     bstring * term -> theory -> (term * term) * theory
   111   val revert_abbrev: string -> string -> theory -> theory
   112   val add_const_constraint: string * typ option -> theory -> theory
   113   val primitive_class: string * class list -> theory -> theory
   114   val primitive_classrel: class * class -> theory -> theory
   115   val primitive_arity: arity -> theory -> theory
   116   val add_trfuns:
   117     (string * (ast list -> ast)) list *
   118     (string * (term list -> term)) list *
   119     (string * (term list -> term)) list *
   120     (string * (ast list -> ast)) list -> theory -> theory
   121   val add_trfunsT:
   122     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   123   val add_advanced_trfuns:
   124     (string * (Proof.context -> ast list -> ast)) list *
   125     (string * (Proof.context -> term list -> term)) list *
   126     (string * (Proof.context -> term list -> term)) list *
   127     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   128   val add_advanced_trfunsT:
   129     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   130   val add_tokentrfuns:
   131     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   132   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   133     -> theory -> theory
   134   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   135   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   136   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   137   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   138   val add_path: string -> theory -> theory
   139   val parent_path: theory -> theory
   140   val root_path: theory -> theory
   141   val absolute_path: theory -> theory
   142   val local_path: theory -> theory
   143   val no_base_names: theory -> theory
   144   val qualified_names: theory -> theory
   145   val sticky_prefix: string -> theory -> theory
   146   val restore_naming: theory -> theory -> theory
   147   val hide_class: bool -> string -> theory -> theory
   148   val hide_type: bool -> string -> theory -> theory
   149   val hide_const: bool -> string -> theory -> theory
   150 end
   151 
   152 structure Sign: SIGN =
   153 struct
   154 
   155 (** datatype sign **)
   156 
   157 datatype sign = Sign of
   158  {naming: NameSpace.naming,     (*common naming conventions*)
   159   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   160   tsig: Type.tsig,              (*order-sorted signature of types*)
   161   consts: Consts.T};            (*polymorphic constants*)
   162 
   163 fun make_sign (naming, syn, tsig, consts) =
   164   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   165 
   166 structure SignData = TheoryDataFun
   167 (
   168   type T = sign;
   169   val copy = I;
   170   fun extend (Sign {syn, tsig, consts, ...}) =
   171     make_sign (NameSpace.default_naming, syn, tsig, consts);
   172 
   173   val empty =
   174     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   175 
   176   fun merge pp (sign1, sign2) =
   177     let
   178       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   179       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   180 
   181       val naming = NameSpace.default_naming;
   182       val syn = Syntax.merge_syntaxes syn1 syn2;
   183       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   184       val consts = Consts.merge (consts1, consts2);
   185     in make_sign (naming, syn, tsig, consts) end;
   186 );
   187 
   188 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   189 
   190 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   191   make_sign (f (naming, syn, tsig, consts)));
   192 
   193 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   194 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   195 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   196 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   197 
   198 
   199 (* naming *)
   200 
   201 val naming_of = #naming o rep_sg;
   202 val base_name = NameSpace.base;
   203 val full_name = NameSpace.full o naming_of;
   204 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   205 val declare_name = NameSpace.declare o naming_of;
   206 
   207 
   208 (* syntax *)
   209 
   210 val syn_of = #syn o rep_sg;
   211 
   212 
   213 (* type signature *)
   214 
   215 val tsig_of = #tsig o rep_sg;
   216 
   217 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   218 val all_classes = Sorts.all_classes o classes_of;
   219 val super_classes = Sorts.super_classes o classes_of;
   220 val minimize_sort = Sorts.minimize_sort o classes_of;
   221 val complete_sort = Sorts.complete_sort o classes_of;
   222 
   223 val defaultS = Type.defaultS o tsig_of;
   224 val subsort = Type.subsort o tsig_of;
   225 val of_sort = Type.of_sort o tsig_of;
   226 val witness_sorts = Type.witness_sorts o tsig_of;
   227 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   228 
   229 val typ_instance = Type.typ_instance o tsig_of;
   230 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   231 val typ_match = Type.typ_match o tsig_of;
   232 val typ_unify = Type.unify o tsig_of;
   233 
   234 
   235 (* polymorphic constants *)
   236 
   237 val consts_of = #consts o rep_sg;
   238 val the_const_constraint = Consts.the_constraint o consts_of;
   239 val the_const_type = Consts.the_type o consts_of;
   240 val const_type = try o the_const_type;
   241 val const_monomorphic = Consts.is_monomorphic o consts_of;
   242 val const_syntax_name = Consts.syntax_name o consts_of;
   243 val const_typargs = Consts.typargs o consts_of;
   244 val const_instance = Consts.instance o consts_of;
   245 
   246 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   247 
   248 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   249 val declared_const = can o the_const_constraint;
   250 
   251 
   252 
   253 (** intern / extern names **)
   254 
   255 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   256 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   257 val const_space = Consts.space_of o consts_of;
   258 
   259 val intern_class = NameSpace.intern o class_space;
   260 val extern_class = NameSpace.extern o class_space;
   261 val intern_type = NameSpace.intern o type_space;
   262 val extern_type = NameSpace.extern o type_space;
   263 val intern_const = NameSpace.intern o const_space;
   264 val extern_const = NameSpace.extern o const_space;
   265 
   266 val intern_sort = map o intern_class;
   267 val extern_sort = map o extern_class;
   268 
   269 local
   270 
   271 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   272   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   273   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   274 
   275 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   276   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   277   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   278   | map_term _ _ _ (t as Bound _) = t
   279   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   280   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   281 
   282 val add_classesT = Term.fold_atyps
   283   (fn TFree (_, S) => fold (insert (op =)) S
   284     | TVar (_, S) => fold (insert (op =)) S
   285     | _ => I);
   286 
   287 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   288   | add_tyconsT _ = I;
   289 
   290 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   291 
   292 fun mapping add_names f t =
   293   let
   294     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   295     val tab = map_filter f' (add_names t []);
   296     fun get x = the_default x (AList.lookup (op =) tab x);
   297   in get end;
   298 
   299 fun typ_mapping f g thy T =
   300   T |> map_typ
   301     (mapping add_classesT (f thy) T)
   302     (mapping add_tyconsT (g thy) T);
   303 
   304 fun term_mapping f g h thy t =
   305   t |> map_term
   306     (mapping (Term.fold_types add_classesT) (f thy) t)
   307     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   308     (mapping add_consts (h thy) t);
   309 
   310 in
   311 
   312 val intern_typ = typ_mapping intern_class intern_type;
   313 val extern_typ = typ_mapping extern_class extern_type;
   314 val intern_term = term_mapping intern_class intern_type intern_const;
   315 fun extern_term h = term_mapping extern_class extern_type (K h);
   316 val intern_tycons = typ_mapping (K I) intern_type;
   317 
   318 end;
   319 
   320 
   321 
   322 (** certify entities **)    (*exception TYPE*)
   323 
   324 (* certify wrt. type signature *)
   325 
   326 val arity_number = Type.arity_number o tsig_of;
   327 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   328 
   329 val certify_class         = Type.cert_class o tsig_of;
   330 val certify_sort          = Type.cert_sort o tsig_of;
   331 val certify_typ           = Type.cert_typ o tsig_of;
   332 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   333 
   334 
   335 (* certify term/prop *)
   336 
   337 local
   338 
   339 fun type_check pp tm =
   340   let
   341     fun err_appl why bs t T u U =
   342       let
   343         val xs = map Free bs;           (*we do not rename here*)
   344         val t' = subst_bounds (xs, t);
   345         val u' = subst_bounds (xs, u);
   346         val msg = cat_lines
   347           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   348       in raise TYPE (msg, [T, U], [t', u']) end;
   349 
   350     fun typ_of (_, Const (_, T)) = T
   351       | typ_of (_, Free  (_, T)) = T
   352       | typ_of (_, Var (_, T)) = T
   353       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   354           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   355       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   356       | typ_of (bs, t $ u) =
   357           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   358             (case T of
   359               Type ("fun", [T1, T2]) =>
   360                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   361             | _ => err_appl "Operator not of function type" bs t T u U)
   362           end;
   363   in typ_of ([], tm) end;
   364 
   365 fun err msg = raise TYPE (msg, [], []);
   366 
   367 fun check_vars (t $ u) = (check_vars t; check_vars u)
   368   | check_vars (Abs (_, _, t)) = check_vars t
   369   | check_vars (Var (xi as (_, i), _)) =
   370       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   371   | check_vars _ = ();
   372 
   373 in
   374 
   375 fun certify' prop pp do_expand consts thy tm =
   376   let
   377     val _ = check_vars tm;
   378     val tm' = Term.map_types (certify_typ thy) tm;
   379     val T = type_check pp tm';
   380     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   381     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   382   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   383 
   384 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   385 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   386 
   387 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   388 val cert_term = #1 oo certify_term;
   389 val cert_prop = #1 oo certify_prop;
   390 
   391 end;
   392 
   393 
   394 (* specifications *)
   395 
   396 fun no_variables kind add addT mk mkT pp tm =
   397   (case (add tm [], addT tm []) of
   398     ([], []) => tm
   399   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   400       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   401        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   402 
   403 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   404 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   405 
   406 fun cert_def ctxt tm =
   407   let val ((lhs, rhs), _) = tm
   408     |> no_vars (Syntax.pp ctxt)
   409     |> Logic.strip_imp_concl
   410     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   411   in (Term.dest_Const (Term.head_of lhs), rhs) end
   412   handle TERM (msg, _) => error msg;
   413 
   414 
   415 
   416 (** read and certify entities **)    (*exception ERROR*)
   417 
   418 (* classes *)
   419 
   420 fun read_class thy c = certify_class thy (intern_class thy c)
   421   handle TYPE (msg, _, _) => error msg;
   422 
   423 
   424 (* type arities *)
   425 
   426 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   427   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   428   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   429 
   430 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   431 val cert_arity = prep_arity (K I) certify_sort;
   432 
   433 
   434 (* types *)
   435 
   436 fun get_sort thy def_sort raw_env =
   437   let
   438     val tsig = tsig_of thy;
   439 
   440     fun eq ((xi, S), (xi', S')) =
   441       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   442     val env = distinct eq raw_env;
   443     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   444       | dups => error ("Inconsistent sort constraints for type variable(s) "
   445           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   446 
   447     fun get xi =
   448       (case (AList.lookup (op =) env xi, def_sort xi) of
   449         (NONE, NONE) => Type.defaultS tsig
   450       | (NONE, SOME S) => S
   451       | (SOME S, NONE) => S
   452       | (SOME S, SOME S') =>
   453           if Type.eq_sort tsig (S, S') then S'
   454           else error ("Sort constraint inconsistent with default for type variable " ^
   455             quote (Term.string_of_vname' xi)));
   456   in get end;
   457 
   458 local
   459 
   460 fun gen_read_typ mode (thy, def_sort) str =
   461   let
   462     val ctxt = ProofContext.init thy;
   463     val syn = syn_of thy;
   464     val T = intern_tycons thy
   465       (Syntax.standard_parse_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   466   in certify_typ_mode mode thy T handle TYPE (msg, _, _) => error msg end
   467   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   468 
   469 in
   470 
   471 fun no_def_sort thy = (thy: theory, K NONE);
   472 
   473 val read_def_typ     = gen_read_typ Type.mode_default;
   474 val read_typ         = gen_read_typ Type.mode_default o no_def_sort;
   475 val read_typ_syntax  = gen_read_typ Type.mode_syntax o no_def_sort;
   476 val read_typ_abbrev  = gen_read_typ Type.mode_abbrev o no_def_sort;
   477 
   478 end;
   479 
   480 
   481 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   482 
   483 (*
   484   def_type: partial map from indexnames to types (constrains Frees and Vars)
   485   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   486   used: context of already used type variables
   487   freeze: if true then generated parameters are turned into TFrees, else TVars
   488 *)
   489 
   490 fun read_def_terms'
   491     pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze raw_args =
   492   let
   493     val thy = ProofContext.theory_of ctxt;
   494     fun check_typs Ts = map (certify_typ thy) Ts
   495       handle TYPE (msg, _, _) => error msg;
   496 
   497     fun infer args = TypeInfer.infer_types pp (tsig_of thy) check_typs
   498         (try (Consts.the_constraint consts)) def_type used ~1 (SOME freeze) args |>> map fst
   499       handle TYPE (msg, _, _) => error msg;
   500 
   501     fun check T t = (singleton (fst o infer) (t, T); NONE) handle ERROR msg => SOME msg;
   502     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   503     fun read T = Syntax.standard_parse_term pp (check T) (get_sort thy def_sort) map_const map_free
   504         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn T;
   505   in
   506     raw_args
   507     |> map (fn (s, raw_T) =>
   508       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   509       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end)
   510     |> infer
   511   end;
   512 
   513 fun read_def_terms (thy, types, sorts) used freeze sTs =
   514   let
   515     val pp = Syntax.pp_global thy;
   516     val consts = consts_of thy;
   517     val cert_consts = Consts.certify pp (tsig_of thy) true consts;
   518     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   519     val (ts, inst) =
   520       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   521         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   522   in (map cert_consts ts, inst) end;
   523 
   524 fun simple_read_term thy T s =
   525   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   526   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   527 
   528 fun read_term thy = simple_read_term thy dummyT;
   529 fun read_prop thy = simple_read_term thy propT;
   530 
   531 
   532 
   533 (** signature extension functions **)  (*exception ERROR/TYPE*)
   534 
   535 (* add default sort *)
   536 
   537 fun gen_add_defsort prep_sort s thy =
   538   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   539 
   540 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   541 val add_defsort_i = gen_add_defsort certify_sort;
   542 
   543 
   544 (* add type constructors *)
   545 
   546 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   547   let
   548     val syn' = Syntax.update_type_gram types syn;
   549     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   550     val tsig' = Type.add_types naming decls tsig;
   551   in (naming, syn', tsig', consts) end);
   552 
   553 
   554 (* add nonterminals *)
   555 
   556 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   557   let
   558     val syn' = Syntax.update_consts ns syn;
   559     val tsig' = Type.add_nonterminals naming ns tsig;
   560   in (naming, syn', tsig', consts) end);
   561 
   562 
   563 (* add type abbreviations *)
   564 
   565 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   566   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   567     let
   568       val ctxt = ProofContext.init thy;
   569       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   570       val a' = Syntax.type_name a mx;
   571       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   572         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   573       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   574     in (naming, syn', tsig', consts) end);
   575 
   576 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   577 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   578 
   579 
   580 (* modify syntax *)
   581 
   582 fun gen_syntax change_gram parse_typ mode args thy =
   583   let
   584     val ctxt = ProofContext.init thy;
   585     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   586       handle ERROR msg =>
   587         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   588   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   589 
   590 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   591 
   592 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   593 val add_modesyntax_i = gen_add_syntax (K I);
   594 val add_syntax = add_modesyntax Syntax.mode_default;
   595 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   596 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   597 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   598 
   599 fun notation add mode args thy =
   600   let
   601     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   602     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   603       | const_syntax _ = NONE;
   604   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   605 
   606 
   607 (* add constants *)
   608 
   609 local
   610 
   611 fun gen_add_consts parse_typ authentic tags raw_args thy =
   612   let
   613     val ctxt = ProofContext.init thy;
   614     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   615     fun prep (raw_c, raw_T, raw_mx) =
   616       let
   617         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   618         val full_c = full_name thy c;
   619         val c' = if authentic then Syntax.constN ^ full_c else c;
   620         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   621           cat_error msg ("in declaration of constant " ^ quote c);
   622         val T' = Logic.varifyT T;
   623       in ((c, T'), (c', T', mx), Const (full_c, T)) end;
   624     val args = map prep raw_args;
   625     val tags' = tags |> AList.update (op =) (Markup.theory_nameN, Context.theory_name thy);
   626   in
   627     thy
   628     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   629     |> add_syntax_i (map #2 args)
   630     |> pair (map #3 args)
   631   end;
   632 
   633 in
   634 
   635 val add_consts = snd oo gen_add_consts Syntax.parse_typ false [];
   636 val add_consts_i = snd oo gen_add_consts (K I) false [];
   637 
   638 fun declare_const tags arg = gen_add_consts (K I) true tags [arg] #>> the_single;
   639 
   640 end;
   641 
   642 
   643 (* abbreviations *)
   644 
   645 fun add_abbrev mode tags (c, raw_t) thy =
   646   let
   647     val pp = Syntax.pp_global thy;
   648     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   649     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   650       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   651     val (res, consts') = consts_of thy
   652       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (c, t);
   653   in (res, thy |> map_consts (K consts')) end;
   654 
   655 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   656 
   657 
   658 (* add constraints *)
   659 
   660 fun add_const_constraint (c, opt_T) thy =
   661   let
   662     fun prepT raw_T =
   663       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   664       in cert_term thy (Const (c, T)); T end
   665       handle TYPE (msg, _, _) => error msg;
   666   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   667 
   668 
   669 (* primitive classes and arities *)
   670 
   671 fun primitive_class (bclass, classes) thy =
   672   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   673     let
   674       val syn' = Syntax.update_consts [bclass] syn;
   675       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   676     in (naming, syn', tsig', consts) end)
   677   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   678 
   679 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   680 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   681 
   682 
   683 (* add translation functions *)
   684 
   685 local
   686 
   687 fun mk trs = map Syntax.mk_trfun trs;
   688 
   689 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   690   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   691 
   692 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   693 
   694 in
   695 
   696 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   697 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   698 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   699 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   700 
   701 end;
   702 
   703 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   704 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   705 
   706 
   707 (* translation rules *)
   708 
   709 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   710   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   711   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   712 
   713 val add_trrules = gen_trrules Syntax.update_trrules;
   714 val del_trrules = gen_trrules Syntax.remove_trrules;
   715 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   716 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   717 
   718 
   719 (* naming *)
   720 
   721 val add_path        = map_naming o NameSpace.add_path;
   722 val no_base_names   = map_naming NameSpace.no_base_names;
   723 val qualified_names = map_naming NameSpace.qualified_names;
   724 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   725 val restore_naming  = map_naming o K o naming_of;
   726 
   727 val parent_path   = add_path "..";
   728 val root_path     = add_path "/";
   729 val absolute_path = add_path "//";
   730 
   731 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   732 
   733 
   734 (* hide names *)
   735 
   736 val hide_class = map_tsig oo Type.hide_class;
   737 val hide_type = map_tsig oo Type.hide_type;
   738 val hide_const = map_consts oo Consts.hide;
   739 
   740 end;