src/HOL/Complex.thy
author haftmann
Wed Apr 22 19:09:21 2009 +0200 (2009-04-22)
changeset 30960 fec1a04b7220
parent 30729 461ee3e49ad3
child 31021 53642251a04f
permissions -rw-r--r--
power operation defined generic
     1 (*  Title:       Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_equality [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma expand_complex_eq: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 lemmas complex_Re_Im_cancel_iff = expand_complex_eq
    35 
    36 
    37 subsection {* Addition and Subtraction *}
    38 
    39 instantiation complex :: ab_group_add
    40 begin
    41 
    42 definition
    43   complex_zero_def: "0 = Complex 0 0"
    44 
    45 definition
    46   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    47 
    48 definition
    49   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    50 
    51 definition
    52   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    53 
    54 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_Re_zero [simp]: "Re 0 = 0"
    58   by (simp add: complex_zero_def)
    59 
    60 lemma complex_Im_zero [simp]: "Im 0 = 0"
    61   by (simp add: complex_zero_def)
    62 
    63 lemma complex_add [simp]:
    64   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    68   by (simp add: complex_add_def)
    69 
    70 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    71   by (simp add: complex_add_def)
    72 
    73 lemma complex_minus [simp]:
    74   "- (Complex a b) = Complex (- a) (- b)"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    78   by (simp add: complex_minus_def)
    79 
    80 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    81   by (simp add: complex_minus_def)
    82 
    83 lemma complex_diff [simp]:
    84   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    85   by (simp add: complex_diff_def)
    86 
    87 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    88   by (simp add: complex_diff_def)
    89 
    90 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    91   by (simp add: complex_diff_def)
    92 
    93 instance
    94   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    95 
    96 end
    97 
    98 
    99 
   100 subsection {* Multiplication and Division *}
   101 
   102 instantiation complex :: "{field, division_by_zero}"
   103 begin
   104 
   105 definition
   106   complex_one_def: "1 = Complex 1 0"
   107 
   108 definition
   109   complex_mult_def: "x * y =
   110     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   111 
   112 definition
   113   complex_inverse_def: "inverse x =
   114     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   115 
   116 definition
   117   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   118 
   119 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Re_one [simp]: "Re 1 = 1"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_Im_one [simp]: "Im 1 = 0"
   126   by (simp add: complex_one_def)
   127 
   128 lemma complex_mult [simp]:
   129   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   136   by (simp add: complex_mult_def)
   137 
   138 lemma complex_inverse [simp]:
   139   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   140   by (simp add: complex_inverse_def)
   141 
   142 lemma complex_Re_inverse:
   143   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   144   by (simp add: complex_inverse_def)
   145 
   146 lemma complex_Im_inverse:
   147   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   148   by (simp add: complex_inverse_def)
   149 
   150 instance
   151   by intro_classes (simp_all add: complex_mult_def
   152   right_distrib left_distrib right_diff_distrib left_diff_distrib
   153   complex_inverse_def complex_divide_def
   154   power2_eq_square add_divide_distrib [symmetric]
   155   expand_complex_eq)
   156 
   157 end
   158 
   159 
   160 subsection {* Exponentiation *}
   161 
   162 instance complex :: recpower ..
   163 
   164 
   165 subsection {* Numerals and Arithmetic *}
   166 
   167 instantiation complex :: number_ring
   168 begin
   169 
   170 definition number_of_complex where
   171   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   172 
   173 instance
   174   by intro_classes (simp only: complex_number_of_def)
   175 
   176 end
   177 
   178 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   179 by (induct n) simp_all
   180 
   181 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   182 by (induct n) simp_all
   183 
   184 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   185 by (cases z rule: int_diff_cases) simp
   186 
   187 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   188 by (cases z rule: int_diff_cases) simp
   189 
   190 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   191 unfolding number_of_eq by (rule complex_Re_of_int)
   192 
   193 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   194 unfolding number_of_eq by (rule complex_Im_of_int)
   195 
   196 lemma Complex_eq_number_of [simp]:
   197   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   198 by (simp add: expand_complex_eq)
   199 
   200 
   201 subsection {* Scalar Multiplication *}
   202 
   203 instantiation complex :: real_field
   204 begin
   205 
   206 definition
   207   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   208 
   209 lemma complex_scaleR [simp]:
   210   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   211   unfolding complex_scaleR_def by simp
   212 
   213 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   214   unfolding complex_scaleR_def by simp
   215 
   216 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   217   unfolding complex_scaleR_def by simp
   218 
   219 instance
   220 proof
   221   fix a b :: real and x y :: complex
   222   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   223     by (simp add: expand_complex_eq right_distrib)
   224   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   225     by (simp add: expand_complex_eq left_distrib)
   226   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   227     by (simp add: expand_complex_eq mult_assoc)
   228   show "scaleR 1 x = x"
   229     by (simp add: expand_complex_eq)
   230   show "scaleR a x * y = scaleR a (x * y)"
   231     by (simp add: expand_complex_eq algebra_simps)
   232   show "x * scaleR a y = scaleR a (x * y)"
   233     by (simp add: expand_complex_eq algebra_simps)
   234 qed
   235 
   236 end
   237 
   238 
   239 subsection{* Properties of Embedding from Reals *}
   240 
   241 abbreviation
   242   complex_of_real :: "real \<Rightarrow> complex" where
   243     "complex_of_real \<equiv> of_real"
   244 
   245 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   246 by (simp add: of_real_def complex_scaleR_def)
   247 
   248 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   249 by (simp add: complex_of_real_def)
   250 
   251 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   252 by (simp add: complex_of_real_def)
   253 
   254 lemma Complex_add_complex_of_real [simp]:
   255      "Complex x y + complex_of_real r = Complex (x+r) y"
   256 by (simp add: complex_of_real_def)
   257 
   258 lemma complex_of_real_add_Complex [simp]:
   259      "complex_of_real r + Complex x y = Complex (r+x) y"
   260 by (simp add: complex_of_real_def)
   261 
   262 lemma Complex_mult_complex_of_real:
   263      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   264 by (simp add: complex_of_real_def)
   265 
   266 lemma complex_of_real_mult_Complex:
   267      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   268 by (simp add: complex_of_real_def)
   269 
   270 
   271 subsection {* Vector Norm *}
   272 
   273 instantiation complex :: real_normed_field
   274 begin
   275 
   276 definition
   277   complex_norm_def: "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   278 
   279 abbreviation
   280   cmod :: "complex \<Rightarrow> real" where
   281   "cmod \<equiv> norm"
   282 
   283 definition
   284   complex_sgn_def: "sgn x = x /\<^sub>R cmod x"
   285 
   286 lemmas cmod_def = complex_norm_def
   287 
   288 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   289   by (simp add: complex_norm_def)
   290 
   291 instance
   292 proof
   293   fix r :: real and x y :: complex
   294   show "0 \<le> norm x"
   295     by (induct x) simp
   296   show "(norm x = 0) = (x = 0)"
   297     by (induct x) simp
   298   show "norm (x + y) \<le> norm x + norm y"
   299     by (induct x, induct y)
   300        (simp add: real_sqrt_sum_squares_triangle_ineq)
   301   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   302     by (induct x)
   303        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   304   show "norm (x * y) = norm x * norm y"
   305     by (induct x, induct y)
   306        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   307   show "sgn x = x /\<^sub>R cmod x" by(simp add: complex_sgn_def)
   308 qed
   309 
   310 end
   311 
   312 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   313 by simp
   314 
   315 lemma cmod_complex_polar [simp]:
   316      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   317 by (simp add: norm_mult)
   318 
   319 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   320 unfolding complex_norm_def
   321 by (rule real_sqrt_sum_squares_ge1)
   322 
   323 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   324 by (rule order_trans [OF _ norm_ge_zero], simp)
   325 
   326 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   327 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   328 
   329 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   330 
   331 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   332 by (cases x) simp
   333 
   334 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   335 by (cases x) simp
   336 
   337 subsection {* Completeness of the Complexes *}
   338 
   339 interpretation Re: bounded_linear "Re"
   340 apply (unfold_locales, simp, simp)
   341 apply (rule_tac x=1 in exI)
   342 apply (simp add: complex_norm_def)
   343 done
   344 
   345 interpretation Im: bounded_linear "Im"
   346 apply (unfold_locales, simp, simp)
   347 apply (rule_tac x=1 in exI)
   348 apply (simp add: complex_norm_def)
   349 done
   350 
   351 lemma LIMSEQ_Complex:
   352   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   353 apply (rule LIMSEQ_I)
   354 apply (subgoal_tac "0 < r / sqrt 2")
   355 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   356 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   357 apply (rename_tac M N, rule_tac x="max M N" in exI, safe)
   358 apply (simp add: real_sqrt_sum_squares_less)
   359 apply (simp add: divide_pos_pos)
   360 done
   361 
   362 instance complex :: banach
   363 proof
   364   fix X :: "nat \<Rightarrow> complex"
   365   assume X: "Cauchy X"
   366   from Re.Cauchy [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   367     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   368   from Im.Cauchy [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   369     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   370   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   371     using LIMSEQ_Complex [OF 1 2] by simp
   372   thus "convergent X"
   373     by (rule convergentI)
   374 qed
   375 
   376 
   377 subsection {* The Complex Number @{term "\<i>"} *}
   378 
   379 definition
   380   "ii" :: complex  ("\<i>") where
   381   i_def: "ii \<equiv> Complex 0 1"
   382 
   383 lemma complex_Re_i [simp]: "Re ii = 0"
   384 by (simp add: i_def)
   385 
   386 lemma complex_Im_i [simp]: "Im ii = 1"
   387 by (simp add: i_def)
   388 
   389 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   390 by (simp add: i_def)
   391 
   392 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   393 by (simp add: expand_complex_eq)
   394 
   395 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   396 by (simp add: expand_complex_eq)
   397 
   398 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   399 by (simp add: expand_complex_eq)
   400 
   401 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   402 by (simp add: expand_complex_eq)
   403 
   404 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   405 by (simp add: expand_complex_eq)
   406 
   407 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   408 by (simp add: i_def complex_of_real_def)
   409 
   410 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   411 by (simp add: i_def complex_of_real_def)
   412 
   413 lemma i_squared [simp]: "ii * ii = -1"
   414 by (simp add: i_def)
   415 
   416 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   417 by (simp add: power2_eq_square)
   418 
   419 lemma inverse_i [simp]: "inverse ii = - ii"
   420 by (rule inverse_unique, simp)
   421 
   422 
   423 subsection {* Complex Conjugation *}
   424 
   425 definition
   426   cnj :: "complex \<Rightarrow> complex" where
   427   "cnj z = Complex (Re z) (- Im z)"
   428 
   429 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   430 by (simp add: cnj_def)
   431 
   432 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   433 by (simp add: cnj_def)
   434 
   435 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   436 by (simp add: cnj_def)
   437 
   438 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   439 by (simp add: expand_complex_eq)
   440 
   441 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   442 by (simp add: cnj_def)
   443 
   444 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   445 by (simp add: expand_complex_eq)
   446 
   447 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   448 by (simp add: expand_complex_eq)
   449 
   450 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   451 by (simp add: expand_complex_eq)
   452 
   453 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   454 by (simp add: expand_complex_eq)
   455 
   456 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   457 by (simp add: expand_complex_eq)
   458 
   459 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   460 by (simp add: expand_complex_eq)
   461 
   462 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   463 by (simp add: expand_complex_eq)
   464 
   465 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   466 by (simp add: complex_inverse_def)
   467 
   468 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   469 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   470 
   471 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   472 by (induct n, simp_all add: complex_cnj_mult)
   473 
   474 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   475 by (simp add: expand_complex_eq)
   476 
   477 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   478 by (simp add: expand_complex_eq)
   479 
   480 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   481 by (simp add: expand_complex_eq)
   482 
   483 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   484 by (simp add: expand_complex_eq)
   485 
   486 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   487 by (simp add: complex_norm_def)
   488 
   489 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   490 by (simp add: expand_complex_eq)
   491 
   492 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   493 by (simp add: expand_complex_eq)
   494 
   495 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   496 by (simp add: expand_complex_eq)
   497 
   498 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   499 by (simp add: expand_complex_eq)
   500 
   501 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   502 by (simp add: expand_complex_eq power2_eq_square)
   503 
   504 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   505 by (simp add: norm_mult power2_eq_square)
   506 
   507 interpretation cnj: bounded_linear "cnj"
   508 apply (unfold_locales)
   509 apply (rule complex_cnj_add)
   510 apply (rule complex_cnj_scaleR)
   511 apply (rule_tac x=1 in exI, simp)
   512 done
   513 
   514 
   515 subsection{*The Functions @{term sgn} and @{term arg}*}
   516 
   517 text {*------------ Argand -------------*}
   518 
   519 definition
   520   arg :: "complex => real" where
   521   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   522 
   523 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   524 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   525 
   526 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   527 by (simp add: i_def complex_of_real_def)
   528 
   529 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   530 by (simp add: i_def complex_one_def)
   531 
   532 lemma complex_eq_cancel_iff2 [simp]:
   533      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   534 by (simp add: complex_of_real_def)
   535 
   536 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   537 by (simp add: complex_sgn_def divide_inverse)
   538 
   539 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   540 by (simp add: complex_sgn_def divide_inverse)
   541 
   542 lemma complex_inverse_complex_split:
   543      "inverse(complex_of_real x + ii * complex_of_real y) =
   544       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   545       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   546 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   547 
   548 (*----------------------------------------------------------------------------*)
   549 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   550 (* many of the theorems are not used - so should they be kept?                *)
   551 (*----------------------------------------------------------------------------*)
   552 
   553 lemma cos_arg_i_mult_zero_pos:
   554    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   555 apply (simp add: arg_def abs_if)
   556 apply (rule_tac a = "pi/2" in someI2, auto)
   557 apply (rule order_less_trans [of _ 0], auto)
   558 done
   559 
   560 lemma cos_arg_i_mult_zero_neg:
   561    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   562 apply (simp add: arg_def abs_if)
   563 apply (rule_tac a = "- pi/2" in someI2, auto)
   564 apply (rule order_trans [of _ 0], auto)
   565 done
   566 
   567 lemma cos_arg_i_mult_zero [simp]:
   568      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   569 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   570 
   571 
   572 subsection{*Finally! Polar Form for Complex Numbers*}
   573 
   574 definition
   575 
   576   (* abbreviation for (cos a + i sin a) *)
   577   cis :: "real => complex" where
   578   "cis a = Complex (cos a) (sin a)"
   579 
   580 definition
   581   (* abbreviation for r*(cos a + i sin a) *)
   582   rcis :: "[real, real] => complex" where
   583   "rcis r a = complex_of_real r * cis a"
   584 
   585 definition
   586   (* e ^ (x + iy) *)
   587   expi :: "complex => complex" where
   588   "expi z = complex_of_real(exp (Re z)) * cis (Im z)"
   589 
   590 lemma complex_split_polar:
   591      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   592 apply (induct z)
   593 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   594 done
   595 
   596 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   597 apply (induct z)
   598 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   599 done
   600 
   601 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   602 by (simp add: rcis_def cis_def)
   603 
   604 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   605 by (simp add: rcis_def cis_def)
   606 
   607 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   608 proof -
   609   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   610     by (simp only: power_mult_distrib right_distrib)
   611   thus ?thesis by simp
   612 qed
   613 
   614 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   615 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   616 
   617 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   618 by (simp add: cmod_def power2_eq_square)
   619 
   620 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   621 by simp
   622 
   623 
   624 (*---------------------------------------------------------------------------*)
   625 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   626 (*---------------------------------------------------------------------------*)
   627 
   628 lemma cis_rcis_eq: "cis a = rcis 1 a"
   629 by (simp add: rcis_def)
   630 
   631 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   632 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   633               complex_of_real_def)
   634 
   635 lemma cis_mult: "cis a * cis b = cis (a + b)"
   636 by (simp add: cis_rcis_eq rcis_mult)
   637 
   638 lemma cis_zero [simp]: "cis 0 = 1"
   639 by (simp add: cis_def complex_one_def)
   640 
   641 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   642 by (simp add: rcis_def)
   643 
   644 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   645 by (simp add: rcis_def)
   646 
   647 lemma complex_of_real_minus_one:
   648    "complex_of_real (-(1::real)) = -(1::complex)"
   649 by (simp add: complex_of_real_def complex_one_def)
   650 
   651 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   652 by (simp add: mult_assoc [symmetric])
   653 
   654 
   655 lemma cis_real_of_nat_Suc_mult:
   656    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   657 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   658 
   659 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   660 apply (induct_tac "n")
   661 apply (auto simp add: cis_real_of_nat_Suc_mult)
   662 done
   663 
   664 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   665 by (simp add: rcis_def power_mult_distrib DeMoivre)
   666 
   667 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   668 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   669 
   670 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   671 by (simp add: divide_inverse rcis_def)
   672 
   673 lemma cis_divide: "cis a / cis b = cis (a - b)"
   674 by (simp add: complex_divide_def cis_mult real_diff_def)
   675 
   676 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   677 apply (simp add: complex_divide_def)
   678 apply (case_tac "r2=0", simp)
   679 apply (simp add: rcis_inverse rcis_mult real_diff_def)
   680 done
   681 
   682 lemma Re_cis [simp]: "Re(cis a) = cos a"
   683 by (simp add: cis_def)
   684 
   685 lemma Im_cis [simp]: "Im(cis a) = sin a"
   686 by (simp add: cis_def)
   687 
   688 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   689 by (auto simp add: DeMoivre)
   690 
   691 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   692 by (auto simp add: DeMoivre)
   693 
   694 lemma expi_add: "expi(a + b) = expi(a) * expi(b)"
   695 by (simp add: expi_def exp_add cis_mult [symmetric] mult_ac)
   696 
   697 lemma expi_zero [simp]: "expi (0::complex) = 1"
   698 by (simp add: expi_def)
   699 
   700 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   701 apply (insert rcis_Ex [of z])
   702 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   703 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   704 done
   705 
   706 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   707 by (simp add: expi_def cis_def)
   708 
   709 end