src/HOL/Tools/inductive_package.ML
author wenzelm
Mon Feb 25 16:31:15 2008 +0100 (2008-02-25)
changeset 26128 fe2d24c26e0c
parent 25978 8ba1eba8d058
child 26336 a0e2b706ce73
permissions -rw-r--r--
inductive package: simplified group handling;
     1 (*  Title:      HOL/Tools/inductive_package.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     5 
     6 (Co)Inductive Definition module for HOL.
     7 
     8 Features:
     9   * least or greatest fixedpoints
    10   * mutually recursive definitions
    11   * definitions involving arbitrary monotone operators
    12   * automatically proves introduction and elimination rules
    13 
    14   Introduction rules have the form
    15   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    16   where M is some monotone operator (usually the identity)
    17   Q x is any side condition on the free variables
    18   ti, t are any terms
    19   Pj, Pk are two of the predicates being defined in mutual recursion
    20 *)
    21 
    22 signature BASIC_INDUCTIVE_PACKAGE =
    23 sig
    24   val quiet_mode: bool ref
    25   type inductive_result
    26   val morph_result: morphism -> inductive_result -> inductive_result
    27   type inductive_info
    28   val the_inductive: Proof.context -> string -> inductive_info
    29   val print_inductives: Proof.context -> unit
    30   val mono_add: attribute
    31   val mono_del: attribute
    32   val get_monos: Proof.context -> thm list
    33   val mk_cases: Proof.context -> term -> thm
    34   val inductive_forall_name: string
    35   val inductive_forall_def: thm
    36   val rulify: thm -> thm
    37   val inductive_cases: ((bstring * Attrib.src list) * string list) list ->
    38     Proof.context -> thm list list * local_theory
    39   val inductive_cases_i: ((bstring * Attrib.src list) * term list) list ->
    40     Proof.context -> thm list list * local_theory
    41   val add_inductive_i:
    42     {verbose: bool, kind: string, alt_name: bstring, coind: bool, no_elim: bool, no_ind: bool} ->
    43     ((string * typ) * mixfix) list ->
    44     (string * typ) list -> ((bstring * Attrib.src list) * term) list -> thm list ->
    45       local_theory -> inductive_result * local_theory
    46   val add_inductive: bool -> bool -> (string * string option * mixfix) list ->
    47     (string * string option * mixfix) list ->
    48     ((bstring * Attrib.src list) * string) list -> (thmref * Attrib.src list) list ->
    49     local_theory -> inductive_result * local_theory
    50   val add_inductive_global: string ->
    51     {verbose: bool, kind: string, alt_name: bstring, coind: bool, no_elim: bool, no_ind: bool} ->
    52     ((string * typ) * mixfix) list -> (string * typ) list ->
    53     ((bstring * Attrib.src list) * term) list -> thm list -> theory -> inductive_result * theory
    54   val arities_of: thm -> (string * int) list
    55   val params_of: thm -> term list
    56   val partition_rules: thm -> thm list -> (string * thm list) list
    57   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    58   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    59   val infer_intro_vars: thm -> int -> thm list -> term list list
    60   val setup: theory -> theory
    61 end;
    62 
    63 signature INDUCTIVE_PACKAGE =
    64 sig
    65   include BASIC_INDUCTIVE_PACKAGE
    66   type add_ind_def
    67   val declare_rules: string -> bstring -> bool -> bool -> string list ->
    68     thm list -> bstring list -> Attrib.src list list -> (thm * string list) list ->
    69     thm -> local_theory -> thm list * thm list * thm * local_theory
    70   val add_ind_def: add_ind_def
    71   val gen_add_inductive_i: add_ind_def ->
    72     {verbose: bool, kind: string, alt_name: bstring, coind: bool, no_elim: bool, no_ind: bool} ->
    73     ((string * typ) * mixfix) list ->
    74     (string * typ) list -> ((bstring * Attrib.src list) * term) list -> thm list ->
    75       local_theory -> inductive_result * local_theory
    76   val gen_add_inductive: add_ind_def ->
    77     bool -> bool -> (string * string option * mixfix) list ->
    78     (string * string option * mixfix) list ->
    79     ((bstring * Attrib.src list) * string) list -> (thmref * Attrib.src list) list ->
    80     local_theory -> inductive_result * local_theory
    81   val gen_ind_decl: add_ind_def ->
    82     bool -> OuterParse.token list ->
    83     (Toplevel.transition -> Toplevel.transition) * OuterParse.token list
    84 end;
    85 
    86 structure InductivePackage: INDUCTIVE_PACKAGE =
    87 struct
    88 
    89 
    90 (** theory context references **)
    91 
    92 val inductive_forall_name = "HOL.induct_forall";
    93 val inductive_forall_def = thm "induct_forall_def";
    94 val inductive_conj_name = "HOL.induct_conj";
    95 val inductive_conj_def = thm "induct_conj_def";
    96 val inductive_conj = thms "induct_conj";
    97 val inductive_atomize = thms "induct_atomize";
    98 val inductive_rulify = thms "induct_rulify";
    99 val inductive_rulify_fallback = thms "induct_rulify_fallback";
   100 
   101 val notTrueE = TrueI RSN (2, notE);
   102 val notFalseI = Seq.hd (atac 1 notI);
   103 val simp_thms' = map (fn s => mk_meta_eq (the (find_first
   104   (equal (Sign.read_prop HOL.thy s) o prop_of) simp_thms)))
   105   ["(~True) = False", "(~False) = True",
   106    "(True --> ?P) = ?P", "(False --> ?P) = True",
   107    "(?P & True) = ?P", "(True & ?P) = ?P"];
   108 
   109 
   110 
   111 (** context data **)
   112 
   113 type inductive_result =
   114   {preds: term list, elims: thm list, raw_induct: thm,
   115    induct: thm, intrs: thm list};
   116 
   117 fun morph_result phi {preds, elims, raw_induct: thm, induct, intrs} =
   118   let
   119     val term = Morphism.term phi;
   120     val thm = Morphism.thm phi;
   121     val fact = Morphism.fact phi;
   122   in
   123    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   124     induct = thm induct, intrs = fact intrs}
   125   end;
   126 
   127 type inductive_info =
   128   {names: string list, coind: bool} * inductive_result;
   129 
   130 structure InductiveData = GenericDataFun
   131 (
   132   type T = inductive_info Symtab.table * thm list;
   133   val empty = (Symtab.empty, []);
   134   val extend = I;
   135   fun merge _ ((tab1, monos1), (tab2, monos2)) =
   136     (Symtab.merge (K true) (tab1, tab2), Thm.merge_thms (monos1, monos2));
   137 );
   138 
   139 val get_inductives = InductiveData.get o Context.Proof;
   140 
   141 fun print_inductives ctxt =
   142   let
   143     val (tab, monos) = get_inductives ctxt;
   144     val space = Consts.space_of (ProofContext.consts_of ctxt);
   145   in
   146     [Pretty.strs ("(co)inductives:" :: map #1 (NameSpace.extern_table (space, tab))),
   147      Pretty.big_list "monotonicity rules:" (map (ProofContext.pretty_thm ctxt) monos)]
   148     |> Pretty.chunks |> Pretty.writeln
   149   end;
   150 
   151 
   152 (* get and put data *)
   153 
   154 fun the_inductive ctxt name =
   155   (case Symtab.lookup (#1 (get_inductives ctxt)) name of
   156     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   157   | SOME info => info);
   158 
   159 fun put_inductives names info = InductiveData.map
   160   (apfst (fold (fn name => Symtab.update (name, info)) names));
   161 
   162 
   163 
   164 (** monotonicity rules **)
   165 
   166 val get_monos = #2 o get_inductives;
   167 val map_monos = InductiveData.map o apsnd;
   168 
   169 fun mk_mono thm =
   170   let
   171     val concl = concl_of thm;
   172     fun eq2mono thm' = [thm' RS (thm' RS eq_to_mono)] @
   173       (case concl of
   174           (_ $ (_ $ (Const ("Not", _) $ _) $ _)) => []
   175         | _ => [thm' RS (thm' RS eq_to_mono2)]);
   176     fun dest_less_concl thm = dest_less_concl (thm RS le_funD)
   177       handle THM _ => thm RS le_boolD
   178   in
   179     case concl of
   180       Const ("==", _) $ _ $ _ => eq2mono (thm RS meta_eq_to_obj_eq)
   181     | _ $ (Const ("op =", _) $ _ $ _) => eq2mono thm
   182     | _ $ (Const ("HOL.ord_class.less_eq", _) $ _ $ _) =>
   183       [dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   184          (resolve_tac [le_funI, le_boolI'])) thm))]
   185     | _ => [thm]
   186   end handle THM _ => error ("Bad monotonicity theorem:\n" ^ string_of_thm thm);
   187 
   188 val mono_add = Thm.declaration_attribute (map_monos o fold Thm.add_thm o mk_mono);
   189 val mono_del = Thm.declaration_attribute (map_monos o fold Thm.del_thm o mk_mono);
   190 
   191 
   192 
   193 (** misc utilities **)
   194 
   195 val quiet_mode = ref false;
   196 fun message s = if ! quiet_mode then () else writeln s;
   197 fun clean_message s = if ! quick_and_dirty then () else message s;
   198 
   199 fun coind_prefix true = "co"
   200   | coind_prefix false = "";
   201 
   202 fun log (b:int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   203 
   204 fun make_bool_args f g [] i = []
   205   | make_bool_args f g (x :: xs) i =
   206       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   207 
   208 fun make_bool_args' xs =
   209   make_bool_args (K HOLogic.false_const) (K HOLogic.true_const) xs;
   210 
   211 fun find_arg T x [] = sys_error "find_arg"
   212   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   213       apsnd (cons p) (find_arg T x ps)
   214   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   215       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   216       else apsnd (cons p) (find_arg T x ps);
   217 
   218 fun make_args Ts xs =
   219   map (fn (T, (NONE, ())) => Const ("arbitrary", T) | (_, (SOME t, ())) => t)
   220     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   221 
   222 fun make_args' Ts xs Us =
   223   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   224 
   225 fun dest_predicate cs params t =
   226   let
   227     val k = length params;
   228     val (c, ts) = strip_comb t;
   229     val (xs, ys) = chop k ts;
   230     val i = find_index_eq c cs;
   231   in
   232     if xs = params andalso i >= 0 then
   233       SOME (c, i, ys, chop (length ys)
   234         (List.drop (binder_types (fastype_of c), k)))
   235     else NONE
   236   end;
   237 
   238 fun mk_names a 0 = []
   239   | mk_names a 1 = [a]
   240   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   241 
   242 
   243 
   244 (** process rules **)
   245 
   246 local
   247 
   248 fun err_in_rule ctxt name t msg =
   249   error (cat_lines ["Ill-formed introduction rule " ^ quote name,
   250     Syntax.string_of_term ctxt t, msg]);
   251 
   252 fun err_in_prem ctxt name t p msg =
   253   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   254     "in introduction rule " ^ quote name, Syntax.string_of_term ctxt t, msg]);
   255 
   256 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   257 
   258 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   259 
   260 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   261 
   262 fun atomize_term thy = MetaSimplifier.rewrite_term thy inductive_atomize [];
   263 
   264 in
   265 
   266 fun check_rule ctxt cs params ((name, att), rule) =
   267   let
   268     val params' = Term.variant_frees rule (Logic.strip_params rule);
   269     val frees = rev (map Free params');
   270     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   271     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   272     val rule' = Logic.list_implies (prems, concl);
   273     val aprems = map (atomize_term (ProofContext.theory_of ctxt)) prems;
   274     val arule = list_all_free (params', Logic.list_implies (aprems, concl));
   275 
   276     fun check_ind err t = case dest_predicate cs params t of
   277         NONE => err (bad_app ^
   278           commas (map (Syntax.string_of_term ctxt) params))
   279       | SOME (_, _, ys, _) =>
   280           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   281           then err bad_ind_occ else ();
   282 
   283     fun check_prem' prem t =
   284       if head_of t mem cs then
   285         check_ind (err_in_prem ctxt name rule prem) t
   286       else (case t of
   287           Abs (_, _, t) => check_prem' prem t
   288         | t $ u => (check_prem' prem t; check_prem' prem u)
   289         | _ => ());
   290 
   291     fun check_prem (prem, aprem) =
   292       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   293       else err_in_prem ctxt name rule prem "Non-atomic premise";
   294   in
   295     (case concl of
   296        Const ("Trueprop", _) $ t =>
   297          if head_of t mem cs then
   298            (check_ind (err_in_rule ctxt name rule') t;
   299             List.app check_prem (prems ~~ aprems))
   300          else err_in_rule ctxt name rule' bad_concl
   301      | _ => err_in_rule ctxt name rule' bad_concl);
   302     ((name, att), arule)
   303   end;
   304 
   305 val rulify =
   306   hol_simplify inductive_conj
   307   #> hol_simplify inductive_rulify
   308   #> hol_simplify inductive_rulify_fallback
   309   #> MetaSimplifier.norm_hhf;
   310 
   311 end;
   312 
   313 
   314 
   315 (** proofs for (co)inductive predicates **)
   316 
   317 (* prove monotonicity -- NOT subject to quick_and_dirty! *)
   318 
   319 fun prove_mono predT fp_fun monos ctxt =
   320  (message "  Proving monotonicity ...";
   321   Goal.prove ctxt [] []   (*NO quick_and_dirty here!*)
   322     (HOLogic.mk_Trueprop
   323       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   324     (fn _ => EVERY [rtac @{thm monoI} 1,
   325       REPEAT (resolve_tac [le_funI, le_boolI'] 1),
   326       REPEAT (FIRST
   327         [atac 1,
   328          resolve_tac (List.concat (map mk_mono monos) @ get_monos ctxt) 1,
   329          etac le_funE 1, dtac le_boolD 1])]));
   330 
   331 
   332 (* prove introduction rules *)
   333 
   334 fun prove_intrs coind mono fp_def k params intr_ts rec_preds_defs ctxt =
   335   let
   336     val _ = clean_message "  Proving the introduction rules ...";
   337 
   338     val unfold = funpow k (fn th => th RS fun_cong)
   339       (mono RS (fp_def RS
   340         (if coind then def_gfp_unfold else def_lfp_unfold)));
   341 
   342     fun select_disj 1 1 = []
   343       | select_disj _ 1 = [rtac disjI1]
   344       | select_disj n i = (rtac disjI2)::(select_disj (n - 1) (i - 1));
   345 
   346     val rules = [refl, TrueI, notFalseI, exI, conjI];
   347 
   348     val intrs = map_index (fn (i, intr) => rulify
   349       (SkipProof.prove ctxt (map (fst o dest_Free) params) [] intr (fn _ => EVERY
   350        [rewrite_goals_tac rec_preds_defs,
   351         rtac (unfold RS iffD2) 1,
   352         EVERY1 (select_disj (length intr_ts) (i + 1)),
   353         (*Not ares_tac, since refl must be tried before any equality assumptions;
   354           backtracking may occur if the premises have extra variables!*)
   355         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)]))) intr_ts
   356 
   357   in (intrs, unfold) end;
   358 
   359 
   360 (* prove elimination rules *)
   361 
   362 fun prove_elims cs params intr_ts intr_names unfold rec_preds_defs ctxt =
   363   let
   364     val _ = clean_message "  Proving the elimination rules ...";
   365 
   366     val ([pname], ctxt') = ctxt |>
   367       Variable.add_fixes (map (fst o dest_Free) params) |> snd |>
   368       Variable.variant_fixes ["P"];
   369     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   370 
   371     fun dest_intr r =
   372       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   373        Logic.strip_assums_hyp r, Logic.strip_params r);
   374 
   375     val intrs = map dest_intr intr_ts ~~ intr_names;
   376 
   377     val rules1 = [disjE, exE, FalseE];
   378     val rules2 = [conjE, FalseE, notTrueE];
   379 
   380     fun prove_elim c =
   381       let
   382         val Ts = List.drop (binder_types (fastype_of c), length params);
   383         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   384         val frees = map Free (anames ~~ Ts);
   385 
   386         fun mk_elim_prem ((_, _, us, _), ts, params') =
   387           list_all (params',
   388             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   389               (frees ~~ us) @ ts, P));
   390         val c_intrs = (List.filter (equal c o #1 o #1 o #1) intrs);
   391         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   392            map mk_elim_prem (map #1 c_intrs)
   393       in
   394         (SkipProof.prove ctxt'' [] prems P
   395           (fn {prems, ...} => EVERY
   396             [cut_facts_tac [hd prems] 1,
   397              rewrite_goals_tac rec_preds_defs,
   398              dtac (unfold RS iffD1) 1,
   399              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   400              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   401              EVERY (map (fn prem =>
   402                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   403           |> rulify
   404           |> singleton (ProofContext.export ctxt'' ctxt),
   405          map #2 c_intrs)
   406       end
   407 
   408    in map prove_elim cs end;
   409 
   410 
   411 (* derivation of simplified elimination rules *)
   412 
   413 local
   414 
   415 (*delete needless equality assumptions*)
   416 val refl_thin = Goal.prove_global HOL.thy [] [] @{prop "!!P. a = a ==> P ==> P"}
   417   (fn _ => assume_tac 1);
   418 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   419 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   420 
   421 fun simp_case_tac ss i =
   422   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   423 
   424 in
   425 
   426 fun mk_cases ctxt prop =
   427   let
   428     val thy = ProofContext.theory_of ctxt;
   429     val ss = Simplifier.local_simpset_of ctxt;
   430 
   431     fun err msg =
   432       error (Pretty.string_of (Pretty.block
   433         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   434 
   435     val elims = Induct.find_casesP ctxt prop;
   436 
   437     val cprop = Thm.cterm_of thy prop;
   438     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   439     fun mk_elim rl =
   440       Thm.implies_intr cprop (Tactic.rule_by_tactic tac (Thm.assume cprop RS rl))
   441       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   442   in
   443     (case get_first (try mk_elim) elims of
   444       SOME r => r
   445     | NONE => err "Proposition not an inductive predicate:")
   446   end;
   447 
   448 end;
   449 
   450 
   451 (* inductive_cases *)
   452 
   453 fun gen_inductive_cases prep_att prep_prop args lthy =
   454   let
   455     val thy = ProofContext.theory_of lthy;
   456     val facts = args |> map (fn ((a, atts), props) =>
   457       ((a, map (prep_att thy) atts),
   458         map (Thm.no_attributes o single o mk_cases lthy o prep_prop lthy) props));
   459   in lthy |> LocalTheory.notes Thm.theoremK facts |>> map snd end;
   460 
   461 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   462 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   463 
   464 
   465 fun ind_cases src = Method.syntax (Scan.lift (Scan.repeat1 Args.name --
   466     Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.name) [])) src
   467   #> (fn ((raw_props, fixes), ctxt) =>
   468     let
   469       val (_, ctxt') = Variable.add_fixes fixes ctxt;
   470       val props = Syntax.read_props ctxt' raw_props;
   471       val ctxt'' = fold Variable.declare_term props ctxt';
   472       val rules = ProofContext.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   473     in Method.erule 0 rules end);
   474 
   475 
   476 
   477 (* prove induction rule *)
   478 
   479 fun prove_indrule cs argTs bs xs rec_const params intr_ts mono
   480     fp_def rec_preds_defs ctxt =
   481   let
   482     val _ = clean_message "  Proving the induction rule ...";
   483     val thy = ProofContext.theory_of ctxt;
   484 
   485     (* predicates for induction rule *)
   486 
   487     val (pnames, ctxt') = ctxt |>
   488       Variable.add_fixes (map (fst o dest_Free) params) |> snd |>
   489       Variable.variant_fixes (mk_names "P" (length cs));
   490     val preds = map Free (pnames ~~
   491       map (fn c => List.drop (binder_types (fastype_of c), length params) --->
   492         HOLogic.boolT) cs);
   493 
   494     (* transform an introduction rule into a premise for induction rule *)
   495 
   496     fun mk_ind_prem r =
   497       let
   498         fun subst s = (case dest_predicate cs params s of
   499             SOME (_, i, ys, (_, Ts)) =>
   500               let
   501                 val k = length Ts;
   502                 val bs = map Bound (k - 1 downto 0);
   503                 val P = list_comb (List.nth (preds, i),
   504                   map (incr_boundvars k) ys @ bs);
   505                 val Q = list_abs (mk_names "x" k ~~ Ts,
   506                   HOLogic.mk_binop inductive_conj_name
   507                     (list_comb (incr_boundvars k s, bs), P))
   508               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   509           | NONE => (case s of
   510               (t $ u) => (fst (subst t) $ fst (subst u), NONE)
   511             | (Abs (a, T, t)) => (Abs (a, T, fst (subst t)), NONE)
   512             | _ => (s, NONE)));
   513 
   514         fun mk_prem (s, prems) = (case subst s of
   515               (_, SOME (t, u)) => t :: u :: prems
   516             | (t, _) => t :: prems);
   517 
   518         val SOME (_, i, ys, _) = dest_predicate cs params
   519           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))
   520 
   521       in list_all_free (Logic.strip_params r,
   522         Logic.list_implies (map HOLogic.mk_Trueprop (foldr mk_prem
   523           [] (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r))),
   524             HOLogic.mk_Trueprop (list_comb (List.nth (preds, i), ys))))
   525       end;
   526 
   527     val ind_prems = map mk_ind_prem intr_ts;
   528 
   529 
   530     (* make conclusions for induction rules *)
   531 
   532     val Tss = map (binder_types o fastype_of) preds;
   533     val (xnames, ctxt'') =
   534       Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   535     val mutual_ind_concl = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   536         (map (fn (((xnames, Ts), c), P) =>
   537            let val frees = map Free (xnames ~~ Ts)
   538            in HOLogic.mk_imp
   539              (list_comb (c, params @ frees), list_comb (P, frees))
   540            end) (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   541 
   542 
   543     (* make predicate for instantiation of abstract induction rule *)
   544 
   545     val ind_pred = fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   546       (map_index (fn (i, P) => foldr HOLogic.mk_imp
   547          (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))
   548          (make_bool_args HOLogic.mk_not I bs i)) preds));
   549 
   550     val ind_concl = HOLogic.mk_Trueprop
   551       (HOLogic.mk_binrel "HOL.ord_class.less_eq" (rec_const, ind_pred));
   552 
   553     val raw_fp_induct = (mono RS (fp_def RS def_lfp_induct));
   554 
   555     val induct = SkipProof.prove ctxt'' [] ind_prems ind_concl
   556       (fn {prems, ...} => EVERY
   557         [rewrite_goals_tac [inductive_conj_def],
   558          DETERM (rtac raw_fp_induct 1),
   559          REPEAT (resolve_tac [le_funI, le_boolI] 1),
   560          rewrite_goals_tac (inf_fun_eq :: inf_bool_eq :: simp_thms'),
   561          (*This disjE separates out the introduction rules*)
   562          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   563          (*Now break down the individual cases.  No disjE here in case
   564            some premise involves disjunction.*)
   565          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   566          REPEAT (FIRSTGOAL
   567            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   568          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   569              (inductive_conj_def :: rec_preds_defs @ simp_thms') prem,
   570            conjI, refl] 1)) prems)]);
   571 
   572     val lemma = SkipProof.prove ctxt'' [] []
   573       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   574         [rewrite_goals_tac rec_preds_defs,
   575          REPEAT (EVERY
   576            [REPEAT (resolve_tac [conjI, impI] 1),
   577             REPEAT (eresolve_tac [le_funE, le_boolE] 1),
   578             atac 1,
   579             rewrite_goals_tac simp_thms',
   580             atac 1])])
   581 
   582   in singleton (ProofContext.export ctxt'' ctxt) (induct RS lemma) end;
   583 
   584 
   585 
   586 (** specification of (co)inductive predicates **)
   587 
   588 fun mk_ind_def alt_name coind cs intr_ts monos params cnames_syn ctxt =
   589   let
   590     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   591 
   592     val argTs = fold (fn c => fn Ts => Ts @
   593       (List.drop (binder_types (fastype_of c), length params) \\ Ts)) cs [];
   594     val k = log 2 1 (length cs);
   595     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   596     val p :: xs = map Free (Variable.variant_frees ctxt intr_ts
   597       (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   598     val bs = map Free (Variable.variant_frees ctxt (p :: xs @ intr_ts)
   599       (map (rpair HOLogic.boolT) (mk_names "b" k)));
   600 
   601     fun subst t = (case dest_predicate cs params t of
   602         SOME (_, i, ts, (Ts, Us)) =>
   603           let
   604             val l = length Us;
   605             val zs = map Bound (l - 1 downto 0)
   606           in
   607             list_abs (map (pair "z") Us, list_comb (p,
   608               make_bool_args' bs i @ make_args argTs
   609                 ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   610           end
   611       | NONE => (case t of
   612           t1 $ t2 => subst t1 $ subst t2
   613         | Abs (x, T, u) => Abs (x, T, subst u)
   614         | _ => t));
   615 
   616     (* transform an introduction rule into a conjunction  *)
   617     (*   [| p_i t; ... |] ==> p_j u                       *)
   618     (* is transformed into                                *)
   619     (*   b_j & x_j = u & p b_j t & ...                    *)
   620 
   621     fun transform_rule r =
   622       let
   623         val SOME (_, i, ts, (Ts, _)) = dest_predicate cs params
   624           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   625         val ps = make_bool_args HOLogic.mk_not I bs i @
   626           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   627           map (subst o HOLogic.dest_Trueprop)
   628             (Logic.strip_assums_hyp r)
   629       in foldr (fn ((x, T), P) => HOLogic.exists_const T $ (Abs (x, T, P)))
   630         (if null ps then HOLogic.true_const else foldr1 HOLogic.mk_conj ps)
   631         (Logic.strip_params r)
   632       end
   633 
   634     (* make a disjunction of all introduction rules *)
   635 
   636     val fp_fun = fold_rev lambda (p :: bs @ xs)
   637       (if null intr_ts then HOLogic.false_const
   638        else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   639 
   640     (* add definiton of recursive predicates to theory *)
   641 
   642     val rec_name = if alt_name = "" then
   643       space_implode "_" (map fst cnames_syn) else alt_name;
   644 
   645     val ((rec_const, (_, fp_def)), ctxt') = ctxt |>
   646       LocalTheory.define Thm.internalK
   647         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   648          (("", []), fold_rev lambda params
   649            (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)));
   650     val fp_def' = Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   651       (cterm_of (ProofContext.theory_of ctxt') (list_comb (rec_const, params)));
   652     val specs = if length cs < 2 then [] else
   653       map_index (fn (i, (name_mx, c)) =>
   654         let
   655           val Ts = List.drop (binder_types (fastype_of c), length params);
   656           val xs = map Free (Variable.variant_frees ctxt intr_ts
   657             (mk_names "x" (length Ts) ~~ Ts))
   658         in
   659           (name_mx, (("", []), fold_rev lambda (params @ xs)
   660             (list_comb (rec_const, params @ make_bool_args' bs i @
   661               make_args argTs (xs ~~ Ts)))))
   662         end) (cnames_syn ~~ cs);
   663     val (consts_defs, ctxt'') = fold_map (LocalTheory.define Thm.internalK) specs ctxt';
   664     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   665 
   666     val mono = prove_mono predT fp_fun monos ctxt''
   667 
   668   in (ctxt'', rec_name, mono, fp_def', map (#2 o #2) consts_defs,
   669     list_comb (rec_const, params), preds, argTs, bs, xs)
   670   end;
   671 
   672 fun declare_rules kind rec_name coind no_ind cnames intrs intr_names intr_atts
   673       elims raw_induct ctxt =
   674   let
   675     val ind_case_names = RuleCases.case_names intr_names;
   676     val induct =
   677       if coind then
   678         (raw_induct, [RuleCases.case_names [rec_name],
   679           RuleCases.case_conclusion (rec_name, intr_names),
   680           RuleCases.consumes 1, Induct.coinduct_pred (hd cnames)])
   681       else if no_ind orelse length cnames > 1 then
   682         (raw_induct, [ind_case_names, RuleCases.consumes 0])
   683       else (raw_induct RSN (2, rev_mp), [ind_case_names, RuleCases.consumes 1]);
   684 
   685     val (intrs', ctxt1) =
   686       ctxt |>
   687       LocalTheory.notes kind
   688         (map (NameSpace.qualified rec_name) intr_names ~~
   689          intr_atts ~~ map (fn th => [([th],
   690            [Attrib.internal (K (ContextRules.intro_query NONE))])]) intrs) |>>
   691       map (hd o snd);
   692     val (((_, elims'), (_, [induct'])), ctxt2) =
   693       ctxt1 |>
   694       LocalTheory.note kind ((NameSpace.qualified rec_name "intros", []), intrs') ||>>
   695       fold_map (fn (name, (elim, cases)) =>
   696         LocalTheory.note kind ((NameSpace.qualified (Sign.base_name name) "cases",
   697           [Attrib.internal (K (RuleCases.case_names cases)),
   698            Attrib.internal (K (RuleCases.consumes 1)),
   699            Attrib.internal (K (Induct.cases_pred name)),
   700            Attrib.internal (K (ContextRules.elim_query NONE))]), [elim]) #>
   701         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   702       LocalTheory.note kind ((NameSpace.qualified rec_name (coind_prefix coind ^ "induct"),
   703         map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   704 
   705     val ctxt3 = if no_ind orelse coind then ctxt2 else
   706       let val inducts = cnames ~~ ProjectRule.projects ctxt2 (1 upto length cnames) induct'
   707       in
   708         ctxt2 |>
   709         LocalTheory.notes kind [((NameSpace.qualified rec_name "inducts", []),
   710           inducts |> map (fn (name, th) => ([th],
   711             [Attrib.internal (K ind_case_names),
   712              Attrib.internal (K (RuleCases.consumes 1)),
   713              Attrib.internal (K (Induct.induct_pred name))])))] |> snd
   714       end
   715   in (intrs', elims', induct', ctxt3) end;
   716 
   717 type add_ind_def =
   718   {verbose: bool, kind: string, alt_name: bstring, coind: bool, no_elim: bool, no_ind: bool} ->
   719   term list -> ((string * Attrib.src list) * term) list -> thm list ->
   720   term list -> (string * mixfix) list ->
   721   local_theory -> inductive_result * local_theory
   722 
   723 fun add_ind_def {verbose, kind, alt_name, coind, no_elim, no_ind}
   724     cs intros monos params cnames_syn ctxt =
   725   let
   726     val _ = null cnames_syn andalso error "No inductive predicates given";
   727     val _ =
   728       if verbose then message ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^
   729         commas_quote (map fst cnames_syn)) else ();
   730 
   731     val cnames = map (Sign.full_name (ProofContext.theory_of ctxt) o #1) cnames_syn;  (* FIXME *)
   732     val ((intr_names, intr_atts), intr_ts) =
   733       apfst split_list (split_list (map (check_rule ctxt cs params) intros));
   734 
   735     val (ctxt1, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   736       argTs, bs, xs) = mk_ind_def alt_name coind cs intr_ts monos params cnames_syn ctxt;
   737 
   738     val (intrs, unfold) = prove_intrs coind mono fp_def (length bs + length xs)
   739       params intr_ts rec_preds_defs ctxt1;
   740     val elims = if no_elim then [] else
   741       prove_elims cs params intr_ts intr_names unfold rec_preds_defs ctxt1;
   742     val raw_induct = zero_var_indexes
   743       (if no_ind then Drule.asm_rl else
   744        if coind then
   745          singleton (ProofContext.export
   746            (snd (Variable.add_fixes (map (fst o dest_Free) params) ctxt1)) ctxt1)
   747            (rotate_prems ~1 (ObjectLogic.rulify (rule_by_tactic
   748              (rewrite_tac [le_fun_def, le_bool_def, sup_fun_eq, sup_bool_eq] THEN
   749                fold_tac rec_preds_defs) (mono RS (fp_def RS def_coinduct)))))
   750        else
   751          prove_indrule cs argTs bs xs rec_const params intr_ts mono fp_def
   752            rec_preds_defs ctxt1);
   753 
   754     val (intrs', elims', induct, ctxt2) = declare_rules kind rec_name coind no_ind
   755       cnames intrs intr_names intr_atts elims raw_induct ctxt1;
   756 
   757     val names = map #1 cnames_syn;
   758     val result =
   759       {preds = preds,
   760        intrs = intrs',
   761        elims = elims',
   762        raw_induct = rulify raw_induct,
   763        induct = induct};
   764 
   765     val ctxt3 = ctxt2
   766       |> LocalTheory.declaration (fn phi =>
   767         let val result' = morph_result phi result;
   768         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   769   in (result, ctxt3) end;
   770 
   771 
   772 (* external interfaces *)
   773 
   774 fun gen_add_inductive_i mk_def (flags as {verbose, kind, alt_name, coind, no_elim, no_ind})
   775     cnames_syn pnames spec monos lthy =
   776   let
   777     val thy = ProofContext.theory_of lthy;
   778     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   779 
   780 
   781     (* abbrevs *)
   782 
   783     val (_, ctxt1) = Variable.add_fixes (map (fst o fst) cnames_syn) lthy;
   784 
   785     fun get_abbrev ((name, atts), t) =
   786       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   787         let
   788           val _ = name = "" andalso null atts orelse
   789             error "Abbreviations may not have names or attributes";
   790           val ((x, T), rhs) = LocalDefs.abs_def (snd (LocalDefs.cert_def ctxt1 t));
   791           val mx =
   792             (case find_first (fn ((c, _), _) => c = x) cnames_syn of
   793               NONE => error ("Undeclared head of abbreviation " ^ quote x)
   794             | SOME ((_, T'), mx) =>
   795                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
   796                 else mx);
   797         in SOME ((x, mx), rhs) end
   798       else NONE;
   799 
   800     val abbrevs = map_filter get_abbrev spec;
   801     val bs = map (fst o fst) abbrevs;
   802 
   803 
   804     (* predicates *)
   805 
   806     val pre_intros = filter_out (is_some o get_abbrev) spec;
   807     val cnames_syn' = filter_out (member (op =) bs o fst o fst) cnames_syn;
   808     val cs = map (Free o fst) cnames_syn';
   809     val ps = map Free pnames;
   810 
   811     val (_, ctxt2) = lthy |> Variable.add_fixes (map (fst o fst) cnames_syn');
   812     val _ = map (fn abbr => LocalDefs.fixed_abbrev abbr ctxt2) abbrevs;
   813     val ctxt3 = ctxt2 |> fold (snd oo LocalDefs.fixed_abbrev) abbrevs;
   814     val expand = Assumption.export_term ctxt3 lthy #> ProofContext.cert_term lthy;
   815 
   816     fun close_rule r = list_all_free (rev (fold_aterms
   817       (fn t as Free (v as (s, _)) =>
   818           if Variable.is_fixed ctxt1 s orelse
   819             member (op =) ps t then I else insert (op =) v
   820         | _ => I) r []), r);
   821 
   822     val intros = map (apsnd (close_rule #> expand)) pre_intros;
   823     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
   824   in
   825     lthy
   826     |> mk_def flags cs intros monos ps preds
   827     ||> fold (snd oo LocalTheory.abbrev Syntax.mode_default) abbrevs
   828   end;
   829 
   830 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos lthy =
   831   let
   832     val ((vars, specs), _) = lthy |> ProofContext.set_mode ProofContext.mode_abbrev
   833       |> Specification.read_specification
   834           (cnames_syn @ pnames_syn) (map (fn (a, s) => [(a, [s])]) intro_srcs);
   835     val (cs, ps) = chop (length cnames_syn) vars;
   836     val intrs = map (apsnd the_single) specs;
   837     val monos = Attrib.eval_thms lthy raw_monos;
   838     val flags = {verbose = verbose, kind = Thm.theoremK, alt_name = "",
   839       coind = coind, no_elim = false, no_ind = false};
   840   in
   841     lthy
   842     |> LocalTheory.set_group (serial_string ())
   843     |> gen_add_inductive_i mk_def flags cs (map fst ps) intrs monos
   844   end;
   845 
   846 val add_inductive_i = gen_add_inductive_i add_ind_def;
   847 val add_inductive = gen_add_inductive add_ind_def;
   848 
   849 fun add_inductive_global group flags cnames_syn pnames pre_intros monos thy =
   850   let
   851     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
   852     val ctxt' = thy
   853       |> TheoryTarget.init NONE
   854       |> LocalTheory.set_group group
   855       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
   856       |> LocalTheory.exit;
   857     val info = #2 (the_inductive ctxt' name);
   858   in (info, ProofContext.theory_of ctxt') end;
   859 
   860 
   861 (* read off arities of inductive predicates from raw induction rule *)
   862 fun arities_of induct =
   863   map (fn (_ $ t $ u) =>
   864       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
   865     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
   866 
   867 (* read off parameters of inductive predicate from raw induction rule *)
   868 fun params_of induct =
   869   let
   870     val (_ $ t $ u :: _) =
   871       HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
   872     val (_, ts) = strip_comb t;
   873     val (_, us) = strip_comb u
   874   in
   875     List.take (ts, length ts - length us)
   876   end;
   877 
   878 val pname_of_intr =
   879   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
   880 
   881 (* partition introduction rules according to predicate name *)
   882 fun gen_partition_rules f induct intros =
   883   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
   884     (map (rpair [] o fst) (arities_of induct));
   885 
   886 val partition_rules = gen_partition_rules I;
   887 fun partition_rules' induct = gen_partition_rules fst induct;
   888 
   889 fun unpartition_rules intros xs =
   890   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
   891     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
   892 
   893 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
   894 fun infer_intro_vars elim arity intros =
   895   let
   896     val thy = theory_of_thm elim;
   897     val _ :: cases = prems_of elim;
   898     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
   899     fun mtch (t, u) =
   900       let
   901         val params = Logic.strip_params t;
   902         val vars = map (Var o apfst (rpair 0))
   903           (Name.variant_list used (map fst params) ~~ map snd params);
   904         val ts = map (curry subst_bounds (rev vars))
   905           (List.drop (Logic.strip_assums_hyp t, arity));
   906         val us = Logic.strip_imp_prems u;
   907         val tab = fold (Pattern.first_order_match thy) (ts ~~ us)
   908           (Vartab.empty, Vartab.empty);
   909       in
   910         map (Envir.subst_vars tab) vars
   911       end
   912   in
   913     map (mtch o apsnd prop_of) (cases ~~ intros)
   914   end;
   915 
   916 
   917 
   918 (** package setup **)
   919 
   920 (* setup theory *)
   921 
   922 val setup =
   923   Method.add_methods [("ind_cases", ind_cases,
   924     "dynamic case analysis on predicates")] #>
   925   Attrib.add_attributes [("mono", Attrib.add_del_args mono_add mono_del,
   926     "declaration of monotonicity rule")];
   927 
   928 
   929 (* outer syntax *)
   930 
   931 local structure P = OuterParse and K = OuterKeyword in
   932 
   933 val _ = OuterSyntax.keywords ["monos"];
   934 
   935 fun flatten_specification specs = specs |> maps
   936   (fn (a, (concl, [])) => concl |> map
   937         (fn ((b, atts), [B]) =>
   938               if a = "" then ((b, atts), B)
   939               else if b = "" then ((a, atts), B)
   940               else error ("Illegal nested case names " ^ quote (NameSpace.append a b))
   941           | ((b, _), _) => error ("Illegal simultaneous specification " ^ quote b))
   942     | (a, _) => error ("Illegal local specification parameters for " ^ quote a));
   943 
   944 fun gen_ind_decl mk_def coind =
   945   P.opt_target --
   946   P.fixes -- P.for_fixes --
   947   Scan.optional (P.$$$ "where" |-- P.!!! SpecParse.specification) [] --
   948   Scan.optional (P.$$$ "monos" |-- P.!!! SpecParse.xthms1) []
   949   >> (fn ((((loc, preds), params), specs), monos) =>
   950     Toplevel.local_theory loc
   951       (fn lthy => lthy |> gen_add_inductive mk_def true coind preds params
   952          (flatten_specification specs) monos |> snd));
   953 
   954 val ind_decl = gen_ind_decl add_ind_def;
   955 
   956 val _ = OuterSyntax.command "inductive" "define inductive predicates" K.thy_decl (ind_decl false);
   957 val _ = OuterSyntax.command "coinductive" "define coinductive predicates" K.thy_decl (ind_decl true);
   958 
   959 val _ =
   960   OuterSyntax.command "inductive_cases"
   961     "create simplified instances of elimination rules (improper)" K.thy_script
   962     (P.opt_target -- P.and_list1 SpecParse.spec
   963       >> (fn (loc, specs) => Toplevel.local_theory loc (snd o inductive_cases specs)));
   964 
   965 end;
   966 
   967 end;