src/HOL/Analysis/Finite_Product_Measure.thy
 author Angeliki KoutsoukouArgyraki Tue Aug 28 13:28:39 2018 +0100 (14 months ago) changeset 68833 fde093888c16 parent 67399 eab6ce8368fa child 69064 5840724b1d71 permissions -rw-r--r--
tagged 21 theories in the Analysis library for the manual
```     1 (*  Title:      HOL/Analysis/Finite_Product_Measure.thy
```
```     2     Author:     Johannes Hölzl, TU München
```
```     3 *)
```
```     4
```
```     5 section%important \<open>Finite product measures\<close>
```
```     6
```
```     7 theory Finite_Product_Measure
```
```     8 imports Binary_Product_Measure
```
```     9 begin
```
```    10
```
```    11 lemma%unimportant PiE_choice: "(\<exists>f\<in>Pi\<^sub>E I F. \<forall>i\<in>I. P i (f i)) \<longleftrightarrow> (\<forall>i\<in>I. \<exists>x\<in>F i. P i x)"
```
```    12   by (auto simp: Bex_def PiE_iff Ball_def dest!: choice_iff'[THEN iffD1])
```
```    13      (force intro: exI[of _ "restrict f I" for f])
```
```    14
```
```    15 lemma%unimportant case_prod_const: "(\<lambda>(i, j). c) = (\<lambda>_. c)"
```
```    16   by auto
```
```    17
```
```    18 subsubsection%unimportant \<open>More about Function restricted by @{const extensional}\<close>
```
```    19
```
```    20 definition
```
```    21   "merge I J = (\<lambda>(x, y) i. if i \<in> I then x i else if i \<in> J then y i else undefined)"
```
```    22
```
```    23 lemma merge_apply[simp]:
```
```    24   "I \<inter> J = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
```
```    25   "I \<inter> J = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
```
```    26   "J \<inter> I = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
```
```    27   "J \<inter> I = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
```
```    28   "i \<notin> I \<Longrightarrow> i \<notin> J \<Longrightarrow> merge I J (x, y) i = undefined"
```
```    29   unfolding merge_def by auto
```
```    30
```
```    31 lemma merge_commute:
```
```    32   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) = merge J I (y, x)"
```
```    33   by (force simp: merge_def)
```
```    34
```
```    35 lemma Pi_cancel_merge_range[simp]:
```
```    36   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
```
```    37   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
```
```    38   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
```
```    39   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
```
```    40   by (auto simp: Pi_def)
```
```    41
```
```    42 lemma Pi_cancel_merge[simp]:
```
```    43   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
```
```    44   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
```
```    45   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
```
```    46   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
```
```    47   by (auto simp: Pi_def)
```
```    48
```
```    49 lemma extensional_merge[simp]: "merge I J (x, y) \<in> extensional (I \<union> J)"
```
```    50   by (auto simp: extensional_def)
```
```    51
```
```    52 lemma restrict_merge[simp]:
```
```    53   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
```
```    54   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
```
```    55   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
```
```    56   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
```
```    57   by (auto simp: restrict_def)
```
```    58
```
```    59 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
```
```    60   unfolding merge_def by auto
```
```    61
```
```    62 lemma PiE_cancel_merge[simp]:
```
```    63   "I \<inter> J = {} \<Longrightarrow>
```
```    64     merge I J (x, y) \<in> Pi\<^sub>E (I \<union> J) B \<longleftrightarrow> x \<in> Pi I B \<and> y \<in> Pi J B"
```
```    65   by (auto simp: PiE_def restrict_Pi_cancel)
```
```    66
```
```    67 lemma merge_singleton[simp]: "i \<notin> I \<Longrightarrow> merge I {i} (x,y) = restrict (x(i := y i)) (insert i I)"
```
```    68   unfolding merge_def by (auto simp: fun_eq_iff)
```
```    69
```
```    70 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
```
```    71   unfolding merge_def extensional_def by auto
```
```    72
```
```    73 lemma merge_restrict[simp]:
```
```    74   "merge I J (restrict x I, y) = merge I J (x, y)"
```
```    75   "merge I J (x, restrict y J) = merge I J (x, y)"
```
```    76   unfolding merge_def by auto
```
```    77
```
```    78 lemma merge_x_x_eq_restrict[simp]:
```
```    79   "merge I J (x, x) = restrict x (I \<union> J)"
```
```    80   unfolding merge_def by auto
```
```    81
```
```    82 lemma injective_vimage_restrict:
```
```    83   assumes J: "J \<subseteq> I"
```
```    84   and sets: "A \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" and ne: "(\<Pi>\<^sub>E i\<in>I. S i) \<noteq> {}"
```
```    85   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
```
```    86   shows "A = B"
```
```    87 proof  (intro set_eqI)
```
```    88   fix x
```
```    89   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
```
```    90   have "J \<inter> (I - J) = {}" by auto
```
```    91   show "x \<in> A \<longleftrightarrow> x \<in> B"
```
```    92   proof cases
```
```    93     assume x: "x \<in> (\<Pi>\<^sub>E i\<in>J. S i)"
```
```    94     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
```
```    95       using y x \<open>J \<subseteq> I\<close> PiE_cancel_merge[of "J" "I - J" x y S]
```
```    96       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1)
```
```    97     then show "x \<in> A \<longleftrightarrow> x \<in> B"
```
```    98       using y x \<open>J \<subseteq> I\<close> PiE_cancel_merge[of "J" "I - J" x y S]
```
```    99       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1 eq)
```
```   100   qed (insert sets, auto)
```
```   101 qed
```
```   102
```
```   103 lemma restrict_vimage:
```
```   104   "I \<inter> J = {} \<Longrightarrow>
```
```   105     (\<lambda>x. (restrict x I, restrict x J)) -` (Pi\<^sub>E I E \<times> Pi\<^sub>E J F) = Pi (I \<union> J) (merge I J (E, F))"
```
```   106   by (auto simp: restrict_Pi_cancel PiE_def)
```
```   107
```
```   108 lemma merge_vimage:
```
```   109   "I \<inter> J = {} \<Longrightarrow> merge I J -` Pi\<^sub>E (I \<union> J) E = Pi I E \<times> Pi J E"
```
```   110   by (auto simp: restrict_Pi_cancel PiE_def)
```
```   111
```
```   112 subsection%important \<open>Finite product spaces\<close>
```
```   113
```
```   114 subsubsection%important \<open>Products\<close>
```
```   115
```
```   116 definition%important prod_emb where
```
```   117   "prod_emb I M K X = (\<lambda>x. restrict x K) -` X \<inter> (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   118
```
```   119 lemma%important prod_emb_iff:
```
```   120   "f \<in> prod_emb I M K X \<longleftrightarrow> f \<in> extensional I \<and> (restrict f K \<in> X) \<and> (\<forall>i\<in>I. f i \<in> space (M i))"
```
```   121   unfolding%unimportant prod_emb_def PiE_def by auto
```
```   122
```
```   123 lemma%unimportant (*FIX ME needs a name *)
```
```   124   shows prod_emb_empty[simp]: "prod_emb M L K {} = {}"
```
```   125     and prod_emb_Un[simp]: "prod_emb M L K (A \<union> B) = prod_emb M L K A \<union> prod_emb M L K B"
```
```   126     and prod_emb_Int: "prod_emb M L K (A \<inter> B) = prod_emb M L K A \<inter> prod_emb M L K B"
```
```   127     and prod_emb_UN[simp]: "prod_emb M L K (\<Union>i\<in>I. F i) = (\<Union>i\<in>I. prod_emb M L K (F i))"
```
```   128     and prod_emb_INT[simp]: "I \<noteq> {} \<Longrightarrow> prod_emb M L K (\<Inter>i\<in>I. F i) = (\<Inter>i\<in>I. prod_emb M L K (F i))"
```
```   129     and prod_emb_Diff[simp]: "prod_emb M L K (A - B) = prod_emb M L K A - prod_emb M L K B"
```
```   130   by%unimportant (auto simp: prod_emb_def)
```
```   131
```
```   132 lemma%unimportant prod_emb_PiE: "J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow>
```
```   133     prod_emb I M J (\<Pi>\<^sub>E i\<in>J. E i) = (\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i))"
```
```   134   by (force simp: prod_emb_def PiE_iff if_split_mem2)
```
```   135
```
```   136 lemma%unimportant prod_emb_PiE_same_index[simp]:
```
```   137     "(\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow> prod_emb I M I (Pi\<^sub>E I E) = Pi\<^sub>E I E"
```
```   138   by (auto simp: prod_emb_def PiE_iff)
```
```   139
```
```   140 lemma%unimportant prod_emb_trans[simp]:
```
```   141   "J \<subseteq> K \<Longrightarrow> K \<subseteq> L \<Longrightarrow> prod_emb L M K (prod_emb K M J X) = prod_emb L M J X"
```
```   142   by (auto simp add: Int_absorb1 prod_emb_def PiE_def)
```
```   143
```
```   144 lemma%unimportant prod_emb_Pi:
```
```   145   assumes "X \<in> (\<Pi> j\<in>J. sets (M j))" "J \<subseteq> K"
```
```   146   shows "prod_emb K M J (Pi\<^sub>E J X) = (\<Pi>\<^sub>E i\<in>K. if i \<in> J then X i else space (M i))"
```
```   147   using assms sets.space_closed
```
```   148   by (auto simp: prod_emb_def PiE_iff split: if_split_asm) blast+
```
```   149
```
```   150 lemma%unimportant prod_emb_id:
```
```   151   "B \<subseteq> (\<Pi>\<^sub>E i\<in>L. space (M i)) \<Longrightarrow> prod_emb L M L B = B"
```
```   152   by (auto simp: prod_emb_def subset_eq extensional_restrict)
```
```   153
```
```   154 lemma%unimportant prod_emb_mono:
```
```   155   "F \<subseteq> G \<Longrightarrow> prod_emb A M B F \<subseteq> prod_emb A M B G"
```
```   156   by (auto simp: prod_emb_def)
```
```   157
```
```   158 definition%important PiM :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
```
```   159   "PiM I M = extend_measure (\<Pi>\<^sub>E i\<in>I. space (M i))
```
```   160     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
```
```   161     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j))
```
```   162     (\<lambda>(J, X). \<Prod>j\<in>J \<union> {i\<in>I. emeasure (M i) (space (M i)) \<noteq> 1}. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
```
```   163
```
```   164 definition%important prod_algebra :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) set set" where
```
```   165   "prod_algebra I M = (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j)) `
```
```   166     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}"
```
```   167
```
```   168 abbreviation
```
```   169   "Pi\<^sub>M I M \<equiv> PiM I M"
```
```   170
```
```   171 syntax
```
```   172   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
```
```   173 translations
```
```   174   "\<Pi>\<^sub>M x\<in>I. M" == "CONST PiM I (%x. M)"
```
```   175
```
```   176 lemma%important extend_measure_cong:
```
```   177   assumes "\<Omega> = \<Omega>'" "I = I'" "G = G'" "\<And>i. i \<in> I' \<Longrightarrow> \<mu> i = \<mu>' i"
```
```   178   shows "extend_measure \<Omega> I G \<mu> = extend_measure \<Omega>' I' G' \<mu>'"
```
```   179   unfolding%unimportant extend_measure_def by (auto simp add: assms)
```
```   180
```
```   181 lemma%unimportant Pi_cong_sets:
```
```   182     "\<lbrakk>I = J; \<And>x. x \<in> I \<Longrightarrow> M x = N x\<rbrakk> \<Longrightarrow> Pi I M = Pi J N"
```
```   183   unfolding Pi_def by auto
```
```   184
```
```   185 lemma%important PiM_cong:
```
```   186   assumes "I = J" "\<And>x. x \<in> I \<Longrightarrow> M x = N x"
```
```   187   shows "PiM I M = PiM J N"
```
```   188   unfolding PiM_def
```
```   189 proof%unimportant (rule extend_measure_cong, goal_cases)
```
```   190   case 1
```
```   191   show ?case using assms
```
```   192     by (subst assms(1), intro PiE_cong[of J "\<lambda>i. space (M i)" "\<lambda>i. space (N i)"]) simp_all
```
```   193 next
```
```   194   case 2
```
```   195   have "\<And>K. K \<subseteq> J \<Longrightarrow> (\<Pi> j\<in>K. sets (M j)) = (\<Pi> j\<in>K. sets (N j))"
```
```   196     using assms by (intro Pi_cong_sets) auto
```
```   197   thus ?case by (auto simp: assms)
```
```   198 next
```
```   199   case 3
```
```   200   show ?case using assms
```
```   201     by (intro ext) (auto simp: prod_emb_def dest: PiE_mem)
```
```   202 next
```
```   203   case (4 x)
```
```   204   thus ?case using assms
```
```   205     by (auto intro!: prod.cong split: if_split_asm)
```
```   206 qed
```
```   207
```
```   208
```
```   209 lemma%unimportant prod_algebra_sets_into_space:
```
```   210   "prod_algebra I M \<subseteq> Pow (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   211   by (auto simp: prod_emb_def prod_algebra_def)
```
```   212
```
```   213 lemma%important prod_algebra_eq_finite:
```
```   214   assumes I: "finite I"
```
```   215   shows "prod_algebra I M = {(\<Pi>\<^sub>E i\<in>I. X i) |X. X \<in> (\<Pi> j\<in>I. sets (M j))}" (is "?L = ?R")
```
```   216 proof%unimportant (intro iffI set_eqI)
```
```   217   fix A assume "A \<in> ?L"
```
```   218   then obtain J E where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
```
```   219     and A: "A = prod_emb I M J (\<Pi>\<^sub>E j\<in>J. E j)"
```
```   220     by (auto simp: prod_algebra_def)
```
```   221   let ?A = "\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i)"
```
```   222   have A: "A = ?A"
```
```   223     unfolding A using J by (intro prod_emb_PiE sets.sets_into_space) auto
```
```   224   show "A \<in> ?R" unfolding A using J sets.top
```
```   225     by (intro CollectI exI[of _ "\<lambda>i. if i \<in> J then E i else space (M i)"]) simp
```
```   226 next
```
```   227   fix A assume "A \<in> ?R"
```
```   228   then obtain X where A: "A = (\<Pi>\<^sub>E i\<in>I. X i)" and X: "X \<in> (\<Pi> j\<in>I. sets (M j))" by auto
```
```   229   then have A: "A = prod_emb I M I (\<Pi>\<^sub>E i\<in>I. X i)"
```
```   230     by (simp add: prod_emb_PiE_same_index[OF sets.sets_into_space] Pi_iff)
```
```   231   from X I show "A \<in> ?L" unfolding A
```
```   232     by (auto simp: prod_algebra_def)
```
```   233 qed
```
```   234
```
```   235 lemma%unimportant prod_algebraI:
```
```   236   "finite J \<Longrightarrow> (J \<noteq> {} \<or> I = {}) \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i))
```
```   237     \<Longrightarrow> prod_emb I M J (\<Pi>\<^sub>E j\<in>J. E j) \<in> prod_algebra I M"
```
```   238   by (auto simp: prod_algebra_def)
```
```   239
```
```   240 lemma%unimportant prod_algebraI_finite:
```
```   241   "finite I \<Longrightarrow> (\<forall>i\<in>I. E i \<in> sets (M i)) \<Longrightarrow> (Pi\<^sub>E I E) \<in> prod_algebra I M"
```
```   242   using prod_algebraI[of I I E M] prod_emb_PiE_same_index[of I E M, OF sets.sets_into_space] by simp
```
```   243
```
```   244 lemma%unimportant Int_stable_PiE: "Int_stable {Pi\<^sub>E J E | E. \<forall>i\<in>I. E i \<in> sets (M i)}"
```
```   245 proof (safe intro!: Int_stableI)
```
```   246   fix E F assume "\<forall>i\<in>I. E i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
```
```   247   then show "\<exists>G. Pi\<^sub>E J E \<inter> Pi\<^sub>E J F = Pi\<^sub>E J G \<and> (\<forall>i\<in>I. G i \<in> sets (M i))"
```
```   248     by (auto intro!: exI[of _ "\<lambda>i. E i \<inter> F i"] simp: PiE_Int)
```
```   249 qed
```
```   250
```
```   251 lemma%unimportant prod_algebraE:
```
```   252   assumes A: "A \<in> prod_algebra I M"
```
```   253   obtains J E where "A = prod_emb I M J (\<Pi>\<^sub>E j\<in>J. E j)"
```
```   254     "finite J" "J \<noteq> {} \<or> I = {}" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i)"
```
```   255   using A by (auto simp: prod_algebra_def)
```
```   256
```
```   257 lemma%important prod_algebraE_all:
```
```   258   assumes A: "A \<in> prod_algebra I M"
```
```   259   obtains E where "A = Pi\<^sub>E I E" "E \<in> (\<Pi> i\<in>I. sets (M i))"
```
```   260 proof%unimportant -
```
```   261   from A obtain E J where A: "A = prod_emb I M J (Pi\<^sub>E J E)"
```
```   262     and J: "J \<subseteq> I" and E: "E \<in> (\<Pi> i\<in>J. sets (M i))"
```
```   263     by (auto simp: prod_algebra_def)
```
```   264   from E have "\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)"
```
```   265     using sets.sets_into_space by auto
```
```   266   then have "A = (\<Pi>\<^sub>E i\<in>I. if i\<in>J then E i else space (M i))"
```
```   267     using A J by (auto simp: prod_emb_PiE)
```
```   268   moreover have "(\<lambda>i. if i\<in>J then E i else space (M i)) \<in> (\<Pi> i\<in>I. sets (M i))"
```
```   269     using sets.top E by auto
```
```   270   ultimately show ?thesis using that by auto
```
```   271 qed
```
```   272
```
```   273 lemma%unimportant Int_stable_prod_algebra: "Int_stable (prod_algebra I M)"
```
```   274 proof (unfold Int_stable_def, safe)
```
```   275   fix A assume "A \<in> prod_algebra I M"
```
```   276   from prod_algebraE[OF this] guess J E . note A = this
```
```   277   fix B assume "B \<in> prod_algebra I M"
```
```   278   from prod_algebraE[OF this] guess K F . note B = this
```
```   279   have "A \<inter> B = prod_emb I M (J \<union> K) (\<Pi>\<^sub>E i\<in>J \<union> K. (if i \<in> J then E i else space (M i)) \<inter>
```
```   280       (if i \<in> K then F i else space (M i)))"
```
```   281     unfolding A B using A(2,3,4) A(5)[THEN sets.sets_into_space] B(2,3,4)
```
```   282       B(5)[THEN sets.sets_into_space]
```
```   283     apply (subst (1 2 3) prod_emb_PiE)
```
```   284     apply (simp_all add: subset_eq PiE_Int)
```
```   285     apply blast
```
```   286     apply (intro PiE_cong)
```
```   287     apply auto
```
```   288     done
```
```   289   also have "\<dots> \<in> prod_algebra I M"
```
```   290     using A B by (auto intro!: prod_algebraI)
```
```   291   finally show "A \<inter> B \<in> prod_algebra I M" .
```
```   292 qed
```
```   293
```
```   294 lemma%unimportant prod_algebra_mono:
```
```   295   assumes space: "\<And>i. i \<in> I \<Longrightarrow> space (E i) = space (F i)"
```
```   296   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (E i) \<subseteq> sets (F i)"
```
```   297   shows "prod_algebra I E \<subseteq> prod_algebra I F"
```
```   298 proof%unimportant
```
```   299   fix A assume "A \<in> prod_algebra I E"
```
```   300   then obtain J G where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I"
```
```   301     and A: "A = prod_emb I E J (\<Pi>\<^sub>E i\<in>J. G i)"
```
```   302     and G: "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (E i)"
```
```   303     by (auto simp: prod_algebra_def)
```
```   304   moreover
```
```   305   from space have "(\<Pi>\<^sub>E i\<in>I. space (E i)) = (\<Pi>\<^sub>E i\<in>I. space (F i))"
```
```   306     by (rule PiE_cong)
```
```   307   with A have "A = prod_emb I F J (\<Pi>\<^sub>E i\<in>J. G i)"
```
```   308     by (simp add: prod_emb_def)
```
```   309   moreover
```
```   310   from sets G J have "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (F i)"
```
```   311     by auto
```
```   312   ultimately show "A \<in> prod_algebra I F"
```
```   313     apply (simp add: prod_algebra_def image_iff)
```
```   314     apply (intro exI[of _ J] exI[of _ G] conjI)
```
```   315     apply auto
```
```   316     done
```
```   317 qed
```
```   318
```
```   319 lemma%unimportant prod_algebra_cong:
```
```   320   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
```
```   321   shows "prod_algebra I M = prod_algebra J N"
```
```   322 proof%unimportant -
```
```   323   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
```
```   324     using sets_eq_imp_space_eq[OF sets] by auto
```
```   325   with sets show ?thesis unfolding \<open>I = J\<close>
```
```   326     by (intro antisym prod_algebra_mono) auto
```
```   327 qed
```
```   328
```
```   329 lemma%unimportant space_in_prod_algebra:
```
```   330   "(\<Pi>\<^sub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
```
```   331 proof cases
```
```   332   assume "I = {}" then show ?thesis
```
```   333     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
```
```   334 next
```
```   335   assume "I \<noteq> {}"
```
```   336   then obtain i where "i \<in> I" by auto
```
```   337   then have "(\<Pi>\<^sub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i))"
```
```   338     by (auto simp: prod_emb_def)
```
```   339   also have "\<dots> \<in> prod_algebra I M"
```
```   340     using \<open>i \<in> I\<close> by (intro prod_algebraI) auto
```
```   341   finally show ?thesis .
```
```   342 qed
```
```   343
```
```   344 lemma%unimportant space_PiM: "space (\<Pi>\<^sub>M i\<in>I. M i) = (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   345   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro space_extend_measure) simp
```
```   346
```
```   347 lemma%unimportant prod_emb_subset_PiM[simp]: "prod_emb I M K X \<subseteq> space (PiM I M)"
```
```   348   by (auto simp: prod_emb_def space_PiM)
```
```   349
```
```   350 lemma%unimportant space_PiM_empty_iff[simp]: "space (PiM I M) = {} \<longleftrightarrow>  (\<exists>i\<in>I. space (M i) = {})"
```
```   351   by (auto simp: space_PiM PiE_eq_empty_iff)
```
```   352
```
```   353 lemma%unimportant undefined_in_PiM_empty[simp]: "(\<lambda>x. undefined) \<in> space (PiM {} M)"
```
```   354   by (auto simp: space_PiM)
```
```   355
```
```   356 lemma%unimportant sets_PiM: "sets (\<Pi>\<^sub>M i\<in>I. M i) = sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) (prod_algebra I M)"
```
```   357   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro sets_extend_measure) simp
```
```   358
```
```   359 lemma%important sets_PiM_single: "sets (PiM I M) =
```
```   360     sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) {{f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> sets (M i)}"
```
```   361     (is "_ = sigma_sets ?\<Omega> ?R")
```
```   362   unfolding sets_PiM
```
```   363 proof%unimportant (rule sigma_sets_eqI)
```
```   364   interpret R: sigma_algebra ?\<Omega> "sigma_sets ?\<Omega> ?R" by (rule sigma_algebra_sigma_sets) auto
```
```   365   fix A assume "A \<in> prod_algebra I M"
```
```   366   from prod_algebraE[OF this] guess J X . note X = this
```
```   367   show "A \<in> sigma_sets ?\<Omega> ?R"
```
```   368   proof cases
```
```   369     assume "I = {}"
```
```   370     with X have "A = {\<lambda>x. undefined}" by (auto simp: prod_emb_def)
```
```   371     with \<open>I = {}\<close> show ?thesis by (auto intro!: sigma_sets_top)
```
```   372   next
```
```   373     assume "I \<noteq> {}"
```
```   374     with X have "A = (\<Inter>j\<in>J. {f\<in>(\<Pi>\<^sub>E i\<in>I. space (M i)). f j \<in> X j})"
```
```   375       by (auto simp: prod_emb_def)
```
```   376     also have "\<dots> \<in> sigma_sets ?\<Omega> ?R"
```
```   377       using X \<open>I \<noteq> {}\<close> by (intro R.finite_INT sigma_sets.Basic) auto
```
```   378     finally show "A \<in> sigma_sets ?\<Omega> ?R" .
```
```   379   qed
```
```   380 next
```
```   381   fix A assume "A \<in> ?R"
```
```   382   then obtain i B where A: "A = {f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" "i \<in> I" "B \<in> sets (M i)"
```
```   383     by auto
```
```   384   then have "A = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. B)"
```
```   385      by (auto simp: prod_emb_def)
```
```   386   also have "\<dots> \<in> sigma_sets ?\<Omega> (prod_algebra I M)"
```
```   387     using A by (intro sigma_sets.Basic prod_algebraI) auto
```
```   388   finally show "A \<in> sigma_sets ?\<Omega> (prod_algebra I M)" .
```
```   389 qed
```
```   390
```
```   391 lemma%unimportant sets_PiM_eq_proj:
```
```   392   "I \<noteq> {} \<Longrightarrow> sets (PiM I M) = sets (SUP i:I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. space (M i)) (\<lambda>x. x i) (M i))"
```
```   393   apply (simp add: sets_PiM_single)
```
```   394   apply (subst sets_Sup_eq[where X="\<Pi>\<^sub>E i\<in>I. space (M i)"])
```
```   395   apply auto []
```
```   396   apply auto []
```
```   397   apply simp
```
```   398   apply (subst SUP_cong[OF refl])
```
```   399   apply (rule sets_vimage_algebra2)
```
```   400   apply auto []
```
```   401   apply (auto intro!: arg_cong2[where f=sigma_sets])
```
```   402   done
```
```   403
```
```   404 lemma%unimportant (*FIX ME needs name *)
```
```   405   shows space_PiM_empty: "space (Pi\<^sub>M {} M) = {\<lambda>k. undefined}"
```
```   406     and sets_PiM_empty: "sets (Pi\<^sub>M {} M) = { {}, {\<lambda>k. undefined} }"
```
```   407   by (simp_all add: space_PiM sets_PiM_single image_constant sigma_sets_empty_eq)
```
```   408
```
```   409 lemma%important sets_PiM_sigma:
```
```   410   assumes \<Omega>_cover: "\<And>i. i \<in> I \<Longrightarrow> \<exists>S\<subseteq>E i. countable S \<and> \<Omega> i = \<Union>S"
```
```   411   assumes E: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (\<Omega> i)"
```
```   412   assumes J: "\<And>j. j \<in> J \<Longrightarrow> finite j" "\<Union>J = I"
```
```   413   defines "P \<equiv> {{f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i} | A j. j \<in> J \<and> A \<in> Pi j E}"
```
```   414   shows "sets (\<Pi>\<^sub>M i\<in>I. sigma (\<Omega> i) (E i)) = sets (sigma (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P)"
```
```   415 proof%unimportant cases
```
```   416   assume "I = {}"
```
```   417   with \<open>\<Union>J = I\<close> have "P = {{\<lambda>_. undefined}} \<or> P = {}"
```
```   418     by (auto simp: P_def)
```
```   419   with \<open>I = {}\<close> show ?thesis
```
```   420     by (auto simp add: sets_PiM_empty sigma_sets_empty_eq)
```
```   421 next
```
```   422   let ?F = "\<lambda>i. {(\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega> |A. A \<in> E i}"
```
```   423   assume "I \<noteq> {}"
```
```   424   then have "sets (Pi\<^sub>M I (\<lambda>i. sigma (\<Omega> i) (E i))) =
```
```   425       sets (SUP i:I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<lambda>x. x i) (sigma (\<Omega> i) (E i)))"
```
```   426     by (subst sets_PiM_eq_proj) (auto simp: space_measure_of_conv)
```
```   427   also have "\<dots> = sets (SUP i:I. sigma (Pi\<^sub>E I \<Omega>) (?F i))"
```
```   428     using E by (intro sets_SUP_cong arg_cong[where f=sets] vimage_algebra_sigma) auto
```
```   429   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i))"
```
```   430     using \<open>I \<noteq> {}\<close> by (intro arg_cong[where f=sets] SUP_sigma_sigma) auto
```
```   431   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) P)"
```
```   432   proof (intro arg_cong[where f=sets] sigma_eqI sigma_sets_eqI)
```
```   433     show "(\<Union>i\<in>I. ?F i) \<subseteq> Pow (Pi\<^sub>E I \<Omega>)" "P \<subseteq> Pow (Pi\<^sub>E I \<Omega>)"
```
```   434       by (auto simp: P_def)
```
```   435   next
```
```   436     interpret P: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
```
```   437       by (auto intro!: sigma_algebra_sigma_sets simp: P_def)
```
```   438
```
```   439     fix Z assume "Z \<in> (\<Union>i\<in>I. ?F i)"
```
```   440     then obtain i A where i: "i \<in> I" "A \<in> E i" and Z_def: "Z = (\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega>"
```
```   441       by auto
```
```   442     from \<open>i \<in> I\<close> J obtain j where j: "i \<in> j" "j \<in> J" "j \<subseteq> I" "finite j"
```
```   443       by auto
```
```   444     obtain S where S: "\<And>i. i \<in> j \<Longrightarrow> S i \<subseteq> E i" "\<And>i. i \<in> j \<Longrightarrow> countable (S i)"
```
```   445       "\<And>i. i \<in> j \<Longrightarrow> \<Omega> i = \<Union>(S i)"
```
```   446       by (metis subset_eq \<Omega>_cover \<open>j \<subseteq> I\<close>)
```
```   447     define A' where "A' n = n(i := A)" for n
```
```   448     then have A'_i: "\<And>n. A' n i = A"
```
```   449       by simp
```
```   450     { fix n assume "n \<in> Pi\<^sub>E (j - {i}) S"
```
```   451       then have "A' n \<in> Pi j E"
```
```   452         unfolding PiE_def Pi_def using S(1) by (auto simp: A'_def \<open>A \<in> E i\<close> )
```
```   453       with \<open>j \<in> J\<close> have "{f \<in> Pi\<^sub>E I \<Omega>. \<forall>i\<in>j. f i \<in> A' n i} \<in> P"
```
```   454         by (auto simp: P_def) }
```
```   455     note A'_in_P = this
```
```   456
```
```   457     { fix x assume "x i \<in> A" "x \<in> Pi\<^sub>E I \<Omega>"
```
```   458       with S(3) \<open>j \<subseteq> I\<close> have "\<forall>i\<in>j. \<exists>s\<in>S i. x i \<in> s"
```
```   459         by (auto simp: PiE_def Pi_def)
```
```   460       then obtain s where s: "\<And>i. i \<in> j \<Longrightarrow> s i \<in> S i" "\<And>i. i \<in> j \<Longrightarrow> x i \<in> s i"
```
```   461         by metis
```
```   462       with \<open>x i \<in> A\<close> have "\<exists>n\<in>Pi\<^sub>E (j-{i}) S. \<forall>i\<in>j. x i \<in> A' n i"
```
```   463         by (intro bexI[of _ "restrict (s(i := A)) (j-{i})"]) (auto simp: A'_def split: if_splits) }
```
```   464     then have "Z = (\<Union>n\<in>Pi\<^sub>E (j-{i}) S. {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A' n i})"
```
```   465       unfolding Z_def
```
```   466       by (auto simp add: set_eq_iff ball_conj_distrib \<open>i\<in>j\<close> A'_i dest: bspec[OF _ \<open>i\<in>j\<close>]
```
```   467                cong: conj_cong)
```
```   468     also have "\<dots> \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
```
```   469       using \<open>finite j\<close> S(2)
```
```   470       by (intro P.countable_UN' countable_PiE) (simp_all add: image_subset_iff A'_in_P)
```
```   471     finally show "Z \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P" .
```
```   472   next
```
```   473     interpret F: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<Union>i\<in>I. ?F i)"
```
```   474       by (auto intro!: sigma_algebra_sigma_sets)
```
```   475
```
```   476     fix b assume "b \<in> P"
```
```   477     then obtain A j where b: "b = {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i}" "j \<in> J" "A \<in> Pi j E"
```
```   478       by (auto simp: P_def)
```
```   479     show "b \<in> sigma_sets (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i)"
```
```   480     proof cases
```
```   481       assume "j = {}"
```
```   482       with b have "b = (\<Pi>\<^sub>E i\<in>I. \<Omega> i)"
```
```   483         by auto
```
```   484       then show ?thesis
```
```   485         by blast
```
```   486     next
```
```   487       assume "j \<noteq> {}"
```
```   488       with J b(2,3) have eq: "b = (\<Inter>i\<in>j. ((\<lambda>x. x i) -` A i \<inter> Pi\<^sub>E I \<Omega>))"
```
```   489         unfolding b(1)
```
```   490         by (auto simp: PiE_def Pi_def)
```
```   491       show ?thesis
```
```   492         unfolding eq using \<open>A \<in> Pi j E\<close> \<open>j \<in> J\<close> J(2)
```
```   493         by (intro F.finite_INT J \<open>j \<in> J\<close> \<open>j \<noteq> {}\<close> sigma_sets.Basic) blast
```
```   494     qed
```
```   495   qed
```
```   496   finally show "?thesis" .
```
```   497 qed
```
```   498
```
```   499 lemma%unimportant sets_PiM_in_sets:
```
```   500   assumes space: "space N = (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   501   assumes sets: "\<And>i A. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {x\<in>space N. x i \<in> A} \<in> sets N"
```
```   502   shows "sets (\<Pi>\<^sub>M i \<in> I. M i) \<subseteq> sets N"
```
```   503   unfolding sets_PiM_single space[symmetric]
```
```   504   by (intro sets.sigma_sets_subset subsetI) (auto intro: sets)
```
```   505
```
```   506 lemma%unimportant sets_PiM_cong[measurable_cong]:
```
```   507   assumes "I = J" "\<And>i. i \<in> J \<Longrightarrow> sets (M i) = sets (N i)" shows "sets (PiM I M) = sets (PiM J N)"
```
```   508   using assms sets_eq_imp_space_eq[OF assms(2)] by (simp add: sets_PiM_single cong: PiE_cong conj_cong)
```
```   509
```
```   510 lemma%important sets_PiM_I:
```
```   511   assumes "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
```
```   512   shows "prod_emb I M J (\<Pi>\<^sub>E j\<in>J. E j) \<in> sets (\<Pi>\<^sub>M i\<in>I. M i)"
```
```   513 proof%unimportant cases
```
```   514   assume "J = {}"
```
```   515   then have "prod_emb I M J (\<Pi>\<^sub>E j\<in>J. E j) = (\<Pi>\<^sub>E j\<in>I. space (M j))"
```
```   516     by (auto simp: prod_emb_def)
```
```   517   then show ?thesis
```
```   518     by (auto simp add: sets_PiM intro!: sigma_sets_top)
```
```   519 next
```
```   520   assume "J \<noteq> {}" with assms show ?thesis
```
```   521     by (force simp add: sets_PiM prod_algebra_def)
```
```   522 qed
```
```   523
```
```   524 lemma%unimportant measurable_PiM:
```
```   525   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   526   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
```
```   527     f -` prod_emb I M J (Pi\<^sub>E J X) \<inter> space N \<in> sets N"
```
```   528   shows "f \<in> measurable N (PiM I M)"
```
```   529   using sets_PiM prod_algebra_sets_into_space space
```
```   530 proof (rule measurable_sigma_sets)
```
```   531   fix A assume "A \<in> prod_algebra I M"
```
```   532   from prod_algebraE[OF this] guess J X .
```
```   533   with sets[of J X] show "f -` A \<inter> space N \<in> sets N" by auto
```
```   534 qed
```
```   535
```
```   536 lemma%important measurable_PiM_Collect:
```
```   537   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   538   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
```
```   539     {\<omega>\<in>space N. \<forall>i\<in>J. f \<omega> i \<in> X i} \<in> sets N"
```
```   540   shows "f \<in> measurable N (PiM I M)"
```
```   541   using sets_PiM prod_algebra_sets_into_space space
```
```   542 proof%unimportant (rule measurable_sigma_sets)
```
```   543   fix A assume "A \<in> prod_algebra I M"
```
```   544   from prod_algebraE[OF this] guess J X . note X = this
```
```   545   then have "f -` A \<inter> space N = {\<omega> \<in> space N. \<forall>i\<in>J. f \<omega> i \<in> X i}"
```
```   546     using space by (auto simp: prod_emb_def del: PiE_I)
```
```   547   also have "\<dots> \<in> sets N" using X(3,2,4,5) by (rule sets)
```
```   548   finally show "f -` A \<inter> space N \<in> sets N" .
```
```   549 qed
```
```   550
```
```   551 lemma%unimportant measurable_PiM_single:
```
```   552   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   553   assumes sets: "\<And>A i. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {\<omega> \<in> space N. f \<omega> i \<in> A} \<in> sets N"
```
```   554   shows "f \<in> measurable N (PiM I M)"
```
```   555   using sets_PiM_single
```
```   556 proof (rule measurable_sigma_sets)
```
```   557   fix A assume "A \<in> {{f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
```
```   558   then obtain B i where "A = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" and B: "i \<in> I" "B \<in> sets (M i)"
```
```   559     by auto
```
```   560   with space have "f -` A \<inter> space N = {\<omega> \<in> space N. f \<omega> i \<in> B}" by auto
```
```   561   also have "\<dots> \<in> sets N" using B by (rule sets)
```
```   562   finally show "f -` A \<inter> space N \<in> sets N" .
```
```   563 qed (auto simp: space)
```
```   564
```
```   565 lemma%important measurable_PiM_single':
```
```   566   assumes f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> measurable N (M i)"
```
```   567     and "(\<lambda>\<omega> i. f i \<omega>) \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   568   shows "(\<lambda>\<omega> i. f i \<omega>) \<in> measurable N (Pi\<^sub>M I M)"
```
```   569 proof%unimportant (rule measurable_PiM_single)
```
```   570   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
```
```   571   then have "{\<omega> \<in> space N. f i \<omega> \<in> A} = f i -` A \<inter> space N"
```
```   572     by auto
```
```   573   then show "{\<omega> \<in> space N. f i \<omega> \<in> A} \<in> sets N"
```
```   574     using A f by (auto intro!: measurable_sets)
```
```   575 qed fact
```
```   576
```
```   577 lemma%unimportant sets_PiM_I_finite[measurable]:
```
```   578   assumes "finite I" and sets: "(\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i))"
```
```   579   shows "(\<Pi>\<^sub>E j\<in>I. E j) \<in> sets (\<Pi>\<^sub>M i\<in>I. M i)"
```
```   580   using sets_PiM_I[of I I E M] sets.sets_into_space[OF sets] \<open>finite I\<close> sets by auto
```
```   581
```
```   582 lemma%unimportant measurable_component_singleton[measurable (raw)]:
```
```   583   assumes "i \<in> I" shows "(\<lambda>x. x i) \<in> measurable (Pi\<^sub>M I M) (M i)"
```
```   584 proof (unfold measurable_def, intro CollectI conjI ballI)
```
```   585   fix A assume "A \<in> sets (M i)"
```
```   586   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) = prod_emb I M {i} (\<Pi>\<^sub>E j\<in>{i}. A)"
```
```   587     using sets.sets_into_space \<open>i \<in> I\<close>
```
```   588     by (fastforce dest: Pi_mem simp: prod_emb_def space_PiM split: if_split_asm)
```
```   589   then show "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) \<in> sets (Pi\<^sub>M I M)"
```
```   590     using \<open>A \<in> sets (M i)\<close> \<open>i \<in> I\<close> by (auto intro!: sets_PiM_I)
```
```   591 qed (insert \<open>i \<in> I\<close>, auto simp: space_PiM)
```
```   592
```
```   593 lemma%unimportant measurable_component_singleton'[measurable_dest]:
```
```   594   assumes f: "f \<in> measurable N (Pi\<^sub>M I M)"
```
```   595   assumes g: "g \<in> measurable L N"
```
```   596   assumes i: "i \<in> I"
```
```   597   shows "(\<lambda>x. (f (g x)) i) \<in> measurable L (M i)"
```
```   598   using measurable_compose[OF measurable_compose[OF g f] measurable_component_singleton, OF i] .
```
```   599
```
```   600 lemma%unimportant measurable_PiM_component_rev:
```
```   601   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<lambda>x. f (x i)) \<in> measurable (PiM I M) N"
```
```   602   by simp
```
```   603
```
```   604 lemma%unimportant measurable_case_nat[measurable (raw)]:
```
```   605   assumes [measurable (raw)]: "i = 0 \<Longrightarrow> f \<in> measurable M N"
```
```   606     "\<And>j. i = Suc j \<Longrightarrow> (\<lambda>x. g x j) \<in> measurable M N"
```
```   607   shows "(\<lambda>x. case_nat (f x) (g x) i) \<in> measurable M N"
```
```   608   by (cases i) simp_all
```
```   609
```
```   610 lemma%unimportant measurable_case_nat'[measurable (raw)]:
```
```   611   assumes fg[measurable]: "f \<in> measurable N M" "g \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
```
```   612   shows "(\<lambda>x. case_nat (f x) (g x)) \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
```
```   613   using fg[THEN measurable_space]
```
```   614   by (auto intro!: measurable_PiM_single' simp add: space_PiM PiE_iff split: nat.split)
```
```   615
```
```   616 lemma%unimportant measurable_add_dim[measurable]:
```
```   617   "(\<lambda>(f, y). f(i := y)) \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M)"
```
```   618     (is "?f \<in> measurable ?P ?I")
```
```   619 proof (rule measurable_PiM_single)
```
```   620   fix j A assume j: "j \<in> insert i I" and A: "A \<in> sets (M j)"
```
```   621   have "{\<omega> \<in> space ?P. (\<lambda>(f, x). fun_upd f i x) \<omega> j \<in> A} =
```
```   622     (if j = i then space (Pi\<^sub>M I M) \<times> A else ((\<lambda>x. x j) \<circ> fst) -` A \<inter> space ?P)"
```
```   623     using sets.sets_into_space[OF A] by (auto simp add: space_pair_measure space_PiM)
```
```   624   also have "\<dots> \<in> sets ?P"
```
```   625     using A j
```
```   626     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
```
```   627   finally show "{\<omega> \<in> space ?P. case_prod (\<lambda>f. fun_upd f i) \<omega> j \<in> A} \<in> sets ?P" .
```
```   628 qed (auto simp: space_pair_measure space_PiM PiE_def)
```
```   629
```
```   630 lemma%important measurable_fun_upd:
```
```   631   assumes I: "I = J \<union> {i}"
```
```   632   assumes f[measurable]: "f \<in> measurable N (PiM J M)"
```
```   633   assumes h[measurable]: "h \<in> measurable N (M i)"
```
```   634   shows "(\<lambda>x. (f x) (i := h x)) \<in> measurable N (PiM I M)"
```
```   635 proof%unimportant (intro measurable_PiM_single')
```
```   636   fix j assume "j \<in> I" then show "(\<lambda>\<omega>. ((f \<omega>)(i := h \<omega>)) j) \<in> measurable N (M j)"
```
```   637     unfolding I by (cases "j = i") auto
```
```   638 next
```
```   639   show "(\<lambda>x. (f x)(i := h x)) \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
```
```   640     using I f[THEN measurable_space] h[THEN measurable_space]
```
```   641     by (auto simp: space_PiM PiE_iff extensional_def)
```
```   642 qed
```
```   643
```
```   644 lemma%unimportant measurable_component_update:
```
```   645   "x \<in> space (Pi\<^sub>M I M) \<Longrightarrow> i \<notin> I \<Longrightarrow> (\<lambda>v. x(i := v)) \<in> measurable (M i) (Pi\<^sub>M (insert i I) M)"
```
```   646   by simp
```
```   647
```
```   648 lemma%important measurable_merge[measurable]:
```
```   649   "merge I J \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M)"
```
```   650     (is "?f \<in> measurable ?P ?U")
```
```   651 proof%unimportant (rule measurable_PiM_single)
```
```   652   fix i A assume A: "A \<in> sets (M i)" "i \<in> I \<union> J"
```
```   653   then have "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} =
```
```   654     (if i \<in> I then ((\<lambda>x. x i) \<circ> fst) -` A \<inter> space ?P else ((\<lambda>x. x i) \<circ> snd) -` A \<inter> space ?P)"
```
```   655     by (auto simp: merge_def)
```
```   656   also have "\<dots> \<in> sets ?P"
```
```   657     using A
```
```   658     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
```
```   659   finally show "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} \<in> sets ?P" .
```
```   660 qed (auto simp: space_pair_measure space_PiM PiE_iff merge_def extensional_def)
```
```   661
```
```   662 lemma%unimportant measurable_restrict[measurable (raw)]:
```
```   663   assumes X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> measurable N (M i)"
```
```   664   shows "(\<lambda>x. \<lambda>i\<in>I. X i x) \<in> measurable N (Pi\<^sub>M I M)"
```
```   665 proof (rule measurable_PiM_single)
```
```   666   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
```
```   667   then have "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} = X i -` A \<inter> space N"
```
```   668     by auto
```
```   669   then show "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} \<in> sets N"
```
```   670     using A X by (auto intro!: measurable_sets)
```
```   671 qed (insert X, auto simp add: PiE_def dest: measurable_space)
```
```   672
```
```   673 lemma%unimportant measurable_abs_UNIV:
```
```   674   "(\<And>n. (\<lambda>\<omega>. f n \<omega>) \<in> measurable M (N n)) \<Longrightarrow> (\<lambda>\<omega> n. f n \<omega>) \<in> measurable M (PiM UNIV N)"
```
```   675   by (intro measurable_PiM_single) (auto dest: measurable_space)
```
```   676
```
```   677 lemma%unimportant measurable_restrict_subset: "J \<subseteq> L \<Longrightarrow> (\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
```
```   678   by (intro measurable_restrict measurable_component_singleton) auto
```
```   679
```
```   680 lemma%unimportant measurable_restrict_subset':
```
```   681   assumes "J \<subseteq> L" "\<And>x. x \<in> J \<Longrightarrow> sets (M x) = sets (N x)"
```
```   682   shows "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
```
```   683 proof-
```
```   684   from assms(1) have "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
```
```   685     by (rule measurable_restrict_subset)
```
```   686   also from assms(2) have "measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M) = measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
```
```   687     by (intro sets_PiM_cong measurable_cong_sets) simp_all
```
```   688   finally show ?thesis .
```
```   689 qed
```
```   690
```
```   691 lemma%unimportant measurable_prod_emb[intro, simp]:
```
```   692   "J \<subseteq> L \<Longrightarrow> X \<in> sets (Pi\<^sub>M J M) \<Longrightarrow> prod_emb L M J X \<in> sets (Pi\<^sub>M L M)"
```
```   693   unfolding prod_emb_def space_PiM[symmetric]
```
```   694   by (auto intro!: measurable_sets measurable_restrict measurable_component_singleton)
```
```   695
```
```   696 lemma%unimportant merge_in_prod_emb:
```
```   697   assumes "y \<in> space (PiM I M)" "x \<in> X" and X: "X \<in> sets (Pi\<^sub>M J M)" and "J \<subseteq> I"
```
```   698   shows "merge J I (x, y) \<in> prod_emb I M J X"
```
```   699   using assms sets.sets_into_space[OF X]
```
```   700   by (simp add: merge_def prod_emb_def subset_eq space_PiM PiE_def extensional_restrict Pi_iff
```
```   701            cong: if_cong restrict_cong)
```
```   702      (simp add: extensional_def)
```
```   703
```
```   704 lemma%unimportant prod_emb_eq_emptyD:
```
```   705   assumes J: "J \<subseteq> I" and ne: "space (PiM I M) \<noteq> {}" and X: "X \<in> sets (Pi\<^sub>M J M)"
```
```   706     and *: "prod_emb I M J X = {}"
```
```   707   shows "X = {}"
```
```   708 proof safe
```
```   709   fix x assume "x \<in> X"
```
```   710   obtain \<omega> where "\<omega> \<in> space (PiM I M)"
```
```   711     using ne by blast
```
```   712   from merge_in_prod_emb[OF this \<open>x\<in>X\<close> X J] * show "x \<in> {}" by auto
```
```   713 qed
```
```   714
```
```   715 lemma%unimportant sets_in_Pi_aux:
```
```   716   "finite I \<Longrightarrow> (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
```
```   717   {x\<in>space (PiM I M). x \<in> Pi I F} \<in> sets (PiM I M)"
```
```   718   by (simp add: subset_eq Pi_iff)
```
```   719
```
```   720 lemma%unimportant sets_in_Pi[measurable (raw)]:
```
```   721   "finite I \<Longrightarrow> f \<in> measurable N (PiM I M) \<Longrightarrow>
```
```   722   (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
```
```   723   Measurable.pred N (\<lambda>x. f x \<in> Pi I F)"
```
```   724   unfolding pred_def
```
```   725   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_Pi_aux]) auto
```
```   726
```
```   727 lemma%unimportant sets_in_extensional_aux:
```
```   728   "{x\<in>space (PiM I M). x \<in> extensional I} \<in> sets (PiM I M)"
```
```   729 proof -
```
```   730   have "{x\<in>space (PiM I M). x \<in> extensional I} = space (PiM I M)"
```
```   731     by (auto simp add: extensional_def space_PiM)
```
```   732   then show ?thesis by simp
```
```   733 qed
```
```   734
```
```   735 lemma%unimportant sets_in_extensional[measurable (raw)]:
```
```   736   "f \<in> measurable N (PiM I M) \<Longrightarrow> Measurable.pred N (\<lambda>x. f x \<in> extensional I)"
```
```   737   unfolding pred_def
```
```   738   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_extensional_aux]) auto
```
```   739
```
```   740 lemma%unimportant sets_PiM_I_countable:
```
```   741   assumes I: "countable I" and E: "\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i)" shows "Pi\<^sub>E I E \<in> sets (Pi\<^sub>M I M)"
```
```   742 proof cases
```
```   743   assume "I \<noteq> {}"
```
```   744   then have "Pi\<^sub>E I E = (\<Inter>i\<in>I. prod_emb I M {i} (Pi\<^sub>E {i} E))"
```
```   745     using E[THEN sets.sets_into_space] by (auto simp: PiE_iff prod_emb_def fun_eq_iff)
```
```   746   also have "\<dots> \<in> sets (PiM I M)"
```
```   747     using I \<open>I \<noteq> {}\<close> by (safe intro!: sets.countable_INT' measurable_prod_emb sets_PiM_I_finite E)
```
```   748   finally show ?thesis .
```
```   749 qed (simp add: sets_PiM_empty)
```
```   750
```
```   751 lemma%important sets_PiM_D_countable:
```
```   752   assumes A: "A \<in> PiM I M"
```
```   753   shows "\<exists>J\<subseteq>I. \<exists>X\<in>PiM J M. countable J \<and> A = prod_emb I M J X"
```
```   754   using A[unfolded sets_PiM_single]
```
```   755 proof%unimportant induction
```
```   756   case (Basic A)
```
```   757   then obtain i X where *: "i \<in> I" "X \<in> sets (M i)" and "A = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> X}"
```
```   758     by auto
```
```   759   then have A: "A = prod_emb I M {i} (\<Pi>\<^sub>E _\<in>{i}. X)"
```
```   760     by (auto simp: prod_emb_def)
```
```   761   then show ?case
```
```   762     by (intro exI[of _ "{i}"] conjI bexI[of _ "\<Pi>\<^sub>E _\<in>{i}. X"])
```
```   763        (auto intro: countable_finite * sets_PiM_I_finite)
```
```   764 next
```
```   765   case Empty then show ?case
```
```   766     by (intro exI[of _ "{}"] conjI bexI[of _ "{}"]) auto
```
```   767 next
```
```   768   case (Compl A)
```
```   769   then obtain J X where "J \<subseteq> I" "X \<in> sets (Pi\<^sub>M J M)" "countable J" "A = prod_emb I M J X"
```
```   770     by auto
```
```   771   then show ?case
```
```   772     by (intro exI[of _ J] bexI[of _ "space (PiM J M) - X"] conjI)
```
```   773        (auto simp add: space_PiM prod_emb_PiE intro!: sets_PiM_I_countable)
```
```   774 next
```
```   775   case (Union K)
```
```   776   obtain J X where J: "\<And>i. J i \<subseteq> I" "\<And>i. countable (J i)" and X: "\<And>i. X i \<in> sets (Pi\<^sub>M (J i) M)"
```
```   777     and K: "\<And>i. K i = prod_emb I M (J i) (X i)"
```
```   778     by (metis Union.IH)
```
```   779   show ?case
```
```   780   proof (intro exI[of _ "\<Union>i. J i"] bexI[of _ "\<Union>i. prod_emb (\<Union>i. J i) M (J i) (X i)"] conjI)
```
```   781     show "(\<Union>i. J i) \<subseteq> I" "countable (\<Union>i. J i)" using J by auto
```
```   782     with J show "UNION UNIV K = prod_emb I M (\<Union>i. J i) (\<Union>i. prod_emb (\<Union>i. J i) M (J i) (X i))"
```
```   783       by (simp add: K[abs_def] SUP_upper)
```
```   784   qed(auto intro: X)
```
```   785 qed
```
```   786
```
```   787 lemma%important measure_eqI_PiM_finite:
```
```   788   assumes [simp]: "finite I" "sets P = PiM I M" "sets Q = PiM I M"
```
```   789   assumes eq: "\<And>A. (\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> P (Pi\<^sub>E I A) = Q (Pi\<^sub>E I A)"
```
```   790   assumes A: "range A \<subseteq> prod_algebra I M" "(\<Union>i. A i) = space (PiM I M)" "\<And>i::nat. P (A i) \<noteq> \<infinity>"
```
```   791   shows "P = Q"
```
```   792 proof%unimportant (rule measure_eqI_generator_eq[OF Int_stable_prod_algebra prod_algebra_sets_into_space])
```
```   793   show "range A \<subseteq> prod_algebra I M" "(\<Union>i. A i) = (\<Pi>\<^sub>E i\<in>I. space (M i))" "\<And>i. P (A i) \<noteq> \<infinity>"
```
```   794     unfolding space_PiM[symmetric] by fact+
```
```   795   fix X assume "X \<in> prod_algebra I M"
```
```   796   then obtain J E where X: "X = prod_emb I M J (\<Pi>\<^sub>E j\<in>J. E j)"
```
```   797     and J: "finite J" "J \<subseteq> I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets (M j)"
```
```   798     by (force elim!: prod_algebraE)
```
```   799   then show "emeasure P X = emeasure Q X"
```
```   800     unfolding X by (subst (1 2) prod_emb_Pi) (auto simp: eq)
```
```   801 qed (simp_all add: sets_PiM)
```
```   802
```
```   803 lemma%important measure_eqI_PiM_infinite:
```
```   804   assumes [simp]: "sets P = PiM I M" "sets Q = PiM I M"
```
```   805   assumes eq: "\<And>A J. finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow>
```
```   806     P (prod_emb I M J (Pi\<^sub>E J A)) = Q (prod_emb I M J (Pi\<^sub>E J A))"
```
```   807   assumes A: "finite_measure P"
```
```   808   shows "P = Q"
```
```   809 proof%unimportant (rule measure_eqI_generator_eq[OF Int_stable_prod_algebra prod_algebra_sets_into_space])
```
```   810   interpret finite_measure P by fact
```
```   811   define i where "i = (SOME i. i \<in> I)"
```
```   812   have i: "I \<noteq> {} \<Longrightarrow> i \<in> I"
```
```   813     unfolding i_def by (rule someI_ex) auto
```
```   814   define A where "A n =
```
```   815     (if I = {} then prod_emb I M {} (\<Pi>\<^sub>E i\<in>{}. {}) else prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i)))"
```
```   816     for n :: nat
```
```   817   then show "range A \<subseteq> prod_algebra I M"
```
```   818     using prod_algebraI[of "{}" I "\<lambda>i. space (M i)" M] by (auto intro!: prod_algebraI i)
```
```   819   have "\<And>i. A i = space (PiM I M)"
```
```   820     by (auto simp: prod_emb_def space_PiM PiE_iff A_def i ex_in_conv[symmetric] exI)
```
```   821   then show "(\<Union>i. A i) = (\<Pi>\<^sub>E i\<in>I. space (M i))" "\<And>i. emeasure P (A i) \<noteq> \<infinity>"
```
```   822     by (auto simp: space_PiM)
```
```   823 next
```
```   824   fix X assume X: "X \<in> prod_algebra I M"
```
```   825   then obtain J E where X: "X = prod_emb I M J (\<Pi>\<^sub>E j\<in>J. E j)"
```
```   826     and J: "finite J" "J \<subseteq> I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets (M j)"
```
```   827     by (force elim!: prod_algebraE)
```
```   828   then show "emeasure P X = emeasure Q X"
```
```   829     by (auto intro!: eq)
```
```   830 qed (auto simp: sets_PiM)
```
```   831
```
```   832 locale%unimportant product_sigma_finite =
```
```   833   fixes M :: "'i \<Rightarrow> 'a measure"
```
```   834   assumes sigma_finite_measures: "\<And>i. sigma_finite_measure (M i)"
```
```   835
```
```   836 sublocale%unimportant product_sigma_finite \<subseteq> M?: sigma_finite_measure "M i" for i
```
```   837   by (rule sigma_finite_measures)
```
```   838
```
```   839 locale%unimportant finite_product_sigma_finite = product_sigma_finite M for M :: "'i \<Rightarrow> 'a measure" +
```
```   840   fixes I :: "'i set"
```
```   841   assumes finite_index: "finite I"
```
```   842
```
```   843 lemma%important (in finite_product_sigma_finite) sigma_finite_pairs:
```
```   844   "\<exists>F::'i \<Rightarrow> nat \<Rightarrow> 'a set.
```
```   845     (\<forall>i\<in>I. range (F i) \<subseteq> sets (M i)) \<and>
```
```   846     (\<forall>k. \<forall>i\<in>I. emeasure (M i) (F i k) \<noteq> \<infinity>) \<and> incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k) \<and>
```
```   847     (\<Union>k. \<Pi>\<^sub>E i\<in>I. F i k) = space (PiM I M)"
```
```   848 proof%unimportant -
```
```   849   have "\<forall>i::'i. \<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (M i) \<and> incseq F \<and> (\<Union>i. F i) = space (M i) \<and> (\<forall>k. emeasure (M i) (F k) \<noteq> \<infinity>)"
```
```   850     using M.sigma_finite_incseq by metis
```
```   851   from choice[OF this] guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
```
```   852   then have F: "\<And>i. range (F i) \<subseteq> sets (M i)" "\<And>i. incseq (F i)" "\<And>i. (\<Union>j. F i j) = space (M i)" "\<And>i k. emeasure (M i) (F i k) \<noteq> \<infinity>"
```
```   853     by auto
```
```   854   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k"
```
```   855   note space_PiM[simp]
```
```   856   show ?thesis
```
```   857   proof (intro exI[of _ F] conjI allI incseq_SucI set_eqI iffI ballI)
```
```   858     fix i show "range (F i) \<subseteq> sets (M i)" by fact
```
```   859   next
```
```   860     fix i k show "emeasure (M i) (F i k) \<noteq> \<infinity>" by fact
```
```   861   next
```
```   862     fix x assume "x \<in> (\<Union>i. ?F i)" with F(1) show "x \<in> space (PiM I M)"
```
```   863       by (auto simp: PiE_def dest!: sets.sets_into_space)
```
```   864   next
```
```   865     fix f assume "f \<in> space (PiM I M)"
```
```   866     with Pi_UN[OF finite_index, of "\<lambda>k i. F i k"] F
```
```   867     show "f \<in> (\<Union>i. ?F i)" by (auto simp: incseq_def PiE_def)
```
```   868   next
```
```   869     fix i show "?F i \<subseteq> ?F (Suc i)"
```
```   870       using \<open>\<And>i. incseq (F i)\<close>[THEN incseq_SucD] by auto
```
```   871   qed
```
```   872 qed
```
```   873
```
```   874 lemma%unimportant emeasure_PiM_empty[simp]: "emeasure (PiM {} M) {\<lambda>_. undefined} = 1"
```
```   875 proof -
```
```   876   let ?\<mu> = "\<lambda>A. if A = {} then 0 else (1::ennreal)"
```
```   877   have "emeasure (Pi\<^sub>M {} M) (prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = 1"
```
```   878   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
```
```   879     show "positive (PiM {} M) ?\<mu>"
```
```   880       by (auto simp: positive_def)
```
```   881     show "countably_additive (PiM {} M) ?\<mu>"
```
```   882       by (rule sets.countably_additiveI_finite)
```
```   883          (auto simp: additive_def positive_def sets_PiM_empty space_PiM_empty intro!: )
```
```   884   qed (auto simp: prod_emb_def)
```
```   885   also have "(prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = {\<lambda>_. undefined}"
```
```   886     by (auto simp: prod_emb_def)
```
```   887   finally show ?thesis
```
```   888     by simp
```
```   889 qed
```
```   890
```
```   891 lemma%unimportant PiM_empty: "PiM {} M = count_space {\<lambda>_. undefined}"
```
```   892   by (rule measure_eqI) (auto simp add: sets_PiM_empty)
```
```   893
```
```   894 lemma%important (in product_sigma_finite) emeasure_PiM:
```
```   895   "finite I \<Longrightarrow> (\<And>i. i\<in>I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (PiM I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
```
```   896 proof%unimportant (induct I arbitrary: A rule: finite_induct)
```
```   897   case (insert i I)
```
```   898   interpret finite_product_sigma_finite M I by standard fact
```
```   899   have "finite (insert i I)" using \<open>finite I\<close> by auto
```
```   900   interpret I': finite_product_sigma_finite M "insert i I" by standard fact
```
```   901   let ?h = "(\<lambda>(f, y). f(i := y))"
```
```   902
```
```   903   let ?P = "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M) ?h"
```
```   904   let ?\<mu> = "emeasure ?P"
```
```   905   let ?I = "{j \<in> insert i I. emeasure (M j) (space (M j)) \<noteq> 1}"
```
```   906   let ?f = "\<lambda>J E j. if j \<in> J then emeasure (M j) (E j) else emeasure (M j) (space (M j))"
```
```   907
```
```   908   have "emeasure (Pi\<^sub>M (insert i I) M) (prod_emb (insert i I) M (insert i I) (Pi\<^sub>E (insert i I) A)) =
```
```   909     (\<Prod>i\<in>insert i I. emeasure (M i) (A i))"
```
```   910   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
```
```   911     fix J E assume "(J \<noteq> {} \<or> insert i I = {}) \<and> finite J \<and> J \<subseteq> insert i I \<and> E \<in> (\<Pi> j\<in>J. sets (M j))"
```
```   912     then have J: "J \<noteq> {}" "finite J" "J \<subseteq> insert i I" and E: "\<forall>j\<in>J. E j \<in> sets (M j)" by auto
```
```   913     let ?p = "prod_emb (insert i I) M J (Pi\<^sub>E J E)"
```
```   914     let ?p' = "prod_emb I M (J - {i}) (\<Pi>\<^sub>E j\<in>J-{i}. E j)"
```
```   915     have "?\<mu> ?p =
```
```   916       emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i))"
```
```   917       by (intro emeasure_distr measurable_add_dim sets_PiM_I) fact+
```
```   918     also have "?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) = ?p' \<times> (if i \<in> J then E i else space (M i))"
```
```   919       using J E[rule_format, THEN sets.sets_into_space]
```
```   920       by (force simp: space_pair_measure space_PiM prod_emb_iff PiE_def Pi_iff split: if_split_asm)
```
```   921     also have "emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?p' \<times> (if i \<in> J then E i else space (M i))) =
```
```   922       emeasure (Pi\<^sub>M I M) ?p' * emeasure (M i) (if i \<in> J then (E i) else space (M i))"
```
```   923       using J E by (intro M.emeasure_pair_measure_Times sets_PiM_I) auto
```
```   924     also have "?p' = (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j))"
```
```   925       using J E[rule_format, THEN sets.sets_into_space]
```
```   926       by (auto simp: prod_emb_iff PiE_def Pi_iff split: if_split_asm) blast+
```
```   927     also have "emeasure (Pi\<^sub>M I M) (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j)) =
```
```   928       (\<Prod> j\<in>I. if j \<in> J-{i} then emeasure (M j) (E j) else emeasure (M j) (space (M j)))"
```
```   929       using E by (subst insert) (auto intro!: prod.cong)
```
```   930     also have "(\<Prod>j\<in>I. if j \<in> J - {i} then emeasure (M j) (E j) else emeasure (M j) (space (M j))) *
```
```   931        emeasure (M i) (if i \<in> J then E i else space (M i)) = (\<Prod>j\<in>insert i I. ?f J E j)"
```
```   932       using insert by (auto simp: mult.commute intro!: arg_cong2[where f="( * )"] prod.cong)
```
```   933     also have "\<dots> = (\<Prod>j\<in>J \<union> ?I. ?f J E j)"
```
```   934       using insert(1,2) J E by (intro prod.mono_neutral_right) auto
```
```   935     finally show "?\<mu> ?p = \<dots>" .
```
```   936
```
```   937     show "prod_emb (insert i I) M J (Pi\<^sub>E J E) \<in> Pow (\<Pi>\<^sub>E i\<in>insert i I. space (M i))"
```
```   938       using J E[rule_format, THEN sets.sets_into_space] by (auto simp: prod_emb_iff PiE_def)
```
```   939   next
```
```   940     show "positive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>" "countably_additive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>"
```
```   941       using emeasure_positive[of ?P] emeasure_countably_additive[of ?P] by simp_all
```
```   942   next
```
```   943     show "(insert i I \<noteq> {} \<or> insert i I = {}) \<and> finite (insert i I) \<and>
```
```   944       insert i I \<subseteq> insert i I \<and> A \<in> (\<Pi> j\<in>insert i I. sets (M j))"
```
```   945       using insert by auto
```
```   946   qed (auto intro!: prod.cong)
```
```   947   with insert show ?case
```
```   948     by (subst (asm) prod_emb_PiE_same_index) (auto intro!: sets.sets_into_space)
```
```   949 qed simp
```
```   950
```
```   951 lemma%unimportant (in product_sigma_finite) PiM_eqI:
```
```   952   assumes I[simp]: "finite I" and P: "sets P = PiM I M"
```
```   953   assumes eq: "\<And>A. (\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> P (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
```
```   954   shows "P = PiM I M"
```
```   955 proof -
```
```   956   interpret finite_product_sigma_finite M I
```
```   957     proof qed fact
```
```   958   from sigma_finite_pairs guess C .. note C = this
```
```   959   show ?thesis
```
```   960   proof (rule measure_eqI_PiM_finite[OF I refl P, symmetric])
```
```   961     show "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> (Pi\<^sub>M I M) (Pi\<^sub>E I A) = P (Pi\<^sub>E I A)" for A
```
```   962       by (simp add: eq emeasure_PiM)
```
```   963     define A where "A n = (\<Pi>\<^sub>E i\<in>I. C i n)" for n
```
```   964     with C show "range A \<subseteq> prod_algebra I M" "\<And>i. emeasure (Pi\<^sub>M I M) (A i) \<noteq> \<infinity>" "(\<Union>i. A i) = space (PiM I M)"
```
```   965       by (auto intro!: prod_algebraI_finite simp: emeasure_PiM subset_eq ennreal_prod_eq_top)
```
```   966   qed
```
```   967 qed
```
```   968
```
```   969 lemma%unimportant (in product_sigma_finite) sigma_finite:
```
```   970   assumes "finite I"
```
```   971   shows "sigma_finite_measure (PiM I M)"
```
```   972 proof
```
```   973   interpret finite_product_sigma_finite M I by standard fact
```
```   974
```
```   975   obtain F where F: "\<And>j. countable (F j)" "\<And>j f. f \<in> F j \<Longrightarrow> f \<in> sets (M j)"
```
```   976     "\<And>j f. f \<in> F j \<Longrightarrow> emeasure (M j) f \<noteq> \<infinity>" and
```
```   977     in_space: "\<And>j. space (M j) = (\<Union>F j)"
```
```   978     using sigma_finite_countable by (metis subset_eq)
```
```   979   moreover have "(\<Union>(Pi\<^sub>E I ` Pi\<^sub>E I F)) = space (Pi\<^sub>M I M)"
```
```   980     using in_space by (auto simp: space_PiM PiE_iff intro!: PiE_choice[THEN iffD2])
```
```   981   ultimately show "\<exists>A. countable A \<and> A \<subseteq> sets (Pi\<^sub>M I M) \<and> \<Union>A = space (Pi\<^sub>M I M) \<and> (\<forall>a\<in>A. emeasure (Pi\<^sub>M I M) a \<noteq> \<infinity>)"
```
```   982     by (intro exI[of _ "Pi\<^sub>E I ` Pi\<^sub>E I F"])
```
```   983        (auto intro!: countable_PiE sets_PiM_I_finite
```
```   984              simp: PiE_iff emeasure_PiM finite_index ennreal_prod_eq_top)
```
```   985 qed
```
```   986
```
```   987 sublocale finite_product_sigma_finite \<subseteq> sigma_finite_measure "Pi\<^sub>M I M"
```
```   988   using sigma_finite[OF finite_index] .
```
```   989
```
```   990 lemma%unimportant (in finite_product_sigma_finite) measure_times:
```
```   991   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (Pi\<^sub>M I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
```
```   992   using emeasure_PiM[OF finite_index] by auto
```
```   993
```
```   994 lemma%unimportant (in product_sigma_finite) nn_integral_empty:
```
```   995   "0 \<le> f (\<lambda>k. undefined) \<Longrightarrow> integral\<^sup>N (Pi\<^sub>M {} M) f = f (\<lambda>k. undefined)"
```
```   996   by (simp add: PiM_empty nn_integral_count_space_finite max.absorb2)
```
```   997
```
```   998 lemma%important (in product_sigma_finite) distr_merge:
```
```   999   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
```
```  1000   shows "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M) (merge I J) = Pi\<^sub>M (I \<union> J) M"
```
```  1001    (is "?D = ?P")
```
```  1002 proof%unimportant (rule PiM_eqI)
```
```  1003   interpret I: finite_product_sigma_finite M I by standard fact
```
```  1004   interpret J: finite_product_sigma_finite M J by standard fact
```
```  1005   fix A assume A: "\<And>i. i \<in> I \<union> J \<Longrightarrow> A i \<in> sets (M i)"
```
```  1006   have *: "(merge I J -` Pi\<^sub>E (I \<union> J) A \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)) = Pi\<^sub>E I A \<times> Pi\<^sub>E J A"
```
```  1007     using A[THEN sets.sets_into_space] by (auto simp: space_PiM space_pair_measure)
```
```  1008   from A fin show "emeasure (distr (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M) (merge I J)) (Pi\<^sub>E (I \<union> J) A) =
```
```  1009       (\<Prod>i\<in>I \<union> J. emeasure (M i) (A i))"
```
```  1010     by (subst emeasure_distr)
```
```  1011        (auto simp: * J.emeasure_pair_measure_Times I.measure_times J.measure_times prod.union_disjoint)
```
```  1012 qed (insert fin, simp_all)
```
```  1013
```
```  1014 lemma%important (in product_sigma_finite) product_nn_integral_fold:
```
```  1015   assumes IJ: "I \<inter> J = {}" "finite I" "finite J"
```
```  1016   and f[measurable]: "f \<in> borel_measurable (Pi\<^sub>M (I \<union> J) M)"
```
```  1017   shows "integral\<^sup>N (Pi\<^sub>M (I \<union> J) M) f =
```
```  1018     (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (merge I J (x, y)) \<partial>(Pi\<^sub>M J M)) \<partial>(Pi\<^sub>M I M))"
```
```  1019 proof%unimportant -
```
```  1020   interpret I: finite_product_sigma_finite M I by standard fact
```
```  1021   interpret J: finite_product_sigma_finite M J by standard fact
```
```  1022   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by standard
```
```  1023   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
```
```  1024     using measurable_comp[OF measurable_merge f] by (simp add: comp_def)
```
```  1025   show ?thesis
```
```  1026     apply (subst distr_merge[OF IJ, symmetric])
```
```  1027     apply (subst nn_integral_distr[OF measurable_merge])
```
```  1028     apply measurable []
```
```  1029     apply (subst J.nn_integral_fst[symmetric, OF P_borel])
```
```  1030     apply simp
```
```  1031     done
```
```  1032 qed
```
```  1033
```
```  1034 lemma%unimportant (in product_sigma_finite) distr_singleton:
```
```  1035   "distr (Pi\<^sub>M {i} M) (M i) (\<lambda>x. x i) = M i" (is "?D = _")
```
```  1036 proof (intro measure_eqI[symmetric])
```
```  1037   interpret I: finite_product_sigma_finite M "{i}" by standard simp
```
```  1038   fix A assume A: "A \<in> sets (M i)"
```
```  1039   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M {i} M) = (\<Pi>\<^sub>E i\<in>{i}. A)"
```
```  1040     using sets.sets_into_space by (auto simp: space_PiM)
```
```  1041   then show "emeasure (M i) A = emeasure ?D A"
```
```  1042     using A I.measure_times[of "\<lambda>_. A"]
```
```  1043     by (simp add: emeasure_distr measurable_component_singleton)
```
```  1044 qed simp
```
```  1045
```
```  1046 lemma%unimportant (in product_sigma_finite) product_nn_integral_singleton:
```
```  1047   assumes f: "f \<in> borel_measurable (M i)"
```
```  1048   shows "integral\<^sup>N (Pi\<^sub>M {i} M) (\<lambda>x. f (x i)) = integral\<^sup>N (M i) f"
```
```  1049 proof -
```
```  1050   interpret I: finite_product_sigma_finite M "{i}" by standard simp
```
```  1051   from f show ?thesis
```
```  1052     apply (subst distr_singleton[symmetric])
```
```  1053     apply (subst nn_integral_distr[OF measurable_component_singleton])
```
```  1054     apply simp_all
```
```  1055     done
```
```  1056 qed
```
```  1057
```
```  1058 lemma%important (in product_sigma_finite) product_nn_integral_insert:
```
```  1059   assumes I[simp]: "finite I" "i \<notin> I"
```
```  1060     and f: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
```
```  1061   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (x(i := y)) \<partial>(M i)) \<partial>(Pi\<^sub>M I M))"
```
```  1062 proof%unimportant -
```
```  1063   interpret I: finite_product_sigma_finite M I by standard auto
```
```  1064   interpret i: finite_product_sigma_finite M "{i}" by standard auto
```
```  1065   have IJ: "I \<inter> {i} = {}" and insert: "I \<union> {i} = insert i I"
```
```  1066     using f by auto
```
```  1067   show ?thesis
```
```  1068     unfolding product_nn_integral_fold[OF IJ, unfolded insert, OF I(1) i.finite_index f]
```
```  1069   proof (rule nn_integral_cong, subst product_nn_integral_singleton[symmetric])
```
```  1070     fix x assume x: "x \<in> space (Pi\<^sub>M I M)"
```
```  1071     let ?f = "\<lambda>y. f (x(i := y))"
```
```  1072     show "?f \<in> borel_measurable (M i)"
```
```  1073       using measurable_comp[OF measurable_component_update f, OF x \<open>i \<notin> I\<close>]
```
```  1074       unfolding comp_def .
```
```  1075     show "(\<integral>\<^sup>+ y. f (merge I {i} (x, y)) \<partial>Pi\<^sub>M {i} M) = (\<integral>\<^sup>+ y. f (x(i := y i)) \<partial>Pi\<^sub>M {i} M)"
```
```  1076       using x
```
```  1077       by (auto intro!: nn_integral_cong arg_cong[where f=f]
```
```  1078                simp add: space_PiM extensional_def PiE_def)
```
```  1079   qed
```
```  1080 qed
```
```  1081
```
```  1082 lemma%unimportant (in product_sigma_finite) product_nn_integral_insert_rev:
```
```  1083   assumes I[simp]: "finite I" "i \<notin> I"
```
```  1084     and [measurable]: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
```
```  1085   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ y. (\<integral>\<^sup>+ x. f (x(i := y)) \<partial>(Pi\<^sub>M I M)) \<partial>(M i))"
```
```  1086   apply (subst product_nn_integral_insert[OF assms])
```
```  1087   apply (rule pair_sigma_finite.Fubini')
```
```  1088   apply intro_locales []
```
```  1089   apply (rule sigma_finite[OF I(1)])
```
```  1090   apply measurable
```
```  1091   done
```
```  1092
```
```  1093 lemma%unimportant (in product_sigma_finite) product_nn_integral_prod:
```
```  1094   assumes "finite I" "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
```
```  1095   shows "(\<integral>\<^sup>+ x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^sub>M I M) = (\<Prod>i\<in>I. integral\<^sup>N (M i) (f i))"
```
```  1096 using assms proof (induction I)
```
```  1097   case (insert i I)
```
```  1098   note insert.prems[measurable]
```
```  1099   note \<open>finite I\<close>[intro, simp]
```
```  1100   interpret I: finite_product_sigma_finite M I by standard auto
```
```  1101   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
```
```  1102     using insert by (auto intro!: prod.cong)
```
```  1103   have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow> (\<lambda>x. (\<Prod>i\<in>J. f i (x i))) \<in> borel_measurable (Pi\<^sub>M J M)"
```
```  1104     using sets.sets_into_space insert
```
```  1105     by (intro borel_measurable_prod_ennreal
```
```  1106               measurable_comp[OF measurable_component_singleton, unfolded comp_def])
```
```  1107        auto
```
```  1108   then show ?case
```
```  1109     apply (simp add: product_nn_integral_insert[OF insert(1,2)])
```
```  1110     apply (simp add: insert(2-) * nn_integral_multc)
```
```  1111     apply (subst nn_integral_cmult)
```
```  1112     apply (auto simp add: insert(2-))
```
```  1113     done
```
```  1114 qed (simp add: space_PiM)
```
```  1115
```
```  1116 lemma%important (in product_sigma_finite) product_nn_integral_pair:
```
```  1117   assumes [measurable]: "case_prod f \<in> borel_measurable (M x \<Otimes>\<^sub>M M y)"
```
```  1118   assumes xy: "x \<noteq> y"
```
```  1119   shows "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {x, y} M) = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
```
```  1120 proof%unimportant -
```
```  1121   interpret psm: pair_sigma_finite "M x" "M y"
```
```  1122     unfolding pair_sigma_finite_def using sigma_finite_measures by simp_all
```
```  1123   have "{x, y} = {y, x}" by auto
```
```  1124   also have "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {y, x} M) = (\<integral>\<^sup>+y. \<integral>\<^sup>+\<sigma>. f (\<sigma> x) y \<partial>PiM {x} M \<partial>M y)"
```
```  1125     using xy by (subst product_nn_integral_insert_rev) simp_all
```
```  1126   also have "... = (\<integral>\<^sup>+y. \<integral>\<^sup>+x. f x y \<partial>M x \<partial>M y)"
```
```  1127     by (intro nn_integral_cong, subst product_nn_integral_singleton) simp_all
```
```  1128   also have "... = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
```
```  1129     by (subst psm.nn_integral_snd[symmetric]) simp_all
```
```  1130   finally show ?thesis .
```
```  1131 qed
```
```  1132
```
```  1133 lemma%unimportant (in product_sigma_finite) distr_component:
```
```  1134   "distr (M i) (Pi\<^sub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^sub>M {i} M" (is "?D = ?P")
```
```  1135 proof (intro PiM_eqI)
```
```  1136   fix A assume A: "\<And>ia. ia \<in> {i} \<Longrightarrow> A ia \<in> sets (M ia)"
```
```  1137   then have "(\<lambda>x. \<lambda>i\<in>{i}. x) -` Pi\<^sub>E {i} A \<inter> space (M i) = A i"
```
```  1138     by (fastforce dest: sets.sets_into_space)
```
```  1139   with A show "emeasure (distr (M i) (Pi\<^sub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x)) (Pi\<^sub>E {i} A) = (\<Prod>i\<in>{i}. emeasure (M i) (A i))"
```
```  1140     by (subst emeasure_distr) (auto intro!: sets_PiM_I_finite measurable_restrict)
```
```  1141 qed simp_all
```
```  1142
```
```  1143 lemma%unimportant (in product_sigma_finite)
```
```  1144   assumes IJ: "I \<inter> J = {}" "finite I" "finite J" and A: "A \<in> sets (Pi\<^sub>M (I \<union> J) M)"
```
```  1145   shows emeasure_fold_integral:
```
```  1146     "emeasure (Pi\<^sub>M (I \<union> J) M) A = (\<integral>\<^sup>+x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M)) \<partial>Pi\<^sub>M I M)" (is ?I)
```
```  1147     and emeasure_fold_measurable:
```
```  1148     "(\<lambda>x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M))) \<in> borel_measurable (Pi\<^sub>M I M)" (is ?B)
```
```  1149 proof -
```
```  1150   interpret I: finite_product_sigma_finite M I by standard fact
```
```  1151   interpret J: finite_product_sigma_finite M J by standard fact
```
```  1152   interpret IJ: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" ..
```
```  1153   have merge: "merge I J -` A \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) \<in> sets (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
```
```  1154     by (intro measurable_sets[OF _ A] measurable_merge assms)
```
```  1155
```
```  1156   show ?I
```
```  1157     apply (subst distr_merge[symmetric, OF IJ])
```
```  1158     apply (subst emeasure_distr[OF measurable_merge A])
```
```  1159     apply (subst J.emeasure_pair_measure_alt[OF merge])
```
```  1160     apply (auto intro!: nn_integral_cong arg_cong2[where f=emeasure] simp: space_pair_measure)
```
```  1161     done
```
```  1162
```
```  1163   show ?B
```
```  1164     using IJ.measurable_emeasure_Pair1[OF merge]
```
```  1165     by (simp add: vimage_comp comp_def space_pair_measure cong: measurable_cong)
```
```  1166 qed
```
```  1167
```
```  1168 lemma%unimportant sets_Collect_single:
```
```  1169   "i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> { x \<in> space (Pi\<^sub>M I M). x i \<in> A } \<in> sets (Pi\<^sub>M I M)"
```
```  1170   by simp
```
```  1171
```
```  1172 lemma%unimportant pair_measure_eq_distr_PiM:
```
```  1173   fixes M1 :: "'a measure" and M2 :: "'a measure"
```
```  1174   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
```
```  1175   shows "(M1 \<Otimes>\<^sub>M M2) = distr (Pi\<^sub>M UNIV (case_bool M1 M2)) (M1 \<Otimes>\<^sub>M M2) (\<lambda>x. (x True, x False))"
```
```  1176     (is "?P = ?D")
```
```  1177 proof (rule pair_measure_eqI[OF assms])
```
```  1178   interpret B: product_sigma_finite "case_bool M1 M2"
```
```  1179     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
```
```  1180   let ?B = "Pi\<^sub>M UNIV (case_bool M1 M2)"
```
```  1181
```
```  1182   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
```
```  1183     by auto
```
```  1184   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
```
```  1185   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (case_bool M1 M2 i) (case_bool A B i))"
```
```  1186     by (simp add: UNIV_bool ac_simps)
```
```  1187   also have "\<dots> = emeasure ?B (Pi\<^sub>E UNIV (case_bool A B))"
```
```  1188     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
```
```  1189   also have "Pi\<^sub>E UNIV (case_bool A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
```
```  1190     using A[THEN sets.sets_into_space] B[THEN sets.sets_into_space]
```
```  1191     by (auto simp: PiE_iff all_bool_eq space_PiM split: bool.split)
```
```  1192   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
```
```  1193     using A B
```
```  1194       measurable_component_singleton[of True UNIV "case_bool M1 M2"]
```
```  1195       measurable_component_singleton[of False UNIV "case_bool M1 M2"]
```
```  1196     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
```
```  1197 qed simp
```
```  1198
```
```  1199 lemma%unimportant infprod_in_sets[intro]:
```
```  1200   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets (M i)"
```
```  1201   shows "Pi UNIV E \<in> sets (\<Pi>\<^sub>M i\<in>UNIV::nat set. M i)"
```
```  1202 proof -
```
```  1203   have "Pi UNIV E = (\<Inter>i. prod_emb UNIV M {..i} (\<Pi>\<^sub>E j\<in>{..i}. E j))"
```
```  1204     using E E[THEN sets.sets_into_space]
```
```  1205     by (auto simp: prod_emb_def Pi_iff extensional_def)
```
```  1206   with E show ?thesis by auto
```
```  1207 qed
```
```  1208
```
```  1209 end
```